configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_SUBST(DISABLE_MEM_POOLS)
 247   AC_MSG_RESULT([yes])
 248 fi
 249
 250 dnl location to install runtime libraries, e.g. ../../lib to install
 251 dnl to /lib if libdir is /usr/lib
 252 AC_ARG_WITH(runtime-libdir,
 253            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 254                            [install runtime libraries relative to libdir])],
 255            [],
 256            [with_runtime_libdir=""])
 257 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 258 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 259 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 260 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 264 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 265 AC_LANG_SAVE
 266 AC_LANG_CPLUSPLUS
 267 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 268 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 269 AC_LANG_RESTORE
 270
 271 AM_PROG_CC_STDC
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test x$cflags_set != xset ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286
 287   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 288 else
 289   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 290
 291   if test "x$enable_debug" = "xno"; then
 292     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 293   fi
 294 fi
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$glib_native_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 331 AC_SUBST(GLIB_EXTRA_CFLAGS)
 332
 333 AC_EXEEXT
 334
 335 # define a MAINT-like variable REBUILD which is set if Perl
 336 # and awk are found, so autogenerated sources can be rebuilt
 337 AC_PROG_AWK
 338 AC_CHECK_PROGS(PERL, [perl5 perl])
 339 # We would like indent, but don't require it.
 340 AC_CHECK_PROG(INDENT, indent, indent)
 341 REBUILD=\#
 342 if test "x$enable_rebuilds" = "xyes" && \
 343      test -n "$PERL" && \
 344      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 345      test -n "$AWK" ; then
 346   REBUILD=
 347 fi
 348 AC_SUBST(REBUILD)
 349
 350 # Need full path to Perl for glib-mkenums
 351 #
 352 if test "x$PERL" != x ; then
 353   AC_PATH_PROG(PERL_PATH, [$PERL])
 354 fi
 355 if test "x$PERL_PATH" = x ; then
 356   PERL_PATH="/usr/bin/env perl"
 357 fi
 358 AC_SUBST(PERL_PATH)
 359
 360 # Need suitable python path for greport
 361 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 362
 363
 364 dnl ***********************
 365 dnl *** Tests for iconv ***
 366 dnl ***********************
 367 dnl
 368 dnl We do this before the gettext checks, to avoid distortion
 369
 370 dnl On Windows we use a native implementation
 371
 372 if test x"$glib_native_win32" = xyes; then
 373   with_libiconv=native
 374 else
 375   AC_ARG_WITH(libiconv,
 376               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 377                               [use the libiconv library])],,
 378               [with_libiconv=maybe])
 379
 380   found_iconv=no
 381   case $with_libiconv in
 382     maybe)
 383       # Check in the C library first
 384       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385       # Check if we have GNU libiconv
 386       if test $found_iconv = "no"; then
 387         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388       fi
 389       # Check if we have a iconv in -liconv, possibly from vendor
 390       if test $found_iconv = "no"; then
 391         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 392       fi
 393       ;;
 394     no)
 395       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 396       ;;
 397     gnu|yes)
 398       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 399       ;;
 400     native)
 401       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 402       ;;
 403   esac
 404
 405   if test "x$found_iconv" = "xno" ; then
 406      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 407   fi
 408 fi
 409
 410 AC_ARG_ENABLE(iconv-cache,
 411               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 412                               [cache iconv descriptors [default=auto]])],,
 413               [enable_iconv_cache=auto])
 414
 415 AC_MSG_CHECKING([whether to cache iconv descriptors])
 416 case $enable_iconv_cache in
 417   auto)
 418     if test $ac_cv_gnu_library_2_1 = yes; then
 419       enable_iconv_cache=no
 420     else
 421       enable_iconv_cache=yes
 422     fi
 423   ;;
 424   yes|no)
 425   ;;
 426   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 427   ;;
 428 esac
 429
 430 if test $enable_iconv_cache = yes; then
 431    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 432 fi
 433
 434 AC_MSG_RESULT($enable_iconv_cache)
 435
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 if test "x$found_zlib" = "xno" ; then
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 fi
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 if test x"$glib_native_win32" != xyes; then
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 fi
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 if test "x$GCC" = "xyes"; then
 509   case " $CFLAGS " in
 510   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 511   *) CFLAGS="$CFLAGS -Wall" ;;
 512   esac
 513 fi
 514
 515 if test "$glib_native_win32" = "yes"; then
 516   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 517     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 518   fi
 519   if test x$enable_static = xyes; then
 520     glib_win32_static_compilation=yes
 521     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 522 #define GOBJECT_STATIC_COMPILATION 1"
 523     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 524   fi
 525 fi
 526 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 527
 528 dnl
 529 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 530 dnl
 531 if test $cross_compiling != yes ; then
 532     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 533     glib_save_LIBS=$LIBS
 534     LIBS="$LIBS -lm"
 535     AC_TRY_RUN([#include <math.h>
 536                  int main (void) { return (log(1) != log(1.)); }],
 537          AC_MSG_RESULT(none needed),
 538          glib_save_CFLAGS=$CFLAGS
 539          CFLAGS="$CFLAGS -std1"
 540          AC_TRY_RUN([#include <math.h>
 541                      int main (void) { return (log(1) != log(1.)); }],
 542              AC_MSG_RESULT(-std1),
 543              AC_MSG_RESULT()
 544              CFLAGS=$glib_save_CFLAGS
 545              AC_MSG_WARN(
 546                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 547          )
 548     )
 549     LIBS=$glib_save_LIBS
 550 fi
 551
 552 dnl NeXTStep cc seems to need this
 553 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 554 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 555   AC_MSG_RESULT(none needed),
 556   glib_save_CFLAGS=$CFLAGS
 557   CFLAGS="$CFLAGS -posix"
 558   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 559     AC_MSG_RESULT(-posix),
 560     AC_MSG_RESULT()
 561     CFLAGS=$glib_save_CFLAGS
 562     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 563
 564 # Checks for header files.
 565 AC_HEADER_STDC
 566
 567 # Checks for library functions.
 568 AC_FUNC_VPRINTF
 569 AC_FUNC_ALLOCA
 570 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 571 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 572
 573 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 574 dnl be automatically defined, which we don't want to do
 575 dnl until we have checked this function is actually usable
 576 AC_CHECK_FUNC([qsort_r])
 577
 578 # BSD has a qsort_r with wrong argument order
 579 if test x$ac_cv_func_qsort_r = xyes ; then
 580   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 581   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 582   #define _GNU_SOURCE
 583   #include <stdlib.h>
 584
 585   static int
 586   cmp (const void *a, const void *b, void *c)
 587   {
 588     const int *ia = a;
 589     const int *ib = b;
 590
 591     if (*ia < *ib)
 592       return -1;
 593     else if (*ia > *ib)
 594       return 1;
 595     else
 596       return 0;
 597   }
 598
 599   int
 600   main (int argc, char **argv)
 601   {
 602     int arr[3] = { 1, 2, 0 };
 603     int d = 3;
 604
 605     qsort_r (arr, 3, sizeof (int), cmp, &d);
 606
 607     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 608       return 0;
 609     else
 610       return 1;
 611   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 612 fi
 613
 614 if test x$glib_cv_have_qsort_r = xyes ; then
 615   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 616 fi
 617
 618 AC_CHECK_SIZEOF(char)
 619 AC_CHECK_SIZEOF(short)
 620 AC_CHECK_SIZEOF(long)
 621 AC_CHECK_SIZEOF(int)
 622 AC_CHECK_SIZEOF(void *)
 623 AC_CHECK_SIZEOF(long long)
 624 AC_CHECK_SIZEOF(__int64)
 625
 626 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 627   :
 628 else
 629   AC_MSG_ERROR([
 630 *** GLib requires a 64 bit type. You might want to consider
 631 *** using the GNU C compiler.
 632 ])
 633 fi
 634
 635 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 636         # long long is a 64 bit integer.
 637         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 638         AC_CACHE_VAL(glib_cv_long_long_format,[
 639                 for format in ll q I64; do
 640                   AC_TRY_RUN([#include <stdio.h>
 641                         int main()
 642                         {
 643                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 644                           char buffer[1000];
 645                           sprintf (buffer, "%${format}u", a);
 646                           sscanf (buffer, "%${format}u", &b);
 647                           exit (b!=a);
 648                         }
 649                         ],
 650                         [glib_cv_long_long_format=${format}
 651                         break],
 652                         [],[:])
 653                 done])
 654         if test -n "$glib_cv_long_long_format"; then
 655           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 656           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 657           if test x"$glib_cv_long_long_format" = xI64; then
 658             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 659           fi
 660         else
 661           AC_MSG_RESULT(none)
 662         fi
 663 elif test x$ac_cv_sizeof___int64 = x8; then
 664         # __int64 is a 64 bit integer.
 665         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 666         # We know this is MSVCRT.DLL, and what the formats are
 667         glib_cv_long_long_format=I64
 668         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 669         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 670         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 671 fi
 672
 673 dnl long doubles were not used, and a portability problem
 674 dnl AC_C_LONG_DOUBLE
 675 AC_C_CONST
 676
 677 dnl ok, here we try to check whether the systems prototypes for
 678 dnl malloc and friends actually match the prototypes provided
 679 dnl by gmem.h (keep in sync). i currently only know how to check
 680 dnl this reliably with gcc (-Werror), improvements for other
 681 dnl compilers are apprechiated.
 682 SANE_MALLOC_PROTOS=no
 683 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 684 glib_save_CFLAGS=$CFLAGS
 685 if test "x$GCC" = "xyes"; then
 686   CFLAGS="$CFLAGS -Werror"
 687   AC_TRY_COMPILE([#include <stdlib.h>], [
 688     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 689     void* (*my_malloc_p)  (size_t)         = malloc;
 690     void  (*my_free_p)    (void*)          = free;
 691     void* (*my_realloc_p) (void*, size_t)  = realloc;
 692     my_calloc_p = 0;
 693     my_malloc_p = 0;
 694     my_free_p = 0;
 695     my_realloc_p = 0;
 696   ],
 697     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 698       [Define if you have correct malloc prototypes])
 699     SANE_MALLOC_PROTOS=yes)
 700 fi
 701 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 702 CFLAGS=$glib_save_CFLAGS
 703
 704 dnl
 705 dnl check in which direction the stack grows
 706 dnl
 707 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 708         AC_TRY_RUN([
 709         volatile int *a = 0, *b = 0;
 710         void foo (void);
 711         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 712         void foo (void) { volatile int x = 5; b = &x; }
 713         ],
 714         glib_cv_stack_grows=no
 715         ,
 716         glib_cv_stack_grows=yes
 717         ,)
 718 ])
 719
 720 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 721 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 722 dnl actually supported.
 723 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 724         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 725         __inline int foo () { return 0; }
 726         int main () { return foo (); }
 727         ]])],
 728         glib_cv_has__inline=yes
 729         ,
 730         glib_cv_has__inline=no
 731         ,)
 732 ])
 733 case x$glib_cv_has__inline in
 734 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 735 esac
 736 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 737         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 738         __inline__ int foo () { return 0; }
 739         int main () { return foo (); }
 740         ]])],
 741         glib_cv_has__inline__=yes
 742         ,
 743         glib_cv_has__inline__=no
 744         ,)
 745 ])
 746 case x$glib_cv_has__inline__ in
 747 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 748 esac
 749 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 750         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 751         #undef inline
 752         inline int foo () { return 0; }
 753         int main () { return foo (); }
 754         ]])],
 755         glib_cv_hasinline=yes
 756         ,
 757         glib_cv_hasinline=no
 758         ,)
 759 ])
 760 case x$glib_cv_hasinline in
 761 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 762 esac
 763
 764 # if we can use inline functions in headers
 765 AC_MSG_CHECKING(if inline functions in headers work)
 766 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 767 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 768 #  undef inline
 769 #  define inline __inline__
 770 #elif !defined (G_HAVE_INLINE)
 771 #  undef inline
 772 #  if defined (G_HAVE___INLINE__)
 773 #    define inline __inline__
 774 #  elif defined (G_HAVE___INLINE)
 775 #    define inline __inline
 776 #  endif
 777 #endif
 778
 779 int glib_test_func2 (int);
 780
 781 static inline int
 782 glib_test_func1 (void) {
 783   return glib_test_func2 (1);
 784 }
 785
 786 int
 787 main (void) {
 788   int i = 1;
 789 }]])],[g_can_inline=yes],[g_can_inline=no])
 790 AC_MSG_RESULT($g_can_inline)
 791
 792 dnl *** check for working do while(0) macros ***
 793 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 794         AC_TRY_COMPILE([],[
 795         #define STMT_START do
 796         #define STMT_END while(0)
 797         #define STMT_TEST STMT_START { i = 0; } STMT_END
 798         int main(void) { int i = 1; STMT_TEST; return i; }],
 799         [g_cv_support_dowhile_macros=yes],
 800         [g_cv_support_dowhile_macros=no],
 801         [g_cv_support_dowhile_macros=yes])
 802 ])
 803 if test x$g_cv_support_dowhile_macros = xyes; then
 804   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 805 fi
 806
 807 # check for flavours of varargs macros
 808 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 809 AC_TRY_COMPILE([],[
 810 int a(int p1, int p2, int p3);
 811 #define call_a(...) a(1,__VA_ARGS__)
 812 call_a(2,3);
 813 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 814 AC_MSG_RESULT($g_have_iso_c_varargs)
 815
 816 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 817 if test "$CXX" = ""; then
 818 dnl No C++ compiler
 819   g_have_iso_cxx_varargs=no
 820 else
 821   AC_LANG_CPLUSPLUS
 822   AC_TRY_COMPILE([],[
 823 int a(int p1, int p2, int p3);
 824 #define call_a(...) a(1,__VA_ARGS__)
 825 call_a(2,3);
 826 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 827   AC_LANG_C
 828 fi
 829 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 830
 831 AC_MSG_CHECKING(for GNUC varargs macros)
 832 AC_TRY_COMPILE([],[
 833 int a(int p1, int p2, int p3);
 834 #define call_a(params...) a(1,params)
 835 call_a(2,3);
 836 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 837 AC_MSG_RESULT($g_have_gnuc_varargs)
 838
 839 # check for GNUC visibility support
 840 AC_MSG_CHECKING(for GNUC visibility attribute)
 841 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 842 void
 843 __attribute__ ((visibility ("hidden")))
 844      f_hidden (void)
 845 {
 846 }
 847 void
 848 __attribute__ ((visibility ("internal")))
 849      f_internal (void)
 850 {
 851 }
 852 void
 853 __attribute__ ((visibility ("protected")))
 854      f_protected (void)
 855 {
 856 }
 857 void
 858 __attribute__ ((visibility ("default")))
 859      f_default (void)
 860 {
 861 }
 862 int main (int argc, char **argv)
 863 {
 864         f_hidden();
 865         f_internal();
 866         f_protected();
 867         f_default();
 868         return 0;
 869 }
 870 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 871 AC_MSG_RESULT($g_have_gnuc_visibility)
 872 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 873
 874 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 875 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 876 #else
 877 # include "error: this is not Sun Studio."
 878 #endif
 879 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 880 AC_MSG_RESULT($g_have_sunstudio_visibility)
 881 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 882
 883 # check for bytesex stuff
 884 AC_C_BIGENDIAN
 885 if test x$ac_cv_c_bigendian = xuniversal ; then
 886 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 887 #else
 888 #error Not a big endian.
 889 #endif],
 890     ac_cv_c_bigendian=yes
 891     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 892 #else
 893 #error Not a little endian.
 894 #endif],
 895     ac_cv_c_bigendian=no
 896     ,AC_MSG_WARN([Could not determine endianness.])))
 897 fi
 898
 899
 900 # check for header files
 901 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 902 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 903 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 904 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 905 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 906 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 907 AC_CHECK_HEADERS([linux/magic.h])
 908 AC_CHECK_HEADERS([sys/prctl.h])
 909
 910 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 911 [#if HAVE_SYS_PARAM_H
 912  #include <sys/param.h>
 913  #endif
 914 ])
 915
 916 AC_CHECK_HEADERS([xlocale.h])
 917
 918 # check for structure fields
 919 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 920 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 921 #include <sys/stat.h>
 922 #include <unistd.h>
 923 #ifdef HAVE_SYS_STATFS_H
 924 #include <sys/statfs.h>
 925 #endif
 926 #ifdef HAVE_SYS_PARAM_H
 927 #include <sys/param.h>
 928 #endif
 929 #ifdef HAVE_SYS_MOUNT_H
 930 #include <sys/mount.h>
 931 #endif])
 932 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 933 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 934 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 935 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 936
 937 # Checks for libcharset
 938 AM_LANGINFO_CODESET
 939 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 940 AC_CHECK_FUNCS(setlocale)
 941
 942 # check additional type sizes
 943 AC_CHECK_SIZEOF(size_t)
 944
 945 dnl Try to figure out whether gsize, gssize should be long or int
 946 AC_MSG_CHECKING([for the appropriate definition for size_t])
 947
 948 case $ac_cv_sizeof_size_t in
 949   $ac_cv_sizeof_short)
 950       glib_size_type=short
 951       ;;
 952   $ac_cv_sizeof_int)
 953       glib_size_type=int
 954       ;;
 955   $ac_cv_sizeof_long)
 956       glib_size_type=long
 957       ;;
 958   $ac_cv_sizeof_long_long)
 959       glib_size_type='long long'
 960       ;;
 961   $ac_cv_sizeof__int64)
 962       glib_size_type='__int64'
 963       ;;
 964   *)  AC_MSG_ERROR([No type matching size_t in size])
 965       ;;
 966 esac
 967
 968 dnl If int/long are the same size, we see which one produces
 969 dnl warnings when used in the location as size_t. (This matters
 970 dnl on AIX with xlc)
 971 dnl
 972 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 973    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 974   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 975 #if defined(_AIX) && !defined(__GNUC__)
 976 #pragma options langlvl=stdc89
 977 #endif
 978 #include <stddef.h>
 979 int main ()
 980 {
 981   size_t s = 1;
 982   unsigned int *size_int = &s;
 983   return (int)*size_int;
 984 }
 985     ]])],glib_size_type=int,
 986       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 987 #if defined(_AIX) && !defined(__GNUC__)
 988 #pragma options langlvl=stdc89
 989 #endif
 990 #include <stddef.h>
 991 int main ()
 992 {
 993    size_t s = 1;
 994    unsigned long *size_long = &s;
 995    return (int)*size_long;
 996 }
 997         ]])],glib_size_type=long)])
 998 fi
 999
