configure.ac

   1 m4_define([weston_major_version], [1])
   2 m4_define([weston_minor_version], [1])
   3 m4_define([weston_micro_version], [90])
   4 m4_define([weston_version],
   5           [weston_major_version.weston_minor_version.weston_micro_version])
   6
   7 AC_PREREQ([2.64])
   8 AC_INIT([weston],
   9         [weston_version],
  10         [https://bugs.freedesktop.org/enter_bug.cgi?product=Wayland&component=weston&version=weston_version],
  11         [weston],
  12         [http://wayland.freedesktop.org/])
  13
  14 AC_SUBST([WESTON_VERSION_MAJOR], [weston_major_version])
  15 AC_SUBST([WESTON_VERSION_MINOR], [weston_minor_version])
  16 AC_SUBST([WESTON_VERSION_MICRO], [weston_micro_version])
  17 AC_SUBST([WESTON_VERSION], [weston_version])
  18
  19 AC_CONFIG_HEADERS([config.h])
  20
  21 AC_USE_SYSTEM_EXTENSIONS
  22
  23 AM_INIT_AUTOMAKE([1.11 parallel-tests foreign no-dist-gzip dist-xz color-tests])
  24
  25 AM_SILENT_RULES([yes])
  26
  27 # Check for programs
  28 AC_PROG_CC
  29 AC_PROG_SED
  30
  31 # Initialize libtool
  32 LT_PREREQ([2.2])
  33 LT_INIT([disable-static])
  34
  35 AC_ARG_VAR([WESTON_NATIVE_BACKEND],
  36            [Set the native backend to use, if Weston is not running under Wayland nor X11. @<:@default=drm-backend.so@:>@])
  37
  38 PKG_PROG_PKG_CONFIG()
  39
  40 AC_CHECK_FUNC([dlopen], [],
  41               AC_CHECK_LIB([dl], [dlopen], DLOPEN_LIBS="-ldl"))
  42 AC_SUBST(DLOPEN_LIBS)
  43
  44 AC_CHECK_DECL(SFD_CLOEXEC,[],
  45               [AC_MSG_ERROR("SFD_CLOEXEC is needed to compile weston")],
  46               [[#include <sys/signalfd.h>]])
  47 AC_CHECK_DECL(TFD_CLOEXEC,[],
  48               [AC_MSG_ERROR("TFD_CLOEXEC is needed to compile weston")],
  49               [[#include <sys/timerfd.h>]])
  50 AC_CHECK_DECL(CLOCK_MONOTONIC,[],
  51               [AC_MSG_ERROR("CLOCK_MONOTONIC is needed to compile weston")],
  52               [[#include <time.h>]])
  53 AC_CHECK_HEADERS([execinfo.h])
  54
  55 AC_CHECK_FUNCS([mkostemp strchrnul])
  56
  57 COMPOSITOR_MODULES="wayland-server >= 1.1.90 pixman-1"
  58
  59 AC_ARG_ENABLE(egl, [  --disable-egl],,
  60               enable_egl=yes)
  61 AM_CONDITIONAL(ENABLE_EGL, test x$enable_egl = xyes)
  62 if test x$enable_egl = xyes; then
  63         AC_DEFINE([ENABLE_EGL], [1], [Build Weston with EGL support])
  64         COMPOSITOR_MODULES="$COMPOSITOR_MODULES egl >= 7.10 glesv2"
  65 fi
  66
  67 AC_ARG_ENABLE(xkbcommon,
  68               AS_HELP_STRING([--disable-xkbcommon], [Disable libxkbcommon
  69                               support: This is only useful in environments
  70                               where you do not have a hardware keyboard. If
  71                               libxkbcommon support is disabled clients will not
  72                               be sent a keymap and and must know how to
  73                               interpret the keycode sent for any key event.]),,
  74               enable_xkbcommon=yes)
  75 if test x$enable_xkbcommon = xyes; then
  76         AC_DEFINE(ENABLE_XKBCOMMON, [1], [Build Weston with libxkbcommon support])
  77         COMPOSITOR_MODULES="$COMPOSITOR_MODULES xkbcommon"
  78 fi
  79
  80 PKG_CHECK_MODULES(COMPOSITOR, [$COMPOSITOR_MODULES])
  81
  82 AC_ARG_ENABLE(setuid-install, [  --enable-setuid-install],,
  83               enable_setuid_install=yes)
  84 AM_CONDITIONAL(ENABLE_SETUID_INSTALL, test x$enable_setuid_install = xyes)
  85
  86
  87 AC_ARG_ENABLE(xwayland, [  --enable-xwayland],,
  88               enable_xwayland=yes)
  89 AC_ARG_ENABLE(xwayland-test, [  --enable-xwayland-test],,
  90               enable_xwayland_test=yes)
  91 AM_CONDITIONAL(ENABLE_XWAYLAND, test x$enable_xwayland = xyes)
  92 AM_CONDITIONAL(ENABLE_XWAYLAND_TEST, test x$enable_xwayland = xyes -a x$enable_xwayland_test = xyes)
  93 if test x$enable_xwayland = xyes; then
  94   PKG_CHECK_MODULES([XWAYLAND], xcb xcb-xfixes xcursor cairo-xcb)
  95   AC_DEFINE([BUILD_XWAYLAND], [1], [Build the X server launcher])
  96
  97   AC_ARG_WITH(xserver-path, AS_HELP_STRING([--with-xserver-path=PATH],
  98               [Path to X server]), [XSERVER_PATH="$withval"],
  99               [XSERVER_PATH="$bindir/Xorg"])
 100   AC_SUBST([XSERVER_PATH])
 101   if test x$enable_xwayland_test = xyes; then
 102     PKG_CHECK_MODULES([XWAYLAND_TEST], xcb xcb-dri2 libdrm)
 103   fi
 104 fi
 105
 106
 107 AC_ARG_ENABLE(x11-compositor, [  --enable-x11-compositor],,
 108               enable_x11_compositor=yes)
 109 AM_CONDITIONAL(ENABLE_X11_COMPOSITOR, test x$enable_x11_compositor = xyes)
 110 if test x$enable_x11_compositor = xyes; then
 111   PKG_CHECK_MODULES([XCB], xcb)
 112   xcb_save_LIBS=$LIBS
 113   xcb_save_CFLAGS=$CFLAGS
 114   CFLAGS=$XCB_CFLAGS
 115   LIBS=$XCB_LIBS
 116   AC_CHECK_FUNCS([xcb_poll_for_queued_event])
 117   LIBS=$xcb_save_LIBS
 118   CFLAGS=$xcb_save_CFLAGS
 119
 120   X11_COMPOSITOR_MODULES="x11 x11-xcb xcb-shm"
 121
 122   PKG_CHECK_MODULES(X11_COMPOSITOR_XKB, [xcb-xkb],
 123                     [have_xcb_xkb="yes"], [have_xcb_xkb="no"])
 124   if test "x$have_xcb_xkb" = xyes; then
 125         # Most versions of XCB have totally broken XKB bindings, where the
 126         # events don't work.  Make sure we can actually use them.
 127         xcb_xkb_save_CFLAGS=$CFLAGS
 128         CFLAGS=$X11_COMPOSITOR_XKB_CFLAGS
 129         AC_CHECK_MEMBER([struct xcb_xkb_state_notify_event_t.xkbType],
 130                         [], [have_xcb_xkb=no], [[#include <xcb/xkb.h>]])
 131         CFLAGS=$xcb_xkb_save_CFLAGS
 132   fi
 133   if test "x$have_xcb_xkb" = xyes; then
 134         X11_COMPOSITOR_MODULES="$X11_COMPOSITOR_MODULES xcb-xkb"
 135         AC_DEFINE([HAVE_XCB_XKB], [1], [libxcb supports XKB protocol])
 136   fi
 137
 138   PKG_CHECK_MODULES(X11_COMPOSITOR, [$X11_COMPOSITOR_MODULES])
 139   AC_DEFINE([BUILD_X11_COMPOSITOR], [1], [Build the X11 compositor])
 140 fi
 141
 142
 143 AC_ARG_ENABLE(drm-compositor, [  --enable-drm-compositor],,
 144               enable_drm_compositor=yes)
 145 AM_CONDITIONAL(ENABLE_DRM_COMPOSITOR, test x$enable_drm_compositor = xyes -a x$enable_egl = xyes)
 146 if test x$enable_drm_compositor = xyes -a x$enable_egl = xyes; then
 147   AC_DEFINE([BUILD_DRM_COMPOSITOR], [1], [Build the DRM compositor])
 148   PKG_CHECK_MODULES(DRM_COMPOSITOR, [libudev >= 136 libdrm >= 2.4.30 gbm mtdev >= 1.1.0])
 149 fi
 150
 151
 152 AC_ARG_ENABLE(wayland-compositor, [  --enable-wayland-compositor],,
 153               enable_wayland_compositor=yes)
 154 AM_CONDITIONAL(ENABLE_WAYLAND_COMPOSITOR,
 155                test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes)
 156 if test x$enable_wayland_compositor = xyes -a x$enable_egl = xyes; then
 157   AC_DEFINE([BUILD_WAYLAND_COMPOSITOR], [1],
 158             [Build the Wayland (nested) compositor])
 159   PKG_CHECK_MODULES(WAYLAND_COMPOSITOR, [wayland-client wayland-egl])
 160 fi
 161
 162
 163 AC_ARG_ENABLE(headless-compositor, [  --enable-headless-compositor],,
 164               enable_headless_compositor=yes)
 165 AM_CONDITIONAL(ENABLE_HEADLESS_COMPOSITOR,
 166                test x$enable_headless_compositor = xyes)
 167
 168
 169 AC_ARG_ENABLE(rpi-compositor,
 170               AS_HELP_STRING([--disable-rpi-compositor],
 171                              [do not build the Raspberry Pi backend]),,
 172               enable_rpi_compositor=yes)
 173 AM_CONDITIONAL(ENABLE_RPI_COMPOSITOR, test "x$enable_rpi_compositor" = "xyes")
 174 have_bcm_host="no"
 175 if test "x$enable_rpi_compositor" = "xyes"; then
 176   AC_DEFINE([BUILD_RPI_COMPOSITOR], [1], [Build the compositor for Raspberry Pi])
 177   PKG_CHECK_MODULES(RPI_COMPOSITOR, [libudev >= 136 mtdev >= 1.1.0])
 178   PKG_CHECK_MODULES(RPI_BCM_HOST, [bcm_host],
 179                     [have_bcm_host="yes"
 180                      AC_DEFINE([HAVE_BCM_HOST], [1], [have Raspberry Pi BCM headers])],
 181                     [AC_MSG_WARN([Raspberry Pi BCM host libraries not found, will use stubs instead.])])
 182 fi
 183 AM_CONDITIONAL(INSTALL_RPI_COMPOSITOR, test "x$have_bcm_host" = "xyes")
 184
 185
 186 AC_ARG_ENABLE([fbdev-compositor], [  --enable-fbdev-compositor],,
 187               enable_fbdev_compositor=yes)
 188 AM_CONDITIONAL([ENABLE_FBDEV_COMPOSITOR],
 189                [test x$enable_fbdev_compositor = xyes])
 190 AS_IF([test x$enable_fbdev_compositor = xyes], [
 191   AC_DEFINE([BUILD_FBDEV_COMPOSITOR], [1], [Build the fbdev compositor])
 192   PKG_CHECK_MODULES([FBDEV_COMPOSITOR], [libudev >= 136 mtdev >= 1.1.0])
 193 ])
 194
 195 AC_ARG_ENABLE([rdp-compositor], [  --enable-rdp-compositor],,
 196               enable_rdp_compositor=no)
 197 AM_CONDITIONAL([ENABLE_RDP_COMPOSITOR],
 198                [test x$enable_rdp_compositor = xyes])
 199 if test x$enable_rdp_compositor = xyes; then
 200   PKG_CHECK_MODULES(RDP_COMPOSITOR, [freerdp >= 1.1.0])
 201 fi
 202
 203 AC_ARG_WITH(cairo-glesv2,
 204             AS_HELP_STRING([--with-cairo-glesv2],
 205                            [Use GLESv2 cairo instead of full GL]))
 206 if test "x$with_cairo_glesv2" = "xyes"; then
 207   cairo_modules="cairo-glesv2"
 208   AC_DEFINE([USE_CAIRO_GLESV2], [1], [Use the GLESv2 GL cairo backend])
 209 else
 210   cairo_modules="cairo-gl"
 211 fi
 212
 213 PKG_CHECK_MODULES(PIXMAN, [pixman-1])
 214 PKG_CHECK_MODULES(PNG, [libpng])
 215 PKG_CHECK_MODULES(WEBP, [libwebp], [have_webp=yes], [have_webp=no])
 216 AS_IF([test "x$have_webp" = "xyes"],
 217       [AC_DEFINE([HAVE_WEBP], [1], [Have webp])])
 218
 219 AC_CHECK_LIB([jpeg], [jpeg_CreateDecompress], have_jpeglib=yes)
 220 if test x$have_jpeglib = xyes; then
 221   JPEG_LIBS="-ljpeg"
 222 else
 223   AC_ERROR([libjpeg not found])
 224 fi
 225 AC_SUBST(JPEG_LIBS)
 226
 227 PKG_CHECK_MODULES(CAIRO, [cairo])
 228
 229 AC_ARG_ENABLE(simple-clients,
 230               AS_HELP_STRING([--disable-simple-clients],
 231                              [do not build the simple wl_shm clients]),,
 232               enable_simple_clients=yes)
 233 AM_CONDITIONAL(BUILD_SIMPLE_CLIENTS, test "x$enable_simple_clients" = "xyes")
 234 if test x$enable_simple_clients = xyes; then
 235   PKG_CHECK_MODULES(SIMPLE_CLIENT, [wayland-client])
 236 fi
 237
 238 AC_ARG_ENABLE(simple-egl-clients,
 239               AS_HELP_STRING([--disable-simple-egl-clients],
 240                              [do not build the simple EGL clients]),,
 241               enable_simple_egl_clients=yes)
 242 AM_CONDITIONAL(BUILD_SIMPLE_EGL_CLIENTS, test "x$enable_simple_egl_clients" = "xyes" -a "x$enable_egl" = "xyes")
 243 if test x$enable_simple_egl_clients = xyes -a x$enable_egl = xyes; then
 244   PKG_CHECK_MODULES(SIMPLE_EGL_CLIENT,
 245                     [egl >= 7.10 glesv2 wayland-client wayland-egl wayland-cursor])
 246 fi
 247
 248 AC_ARG_ENABLE(clients, [  --enable-clients],, enable_clients=yes)
 249 AM_CONDITIONAL(BUILD_CLIENTS, test x$enable_clients = xyes)
 250 if test x$enable_clients = xyes; then
 251   AC_DEFINE([BUILD_CLIENTS], [1], [Build the Wayland clients])
 252
 253   PKG_CHECK_MODULES(CLIENT, [wayland-client cairo >= 1.10.0 xkbcommon wayland-cursor])
 254   PKG_CHECK_MODULES(SERVER, [wayland-server])
 255   PKG_CHECK_MODULES(WESTON_INFO, [wayland-client])
 256
 257   PKG_CHECK_MODULES(POPPLER, [poppler-glib glib-2.0 gobject-2.0 gio-2.0 ],
 258                              [have_poppler=yes], [have_poppler=no])
 259   PKG_CHECK_MODULES(CAIRO_EGL, [wayland-egl egl >= 7.10 cairo-egl >= 1.11.3 $cairo_modules],
 260                     [have_cairo_egl=yes], [have_cairo_egl=no])
 261   AS_IF([test "x$have_cairo_egl" = "xyes"],
 262         [AC_DEFINE([HAVE_CAIRO_EGL], [1], [Have cairo-egl])],
 263         [AC_MSG_WARN([clients will use cairo image, cairo-egl not used because $CAIRO_EGL_PKG_ERRORS])])
 264   PKG_CHECK_MODULES(PANGO, [pangocairo], [have_pango=yes], [have_pango=no])
 265 fi
 266
 267 AC_ARG_ENABLE(resize-optimization,
 268               AS_HELP_STRING([--disable-resize-optimization],
 269                              [disable resize optimization allocating a big buffer in toytoolkit]),,
 270               enable_resize_optimization=yes)
 271 AS_IF([test "x$enable_resize_optimization" = "xyes"],
 272       [AC_DEFINE([USE_RESIZE_POOL], [1], [Use resize memory pool as a performance optimization])])
 273
 274 AC_ARG_ENABLE(weston-launch, [  --enable-weston-launch],, enable_weston_launch=yes)
 275 AM_CONDITIONAL(BUILD_WESTON_LAUNCH, test x$enable_weston_launch == xyes)
 276 if test x$enable_weston_launch == xyes; then
 277   PKG_CHECK_MODULES(WESTON_LAUNCH, [libdrm])
 278   PKG_CHECK_MODULES(SYSTEMD_LOGIN, [libsystemd-login],
 279                     [have_systemd_login=yes], [have_systemd_login=no])
 280   AS_IF([test "x$have_systemd_login" = "xyes"],
 281         [AC_DEFINE([HAVE_SYSTEMD_LOGIN], [1], [Have systemd-login])])
 282
 283   AC_CHECK_LIB([pam], [pam_open_session], [have_pam=yes], [have_pam=no])
 284   if test x$have_pam == xno; then
 285     AC_ERROR([weston-launch requires pam])
 286   fi
 287   WESTON_LAUNCH_LIBS="$WESTON_LAUNCH_LIBS -lpam"
 288 fi
 289
 290 if test x$enable_egl = xyes; then
 291   PKG_CHECK_MODULES(GLU, [glu], [have_glu=yes], [have_glu=no])
 292 fi
 293 AM_CONDITIONAL(HAVE_GLU, test "x$have_glu" = "xyes")
 294
 295
 296 AM_CONDITIONAL(HAVE_POPPLER, test "x$have_poppler" = "xyes")
 297
 298 AM_CONDITIONAL(HAVE_PANGO, test "x$have_pango" = "xyes")
 299
 300 AM_CONDITIONAL(HAVE_CAIRO_GLESV2,
 301                [test "x$have_cairo_egl" = "xyes" -a "x$cairo_modules" = "xcairo-glesv2" -a "x$enable_egl" = "xyes"])
 302
 303 AM_CONDITIONAL(BUILD_FULL_GL_CLIENTS,
 304                test x$cairo_modules = "xcairo-gl" -a "x$have_cairo_egl" = "xyes" -a "x$enable_egl" = "xyes")
 305
 306 AM_CONDITIONAL(BUILD_SUBSURFACES_CLIENT,
 307                [test '(' "x$have_cairo_egl" != "xyes" -o "x$cairo_modules" = "xcairo-glesv2" ')' -a "x$enable_simple_egl_clients" = "xyes"])
 308
 309 AM_CONDITIONAL(ENABLE_DESKTOP_SHELL, true)
 310
 311 AC_ARG_ENABLE(tablet-shell,
 312               AS_HELP_STRING([--disable-tablet-shell],
 313                              [do not build tablet-shell server plugin and client]),,
 314               enable_tablet_shell=yes)
 315 AM_CONDITIONAL(ENABLE_TABLET_SHELL,
 316                test "x$enable_tablet_shell" = "xyes")
 317
 318 # CMS modules
 319 AC_ARG_ENABLE(colord,
 320               AS_HELP_STRING([--disable-colord],
 321                              [do not build colord CMS support]),,
 322               enable_colord=auto)
 323 AM_CONDITIONAL(ENABLE_COLORD, test "x$enable_colord" = "xyes")
 324 if test "x$enable_colord" != "xno"; then
 325         PKG_CHECK_MODULES(COLORD,
 326                           colord >= 0.1.27,
 327                           have_colord=yes,
 328                           have_colord=no)
 329         if test "x$have_colord" = "xno" -a "x$enable_colord" = "xyes"; then
 330           AC_MSG_ERROR([colord support explicitly requested, but colord couldn't be found])
 331         fi
 332         if test "x$have_colord" = "xyes"; then
 333              enable_colord=yes
 334         fi
 335 fi
 336
 337 AC_ARG_ENABLE(wcap-tools, [  --disable-wcap-tools],, enable_wcap_tools=yes)
 338 AM_CONDITIONAL(BUILD_WCAP_TOOLS, test x$enable_wcap_tools = xyes)
 339 if test x$enable_wcap_tools = xyes; then
 340   AC_DEFINE([BUILD_WCAP_TOOLS], [1], [Build the wcap tools])
 341   PKG_CHECK_MODULES(WCAP, [cairo])
 342   WCAP_LIBS="$WCAP_LIBS -lm"
 343 fi
 344
 345 AC_CHECK_PROG(RSVG_CONVERT, rsvg-convert, rsvg-convert)
 346 AM_CONDITIONAL(HAVE_RSVG_CONVERT, test -n "$RSVG_CONVERT")
 347
 348 PKG_CHECK_MODULES(SETBACKLIGHT, [libudev libdrm], enable_setbacklight=yes, enable_setbacklight=no)
 349 AM_CONDITIONAL(BUILD_SETBACKLIGHT, test "x$enable_setbacklight" = "xyes")
 350
 351 if test "x$GCC" = "xyes"; then
 352         GCC_CFLAGS="-Wall -Wextra -Wno-unused-parameter \
 353                 -Wno-missing-field-initializers -g -fvisibility=hidden \
 354                 -Wstrict-prototypes -Wmissing-prototypes"
 355 fi
 356 AC_SUBST(GCC_CFLAGS)
 357
 358 AC_ARG_ENABLE(libunwind,
 359               AS_HELP_STRING([--disable-libunwind],
 360                              [Disable libunwind usage for backtraces]),,
 361               enable_libunwind=auto)
 362 AM_CONDITIONAL(HAVE_LIBUNWIND, [test "x$enable_libunwind" = xyes])
 363 if test "x$enable_libunwind" != "xno"; then
 364         PKG_CHECK_MODULES(LIBUNWIND,
 365                           libunwind,
 366                           have_libunwind=yes,
 367                           have_libunwind=no)
 368         if test "x$have_libunwind" = "xno" -a "x$enable_libunwind" = "xyes"; then
 369           AC_MSG_ERROR([libunwind support explicitly requested, but libunwind couldn't be found])
 370         fi
 371         if test "x$have_libunwind" = "xyes"; then
 372              enable_libunwind=yes
 373              AC_DEFINE(HAVE_LIBUNWIND, 1, [Have libunwind support])
 374         fi
 375 fi
 376
 377
 378 if test "x$WESTON_NATIVE_BACKEND" = "x"; then
 379         WESTON_NATIVE_BACKEND="drm-backend.so"
 380 fi
 381 AC_MSG_NOTICE([Weston's native backend: $WESTON_NATIVE_BACKEND])
 382 AC_DEFINE_UNQUOTED([WESTON_NATIVE_BACKEND], ["$WESTON_NATIVE_BACKEND"],
 383                    [The default backend to load, if not wayland nor x11.])
 384
 385 PKG_CHECK_MODULES(LCMS, lcms2,
 386                   [have_lcms=yes], [have_lcms=no])
 387 if test "x$have_lcms" = xyes; then
 388        AC_DEFINE(HAVE_LCMS, 1, [Have lcms support])
 389 fi
 390 AM_CONDITIONAL(HAVE_LCMS, [test "x$have_lcms" = xyes])
 391
 392 WAYLAND_SCANNER_RULES(['$(top_srcdir)/protocol'])
 393
 394 AC_CONFIG_FILES([Makefile
 395                  shared/Makefile
 396                  src/Makefile
 397                  src/xwayland/Makefile
 398                  src/version.h
 399                  src/weston.pc
 400                  clients/Makefile
 401                  wcap/Makefile
 402                  data/Makefile
 403                  protocol/Makefile
 404                  man/Makefile
 405                  tests/Makefile])
 406 AC_OUTPUT