configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([weston],
   3         [0.89],
   4         [https://bugs.freedesktop.org/enter_bug.cgi?product=weston],
   5         [weston],
   6         [http://wayland.freedesktop.org/])
   7
   8 AC_CONFIG_HEADERS([config.h])
   9
  10 AM_INIT_AUTOMAKE([1.11 foreign no-dist-gzip dist-xz])
  11
  12 AM_SILENT_RULES([yes])
  13
  14 # Check for programs
  15 AC_PROG_CC
  16
  17 # Initialize libtool
  18 LT_PREREQ([2.2])
  19 LT_INIT([disable-static])
  20
  21 PKG_PROG_PKG_CONFIG()
  22
  23 AC_CHECK_FUNC([dlopen], [],
  24               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  25 AC_SUBST(DLOPEN_LIBS)
  26
  27 PKG_CHECK_MODULES(COMPOSITOR,
  28                   [wayland-server egl >= 7.10 glesv2 pixman-1 libpng])
  29
  30 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
  31 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
  32
  33
  34 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  35               enable_setuid_install=yes)
  36 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install == xyes)
  37
  38
  39 AC_ARG_ENABLE(xserver-launcher, [  --enable-xserver-launcher],,
  40               enable_xserver_launcher=yes)
  41 AM_CONDITIONAL(ENABLE_XSERVER_LAUNCHER, test x$enable_xserver_launcher == xyes)
  42 if test x$enable_xserver_launcher == xyes; then
  43   PKG_CHECK_MODULES([XSERVER_LAUNCHER], xcb xcb-xfixes)
  44   AC_DEFINE([BUILD_XSERVER_LAUNCHER], [1], [Build the X server launcher])
  45
  46   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
  47               [Path to X server]), [XSERVER_PATH="$withval"],
  48               [XSERVER_PATH="$bindir/Xorg"])
  49   AC_SUBST([XSERVER_PATH])
  50 fi
  51
  52
  53 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
  54               enable_x11_compositor=yes)
  55 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor == xyes)
  56 if test x$enable_x11_compositor == xyes; then
  57   PKG_CHECK_MODULES([XCB], xcb)
  58   xcb_save_LIBS=$LIBS
  59   xcb_save_CFLAGS=$CFLAGS
  60   CFLAGS=$XCB_CFLAGS
  61   LIBS=$XCB_LIBS
  62   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
  63   LIBS=$xcb_save_LIBS
  64   CFLAGS=$xcb_save_CFLAGS
  65
  66   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
  67   PKG_CHECK_MODULES(X11_COMPOSITOR, [x11 x11-xcb])
  68 fi
  69
  70
  71 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
  72               enable_drm_compositor=yes)
  73 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor == xyes)
  74 if test x$enable_drm_compositor == xyes; then
  75   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
  76   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.23 gbm])
  77 fi
  78
  79
  80 AC_ARG_ENABLE(openwfd-compositor, [  --enable-openwfd-compositor],,
  81               enable_openwfd_compositor=no)
  82 AM_CONDITIONAL(ENABLE_OPENWFD_COMPOSITOR, test x$enable_openwfd_compositor == xyes)
  83 if test x$enable_openwfd_compositor == xyes; then
  84   AC_DEFINE([BUILD_OPENWFD_COMPOSITOR], [1], [Build the OpenWF compositor])
  85   PKG_CHECK_MODULES(OPENWFD_COMPOSITOR, [openwfd gbm])
  86 fi
  87
  88
  89 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
  90               enable_wayland_compositor=yes)
  91 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
  92                test x$enable_wayland_compositor == xyes)
  93 if test x$enable_wayland_compositor == xyes; then
  94   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
  95             [Build the Wayland (nested) compositor])
  96   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
  97 fi
  98
  99 AC_ARG_WITH(cairo-glesv2, AS_HELP_STRING([--with-cairo-glesv2],
 100               [Use GLESv2 cairo instead of full GL]),
 101               [cairo_modules="cairo-glesv2"],
 102               [cairo_modules="cairo-gl"])
 103 if test x$cairo_modules == xcairo-glesv2; then
 104   AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 105 fi
 106
 107 AC_ARG_ENABLE(simple-clients, [  --enable-simple-clients],, enable_simple_clients=yes)
 108 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test x$enable_simple_clients == xyes)
 109 if test x$enable_simple_clients == xyes; then
 110   AC_DEFINE([BUILD_SIMPLE_CLIENTS], [1], [Build the Wayland simple clients])
 111   PKG_CHECK_MODULES(SIMPLE_CLIENT,
 112                     [egl >= 7.10 glesv2 wayland-client wayland-egl])
 113 fi
 114
 115 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 116 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients == xyes)
 117 if test x$enable_clients == xyes; then
 118   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 119
 120   PKG_CHECK_MODULES(CLIENT, [wayland-client wayland-egl egl >= 7.10 cairo >= 1.10.0 gdk-pixbuf-2.0 glib-2.0 gobject-2.0 gio-2.0 xkbcommon libpng])
 121
 122   PKG_CHECK_MODULES(POPPLER, [poppler-glib],
 123                              [have_poppler=yes], [have_poppler=no])
 124   PKG_CHECK_MODULES(CAIRO_EGL, [cairo-egl >= 1.11.3 $cairo_modules],
 125                     [have_cairo_egl=yes], [have_cairo_egl=no])
 126   AS_IF([test "x$have_cairo_egl" = "xyes"],
 127         [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 128         [AC_MSG_WARN([Cairo-EGL not found - clients will use cairo image])])
 129
 130   PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 131   AS_IF([test "x$have_webp" = "xyes"],
 132         [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 133   CLIENT_LIBS="$CLIENT_LIBS $WEBP_LIBS"
 134   CLIENT_CFLAGS="$CLIENT_CFLAGS $WEBP_CFLAGS"
 135
 136   AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 137   if test x$have_jpeglib == xyes; then
 138     CLIENT_LIBS="$CLIENT_LIBS -ljpeg"
 139   else
 140     AC_ERROR([libjpeg not found])
 141   fi
 142
 143 fi
 144
 145 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
 146
 147 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 148                test x$cairo_modules == "xcairo-gl" -a "x$have_cairo_egl" = "xyes")
 149
 150 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 151
 152 AC_ARG_ENABLE(tablet-shell, [  --enable-tablet-shell],,
 153               enable_tablet_shell=yes)
 154 AM_CONDITIONAL(ENABLE_TABLET_SHELL,
 155                test x$enable_tablet_shell == xyes)
 156
 157 AC_ARG_ENABLE(tests,
 158               AS_HELP_STRING([--disable-tests],
 159                              [do not build unit tests [default=enabled]]),,
 160               enable_tests=yes)
 161 AM_CONDITIONAL(BUILD_TESTS, test x$enable_tests == xyes)
 162
 163 if test "x$GCC" = "xyes"; then
 164         GCC_CFLAGS="-Wall -g -Wstrict-prototypes -Wmissing-prototypes -fvisibility=hidden"
 165 fi
 166 AC_SUBST(GCC_CFLAGS)
 167
 168 WAYLAND_SCANNER_RULES(['$(top_srcdir)/protocol'])
 169
 170 AC_CONFIG_FILES([Makefile
 171                  shared/Makefile
 172                  src/Makefile
 173                  clients/Makefile
 174                  data/Makefile
 175                  protocol/Makefile
 176                  tests/Makefile])
 177 AC_OUTPUT
 178
 179 if test "x$enable_setuid_install" == xyes; then
 180 AC_MSG_WARN([
 181
 182  *** You've enabled the setuid install hook.  Weston is still a
 183  *** pre-alpha project and may have bugs and issues that make a
 184  *** setuid install unsafe. Proceed at your own risk.
 185 ])
 186 fi
 187