configure.ac

   1 AC_PREREQ(2.53)
   2 AC_INIT([rygel],
   3         m4_esyscmd([GNOME_TAG_PATTERN=RYGEL build-aux/git-version-gen .tarball-version]),
   4         [http://live.gnome.org/Rygel])
   5 AC_CONFIG_AUX_DIR([build-aux])
   6 AM_INIT_AUTOMAKE
   7 AC_CONFIG_SRCDIR([src/rygel/rygel-media-server.vala])
   8 AM_CONFIG_HEADER([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AM_MAINTAINER_MODE
  11
  12 # Disable generation of static libraries
  13 AC_DISABLE_STATIC
  14
  15 AC_ISC_POSIX
  16 AC_PROG_CC
  17 AC_STDC_HEADERS
  18 AC_PROG_LIBTOOL
  19 AC_FUNC_MMAP
  20
  21 VALA_REQUIRED=0.7.3
  22 GUPNP_REQUIRED=0.12.5
  23 GUPNP_AV_REQUIRED=0.3.2
  24 GUPNP_VALA_REQUIRED=0.5.3
  25 GCONF_REQUIRED=2.16
  26 DBUS_GLIB_REQUIRED=0.74
  27 GSTREAMER_REQUIRED=0.10.22
  28 GIO_REQUIRED=2.16
  29 GEE_REQUIRED=0.1.5
  30 UUID_REQUIRED=1.41.3
  31 LIBSOUP_REQUIRED=2.26.0
  32 GTK_REQUIRED=2.16
  33
  34 PKG_CHECK_MODULES(LIBGUPNP, gupnp-1.0 >= $GUPNP_REQUIRED)
  35 PKG_CHECK_MODULES(LIBGUPNP_AV, gupnp-av-1.0 >= $GUPNP_AV_REQUIRED)
  36 PKG_CHECK_MODULES(LIBGCONF, gconf-2.0 >= $GCONF_REQUIRED)
  37 PKG_CHECK_MODULES(LIBDBUS_GLIB, dbus-glib-1 >= $DBUS_GLIB_REQUIRED)
  38 PKG_CHECK_MODULES(LIBGSTREAMER, gstreamer-0.10 >= $GSTREAMER_REQUIRED)
  39 PKG_CHECK_MODULES(LIBGIO, gio-2.0 >= $GIO_REQUIRED)
  40 PKG_CHECK_MODULES(GEE, gee-1.0 >= $GEE_REQUIRED)
  41 PKG_CHECK_MODULES(UUID, uuid >= $UUID_REQUIRED)
  42 PKG_CHECK_MODULES(LIBSOUP, libsoup-2.4 >= $LIBSOUP_REQUIRED)
  43
  44 AC_PATH_PROG(GCONFTOOL, gconftool-2)
  45 AM_GCONF_SOURCE_2
  46
  47 # glib-genmarshal
  48 GLIB_GENMARSHAL=`pkg-config --variable=glib_genmarshal glib-2.0`
  49 AC_SUBST(GLIB_GENMARSHAL)
  50
  51 AC_ARG_ENABLE(vala,
  52         [  --enable-vala          enable checks for vala],,
  53         enable_vala=no)
  54
  55 # Vala
  56 if test x$enable_vala = xyes ; then
  57     # check for vala
  58     PKG_CHECK_MODULES(VALA, [vala-1.0 >= $VALA_REQUIRED])
  59     PKG_CHECK_MODULES(GUPNP_VALA, gupnp-vala-1.0 >= $GUPNP_VALA_REQUIRED)
  60
  61     # Vala compiler
  62     # This is more to get the path of the compiler since the pkg-config check
  63     # should covers check for compiler as well.
  64
  65     AC_PATH_PROG(VALAC, valac, no)
  66
  67     if test "x$VALAC" = "xno"; then
  68         AC_MSG_ERROR([Cannot find the "valac" compiler in your PATH])
  69     fi
  70
  71     VAPIDIR=`pkg-config --variable=vapidir vala-1.0`
  72     AC_SUBST(VAPIDIR)
  73
  74     # FIXME: Whats the proper way for checking for particular Vala bindings
  75     AC_CHECK_FILE("${VAPIDIR}/gupnp-1.0.vapi",
  76                   true,
  77                   [AC_MSG_ERROR("Unable to find Vala bindings for gupnp-1.0")])
  78
  79     AC_CHECK_FILE("${VAPIDIR}/gupnp-av-1.0.vapi",
  80                   true,
  81                   [AC_MSG_ERROR("Unable to find Vala bindings for gupnp-av-1.0")])
  82
  83     AC_CHECK_FILE("${VAPIDIR}/dbus-glib-1.vapi",
  84                   true,
  85                   [AC_MSG_ERROR("Unable to find Vala bindings for dbus-glib-1")])
  86
  87     AC_CHECK_FILE("${VAPIDIR}/gconf-2.0.vapi",
  88                   true,
  89                   [AC_MSG_ERROR("Unable to find Vala bindings for gconf-2.0")])
  90
  91     AC_CHECK_FILE("${VAPIDIR}/gstreamer-0.10.vapi",
  92                   true,
  93                   [AC_MSG_ERROR("Unable to find Vala bindings for gstreamer-0.10")])
  94
  95     AC_CHECK_FILE("${VAPIDIR}/gio-2.0.vapi",
  96                   true,
  97                   [AC_MSG_ERROR("Unable to find Vala bindings for gio-2.0")])
  98
  99     AC_CHECK_FILE("${VAPIDIR}/gee-1.0.vapi",
 100                   true,
 101                   [AC_MSG_ERROR("Unable to find Vala bindings for gee-1.0")])
 102 fi
 103
 104 # Debugging
 105 AC_ARG_ENABLE(debug,
 106         [  --enable-debug          enable debugging],,
 107         enable_debug=no)
 108 if test "x$enable_debug" = "xyes"; then
 109         CFLAGS="$CFLAGS -g"
 110 fi
 111
 112 # Strict compiler
 113 AC_ARG_ENABLE(strict-cc,
 114         [  --enable-strict-cc          enable strict C compiler],,
 115         enable_strict_cc=no)
 116 if test "x$enable_strict_cc" = "xyes"; then
 117         CFLAGS="$CFLAGS -Wall -Werror"
 118 fi
 119
 120 # Run uninstalled
 121 AC_ARG_ENABLE(uninstalled,
 122         [  --enable-uninstalled          run uninstalled],,
 123         enable_uninstalled=no)
 124 if test "x$enable_uninstalled" = "xyes"; then
 125         AC_MSG_WARN("You want to run the tools uninstalled only? Fine!")
 126 fi
 127
 128 # Check wether user wants to build UIs
 129 AC_ARG_WITH( ui,
 130   AC_HELP_STRING([--disable-ui],[Don't build UI applications]),
 131   try_ui=$withval, try_ui=yes )
 132
 133 HAVE_GTK=no
 134 if test x$try_ui = xyes ; then
 135     dnl check for gtk
 136     PKG_CHECK_MODULES(GTK, gtk+-2.0 >= $GTK_REQUIRED ,
 137       [
 138         AC_SUBST(GTK_CFLAGS)
 139         AC_SUBST(GTK_LIBS)
 140         if test x$enable_vala = xyes ; then
 141                 AC_CHECK_FILE("${VAPIDIR}/gtk+-2.0.vapi",
 142                   [
 143                         HAVE_GTK=yes
 144                   ],
 145                   [
 146                         HAVE_GTK=no
 147                         AC_MSG_ERROR("Unable to find Vala bindings for gtk+-2.0")
 148                   ])
 149         fi
 150       ],
 151       [
 152         HAVE_GTK=no
 153         AC_MSG_WARN([gtk $GTK_REQUIRED or greater not found.])
 154         AC_MSG_WARN([UI applications will not be built.])
 155       ])
 156 else
 157     AC_MSG_NOTICE([UI applications disabled.])
 158 fi
 159
 160 if test x$HAVE_GTK = xno; then
 161   BUILD_UI=no
 162 else
 163   BUILD_UI=yes
 164   AC_DEFINE(HAVE_GTK, , [Build UI applications])
 165 fi
 166
 167 AC_SUBST(HAVE_GTK)
 168 AM_CONDITIONAL(BUILD_UI, test x$BUILD_UI = xyes)
 169
 170 # Build test plugin
 171 AC_ARG_ENABLE(test-plugin,
 172         [  --enable-test-plugin          build test plugin],,
 173         enable_test_plugin=no)
 174
 175 # Build Tracker plugin
 176 AC_ARG_ENABLE(tracker-plugin,
 177         [  --enable-tracker-plugin      build tracker plugin],,
 178         enable_tracker_plugin=yes)
 179
 180 # Build DVB plugin
 181 AC_ARG_ENABLE(dvb-plugin,
 182         [  --enable-dvb-plugin          build DVB plugin],,
 183         enable_dvb_plugin=yes)
 184
 185 # Build Folder plugin
 186 AC_ARG_ENABLE(folder-plugin,
 187         [  --enable-folder-plugin          build Folder plugin],,
 188         enable_folder_plugin=yes)
 189
 190 # Build External plugin
 191 AC_ARG_ENABLE(external-plugin,
 192         [  --enable-external-plugin          build External plugin],,
 193         enable_external_plugin=yes)
 194
 195 # Build Mediathek plugin
 196 AC_ARG_ENABLE(mediathek-plugin,
 197         [  --enable-mediathek-plugin          build Mediathek plugin],,
 198         enable_mediathek_plugin=no)
 199
 200
 201 AC_SUBST(abs_top_builddir)
 202
 203 AM_CONDITIONAL([UNINSTALLED], [test "x$enable_uninstalled" = "xyes"])
 204 AM_CONDITIONAL([BUILD_TEST_PLUGIN], [test "x$enable_test_plugin" = "xyes"])
 205 AM_CONDITIONAL([BUILD_TRACKER_PLUGIN],
 206                [test "x$enable_tracker_plugin" = "xyes"])
 207 AM_CONDITIONAL([BUILD_DVB_PLUGIN], [test "x$enable_dvb_plugin" = "xyes"])
 208 AM_CONDITIONAL([BUILD_MEDIATHEK_PLUGIN], [test "x$enable_mediathek_plugin" = "xyes"])
 209 AM_CONDITIONAL([BUILD_FOLDER_PLUGIN], [test "x$enable_folder_plugin" = "xyes"])
 210 AM_CONDITIONAL([BUILD_EXTERNAL_PLUGIN], [test "x$enable_external_plugin" = "xyes"])
 211
 212 # Gettext
 213 GETTEXT_PACKAGE=rygel
 214 AC_SUBST(GETTEXT_PACKAGE)
 215 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 216   [Define the gettext package to be used])
 217
 218 ALL_LINGUAS=""
 219 AM_GLIB_GNU_GETTEXT
 220 AM_GLIB_DEFINE_LOCALEDIR([LOCALEDIR])
 221
 222 AC_OUTPUT([
 223 Makefile
 224 src/Makefile
 225 src/rygel/Makefile
 226 src/ui/Makefile
 227 src/plugins/Makefile
 228 src/plugins/dvb/Makefile
 229 src/plugins/folder/Makefile
 230 src/plugins/external/Makefile
 231 src/plugins/mediathek/Makefile
 232 src/plugins/tracker/Makefile
 233 src/plugins/test/Makefile
 234 data/Makefile
 235 data/xml/Makefile
 236 rygel-1.0.pc
 237 ])
 238
 239 echo "
 240
 241                     ${PACKAGE} ${VERSION}
 242                     ============
 243
 244
 245         Prefix:                 ${prefix}
 246         Source code location:   ${srcdir}
 247         Compiler:               ${CC}
 248         CFLAGS:                 ${CFLAGS}
 249 "