configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [7])
   6 m4_define([folks_micro_version], [0])
   7 m4_define([folks_nano_version], [1])
   8
   9 # If library source has changed since last release, increment revision
  10 # If public symbols have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If public symbols have been added since last release, increment age
  13 # If public symbols have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [33])
  15 m4_define([folks_lt_revision], [0])
  16 m4_define([folks_lt_age], [8])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54 GLIB_GSETTINGS
  55
  56 AC_SUBST([CFLAGS])
  57 AC_SUBST([CPPFLAGS])
  58 AC_SUBST([LDFLAGS])
  59
  60 LT_CURRENT=folks_lt_current
  61 LT_REVISION=folks_lt_revision
  62 LT_AGE=folks_lt_age
  63 AC_SUBST([LT_CURRENT])
  64 AC_SUBST([LT_REVISION])
  65 AC_SUBST([LT_AGE])
  66
  67 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  68 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  69
  70 API_VERSION=0.6
  71 AC_SUBST([API_VERSION])
  72
  73 AC_ARG_ENABLE(tracker-backend,
  74         AC_HELP_STRING([--enable-tracker-backend],
  75                        [ build the Tracker backend]),
  76         enable_tracker_backend=$enableval,
  77         enable_tracker_backend=no )
  78
  79 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  80
  81 if test "x$enable_tracker_backend" = "xyes"; then
  82         AC_DEFINE(HAVE_TRACKER, [1],
  83                   [Define as 1 if you have the Tracker backend])
  84 else
  85         AC_DEFINE(HAVE_TRACKER, [0],
  86                   [Define as 1 if you have the Tracker backend])
  87 fi
  88
  89 AC_ARG_ENABLE(eds-backend,
  90         AC_HELP_STRING([--enable-eds-backend],
  91                        [ build the E-D-S backend]),
  92         enable_eds_backend=$enableval,
  93         enable_eds_backend=yes )
  94
  95 if test "x$enable_eds_backend" = "xyes"; then
  96         AC_DEFINE(HAVE_EDS, [1], [Define as 1 if you have the eds backend])
  97 else
  98         AC_DEFINE(HAVE_EDS, [0], [Define as 1 if you have the eds backend])
  99 fi
 100
 101
 102 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
 103
 104 # Automatically check the dependencies for the libsocialweb backend
 105 SW_CLIENT_REQUIRED=0.25.20
 106 AC_ARG_ENABLE(libsocialweb-backend,
 107         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
 108                        [build the Libsocialweb backend (default: auto)]),
 109         enable_libsocialweb_backend=$enableval,
 110         enable_libsocialweb_backend=auto )
 111
 112 # this may be overwritten farther down
 113 AC_DEFINE(HAVE_LIBSOCIALWEB, [0],
 114           [Define as 1 if you have the libsocialweb backend])
 115 if test "x$enable_libsocialweb_backend" != "xno"; then
 116   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
 117       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
 118   if test "x$have_libsocialweb_backend" = "xyes" -a \
 119           "x$enable_vala" = "xyes"; then
 120     VALA_CHECK_PACKAGES([telepathy-glib
 121                          gio-2.0
 122                          gee-1.0
 123                          libsocialweb-client],
 124         ,
 125         have_libsocialweb_backend="no")
 126   fi
 127
 128   if test "x$have_libsocialweb_backend" = "xyes"; then
 129     AC_DEFINE(HAVE_LIBSOCIALWEB, [1],
 130               [Define if you have the libsocialweb backend])
 131   fi
 132 else
 133    have_libsocialweb_backend=no
 134 fi
 135
 136 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 137   "x$have_libsocialweb_backend" != "xyes"; then
 138     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 139 fi
 140
 141 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 142         [test "x$have_libsocialweb_backend" = "xyes"])
 143
 144 # -----------------------------------------------------------
 145 # Dependencies
 146 # -----------------------------------------------------------
 147
 148 GLIB_REQUIRED=2.26.0
 149 TP_GLIB_REQUIRED=0.17.5
 150 VALA_REQUIRED=0.15.2
 151 VALADOC_REQUIRED=0.3.1
 152 TRACKER_SPARQL_MAJOR=0.14
 153 TRACKER_SPARQL_REQUIRED=0.13.1
 154 EBOOK_REQUIRED=3.1.5
 155 EDATASERVER_REQUIRED=3.1.5
 156
 157 AC_SUBST([TRACKER_SPARQL_MAJOR])
 158
 159 PKG_CHECK_MODULES([GLIB],
 160                   [glib-2.0 >= $GLIB_REQUIRED
 161                    gobject-2.0 >= $GLIB_REQUIRED])
 162 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 163 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 164 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
 165
 166 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
 167 PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7],
 168                   have_gee_0_6_x="yes",
 169                   have_gee_0_6_x="no")
 170
 171 if test "x$have_gee_0_6_x" != "xyes"; then
 172     AC_MSG_ERROR([
 173 Gee 0.6.x required but not installed.
 174
 175 Note that Gee 0.8.x provides gee-0.8 (but gee-1.0 is, confusingly, provided by
 176 Gee 0.6.x)])
 177 fi
 178
 179 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 180
 181 if test x$enable_tracker_backend = xyes; then
 182         PKG_CHECK_MODULES([TRACKER_SPARQL],
 183                           [tracker-sparql-$TRACKER_SPARQL_MAJOR >= \
 184                            $TRACKER_SPARQL_REQUIRED])
 185 fi
 186
 187 if test x$enable_eds_backend = xyes; then
 188         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 189         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 190 fi
 191
 192 #
 193 # Vala building options -- allows tarball builds without installing Vala
 194 #
 195 AC_ARG_ENABLE([vala],
 196               AS_HELP_STRING([--enable-vala],
 197                              [Enable building from the Vala sources]),
 198               [enable_vala=$enableval],
 199               [enable_vala=no])
 200
 201 # will be re-set as necessary below
 202 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 203 sd=${srcdir}/
 204
 205 # Force Vala for non-release builds
 206 m4_if(folks_released, [1], [],
 207     [
 208         enable_vala=yes
 209         echo "Vala compiler required for non-release builds; requiring Vala..."
 210     ])
 211
 212 # Force Vala if generated source is missing or outdated
 213 if test \
 214         ! -e ${sd}tools/folks_import_vala.stamp -o \
 215         ! -e ${sd}tests/folks/abstract_field_details_vala.stamp -o \
 216         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 217         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 218         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 219         ! -e ${sd}tests/lib/folks-test.vapi -o \
 220         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 221         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 222         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 223         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 224         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 225         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 226         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 227         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 228         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 229         ! -e ${sd}backends/key-file/key_file_la_vala.stamp -o \
 230         ! -e ${sd}backends/telepathy/telepathy_la_vala.stamp \
 231                 -o \
 232         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 233         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 234         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 235         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 236         ! -e ${sd}folks/folks-internal.h -o \
 237         ! -e ${sd}folks/folks-internal.vapi -o \
 238         ! -e ${sd}folks/libfolks_internal_la_vala.stamp -o \
 239         ! -e ${sd}folks/folks.vapi -o \
 240         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 241         enable_vala=yes
 242         echo "Vala source needs to be re-compiled; requiring Vala..."
 243 fi
 244
 245 if test "x$enable_vala" = "xyes" ; then
 246         AM_PROG_VALAC([$VALA_REQUIRED])
 247         if test "x$VALAC" = "x"; then
 248               AC_MSG_ERROR([Vala requested but valac is not installed])
 249         fi
 250
 251         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 252         if test "x$VAPIGEN" = "x"; then
 253               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 254         fi
 255
 256         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 257         # automatically
 258         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 259         AC_SUBST([VALAFLAGS])
 260         AC_SUBST([VAPIGENFLAGS])
 261         AC_SUBST([VAPIDIR])
 262
 263         VALA_CHECK_PACKAGES([telepathy-glib
 264                              gio-2.0
 265                              gee-1.0])
 266
 267         if test x$enable_tracker_backend = xyes; then
 268           VALA_CHECK_PACKAGES([tracker-sparql-$TRACKER_SPARQL_MAJOR])
 269         fi
 270
 271         if test x$enable_eds_backend = xyes; then
 272           VALA_CHECK_PACKAGES([libebook-1.2 libedataserver-1.2 libxml-2.0])
 273         fi
 274 fi
 275
 276 # this will set HAVE_INTROSPECTION
 277 GOBJECT_INTROSPECTION_REQUIRE([1.30])
 278
 279 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 280
 281 # Various functions that we need (used in C code generated from Vala)
 282 AC_CHECK_FUNCS([memset])
 283 AC_CHECK_FUNCS([strstr])
 284
 285 # -----------------------------------------------------------
 286 # Backends
 287 # -----------------------------------------------------------
 288
 289 FOLKS_MODULE_VERSION=folks_module_version
 290 AC_SUBST([FOLKS_MODULE_VERSION])
 291 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 292
 293 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 294 AC_SUBST([BACKEND_DIR])
 295
 296 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/key-file.so'
 297 AC_SUBST([BACKEND_KF])
 298 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/telepathy.so'
 299 AC_SUBST([BACKEND_TP])
 300
 301 if test x$have_libsocialweb_backend = xyes; then
 302   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libsocialweb.so'
 303   AC_SUBST([BACKEND_LIBSOCIALWEB])
 304 fi
 305
 306 if test x$enable_tracker_backend = xyes; then
 307   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/tracker.so'
 308   AC_SUBST([BACKEND_TRACKER])
 309 fi
 310
 311 if test x$enable_eds_backend = xyes; then
 312   BACKEND_EDS='$(top_builddir)/backends/eds/.libs/eds.so'
 313   AC_SUBST([BACKEND_EDS])
 314 fi
 315
 316 # All of the backend libraries in our tree; to be used by the tests
 317 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 318 if test x$have_libsocialweb_backend = xyes; then
 319   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 320   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 321 fi
 322 if test x$enable_tracker_backend = xyes; then
 323   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 324   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 325 fi
 326 if test x$enable_eds_backend = xyes; then
 327   EDS_BACKEND_UNINST_PATH='$(BACKEND_EDS)'
 328   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$EDS_BACKEND_UNINST_PATH"
 329 fi
 330 AC_SUBST([BACKEND_UNINST_PATH])
 331
 332 # -----------------------------------------------------------
 333 # Tools
 334 # -----------------------------------------------------------
 335
 336 AC_ARG_ENABLE([import-tool],
 337               AS_HELP_STRING([--enable-import-tool],
 338                              [Enable building the meta-contact import tool]),
 339               [enable_import_tool=$enableval with_import_tool=$enableval],
 340               [enable_import_tool=maybe with_import_tool=no])
 341 AS_IF([test "$enable_import_tool" != "no"],
 342       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 343                          [with_import_tool=yes], [with_import_tool=no])])
 344 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 345       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 346 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 347
 348 # Readline's required for the folks-inspect program
 349 AC_ARG_ENABLE([inspect-tool],
 350               AS_HELP_STRING([--enable-inspect-tool],
 351                              [Enable building the data inspection tool]),
 352               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 353               [enable_inspect_tool=maybe with_inspect_tool=no])
 354 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 355       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 356                      using --enable-vala])])
 357 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 358       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 359                       --enable-vala])])
 360 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 361       [AC_CHECK_LIB([readline], [main],
 362                     [with_inspect_tool=yes], [with_inspect_tool=no],
 363                     [-lncurses])])
 364 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 365        "x$enable_vala" = "xyes"],
 366       [VALA_CHECK_PACKAGES([readline])
 367        LIBREADLINE="-lreadline -lncurses"
 368        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 369        AC_SUBST([LIBREADLINE])])
 370 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 371       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 372 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 373
 374 # -----------------------------------------------------------
 375 # Documentation
 376 # -----------------------------------------------------------
 377
 378 AC_ARG_ENABLE([docs],
 379               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 380               [enable_docs=$enableval], [enable_docs=no])
 381 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 382
 383 have_valadoc=no
 384 if test x$enable_docs = xyes; then
 385   # make sure the library is new enough and the program exists
 386   PKG_CHECK_MODULES([VALADOC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 387   AC_PATH_PROG([VALADOC], [valadoc], [:])
 388   AS_IF([test "$VALADOC" != :], have_valadoc=yes)
 389 fi
 390 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 391
 392 if test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"; then
 393     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 394 fi
 395
 396 # -----------------------------------------------------------
 397 # Gettext
 398 # -----------------------------------------------------------
 399
 400 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 401 AC_SUBST(GETTEXT_PACKAGE)
 402 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 403 IT_PROG_INTLTOOL([0.35.0])
 404
 405 # -----------------------------------------------------------
 406 # Error flags
 407 # -----------------------------------------------------------
 408
 409 # Disable GLib deprecation warnings for now (#670196); GValueArray is deprecated
 410 # but we need it for dbus-glib. Porting to GDBus will solve this (#653198)
 411 AC_DEFINE(GLIB_DISABLE_DEPRECATION_WARNINGS, 1, [Build with GLib deprecated])
 412
 413 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 414 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 415
 416 AC_ARG_ENABLE([debug],
 417               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 418               [enable_debug=$enableval], [enable_debug=yes])
 419
 420 AC_ARG_ENABLE([Werror],
 421               AS_HELP_STRING([--disable-Werror],
 422                              [compile without -Werror (normally enabled in
 423                               development builds)]),
 424               [werror=$enableval], [werror=yes])
 425
 426 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 427 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 428                  [wno_missing_field_initializers=yes],
 429                  [wno_missing_field_initializers=no])
 430 AS_COMPILER_FLAG([-Wno-unused-parameter],
 431                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 432
 433 m4_if(folks_released, [1], [],
 434     [
 435         if test x$werror = xyes; then
 436             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 437         fi
 438         if test x$wextra = xyes -a \
 439             x$wno_missing_field_initializers = xyes -a \
 440             x$wno_unused_parameter = xyes; then
 441             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 442                 -Wno-missing-field-initializers -Wno-unused-parameter"
 443         fi
 444     ])
 445
 446 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 447 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 448 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 449 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 450                                           -Wmissing-prototypes"])
 451 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 452                                             -Wmissing-declarations"])
 453 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 454                                          -Wstrict-prototypes"])
 455
 456 AC_SUBST([ERROR_CFLAGS])
 457
 458 # -----------------------------------------------------------
 459 # Code coverage flags
 460 # -----------------------------------------------------------
 461
 462 AC_ARG_ENABLE([code-coverage],
 463               AS_HELP_STRING([--enable-code-coverage],
 464                              [compile with code coverage code]),
 465               [enable_code_coverage=$enableval], [enable_code_coverage=no])
 466
 467 # Only enable code coverage if this isn't a release.
 468 m4_if(folks_released, [1], [],
 469     [
 470         if test "x$GCC" = "xyes"; then
 471             if test "x$enable_code_coverage" = "xyes"; then
 472                 CODE_COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage -O0 -ggdb"
 473                 CODE_COVERAGE_LDFLAGS="-lgcov"
 474             fi
 475         fi
 476     ])
 477
 478 AC_SUBST([CODE_COVERAGE_CFLAGS])
 479 AC_SUBST([CODE_COVERAGE_LDFLAGS])
 480
 481 # Vala-related flags
 482 AC_ARG_ENABLE([fatal-warnings],
 483               AS_HELP_STRING([--disable-fatal-warnings],
 484                              [Make warnings from valac and g-ir-scanner non-fatal]),
 485               [enable_fatal_warnings=$enableval], [enable_fatal_warnings=yes])
 486 AS_IF([test "x$enable_vala" = "xyes" && test "x$enable_fatal_warnings" = "xyes"],
 487       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 488                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 489        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 490
 491 # Disable -g if we're building with code coverage enabled, since Vala's
 492 # insertion of #line directives into .c files confuses lcov. For the moment,
 493 # we'll have to do with looking at code coverage of the generated C files only.
 494 # We set the debug flags in CODE_COVERAGE_CFLAGS instead in that case.
 495 m4_if(folks_released, [1], [],
 496     [
 497         if test "x$enable_code_coverage" != "xyes" -o "x$GCC" != "xyes"; then
 498             ERROR_VALAFLAGS="$ERROR_VALAFLAGS -g"
 499         fi
 500     ])
 501
 502 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 503 AC_SUBST([ERROR_VALAFLAGS])
 504
 505 # -----------------------------------------------------------
 506 # Final output
 507 # -----------------------------------------------------------
 508
 509 # FIXME: We can't remove gconf.path until bgo#635379 is fixed, since we need to
 510 # safely contain EDS' use of GConf for the EDS backend tests.
 511 # Note that our use of gconf.path doesn't actually need GConf to be installed,
 512 # though, so it's not a hard dependency of folks.
 513
 514 AC_CONFIG_FILES([
 515     backends/telepathy/lib/folks-telepathy.pc
 516     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 517     backends/tracker/lib/folks-tracker.deps
 518     backends/tracker/lib/folks-tracker.pc
 519     backends/tracker/lib/folks-tracker-uninstalled.pc
 520     backends/eds/lib/folks-eds.pc
 521     backends/eds/lib/folks-eds-uninstalled.pc
 522     folks/folks.pc
 523     folks/folks-uninstalled.pc
 524     folks/org.freedesktop.folks.gschema.xml.in
 525     Makefile
 526     backends/Makefile
 527     backends/key-file/Makefile
 528     backends/libsocialweb/Makefile
 529     backends/libsocialweb/lib/Makefile
 530     backends/libsocialweb/lib/folks-libsocialweb.pc
 531     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 532     backends/telepathy/Makefile
 533     backends/telepathy/lib/Makefile
 534     backends/tracker/Makefile
 535     backends/tracker/lib/Makefile
 536     backends/eds/Makefile
 537     backends/eds/lib/Makefile
 538     folks/Makefile
 539     docs/Makefile
 540     po/Makefile.in
 541     tests/Makefile
 542     tests/data/Makefile
 543     tests/data/gconf.path
 544     tests/folks/Makefile
 545     tests/key-file/Makefile
 546     tests/libsocialweb/Makefile
 547     tests/telepathy/Makefile
 548     tests/tracker/Makefile
 549     tests/lib/Makefile
 550     tests/lib/folks-test-uninstalled.pc
 551     tests/lib/key-file/Makefile
 552     tests/lib/libsocialweb/Makefile
 553     tests/lib/libsocialweb/session.conf
 554     tests/eds/Makefile
 555     tests/lib/eds/Makefile
 556     tests/lib/telepathy/Makefile
 557     tests/lib/tracker/Makefile
 558     tests/lib/telepathy/contactlist/Makefile
 559     tests/lib/telepathy/contactlist/session.conf
 560     tests/tools/Makefile
 561     tools/Makefile
 562     tools/inspect/Makefile
 563 ])
 564
 565 AC_OUTPUT
 566
 567 echo "
 568 Configure summary:
 569
 570         Vala........................:  ${enable_vala}
 571         Vala Compiler...............:  ${VALAC}
 572         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS} ${CODE_COVERAGE_CFLAGS}
 573         Linker Flags................:  ${LDFLAGS} ${CODE_COVERAGE_LDFLAGS}
 574         Prefix......................:  ${prefix}
 575         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 576         Documentation...............:  ${have_valadoc}
 577         Import tool.................:  ${with_import_tool}
 578         Inspector tool..............:  ${with_inspect_tool}
 579         Tracker backend.............:  ${enable_tracker_backend}
 580         Libsocialweb backend........:  ${have_libsocialweb_backend}
 581         E-D-S backend...............:  ${enable_eds_backend}
 582
 583 "