configure.ac

   1 AC_INIT([at-spi2-core], [1.91.91], [accessibility-atspi@lists.linux-foundation.org])
   2 AC_PREREQ([2.59])
   3 AC_CONFIG_AUX_DIR(config)
   4 AC_CONFIG_MACRO_DIR([m4])
   5
   6 AT_SPI_CORE_MAJOR_VERSION=0
   7 AT_SPI_CORE_MINOR_VERSION=1
   8 AT_SPI_CORE_MICRO_VERSION=3
   9 AT_SPI_CORE_VERSION="$AT_SPI_CORE_MAJOR_VERSION.$AT_SPI_CORE_MINOR_VERSION"
  10 AC_SUBST(AT_SPI_CORE_VERSION)
  11
  12 LT_RELEASE=$AT_SPI_CORE_VERSION
  13 LT_CURRENT=0
  14 LT_REVISION=1
  15 LT_AGE=0
  16 LT_VERSION_INFO='-version-info ${LT_CURRENT}:${LT_REVISION}:${LT_AGE}'
  17 AC_SUBST(LT_VERSION_INFO)
  18 AC_SUBST(LT_RELEASE)
  19 AC_SUBST(LT_CURRENT)
  20 AC_SUBST(LT_REVISION)
  21 AC_SUBST(LT_AGE)
  22
  23 AM_INIT_AUTOMAKE([1.9 -Wall foreign])
  24
  25 AC_PROG_CC
  26 LT_INIT([disable-static])
  27 PKG_PROG_PKG_CONFIG
  28
  29 AC_CONFIG_HEADERS([config.h])
  30
  31 dnl translation of at-spi strings
  32 IT_PROG_INTLTOOL([0.40.0])
  33
  34
  35 GETTEXT_PACKAGE="${PACKAGE}"
  36 AC_SUBST(GETTEXT_PACKAGE)
  37
  38 PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.0])
  39 AC_SUBST(DBUS_LIBS)
  40 AC_SUBST(DBUS_CFLAGS)
  41
  42 PKG_CHECK_MODULES(GLIB, [glib-2.0 >= 2.26.0])
  43 AC_SUBST(GLIB_LIBS)
  44 AC_SUBST(GLIB_CFLAGS)
  45 AC_CHECK_LIB([glib-2.0], [g_ptr_array_new_with_free_func], [],
  46         [AC_MSG_ERROR([The version of glib-2.0 found does not define ]
  47                 [g_ptr_array_new_with_free_func. Please upgrade glib.])],
  48         [$GLIB_LIBS])
  49
  50 PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.26.0])
  51 AC_SUBST(GIO_LIBS)
  52 AC_SUBST(GIO_CFLAGS)
  53
  54 PKG_CHECK_MODULES(DBUS_GLIB, [dbus-glib-1 >= 0.7.0])
  55 AC_SUBST(DBUS_GLIB_LIBS)
  56 AC_SUBST(DBUS_GLIB_CFLAGS)
  57
  58 PKG_CHECK_MODULES(GOBJ, [gobject-2.0 >= 2.0.0])
  59 AC_SUBST(GOBJ_LIBS)
  60 AC_SUBST(GOBJ_CFLAGS)
  61
  62 PKG_CHECK_MODULES(GIO, [gio-2.0 >= 2.28])
  63 AC_SUBST(GIO_LIBS)
  64 AC_SUBST(GIO_CFLAGS)
  65
  66 # --------------------------------------------------------------------
  67 # Find DL functionality
  68
  69 AC_CHECK_LIB(c, dlopen, DL_LIBS="",
  70         AC_CHECK_LIB(dl, dlopen, DL_LIBS="-ldl",
  71                 AC_MSG_ERROR([Could not find a library with the dlopen function])
  72         )
  73 )
  74
  75 AC_SUBST(DL_LIBS)
  76
  77 AC_PATH_XTRA
  78
  79 if test x$no_x = xyes ; then
  80         AC_MSG_ERROR([X development libraries not found])
  81 else
  82         X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
  83 fi
  84 AC_SUBST(X_LIBS)
  85
  86 save_LIBS="$LIBS"
  87 LIBS=""
  88 CPPFLAGS="$CPPFLAGS $X_CFLAGS"
  89 AC_CHECK_LIB(Xtst, XTestFakeKeyEvent, XTST_LIBS=-lXtst,[
  90         AC_MSG_ERROR([Couldn't find the Xtst library. Check config.log])],
  91         $X_LIBS)
  92 AC_SUBST(XTST_LIBS)
  93 LIBS="$LIBS $save_LIBS"
  94
  95 save_LIBS="$LIBS"
  96 LIBS=""
  97 AC_CHECK_LIB(X11, XkbQueryExtension, have_xkb="maybe", have_xkb="no", $X_LIBS)
  98 if test "x$have_xkb" = "xmaybe"; then
  99         AC_CHECK_HEADER([X11/XKBlib.h], have_xkb=yes)
 100 fi
 101 if test "x$have_xkb" = "xyes"; then
 102         AC_DEFINE([HAVE_XKB], [], [Xkb is present])
 103 fi
 104 LIBS="$LIBS $save_LIBS"
 105
 106 save_LIBS="$LIBS"
 107 LIBS=""
 108 AC_CHECK_LIB(Xi, XOpenDevice, have_xinput="maybe", have_xinput="no", $X_LIBS)
 109 if test "x$have_xinput" = "xmaybe"; then
 110         save_LIBS="$LIBS"
 111         LIBS="$LIBS $X_LIBS"
 112         AC_CHECK_HEADER([X11/extensions/XInput.h], [have_xinput="yes"])
 113         LIBS="$save_LIBS"
 114 fi
 115 if test "x$have_xinput" != "xyes"; then
 116         AC_MSG_ERROR([Couldn't find the XInput library. Check config.log for details])
 117 fi
 118 XINPUT_LIBS="-lXi"
 119 AC_SUBST(XINPUT_LIBS)
 120 LIBS="$LIBS $save_LIBS"
 121
 122 save_LIBS="$LIBS"
 123 LIBS=""
 124 AC_ARG_ENABLE(xevie,
 125         [AS_HELP_STRING([--enable-xevie],
 126                 [Build with XEViE support [default=yes]])],
 127         enable_xevie="$enableval", enable_xevie=yes)
 128
 129 if test x$enable_xevie = xyes ; then
 130         have_xevie=
 131         AC_CHECK_LIB(Xext, XevieStart, have_xevie="yes", have_xevie="no", $X_LIBS)
 132
 133         if test "x$have_xevie" = "xyes"; then
 134                 XEVIE_LIBS="-lXext"
 135                 AC_DEFINE([HAVE_XEVIE], [], [Xevie is present])
 136         else
 137            AC_CHECK_LIB(Xevie, XevieQueryVersion, have_xevie="maybe",,$X_LIBS)
 138            if test "x$have_xevie" = "xmaybe"; then
 139               AC_CHECK_HEADER(X11/extensions/Xevie.h, have_xevie=yes, [],
 140               [[#include <X11/Xlib.h>
 141 ]])
 142               if test "x$have_xevie" = "xyes"; then
 143                       XEVIE_LIBS="-lXext -lXevie"
 144                       AC_DEFINE([HAVE_XEVIE], [], [Xevie is present])
 145               fi
 146            fi
 147         fi
 148         AC_SUBST(XEVIE_LIBS)
 149 fi
 150 LIBS="$LIBS $save_LIBS"
 151
 152 AC_ARG_WITH([dbus_daemondir],
 153         [AS_HELP_STRING([--with-dbus-daemondir=<directory>],
 154                 [Directory where the DBUS daemon is installed])],
 155     [DBUS_DAEMON="$with_dbus_daemondir/dbus-daemon"],
 156     [AC_PATH_PROG([DBUS_DAEMON], [dbus-daemon], [XXXDBUSDAEMONNOTFOUND],
 157                 [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR]dnl
 158 [/libexec$PATH_SEPARATOR/usr/libexec$PATH_SEPARATOR/usr/local/bin]dnl
 159 [$PATH_SEPARATOR/usr/pkg/bin])]
 160         )
 161 if test "$DBUS_DAEMON" = "XXXDBUSDAEMONNOTFOUND"; then
 162         DBUS_DAEMON = "$bindir/dbus-daemon"
 163         AC_MSG_WARN([at-spi2 relies on dbus, and the dbus-daemon was not found])
 164         AC_MSG_WARN([we assume that it will be installed in "$bindir"])
 165 fi
 166 AC_SUBST(DBUS_DAEMON)
 167
 168 AC_ARG_WITH(dbus-services,
 169            [AS_HELP_STRING([--with-dbus-services=<directory>],
 170            [where D-BUS services directory is])])
 171 if ! test -z "$with_dbus_services" ; then
 172            DBUS_SERVICES_DIR="$with_dbus_services"
 173 else
 174            DBUS_SERVICES_DIR="$datadir/dbus-1/services"
 175 fi
 176 AC_SUBST(DBUS_SERVICES_DIR)
 177
 178 GOBJECT_INTROSPECTION_CHECK([0.9.6])
 179
 180 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 181
 182 dnl find sizes & alignments
 183 orig_CPPFLAGS=$CPPFLAGS
 184 CPPFLAGS="$CPPFLAGS $DBUS_CFLAGS"
 185 DBIND_CHECK_ALIGNOF(char)
 186 DBIND_CHECK_ALIGNOF(dbus_bool_t)
 187 DBIND_CHECK_ALIGNOF(dbus_int16_t)
 188 DBIND_CHECK_ALIGNOF(dbus_int32_t)
 189 DBIND_CHECK_ALIGNOF(dbus_int64_t)
 190 DBIND_CHECK_ALIGNOF(double)
 191 DBIND_CHECK_ALIGNOF(dbind_pointer)
 192 DBIND_CHECK_ALIGNOF(dbind_struct)
 193
 194 GTK_DOC_CHECK([1.09])
 195
 196 CPPFLAGS=$orig_CPPFLAGS
 197 AC_CONFIG_FILES([Makefile po/Makefile.in
 198         xml/Makefile
 199         dbind/Makefile
 200 dbind/dbind-config.h
 201         atspi/Makefile
 202         registryd/Makefile
 203         bus/Makefile
 204 doc/Makefile
 205 doc/libatspi/Makefile
 206 ])
 207
 208 AC_OUTPUT