configure.ac

   1 AC_PREREQ(2.57)
   2
   3 dnl Version not hardcoded here. Fetched later from ares_version.h
   4 AC_INIT([c-ares], [-],
   5   [c-ares mailing list => http://cool.haxx.se/mailman/listinfo/c-ares])
   6
   7 CARES_OVERRIDE_AUTOCONF
   8
   9 AC_CONFIG_SRCDIR([ares_ipv6.h])
  10 AM_CONFIG_HEADER([ares_config.h ares_build.h])
  11 AM_MAINTAINER_MODE
  12
  13 CARES_CHECK_OPTION_DEBUG
  14 CARES_CHECK_OPTION_OPTIMIZE
  15 CARES_CHECK_OPTION_WARNINGS
  16 CARES_CHECK_OPTION_CURLDEBUG
  17 CARES_CHECK_OPTION_SYMBOL_HIDING
  18
  19 CARES_CHECK_PATH_SEPARATOR_REQUIRED
  20
  21 dnl SED is mandatory for configure process and libtool.
  22 dnl Set it now, allowing it to be changed later.
  23 AC_PATH_PROG([SED], [sed], [not_found],
  24   [$PATH:/usr/bin:/usr/local/bin])
  25 if test -z "$SED" || test "$SED" = "not_found"; then
  26   AC_MSG_ERROR([sed not found in PATH. Cannot continue without sed.])
  27 fi
  28 AC_SUBST([SED])
  29
  30 dnl GREP is mandatory for configure process and libtool.
  31 dnl Set it now, allowing it to be changed later.
  32 AC_PATH_PROG([GREP], [grep], [not_found],
  33   [$PATH:/usr/bin:/usr/local/bin])
  34 if test -z "$GREP" || test "$GREP" = "not_found"; then
  35   AC_MSG_ERROR([grep not found in PATH. Cannot continue without grep.])
  36 fi
  37 AC_SUBST([GREP])
  38
  39 dnl EGREP is mandatory for configure process and libtool.
  40 dnl Set it now, allowing it to be changed later.
  41 if echo a | ($GREP -E '(a|b)') >/dev/null 2>&1; then
  42   AC_MSG_CHECKING([for egrep])
  43   EGREP="$GREP -E"
  44   AC_MSG_RESULT([$EGREP])
  45 else
  46   AC_PATH_PROG([EGREP], [egrep], [not_found],
  47     [$PATH:/usr/bin:/usr/local/bin])
  48 fi
  49 if test -z "$EGREP" || test "$EGREP" = "not_found"; then
  50   AC_MSG_ERROR([egrep not found in PATH. Cannot continue without egrep.])
  51 fi
  52 AC_SUBST([EGREP])
  53
  54 dnl AR is mandatory for configure process and libtool.
  55 dnl This is target dependent, so check it as a tool.
  56 AC_PATH_TOOL([AR], [ar], [not_found],
  57   [$PATH:/usr/bin:/usr/local/bin])
  58 if test -z "$AR" || test "$AR" = "not_found"; then
  59   AC_MSG_ERROR([ar not found in PATH. Cannot continue without ar.])
  60 fi
  61 AC_SUBST([AR])
  62
  63 dnl Fetch c-ares version from ares_version.h
  64 VERSION=`$SED -ne 's/^#define ARES_VERSION_STR "\(.*\)"/\1/p' ${srcdir}/ares_version.h`
  65 AM_INIT_AUTOMAKE([c-ares], [$VERSION])
  66 AC_MSG_CHECKING([c-ares version])
  67 AC_MSG_RESULT([$VERSION])
  68
  69 dnl
  70 dnl Detect the canonical host and target build environment
  71 dnl
  72
  73 AC_CANONICAL_HOST
  74 dnl Get system canonical name
  75 AC_DEFINE_UNQUOTED(OS, "${host}", [cpu-machine-OS])
  76
  77 CARES_CHECK_PROG_CC
  78 AM_PROG_CC_C_O
  79 AC_PROG_INSTALL
  80
  81 dnl This defines _ALL_SOURCE for AIX
  82 CARES_CHECK_AIX_ALL_SOURCE
  83
  84 dnl Our configure and build reentrant settings
  85 CARES_CONFIGURE_THREAD_SAFE
  86 CARES_CONFIGURE_REENTRANT
  87
  88 dnl check for how to do large files
  89 AC_SYS_LARGEFILE
  90
  91 case $host_os in
  92   solaris*)
  93     AC_DEFINE(ETC_INET, 1, [if a /etc/inet dir is being used])
  94     ;;
  95 esac
  96
  97 dnl support building of Windows DLLs
  98 AC_LIBTOOL_WIN32_DLL
  99
 100 dnl force libtool to build static libraries with PIC on AMD64-Linux & FreeBSD
 101 AC_MSG_CHECKING([if arch-OS host is AMD64-Linux/FreeBSD (to build static libraries with PIC)])
 102 case $host in
 103   x86_64*linux*|amd64*freebsd*|ia64*freebsd*)
 104     AC_MSG_RESULT([yes])
 105     with_pic=yes
 106     ;;
 107   *)
 108     AC_MSG_RESULT([no])
 109     ;;
 110 esac
 111
 112 dnl libtool setup
 113 AC_PROG_LIBTOOL
 114
 115 AC_MSG_CHECKING([if we need CARES_BUILDING_LIBRARY])
 116 case $host in
 117   *-*-mingw*)
 118     AC_DEFINE(CARES_BUILDING_LIBRARY, 1, [when building c-ares library])
 119     AC_MSG_RESULT(yes)
 120     AC_MSG_CHECKING([if we need CARES_STATICLIB])
 121     if test "X$enable_shared" = "Xno"
 122     then
 123       AC_DEFINE(CARES_STATICLIB, 1, [when not building a shared library])
 124       AC_MSG_RESULT(yes)
 125     else
 126       AC_MSG_RESULT(no)
 127     fi
 128     ;;
 129   *)
 130     AC_MSG_RESULT(no)
 131     ;;
 132 esac
 133
 134 dnl **********************************************************************
 135 dnl platform/compiler/architecture specific checks/flags
 136 dnl **********************************************************************
 137
 138 CARES_CHECK_COMPILER
 139 CARES_SET_COMPILER_BASIC_OPTS
 140 CARES_SET_COMPILER_DEBUG_OPTS
 141 CARES_SET_COMPILER_OPTIMIZE_OPTS
 142 CARES_SET_COMPILER_WARNING_OPTS
 143
 144 case $host in
 145   #
 146   x86_64*linux*|amd64*freebsd*|ia64*freebsd*)
 147     #
 148     if test "$compiler_id" = "INTEL_UNIX_C"; then
 149       #
 150       if test "$compiler_num" -ge "900" &&
 151         test "$compiler_num" -lt "1000"; then
 152         dnl icc 9.X specific
 153         CFLAGS="$CFLAGS -i-dynamic"
 154       fi
 155       #
 156       if test "$compiler_num" -ge "1000"; then
 157         dnl icc 10.X or later
 158         CFLAGS="$CFLAGS -shared-intel"
 159       fi
 160       #
 161     fi
 162     ;;
 163   #
 164 esac
 165
 166 CARES_CHECK_COMPILER_HALT_ON_ERROR
 167 CARES_CHECK_COMPILER_ARRAY_SIZE_NEGATIVE
 168 CARES_CHECK_COMPILER_SYMBOL_HIDING
 169
 170 CARES_CHECK_NO_UNDEFINED
 171 AM_CONDITIONAL(NO_UNDEFINED, test x$need_no_undefined = xyes)
 172
 173 CARES_CHECK_CURLDEBUG
 174 AM_CONDITIONAL(CURLDEBUG, test x$want_curldebug = xyes)
 175
 176 dnl **********************************************************************
 177 dnl Compilation based checks should not be done before this point.
 178 dnl **********************************************************************
 179
 180 dnl **********************************************************************
 181 dnl Make sure that our checks for headers windows.h winsock.h winsock2.h
 182 dnl and ws2tcpip.h take precedence over any other further checks which
 183 dnl could be done later using AC_CHECK_HEADER or AC_CHECK_HEADERS for
 184 dnl this specific header files. And do them before its results are used.
 185 dnl **********************************************************************
 186
 187 CURL_CHECK_HEADER_WINDOWS
 188 CURL_CHECK_NATIVE_WINDOWS
 189 case X-"$ac_cv_native_windows" in
 190   X-yes)
 191     CURL_CHECK_HEADER_WINSOCK
 192     CURL_CHECK_HEADER_WINSOCK2
 193     CURL_CHECK_HEADER_WS2TCPIP
 194     ;;
 195   *)
 196     ac_cv_header_winsock_h="no"
 197     ac_cv_header_winsock2_h="no"
 198     ac_cv_header_ws2tcpip_h="no"
 199     ;;
 200 esac
 201
 202 dnl **********************************************************************
 203 dnl Checks for libraries.
 204 dnl **********************************************************************
 205
 206 CARES_CHECK_LIB_XNET
 207
 208 dnl gethostbyname without lib or in the nsl lib?
 209 AC_CHECK_FUNC(gethostbyname,
 210               [HAVE_GETHOSTBYNAME="1"
 211               ],
 212               [ AC_CHECK_LIB(nsl, gethostbyname,
 213                              [HAVE_GETHOSTBYNAME="1"
 214                              LIBS="$LIBS -lnsl"
 215                              ])
 216               ])
 217
 218 if test "$HAVE_GETHOSTBYNAME" != "1"
 219 then
 220   dnl gethostbyname in the socket lib?
 221   AC_CHECK_LIB(socket, gethostbyname,
 222                [HAVE_GETHOSTBYNAME="1"
 223                LIBS="$LIBS -lsocket"
 224                ])
 225 fi
 226
 227 dnl At least one system has been identified to require BOTH nsl and socket
 228 dnl libs at the same time to link properly.
 229 if test "$HAVE_GETHOSTBYNAME" != "1"
 230 then
 231   AC_MSG_CHECKING([for gethostbyname with both nsl and socket libs])
 232   my_ac_save_LIBS=$LIBS
 233   LIBS="-lnsl -lsocket $LIBS"
 234   AC_LINK_IFELSE([
 235     AC_LANG_PROGRAM([[
 236     ]],[[
 237       gethostbyname();
 238     ]])
 239   ],[
 240     AC_MSG_RESULT([yes])
 241     HAVE_GETHOSTBYNAME="1"
 242   ],[
 243     AC_MSG_RESULT([no])
 244     LIBS=$my_ac_save_LIBS
 245   ])
 246 fi
 247
 248 if test "$HAVE_GETHOSTBYNAME" != "1"
 249 then
 250   dnl This is for winsock systems
 251   if test "$ac_cv_header_windows_h" = "yes"; then
 252     if test "$ac_cv_header_winsock_h" = "yes"; then
 253       case $host in
 254         *-*-mingw32ce*)
 255           winsock_LIB="-lwinsock"
 256           ;;
 257         *)
 258           winsock_LIB="-lwsock32"
 259           ;;
 260       esac
 261     fi
 262     if test "$ac_cv_header_winsock2_h" = "yes"; then
 263       winsock_LIB="-lws2_32"
 264     fi
 265     if test ! -z "$winsock_LIB"; then
 266       my_ac_save_LIBS=$LIBS
 267       LIBS="$winsock_LIB $LIBS"
 268       AC_MSG_CHECKING([for gethostbyname in $winsock_LIB])
 269       AC_LINK_IFELSE([
 270         AC_LANG_PROGRAM([[
 271 #ifdef HAVE_WINDOWS_H
 272 #ifndef WIN32_LEAN_AND_MEAN
 273 #define WIN32_LEAN_AND_MEAN
 274 #endif
 275 #include <windows.h>
 276 #ifdef HAVE_WINSOCK2_H
 277 #include <winsock2.h>
 278 #else
 279 #ifdef HAVE_WINSOCK_H
 280 #include <winsock.h>
 281 #endif
 282 #endif
 283 #endif
 284         ]],[[
 285           gethostbyname("www.dummysite.com");
 286         ]])
 287       ],[
 288         AC_MSG_RESULT([yes])
 289         HAVE_GETHOSTBYNAME="1"
 290       ],[
 291         AC_MSG_RESULT([no])
 292         winsock_LIB=""
 293         LIBS=$my_ac_save_LIBS
 294       ])
 295     fi
 296   fi
 297 fi
 298
 299 if test "$HAVE_GETHOSTBYNAME" != "1"
 300 then
 301   dnl This is for Minix 3.1
 302   AC_MSG_CHECKING([for gethostbyname for Minix 3])
 303   AC_LINK_IFELSE([
 304     AC_LANG_PROGRAM([[
 305 /* Older Minix versions may need <net/gen/netdb.h> here instead */
 306 #include <netdb.h>
 307     ]],[[
 308       gethostbyname("www.dummysite.com");
 309     ]])
 310   ],[
 311     AC_MSG_RESULT([yes])
 312     HAVE_GETHOSTBYNAME="1"
 313   ],[
 314     AC_MSG_RESULT([no])
 315   ])
 316 fi
 317
 318 if test "$HAVE_GETHOSTBYNAME" != "1"
 319 then
 320   dnl This is for eCos with a stubbed DNS implementation
 321   AC_MSG_CHECKING([for gethostbyname for eCos])
 322   AC_LINK_IFELSE([
 323     AC_LANG_PROGRAM([[
 324 #include <stdio.h>
 325 #include <netdb.h>
 326     ]],[[
 327       gethostbyname("www.dummysite.com");
 328     ]])
 329   ],[
 330     AC_MSG_RESULT([yes])
 331     HAVE_GETHOSTBYNAME="1"
 332   ],[
 333     AC_MSG_RESULT([no])
 334   ])
 335 fi
 336
 337 if test "$HAVE_GETHOSTBYNAME" != "1"
 338 then
 339   dnl gethostbyname in the net lib - for BeOS
 340   AC_CHECK_LIB(net, gethostbyname,
 341                [HAVE_GETHOSTBYNAME="1"
 342                LIBS="$LIBS -lnet"
 343                ])
 344 fi
 345
 346
 347 if test "$HAVE_GETHOSTBYNAME" != "1"; then
 348   AC_MSG_ERROR([couldn't find libraries for gethostbyname()])
 349 fi
 350
 351 dnl resolve lib?
 352 AC_CHECK_FUNC(strcasecmp, , [ AC_CHECK_LIB(resolve, strcasecmp) ])
 353
 354 if test "$ac_cv_lib_resolve_strcasecmp" = "$ac_cv_func_strcasecmp"; then
 355   AC_CHECK_LIB(resolve, strcasecmp,
 356               [LIBS="-lresolve $LIBS"],
 357                ,
 358                -lnsl)
 359 fi
 360 ac_cv_func_strcasecmp="no"
 361
 362 CARES_CHECK_LIBS_CONNECT
 363
 364 dnl **********************************************************************
 365 dnl In case that function clock_gettime with monotonic timer is available,
 366 dnl check for additional required libraries.
 367 dnl **********************************************************************
 368 CURL_CHECK_LIBS_CLOCK_GETTIME_MONOTONIC
 369
 370 AC_MSG_CHECKING([whether to use libgcc])
 371 AC_ARG_ENABLE(libgcc,
 372 AC_HELP_STRING([--enable-libgcc],[use libgcc when linking]),
 373 [ case "$enableval" in
 374   yes)
 375         LIBS="$LIBS -lgcc"
 376        AC_MSG_RESULT(yes)
 377        ;;
 378   *)   AC_MSG_RESULT(no)
 379        ;;
 380   esac ],
 381        AC_MSG_RESULT(no)
 382 )
 383
 384
 385 dnl Let's hope this split URL remains working:
 386 dnl http://publibn.boulder.ibm.com/doc_link/en_US/a_doc_lib/aixprggd/ \
 387 dnl genprogc/thread_quick_ref.htm
 388
 389
 390 dnl **********************************************************************
 391 dnl Back to "normal" configuring
 392 dnl **********************************************************************
 393
 394 dnl Checks for header files.
 395 AC_HEADER_STDC
 396
 397 CURL_CHECK_HEADER_MALLOC
 398 CURL_CHECK_HEADER_MEMORY
 399
 400 dnl check for a few basic system headers we need
 401 AC_CHECK_HEADERS(
 402        sys/types.h \
 403        sys/time.h \
 404        sys/select.h \
 405        sys/socket.h \
 406        sys/ioctl.h \
 407        sys/param.h \
 408        sys/uio.h \
 409        netdb.h \
 410        netinet/in.h \
 411        netinet/tcp.h \
 412        net/if.h \
 413        errno.h \
 414        socket.h \
 415        strings.h \
 416        stdbool.h \
 417        time.h \
 418        limits.h \
 419        arpa/nameser.h \
 420        arpa/nameser_compat.h \
 421        arpa/inet.h,
 422 dnl to do if not found
 423 [],
 424 dnl to do if found
 425 [],
 426 dnl default includes
 427 [
 428 #ifdef HAVE_SYS_TYPES_H
 429 #include <sys/types.h>
 430 #endif
 431 #ifdef HAVE_SYS_TIME_H
 432 #include <sys/time.h>
 433 #endif
 434 dnl We do this default-include simply to make sure that the nameser_compat.h
 435 dnl header *REALLY* can be include after the new nameser.h. It seems AIX 5.1
 436 dnl (and others?) is not designed to allow this.
 437 #ifdef HAVE_ARPA_NAMESER_H
 438 #include <arpa/nameser.h>
 439 #endif
 440
 441 dnl *Sigh* these are needed in order for net/if.h to get properly detected.
 442 #ifdef HAVE_SYS_SOCKET_H
 443 #include <sys/socket.h>
 444 #endif
 445 #ifdef HAVE_NETINET_IN_H
 446 #include <netinet/in.h>
 447 #endif
 448 ]
 449 )
 450
 451 dnl Checks for typedefs, structures, and compiler characteristics.
 452 AC_C_CONST
 453 AC_TYPE_SIZE_T
 454 AC_HEADER_TIME
 455 CURL_CHECK_STRUCT_TIMEVAL
 456
 457 AC_CHECK_SIZEOF(size_t)
 458 AC_CHECK_SIZEOF(int)
 459 AC_CHECK_SIZEOF(long)
 460 CARES_CONFIGURE_LONG
 461 AC_CHECK_SIZEOF(time_t)
 462
 463 AC_CHECK_TYPE(long long,
 464    [AC_DEFINE(HAVE_LONGLONG, 1,
 465      [Define to 1 if the compiler supports the 'long long' data type.])]
 466    longlong="yes"
 467 )
 468
 469 if test "xyes" = "x$longlong"; then
 470   AC_MSG_CHECKING([if numberLL works])
 471   AC_COMPILE_IFELSE([long long val = 1000LL;],
 472    [AC_DEFINE(HAVE_LL, 1, [if your compiler supports LL])]
 473    AC_MSG_RESULT(yes),
 474    AC_MSG_RESULT(no)
 475   )
 476 fi
 477
 478
 479 # check for ssize_t
 480 AC_CHECK_TYPE(ssize_t, ,
 481    AC_DEFINE(ssize_t, int, [the signed version of size_t]))
 482
 483 # check for bool type
 484 AC_CHECK_TYPE([bool],[
 485   AC_DEFINE(HAVE_BOOL_T, 1,
 486     [Define to 1 if bool is an available type.])
 487 ], ,[
 488 #ifdef HAVE_SYS_TYPES_H
 489 #include <sys/types.h>
 490 #endif
 491 #ifdef HAVE_STDBOOL_H
 492 #include <stdbool.h>
 493 #endif
 494 ])
 495
 496 CARES_CONFIGURE_ARES_SOCKLEN_T
 497
 498 TYPE_IN_ADDR_T
 499
 500 TYPE_SOCKADDR_STORAGE
 501
 502 TYPE_SIG_ATOMIC_T
 503
 504 AC_TYPE_SIGNAL
 505
 506 CURL_CHECK_FUNC_RECV
 507 CURL_CHECK_FUNC_RECVFROM
 508 CURL_CHECK_FUNC_SEND
 509 CURL_CHECK_MSG_NOSIGNAL
 510
 511 CARES_CHECK_FUNC_CLOSESOCKET
 512 CARES_CHECK_FUNC_CLOSESOCKET_CAMEL
 513 CARES_CHECK_FUNC_CONNECT
 514 CARES_CHECK_FUNC_FCNTL
 515 CARES_CHECK_FUNC_FREEADDRINFO
 516 CARES_CHECK_FUNC_GETADDRINFO
 517 CARES_CHECK_FUNC_GETHOSTBYADDR
 518 CARES_CHECK_FUNC_GETHOSTBYNAME
 519 CARES_CHECK_FUNC_GETHOSTNAME
 520 CARES_CHECK_FUNC_GETSERVBYPORT_R
 521 CARES_CHECK_FUNC_INET_NTOP
 522 CARES_CHECK_FUNC_INET_PTON
 523 CARES_CHECK_FUNC_IOCTL
 524 CARES_CHECK_FUNC_IOCTLSOCKET
 525 CARES_CHECK_FUNC_IOCTLSOCKET_CAMEL
 526 CARES_CHECK_FUNC_SETSOCKOPT
 527 CARES_CHECK_FUNC_SOCKET
 528 CARES_CHECK_FUNC_STRCASECMP
 529 CARES_CHECK_FUNC_STRCMPI
 530 CARES_CHECK_FUNC_STRDUP
 531 CARES_CHECK_FUNC_STRICMP
 532 CARES_CHECK_FUNC_STRNCASECMP
 533 CARES_CHECK_FUNC_STRNCMPI
 534 CARES_CHECK_FUNC_STRNICMP
 535 CARES_CHECK_FUNC_WRITEV
 536
 537
 538 dnl check for AF_INET6
 539 CARES_CHECK_CONSTANT(
 540   [
 541 #undef inline
 542 #ifdef HAVE_WINDOWS_H
 543 #ifndef WIN32_LEAN_AND_MEAN
 544 #define WIN32_LEAN_AND_MEAN
 545 #endif
 546 #include <windows.h>
 547 #ifdef HAVE_WINSOCK2_H
 548 #include <winsock2.h>
 549 #endif
 550 #else
 551 #ifdef HAVE_SYS_TYPES_H
 552 #include <sys/types.h>
 553 #endif
 554 #ifdef HAVE_SYS_SOCKET_H
 555 #include <sys/socket.h>
 556 #endif
 557 #endif
 558   ], [PF_INET6],
 559      AC_DEFINE_UNQUOTED(HAVE_PF_INET6,1,[Define to 1 if you have PF_INET6.])
 560 )
 561
 562 dnl check for PF_INET6
 563 CARES_CHECK_CONSTANT(
 564   [
 565 #undef inline
 566 #ifdef HAVE_WINDOWS_H
 567 #ifndef WIN32_LEAN_AND_MEAN
 568 #define WIN32_LEAN_AND_MEAN
 569 #endif
 570 #include <windows.h>
 571 #ifdef HAVE_WINSOCK2_H
 572 #include <winsock2.h>
 573 #endif
 574 #else
 575 #ifdef HAVE_SYS_TYPES_H
 576 #include <sys/types.h>
 577 #endif
 578 #ifdef HAVE_SYS_SOCKET_H
 579 #include <sys/socket.h>
 580 #endif
 581 #endif
 582   ], [AF_INET6],
 583      AC_DEFINE_UNQUOTED(HAVE_AF_INET6,1,[Define to 1 if you have AF_INET6.])
 584 )
 585
 586
 587 dnl check for the in6_addr structure
 588 CARES_CHECK_STRUCT(
 589   [
 590 #undef inline
 591 #ifdef HAVE_WINDOWS_H
 592 #ifndef WIN32_LEAN_AND_MEAN
 593 #define WIN32_LEAN_AND_MEAN
 594 #endif
 595 #include <windows.h>
 596 #ifdef HAVE_WINSOCK2_H
 597 #include <winsock2.h>
 598 #ifdef HAVE_WS2TCPIP_H
 599 #include <ws2tcpip.h>
 600 #endif
 601 #endif
 602 #else
 603 #ifdef HAVE_SYS_TYPES_H
 604 #include <sys/types.h>
 605 #endif
 606 #ifdef HAVE_NETINET_IN_H
 607 #include <netinet/in.h>
 608 #endif
 609 #endif
 610   ], [in6_addr],
 611      AC_DEFINE_UNQUOTED(HAVE_STRUCT_IN6_ADDR,1,[Define to 1 if you have struct in6_addr.])
 612 )
 613
 614 dnl check for the sockaddr_in6 structure
 615 CARES_CHECK_STRUCT(
 616   [
 617 #undef inline
 618 #ifdef HAVE_WINDOWS_H
 619 #ifndef WIN32_LEAN_AND_MEAN
 620 #define WIN32_LEAN_AND_MEAN
 621 #endif
 622 #include <windows.h>
 623 #ifdef HAVE_WINSOCK2_H
 624 #include <winsock2.h>
 625 #ifdef HAVE_WS2TCPIP_H
 626 #include <ws2tcpip.h>
 627 #endif
 628 #endif
 629 #else
 630 #ifdef HAVE_SYS_TYPES_H
 631 #include <sys/types.h>
 632 #endif
 633 #ifdef HAVE_NETINET_IN_H
 634 #include <netinet/in.h>
 635 #endif
 636 #endif
 637   ], [sockaddr_in6],
 638      AC_DEFINE_UNQUOTED(HAVE_STRUCT_SOCKADDR_IN6,1,
 639        [Define to 1 if you have struct sockaddr_in6.]) ac_have_sockaddr_in6=yes
 640 )
 641
 642 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_scope_id,
 643     AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_IN6_SIN6_SCOPE_ID,1,
 644       [Define to 1 if your struct sockaddr_in6 has sin6_scope_id.])
 645    , ,
 646   [
 647 #undef inline
 648 #ifdef HAVE_WINDOWS_H
 649 #ifndef WIN32_LEAN_AND_MEAN
 650 #define WIN32_LEAN_AND_MEAN
 651 #endif
 652 #include <windows.h>
 653 #ifdef HAVE_WINSOCK2_H
 654 #include <winsock2.h>
 655 #ifdef HAVE_WS2TCPIP_H
 656 #include <ws2tcpip.h>
 657 #endif
 658 #endif
 659 #else
 660 #ifdef HAVE_SYS_TYPES_H
 661 #include <sys/types.h>
 662 #endif
 663 #ifdef HAVE_NETINET_IN_H
 664 #include <netinet/in.h>
 665 #endif
 666 #endif
 667   ])
 668
 669 dnl check for the addrinfo structure
 670 AC_CHECK_MEMBER(struct addrinfo.ai_flags,
 671      AC_DEFINE_UNQUOTED(HAVE_STRUCT_ADDRINFO,1,
 672        [Define to 1 if you have struct addrinfo.]),,
 673   [
 674 #undef inline
 675 #ifdef HAVE_WINDOWS_H
 676 #ifndef WIN32_LEAN_AND_MEAN
 677 #define WIN32_LEAN_AND_MEAN
 678 #endif
 679 #include <windows.h>
 680 #ifdef HAVE_WINSOCK2_H
 681 #include <winsock2.h>
 682 #ifdef HAVE_WS2TCPIP_H
 683 #include <ws2tcpip.h>
 684 #endif
 685 #endif
 686 #else
 687 #ifdef HAVE_SYS_TYPES_H
 688 #include <sys/types.h>
 689 #endif
 690 #ifdef HAVE_NETINET_IN_H
 691 #include <netinet/in.h>
 692 #endif
 693 #ifdef HAVE_SYS_SOCKET_H
 694 #include <sys/socket.h>
 695 #endif
 696 #ifdef HAVE_NETDB_H
 697 #include <netdb.h>
 698 #endif
 699 #endif
 700   ]
 701 )
 702
 703
 704 AC_CHECK_FUNCS([bitncmp \
 705   gettimeofday \
 706   if_indextoname
 707 ],[
 708 ],[
 709   func="$ac_func"
 710   AC_MSG_CHECKING([deeper for $func])
 711   AC_LINK_IFELSE([
 712     AC_LANG_PROGRAM([[
 713     ]],[[
 714       $func ();
 715     ]])
 716   ],[
 717     AC_MSG_RESULT([yes])
 718     eval "ac_cv_func_$func=yes"
 719     AC_DEFINE_UNQUOTED(AS_TR_CPP([HAVE_$func]), [1],
 720       [Define to 1 if you have the $func function.])
 721   ],[
 722     AC_MSG_RESULT([but still no])
 723   ])
 724 ])
 725
 726
 727 dnl Check for inet_net_pton
 728 AC_CHECK_FUNCS(inet_net_pton)
 729 dnl Again, some systems have it, but not IPv6
 730 if test "$ac_cv_func_inet_net_pton" = "yes" ; then
 731 AC_MSG_CHECKING(if inet_net_pton supports IPv6)
 732 AC_TRY_RUN(
 733   [
 734 #ifdef HAVE_SYS_TYPES_H
 735 #include <sys/types.h>
 736 #endif
 737 #ifdef HAVE_SYS_SOCKET_H
 738 #include <sys/socket.h>
 739 #endif
 740 #ifdef HAVE_NETINET_IN_H
 741 #include <netinet/in.h>
 742 #endif
 743 int main()
 744   {
 745     struct in6_addr addr6;
 746     if (inet_net_pton(AF_INET6, "::1", &addr6, sizeof(addr6)) < 1)
 747       exit(1);
 748     else
 749       exit(0);
 750   }
 751   ], [
 752        AC_MSG_RESULT(yes)
 753        AC_DEFINE_UNQUOTED(HAVE_INET_NET_PTON_IPV6,1,[Define to 1 if inet_net_pton supports IPv6.])
 754      ], AC_MSG_RESULT(no),AC_MSG_RESULT(no))
 755 fi
 756
 757
 758 AC_CHECK_SIZEOF(struct in6_addr, ,
 759 [
 760 #undef inline
 761 #ifdef HAVE_WINDOWS_H
 762 #ifndef WIN32_LEAN_AND_MEAN
 763 #define WIN32_LEAN_AND_MEAN
 764 #endif
 765 #include <windows.h>
 766 #ifdef HAVE_WINSOCK2_H
 767 #include <winsock2.h>
 768 #ifdef HAVE_WS2TCPIP_H
 769 #include <ws2tcpip.h>
 770 #endif
 771 #endif
 772 #else
 773 #ifdef HAVE_SYS_TYPES_H
 774 #include <sys/types.h>
 775 #endif
 776 #ifdef HAVE_SYS_SOCKET_H
 777 #include <sys/socket.h>
 778 #endif
 779 #ifdef HAVE_NETINET_IN_H
 780 #include <netinet/in.h>
 781 #endif
 782 #endif
 783 ]
 784 )
 785
 786 AC_CHECK_SIZEOF(struct in_addr, ,
 787 [
 788 #undef inline
 789 #ifdef HAVE_WINDOWS_H
 790 #ifndef WIN32_LEAN_AND_MEAN
 791 #define WIN32_LEAN_AND_MEAN
 792 #endif
 793 #include <windows.h>
 794 #ifdef HAVE_WINSOCK2_H
 795 #include <winsock2.h>
 796 #ifdef HAVE_WS2TCPIP_H
 797 #include <ws2tcpip.h>
 798 #endif
 799 #endif
 800 #else
 801 #ifdef HAVE_SYS_TYPES_H
 802 #include <sys/types.h>
 803 #endif
 804 #ifdef HAVE_SYS_SOCKET_H
 805 #include <sys/socket.h>
 806 #endif
 807 #ifdef HAVE_NETINET_IN_H
 808 #include <netinet/in.h>
 809 #endif
 810 #endif
 811 ]
 812 )
 813
 814
 815 dnl Check if the getnameinfo function is available
 816 dnl and get the types of five of its arguments.
 817 CURL_CHECK_FUNC_GETNAMEINFO
 818
 819
 820 AC_C_BIGENDIAN(
 821     [AC_DEFINE(ARES_BIG_ENDIAN, 1,
 822       [define this if ares is built for a big endian system])],
 823     ,
 824     [AC_MSG_WARN([couldn't figure out endianess, assuming little endian!])]
 825 )
 826
 827 dnl Check for user-specified random device
 828 AC_ARG_WITH(random,
 829 AC_HELP_STRING([--with-random=FILE],
 830                [read randomness from FILE (default=/dev/urandom)]),
 831     [ RANDOM_FILE="$withval" ],
 832     [
 833         dnl Check for random device.  If we're cross compiling, we can't
 834         dnl check, and it's better to assume it doesn't exist than it is
 835         dnl to fail on AC_CHECK_FILE or later.
 836         if test "$cross_compiling" = "no"; then
 837           AC_CHECK_FILE("/dev/urandom", [ RANDOM_FILE="/dev/urandom"] )
 838         else
 839           AC_MSG_WARN([cannot check for /dev/urandom while cross compiling; assuming none])
 840         fi
 841
 842     ]
 843 )
 844 if test -n "$RANDOM_FILE" && test X"$RANDOM_FILE" != Xno ; then
 845         AC_SUBST(RANDOM_FILE)
 846         AC_DEFINE_UNQUOTED(RANDOM_FILE, "$RANDOM_FILE",
 847         [a suitable file/device to read random data from])
 848 fi
 849
 850 CARES_CHECK_OPTION_NONBLOCKING
 851 CARES_CHECK_NONBLOCKING_SOCKET
 852
 853 CARES_CONFIGURE_SYMBOL_HIDING
 854
 855 CARES_PRIVATE_LIBS="$LIBS"
 856 AC_SUBST(CARES_PRIVATE_LIBS)
 857
 858 dnl squeeze whitespace out of some variables
 859
 860 squeeze CFLAGS
 861 squeeze CPPFLAGS
 862 squeeze DEFS
 863 squeeze LDFLAGS
 864 squeeze LIBS
 865
 866 squeeze CARES_PRIVATE_LIBS
 867
 868 AC_CONFIG_FILES([Makefile libcares.pc])
 869 AC_OUTPUT