1000 AC_MSG_RESULT(unsigned $glib_size_type)
1001
1002 # Check for some functions
1003 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1004 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1005 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1006 # Check for high-resolution sleep functions
1007 AC_CHECK_FUNCS(splice)
1008 AC_CHECK_FUNCS(prlimit)
1009
1010 # To avoid finding a compatibility unusable statfs, which typically
1011 # successfully compiles, but warns to use the newer statvfs interface:
1012 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1013 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1014
1015 AC_MSG_CHECKING([whether to use statfs or statvfs])
1016 # Some systems have both statfs and statvfs, pick the most "native" for these
1017 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1018    [
1019    # on solaris and irix, statfs doesn't even have the f_bavail field
1020    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1021       [ac_cv_func_statfs=no],
1022    # else, at least on linux, statfs is the actual syscall
1023       [ac_cv_func_statvfs=no])
1024    ])
1025
1026 AS_IF([test x$ac_cv_func_statfs = xyes],
1027       [
1028          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1029          AC_MSG_RESULT([statfs])
1030       ],
1031       [test x$ac_cv_func_statvfs = xyes],
1032       [
1033          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1034          AC_MSG_RESULT([statvfs])
1035       ],
1036       [  AC_MSG_RESULT([neither])])
1037
1038 AC_CHECK_HEADERS(crt_externs.h)
1039 AC_CHECK_FUNCS(_NSGetEnviron)
1040
1041 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1042
1043 AC_FUNC_VSNPRINTF_C99
1044 AC_FUNC_PRINTF_UNIX98
1045
1046 # Internet address families
1047 if test $glib_native_win32 = yes; then
1048   glib_inet_includes=["
1049 #include <winsock2.h>
1050   "]
1051 else
1052   glib_inet_includes=["
1053 #include <sys/types.h>
1054 #include <sys/socket.h>
1055   "]
1056 fi
1057
1058 glib_failed=false
1059 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1060 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1061 # winsock defines this even though it doesn't support it
1062 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1063 if $glib_failed ; then
1064   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1065 fi
1066
1067 glib_failed=false
1068 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1069 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1070 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1071 if $glib_failed ; then
1072   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1073 fi
1074
1075 AC_CHECK_FUNCS(getprotobyname_r endservent)
1076 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1077
1078 if test $glib_native_win32 = no; then
1079   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1080   NETWORK_LIBS=""
1081   AC_MSG_CHECKING([for res_query])
1082   AC_TRY_LINK([#include <sys/types.h>
1083                #include <netinet/in.h>
1084                #include <arpa/nameser.h>
1085                #include <resolv.h>
1086               ],[
1087                res_query("test", 0, 0, (void *)0, 0);
1088               ],[AC_MSG_RESULT([yes])],
1089               [save_libs="$LIBS"
1090                LIBS="-lresolv $LIBS"
1091                AC_TRY_LINK([#include <sys/types.h>
1092                             #include <netinet/in.h>
1093                             #include <arpa/nameser.h>
1094                             #include <resolv.h>
1095                            ],[
1096                             res_query("test", 0, 0, (void *)0, 0);
1097                            ],[AC_MSG_RESULT([in -lresolv])
1098                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1099                            [LIBS="-lbind $save_libs"
1100                             AC_TRY_LINK([#include <resolv.h>],
1101                                         [res_query("test", 0, 0, (void *)0, 0);],
1102                                         [AC_MSG_RESULT([in -lbind])
1103                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1104                                         [AC_MSG_ERROR(not found)])])
1105                LIBS="$save_libs"])
1106   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1107                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1108                                         [AC_MSG_ERROR(Could not find socket())]))
1109 fi
1110 AC_SUBST(NETWORK_LIBS)
1111
1112 AC_CHECK_HEADER([linux/netlink.h],
1113                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])])
1114 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1115
1116 case $host in
1117   *-*-solaris* )
1118      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1119      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1120      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1121      ;;
1122 esac
1123
1124 dnl
1125 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1126 dnl
1127 if test "$ac_cv_func_statfs" = yes ; then
1128   AC_MSG_CHECKING([number of arguments to statfs()])
1129   AC_TRY_COMPILE([#include <unistd.h>
1130   #ifdef HAVE_SYS_PARAM_H
1131   #include <sys/param.h>
1132   #endif
1133   #ifdef HAVE_SYS_VFS_H
1134   #include <sys/vfs.h>
1135   #endif
1136   #ifdef HAVE_SYS_MOUNT_H
1137   #include <sys/mount.h>
1138   #endif
1139   #ifdef HAVE_SYS_STATFS_H
1140   #include <sys/statfs.h>
1141   #endif], [struct statfs st;
1142   statfs(NULL, &st);],[
1143     AC_MSG_RESULT([2])
1144     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1145     AC_TRY_COMPILE([#include <unistd.h>
1146   #ifdef HAVE_SYS_PARAM_H
1147   #include <sys/param.h>
1148   #endif
1149   #ifdef HAVE_SYS_VFS_H
1150   #include <sys/vfs.h>
1151   #endif
1152   #ifdef HAVE_SYS_MOUNT_H
1153   #include <sys/mount.h>
1154   #endif
1155   #ifdef HAVE_SYS_STATFS_H
1156   #include <sys/statfs.h>
1157   #endif], [struct statfs st;
1158   statfs(NULL, &st, sizeof (st), 0);],[
1159       AC_MSG_RESULT([4])
1160       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1161       AC_MSG_RESULT(unknown)
1162       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1163 fi
1164
1165 #
1166 # Check whether to use an included printf
1167 #
1168
1169 AC_ARG_ENABLE(included-printf,
1170               [AC_HELP_STRING([--enable-included-printf],
1171                               [use included printf [default=auto]])],
1172               enable_included_printf="$enableval")
1173
1174 need_included_printf=no
1175 if test "x$enable_included_printf" = "xyes" ; then
1176   need_included_printf=yes
1177 fi
1178 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1179   need_included_printf=yes
1180 fi
1181 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1182   need_included_printf=yes
1183 fi
1184 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1185    test -z "$glib_cv_long_long_format" ; then
1186   need_included_printf=yes
1187 fi
1188
1189 if test "x$enable_included_printf" = "xno" &&
1190    test "x$need_included_printf" = "xyes" ; then
1191   AC_MSG_ERROR([
1192 *** Your C library's printf doesn't appear to have the features that
1193 *** GLib needs, but you specified --enable-included-printf=no.])
1194 fi
1195
1196 enable_included_printf=$need_included_printf
1197
1198 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1199 if test "$enable_included_printf" != "yes" ; then
1200   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1201 else
1202   if test -z "$glib_cv_long_long_format" ; then
1203     glib_cv_long_long_format="ll"
1204   fi
1205   AC_DEFINE(HAVE_VASPRINTF,1)
1206 fi
1207
1208 # Checks needed for gnulib vasnprintf
1209 bh_C_SIGNED
1210 jm_AC_TYPE_LONG_LONG
1211 gt_TYPE_LONGDOUBLE
1212 gt_TYPE_WCHAR_T
1213 gt_TYPE_WINT_T
1214 AC_TYPE_SIZE_T
1215 AC_CHECK_TYPES(ptrdiff_t)
1216 jm_AC_TYPE_INTMAX_T
1217 AC_CHECK_FUNCS([snprintf wcslen])
1218 AC_FUNC_SNPRINTF_C99
1219
1220 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1221 # The check is borrowed from the PERL Configure script.
1222 if test "$ac_cv_func_memmove" != "yes"; then
1223   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1224     glib_cv_working_bcopy,[AC_TRY_RUN([
1225       int main() {
1226         char buf[128], abc[128], *b;
1227         int len, off, align;
1228         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1229         for (align = 7; align >= 0; align--) {
1230           for (len = 36; len; len--) {
1231             b = buf+align; bcopy(abc, b, len);
1232             for (off = 1; off <= len; off++) {
1233               bcopy(b, b+off, len); bcopy(b+off, b, len);
1234                 if (bcmp(b, abc, len)) return(1);
1235             }
1236           }
1237         }
1238         return(0);
1239       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1240
1241   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1242   if test "$glib_cv_working_bcopy" = "yes"; then
1243     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1244   fi
1245 fi
1246
1247 # Check if <sys/select.h> needs to be included for fd_set
1248 AC_MSG_CHECKING([for fd_set])
1249 AC_TRY_COMPILE([#include <sys/types.h>],
1250         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1251 if test "$gtk_ok" = "yes"; then
1252     AC_MSG_RESULT([yes, found in sys/types.h])
1253 else
1254     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1255     if test "$gtk_ok" = "yes"; then
1256         # *** FIXME: give it a different name
1257         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1258         AC_MSG_RESULT([yes, found in sys/select.h])
1259     else
1260         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1261         AC_MSG_RESULT(no)
1262     fi
1263 fi
1264
1265 dnl *** check for sane realloc() ***
1266 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1267         AC_TRY_RUN([#include <stdlib.h>
1268         int main() {
1269           return realloc (0, sizeof (int)) == 0;
1270         }],
1271         [glib_cv_sane_realloc=yes],
1272         [glib_cv_sane_realloc=no],
1273         [glib_cv_sane_realloc=yes])
1274 ])
1275 if test x$glib_cv_sane_realloc = xyes; then
1276   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1277 fi
1278
1279 dnl Check for nl_langinfo and CODESET
1280 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1281         AC_TRY_COMPILE([#include <langinfo.h>],
1282                 [char *codeset = nl_langinfo (CODESET);],
1283                 [glib_cv_langinfo_codeset=yes],
1284                 [glib_cv_langinfo_codeset=no])])
1285 if test x$glib_cv_langinfo_codeset = xyes; then
1286   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1287 fi
1288
1289 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1290 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1291         AC_TRY_COMPILE([#include <langinfo.h>],
1292                 [char *str;
1293                  str = nl_langinfo (PM_STR);
1294                  str = nl_langinfo (D_T_FMT);
1295                  str = nl_langinfo (D_FMT);
1296                  str = nl_langinfo (T_FMT);
1297                  str = nl_langinfo (T_FMT_AMPM);
1298                  str = nl_langinfo (MON_1);
1299                  str = nl_langinfo (ABMON_12);
1300                  str = nl_langinfo (DAY_1);
1301                  str = nl_langinfo (ABDAY_7);],
1302                 [glib_cv_langinfo_time=yes],
1303                 [glib_cv_langinfo_time=no])])
1304 if test x$glib_cv_langinfo_time = xyes; then
1305   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1306 fi
1307
1308 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1309 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1310         AC_TRY_COMPILE([#include <langinfo.h>],
1311                 [char *str;
1312                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1313                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1315                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1316                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1317                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1318                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1319                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1320                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1321                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1322                 [glib_cv_langinfo_outdigit=yes],
1323                 [glib_cv_langinfo_outdigit=no])])
1324 if test x$glib_cv_langinfo_outdigit = xyes; then
1325   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1326 fi
1327
1328 dnl ****************************************
1329 dnl *** posix_memalign                   ***
1330 dnl ****************************************
1331 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1332 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1333     glib_cv_compliant_posix_memalign=0
1334     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1335         AC_TRY_RUN([
1336                 #define _XOPEN_SOURCE 600
1337                 #include <stdlib.h> /* posix_memalign() should be defined here */
1338                 /* some systems break if #include <malloc.h> used */
1339                 static void test_memalign (size_t boundary, size_t size) {
1340                     void *mem = 0;
1341                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1342                         exit (1);
1343                     else
1344                       free (mem);
1345                 }
1346                 int main() {
1347                     test_memalign (  128,   128 - 2 * sizeof (void*));
1348                     test_memalign (  256,   256 - 2 * sizeof (void*));
1349                     test_memalign (  512,   512 - 2 * sizeof (void*));
1350                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1351                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1352                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1353                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1354                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1355                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1356                     exit (0); /* success */
1357                 }
1358                 ],
1359             [glib_cv_compliant_posix_memalign=1], [], [:])
1360       :
1361     fi
1362     ])
1363 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1364     AC_MSG_RESULT(yes)
1365     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1366 else
1367     AC_MSG_RESULT(no)
1368 fi
1369
1370
1371 dnl ****************************************
1372 dnl *** strlcpy/strlcat                  ***
1373 dnl ****************************************
1374 # Check for strlcpy
1375 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1376 AC_TRY_RUN([#include <stdlib.h>
1377 #include <string.h>
1378 int main() {
1379   char p[10];
1380   (void) strlcpy (p, "hi", 10);
1381   if (strlcat (p, "bye", 0) != 3)
1382     return 1;
1383   return 0;
1384 }], glib_cv_have_strlcpy=yes,
1385     glib_cv_have_strlcpy=no,
1386     glib_cv_have_strlcpy=no)])
1387 if test "$glib_cv_have_strlcpy" = "yes"; then
1388     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1389 fi
1390
1391
1392 dnl **********************
1393 dnl *** va_copy checks ***
1394 dnl **********************
1395 dnl we currently check for all three va_copy possibilities, so we get
1396 dnl all results in config.log for bug reports.
1397 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1398         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1399 #include <stdlib.h>
1400         void f (int i, ...) {
1401         va_list args1, args2;
1402         va_start (args1, i);
1403         va_copy (args2, args1);
1404         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1405           exit (1);
1406         va_end (args1); va_end (args2);
1407         }
1408         int main() {
1409           f (0, 42);
1410           return 0;
1411         }]])],
1412         [glib_cv_va_copy=yes],
1413         [glib_cv_va_copy=no])
1414 ])
1415 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1416         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1417 #include <stdlib.h>
1418         void f (int i, ...) {
1419         va_list args1, args2;
1420         va_start (args1, i);
1421         __va_copy (args2, args1);
1422         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1423           exit (1);
1424         va_end (args1); va_end (args2);
1425         }
1426         int main() {
1427           f (0, 42);
1428           return 0;
1429         }]])],
1430         [glib_cv___va_copy=yes],
1431         [glib_cv___va_copy=no])
1432 ])
1433
1434 if test "x$glib_cv_va_copy" = "xyes"; then
1435   g_va_copy_func=va_copy
1436 else if test "x$glib_cv___va_copy" = "xyes"; then
1437   g_va_copy_func=__va_copy
1438 fi
1439 fi
1440
1441 if test -n "$g_va_copy_func"; then
1442   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1443 fi
1444
1445 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1446         AC_TRY_RUN([#include <stdarg.h>
1447 #include <stdlib.h>
1448         void f (int i, ...) {
1449         va_list args1, args2;
1450         va_start (args1, i);
1451         args2 = args1;
1452         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1453           exit (1);
1454         va_end (args1); va_end (args2);
1455         }
1456         int main() {
1457           f (0, 42);
1458           return 0;
1459         }],
1460         [glib_cv_va_val_copy=yes],
1461         [glib_cv_va_val_copy=no],
1462         [glib_cv_va_val_copy=yes])
1463 ])
1464
1465 if test "x$glib_cv_va_val_copy" = "xno"; then
1466   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1467 fi
1468
1469 dnl ***********************
1470 dnl *** g_module checks ***
1471 dnl ***********************
1472 G_MODULE_LIBS=
1473 G_MODULE_LIBS_EXTRA=
1474 G_MODULE_PLUGIN_LIBS=
1475 if test x"$glib_native_win32" = xyes; then
1476   dnl No use for this on Win32
1477   G_MODULE_LDFLAGS=
1478 else
1479   export SED
1480   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1481 fi
1482 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1483 G_MODULE_NEED_USCORE=0
1484 G_MODULE_BROKEN_RTLD_GLOBAL=0
1485 G_MODULE_HAVE_DLERROR=0
1486 dnl *** force native WIN32 shared lib loader
1487 if test -z "$G_MODULE_IMPL"; then
1488   case "$host" in
1489   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1490   esac
1491 fi
1492 dnl *** force native AIX library loader
1493 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1494 if test -z "$G_MODULE_IMPL"; then
1495   case "$host" in
1496   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1497   esac
1498 fi
1499 dnl *** dlopen() and dlsym() in system libraries
1500 if test -z "$G_MODULE_IMPL"; then
1501         AC_CHECK_FUNC(dlopen,
1502                       [AC_CHECK_FUNC(dlsym,
1503                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1504                       [])
1505 fi
1506 dnl *** load_image (BeOS)
1507 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1508   AC_CHECK_LIB(root, load_image,
1509       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1510       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1511       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1512       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1513       [])
1514 fi
1515 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1516 if test -z "$G_MODULE_IMPL"; then
1517         AC_CHECK_FUNC(NSLinkModule,
1518                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1519                        G_MODULE_NEED_USCORE=1],
1520                       [])
1521 fi
1522 dnl *** dlopen() and dlsym() in libdl
1523 if test -z "$G_MODULE_IMPL"; then
1524         AC_CHECK_LIB(dl, dlopen,
1525                      [AC_CHECK_LIB(dl, dlsym,
1526                                    [G_MODULE_LIBS=-ldl
1527                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1528                      [])
1529 fi
1530 dnl *** shl_load() in libdld (HP-UX)
1531 if test -z "$G_MODULE_IMPL"; then
1532         AC_CHECK_LIB(dld, shl_load,
1533                 [G_MODULE_LIBS=-ldld
1534                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1535                 [])
1536 fi
1537 dnl *** additional checks for G_MODULE_IMPL_DL
1538 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1539         LIBS_orig="$LIBS"
1540         LDFLAGS_orig="$LDFLAGS"
1541         LIBS="$G_MODULE_LIBS $LIBS"
1542         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1543 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1544         echo "void glib_plugin_test(void) { }" > plugin.c
1545         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1546                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1547         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1548                 glib_cv_rtldglobal_broken,[
1549                 AC_TRY_RUN([
1550 #include <dlfcn.h>
1551 #ifndef RTLD_GLOBAL
1552 #  define RTLD_GLOBAL 0
1553 #endif
1554 #ifndef RTLD_LAZY
1555 #  define RTLD_LAZY 0
1556 #endif
1557 int glib_plugin_test;
1558 int main () {
1559     void *handle, *global, *local;
1560     global = &glib_plugin_test;
1561     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1562     if (!handle) return 0;
1563     local = dlsym (handle, "glib_plugin_test");
1564     return global == local;
1565 }                       ],
1566                         [glib_cv_rtldglobal_broken=no],
1567                         [glib_cv_rtldglobal_broken=yes],
1568                         [glib_cv_rtldglobal_broken=no])
1569                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1570                 rmdir .libs 2>/dev/null
1571         ])
1572         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1573                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1574         else
1575                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1576         fi
1577 dnl *** check whether we need preceeding underscores
1578         AC_CACHE_CHECK([for preceeding underscore in symbols],
1579                 glib_cv_uscore,[
1580                 AC_TRY_RUN([#include <dlfcn.h>
1581                 int glib_underscore_test (void) { return 42; }
1582                 int main() {
1583                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1584                   handle = dlopen ((void*)0, 0);
1585                   if (handle) {
1586                     f1 = dlsym (handle, "glib_underscore_test");
1587                     f2 = dlsym (handle, "_glib_underscore_test");
1588                   } return (!f2 || f1);
1589                 }],
1590                         [glib_cv_uscore=yes],
1591                         [glib_cv_uscore=no],
1592                         [])
1593                 rm -f plugin.c plugin.$ac_objext plugin.lo
1594         ])
1595         GLIB_ASSERT_SET(glib_cv_uscore)
1596         if test "x$glib_cv_uscore" = "xyes"; then
1597                 G_MODULE_NEED_USCORE=1
1598         else
1599                 G_MODULE_NEED_USCORE=0
1600         fi
1601
1602         LDFLAGS="$LDFLAGS_orig"
1603 dnl *** check for having dlerror()
1604         AC_CHECK_FUNC(dlerror,
1605                 [G_MODULE_HAVE_DLERROR=1],
1606                 [G_MODULE_HAVE_DLERROR=0])
1607         LIBS="$LIBS_orig"
1608 fi
1609 dnl *** done, have we got an implementation?
1610 if test -z "$G_MODULE_IMPL"; then
1611         G_MODULE_IMPL=0
1612         G_MODULE_SUPPORTED=false
1613 else
1614         G_MODULE_SUPPORTED=true
1615 fi
1616
1617 AC_MSG_CHECKING(for the suffix of module shared libraries)
1618 export SED
1619 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1620 eval $shrext_cmds
1621 module=yes eval std_shrext=$shrext_cmds
1622 # chop the initial dot
1623 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1624 AC_MSG_RESULT(.$glib_gmodule_suffix)
1625 # any reason it may fail?
1626 if test "x$glib_gmodule_suffix" = x; then
1627         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1628 fi
1629
1630 AC_SUBST(G_MODULE_SUPPORTED)
1631 AC_SUBST(G_MODULE_IMPL)
1632 AC_SUBST(G_MODULE_LIBS)
1633 AC_SUBST(G_MODULE_LIBS_EXTRA)
1634 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1635 AC_SUBST(G_MODULE_LDFLAGS)
1636 AC_SUBST(G_MODULE_HAVE_DLERROR)
1637 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1638 AC_SUBST(G_MODULE_NEED_USCORE)
1639 AC_SUBST(GLIB_DEBUG_FLAGS)
1640
1641 dnl **********************
1642 dnl *** g_spawn checks ***
1643 dnl **********************
1644
1645 AC_MSG_CHECKING(for gspawn implementation)
1646 case "$host" in
1647   *-*-mingw*)
1648     GSPAWN=gspawn-win32.lo
1649     ;;
1650   *)
1651     GSPAWN=gspawn.lo
1652     ;;
1653 esac
1654 AC_MSG_RESULT($GSPAWN)
1655 AC_SUBST(GSPAWN)
1656
1657 dnl *************************
1658 dnl *** GIOChannel checks ***
1659 dnl *************************
1660
1661 AC_MSG_CHECKING(for GIOChannel implementation)
1662 case "$host" in
1663   *-*-mingw*)
1664     GIO=giowin32.lo
1665     ;;
1666   *)
1667     GIO=giounix.lo
1668     ;;
1669 esac
1670 AC_MSG_RESULT($GIO)
1671 AC_SUBST(GIO)
1672
1673 dnl *********************************
1674 dnl *** Directory for GIO modules ***
1675 dnl *********************************
1676
1677 AC_ARG_WITH(gio-module-dir,
1678            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1679                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1680            [],
1681            [with_gio_module_dir='${libdir}/gio/modules'])
1682 GIO_MODULE_DIR=$with_gio_module_dir
1683 AC_SUBST(GIO_MODULE_DIR)
1684
1685 dnl **********************************
1686 dnl *** Check for libselinux (GIO) ***
1687 dnl **********************************
1688 AC_ARG_ENABLE(selinux,
1689               AC_HELP_STRING([--disable-selinux],
1690                              [build without selinux support]))
1691 msg_selinux=no
1692 SELINUX_LIBS=
1693 if test "x$enable_selinux" != "xno"; then
1694
1695  AC_CHECK_LIB(selinux, is_selinux_enabled,
1696    [AC_CHECK_HEADERS(selinux/selinux.h,
1697      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1698        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1699         SELINUX_LIBS="-lselinux"
1700         msg_selinux=yes])
1701      ])
1702    ])
1703 fi
1704 AC_SUBST(SELINUX_LIBS)
1705
1706 dnl *****************************
1707 dnl ** Check for inotify (GIO) **
1708 dnl *****************************
1709 inotify_support=no
1710 AC_CHECK_HEADERS([sys/inotify.h],
1711 [
1712         inotify_support=yes
1713         AC_CHECK_FUNCS(inotify_init1)
1714 ])
1715
1716 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1717
1718 dnl *********************************
1719 dnl ** Check for Solaris FEN (GIO) **
1720 dnl *********************************
1721 fen_support=no
1722 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1723 #include <port.h>
1724 #ifndef PORT_SOURCE_FILE
1725 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1726 #endif
1727 int main() { return 0; } ]])],
1728 [
1729         fen_support=yes
1730 ],)
1731
1732 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1733
1734 dnl ****************************
1735 dnl *** Checks for FAM (GIO) ***
1736 dnl ****************************
1737
1738 should_disable_fam=no
1739
1740 AC_ARG_ENABLE(fam,
1741               AC_HELP_STRING([--disable-fam],
1742                              [don't use fam for file system monitoring]),
1743                          [
1744                                 if test "x$enable_fam" = "xno"; then
1745                                         should_disable_fam=yes
1746                                 fi
1747                          ]
1748                          )
1749 fam_support=no
1750 FAM_LIBS=
1751 if test "x$should_disable_fam" = "xno"; then
1752 AC_CHECK_LIB(fam, FAMOpen,
1753   [AC_CHECK_HEADERS(fam.h,
1754     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1755      AC_CHECK_LIB(fam, FAMNoExists,
1756                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1757      FAM_LIBS="-lfam"]
1758      fam_support=yes,
1759     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1760   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1761 AC_SUBST(FAM_LIBS)
1762 fi
1763 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1764
1765
1766 dnl *****************************
1767 dnl *** Check for xattr (GIO) ***
1768 dnl *****************************
1769 AC_ARG_ENABLE(xattr,
1770               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1771 msg_xattr=no
1772 XATTR_LIBS=
1773 if test "x$enable_xattr" != "xno"; then
1774
1775 dnl either glibc or libattr can provide xattr support
1776
1777 dnl for both of them, we check for getxattr being in
1778 dnl the library and a valid xattr header.
1779
1780 dnl try glibc
1781  AC_CHECK_LIB(c, getxattr,
1782    [AC_CHECK_HEADERS(sys/xattr.h,
1783      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1784       msg_xattr=yes])
1785    ])
1786
1787   if test "x$msg_xattr" != "xyes"; then
1788 dnl   failure. try libattr
1789    AC_CHECK_LIB(attr, getxattr,
1790       [AC_CHECK_HEADERS(attr/xattr.h,
1791        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1792         XATTR_LIBS="-lattr"
1793         msg_xattr=yes])
1794       ])
1795   fi
1796
1797   if test "x$msg_xattr" = "xyes"; then
1798     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1799     AC_TRY_COMPILE([
1800       #include <stdio.h>
1801       #ifdef HAVE_SYS_TYPES_H
1802       #include <sys/types.h>
1803       #endif
1804       #ifdef HAVE_SYS_XATTR_H
1805       #include <sys/xattr.h>
1806       #elif HAVE_ATTR_XATTR_H
1807       #include <attr/xattr.h>
1808       #endif
1809     ],
1810     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1811     [
1812       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1813       AC_MSG_RESULT([yes])
1814     ],
1815     [AC_MSG_RESULT([no])]
1816     )
1817   fi
1818
1819 fi
1820 AC_SUBST(XATTR_LIBS)
1821
1822 dnl ****************************************
1823 dnl *** platform dependent source checks ***
1824 dnl ****************************************
1825
1826 AC_MSG_CHECKING(for platform-dependent source)
1827 case "$host" in
1828   *-*-cygwin*|*-*-mingw*)
1829     PLATFORMDEP=gwin32.lo
1830     ;;
1831   *)
1832     PLATFORMDEP=
1833     ;;
1834 esac
1835 AC_MSG_RESULT($PLATFORMDEP)
1836 AC_SUBST(PLATFORMDEP)
1837
1838 AC_MSG_CHECKING([whether to compile timeloop])
1839 case "$host" in
1840   *-*-cygwin*|*-*-mingw*|*-*-minix)
1841     enable_timeloop=no
1842     ;;
1843   *)
1844     enable_timeloop=yes
1845     ;;
1846 esac
1847 AC_MSG_RESULT($enable_timeloop)
1848 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1849
1850 AC_MSG_CHECKING([if building for some Win32 platform])
1851 case "$host" in
1852   *-*-mingw*|*-*-cygwin*)
1853     platform_win32=yes
1854     ;;
1855   *)
1856     platform_win32=no
1857     ;;
1858 esac
1859 AC_MSG_RESULT($platform_win32)
1860 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1861
1862 dnl ***********************
1863 dnl *** g_thread checks ***
1864 dnl ***********************
1865
1866 AC_ARG_WITH(threads,
1867            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1868                            [specify a thread implementation to use])],
1869            [if test "x$with_threads" = x; then
1870                 want_threads=yes
1871             else
1872                 want_threads=$with_threads
1873             fi],
1874            [want_threads=yes])
1875
1876 dnl error and warning message
1877 dnl *************************
1878
1879 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1880                 computer."
1881
1882 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1883                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1884                 compilation now, but then your programs might not work.
1885                 Please provide information on how it is done on your system."
1886
1887 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1888                 "
1889
1890 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1891                 provide information on your thread implementation."
1892
1893 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1894                 functions will not be MT-safe during their first call because
1895                 there is no working 'getpwuid_r' on your system."
1896
1897 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1898                 because there is no 'localtime_r' on your system."
1899
1900 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1901                 crude surrogate will be used. If you happen to know a
1902                 yield function for your system, please inform the GLib
1903                 developers."
1904
1905 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1906                 threads on your system. Thus threads can only have the default
1907                 priority. If you happen to know these main/max
1908                 priorities, please inform the GLib developers."
1909
1910 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1911                 linking threaded applications. As GLib cannot do that
1912                 automatically, you will get an linkg error everytime you are
1913                 not using the right compiler. In that case you have to relink
1914                 with the right compiler. Ususally just '_r' is appended
1915                 to the compiler name."
1916
1917 dnl determination of thread implementation
1918 dnl ***************************************
1919
1920 have_threads=no
1921 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1922                                 || test "x$want_threads" = xdce; then
1923         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1924         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1925         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1926         glib_save_CPPFLAGS="$CPPFLAGS"
1927         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1928         if test "x$have_threads" = xno; then
1929                 AC_TRY_COMPILE([#include <pthread.h>],
1930                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1931                         have_threads=posix)
1932         fi
1933         # Tru64Unix requires -pthread to find pthread.h. See #103020
1934         CPPFLAGS="$CPPFLAGS -pthread"
1935         if test "x$have_threads" = xno; then
1936         AC_TRY_COMPILE([#include <pthread.h>],
1937                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1938                        have_threads=posix)
1939         fi
1940         CPPFLAGS="$glib_save_CPPFLAGS"
1941 fi
1942 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1943         case $host in
1944                 *-*-mingw*)
1945                 have_threads=win32
1946                 ;;
1947         esac
1948 fi
1949
1950 AC_MSG_CHECKING(for thread implementation)
1951
1952 if test "x$have_threads" = xno; then
1953         AC_MSG_RESULT(none available)
1954         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1955 else
1956         AC_MSG_RESULT($have_threads)
1957 fi
1958
1959
1960 dnl determination of G_THREAD_CFLAGS
1961 dnl ********************************
1962
1963 G_THREAD_LIBS=
1964 G_THREAD_LIBS_EXTRA=
1965 G_THREAD_CFLAGS=
1966
1967 dnl
1968 dnl Test program for basic POSIX threads functionality
1969 dnl
1970 m4_define([glib_thread_test],[
1971 #include <pthread.h>
1972 int check_me = 0;
1973 void* func(void* data) {check_me = 42; return &check_me;}
1974 int main()
1975  { pthread_t t;
1976    void *ret;
1977    pthread_create (&t, $1, func, 0);
1978    pthread_join (t, &ret);
1979    return (check_me != 42 || ret != &check_me);
1980 }])
1981
1982 dnl
1983 dnl Test program for sched_get_priority_min()
1984 dnl
1985 m4_define([glib_sched_priority_test],[
1986 #include <sched.h>
1987 #include <errno.h>
1988 int main() {
1989     errno = 0;
1990     return sched_get_priority_min(SCHED_OTHER)==-1
1991            && errno != 0;
1992 }])
1993
1994 if test x"$have_threads" = xposix; then
1995   # First we test for posix, whether -pthread or -pthreads do the trick as
1996   # both CPPFLAG and LIBS.
1997   # One of them does for most gcc versions and some other platforms/compilers
1998   # too and could be considered as the canonical way to go.
1999   case $host in
2000     *-*-cygwin*|*-*-darwin*)
2001        # skip cygwin and darwin -pthread or -pthreads test
2002        ;;
2003     *-solaris*)
2004       # These compiler/linker flags work with both Sun Studio and gcc
2005       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2006       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2007       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2008       G_THREAD_LIBS="-lpthread -lthread"
2009       ;;
2010     *)
2011       for flag in pthread pthreads mt; do
2012         glib_save_CFLAGS="$CFLAGS"
2013         CFLAGS="$CFLAGS -$flag"
2014         AC_TRY_RUN(glib_thread_test(0),
2015                    glib_flag_works=yes,
2016                    glib_flag_works=no,
2017                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2018                                    glib_flag_works=yes,
2019                                    glib_flag_works=no)])
2020         CFLAGS="$glib_save_CFLAGS"
2021         if test $glib_flag_works = yes ; then
2022            G_THREAD_CFLAGS=-$flag
2023         G_THREAD_LIBS=-$flag
2024         break;
2025         fi
2026       done
2027        ;;
2028   esac
2029 fi
2030
2031 if test x"$G_THREAD_CFLAGS" = x; then
2032
2033   # The canonical -pthread[s] does not work. Try something different.
2034
2035   case $host in
2036         *-aix*)
2037                 if test x"$GCC" = xyes; then
2038                         # GCC 3.0 and above needs -pthread.
2039                         # Should be coverd by the case above.
2040                         # GCC 2.x and below needs -mthreads
2041                         G_THREAD_CFLAGS="-mthreads"
2042                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2043                 else
2044                         # We are probably using the aix compiler. Normaly a
2045                         # program would have to be compiled with the _r variant
2046                         # of the corresponding compiler, but we as GLib cannot
2047                         # do that: but the good news is that for compiling the
2048                         # only difference is the added -D_THREAD_SAFE compile
2049                         # option. This is according to the "C for AIX User's
2050                         # Guide".
2051                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2052                 fi
2053                 ;;
2054         *-dg-dgux*)  # DG/UX
2055                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2056                 ;;
2057         *-sysv5uw7*) # UnixWare 7
2058                 # We are not using gcc with -pthread. Catched above.
2059                 G_THREAD_CFLAGS="-Kthread"
2060                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2061                 ;;
2062         *-mingw*)
2063                 # No flag needed when using MSVCRT.DLL
2064                 G_THREAD_CFLAGS=""
2065                 ;;
2066         *)
2067                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2068                 ;;
2069   esac
2070
2071 fi
2072
2073 # if we are not finding the localtime_r function, then we probably are
2074 # not using the proper multithread flag
2075
2076 glib_save_CPPFLAGS="$CPPFLAGS"
2077 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2078
2079 # First we test, whether localtime_r is declared in time.h
2080 # directly. Then we test whether a macro localtime_r exists, in
2081 # which case localtime_r in the test program is replaced and thus
2082 # if we still find localtime_r in the output, it is not defined as
2083 # a macro.
2084
2085 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2086   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2087                                                            localtime_r(a,b)],
2088                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2089
2090 CPPFLAGS="$glib_save_CPPFLAGS"
2091
2092 AC_MSG_CHECKING(thread related cflags)
2093 AC_MSG_RESULT($G_THREAD_CFLAGS)
2094 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2095
2096 dnl determination of G_THREAD_LIBS
2097 dnl ******************************
2098
2099 case $have_threads in
2100         posix)
2101           glib_save_CPPFLAGS="$CPPFLAGS"
2102           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2103           if test x"$G_THREAD_LIBS" = x; then
2104             case $host in
2105               *-aix*)
2106                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2107                 # probably using the aix compiler.
2108                 AC_MSG_WARN($AIX_COMPILE_INFO)
2109                 ;;
2110               *)
2111                 G_THREAD_LIBS=error
2112                 glib_save_LIBS="$LIBS"
2113                 for thread_lib in "" pthread pthread32 pthreads thread; do
2114                         if test x"$thread_lib" = x; then
2115                                 add_thread_lib=""
2116                                 IN=""
2117                         else
2118                                 add_thread_lib="-l$thread_lib"
2119                                 IN=" in -l$thread_lib"
2120                         fi
2121                         if test x"$have_threads" = xposix; then
2122                                 defattr=0
2123                         else
2124                                 defattr=pthread_attr_default
2125                         fi
2126
2127                         LIBS="$add_thread_lib $glib_save_LIBS"
2128
2129                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2130                         AC_TRY_RUN(glib_thread_test($defattr),
2131                                    glib_result=yes,
2132                                    glib_result=no,
2133                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2134                                                    glib_result=yes,
2135                                                    glib_result=no)])
2136                         AC_MSG_RESULT($glib_result)
2137
2138                         if test "$glib_result" = "yes" ; then
2139                           G_THREAD_LIBS="$add_thread_lib"
2140                           break
2141                         fi
2142                 done
2143                 if test "x$G_THREAD_LIBS" = xerror; then
2144                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2145                 fi
2146                 LIBS="$glib_save_LIBS"
2147                 ;;
2148             esac
2149           fi
2150
2151           glib_save_LIBS="$LIBS"
2152           for thread_lib in "" rt rte; do
2153             if test x"$thread_lib" = x; then
2154               add_thread_lib=""
2155               IN=""
2156             else
2157               add_thread_lib="-l$thread_lib"
2158               IN=" in -l$thread_lib"
2159             fi
2160             LIBS="$add_thread_lib $glib_save_LIBS"
2161
2162             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2163             AC_TRY_RUN(glib_sched_priority_test,
2164                        glib_result=yes,
2165                        glib_result=no,
2166                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2167                                        glib_result=yes,
2168                                        glib_result=no)])
2169             AC_MSG_RESULT($glib_result)
2170
2171             if test "$glib_result" = "yes" ; then
2172                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2173                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2174                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2175                break
2176             fi
2177           done
2178           LIBS="$glib_save_LIBS"
2179           g_threads_impl="POSIX"
2180           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2181           CPPFLAGS="$glib_save_CPPFLAGS"
2182           ;;
2183         win32)
2184            g_threads_impl="WIN32"
2185            ;;
2186         *)
2187            g_threads_impl="NONE"
2188            G_THREAD_LIBS=error
2189            ;;
2190 esac
2191
2192 if test "x$G_THREAD_LIBS" = xerror; then
2193         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2194 fi
2195
2196 case $host in
2197   *-*-beos*)
2198     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2199     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2200     ;;
2201   *)
2202     ;;
2203 esac
2204
2205 AC_MSG_CHECKING(thread related libraries)
2206 AC_MSG_RESULT($G_THREAD_LIBS)
2207
2208 dnl check for mt safe function variants and some posix functions
2209 dnl ************************************************************
2210
2211 glib_save_LIBS="$LIBS"
2212 # we are not doing the following for now, as this might require glib
2213 # to always be linked with the thread libs on some platforms.
2214 # LIBS="$LIBS $G_THREAD_LIBS"
2215 AC_CHECK_FUNCS(localtime_r gmtime_r)
2216 if test "$ac_cv_header_pwd_h" = "yes"; then
2217         AC_CACHE_CHECK([for posix getpwuid_r],
2218                 ac_cv_func_posix_getpwuid_r,
2219                 [AC_TRY_RUN([
2220 #include <errno.h>
2221 #include <pwd.h>
2222 int main () {
2223     char buffer[10000];
2224     struct passwd pwd, *pwptr = &pwd;
2225     int error;
2226     errno = 0;
2227     error = getpwuid_r (0, &pwd, buffer,
2228                         sizeof (buffer), &pwptr);
2229    return (error < 0 && errno == ENOSYS)
2230            || error == ENOSYS;
2231 }                               ],
2232                         [ac_cv_func_posix_getpwuid_r=yes],
2233                         [ac_cv_func_posix_getpwuid_r=no])])
2234         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2235         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2236                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2237                         [Have POSIX function getpwuid_r])
2238         else
2239                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2240                         ac_cv_func_nonposix_getpwuid_r,
2241                         [AC_TRY_LINK([#include <pwd.h>],
2242                                 [char buffer[10000];
2243                                 struct passwd pwd;
2244                                 getpwuid_r (0, &pwd, buffer,
2245                                                 sizeof (buffer));],
2246                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2247                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2248                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2249                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2250                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2251                                 [Have non-POSIX function getpwuid_r])
2252                 fi
2253         fi
2254 fi
2255 if test "$ac_cv_header_grp_h" = "yes"; then
2256         AC_CACHE_CHECK([for posix getgrgid_r],
2257                 ac_cv_func_posix_getgrgid_r,
2258                 [AC_TRY_RUN([
2259 #include <errno.h>
2260 #include <grp.h>
2261 int main () {
2262     char buffer[10000];
2263     struct group grp, *grpptr = &grp;
2264     int error;
2265     errno = 0;
2266     error = getgrgid_r (0, &grp, buffer,
2267                         sizeof (buffer), &grpptr);
2268    return (error < 0 && errno == ENOSYS)
2269            || error == ENOSYS;
2270 }                              ],
2271                        [ac_cv_func_posix_getgrgid_r=yes],
2272                        [ac_cv_func_posix_getgrgid_r=no])])
2273         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2274         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2275                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2276                         [Have POSIX function getgrgid_r])
2277         else
2278                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2279                         ac_cv_func_nonposix_getgrgid_r,
2280                         [AC_TRY_LINK([#include <grp.h>],
2281                                 [char buffer[10000];
2282                                 struct group grp;
2283                                 getgrgid_r (0, &grp, buffer,
2284                                 sizeof (buffer));],
2285                         [ac_cv_func_nonposix_getgrgid_r=yes],
2286                         [ac_cv_func_nonposix_getgrgid_r=no])])
2287                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2288                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2289                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2290                                 [Have non-POSIX function getgrgid_r])
2291                 fi
2292         fi
2293 fi
2294 LIBS="$G_THREAD_LIBS $LIBS"
2295 if test x"$have_threads" = xposix; then
2296         glib_save_CPPFLAGS="$CPPFLAGS"
2297         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2298         dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2299         GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2300         # This is not AC_CHECK_FUNC to also work with function
2301         # name mangling in header files.
2302         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2303         AC_TRY_LINK([#include <pthread.h>],
2304                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2305                 [AC_MSG_RESULT(yes)
2306                 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2307                           [Have function pthread_attr_setstacksize])],
2308                 [AC_MSG_RESULT(no)])
2309         AC_MSG_CHECKING(for minimal/maximal thread priority)
2310         if test x"$posix_priority_min" = x; then
2311                 AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2312                         PX_PRIO_MIN],,[
2313                         posix_priority_min=PX_PRIO_MIN
2314                         posix_priority_max=PX_PRIO_MAX])
2315         fi
2316         if test x"$posix_priority_min" = x; then
2317                 # AIX
2318                 AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2319                         PTHREAD_PRIO_MIN],,[
2320                         posix_priority_min=PTHREAD_PRIO_MIN
2321                         posix_priority_max=PTHREAD_PRIO_MAX])
2322         fi
2323         if test x"$posix_priority_min" = x; then
2324                 AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2325                         PRI_OTHER_MIN],,[
2326                         posix_priority_min=PRI_OTHER_MIN
2327                         posix_priority_max=PRI_OTHER_MAX])
2328         fi
2329         if test x"$posix_priority_min" = x; then
2330                 AC_MSG_RESULT(none found)
2331                 AC_MSG_WARN($POSIX_NO_PRIORITIES)
2332                 posix_priority_min=-1
2333                 posix_priority_max=-1
2334         else
2335                 AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2336                 AC_MSG_CHECKING(for pthread_setschedparam)
2337                 AC_TRY_LINK([#include <pthread.h>],
2338                   [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2339                   [AC_MSG_RESULT(yes)
2340                 AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2341                    AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2342                   [AC_MSG_RESULT(no)
2343                    AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2344         fi
2345         posix_yield_func=none
2346         AC_MSG_CHECKING(for posix yield function)
2347         for yield_func in sched_yield pthread_yield_np pthread_yield \
2348                                                 thr_yield; do
2349                 AC_TRY_LINK([#include <pthread.h>],
2350                         [$yield_func()],
2351                         [posix_yield_func="$yield_func"
2352                         break])
2353         done
2354         if test x"$posix_yield_func" = xnone; then
2355                 AC_MSG_RESULT(none found)
2356                 AC_MSG_WARN($POSIX_NO_YIELD)
2357                 posix_yield_func="g_usleep(1000)"
2358         else
2359                 AC_MSG_RESULT($posix_yield_func)
2360                 posix_yield_func="$posix_yield_func()"
2361         fi
2362         AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2363         CPPFLAGS="$glib_save_CPPFLAGS"
2364
2365 elif test x"$have_threads" = xwin32; then
2366         # It's a pointer to a private struct
2367         GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2368 fi
2369
2370 LIBS="$glib_save_LIBS"
2371
2372 # now spit out all the warnings.
2373 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2374    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2375         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2376 fi
2377 if test "$ac_cv_func_localtime_r" != "yes"; then
2378         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2379 fi
2380
2381 if test x"$glib_cv_sizeof_system_thread" = x; then
2382    # use a pointer as a fallback.
2383    GLIB_SIZEOF(,void *, system_thread)
2384 fi
2385
2386 #
2387 # Hack to deal with:
2388 #
2389 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2390 #     building shared libraries with linux.
2391 #  b) FreeBSD doesn't do this either.
2392 #
2393 case $host in
2394   *-*-freebsd*|*-*-linux*)
2395     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2396     ;;
2397   *-*-openbsd*)
2398     LDFLAGS="$LDFLAGS -pthread"
2399     ;;
2400   *)
2401     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2402     ;;
2403 esac
2404
2405 AC_SUBST(G_THREAD_CFLAGS)
2406 AC_SUBST(G_THREAD_LIBS)
2407 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2408 AC_SUBST(G_THREAD_LIBS_EXTRA)
2409
2410 AC_CHECK_FUNCS(clock_gettime, [], [
2411   AC_CHECK_LIB(rt, clock_gettime, [
2412     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2413     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2414     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2415     GLIB_RT_LIBS="-lrt"
2416   ])
2417 ])
2418 AC_SUBST(GLIB_RT_LIBS)
2419
2420
2421 dnl ************************
2422 dnl *** g_atomic_* tests ***
2423 dnl ************************
2424
2425 dnl We need to decide at configure time if GLib will use real atomic
2426 dnl operations ("lock free") or emulated ones with a mutex.  This is
2427 dnl because we must put this information in glibconfig.h so we know if
2428 dnl it is safe or not to inline using compiler intrinsics directly from
2429 dnl the header.
2430 dnl
2431 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2432 dnl user is interested in knowing if they can use the atomic ops across
2433 dnl processes.
2434 dnl
2435 dnl We can currently support the atomic ops natively when building GLib
2436 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2437 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2438 dnl we are using GCC.
2439 dnl
2440 dnl Note that the atomic ops are only available with GCC on x86 when
2441 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2442 dnl not available but would be available given the right flags, we want
2443 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2444 dnl that then to silently fall back on emulated atomic ops just because
2445 dnl the user had the wrong build environment.
2446
2447 dnl We may add other compilers here in the future...
2448 AC_MSG_CHECKING([for lock-free atomic intrinsics])
2449 AC_TRY_COMPILE([],
2450                [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2451                [glib_cv_g_atomic_lock_free=yes],
2452                [glib_cv_g_atomic_lock_free=no])
2453 AC_MSG_RESULT($glib_cv_g_atomic_lock_free)
2454
2455 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2456   SAVE_CFLAGS="${CFLAGS}"
2457   CFLAGS="-march=i486"
2458   AC_TRY_COMPILE([],
2459                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2460                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2461                  [])
2462   CFLAGS="${SAVE_CFLAGS}"
2463 fi
2464
2465 dnl We need a more robust approach here...
2466 case $host_cpu in
2467   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2468     glib_memory_barrier_needed=no
2469     ;;
2470   sparc*|alpha*|powerpc*|ia64)
2471     glib_memory_barrier_needed=yes
2472     ;;
2473   *)
2474     glib_memory_barrier_needed=yes
2475     ;;
2476 esac
2477
2478 dnl ************************
2479 dnl ** Check for futex(2) **
2480 dnl ************************
2481 AC_CACHE_CHECK(for futex(2) system call,
2482     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2483 #include <linux/futex.h>
2484 #include <sys/syscall.h>
2485 #include <unistd.h>
2486 ],[
2487 int
2488 main (void)
2489 {
2490   /* it is not like this actually runs or anything... */
2491   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2492   return 0;
2493 }
2494 ])],glib_cv_futex=yes,glib_cv_futex=no))
2495 if test x"$glib_cv_futex" = xyes; then
2496   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2497 fi
2498
2499 AC_CACHE_CHECK(for eventfd(2) system call,
2500     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2501 #include <sys/eventfd.h>
2502 #include <unistd.h>
2503 ],[
2504 int
2505 main (void)
2506 {
2507   eventfd (0, EFD_CLOEXEC);
2508   return 0;
2509 }
2510 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2511 if test x"$glib_cv_eventfd" = x"yes"; then
2512   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2513 fi
2514 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2515
2516 dnl ****************************************
2517 dnl *** GLib POLL* compatibility defines ***
2518 dnl ****************************************
2519
2520 glib_poll_includes=["
2521 #include <sys/types.h>
2522 #include <sys/poll.h>
2523 "]
2524
2525 if test $ac_cv_header_sys_types_h = yes &&
2526    test $ac_cv_header_sys_poll_h = yes ; then
2527   glib_failed=false
2528   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2529   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2530   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2531   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2532   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2533   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2534   if $glib_failed ; then
2535     AC_MSG_ERROR([Could not determine values for POLL* constants])
2536   fi
2537 else
2538   glib_cv_value_POLLIN=1
2539   glib_cv_value_POLLOUT=4
2540   glib_cv_value_POLLPRI=2
2541   glib_cv_value_POLLERR=8
2542   glib_cv_value_POLLHUP=16
2543   glib_cv_value_POLLNVAL=32
2544 fi
2545
2546 AC_MSG_CHECKING([for broken poll])
2547 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2548         #include <stdlib.h>
2549         #include <fcntl.h>
2550         #include <poll.h>
2551         #ifdef HAVE_SYS_POLL_H
2552         #include <sys/poll.h>
2553         #endif
2554         int main(void) {
2555           struct pollfd fds[1];
2556           int fd;
2557           fd = open("/dev/null", 1);
2558           fds[0].fd = fd;
2559           fds[0].events = POLLIN;
2560           fds[0].revents = 0;
2561           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2562                 exit(1);  /* Does not work for devices -- fail */
2563           }
2564           exit(0);
2565         }]])],
2566   [broken_poll=no],
2567   [broken_poll=yes
2568    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2569   [broken_poll="no (cross compiling)"])
2570 AC_MSG_RESULT($broken_poll)
2571
2572 dnl *********************
2573 dnl *** GRegex checks ***
2574 dnl *********************
2575 PCRE_REQUIRED_VERSION=8.11
2576
2577 # Check if we should compile GRegex
2578 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2579                                     [disable the compilation of GRegex]),
2580 [case "${enableval}" in
2581   yes) enable_regex=true ;;
2582   no)  enable_regex=false ;;
2583   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2584 esac],
2585 [enable_regex=true])
2586
2587 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2588
2589 if test x$enable_regex = xtrue; then
2590   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2591   # Check if we should use the internal or the system-supplied pcre
2592   AC_ARG_WITH(pcre,
2593              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2594                              [whether to use system PCRE [default=internal]])])
2595
2596   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2597
2598   if test "x$with_pcre" = xsystem; then
2599     PKG_CHECK_MODULES(PCRE,
2600                       libpcre >= $PCRE_REQUIRED_VERSION)
2601     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2602                    glib_save_CFLAGS="$CFLAGS"
2603                    glib_save_LIBS="$LIBS"
2604                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2605                    AC_TRY_RUN([#include <pcre.h>
2606                                int main () {
2607                                  int support;
2608                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2609                                  if (!support)
2610                                    return 1;
2611                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2612                                  if (!support)
2613                                    return 1;
2614                                  return 0;
2615                                }],
2616                    glib_cv_pcre_has_unicode=yes,
2617                    glib_cv_pcre_has_unicode=no,
2618                    glib_cv_pcre_has_unicode=yes)
2619                    CFLAGS="$glib_save_CFLAGS"
2620                    LIBS="$glib_save_LIBS"
2621         ])
2622     if test "$glib_cv_pcre_has_unicode" = "no"; then
2623       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2624     fi
2625     AC_SUBST(PCRE_CFLAGS)
2626     AC_SUBST(PCRE_LIBS)
2627     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2628     PCRE_REQUIRES=libpcre
2629     AC_SUBST(PCRE_REQUIRES)
2630   else
2631     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2632     if test x"$GCC" = xyes; then
2633       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2634       save_CFLAGS="$CFLAGS"
2635       CFLAGS="$CFLAGS -Wno-pointer-sign"
2636       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2637                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2638       CFLAGS="$save_CFLAGS"
2639     fi
2640   fi
2641   AC_SUBST(PCRE_WARN_CFLAGS)
2642 else
2643   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2644 fi
2645
2646 dnl **********************
2647 dnl *** Win32 API libs ***
2648 dnl **********************
2649
2650 case $host in
2651   *-*-cygwin*)
2652         G_LIBS_EXTRA="-luser32 -lkernel32"
2653     ;;
2654   *-*-mingw*)
2655         G_LIBS_EXTRA="-lws2_32 -lole32"
2656     ;;
2657   *)
2658         G_LIBS_EXTRA=""
2659     ;;
2660 esac
2661 AC_SUBST(G_LIBS_EXTRA)
2662
2663 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2664 dnl since we need it for g_iconv()
2665
2666 AC_MSG_CHECKING([for EILSEQ])
2667 AC_TRY_COMPILE([
2668 #include <errno.h>
2669 ],
2670 [
2671 int error = EILSEQ;
2672 ], have_eilseq=yes, have_eilseq=no);
2673 AC_MSG_RESULT($have_eilseq)
2674
2675 dnl ******************************************************************
2676 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2677 dnl *** glib-compile-schemas in PATH                               ***
2678 dnl ******************************************************************
2679
2680 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2681
2682 if test $cross_compiling = yes; then
2683   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2684   if test x$GLIB_GENMARSHAL = xno; then
2685     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2686   fi
2687
2688   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2689   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2690     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2691   fi
2692 fi
2693
2694 dnl **************************
2695 dnl *** Checks for gtk-doc ***
2696 dnl **************************
2697
2698 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2699
2700 AC_ARG_ENABLE(man,
2701               [AC_HELP_STRING([--enable-man],
2702                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2703               enable_man=no)
2704
2705 if test "${enable_man}" != no; then
2706 dnl
2707 dnl Check for xsltproc
2708 dnl
2709 AC_PATH_PROG([XSLTPROC], [xsltproc])
2710   if test -z "$XSLTPROC"; then
2711     enable_man=no
2712   fi
2713
2714   dnl check for DocBook DTD and stylesheets in the local catalog.
2715   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2716      [DocBook XML DTD V4.1.2],,enable_man=no)
2717   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2718      [DocBook XSL Stylesheets],,enable_man=no)
2719 fi
2720
2721 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2722
2723 dnl
2724 dnl Tracing
2725 dnl
2726
2727 AC_ARG_ENABLE([dtrace],
2728              [AS_HELP_STRING([--enable-dtrace],
2729                               [include tracing support for dtrace])])
2730 have_dtrace=no
2731 AC_MSG_CHECKING([whether to include dtrace tracing support])
2732 if test "x$enable_dtrace" != xno; then
2733   if test x$glib_have_carbon = xyes; then
2734     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2735   else
2736     AC_MSG_RESULT([yes])
2737     AC_CHECK_PROGS(DTRACE, dtrace)
2738     if test -z "$DTRACE"; then
2739       if test "x$enable_dtrace" = xyes; then
2740         AC_MSG_ERROR([dtrace not found])
2741       fi
2742     else
2743       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2744                       [if test "x$enable_dtrace" = xyes; then
2745                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2746                        fi])
2747     fi
2748   fi
2749 else
2750   AC_MSG_RESULT([no])
2751 fi
2752 if test "x$have_dtrace" = xyes; then
2753   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2754 fi
2755 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2756
2757 AC_MSG_CHECKING([whether to include systemtap tracing support])
2758 AC_ARG_ENABLE([systemtap],
2759              [AS_HELP_STRING([--enable-systemtap],
2760                               [include tracing support for systemtap])])
2761 have_systemtap=no
2762 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2763   have_systemtap=yes
2764 fi
2765 AC_MSG_RESULT(${have_systemtap})
2766
2767 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2768
2769 AC_ARG_WITH([tapset-install-dir],
2770             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2771                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2772             [if test "x${withval}" = x; then
2773                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2774              else
2775                ABS_TAPSET_DIR="${withval}"
2776               fi],
2777             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2778 AC_SUBST(ABS_TAPSET_DIR)
2779
2780 dnl ************************************
2781 dnl *** Enable lcov coverage reports ***
2782 dnl ************************************
2783
2784 AC_ARG_ENABLE(gcov,
2785   AS_HELP_STRING([--enable-gcov],
2786                  [enable coverage testing with gcov]),
2787   [use_gcov=$enableval], [use_gcov=no])
2788
2789 if test "x$use_gcov" = "xyes"; then
2790   dnl we need gcc:
2791   if test "$GCC" != "yes"; then
2792     AC_MSG_ERROR([GCC is required for --enable-gcov])
2793   fi
2794
2795   dnl Check if ccache is being used
2796   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2797   case `$SHTOOL path $CC` in
2798     *ccache*[)] gcc_ccache=yes;;
2799     *[)] gcc_ccache=no;;
2800   esac
2801
2802   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2803     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2804   fi
2805
2806   ltp_version_list="1.6 1.7 1.8 1.9"
2807   AC_CHECK_PROG(LTP, lcov, lcov)
2808   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2809
2810   if test "$LTP"; then
2811     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2812       glib_cv_ltp_version=invalid
2813       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2814       for ltp_check_version in $ltp_version_list; do
2815         if test "$ltp_version" = "$ltp_check_version"; then
2816           glib_cv_ltp_version="$ltp_check_version (ok)"
2817         fi
2818       done
2819     ])
2820   else
2821     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2822     AC_MSG_ERROR([$ltp_msg])
2823   fi
2824
2825   case $glib_cv_ltp_version in
2826     ""|invalid[)]
2827       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2828       AC_MSG_ERROR([$ltp_msg])
2829       LTP="exit 0;"
2830       ;;
2831   esac
2832
2833   if test -z "$LTP_GENHTML"; then
2834     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2835   fi
2836
2837   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2838
2839   dnl Remove all optimization flags from CFLAGS
2840   changequote({,})
2841   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2842   changequote([,])
2843
2844   dnl Add the special gcc flags
2845   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2846   LDFLAGS="$LDFLAGS -lgcov"
2847 fi
2848
2849 dnl ******************************
2850 dnl *** output the whole stuff ***
2851 dnl ******************************
2852
2853 dnl this section will only be run if config.status is invoked with no
2854 dnl arguments, or with "glib/glibconfig.h" as an argument.
2855 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2856 [
2857         outfile=glib/glibconfig.h-tmp
2858         cat > $outfile <<\_______EOF
2859 /* glibconfig.h
2860  *
2861  * This is a generated file.  Please modify 'configure.ac'
2862  */
2863
2864 #ifndef __G_LIBCONFIG_H__
2865 #define __G_LIBCONFIG_H__
2866
2867 #include <glib/gmacros.h>
2868
2869 _______EOF
2870
2871         if test x$glib_limits_h = xyes; then
2872           echo '#include <limits.h>' >> $outfile
2873         fi
2874         if test x$glib_float_h = xyes; then
2875           echo '#include <float.h>' >> $outfile
2876         fi
2877         if test x$glib_values_h = xyes; then
2878           echo '#include <values.h>' >> $outfile
2879         fi
2880         if test "$glib_header_alloca_h" = "yes"; then
2881           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2882         fi
2883         if test x$glib_sys_poll_h = xyes; then
2884           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2885         fi
2886         if test x$glib_included_printf != xyes; then
2887           echo "
2888 /* Specifies that GLib's g_print*() functions wrap the
2889  * system printf functions.  This is useful to know, for example,
2890  * when using glibc's register_printf_function().
2891  */" >> $outfile
2892           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2893         fi
2894
2895         cat >> $outfile <<_______EOF
2896
2897 G_BEGIN_DECLS
2898
2899 #define G_MINFLOAT      $glib_mf
2900 #define G_MAXFLOAT      $glib_Mf
2901 #define G_MINDOUBLE     $glib_md
2902 #define G_MAXDOUBLE     $glib_Md
2903 #define G_MINSHORT      $glib_ms
2904 #define G_MAXSHORT      $glib_Ms
2905 #define G_MAXUSHORT     $glib_Mus
2906 #define G_MININT        $glib_mi
2907 #define G_MAXINT        $glib_Mi
2908 #define G_MAXUINT       $glib_Mui
2909 #define G_MINLONG       $glib_ml
2910 #define G_MAXLONG       $glib_Ml
2911 #define G_MAXULONG      $glib_Mul
2912
2913 _______EOF
2914
2915
2916         ### this should always be true in a modern C/C++ compiler
2917         cat >>$outfile <<_______EOF
2918 typedef signed char gint8;
2919 typedef unsigned char guint8;
2920 _______EOF
2921
2922
2923         if test -n "$gint16"; then
2924           cat >>$outfile <<_______EOF
2925 typedef signed $gint16 gint16;
2926 typedef unsigned $gint16 guint16;
2927 #define G_GINT16_MODIFIER $gint16_modifier
2928 #define G_GINT16_FORMAT $gint16_format
2929 #define G_GUINT16_FORMAT $guint16_format
2930 _______EOF
2931         fi
2932
2933
2934         if test -n "$gint32"; then
2935           cat >>$outfile <<_______EOF
2936 typedef signed $gint32 gint32;
2937 typedef unsigned $gint32 guint32;
2938 #define G_GINT32_MODIFIER $gint32_modifier
2939 #define G_GINT32_FORMAT $gint32_format
2940 #define G_GUINT32_FORMAT $guint32_format
2941 _______EOF
2942         fi
2943
2944         cat >>$outfile <<_______EOF
2945 #define G_HAVE_GINT64 1          /* deprecated, always true */
2946
2947 ${glib_extension}typedef signed $gint64 gint64;
2948 ${glib_extension}typedef unsigned $gint64 guint64;
2949
2950 #define G_GINT64_CONSTANT(val)  $gint64_constant
2951 #define G_GUINT64_CONSTANT(val) $guint64_constant
2952 _______EOF
2953
2954         if test x$gint64_format != x ; then
2955           cat >>$outfile <<_______EOF
2956 #define G_GINT64_MODIFIER $gint64_modifier
2957 #define G_GINT64_FORMAT $gint64_format
2958 #define G_GUINT64_FORMAT $guint64_format
2959 _______EOF
2960         else
2961           cat >>$outfile <<_______EOF
2962 #undef G_GINT64_MODIFIER
2963 #undef G_GINT64_FORMAT
2964 #undef G_GUINT64_FORMAT
2965 _______EOF
2966         fi
2967
2968         cat >>$outfile <<_______EOF
2969
2970 #define GLIB_SIZEOF_VOID_P $glib_void_p
2971 #define GLIB_SIZEOF_LONG   $glib_long
2972 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2973
2974 _______EOF
2975
2976         cat >>$outfile <<_______EOF
2977 typedef signed $glib_size_type_define gssize;
2978 typedef unsigned $glib_size_type_define gsize;
2979 #define G_GSIZE_MODIFIER $gsize_modifier
2980 #define G_GSSIZE_FORMAT $gssize_format
2981 #define G_GSIZE_FORMAT $gsize_format
2982
2983 #define G_MAXSIZE       G_MAXU$glib_msize_type
2984 #define G_MINSSIZE      G_MIN$glib_msize_type
2985 #define G_MAXSSIZE      G_MAX$glib_msize_type
2986
2987 typedef gint64 goffset;
2988 #define G_MINOFFSET     G_MININT64
2989 #define G_MAXOFFSET     G_MAXINT64
2990
2991 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2992 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2993 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2994
2995 _______EOF
2996
2997         if test -z "$glib_unknown_void_p"; then
2998           cat >>$outfile <<_______EOF
2999
3000 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3001 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3002
3003 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3004 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3005
3006 typedef signed $glib_intptr_type_define gintptr;
3007 typedef unsigned $glib_intptr_type_define guintptr;
3008
3009 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3010 #define G_GINTPTR_FORMAT        $gintptr_format
3011 #define G_GUINTPTR_FORMAT       $guintptr_format
3012 _______EOF
3013         else
3014           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3015         fi
3016
3017
3018
3019         cat >>$outfile <<_______EOF
3020 $glib_atexit
3021 $glib_memmove
3022 $glib_defines
3023 $glib_os
3024 $glib_static_compilation
3025
3026 $glib_vacopy
3027
3028 #ifdef  __cplusplus
3029 #define G_HAVE_INLINE   1
3030 #else   /* !__cplusplus */
3031 $glib_inline
3032 #endif  /* !__cplusplus */
3033
3034 #ifdef  __cplusplus
3035 #define G_CAN_INLINE    1
3036 _______EOF
3037
3038         if test x$g_can_inline = xyes ; then
3039                 cat >>$outfile <<_______EOF
3040 #else   /* !__cplusplus */
3041 #define G_CAN_INLINE    1
3042 _______EOF
3043         fi
3044
3045         cat >>$outfile <<_______EOF
3046 #endif
3047
3048 _______EOF
3049
3050         if test x$g_have_iso_c_varargs = xyes ; then
3051                 cat >>$outfile <<_______EOF
3052 #ifndef __cplusplus
3053 # define G_HAVE_ISO_VARARGS 1
3054 #endif
3055 _______EOF
3056         fi
3057         if test x$g_have_iso_cxx_varargs = xyes ; then
3058                 cat >>$outfile <<_______EOF
3059 #ifdef __cplusplus
3060 # define G_HAVE_ISO_VARARGS 1
3061 #endif
3062 _______EOF
3063         fi
3064         if test x$g_have_gnuc_varargs = xyes ; then
3065                 cat >>$outfile <<_______EOF
3066
3067 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3068  * is passed ISO vararg support is turned off, and there is no work
3069  * around to turn it on, so we unconditionally turn it off.
3070  */
3071 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3072 #  undef G_HAVE_ISO_VARARGS
3073 #endif
3074
3075 #define G_HAVE_GNUC_VARARGS 1
3076 _______EOF
3077         fi
3078
3079         case x$g_stack_grows in
3080         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3081         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3082         esac
3083
3084
3085         echo >>$outfile
3086         if test x$g_have_eilseq = xno; then
3087                 cat >>$outfile <<_______EOF
3088 #ifndef EILSEQ
3089 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3090  * The correspondence between this and the corresponding definition
3091  * in libiconv is essential.
3092  */
3093 #  define EILSEQ ENOENT
3094 #endif
3095 _______EOF
3096
3097         fi
3098
3099         if test x$g_have_gnuc_visibility = xyes; then
3100                 cat >>$outfile <<_______EOF
3101 #define G_HAVE_GNUC_VISIBILITY 1
3102 _______EOF
3103         fi
3104                 cat >>$outfile <<_______EOF
3105 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3106 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3107 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3108 #define G_GNUC_INTERNAL __hidden
3109 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3110 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3111 #else
3112 #define G_GNUC_INTERNAL
3113 #endif
3114 _______EOF
3115
3116         echo >>$outfile
3117         cat >>$outfile <<_______EOF
3118 #define G_THREADS_ENABLED
3119 #define G_THREADS_IMPL_$g_threads_impl_def
3120 _______EOF
3121
3122         if test x"$g_memory_barrier_needed" != xno; then
3123           echo >>$outfile
3124           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3125         fi
3126         if test x"$g_atomic_lock_free" = xyes; then
3127           echo >>$outfile
3128           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3129         fi
3130         echo >>$outfile
3131         g_bit_sizes="16 32 64"
3132         for bits in $g_bit_sizes; do
3133           cat >>$outfile <<_______EOF
3134 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3135 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3136 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3137 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3138 _______EOF
3139         done
3140
3141         cat >>$outfile <<_______EOF
3142 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3143 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3144 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3145 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3146 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3147 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3148 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3149 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3150 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3151 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3152 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3153 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3154 #define G_BYTE_ORDER $g_byte_order
3155
3156 #define GLIB_SYSDEF_POLLIN =$g_pollin
3157 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3158 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3159 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3160 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3161 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3162
3163 #define G_MODULE_SUFFIX "$g_module_suffix"
3164
3165 /* A GPid is an abstraction for a process "handle". It is *not* an
3166  * abstraction for a process identifier in general. GPid is used in
3167  * GLib only for descendant processes spawned with the g_spawn*
3168  * functions. On POSIX there is no "process handle" concept as such,
3169  * but on Windows a GPid is a handle to a process, a kind of pointer,
3170  * not a process identifier.
3171  */
3172 typedef $g_pid_type GPid;
3173
3174 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3175 #define GLIB_SYSDEF_AF_INET $g_af_inet
3176 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3177
3178 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3179 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3180 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3181
3182 G_END_DECLS
3183
3184 #endif /* GLIBCONFIG_H */
3185 _______EOF
3186
3187
3188         if cmp -s $outfile glib/glibconfig.h; then
3189           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3190           rm -f $outfile
3191         else
3192           mv $outfile glib/glibconfig.h
3193         fi
3194 ],[
3195
3196 # Note that if two cases are the same, case goes with the first one.
3197 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3198 # on variable expansion in case labels.  Look at the generated config.status
3199 # for a hint.
3200
3201 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3202   glib_header_alloca_h="$ac_cv_working_alloca_h"
3203 else
3204   glib_header_alloca_h="$ac_cv_header_alloca_h"
3205 fi
3206
3207 case xyes in
3208 x$ac_cv_header_float_h)
3209   glib_float_h=yes
3210   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3211   glib_md=DBL_MIN glib_Md=DBL_MAX
3212   ;;
3213 x$ac_cv_header_values_h)
3214   glib_values_h=yes
3215   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3216   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3217   ;;
3218 esac
3219
3220 case xyes in
3221 x$ac_cv_header_limits_h)
3222   glib_limits_h=yes
3223   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3224   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3225   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3226   ;;
3227 x$ac_cv_header_values_h)
3228   glib_values_h=yes
3229   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3230   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3231   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3232   ;;
3233 esac
3234
3235 if test x$ac_cv_header_sys_poll_h = xyes ; then
3236   glib_sys_poll_h=yes
3237 fi
3238
3239 if test x$enable_included_printf = xyes ; then
3240   glib_included_printf=yes
3241 fi
3242
3243 case 2 in
3244 $ac_cv_sizeof_short)
3245   gint16=short
3246   gint16_modifier='"h"'
3247   gint16_format='"hi"'
3248   guint16_format='"hu"'
3249   ;;
3250 $ac_cv_sizeof_int)
3251   gint16=int
3252   gint16_modifier='""'
3253   gint16_format='"i"'
3254   guint16_format='"u"'
3255   ;;
3256 esac
3257 case 4 in
3258 $ac_cv_sizeof_short)
3259   gint32=short
3260   gint32_modifier='"h"'
3261   gint32_format='"hi"'
3262   guint32_format='"hu"'
3263   ;;
3264 $ac_cv_sizeof_int)
3265   gint32=int
3266   gint32_modifier='""'
3267   gint32_format='"i"'
3268   guint32_format='"u"'
3269   ;;
3270 $ac_cv_sizeof_long)
3271   gint32=long
3272   gint32_modifier='"l"'
3273   gint32_format='"li"'
3274   guint32_format='"lu"'
3275   ;;
3276 esac
3277 case 8 in
3278 $ac_cv_sizeof_int)
3279   gint64=int
3280   gint64_modifier='""'
3281   gint64_format='"i"'
3282   guint64_format='"u"'
3283   glib_extension=
3284   gint64_constant='(val)'
3285   guint64_constant='(val)'
3286   ;;
3287 $ac_cv_sizeof_long)
3288   gint64=long
3289   gint64_modifier='"l"'
3290   gint64_format='"li"'
3291   guint64_format='"lu"'
3292   glib_extension=
3293   gint64_constant='(val##L)'
3294   guint64_constant='(val##UL)'
3295   ;;
3296 $ac_cv_sizeof_long_long)
3297   gint64='long long'
3298   if test -n "$glib_cv_long_long_format"; then
3299     gint64_modifier='"'$glib_cv_long_long_format'"'
3300     gint64_format='"'$glib_cv_long_long_format'i"'
3301     guint64_format='"'$glib_cv_long_long_format'u"'
3302   fi
3303   glib_extension='G_GNUC_EXTENSION '
3304   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3305   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3306   ;;
3307 $ac_cv_sizeof___int64)
3308   gint64='__int64'
3309   if test -n "$glib_cv_long_long_format"; then
3310     gint64_modifier='"'$glib_cv_long_long_format'"'
3311     gint64_format='"'$glib_cv_long_long_format'i"'
3312     guint64_format='"'$glib_cv_long_long_format'u"'
3313   fi
3314   glib_extension=
3315   gint64_constant='(val##i64)'
3316   guint64_constant='(val##ui64)'
3317   ;;
3318 esac
3319 glib_size_t=$ac_cv_sizeof_size_t
3320 glib_size_type_define="$glib_size_type"
3321 glib_void_p=$ac_cv_sizeof_void_p
3322 glib_long=$ac_cv_sizeof_long
3323
3324 case "$glib_size_type" in
3325 short)
3326   gsize_modifier='"h"'
3327   gsize_format='"hu"'
3328   gssize_format='"hi"'
3329   glib_msize_type='SHRT'
3330   ;;
3331 int)
3332   gsize_modifier='""'
3333   gsize_format='"u"'
3334   gssize_format='"i"'
3335   glib_msize_type='INT'
3336   ;;
3337 long)
3338   gsize_modifier='"l"'
3339   gsize_format='"lu"'
3340   gssize_format='"li"'
3341   glib_msize_type='LONG'
3342   ;;
3343 "long long"|__int64)
3344   gsize_modifier='"I64"'
3345   gsize_format='"I64u"'
3346   gssize_format='"I64i"'
3347   glib_msize_type='INT64'
3348   ;;
3349 esac
3350
3351 gintbits=`expr $ac_cv_sizeof_int \* 8`
3352 glongbits=`expr $ac_cv_sizeof_long \* 8`
3353 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3354
3355 case $ac_cv_sizeof_void_p in
3356 $ac_cv_sizeof_int)
3357   glib_intptr_type_define=int
3358   gintptr_modifier='""'
3359   gintptr_format='"i"'
3360   guintptr_format='"u"'
3361   glib_gpi_cast=''
3362   glib_gpui_cast=''
3363   ;;
3364 $ac_cv_sizeof_long)
3365   glib_intptr_type_define=long
3366   gintptr_modifier='"l"'
3367   gintptr_format='"li"'
3368   guintptr_format='"lu"'
3369   glib_gpi_cast='(glong)'
3370   glib_gpui_cast='(gulong)'
3371   ;;
3372 $ac_cv_sizeof_long_long)
3373   glib_intptr_type_define='long long'
3374   gintptr_modifier='"I64"'
3375   gintptr_format='"I64i"'
3376   guintptr_format='"I64u"'
3377   glib_gpi_cast='(gint64)'
3378   glib_gpui_cast='(guint64)'
3379   ;;
3380 $ac_cv_sizeof___int64)
3381   glib_intptr_type_define=__int64
3382   gintptr_modifier='"I64"'
3383   gintptr_format='"I64i"'
3384   guintptr_format='"I64u"'
3385   glib_gpi_cast='(gint64)'
3386   glib_gpui_cast='(guint64)'
3387   ;;
3388 *)
3389   glib_unknown_void_p=yes
3390   ;;
3391 esac
3392
3393
3394 case xyes in
3395 x$ac_cv_func_atexit)
3396   glib_atexit="
3397 #ifdef NeXT /* @#%@! NeXTStep */
3398 # define g_ATEXIT(proc) (!atexit (proc))
3399 #else
3400 # define g_ATEXIT(proc) (atexit (proc))
3401 #endif"
3402   ;;
3403 x$ac_cv_func_on_exit)
3404   glib_atexit="
3405 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3406   ;;
3407 esac
3408
3409 case xyes in
3410 x$ac_cv_func_memmove)
3411   glib_memmove='
3412 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3413   ;;
3414 x$glib_cv_working_bcopy)
3415   glib_memmove="
3416 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3417 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3418   ;;
3419 *)
3420   glib_memmove="
3421 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3422  * so we have to roll our own copy routine. */
3423 void g_memmove (void* dest, const void * src, unsigned long len);"
3424   ;;
3425 esac
3426
3427 glib_defines="
3428 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3429 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3430 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3431 "
3432
3433 case xyes in
3434 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3435 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3436 *)                      glib_vacopy=''
3437 esac
3438
3439 if test x$glib_cv_va_val_copy = xno; then
3440   glib_vacopy="\$glib_vacopy
3441 #define G_VA_COPY_AS_ARRAY 1"
3442 fi
3443
3444 if test x$glib_cv_hasinline = xyes; then
3445     glib_inline='#define G_HAVE_INLINE 1'
3446 fi
3447 if test x$glib_cv_has__inline = xyes; then
3448     glib_inline="\$glib_inline
3449 #define G_HAVE___INLINE 1"
3450 fi
3451 if test x$glib_cv_has__inline__ = xyes; then
3452     glib_inline="\$glib_inline
3453 #define G_HAVE___INLINE__ 1"
3454 fi
3455
3456 g_have_gnuc_varargs=$g_have_gnuc_varargs
3457 g_have_iso_c_varargs=$g_have_iso_c_varargs
3458 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3459
3460 g_can_inline=$g_can_inline
3461 g_have_gnuc_visibility=$g_have_gnuc_visibility
3462 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3463
3464 if test x$ac_cv_c_bigendian = xyes; then
3465   g_byte_order=G_BIG_ENDIAN
3466   g_bs_native=BE
3467   g_bs_alien=LE
3468 else
3469   g_byte_order=G_LITTLE_ENDIAN
3470   g_bs_native=LE
3471   g_bs_alien=BE
3472 fi
3473
3474 g_pollin=$glib_cv_value_POLLIN
3475 g_pollout=$glib_cv_value_POLLOUT
3476 g_pollpri=$glib_cv_value_POLLPRI
3477 g_pollhup=$glib_cv_value_POLLHUP
3478 g_pollerr=$glib_cv_value_POLLERR
3479 g_pollnval=$glib_cv_value_POLLNVAL
3480
3481 g_af_unix=$glib_cv_value_AF_UNIX
3482 g_af_inet=$glib_cv_value_AF_INET
3483 g_af_inet6=$glib_cv_value_AF_INET6
3484
3485 g_msg_peek=$glib_cv_value_MSG_PEEK
3486 g_msg_oob=$glib_cv_value_MSG_OOB
3487 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3488
3489 g_stack_grows=$glib_cv_stack_grows
3490
3491 g_have_eilseq=$have_eilseq
3492
3493 g_threads_impl_def=$g_threads_impl
3494
3495 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3496
3497 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3498 g_memory_barrier_needed="$glib_memory_barrier_needed"
3499 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3500
3501 g_module_suffix="$glib_gmodule_suffix"
3502
3503 g_pid_type="$glib_pid_type"
3504 case $host in
3505   *-*-beos*)
3506     glib_os="#define G_OS_BEOS"
3507     ;;
3508   *-*-cygwin*)
3509     glib_os="#define G_OS_UNIX
3510 #define G_PLATFORM_WIN32
3511 #define G_WITH_CYGWIN"
3512     ;;
3513   *-*-mingw*)
3514     glib_os="#define G_OS_WIN32
3515 #define G_PLATFORM_WIN32"
3516     ;;
3517   *)
3518     glib_os="#define G_OS_UNIX"
3519     ;;
3520 esac
3521 glib_static_compilation=""
3522 if test x$glib_win32_static_compilation = xyes; then
3523   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3524 #define GOBJECT_STATIC_COMPILATION 1"
3525 fi
3526 ])
3527
3528 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3529 #
3530 # 1.2.14 required for dbus_message_set_serial
3531 PKG_CHECK_MODULES(DBUS1,
3532                   dbus-1 >= 1.2.14,
3533                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3534                   have_dbus1=no)
3535 AC_SUBST(DBUS1_CFLAGS)
3536 AC_SUBST(DBUS1_LIBS)
3537 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3538
3539 dnl
3540 dnl Check for -Bsymbolic-functions linker flag used to avoid
3541 dnl intra-library PLT jumps, if available.
3542 dnl
3543
3544 AC_ARG_ENABLE(Bsymbolic,
3545               [AC_HELP_STRING([--disable-Bsymbolic],
3546                               [avoid linking with -Bsymbolic])],,
3547               [SAVED_LDFLAGS="${LDFLAGS}"
3548                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3549                LDFLAGS=-Wl,-Bsymbolic-functions
3550                AC_TRY_LINK([], [int main (void) { return 0; }],
3551                            AC_MSG_RESULT(yes)
3552                            enable_Bsymbolic=yes,
3553                            AC_MSG_RESULT(no)
3554                            enable_Bsymbolic=no)
3555                LDFLAGS="${SAVED_LDFLAGS}"])
3556
3557 if test "x${enable_Bsymbolic}" == "xyes"; then
3558   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3559 fi
3560
3561 AC_SUBST(GLIB_LINK_FLAGS)
3562
3563 #
3564 # Define variables corresponding to the correct include paths to use for
3565 # in-tree building.
3566 #
3567
3568 # for config.h:
3569 config_h_INCLUDES='-I$(top_builddir)'
3570 AC_SUBST(config_h_INCLUDES)
3571
3572 # glib:
3573 #   config.h
3574 #   $(top_builddir)/glib: for glibconfig.h
3575 #   $(top_srcdir)/glib:   for glib.h
3576 #   $(top_srcdir):        for everything
3577 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3578 AC_SUBST(glib_INCLUDES)
3579
3580 # gthread:
3581 #   same as glib
3582 gthread_INCLUDES='$(glib_INCLUDES)'
3583 AC_SUBST(gthread_INCLUDES)
3584
3585 # gobject:
3586 #   same as gthread
3587 gobject_INCLUDES='$(gthread_INCLUDES)'
3588 AC_SUBST(gobject_INCLUDES)
3589
3590 # gmodule:
3591 #   glib includes
3592 #   $(top_srcdir)/gmodule: for gmodule.h
3593 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3594 AC_SUBST(gmodule_INCLUDES)
3595
3596 # gio:
3597 #   same as gmodule
3598 gio_INCLUDES='$(gmodule_INCLUDES)'
3599 AC_SUBST(gio_INCLUDES)
3600
3601
3602 AC_CONFIG_FILES([
3603 glib-2.0.pc
3604 gmodule-2.0.pc
3605 gmodule-export-2.0.pc
3606 gmodule-no-export-2.0.pc
3607 gthread-2.0.pc
3608 gobject-2.0.pc
3609 gio-2.0.pc
3610 gio-unix-2.0.pc
3611 gio-windows-2.0.pc
3612 glib-zip
3613 glib-gettextize
3614 Makefile
3615 build/Makefile
3616 build/win32/Makefile
3617 build/win32/dirent/Makefile
3618 build/win32/vs9/Makefile
3619 build/win32/vs10/Makefile
3620 glib/Makefile
3621 glib/glib.stp
3622 glib/libcharset/Makefile
3623 glib/gnulib/Makefile
3624 glib/pcre/Makefile
3625 glib/update-pcre/Makefile
3626 glib/tests/Makefile
3627 gmodule/Makefile
3628 gmodule/gmoduleconf.h
3629 gobject/Makefile
3630 gobject/gobject.stp
3631 gobject/glib-mkenums
3632 gobject/tests/Makefile
3633 gthread/Makefile
3634 gio/Makefile
3635 gio/gdbus-2.0/codegen/Makefile
3636 gio/gdbus-2.0/codegen/config.py
3637 gio/xdgmime/Makefile
3638 gio/inotify/Makefile
3639 gio/fen/Makefile
3640 gio/fam/Makefile
3641 gio/win32/Makefile
3642 gio/tests/Makefile
3643 gio/tests/gdbus-object-manager-example/Makefile
3644 po/Makefile.in
3645 docs/Makefile
3646 docs/reference/Makefile
3647 docs/reference/glib/Makefile
3648 docs/reference/glib/version.xml
3649 docs/reference/gobject/Makefile
3650 docs/reference/gobject/version.xml
3651 docs/reference/gio/Makefile
3652 docs/reference/gio/gdbus-object-manager-example/Makefile
3653 docs/reference/gio/version.xml
3654 tests/Makefile
3655 tests/gobject/Makefile
3656 tests/refcount/Makefile
3657 m4macros/Makefile
3658 ])
3659
3660 AC_CONFIG_COMMANDS([chmod-scripts],
3661 [chmod 0755 glib-zip
3662 chmod 0755 glib-gettextize
3663 chmod 0755 gobject/glib-mkenums])
3664
3665 # we want to invoke this macro solely so that the config.status script
3666 # and automake generated makefiles know about these generated files.
3667 # They are only needed to distcheck the package
3668 if false; then
3669   AC_CONFIG_FILES([
3670     INSTALL
3671     README
3672     config.h.win32
3673     glib/glibconfig.h.win32
3674     glib/makefile.msc
3675     glib/glib.rc
3676     gmodule/makefile.msc
3677     gmodule/gmodule.rc
3678     gobject/makefile.msc
3679     gobject/gobject.rc
3680     gthread/makefile.msc
3681     gthread/gthread.rc
3682     gio/gio.rc
3683     tests/makefile.msc
3684   ])
3685 fi
3686
3687 AC_OUTPUT