configure.ac

   1 AC_INIT([libusb], [1.0.8])
   2 AM_INIT_AUTOMAKE
   3 AC_CONFIG_SRCDIR([libusb/core.c])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AM_CONFIG_HEADER([config.h])
   6 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   7
   8 AC_PREREQ([2.50])
   9 AC_PROG_CC
  10 AC_PROG_LIBTOOL
  11 AC_C_INLINE
  12 AM_PROG_CC_C_O
  13 AC_DEFINE([_GNU_SOURCE], [], [Use GNU extensions])
  14
  15 AM_MAINTAINER_MODE
  16
  17 AC_MSG_CHECKING([operating system])
  18 case $host in
  19 *-linux*)
  20         AC_DEFINE(OS_LINUX, [], [Linux backend])
  21         AC_SUBST(OS_LINUX)
  22         AC_MSG_RESULT([Linux])
  23         backend="linux"
  24         AC_CHECK_LIB(rt, clock_gettime)
  25         threads="posix"
  26         THREAD_CFLAGS="-pthread"
  27         AM_LDFLAGS=""
  28         ;;
  29 *-darwin*)
  30         AC_DEFINE(OS_DARWIN, [], [Darwin backend])
  31         AC_SUBST(OS_DARWIN)
  32         AC_DEFINE(USBI_OS_HANDLES_TIMEOUT, [], [Backend handles timeout])
  33         AC_MSG_RESULT([Darwin/MacOS X])
  34         backend="darwin"
  35         threads="posix"
  36         THREAD_CFLAGS="-pthread"
  37         AM_LDFLAGS="-Wl,-framework -Wl,IOKit -Wl,-framework -Wl,CoreFoundation -Wl,-prebind -no-undefined"
  38         ;;
  39 *)
  40         AC_MSG_ERROR([unsupported operating system])
  41 esac
  42
  43 AM_CONDITIONAL([OS_LINUX], [test "x$backend" == "xlinux"])
  44 AM_CONDITIONAL([OS_DARWIN], [test "x$backend" == "xdarwin"])
  45 AM_CONDITIONAL([THREADS_POSIX], [test "x$threads" == "xposix"])
  46
  47 # Library versioning
  48 lt_major="0"
  49 lt_revision="0"
  50 lt_age="0"
  51 AC_SUBST(lt_major)
  52 AC_SUBST(lt_revision)
  53 AC_SUBST(lt_age)
  54
  55 # timerfd
  56 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
  57 AC_ARG_ENABLE([timerfd],
  58         [AS_HELP_STRING([--enable-timerfd],
  59                 [use timerfd for timing (default auto)])],
  60         [use_timerfd=$enableval], [use_timerfd='auto'])
  61
  62 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
  63         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
  64 fi
  65
  66 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
  67 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
  68         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
  69 fi
  70
  71 AC_MSG_CHECKING([whether to use timerfd for timing])
  72 if test "x$use_timerfd" = "xno"; then
  73         AC_MSG_RESULT([no (disabled by user)])
  74 else
  75         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
  76                 AC_MSG_RESULT([yes])
  77                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, [], [timerfd headers available])
  78         else
  79                 AC_MSG_RESULT([no (header not available)])
  80         fi
  81 fi
  82
  83 # Message logging
  84 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
  85         [log_enabled=$enableval],
  86         [log_enabled='yes'])
  87 if test "x$log_enabled" != "xno"; then
  88         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
  89 fi
  90
  91 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
  92         [enable debug logging (default n)])],
  93         [debug_log_enabled=$enableval],
  94         [debug_log_enabled='no'])
  95 if test "x$debug_log_enabled" != "xno"; then
  96         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
  97 fi
  98
  99 # Examples build
 100 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 101         [build example applications (default n)])],
 102         [build_examples=$enableval],
 103         [build_examples='no'])
 104 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 105
 106 # Restore gnu89 inline semantics on gcc 4.3 and newer
 107 saved_cflags="$CFLAGS"
 108 CFLAGS="$CFLAGS -fgnu89-inline"
 109 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), inline_cflags="-fgnu89-inline", inline_cflags="")
 110 CFLAGS="$saved_cflags"
 111
 112 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 113 saved_cflags="$CFLAGS"
 114 CFLAGS="$CFLAGS -fvisibility=hidden"
 115 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 116         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 117          AC_DEFINE([API_EXPORTED], [__attribute__((visibility("default")))], [Default visibility]) ],
 118         [ VISIBILITY_CFLAGS=""
 119          AC_DEFINE([API_EXPORTED], [], [Default visibility]) ],
 120         ])
 121 CFLAGS="$saved_cflags"
 122
 123 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 124 saved_cflags="$CFLAGS"
 125 CFLAGS="$CFLAGS -Wno-pointer-sign"
 126 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 127         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 128 CFLAGS="$saved_cflags"
 129
 130 AC_SUBST([THREAD_CFLAGS])
 131
 132 AM_CFLAGS="-std=gnu99 $inline_cflags -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 133
 134 AC_SUBST(VISIBILITY_CFLAGS)
 135 AC_SUBST(AM_CFLAGS)
 136 AC_SUBST(AM_LDFLAGS)
 137
 138 AC_CONFIG_FILES([libusb-1.0.pc] [Makefile] [libusb/Makefile] [examples/Makefile] [doc/Makefile] [doc/doxygen.cfg])
 139 AC_OUTPUT
 140