configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [31])
  34 m4_define([glib_micro_version], [19])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     glib_native_win32=no
 156     glib_pid_type=int
 157     ;;
 158 esac
 159 case $host in
 160   *-*-linux*)
 161     glib_os_linux=yes
 162     ;;
 163 esac
 164
 165 AC_MSG_RESULT([$glib_native_win32])
 166
 167 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 168
 169 glib_have_carbon=no
 170 AC_MSG_CHECKING([for Mac OS X Carbon support])
 171 AC_TRY_CPP([
 172 #include <Carbon/Carbon.h>
 173 #include <CoreServices/CoreServices.h>
 174 ], glib_have_carbon=yes)
 175
 176 AC_MSG_RESULT([$glib_have_carbon])
 177
 178 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 179 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 180 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 181 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 182 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 183
 184 if test "$glib_native_win32" = "yes"; then
 185   AC_CHECK_TOOL(WINDRES, windres, no)
 186   if test "$WINDRES" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(NM, nm, no)
 190   if test "$NM" = no; then
 191     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 192   fi
 193   AC_CHECK_TOOL(RANLIB, ranlib, :)
 194   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 195 fi
 196 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 197
 198 if test "$glib_native_win32" != yes; then
 199     # libtool option to control which symbols are exported
 200     # right now, symbols starting with _ are not exported
 201     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 202 else
 203     # We currently use .def files on Windows
 204     LIBTOOL_EXPORT_OPTIONS=
 205 fi
 206 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 207
 208 if test "x$glib_have_carbon" = "xyes"; then
 209   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 210   LDFLAGS="$LDFLAGS -framework Carbon"
 211 fi
 212
 213 gl_GLIBC21
 214 if test "x$GLIBC21" = "xyes"; then
 215   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 216 fi
 217
 218 dnl declare --enable-* args and collect ac_help strings
 219 AC_ARG_ENABLE(debug,
 220               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 221                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 222               enable_debug=glib_debug_default)
 223
 224 AC_ARG_ENABLE(gc_friendly,
 225               [AC_HELP_STRING([--enable-gc-friendly],
 226                               [turn on garbage collector friendliness [default=no]])],,
 227               [enable_gc_friendly=no])
 228 AC_ARG_ENABLE(mem_pools,
 229               [AC_HELP_STRING([--disable-mem-pools],
 230                               [disable all glib memory pools])],,
 231               [disable_mem_pools=no])
 232 AC_ARG_ENABLE(rebuilds,
 233               [AC_HELP_STRING([--disable-rebuilds],
 234                               [disable all source autogeneration rules])],,
 235               [enable_rebuilds=yes])
 236
 237 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 238 if test "x$enable_gc_friendly" = "xyes"; then
 239   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 240   AC_MSG_RESULT([yes])
 241 else
 242   AC_MSG_RESULT([no])
 243 fi
 244
 245 AC_MSG_CHECKING([whether to disable memory pools])
 246 if test "x$disable_mem_pools" = "xno"; then
 247   AC_MSG_RESULT([no])
 248 else
 249   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 250   AC_MSG_RESULT([yes])
 251 fi
 252
 253 dnl location to install runtime libraries, e.g. ../../lib to install
 254 dnl to /lib if libdir is /usr/lib
 255 AC_ARG_WITH(runtime-libdir,
 256            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 257                            [install runtime libraries relative to libdir])],
 258            [],
 259            [with_runtime_libdir=""])
 260 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 261 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 262 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 263 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 264 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 265
 266 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 267 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 268 AC_LANG_SAVE
 269 AC_LANG_CPLUSPLUS
 270 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 271 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 272 AC_LANG_RESTORE
 273
 274 AM_PROG_CC_STDC
 275 AM_PROG_CC_C_O
 276 AC_PROG_INSTALL
 277
 278 AC_SYS_LARGEFILE
 279
 280 PKG_PROG_PKG_CONFIG(0.16)
 281
 282 if test "x$enable_debug" = "xyes"; then
 283   if test x$cflags_set != xset ; then
 284       case " $CFLAGS " in
 285       *[[\ \    ]]-g[[\ \       ]]*) ;;
 286       *) CFLAGS="$CFLAGS -g" ;;
 287       esac
 288   fi
 289   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 290 else
 291   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 292
 293   if test "x$enable_debug" = "xno"; then
 294     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 295   fi
 296 fi
 297
 298 # Ensure MSVC-compatible struct packing convention is used when
 299 # compiling for Win32 with gcc.
 300 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 301 # gcc2 uses "-fnative-struct".
 302 if test x"$glib_native_win32" = xyes; then
 303   if test x"$GCC" = xyes; then
 304     msnative_struct=''
 305     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 306     if test -z "$ac_cv_prog_CC"; then
 307       our_gcc="$CC"
 308     else
 309       our_gcc="$ac_cv_prog_CC"
 310     fi
 311     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 312       2.)
 313         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 314           msnative_struct='-fnative-struct'
 315         fi
 316         ;;
 317       *)
 318         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 319           msnative_struct='-mms-bitfields'
 320         fi
 321         ;;
 322     esac
 323     if test x"$msnative_struct" = x ; then
 324       AC_MSG_RESULT([no way])
 325       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 326     else
 327       CFLAGS="$CFLAGS $msnative_struct"
 328       AC_MSG_RESULT([${msnative_struct}])
 329     fi
 330   fi
 331 fi
 332 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 333 AC_SUBST(GLIB_EXTRA_CFLAGS)
 334
 335 AC_EXEEXT
 336
 337 # define a MAINT-like variable REBUILD which is set if Perl
 338 # and awk are found, so autogenerated sources can be rebuilt
 339 AC_PROG_AWK
 340 AC_CHECK_PROGS(PERL, [perl5 perl])
 341 # We would like indent, but don't require it.
 342 AC_CHECK_PROG(INDENT, indent, indent)
 343 REBUILD=\#
 344 if test "x$enable_rebuilds" = "xyes" && \
 345      test -n "$PERL" && \
 346      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 347      test -n "$AWK" ; then
 348   REBUILD=
 349 fi
 350 AC_SUBST(REBUILD)
 351
 352 # Need full path to Perl for glib-mkenums
 353 #
 354 if test "x$PERL" != x ; then
 355   AC_PATH_PROG(PERL_PATH, [$PERL])
 356 fi
 357 if test "x$PERL_PATH" = x ; then
 358   PERL_PATH="/usr/bin/env perl"
 359 fi
 360 AC_SUBST(PERL_PATH)
 361
 362 # Need suitable python path for greport
 363 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 364
 365
 366 dnl ***********************
 367 dnl *** Tests for iconv ***
 368 dnl ***********************
 369 dnl
 370 dnl We do this before the gettext checks, to avoid distortion
 371
 372 dnl On Windows we use a native implementation
 373
 374 if test x"$glib_native_win32" = xyes; then
 375   with_libiconv=native
 376 else
 377   AC_ARG_WITH(libiconv,
 378               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 379                               [use the libiconv library])],,
 380               [with_libiconv=maybe])
 381
 382   found_iconv=no
 383   case $with_libiconv in
 384     maybe)
 385       # Check in the C library first
 386       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 387       # Check if we have GNU libiconv
 388       if test $found_iconv = "no"; then
 389         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 390       fi
 391       # Check if we have a iconv in -liconv, possibly from vendor
 392       if test $found_iconv = "no"; then
 393         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 394       fi
 395       ;;
 396     no)
 397       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 398       ;;
 399     gnu|yes)
 400       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 401       ;;
 402     native)
 403       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 404       ;;
 405   esac
 406
 407   if test "x$found_iconv" = "xno" ; then
 408      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 409   fi
 410 fi
 411
 412 AC_ARG_ENABLE(iconv-cache,
 413               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 414                               [cache iconv descriptors [default=auto]])],,
 415               [enable_iconv_cache=auto])
 416
 417 AC_MSG_CHECKING([whether to cache iconv descriptors])
 418 case $enable_iconv_cache in
 419   auto)
 420     if test $ac_cv_gnu_library_2_1 = yes; then
 421       enable_iconv_cache=no
 422     else
 423       enable_iconv_cache=yes
 424     fi
 425   ;;
 426   yes|no)
 427   ;;
 428   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 429   ;;
 430 esac
 431
 432 if test $enable_iconv_cache = yes; then
 433    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 434 fi
 435
 436 AC_MSG_RESULT($enable_iconv_cache)
 437
 438
 439 dnl
 440 dnl zlib support
 441 dnl
 442 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 443 if test "x$found_zlib" = "xno" ; then
 444   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 445   if test "x$found_zlib" = "xno" ; then
 446     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 447   fi
 448   ZLIB_LIBS='-lz'
 449   AC_SUBST(ZLIB_LIBS)
 450 fi
 451
 452 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 453 AC_SUBST(LIBFFI_CFLAGS)
 454 AC_SUBST(LIBFFI_LIBS)
 455
 456 dnl
 457 dnl gettext support
 458 dnl
 459
 460 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 461 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 462 GLIB_GNU_GETTEXT
 463
 464 if test "$gt_cv_have_gettext" != "yes" ; then
 465   AC_MSG_ERROR([
 466 *** You must have either have gettext support in your C library, or use the
 467 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 468 ])
 469 fi
 470
 471 LIBS="$INTLLIBS $LIBS"
 472
 473 GETTEXT_PACKAGE=glib20
 474 AC_SUBST(GETTEXT_PACKAGE)
 475 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 476   [Define the gettext package to be used])
 477
 478 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 479
 480 dnl
 481 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 482 dnl
 483
 484 if test x"$glib_native_win32" != xyes; then
 485   if test x$with_libiconv != xno ; then
 486     case " $INTLLIBS " in
 487     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 488     *) ICONV_LIBS="-liconv" ;;
 489     esac
 490   fi
 491 fi
 492 AC_SUBST(ICONV_LIBS)
 493
 494 case $with_libiconv in
 495   gnu)
 496     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 497     ;;
 498   native)
 499     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 500     ;;
 501 esac
 502
 503 dnl Initialize libtool
 504 LT_PREREQ([2.2])
 505 LT_INIT([disable-static win32-dll])
 506 dnl when using libtool 2.x create libtool early, because it's used in configure
 507 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 508
 509
 510 if test "x$GCC" = "xyes"; then
 511   case " $CFLAGS " in
 512   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 513   *) CFLAGS="$CFLAGS -Wall" ;;
 514   esac
 515 fi
 516
 517 if test "$glib_native_win32" = "yes"; then
 518   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 519     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 520   fi
 521   if test x$enable_static = xyes; then
 522     glib_win32_static_compilation=yes
 523     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 524 #define GOBJECT_STATIC_COMPILATION 1"
 525     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 526   fi
 527 fi
 528 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 529
 530 dnl
 531 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 532 dnl
 533 if test $cross_compiling != yes ; then
 534     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 535     glib_save_LIBS=$LIBS
 536     LIBS="$LIBS -lm"
 537     AC_TRY_RUN([#include <math.h>
 538                  int main (void) { return (log(1) != log(1.)); }],
 539          AC_MSG_RESULT(none needed),
 540          glib_save_CFLAGS=$CFLAGS
 541          CFLAGS="$CFLAGS -std1"
 542          AC_TRY_RUN([#include <math.h>
 543                      int main (void) { return (log(1) != log(1.)); }],
 544              AC_MSG_RESULT(-std1),
 545              AC_MSG_RESULT()
 546              CFLAGS=$glib_save_CFLAGS
 547              AC_MSG_WARN(
 548                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 549          )
 550     )
 551     LIBS=$glib_save_LIBS
 552 fi
 553
 554 dnl NeXTStep cc seems to need this
 555 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 556 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 557   AC_MSG_RESULT(none needed),
 558   glib_save_CFLAGS=$CFLAGS
 559   CFLAGS="$CFLAGS -posix"
 560   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 561     AC_MSG_RESULT(-posix),
 562     AC_MSG_RESULT()
 563     CFLAGS=$glib_save_CFLAGS
 564     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 565
 566 # Checks for library functions.
 567 AC_FUNC_VPRINTF
 568 AC_FUNC_ALLOCA
 569 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 570 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 571
 572 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 573 dnl be automatically defined, which we don't want to do
 574 dnl until we have checked this function is actually usable
 575 AC_CHECK_FUNC([qsort_r])
 576
 577 # BSD has a qsort_r with wrong argument order
 578 if test x$ac_cv_func_qsort_r = xyes ; then
 579   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 580   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 581   #define _GNU_SOURCE
 582   #include <stdlib.h>
 583
 584   static int
 585   cmp (const void *a, const void *b, void *c)
 586   {
 587     const int *ia = a;
 588     const int *ib = b;
 589
 590     if (*ia < *ib)
 591       return -1;
 592     else if (*ia > *ib)
 593       return 1;
 594     else
 595       return 0;
 596   }
 597
 598   int
 599   main (int argc, char **argv)
 600   {
 601     int arr[3] = { 1, 2, 0 };
 602     int d = 3;
 603
 604     qsort_r (arr, 3, sizeof (int), cmp, &d);
 605
 606     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 607       return 0;
 608     else
 609       return 1;
 610   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no],[glib_cv_have_qsort_r=no])])
 611 fi
 612
 613 if test x$glib_cv_have_qsort_r = xyes ; then
 614   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 615 fi
 616
 617 AC_CHECK_SIZEOF(char)
 618 AC_CHECK_SIZEOF(short)
 619 AC_CHECK_SIZEOF(long)
 620 AC_CHECK_SIZEOF(int)
 621 AC_CHECK_SIZEOF(void *)
 622 AC_CHECK_SIZEOF(long long)
 623 AC_CHECK_SIZEOF(__int64)
 624
 625 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 626   :
 627 else
 628   AC_MSG_ERROR([
 629 *** GLib requires a 64 bit type. You might want to consider
 630 *** using the GNU C compiler.
 631 ])
 632 fi
 633
 634 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 635         # long long is a 64 bit integer.
 636         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 637         AC_CACHE_VAL(glib_cv_long_long_format,[
 638                 for format in ll q I64; do
 639                   AC_TRY_RUN([#include <stdio.h>
 640                         int main()
 641                         {
 642                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 643                           char buffer[1000];
 644                           sprintf (buffer, "%${format}u", a);
 645                           sscanf (buffer, "%${format}u", &b);
 646                           exit (b!=a);
 647                         }
 648                         ],
 649                         [glib_cv_long_long_format=${format}
 650                         break],
 651                         [],[:])
 652                 done])
 653         if test -n "$glib_cv_long_long_format"; then
 654           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 655           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 656           if test x"$glib_cv_long_long_format" = xI64; then
 657             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 658           fi
 659         else
 660           AC_MSG_RESULT(none)
 661         fi
 662 elif test x$ac_cv_sizeof___int64 = x8; then
 663         # __int64 is a 64 bit integer.
 664         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 665         # We know this is MSVCRT.DLL, and what the formats are
 666         glib_cv_long_long_format=I64
 667         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 668         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 669         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 670 fi
 671
 672 AC_C_CONST
 673
 674 dnl ok, here we try to check whether the systems prototypes for
 675 dnl malloc and friends actually match the prototypes provided
 676 dnl by gmem.h (keep in sync). i currently only know how to check
 677 dnl this reliably with gcc (-Werror), improvements for other
 678 dnl compilers are apprechiated.
 679 SANE_MALLOC_PROTOS=no
 680 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 681 glib_save_CFLAGS=$CFLAGS
 682 if test "x$GCC" = "xyes"; then
 683   CFLAGS="$CFLAGS -Werror"
 684   AC_TRY_COMPILE([#include <stdlib.h>], [
 685     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 686     void* (*my_malloc_p)  (size_t)         = malloc;
 687     void  (*my_free_p)    (void*)          = free;
 688     void* (*my_realloc_p) (void*, size_t)  = realloc;
 689     my_calloc_p = 0;
 690     my_malloc_p = 0;
 691     my_free_p = 0;
 692     my_realloc_p = 0;
 693   ],
 694     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 695       [Define if you have correct malloc prototypes])
 696     SANE_MALLOC_PROTOS=yes)
 697 fi
 698 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 699 CFLAGS=$glib_save_CFLAGS
 700
 701 dnl
 702 dnl check in which direction the stack grows
 703 dnl
 704 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 705         AC_TRY_RUN([
 706         volatile int *a = 0, *b = 0;
 707         void foo (void);
 708         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 709         void foo (void) { volatile int x = 5; b = &x; }
 710         ],
 711         glib_cv_stack_grows=no
 712         ,
 713         glib_cv_stack_grows=yes
 714         ,)
 715 ])
 716
 717 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 718 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 719 dnl actually supported.
 720 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 721         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 722         __inline int foo () { return 0; }
 723         int main () { return foo (); }
 724         ]])],
 725         glib_cv_has__inline=yes
 726         ,
 727         glib_cv_has__inline=no
 728         ,)
 729 ])
 730 case x$glib_cv_has__inline in
 731 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 732 esac
 733 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 734         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 735         __inline__ int foo () { return 0; }
 736         int main () { return foo (); }
 737         ]])],
 738         glib_cv_has__inline__=yes
 739         ,
 740         glib_cv_has__inline__=no
 741         ,)
 742 ])
 743 case x$glib_cv_has__inline__ in
 744 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 745 esac
 746 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 747         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 748         #undef inline
 749         inline int foo () { return 0; }
 750         int main () { return foo (); }
 751         ]])],
 752         glib_cv_hasinline=yes
 753         ,
 754         glib_cv_hasinline=no
 755         ,)
 756 ])
 757 case x$glib_cv_hasinline in
 758 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 759 esac
 760
 761 # if we can use inline functions in headers
 762 AC_MSG_CHECKING(if inline functions in headers work)
 763 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 764 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 765 #  undef inline
 766 #  define inline __inline__
 767 #elif !defined (G_HAVE_INLINE)
 768 #  undef inline
 769 #  if defined (G_HAVE___INLINE__)
 770 #    define inline __inline__
 771 #  elif defined (G_HAVE___INLINE)
 772 #    define inline __inline
 773 #  endif
 774 #endif
 775
 776 int glib_test_func2 (int);
 777
 778 static inline int
 779 glib_test_func1 (void) {
 780   return glib_test_func2 (1);
 781 }
 782
 783 int
 784 main (void) {
 785   int i = 1;
 786 }]])],[g_can_inline=yes],[g_can_inline=no])
 787 AC_MSG_RESULT($g_can_inline)
 788
 789 dnl *** check for working do while(0) macros ***
 790 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 791         AC_TRY_COMPILE([],[
 792         #define STMT_START do
 793         #define STMT_END while(0)
 794         #define STMT_TEST STMT_START { i = 0; } STMT_END
 795         int main(void) { int i = 1; STMT_TEST; return i; }],
 796         [g_cv_support_dowhile_macros=yes],
 797         [g_cv_support_dowhile_macros=no],
 798         [g_cv_support_dowhile_macros=yes])
 799 ])
 800 if test x$g_cv_support_dowhile_macros = xyes; then
 801   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 802 fi
 803
 804 # check for flavours of varargs macros
 805 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 806 AC_TRY_COMPILE([],[
 807 int a(int p1, int p2, int p3);
 808 #define call_a(...) a(1,__VA_ARGS__)
 809 call_a(2,3);
 810 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 811 AC_MSG_RESULT($g_have_iso_c_varargs)
 812
 813 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 814 if test "$CXX" = ""; then
 815 dnl No C++ compiler
 816   g_have_iso_cxx_varargs=no
 817 else
 818   AC_LANG_CPLUSPLUS
 819   AC_TRY_COMPILE([],[
 820 int a(int p1, int p2, int p3);
 821 #define call_a(...) a(1,__VA_ARGS__)
 822 call_a(2,3);
 823 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 824   AC_LANG_C
 825 fi
 826 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 827
 828 AC_MSG_CHECKING(for GNUC varargs macros)
 829 AC_TRY_COMPILE([],[
 830 int a(int p1, int p2, int p3);
 831 #define call_a(params...) a(1,params)
 832 call_a(2,3);
 833 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 834 AC_MSG_RESULT($g_have_gnuc_varargs)
 835
 836 # check for GNUC visibility support
 837 AC_MSG_CHECKING(for GNUC visibility attribute)
 838 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 839 void
 840 __attribute__ ((visibility ("hidden")))
 841      f_hidden (void)
 842 {
 843 }
 844 void
 845 __attribute__ ((visibility ("internal")))
 846      f_internal (void)
 847 {
 848 }
 849 void
 850 __attribute__ ((visibility ("protected")))
 851      f_protected (void)
 852 {
 853 }
 854 void
 855 __attribute__ ((visibility ("default")))
 856      f_default (void)
 857 {
 858 }
 859 int main (int argc, char **argv)
 860 {
 861         f_hidden();
 862         f_internal();
 863         f_protected();
 864         f_default();
 865         return 0;
 866 }
 867 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 868 AC_MSG_RESULT($g_have_gnuc_visibility)
 869 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 870
 871 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 872 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 873 #else
 874 # include "error: this is not Sun Studio."
 875 #endif
 876 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 877 AC_MSG_RESULT($g_have_sunstudio_visibility)
 878 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 879
 880 # check for bytesex stuff
 881 AC_C_BIGENDIAN
 882 if test x$ac_cv_c_bigendian = xuniversal ; then
 883 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 884 #else
 885 #error Not a big endian.
 886 #endif],
 887     ac_cv_c_bigendian=yes
 888     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 889 #else
 890 #error Not a little endian.
 891 #endif],
 892     ac_cv_c_bigendian=no
 893     ,AC_MSG_WARN([Could not determine endianness.])))
 894 fi
 895
 896
 897 # check for header files
 898 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 899 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 900 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 901 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 902 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 903 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 904 AC_CHECK_HEADERS([linux/magic.h])
 905 AC_CHECK_HEADERS([sys/prctl.h])
 906
 907 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 908 [#if HAVE_SYS_PARAM_H
 909  #include <sys/param.h>
 910  #endif
 911 ])
 912
 913 AC_CHECK_HEADERS([xlocale.h])
 914
 915 # check for structure fields
 916 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 917 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 918 #include <sys/stat.h>
 919 #include <unistd.h>
 920 #ifdef HAVE_SYS_STATFS_H
 921 #include <sys/statfs.h>
 922 #endif
 923 #ifdef HAVE_SYS_PARAM_H
 924 #include <sys/param.h>
 925 #endif
 926 #ifdef HAVE_SYS_MOUNT_H
 927 #include <sys/mount.h>
 928 #endif])
 929 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 930 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 931 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 932 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 933
 934 AC_STRUCT_DIRENT_D_TYPE
 935
 936 # Checks for libcharset
 937 AM_LANGINFO_CODESET
 938 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 939 AC_CHECK_FUNCS(setlocale)
 940
 941 # check additional type sizes
 942 AC_CHECK_SIZEOF(size_t)
 943
 944 dnl Try to figure out whether gsize, gssize should be long or int
 945 AC_MSG_CHECKING([for the appropriate definition for size_t])
 946
 947 case $ac_cv_sizeof_size_t in
 948   $ac_cv_sizeof_short)
 949       glib_size_type=short
 950       ;;
 951   $ac_cv_sizeof_int)
 952       glib_size_type=int
 953       ;;
 954   $ac_cv_sizeof_long)
 955       glib_size_type=long
 956       ;;
 957   $ac_cv_sizeof_long_long)
 958       glib_size_type='long long'
 959       ;;
 960   $ac_cv_sizeof__int64)
 961       glib_size_type='__int64'
 962       ;;
 963   *)  AC_MSG_ERROR([No type matching size_t in size])
 964       ;;
 965 esac
 966
 967 dnl If int/long are the same size, we see which one produces
 968 dnl warnings when used in the location as size_t. (This matters
 969 dnl on AIX with xlc)
 970 dnl
 971 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 972    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 973   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 974 #if defined(_AIX) && !defined(__GNUC__)
 975 #pragma options langlvl=stdc89
 976 #endif
 977 #include <stddef.h>
 978 int main ()
 979 {
 980   size_t s = 1;
 981   unsigned int *size_int = &s;
 982   return (int)*size_int;
 983 }
 984     ]])],glib_size_type=int,
 985       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 986 #if defined(_AIX) && !defined(__GNUC__)
 987 #pragma options langlvl=stdc89
 988 #endif
 989 #include <stddef.h>
 990 int main ()
 991 {
 992    size_t s = 1;
 993    unsigned long *size_long = &s;
 994    return (int)*size_long;
 995 }
 996         ]])],glib_size_type=long)])
 997 fi
 998
 999 AC_MSG_RESULT(unsigned $glib_size_type)
1000
1001 # Check for some functions
1002 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1003 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1004 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1005 # Check for high-resolution sleep functions
1006 AC_CHECK_FUNCS(splice)
1007 AC_CHECK_FUNCS(prlimit)
1008
1009 # To avoid finding a compatibility unusable statfs, which typically
1010 # successfully compiles, but warns to use the newer statvfs interface:
1011 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1012 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1013
1014 AC_MSG_CHECKING([whether to use statfs or statvfs])
1015 # Some systems have both statfs and statvfs, pick the most "native" for these
1016 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1017    [
1018    # on solaris and irix, statfs doesn't even have the f_bavail field
1019    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1020       [ac_cv_func_statfs=no],
1021    # else, at least on linux, statfs is the actual syscall
1022       [ac_cv_func_statvfs=no])
1023    ])
1024
1025 AS_IF([test x$ac_cv_func_statfs = xyes],
1026       [
1027          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1028          AC_MSG_RESULT([statfs])
1029       ],
1030       [test x$ac_cv_func_statvfs = xyes],
1031       [
1032          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1033          AC_MSG_RESULT([statvfs])
1034       ],
1035       [  AC_MSG_RESULT([neither])])
1036
1037 AC_CHECK_HEADERS(crt_externs.h)
1038 AC_CHECK_FUNCS(_NSGetEnviron)
1039
1040 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1041
1042 AC_FUNC_VSNPRINTF_C99
1043 AC_FUNC_PRINTF_UNIX98
1044
1045 # Internet address families
1046 if test $glib_native_win32 = yes; then
1047   glib_inet_includes=["
1048 #include <winsock2.h>
1049   "]
1050 else
1051   glib_inet_includes=["
1052 #include <sys/types.h>
1053 #include <sys/socket.h>
1054   "]
1055 fi
1056
1057 glib_failed=false
1058 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1059 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1060 # winsock defines this even though it doesn't support it
1061 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1062 if $glib_failed ; then
1063   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1064 fi
1065
1066 glib_failed=false
1067 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1068 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1069 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1070 if $glib_failed ; then
1071   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1072 fi
1073
1074 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1075 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1076
1077 if test $glib_native_win32 = no; then
1078   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1079   NETWORK_LIBS=""
1080   AC_MSG_CHECKING([for res_query])
1081   AC_TRY_LINK([#include <sys/types.h>
1082                #include <netinet/in.h>
1083                #include <arpa/nameser.h>
1084                #include <resolv.h>
1085               ],[
1086                res_query("test", 0, 0, (void *)0, 0);
1087               ],[AC_MSG_RESULT([yes])],
1088               [save_libs="$LIBS"
1089                LIBS="-lresolv $LIBS"
1090                AC_TRY_LINK([#include <sys/types.h>
1091                             #include <netinet/in.h>
1092                             #include <arpa/nameser.h>
1093                             #include <resolv.h>
1094                            ],[
1095                             res_query("test", 0, 0, (void *)0, 0);
1096                            ],[AC_MSG_RESULT([in -lresolv])
1097                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1098                            [LIBS="-lbind $save_libs"
1099                             AC_TRY_LINK([#include <resolv.h>],
1100                                         [res_query("test", 0, 0, (void *)0, 0);],
1101                                         [AC_MSG_RESULT([in -lbind])
1102                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1103                                         [AC_MSG_ERROR(not found)])])
1104                LIBS="$save_libs"])
1105   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1106                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1107                                         [AC_MSG_ERROR(Could not find socket())]))
1108 fi
1109 AC_SUBST(NETWORK_LIBS)
1110
1111 AC_CHECK_HEADER([linux/netlink.h],
1112                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1113                 [#include <sys/socket.h>])
1114 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1115
1116 AC_CHECK_TYPE([struct ip_mreqn], [
1117               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1118               [#include <netinet/in.h>])
1119
1120 case $host in
1121   *-*-solaris* )
1122      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1123      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1124      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1125      ;;
1126 esac
1127
1128 dnl
1129 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1130 dnl
1131 if test "$ac_cv_func_statfs" = yes ; then
1132   AC_MSG_CHECKING([number of arguments to statfs()])
1133   AC_TRY_COMPILE([#include <unistd.h>
1134   #ifdef HAVE_SYS_PARAM_H
1135   #include <sys/param.h>
1136   #endif
1137   #ifdef HAVE_SYS_VFS_H
1138   #include <sys/vfs.h>
1139   #endif
1140   #ifdef HAVE_SYS_MOUNT_H
1141   #include <sys/mount.h>
1142   #endif
1143   #ifdef HAVE_SYS_STATFS_H
1144   #include <sys/statfs.h>
1145   #endif], [struct statfs st;
1146   statfs(NULL, &st);],[
1147     AC_MSG_RESULT([2])
1148     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1149     AC_TRY_COMPILE([#include <unistd.h>
1150   #ifdef HAVE_SYS_PARAM_H
1151   #include <sys/param.h>
1152   #endif
1153   #ifdef HAVE_SYS_VFS_H
1154   #include <sys/vfs.h>
1155   #endif
1156   #ifdef HAVE_SYS_MOUNT_H
1157   #include <sys/mount.h>
1158   #endif
1159   #ifdef HAVE_SYS_STATFS_H
1160   #include <sys/statfs.h>
1161   #endif], [struct statfs st;
1162   statfs(NULL, &st, sizeof (st), 0);],[
1163       AC_MSG_RESULT([4])
1164       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1165       AC_MSG_RESULT(unknown)
1166       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1167 fi
1168
1169 #
1170 # Check whether to use an included printf
1171 #
1172
1173 AC_ARG_ENABLE(included-printf,
1174               [AC_HELP_STRING([--enable-included-printf],
1175                               [use included printf [default=auto]])],
1176               enable_included_printf="$enableval")
1177
1178 need_included_printf=no
1179 if test "x$enable_included_printf" = "xyes" ; then
1180   need_included_printf=yes
1181 fi
1182 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1183   need_included_printf=yes
1184 fi
1185 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1186   need_included_printf=yes
1187 fi
1188 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1189    test -z "$glib_cv_long_long_format" ; then
1190   need_included_printf=yes
1191 fi
1192
1193 if test "x$enable_included_printf" = "xno" &&
1194    test "x$need_included_printf" = "xyes" ; then
1195   AC_MSG_ERROR([
1196 *** Your C library's printf doesn't appear to have the features that
1197 *** GLib needs, but you specified --enable-included-printf=no.])
1198 fi
1199
1200 enable_included_printf=$need_included_printf
1201
1202 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1203 if test "$enable_included_printf" != "yes" ; then
1204   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1205 else
1206   if test -z "$glib_cv_long_long_format" ; then
1207     glib_cv_long_long_format="ll"
1208   fi
1209   AC_DEFINE(HAVE_VASPRINTF,1)
1210 fi
1211
1212 # Checks needed for gnulib vasnprintf
1213 bh_C_SIGNED
1214 jm_AC_TYPE_LONG_LONG
1215 gt_TYPE_LONGDOUBLE
1216 gt_TYPE_WCHAR_T
1217 gt_TYPE_WINT_T
1218 AC_TYPE_SIZE_T
1219 AC_CHECK_TYPES(ptrdiff_t)
1220 jm_AC_TYPE_INTMAX_T
1221 AC_CHECK_FUNCS([snprintf wcslen])
1222 AC_FUNC_SNPRINTF_C99
1223
1224 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1225 # The check is borrowed from the PERL Configure script.
1226 if test "$ac_cv_func_memmove" != "yes"; then
1227   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1228     glib_cv_working_bcopy,[AC_TRY_RUN([
1229       int main() {
1230         char buf[128], abc[128], *b;
1231         int len, off, align;
1232         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1233         for (align = 7; align >= 0; align--) {
1234           for (len = 36; len; len--) {
1235             b = buf+align; bcopy(abc, b, len);
1236             for (off = 1; off <= len; off++) {
1237               bcopy(b, b+off, len); bcopy(b+off, b, len);
1238                 if (bcmp(b, abc, len)) return(1);
1239             }
1240           }
1241         }
1242         return(0);
1243       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1244
1245   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1246   if test "$glib_cv_working_bcopy" = "yes"; then
1247     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1248   fi
1249 fi
1250
1251 # Check if <sys/select.h> needs to be included for fd_set
1252 AC_MSG_CHECKING([for fd_set])
1253 AC_TRY_COMPILE([#include <sys/types.h>],
1254         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1255 if test "$gtk_ok" = "yes"; then
1256     AC_MSG_RESULT([yes, found in sys/types.h])
1257 else
1258     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1259     if test "$gtk_ok" = "yes"; then
1260         # *** FIXME: give it a different name
1261         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1262         AC_MSG_RESULT([yes, found in sys/select.h])
1263     else
1264         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1265         AC_MSG_RESULT(no)
1266     fi
1267 fi
1268
1269 dnl *** check for sane realloc() ***
1270 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1271         AC_TRY_RUN([#include <stdlib.h>
1272         int main() {
1273           return realloc (0, sizeof (int)) == 0;
1274         }],
1275         [glib_cv_sane_realloc=yes],
1276         [glib_cv_sane_realloc=no],
1277         [glib_cv_sane_realloc=yes])
1278 ])
1279 if test x$glib_cv_sane_realloc = xyes; then
1280   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1281 fi
1282
1283 dnl Check for nl_langinfo and CODESET
1284 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1285         AC_TRY_COMPILE([#include <langinfo.h>],
1286                 [char *codeset = nl_langinfo (CODESET);],
1287                 [glib_cv_langinfo_codeset=yes],
1288                 [glib_cv_langinfo_codeset=no])])
1289 if test x$glib_cv_langinfo_codeset = xyes; then
1290   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1291 fi
1292
1293 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1294 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1295         AC_TRY_COMPILE([#include <langinfo.h>],
1296                 [char *str;
1297                  str = nl_langinfo (PM_STR);
1298                  str = nl_langinfo (D_T_FMT);
1299                  str = nl_langinfo (D_FMT);
1300                  str = nl_langinfo (T_FMT);
1301                  str = nl_langinfo (T_FMT_AMPM);
1302                  str = nl_langinfo (MON_1);
1303                  str = nl_langinfo (ABMON_12);
1304                  str = nl_langinfo (DAY_1);
1305                  str = nl_langinfo (ABDAY_7);],
1306                 [glib_cv_langinfo_time=yes],
1307                 [glib_cv_langinfo_time=no])])
1308 if test x$glib_cv_langinfo_time = xyes; then
1309   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1310 fi
1311
1312 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1313 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1314         AC_TRY_COMPILE([#include <langinfo.h>],
1315                 [char *str;
1316                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1317                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1318                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1319                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1320                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1321                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1322                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1323                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1324                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1325                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1326                 [glib_cv_langinfo_outdigit=yes],
1327                 [glib_cv_langinfo_outdigit=no])])
1328 if test x$glib_cv_langinfo_outdigit = xyes; then
1329   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1330 fi
1331
1332 dnl ****************************************
1333 dnl *** posix_memalign                   ***
1334 dnl ****************************************
1335 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1336 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1337     glib_cv_compliant_posix_memalign=0
1338     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1339         AC_TRY_RUN([
1340                 #define _XOPEN_SOURCE 600
1341                 #include <stdlib.h> /* posix_memalign() should be defined here */
1342                 /* some systems break if #include <malloc.h> used */
1343                 static void test_memalign (size_t boundary, size_t size) {
1344                     void *mem = 0;
1345                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1346                         exit (1);
1347                     else
1348                       free (mem);
1349                 }
1350                 int main() {
1351                     test_memalign (  128,   128 - 2 * sizeof (void*));
1352                     test_memalign (  256,   256 - 2 * sizeof (void*));
1353                     test_memalign (  512,   512 - 2 * sizeof (void*));
1354                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1355                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1356                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1357                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1358                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1359                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1360                     exit (0); /* success */
1361                 }
1362                 ],
1363             [glib_cv_compliant_posix_memalign=1], [], [:])
1364       :
1365     fi
1366     ])
1367 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1368     AC_MSG_RESULT(yes)
1369     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1370 else
1371     AC_MSG_RESULT(no)
1372 fi
1373
1374
1375 dnl ****************************************
1376 dnl *** strlcpy/strlcat                  ***
1377 dnl ****************************************
1378 # Check for strlcpy
1379 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1380 AC_TRY_RUN([#include <stdlib.h>
1381 #include <string.h>
1382 int main() {
1383   char p[10];
1384   (void) strlcpy (p, "hi", 10);
1385   if (strlcat (p, "bye", 0) != 3)
1386     return 1;
1387   return 0;
1388 }], glib_cv_have_strlcpy=yes,
1389     glib_cv_have_strlcpy=no,
1390     glib_cv_have_strlcpy=no)])
1391 if test "$glib_cv_have_strlcpy" = "yes"; then
1392     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1393 fi
1394
1395
1396 dnl **********************
1397 dnl *** va_copy checks ***
1398 dnl **********************
1399 dnl we currently check for all three va_copy possibilities, so we get
1400 dnl all results in config.log for bug reports.
1401 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1402         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1403 #include <stdlib.h>
1404         void f (int i, ...) {
1405         va_list args1, args2;
1406         va_start (args1, i);
1407         va_copy (args2, args1);
1408         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1409           exit (1);
1410         va_end (args1); va_end (args2);
1411         }
1412         int main() {
1413           f (0, 42);
1414           return 0;
1415         }]])],
1416         [glib_cv_va_copy=yes],
1417         [glib_cv_va_copy=no])
1418 ])
1419 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1420         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1421 #include <stdlib.h>
1422         void f (int i, ...) {
1423         va_list args1, args2;
1424         va_start (args1, i);
1425         __va_copy (args2, args1);
1426         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1427           exit (1);
1428         va_end (args1); va_end (args2);
1429         }
1430         int main() {
1431           f (0, 42);
1432           return 0;
1433         }]])],
1434         [glib_cv___va_copy=yes],
1435         [glib_cv___va_copy=no])
1436 ])
1437
1438 if test "x$glib_cv_va_copy" = "xyes"; then
1439   g_va_copy_func=va_copy
1440 else if test "x$glib_cv___va_copy" = "xyes"; then
1441   g_va_copy_func=__va_copy
1442 fi
1443 fi
1444
1445 if test -n "$g_va_copy_func"; then
1446   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1447 fi
1448
1449 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1450         AC_TRY_RUN([#include <stdarg.h>
1451 #include <stdlib.h>
1452         void f (int i, ...) {
1453         va_list args1, args2;
1454         va_start (args1, i);
1455         args2 = args1;
1456         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1457           exit (1);
1458         va_end (args1); va_end (args2);
1459         }
1460         int main() {
1461           f (0, 42);
1462           return 0;
1463         }],
1464         [glib_cv_va_val_copy=yes],
1465         [glib_cv_va_val_copy=no],
1466         [glib_cv_va_val_copy=yes])
1467 ])
1468
1469 if test "x$glib_cv_va_val_copy" = "xno"; then
1470   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1471 fi
1472
1473 dnl ***********************
1474 dnl *** g_module checks ***
1475 dnl ***********************
1476 G_MODULE_LIBS=
1477 G_MODULE_LIBS_EXTRA=
1478 G_MODULE_PLUGIN_LIBS=
1479 if test x"$glib_native_win32" = xyes; then
1480   dnl No use for this on Win32
1481   G_MODULE_LDFLAGS=
1482 else
1483   export SED
1484   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1485 fi
1486 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1487 G_MODULE_NEED_USCORE=0
1488 G_MODULE_BROKEN_RTLD_GLOBAL=0
1489 G_MODULE_HAVE_DLERROR=0
1490 dnl *** force native WIN32 shared lib loader
1491 if test -z "$G_MODULE_IMPL"; then
1492   case "$host" in
1493   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1494   esac
1495 fi
1496 dnl *** force native AIX library loader
1497 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1498 if test -z "$G_MODULE_IMPL"; then
1499   case "$host" in
1500   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1501   esac
1502 fi
1503 dnl *** dlopen() and dlsym() in system libraries
1504 if test -z "$G_MODULE_IMPL"; then
1505         AC_CHECK_FUNC(dlopen,
1506                       [AC_CHECK_FUNC(dlsym,
1507                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1508                       [])
1509 fi
1510 dnl *** load_image (BeOS)
1511 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1512   AC_CHECK_LIB(root, load_image,
1513       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1514       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1515       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1516       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1517       [])
1518 fi
1519 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1520 if test -z "$G_MODULE_IMPL"; then
1521         AC_CHECK_FUNC(NSLinkModule,
1522                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1523                        G_MODULE_NEED_USCORE=1],
1524                       [])
1525 fi
1526 dnl *** dlopen() and dlsym() in libdl
1527 if test -z "$G_MODULE_IMPL"; then
1528         AC_CHECK_LIB(dl, dlopen,
1529                      [AC_CHECK_LIB(dl, dlsym,
1530                                    [G_MODULE_LIBS=-ldl
1531                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1532                      [])
1533 fi
1534 dnl *** shl_load() in libdld (HP-UX)
1535 if test -z "$G_MODULE_IMPL"; then
1536         AC_CHECK_LIB(dld, shl_load,
1537                 [G_MODULE_LIBS=-ldld
1538                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1539                 [])
1540 fi
1541 dnl *** additional checks for G_MODULE_IMPL_DL
1542 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1543         LIBS_orig="$LIBS"
1544         LDFLAGS_orig="$LDFLAGS"
1545         LIBS="$G_MODULE_LIBS $LIBS"
1546         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1547 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1548         echo "void glib_plugin_test(void) { }" > plugin.c
1549         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1550                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1551         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1552                 glib_cv_rtldglobal_broken,[
1553                 AC_TRY_RUN([
1554 #include <dlfcn.h>
1555 #ifndef RTLD_GLOBAL
1556 #  define RTLD_GLOBAL 0
1557 #endif
1558 #ifndef RTLD_LAZY
1559 #  define RTLD_LAZY 0
1560 #endif
1561 int glib_plugin_test;
1562 int main () {
1563     void *handle, *global, *local;
1564     global = &glib_plugin_test;
1565     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1566     if (!handle) return 0;
1567     local = dlsym (handle, "glib_plugin_test");
1568     return global == local;
1569 }                       ],
1570                         [glib_cv_rtldglobal_broken=no],
1571                         [glib_cv_rtldglobal_broken=yes],
1572                         [glib_cv_rtldglobal_broken=no])
1573                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1574                 rmdir .libs 2>/dev/null
1575         ])
1576         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1577                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1578         else
1579                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1580         fi
1581 dnl *** check whether we need preceeding underscores
1582         AC_CACHE_CHECK([for preceeding underscore in symbols],
1583                 glib_cv_uscore,[
1584                 AC_TRY_RUN([#include <dlfcn.h>
1585                 int glib_underscore_test (void) { return 42; }
1586                 int main() {
1587                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1588                   handle = dlopen ((void*)0, 0);
1589                   if (handle) {
1590                     f1 = dlsym (handle, "glib_underscore_test");
1591                     f2 = dlsym (handle, "_glib_underscore_test");
1592                   } return (!f2 || f1);
1593                 }],
1594                         [glib_cv_uscore=yes],
1595                         [glib_cv_uscore=no],
1596                         [])
1597                 rm -f plugin.c plugin.$ac_objext plugin.lo
1598         ])
1599         GLIB_ASSERT_SET(glib_cv_uscore)
1600         if test "x$glib_cv_uscore" = "xyes"; then
1601                 G_MODULE_NEED_USCORE=1
1602         else
1603                 G_MODULE_NEED_USCORE=0
1604         fi
1605
1606         LDFLAGS="$LDFLAGS_orig"
1607 dnl *** check for having dlerror()
1608         AC_CHECK_FUNC(dlerror,
1609                 [G_MODULE_HAVE_DLERROR=1],
1610                 [G_MODULE_HAVE_DLERROR=0])
1611         LIBS="$LIBS_orig"
1612 fi
1613 dnl *** done, have we got an implementation?
1614 if test -z "$G_MODULE_IMPL"; then
1615         G_MODULE_IMPL=0
1616         G_MODULE_SUPPORTED=false
1617 else
1618         G_MODULE_SUPPORTED=true
1619 fi
1620
1621 AC_MSG_CHECKING(for the suffix of module shared libraries)
1622 export SED
1623 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1624 eval $shrext_cmds
1625 module=yes eval std_shrext=$shrext_cmds
1626 # chop the initial dot
1627 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1628 AC_MSG_RESULT(.$glib_gmodule_suffix)
1629 # any reason it may fail?
1630 if test "x$glib_gmodule_suffix" = x; then
1631         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1632 fi
1633
1634 AC_SUBST(G_MODULE_SUPPORTED)
1635 AC_SUBST(G_MODULE_IMPL)
1636 AC_SUBST(G_MODULE_LIBS)
1637 AC_SUBST(G_MODULE_LIBS_EXTRA)
1638 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1639 AC_SUBST(G_MODULE_LDFLAGS)
1640 AC_SUBST(G_MODULE_HAVE_DLERROR)
1641 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1642 AC_SUBST(G_MODULE_NEED_USCORE)
1643 AC_SUBST(GLIB_DEBUG_FLAGS)
1644
1645 dnl **********************
1646 dnl *** g_spawn checks ***
1647 dnl **********************
1648
1649 AC_MSG_CHECKING(for gspawn implementation)
1650 case "$host" in
1651   *-*-mingw*)
1652     GSPAWN=gspawn-win32.lo
1653     ;;
1654   *)
1655     GSPAWN=gspawn.lo
1656     ;;
1657 esac
1658 AC_MSG_RESULT($GSPAWN)
1659 AC_SUBST(GSPAWN)
1660
1661 dnl *************************
1662 dnl *** GIOChannel checks ***
1663 dnl *************************
1664
1665 AC_MSG_CHECKING(for GIOChannel implementation)
1666 case "$host" in
1667   *-*-mingw*)
1668     GIO=giowin32.lo
1669     ;;
1670   *)
1671     GIO=giounix.lo
1672     ;;
1673 esac
1674 AC_MSG_RESULT($GIO)
1675 AC_SUBST(GIO)
1676
1677 dnl *********************************
1678 dnl *** Directory for GIO modules ***
1679 dnl *********************************
1680
1681 AC_ARG_WITH(gio-module-dir,
1682            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1683                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1684            [],
1685            [with_gio_module_dir='${libdir}/gio/modules'])
1686 GIO_MODULE_DIR=$with_gio_module_dir
1687 AC_SUBST(GIO_MODULE_DIR)
1688
1689 dnl **********************************
1690 dnl *** Check for libselinux (GIO) ***
1691 dnl **********************************
1692 AC_ARG_ENABLE(selinux,
1693               AC_HELP_STRING([--disable-selinux],
1694                              [build without selinux support]))
1695 msg_selinux=no
1696 SELINUX_LIBS=
1697 if test "x$enable_selinux" != "xno"; then
1698
1699  AC_CHECK_LIB(selinux, is_selinux_enabled,
1700    [AC_CHECK_HEADERS(selinux/selinux.h,
1701      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1702        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1703         SELINUX_LIBS="-lselinux"
1704         msg_selinux=yes])
1705      ])
1706    ])
1707 fi
1708 AC_SUBST(SELINUX_LIBS)
1709
1710 dnl *****************************
1711 dnl ** Check for inotify (GIO) **
1712 dnl *****************************
1713 inotify_support=no
1714 AC_CHECK_HEADERS([sys/inotify.h],
1715 [
1716         inotify_support=yes
1717         AC_CHECK_FUNCS(inotify_init1)
1718 ])
1719
1720 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1721
1722 dnl *********************************
1723 dnl ** Check for Solaris FEN (GIO) **
1724 dnl *********************************
1725 fen_support=no
1726 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1727 #include <port.h>
1728 #ifndef PORT_SOURCE_FILE
1729 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1730 #endif
1731 int main() { return 0; } ]])],
1732 [
1733         fen_support=yes
1734 ],)
1735
1736 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1737
1738 dnl ****************************
1739 dnl *** Checks for FAM (GIO) ***
1740 dnl ****************************
1741
1742 should_disable_fam=no
1743
1744 AC_ARG_ENABLE(fam,
1745               AC_HELP_STRING([--disable-fam],
1746                              [don't use fam for file system monitoring]),
1747                          [
1748                                 if test "x$enable_fam" = "xno"; then
1749                                         should_disable_fam=yes
1750                                 fi
1751                          ]
1752                          )
1753 fam_support=no
1754 FAM_LIBS=
1755 if test "x$should_disable_fam" = "xno"; then
1756 AC_CHECK_LIB(fam, FAMOpen,
1757   [AC_CHECK_HEADERS(fam.h,
1758     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1759      AC_CHECK_LIB(fam, FAMNoExists,
1760                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1761      FAM_LIBS="-lfam"]
1762      fam_support=yes,
1763     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1764   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1765 AC_SUBST(FAM_LIBS)
1766 fi
1767 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1768
1769
1770 dnl *****************************
1771 dnl *** Check for xattr (GIO) ***
1772 dnl *****************************
1773 AC_ARG_ENABLE(xattr,
1774               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1775 msg_xattr=no
1776 XATTR_LIBS=
1777 if test "x$enable_xattr" != "xno"; then
1778
1779 dnl either glibc or libattr can provide xattr support
1780
1781 dnl for both of them, we check for getxattr being in
1782 dnl the library and a valid xattr header.
1783
1784 dnl try glibc
1785  AC_CHECK_LIB(c, getxattr,
1786    [AC_CHECK_HEADERS(sys/xattr.h,
1787      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1788       msg_xattr=yes])
1789    ])
1790
1791   if test "x$msg_xattr" != "xyes"; then
1792 dnl   failure. try libattr
1793    AC_CHECK_LIB(attr, getxattr,
1794       [AC_CHECK_HEADERS(attr/xattr.h,
1795        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1796         XATTR_LIBS="-lattr"
1797         msg_xattr=yes])
1798       ])
1799   fi
1800
1801   if test "x$msg_xattr" = "xyes"; then
1802     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1803     AC_TRY_COMPILE([
1804       #include <stdio.h>
1805       #ifdef HAVE_SYS_TYPES_H
1806       #include <sys/types.h>
1807       #endif
1808       #ifdef HAVE_SYS_XATTR_H
1809       #include <sys/xattr.h>
1810       #elif HAVE_ATTR_XATTR_H
1811       #include <attr/xattr.h>
1812       #endif
1813     ],
1814     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1815     [
1816       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1817       AC_MSG_RESULT([yes])
1818     ],
1819     [AC_MSG_RESULT([no])]
1820     )
1821   fi
1822
1823 fi
1824 AC_SUBST(XATTR_LIBS)
1825
1826 dnl ************************
1827 dnl *** check for libelf ***
1828 dnl ************************
1829
1830 AC_CHECK_LIB([elf], [elf_begin], have_libelf=yes, have_libelf=no)
1831 if test $have_libelf = yes; then
1832   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1833   ELF_LIBS=-lelf
1834 fi
1835 AC_SUBST(ELF_LIBS)
1836
1837 dnl ****************************************
1838 dnl *** platform dependent source checks ***
1839 dnl ****************************************
1840
1841 AC_MSG_CHECKING(for platform-dependent source)
1842 case "$host" in
1843   *-*-cygwin*|*-*-mingw*)
1844     PLATFORMDEP=gwin32.lo
1845     ;;
1846   *)
1847     PLATFORMDEP=
1848     ;;
1849 esac
1850 AC_MSG_RESULT($PLATFORMDEP)
1851 AC_SUBST(PLATFORMDEP)
1852
1853 AC_MSG_CHECKING([whether to compile timeloop])
1854 case "$host" in
1855   *-*-cygwin*|*-*-mingw*|*-*-minix)
1856     enable_timeloop=no
1857     ;;
1858   *)
1859     enable_timeloop=yes
1860     ;;
1861 esac
1862 AC_MSG_RESULT($enable_timeloop)
1863 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1864
1865 AC_MSG_CHECKING([if building for some Win32 platform])
1866 case "$host" in
1867   *-*-mingw*|*-*-cygwin*)
1868     platform_win32=yes
1869     ;;
1870   *)
1871     platform_win32=no
1872     ;;
1873 esac
1874 AC_MSG_RESULT($platform_win32)
1875 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1876
1877 dnl ***********************
1878 dnl *** g_thread checks ***
1879 dnl ***********************
1880
1881 AC_ARG_WITH(threads,
1882            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1883                            [specify a thread implementation to use])],
1884            [],
1885            [with_threads=yes])
1886
1887 dnl error and warning message
1888 dnl *************************
1889
1890 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1891
1892 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1893                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1894                 compilation now, but then your programs might not work.
1895                 Please provide information on how it is done on your system."
1896
1897 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1898                  "
1899
1900 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1901                   provide information on your thread implementation."
1902
1903 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1904                 functions will not be MT-safe during their first call because
1905                 there is no working 'getpwuid_r' on your system."
1906
1907 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1908                 because there is no 'localtime_r' on your system."
1909
1910 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1911                 linking threaded applications. As GLib cannot do that
1912                 automatically, you will get an linkg error everytime you are
1913                 not using the right compiler. In that case you have to relink
1914                 with the right compiler. Ususally just '_r' is appended
1915                 to the compiler name."
1916
1917 dnl determination of thread implementation
1918 dnl ***************************************
1919
1920 AC_MSG_CHECKING(for thread implementation)
1921
1922 have_threads=no
1923 if test "x$with_threads" = xyes || test "x$with_threads" = xposix; then
1924         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1925         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1926         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1927         glib_save_CPPFLAGS="$CPPFLAGS"
1928         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1929         if test "x$have_threads" = xno; then
1930                 AC_TRY_COMPILE([#include <pthread.h>],
1931                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1932                         have_threads=posix)
1933         fi
1934         # Tru64Unix requires -pthread to find pthread.h. See #103020
1935         CPPFLAGS="$CPPFLAGS -pthread"
1936         if test "x$have_threads" = xno; then
1937         AC_TRY_COMPILE([#include <pthread.h>],
1938                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1939                        have_threads=posix)
1940         fi
1941         CPPFLAGS="$glib_save_CPPFLAGS"
1942 fi
1943 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1944         case $host in
1945                 *-*-mingw*)
1946                 have_threads=win32
1947                 ;;
1948         esac
1949 fi
1950
1951 if test "x$have_threads" = xno; then
1952         AC_MSG_RESULT(none available)
1953         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1954 else
1955         AC_MSG_RESULT($have_threads)
1956 fi
1957
1958
1959 dnl determination of G_THREAD_CFLAGS
1960 dnl ********************************
1961
1962 G_THREAD_LIBS=
1963 G_THREAD_LIBS_EXTRA=
1964 G_THREAD_CFLAGS=
1965
1966 dnl
1967 dnl Test program for basic POSIX threads functionality
1968 dnl
1969 m4_define([glib_thread_test],[
1970 #include <pthread.h>
1971 int check_me = 0;
1972 void* func(void* data) {check_me = 42; return &check_me;}
1973 int main()
1974  { pthread_t t;
1975    void *ret;
1976    pthread_create (&t, $1, func, 0);
1977    pthread_join (t, &ret);
1978    return (check_me != 42 || ret != &check_me);
1979 }])
1980
1981 if test x"$have_threads" = xposix; then
1982   # First we test for posix, whether -pthread or -pthreads do the trick as
1983   # both CPPFLAG and LIBS.
1984   # One of them does for most gcc versions and some other platforms/compilers
1985   # too and could be considered as the canonical way to go.
1986   case $host in
1987     *-*-cygwin*|*-*-darwin*)
1988        # skip cygwin and darwin -pthread or -pthreads test
1989        ;;
1990     *-solaris*)
1991       # These compiler/linker flags work with both Sun Studio and gcc
1992       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1993       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1994       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1995       G_THREAD_LIBS="-lpthread -lthread"
1996       ;;
1997     *)
1998       for flag in pthread pthreads mt; do
1999         glib_save_CFLAGS="$CFLAGS"
2000         CFLAGS="$CFLAGS -$flag"
2001         AC_TRY_RUN(glib_thread_test(0),
2002                    glib_flag_works=yes,
2003                    glib_flag_works=no,
2004                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2005                                    glib_flag_works=yes,
2006                                    glib_flag_works=no)])
2007         CFLAGS="$glib_save_CFLAGS"
2008         if test $glib_flag_works = yes ; then
2009            G_THREAD_CFLAGS=-$flag
2010         G_THREAD_LIBS=-$flag
2011         break;
2012         fi
2013       done
2014        ;;
2015   esac
2016 fi
2017
2018 if test x"$G_THREAD_CFLAGS" = x; then
2019
2020   # The canonical -pthread[s] does not work. Try something different.
2021
2022   case $host in
2023         *-aix*)
2024                 if test x"$GCC" = xyes; then
2025                         # GCC 3.0 and above needs -pthread.
2026                         # Should be coverd by the case above.
2027                         # GCC 2.x and below needs -mthreads
2028                         G_THREAD_CFLAGS="-mthreads"
2029                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2030                 else
2031                         # We are probably using the aix compiler. Normaly a
2032                         # program would have to be compiled with the _r variant
2033                         # of the corresponding compiler, but we as GLib cannot
2034                         # do that: but the good news is that for compiling the
2035                         # only difference is the added -D_THREAD_SAFE compile
2036                         # option. This is according to the "C for AIX User's
2037                         # Guide".
2038                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2039                 fi
2040                 ;;
2041         *-dg-dgux*)  # DG/UX
2042                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2043                 ;;
2044         *-sysv5uw7*) # UnixWare 7
2045                 # We are not using gcc with -pthread. Catched above.
2046                 G_THREAD_CFLAGS="-Kthread"
2047                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2048                 ;;
2049         *-mingw*)
2050                 # No flag needed when using MSVCRT.DLL
2051                 G_THREAD_CFLAGS=""
2052                 ;;
2053         *)
2054                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2055                 ;;
2056   esac
2057
2058 fi
2059
2060 # if we are not finding the localtime_r function, then we probably are
2061 # not using the proper multithread flag
2062
2063 glib_save_CPPFLAGS="$CPPFLAGS"
2064 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2065
2066 # First we test, whether localtime_r is declared in time.h
2067 # directly. Then we test whether a macro localtime_r exists, in
2068 # which case localtime_r in the test program is replaced and thus
2069 # if we still find localtime_r in the output, it is not defined as
2070 # a macro.
2071
2072 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2073   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2074                                                            localtime_r(a,b)],
2075                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2076
2077 CPPFLAGS="$glib_save_CPPFLAGS"
2078
2079 AC_MSG_CHECKING(thread related cflags)
2080 AC_MSG_RESULT($G_THREAD_CFLAGS)
2081 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2082
2083 dnl determination of G_THREAD_LIBS
2084 dnl ******************************
2085
2086 case $have_threads in
2087         posix)
2088           glib_save_CPPFLAGS="$CPPFLAGS"
2089           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2090           if test x"$G_THREAD_LIBS" = x; then
2091             case $host in
2092               *-aix*)
2093                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2094                 # probably using the aix compiler.
2095                 AC_MSG_WARN($AIX_COMPILE_INFO)
2096                 ;;
2097               *)
2098                 G_THREAD_LIBS=error
2099                 glib_save_LIBS="$LIBS"
2100                 for thread_lib in "" pthread pthread32 pthreads thread; do
2101                         if test x"$thread_lib" = x; then
2102                                 add_thread_lib=""
2103                                 IN=""
2104                         else
2105                                 add_thread_lib="-l$thread_lib"
2106                                 IN=" in -l$thread_lib"
2107                         fi
2108                         if test x"$have_threads" = xposix; then
2109                                 defattr=0
2110                         else
2111                                 defattr=pthread_attr_default
2112                         fi
2113
2114                         LIBS="$add_thread_lib $glib_save_LIBS"
2115
2116                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2117                         AC_TRY_RUN(glib_thread_test($defattr),
2118                                    glib_result=yes,
2119                                    glib_result=no,
2120                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2121                                                    glib_result=yes,
2122                                                    glib_result=no)])
2123                         AC_MSG_RESULT($glib_result)
2124
2125                         if test "$glib_result" = "yes" ; then
2126                           G_THREAD_LIBS="$add_thread_lib"
2127                           break
2128                         fi
2129                 done
2130                 if test "x$G_THREAD_LIBS" = xerror; then
2131                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2132                 fi
2133                 LIBS="$glib_save_LIBS"
2134                 ;;
2135             esac
2136           fi
2137
2138           g_threads_impl="POSIX"
2139           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2140           CPPFLAGS="$glib_save_CPPFLAGS"
2141           ;;
2142         win32)
2143            g_threads_impl="WIN32"
2144            ;;
2145         *)
2146            g_threads_impl="NONE"
2147            G_THREAD_LIBS=error
2148            ;;
2149 esac
2150
2151 if test "x$G_THREAD_LIBS" = xerror; then
2152         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2153 fi
2154
2155 case $host in
2156   *-*-beos*)
2157     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2158     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2159     ;;
2160   *)
2161     ;;
2162 esac
2163
2164 AC_MSG_CHECKING(thread related libraries)
2165 AC_MSG_RESULT($G_THREAD_LIBS)
2166
2167 dnl check for mt safe function variants and some posix functions
2168 dnl ************************************************************
2169
2170 glib_save_LIBS="$LIBS"
2171 # we are not doing the following for now, as this might require glib
2172 # to always be linked with the thread libs on some platforms.
2173 # LIBS="$LIBS $G_THREAD_LIBS"
2174 AC_CHECK_FUNCS(localtime_r gmtime_r)
2175 if test "$ac_cv_header_pwd_h" = "yes"; then
2176         AC_CACHE_CHECK([for posix getpwuid_r],
2177                 ac_cv_func_posix_getpwuid_r,
2178                 [AC_TRY_RUN([
2179 #include <errno.h>
2180 #include <pwd.h>
2181 int main () {
2182     char buffer[10000];
2183     struct passwd pwd, *pwptr = &pwd;
2184     int error;
2185     errno = 0;
2186     error = getpwuid_r (0, &pwd, buffer,
2187                         sizeof (buffer), &pwptr);
2188    return (error < 0 && errno == ENOSYS)
2189            || error == ENOSYS;
2190 }                               ],
2191                         [ac_cv_func_posix_getpwuid_r=yes],
2192                         [ac_cv_func_posix_getpwuid_r=no])])
2193         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2194         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2195                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2196                         [Have POSIX function getpwuid_r])
2197         else
2198                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2199                         ac_cv_func_nonposix_getpwuid_r,
2200                         [AC_TRY_LINK([#include <pwd.h>],
2201                                 [char buffer[10000];
2202                                 struct passwd pwd;
2203                                 getpwuid_r (0, &pwd, buffer,
2204                                                 sizeof (buffer));],
2205                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2206                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2207                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2208                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2209                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2210                                 [Have non-POSIX function getpwuid_r])
2211                 fi
2212         fi
2213 fi
2214 if test "$ac_cv_header_grp_h" = "yes"; then
2215         AC_CACHE_CHECK([for posix getgrgid_r],
2216                 ac_cv_func_posix_getgrgid_r,
2217                 [AC_TRY_RUN([
2218 #include <errno.h>
2219 #include <grp.h>
2220 int main () {
2221     char buffer[10000];
2222     struct group grp, *grpptr = &grp;
2223     int error;
2224     errno = 0;
2225     error = getgrgid_r (0, &grp, buffer,
2226                         sizeof (buffer), &grpptr);
2227    return (error < 0 && errno == ENOSYS)
2228            || error == ENOSYS;
2229 }                              ],
2230                        [ac_cv_func_posix_getgrgid_r=yes],
2231                        [ac_cv_func_posix_getgrgid_r=no])])
2232         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2233         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2234                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2235                         [Have POSIX function getgrgid_r])
2236         else
2237                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2238                         ac_cv_func_nonposix_getgrgid_r,
2239                         [AC_TRY_LINK([#include <grp.h>],
2240                                 [char buffer[10000];
2241                                 struct group grp;
2242                                 getgrgid_r (0, &grp, buffer,
2243                                 sizeof (buffer));],
2244                         [ac_cv_func_nonposix_getgrgid_r=yes],
2245                         [ac_cv_func_nonposix_getgrgid_r=no])])
2246                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2247                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2248                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2249                                 [Have non-POSIX function getgrgid_r])
2250                 fi
2251         fi
2252 fi
2253 LIBS="$G_THREAD_LIBS $LIBS"
2254 if test x"$have_threads" = xposix; then
2255         glib_save_CPPFLAGS="$CPPFLAGS"
2256         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2257         # This is not AC_CHECK_FUNC to also work with function
2258         # name mangling in header files.
2259         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2260         AC_LINK_IFELSE(
2261             [AC_LANG_PROGRAM(
2262                 [#include <pthread.h>],
2263                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2264             [AC_MSG_RESULT(yes)
2265              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2266                 [Have function pthread_attr_setstacksize])],
2267             [AC_MSG_RESULT(no)])
2268         AC_MSG_CHECKING(for pthread_condattr_setclock)
2269         AC_LINK_IFELSE(
2270             [AC_LANG_PROGRAM(
2271                 [#include <pthread.h>],
2272                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2273             [AC_MSG_RESULT(yes)
2274              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2275                 [Have function pthread_condattr_setclock])],
2276             [AC_MSG_RESULT(no)])
2277         CPPFLAGS="$glib_save_CPPFLAGS"
2278 fi
2279
2280 LIBS="$glib_save_LIBS"
2281
2282 # now spit out all the warnings.
2283 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2284    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2285         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2286 fi
2287 if test "$ac_cv_func_localtime_r" != "yes"; then
2288         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2289 fi
2290
2291 #
2292 # Hack to deal with:
2293 #
2294 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2295 #     building shared libraries with linux.
2296 #  b) FreeBSD doesn't do this either.
2297 #
2298 case $host in
2299   *-*-freebsd*|*-*-linux*)
2300     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2301     ;;
2302   *-*-openbsd*)
2303     LDFLAGS="$LDFLAGS -pthread"
2304     ;;
2305   *)
2306     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2307     ;;
2308 esac
2309
2310 AC_SUBST(G_THREAD_CFLAGS)
2311 AC_SUBST(G_THREAD_LIBS)
2312 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2313 AC_SUBST(G_THREAD_LIBS_EXTRA)
2314
2315 AC_CHECK_FUNCS(clock_gettime, [], [
2316   AC_CHECK_LIB(rt, clock_gettime, [
2317     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2318     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2319     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2320   ])
2321 ])
2322
2323
2324 dnl ************************
2325 dnl *** g_atomic_* tests ***
2326 dnl ************************
2327
2328 dnl We need to decide at configure time if GLib will use real atomic
2329 dnl operations ("lock free") or emulated ones with a mutex.  This is
2330 dnl because we must put this information in glibconfig.h so we know if
2331 dnl it is safe or not to inline using compiler intrinsics directly from
2332 dnl the header.
2333 dnl
2334 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2335 dnl user is interested in knowing if they can use the atomic ops across
2336 dnl processes.
2337 dnl
2338 dnl We can currently support the atomic ops natively when building GLib
2339 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2340 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2341 dnl we are using GCC.
2342 dnl
2343 dnl Note that the atomic ops are only available with GCC on x86 when
2344 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2345 dnl not available but would be available given the right flags, we want
2346 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2347 dnl that then to silently fall back on emulated atomic ops just because
2348 dnl the user had the wrong build environment.
2349
2350 dnl We may add other compilers here in the future...
2351
2352 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2353   AC_TRY_COMPILE([],
2354                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2355                  [glib_cv_g_atomic_lock_free=yes],
2356                  [glib_cv_g_atomic_lock_free=no])])
2357
2358 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2359   SAVE_CFLAGS="${CFLAGS}"
2360   CFLAGS="-march=i486"
2361   AC_TRY_COMPILE([],
2362                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2363                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2364                  [])
2365   CFLAGS="${SAVE_CFLAGS}"
2366 fi
2367
2368 dnl We need a more robust approach here...
2369 case $host_cpu in
2370   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2371     glib_memory_barrier_needed=no
2372     ;;
2373   sparc*|alpha*|powerpc*|ia64)
2374     glib_memory_barrier_needed=yes
2375     ;;
2376   *)
2377     glib_memory_barrier_needed=yes
2378     ;;
2379 esac
2380
2381 dnl ************************
2382 dnl ** Check for futex(2) **
2383 dnl ************************
2384 AC_CACHE_CHECK(for futex(2) system call,
2385     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2386 #include <linux/futex.h>
2387 #include <sys/syscall.h>
2388 #include <unistd.h>
2389 ],[
2390 int
2391 main (void)
2392 {
2393   /* it is not like this actually runs or anything... */
2394   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2395   return 0;
2396 }
2397 ])],glib_cv_futex=yes,glib_cv_futex=no))
2398 if test x"$glib_cv_futex" = xyes; then
2399   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2400 fi
2401
2402 AC_CACHE_CHECK(for eventfd(2) system call,
2403     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2404 #include <sys/eventfd.h>
2405 #include <unistd.h>
2406 ],[
2407 int
2408 main (void)
2409 {
2410   eventfd (0, EFD_CLOEXEC);
2411   return 0;
2412 }
2413 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2414 if test x"$glib_cv_eventfd" = x"yes"; then
2415   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2416 fi
2417 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2418
2419 dnl ****************************************
2420 dnl *** GLib POLL* compatibility defines ***
2421 dnl ****************************************
2422
2423 glib_poll_includes=["
2424 #include <sys/types.h>
2425 #include <sys/poll.h>
2426 "]
2427
2428 if test $ac_cv_header_sys_types_h = yes &&
2429    test $ac_cv_header_sys_poll_h = yes ; then
2430   glib_failed=false
2431   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2432   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2433   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2434   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2435   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2436   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2437   if $glib_failed ; then
2438     AC_MSG_ERROR([Could not determine values for POLL* constants])
2439   fi
2440 else
2441   glib_cv_value_POLLIN=1
2442   glib_cv_value_POLLOUT=4
2443   glib_cv_value_POLLPRI=2
2444   glib_cv_value_POLLERR=8
2445   glib_cv_value_POLLHUP=16
2446   glib_cv_value_POLLNVAL=32
2447 fi
2448
2449 AC_MSG_CHECKING([for broken poll])
2450 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2451         #include <stdlib.h>
2452         #include <fcntl.h>
2453         #include <poll.h>
2454         #ifdef HAVE_SYS_POLL_H
2455         #include <sys/poll.h>
2456         #endif
2457         int main(void) {
2458           struct pollfd fds[1];
2459           int fd;
2460           fd = open("/dev/null", 1);
2461           fds[0].fd = fd;
2462           fds[0].events = POLLIN;
2463           fds[0].revents = 0;
2464           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2465                 exit(1);  /* Does not work for devices -- fail */
2466           }
2467           exit(0);
2468         }]])],
2469   [broken_poll=no],
2470   [broken_poll=yes
2471    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2472   [broken_poll="no (cross compiling)"])
2473 AC_MSG_RESULT($broken_poll)
2474
2475 dnl *********************
2476 dnl *** GRegex checks ***
2477 dnl *********************
2478
2479 PCRE_REQUIRED_VERSION=8.11
2480
2481 # Check if we should use the internal or the system-supplied pcre
2482 AC_ARG_WITH(pcre,
2483             [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2484                             [whether to use system PCRE [default=internal]])])
2485
2486 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2487
2488 if test "x$with_pcre" = xsystem; then
2489   PKG_CHECK_MODULES(PCRE,
2490                     libpcre >= $PCRE_REQUIRED_VERSION)
2491   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2492                   glib_save_CFLAGS="$CFLAGS"
2493                   glib_save_LIBS="$LIBS"
2494                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2495                   AC_TRY_RUN([#include <pcre.h>
2496                               int main () {
2497                                 int support;
2498                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2499                                 if (!support)
2500                                   return 1;
2501                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2502                                 if (!support)
2503                                   return 1;
2504                                 return 0;
2505                               }],
2506                   glib_cv_pcre_has_unicode=yes,
2507                   glib_cv_pcre_has_unicode=no,
2508                   glib_cv_pcre_has_unicode=yes)
2509                   CFLAGS="$glib_save_CFLAGS"
2510                   LIBS="$glib_save_LIBS"
2511       ])
2512   if test "$glib_cv_pcre_has_unicode" = "no"; then
2513     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2514   fi
2515   AC_SUBST(PCRE_CFLAGS)
2516   AC_SUBST(PCRE_LIBS)
2517   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2518   PCRE_REQUIRES=libpcre
2519   AC_SUBST(PCRE_REQUIRES)
2520 else
2521   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2522   if test x"$GCC" = xyes; then
2523     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2524     save_CFLAGS="$CFLAGS"
2525     CFLAGS="$CFLAGS -Wno-pointer-sign"
2526     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2527                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2528     CFLAGS="$save_CFLAGS"
2529   fi
2530 fi
2531 AC_SUBST(PCRE_WARN_CFLAGS)
2532
2533 dnl **********************
2534 dnl *** Win32 API libs ***
2535 dnl **********************
2536
2537 case $host in
2538   *-*-cygwin*)
2539         G_LIBS_EXTRA="-luser32 -lkernel32"
2540     ;;
2541   *-*-mingw*)
2542         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2543     ;;
2544   *)
2545         G_LIBS_EXTRA=""
2546     ;;
2547 esac
2548 AC_SUBST(G_LIBS_EXTRA)
2549
2550 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2551 dnl since we need it for g_iconv()
2552
2553 AC_MSG_CHECKING([for EILSEQ])
2554 AC_TRY_COMPILE([
2555 #include <errno.h>
2556 ],
2557 [
2558 int error = EILSEQ;
2559 ], have_eilseq=yes, have_eilseq=no);
2560 AC_MSG_RESULT($have_eilseq)
2561
2562 dnl ******************************************************************
2563 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2564 dnl *** glib-compile-schemas in PATH                               ***
2565 dnl ******************************************************************
2566
2567 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2568
2569 if test $cross_compiling = yes; then
2570   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2571   if test x$GLIB_GENMARSHAL = xno; then
2572     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2573   fi
2574
2575   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2576   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2577     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2578   fi
2579
2580   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2581   if test x$GLIB_COMPILE_RESOURCES = xno; then
2582     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2583   fi
2584 fi
2585
2586 dnl **************************
2587 dnl *** Checks for gtk-doc ***
2588 dnl **************************
2589
2590 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2591
2592 AC_ARG_ENABLE(man,
2593               [AC_HELP_STRING([--enable-man],
2594                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2595               enable_man=no)
2596
2597 if test "${enable_man}" != no; then
2598 dnl
2599 dnl Check for xsltproc
2600 dnl
2601 AC_PATH_PROG([XSLTPROC], [xsltproc])
2602   if test -z "$XSLTPROC"; then
2603     enable_man=no
2604   fi
2605
2606   dnl check for DocBook DTD and stylesheets in the local catalog.
2607   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2608      [DocBook XML DTD V4.1.2],,enable_man=no)
2609   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2610      [DocBook XSL Stylesheets],,enable_man=no)
2611 fi
2612
2613 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2614
2615 dnl
2616 dnl Tracing
2617 dnl
2618
2619 AC_ARG_ENABLE([dtrace],
2620              [AS_HELP_STRING([--enable-dtrace],
2621                               [include tracing support for dtrace])])
2622 have_dtrace=no
2623 AC_MSG_CHECKING([whether to include dtrace tracing support])
2624 if test "x$enable_dtrace" != xno; then
2625   if test x$glib_have_carbon = xyes; then
2626     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2627   else
2628     AC_MSG_RESULT([yes])
2629     AC_CHECK_PROGS(DTRACE, dtrace)
2630     if test -z "$DTRACE"; then
2631       if test "x$enable_dtrace" = xyes; then
2632         AC_MSG_ERROR([dtrace not found])
2633       fi
2634     else
2635       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2636                       [if test "x$enable_dtrace" = xyes; then
2637                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2638                        fi])
2639     fi
2640   fi
2641 else
2642   AC_MSG_RESULT([no])
2643 fi
2644 if test "x$have_dtrace" = xyes; then
2645   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2646 fi
2647 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2648
2649 AC_MSG_CHECKING([whether to include systemtap tracing support])
2650 AC_ARG_ENABLE([systemtap],
2651              [AS_HELP_STRING([--enable-systemtap],
2652                               [include tracing support for systemtap])])
2653 have_systemtap=no
2654 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2655   have_systemtap=yes
2656 fi
2657 AC_MSG_RESULT(${have_systemtap})
2658
2659 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2660
2661 AC_ARG_WITH([tapset-install-dir],
2662             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2663                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2664             [if test "x${withval}" = x; then
2665                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2666              else
2667                ABS_TAPSET_DIR="${withval}"
2668               fi],
2669             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2670 AC_SUBST(ABS_TAPSET_DIR)
2671
2672 dnl ************************************
2673 dnl *** Enable lcov coverage reports ***
2674 dnl ************************************
2675
2676 AC_ARG_ENABLE(gcov,
2677   AS_HELP_STRING([--enable-gcov],
2678                  [enable coverage testing with gcov]),
2679   [use_gcov=$enableval], [use_gcov=no])
2680
2681 if test "x$use_gcov" = "xyes"; then
2682   dnl we need gcc:
2683   if test "$GCC" != "yes"; then
2684     AC_MSG_ERROR([GCC is required for --enable-gcov])
2685   fi
2686
2687   dnl Check if ccache is being used
2688   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2689   case `$SHTOOL path $CC` in
2690     *ccache*[)] gcc_ccache=yes;;
2691     *[)] gcc_ccache=no;;
2692   esac
2693
2694   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2695     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2696   fi
2697
2698   ltp_version_list="1.6 1.7 1.8 1.9"
2699   AC_CHECK_PROG(LTP, lcov, lcov)
2700   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2701
2702   if test "$LTP"; then
2703     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2704       glib_cv_ltp_version=invalid
2705       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2706       for ltp_check_version in $ltp_version_list; do
2707         if test "$ltp_version" = "$ltp_check_version"; then
2708           glib_cv_ltp_version="$ltp_check_version (ok)"
2709         fi
2710       done
2711     ])
2712   else
2713     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2714     AC_MSG_ERROR([$ltp_msg])
2715   fi
2716
2717   case $glib_cv_ltp_version in
2718     ""|invalid[)]
2719       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2720       AC_MSG_ERROR([$ltp_msg])
2721       LTP="exit 0;"
2722       ;;
2723   esac
2724
2725   if test -z "$LTP_GENHTML"; then
2726     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2727   fi
2728
2729   dnl Remove all optimization flags from CFLAGS
2730   changequote({,})
2731   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2732   changequote([,])
2733
2734   dnl Add the special gcc flags
2735   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2736   LDFLAGS="$LDFLAGS -lgcov"
2737 fi
2738
2739 dnl ******************************
2740 dnl *** output the whole stuff ***
2741 dnl ******************************
2742
2743 dnl this section will only be run if config.status is invoked with no
2744 dnl arguments, or with "glib/glibconfig.h" as an argument.
2745 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2746 [
2747         outfile=glib/glibconfig.h-tmp
2748         cat > $outfile <<\_______EOF
2749 /* glibconfig.h
2750  *
2751  * This is a generated file.  Please modify 'configure.ac'
2752  */
2753
2754 #ifndef __GLIBCONFIG_H__
2755 #define __GLIBCONFIG_H__
2756
2757 #include <glib/gmacros.h>
2758
2759 _______EOF
2760
2761         if test x$glib_limits_h = xyes; then
2762           echo '#include <limits.h>' >> $outfile
2763         fi
2764         if test x$glib_float_h = xyes; then
2765           echo '#include <float.h>' >> $outfile
2766         fi
2767         if test x$glib_values_h = xyes; then
2768           echo '#include <values.h>' >> $outfile
2769         fi
2770         if test "$glib_header_alloca_h" = "yes"; then
2771           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2772         fi
2773         if test x$glib_sys_poll_h = xyes; then
2774           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2775         fi
2776         if test x$glib_included_printf != xyes; then
2777           echo "
2778 /* Specifies that GLib's g_print*() functions wrap the
2779  * system printf functions.  This is useful to know, for example,
2780  * when using glibc's register_printf_function().
2781  */" >> $outfile
2782           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2783         fi
2784
2785         cat >> $outfile <<_______EOF
2786
2787 G_BEGIN_DECLS
2788
2789 #define G_MINFLOAT      $glib_mf
2790 #define G_MAXFLOAT      $glib_Mf
2791 #define G_MINDOUBLE     $glib_md
2792 #define G_MAXDOUBLE     $glib_Md
2793 #define G_MINSHORT      $glib_ms
2794 #define G_MAXSHORT      $glib_Ms
2795 #define G_MAXUSHORT     $glib_Mus
2796 #define G_MININT        $glib_mi
2797 #define G_MAXINT        $glib_Mi
2798 #define G_MAXUINT       $glib_Mui
2799 #define G_MINLONG       $glib_ml
2800 #define G_MAXLONG       $glib_Ml
2801 #define G_MAXULONG      $glib_Mul
2802
2803 _______EOF
2804
2805
2806         ### this should always be true in a modern C/C++ compiler
2807         cat >>$outfile <<_______EOF
2808 typedef signed char gint8;
2809 typedef unsigned char guint8;
2810 _______EOF
2811
2812
2813         if test -n "$gint16"; then
2814           cat >>$outfile <<_______EOF
2815 typedef signed $gint16 gint16;
2816 typedef unsigned $gint16 guint16;
2817 #define G_GINT16_MODIFIER $gint16_modifier
2818 #define G_GINT16_FORMAT $gint16_format
2819 #define G_GUINT16_FORMAT $guint16_format
2820 _______EOF
2821         fi
2822
2823
2824         if test -n "$gint32"; then
2825           cat >>$outfile <<_______EOF
2826 typedef signed $gint32 gint32;
2827 typedef unsigned $gint32 guint32;
2828 #define G_GINT32_MODIFIER $gint32_modifier
2829 #define G_GINT32_FORMAT $gint32_format
2830 #define G_GUINT32_FORMAT $guint32_format
2831 _______EOF
2832         fi
2833
2834         cat >>$outfile <<_______EOF
2835 #define G_HAVE_GINT64 1          /* deprecated, always true */
2836
2837 ${glib_extension}typedef signed $gint64 gint64;
2838 ${glib_extension}typedef unsigned $gint64 guint64;
2839
2840 #define G_GINT64_CONSTANT(val)  $gint64_constant
2841 #define G_GUINT64_CONSTANT(val) $guint64_constant
2842 _______EOF
2843
2844         if test x$gint64_format != x ; then
2845           cat >>$outfile <<_______EOF
2846 #define G_GINT64_MODIFIER $gint64_modifier
2847 #define G_GINT64_FORMAT $gint64_format
2848 #define G_GUINT64_FORMAT $guint64_format
2849 _______EOF
2850         else
2851           cat >>$outfile <<_______EOF
2852 #undef G_GINT64_MODIFIER
2853 #undef G_GINT64_FORMAT
2854 #undef G_GUINT64_FORMAT
2855 _______EOF
2856         fi
2857
2858         cat >>$outfile <<_______EOF
2859
2860 #define GLIB_SIZEOF_VOID_P $glib_void_p
2861 #define GLIB_SIZEOF_LONG   $glib_long
2862 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2863
2864 _______EOF
2865
2866         cat >>$outfile <<_______EOF
2867 typedef signed $glib_size_type_define gssize;
2868 typedef unsigned $glib_size_type_define gsize;
2869 #define G_GSIZE_MODIFIER $gsize_modifier
2870 #define G_GSSIZE_FORMAT $gssize_format
2871 #define G_GSIZE_FORMAT $gsize_format
2872
2873 #define G_MAXSIZE       G_MAXU$glib_msize_type
2874 #define G_MINSSIZE      G_MIN$glib_msize_type
2875 #define G_MAXSSIZE      G_MAX$glib_msize_type
2876
2877 typedef gint64 goffset;
2878 #define G_MINOFFSET     G_MININT64
2879 #define G_MAXOFFSET     G_MAXINT64
2880
2881 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2882 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2883 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2884
2885 _______EOF
2886
2887         if test -z "$glib_unknown_void_p"; then
2888           cat >>$outfile <<_______EOF
2889
2890 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2891 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2892
2893 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2894 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2895
2896 typedef signed $glib_intptr_type_define gintptr;
2897 typedef unsigned $glib_intptr_type_define guintptr;
2898
2899 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2900 #define G_GINTPTR_FORMAT        $gintptr_format
2901 #define G_GUINTPTR_FORMAT       $guintptr_format
2902 _______EOF
2903         else
2904           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2905         fi
2906
2907
2908
2909         cat >>$outfile <<_______EOF
2910 $glib_atexit
2911 $glib_memmove
2912 $glib_defines
2913 $glib_os
2914 $glib_static_compilation
2915
2916 $glib_vacopy
2917
2918 #ifdef  __cplusplus
2919 #define G_HAVE_INLINE   1
2920 #else   /* !__cplusplus */
2921 $glib_inline
2922 #endif  /* !__cplusplus */
2923
2924 #ifdef  __cplusplus
2925 #define G_CAN_INLINE    1
2926 _______EOF
2927
2928         if test x$g_can_inline = xyes ; then
2929                 cat >>$outfile <<_______EOF
2930 #else   /* !__cplusplus */
2931 #define G_CAN_INLINE    1
2932 _______EOF
2933         fi
2934
2935         cat >>$outfile <<_______EOF
2936 #endif
2937
2938 _______EOF
2939
2940         if test x$g_have_iso_c_varargs = xyes ; then
2941                 cat >>$outfile <<_______EOF
2942 #ifndef __cplusplus
2943 # define G_HAVE_ISO_VARARGS 1
2944 #endif
2945 _______EOF
2946         fi
2947         if test x$g_have_iso_cxx_varargs = xyes ; then
2948                 cat >>$outfile <<_______EOF
2949 #ifdef __cplusplus
2950 # define G_HAVE_ISO_VARARGS 1
2951 #endif
2952 _______EOF
2953         fi
2954         if test x$g_have_gnuc_varargs = xyes ; then
2955                 cat >>$outfile <<_______EOF
2956
2957 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2958  * is passed ISO vararg support is turned off, and there is no work
2959  * around to turn it on, so we unconditionally turn it off.
2960  */
2961 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2962 #  undef G_HAVE_ISO_VARARGS
2963 #endif
2964
2965 #define G_HAVE_GNUC_VARARGS 1
2966 _______EOF
2967         fi
2968
2969         case x$g_stack_grows in
2970         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2971         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2972         esac
2973
2974
2975         echo >>$outfile
2976         if test x$g_have_eilseq = xno; then
2977                 cat >>$outfile <<_______EOF
2978 #ifndef EILSEQ
2979 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2980  * The correspondence between this and the corresponding definition
2981  * in libiconv is essential.
2982  */
2983 #  define EILSEQ ENOENT
2984 #endif
2985 _______EOF
2986
2987         fi
2988
2989         if test x$g_have_gnuc_visibility = xyes; then
2990                 cat >>$outfile <<_______EOF
2991 #define G_HAVE_GNUC_VISIBILITY 1
2992 _______EOF
2993         fi
2994                 cat >>$outfile <<_______EOF
2995 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2996 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2997 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2998 #define G_GNUC_INTERNAL __hidden
2999 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3000 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3001 #else
3002 #define G_GNUC_INTERNAL
3003 #endif
3004 _______EOF
3005
3006         echo >>$outfile
3007         cat >>$outfile <<_______EOF
3008 #define G_THREADS_ENABLED
3009 #define G_THREADS_IMPL_$g_threads_impl_def
3010 _______EOF
3011
3012         if test x"$g_memory_barrier_needed" != xno; then
3013           echo >>$outfile
3014           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3015         fi
3016         if test x"$g_atomic_lock_free" = xyes; then
3017           echo >>$outfile
3018           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3019         fi
3020         echo >>$outfile
3021         g_bit_sizes="16 32 64"
3022         for bits in $g_bit_sizes; do
3023           cat >>$outfile <<_______EOF
3024 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3025 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3026 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3027 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3028 _______EOF
3029         done
3030
3031         cat >>$outfile <<_______EOF
3032 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3033 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3034 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3035 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3036 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3037 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3038 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3039 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3040 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3041 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3042 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3043 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3044 #define G_BYTE_ORDER $g_byte_order
3045
3046 #define GLIB_SYSDEF_POLLIN =$g_pollin
3047 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3048 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3049 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3050 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3051 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3052
3053 #define G_MODULE_SUFFIX "$g_module_suffix"
3054
3055 typedef $g_pid_type GPid;
3056
3057 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3058 #define GLIB_SYSDEF_AF_INET $g_af_inet
3059 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3060
3061 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3062 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3063 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3064
3065 G_END_DECLS
3066
3067 #endif /* __GLIBCONFIG_H__ */
3068 _______EOF
3069
3070
3071         if cmp -s $outfile glib/glibconfig.h; then
3072           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3073           rm -f $outfile
3074         else
3075           mv $outfile glib/glibconfig.h
3076         fi
3077 ],[
3078
3079 # Note that if two cases are the same, case goes with the first one.
3080 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3081 # on variable expansion in case labels.  Look at the generated config.status
3082 # for a hint.
3083
3084 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3085   glib_header_alloca_h="$ac_cv_working_alloca_h"
3086 else
3087   glib_header_alloca_h="$ac_cv_header_alloca_h"
3088 fi
3089
3090 case xyes in
3091 x$ac_cv_header_float_h)
3092   glib_float_h=yes
3093   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3094   glib_md=DBL_MIN glib_Md=DBL_MAX
3095   ;;
3096 x$ac_cv_header_values_h)
3097   glib_values_h=yes
3098   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3099   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3100   ;;
3101 esac
3102
3103 case xyes in
3104 x$ac_cv_header_limits_h)
3105   glib_limits_h=yes
3106   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3107   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3108   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3109   ;;
3110 x$ac_cv_header_values_h)
3111   glib_values_h=yes
3112   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3113   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3114   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3115   ;;
3116 esac
3117
3118 if test x$ac_cv_header_sys_poll_h = xyes ; then
3119   glib_sys_poll_h=yes
3120 fi
3121
3122 if test x$enable_included_printf = xyes ; then
3123   glib_included_printf=yes
3124 fi
3125
3126 case 2 in
3127 $ac_cv_sizeof_short)
3128   gint16=short
3129   gint16_modifier='"h"'
3130   gint16_format='"hi"'
3131   guint16_format='"hu"'
3132   ;;
3133 $ac_cv_sizeof_int)
3134   gint16=int
3135   gint16_modifier='""'
3136   gint16_format='"i"'
3137   guint16_format='"u"'
3138   ;;
3139 esac
3140 case 4 in
3141 $ac_cv_sizeof_short)
3142   gint32=short
3143   gint32_modifier='"h"'
3144   gint32_format='"hi"'
3145   guint32_format='"hu"'
3146   ;;
3147 $ac_cv_sizeof_int)
3148   gint32=int
3149   gint32_modifier='""'
3150   gint32_format='"i"'
3151   guint32_format='"u"'
3152   ;;
3153 $ac_cv_sizeof_long)
3154   gint32=long
3155   gint32_modifier='"l"'
3156   gint32_format='"li"'
3157   guint32_format='"lu"'
3158   ;;
3159 esac
3160 case 8 in
3161 $ac_cv_sizeof_int)
3162   gint64=int
3163   gint64_modifier='""'
3164   gint64_format='"i"'
3165   guint64_format='"u"'
3166   glib_extension=
3167   gint64_constant='(val)'
3168   guint64_constant='(val)'
3169   ;;
3170 $ac_cv_sizeof_long)
3171   gint64=long
3172   gint64_modifier='"l"'
3173   gint64_format='"li"'
3174   guint64_format='"lu"'
3175   glib_extension=
3176   gint64_constant='(val##L)'
3177   guint64_constant='(val##UL)'
3178   ;;
3179 $ac_cv_sizeof_long_long)
3180   gint64='long long'
3181   if test -n "$glib_cv_long_long_format"; then
3182     gint64_modifier='"'$glib_cv_long_long_format'"'
3183     gint64_format='"'$glib_cv_long_long_format'i"'
3184     guint64_format='"'$glib_cv_long_long_format'u"'
3185   fi
3186   glib_extension='G_GNUC_EXTENSION '
3187   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3188   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3189   ;;
3190 $ac_cv_sizeof___int64)
3191   gint64='__int64'
3192   if test -n "$glib_cv_long_long_format"; then
3193     gint64_modifier='"'$glib_cv_long_long_format'"'
3194     gint64_format='"'$glib_cv_long_long_format'i"'
3195     guint64_format='"'$glib_cv_long_long_format'u"'
3196   fi
3197   glib_extension=
3198   gint64_constant='(val##i64)'
3199   guint64_constant='(val##ui64)'
3200   ;;
3201 esac
3202 glib_size_t=$ac_cv_sizeof_size_t
3203 glib_size_type_define="$glib_size_type"
3204 glib_void_p=$ac_cv_sizeof_void_p
3205 glib_long=$ac_cv_sizeof_long
3206
3207 case "$glib_size_type" in
3208 short)
3209   gsize_modifier='"h"'
3210   gsize_format='"hu"'
3211   gssize_format='"hi"'
3212   glib_msize_type='SHRT'
3213   ;;
3214 int)
3215   gsize_modifier='""'
3216   gsize_format='"u"'
3217   gssize_format='"i"'
3218   glib_msize_type='INT'
3219   ;;
3220 long)
3221   gsize_modifier='"l"'
3222   gsize_format='"lu"'
3223   gssize_format='"li"'
3224   glib_msize_type='LONG'
3225   ;;
3226 "long long"|__int64)
3227   gsize_modifier='"I64"'
3228   gsize_format='"I64u"'
3229   gssize_format='"I64i"'
3230   glib_msize_type='INT64'
3231   ;;
3232 esac
3233
3234 gintbits=`expr $ac_cv_sizeof_int \* 8`
3235 glongbits=`expr $ac_cv_sizeof_long \* 8`
3236 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3237
3238 case $ac_cv_sizeof_void_p in
3239 $ac_cv_sizeof_int)
3240   glib_intptr_type_define=int
3241   gintptr_modifier='""'
3242   gintptr_format='"i"'
3243   guintptr_format='"u"'
3244   glib_gpi_cast='(gint)'
3245   glib_gpui_cast='(guint)'
3246   ;;
3247 $ac_cv_sizeof_long)
3248   glib_intptr_type_define=long
3249   gintptr_modifier='"l"'
3250   gintptr_format='"li"'
3251   guintptr_format='"lu"'
3252   glib_gpi_cast='(glong)'
3253   glib_gpui_cast='(gulong)'
3254   ;;
3255 $ac_cv_sizeof_long_long)
3256   glib_intptr_type_define='long long'
3257   gintptr_modifier='"I64"'
3258   gintptr_format='"I64i"'
3259   guintptr_format='"I64u"'
3260   glib_gpi_cast='(gint64)'
3261   glib_gpui_cast='(guint64)'
3262   ;;
3263 $ac_cv_sizeof___int64)
3264   glib_intptr_type_define=__int64
3265   gintptr_modifier='"I64"'
3266   gintptr_format='"I64i"'
3267   guintptr_format='"I64u"'
3268   glib_gpi_cast='(gint64)'
3269   glib_gpui_cast='(guint64)'
3270   ;;
3271 *)
3272   glib_unknown_void_p=yes
3273   ;;
3274 esac
3275
3276
3277 case xyes in
3278 x$ac_cv_func_atexit)
3279   glib_atexit="
3280 #ifdef NeXT /* @#%@! NeXTStep */
3281 # define g_ATEXIT(proc) (!atexit (proc))
3282 #else
3283 # define g_ATEXIT(proc) (atexit (proc))
3284 #endif"
3285   ;;
3286 x$ac_cv_func_on_exit)
3287   glib_atexit="
3288 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3289   ;;
3290 esac
3291
3292 case xyes in
3293 x$ac_cv_func_memmove)
3294   glib_memmove='
3295 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3296   ;;
3297 x$glib_cv_working_bcopy)
3298   glib_memmove="
3299 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3300 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3301   ;;
3302 *)
3303   glib_memmove="
3304 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3305  * so we have to roll our own copy routine. */
3306 void g_memmove (void* dest, const void * src, unsigned long len);"
3307   ;;
3308 esac
3309
3310 glib_defines="
3311 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3312 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3313 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3314 "
3315
3316 case xyes in
3317 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3318 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3319 *)                      glib_vacopy=''
3320 esac
3321
3322 if test x$glib_cv_va_val_copy = xno; then
3323   glib_vacopy="\$glib_vacopy
3324 #define G_VA_COPY_AS_ARRAY 1"
3325 fi
3326
3327 if test x$glib_cv_hasinline = xyes; then
3328     glib_inline='#define G_HAVE_INLINE 1'
3329 fi
3330 if test x$glib_cv_has__inline = xyes; then
3331     glib_inline="\$glib_inline
3332 #define G_HAVE___INLINE 1"
3333 fi
3334 if test x$glib_cv_has__inline__ = xyes; then
3335     glib_inline="\$glib_inline
3336 #define G_HAVE___INLINE__ 1"
3337 fi
3338
3339 g_have_gnuc_varargs=$g_have_gnuc_varargs
3340 g_have_iso_c_varargs=$g_have_iso_c_varargs
3341 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3342
3343 g_can_inline=$g_can_inline
3344 g_have_gnuc_visibility=$g_have_gnuc_visibility
3345 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3346
3347 if test x$ac_cv_c_bigendian = xyes; then
3348   g_byte_order=G_BIG_ENDIAN
3349   g_bs_native=BE
3350   g_bs_alien=LE
3351 else
3352   g_byte_order=G_LITTLE_ENDIAN
3353   g_bs_native=LE
3354   g_bs_alien=BE
3355 fi
3356
3357 g_pollin=$glib_cv_value_POLLIN
3358 g_pollout=$glib_cv_value_POLLOUT
3359 g_pollpri=$glib_cv_value_POLLPRI
3360 g_pollhup=$glib_cv_value_POLLHUP
3361 g_pollerr=$glib_cv_value_POLLERR
3362 g_pollnval=$glib_cv_value_POLLNVAL
3363
3364 g_af_unix=$glib_cv_value_AF_UNIX
3365 g_af_inet=$glib_cv_value_AF_INET
3366 g_af_inet6=$glib_cv_value_AF_INET6
3367
3368 g_msg_peek=$glib_cv_value_MSG_PEEK
3369 g_msg_oob=$glib_cv_value_MSG_OOB
3370 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3371
3372 g_stack_grows=$glib_cv_stack_grows
3373
3374 g_have_eilseq=$have_eilseq
3375
3376 g_threads_impl_def=$g_threads_impl
3377
3378 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3379 g_memory_barrier_needed="$glib_memory_barrier_needed"
3380 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3381
3382 g_module_suffix="$glib_gmodule_suffix"
3383
3384 g_pid_type="$glib_pid_type"
3385 case $host in
3386   *-*-beos*)
3387     glib_os="#define G_OS_BEOS"
3388     ;;
3389   *-*-cygwin*)
3390     glib_os="#define G_OS_UNIX
3391 #define G_PLATFORM_WIN32
3392 #define G_WITH_CYGWIN"
3393     ;;
3394   *-*-mingw*)
3395     glib_os="#define G_OS_WIN32
3396 #define G_PLATFORM_WIN32"
3397     ;;
3398   *)
3399     glib_os="#define G_OS_UNIX"
3400     ;;
3401 esac
3402 glib_static_compilation=""
3403 if test x$glib_win32_static_compilation = xyes; then
3404   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3405 #define GOBJECT_STATIC_COMPILATION 1"
3406 fi
3407 ])
3408
3409 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3410 #
3411 # 1.2.14 required for dbus_message_set_serial
3412 PKG_CHECK_MODULES(DBUS1,
3413                   dbus-1 >= 1.2.14,
3414                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3415                   have_dbus1=no)
3416 AC_SUBST(DBUS1_CFLAGS)
3417 AC_SUBST(DBUS1_LIBS)
3418 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3419
3420 dnl
3421 dnl Check for -Bsymbolic-functions linker flag used to avoid
3422 dnl intra-library PLT jumps, if available.
3423 dnl
3424
3425 AC_ARG_ENABLE(Bsymbolic,
3426               [AC_HELP_STRING([--disable-Bsymbolic],
3427                               [avoid linking with -Bsymbolic])],,
3428               [SAVED_LDFLAGS="${LDFLAGS}"
3429                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3430                LDFLAGS=-Wl,-Bsymbolic-functions
3431                AC_TRY_LINK([], [int main (void) { return 0; }],
3432                            AC_MSG_RESULT(yes)
3433                            enable_Bsymbolic=yes,
3434                            AC_MSG_RESULT(no)
3435                            enable_Bsymbolic=no)
3436                LDFLAGS="${SAVED_LDFLAGS}"])
3437
3438 if test "x${enable_Bsymbolic}" = "xyes"; then
3439   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3440 fi
3441
3442 AC_SUBST(GLIB_LINK_FLAGS)
3443
3444 #
3445 # Define variables corresponding to the correct include paths to use for
3446 # in-tree building.
3447 #
3448
3449 # for config.h:
3450 config_h_INCLUDES='-I$(top_builddir)'
3451 AC_SUBST(config_h_INCLUDES)
3452
3453 # glib:
3454 #   config.h
3455 #   $(top_builddir)/glib: for glibconfig.h
3456 #   $(top_srcdir)/glib:   for glib.h
3457 #   $(top_srcdir):        for everything
3458 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3459 AC_SUBST(glib_INCLUDES)
3460
3461 # gthread:
3462 #   same as glib
3463 gthread_INCLUDES='$(glib_INCLUDES)'
3464 AC_SUBST(gthread_INCLUDES)
3465
3466 # gobject:
3467 #   same as gthread
3468 gobject_INCLUDES='$(gthread_INCLUDES)'
3469 AC_SUBST(gobject_INCLUDES)
3470
3471 # gmodule:
3472 #   glib includes
3473 #   $(top_srcdir)/gmodule: for gmodule.h
3474 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3475 AC_SUBST(gmodule_INCLUDES)
3476
3477 # gio:
3478 #   same as gmodule
3479 gio_INCLUDES='$(gmodule_INCLUDES)'
3480 AC_SUBST(gio_INCLUDES)
3481
3482
3483 AC_CONFIG_FILES([
3484 glib-2.0.pc
3485 gmodule-2.0.pc
3486 gmodule-export-2.0.pc
3487 gmodule-no-export-2.0.pc
3488 gthread-2.0.pc
3489 gobject-2.0.pc
3490 gio-2.0.pc
3491 gio-unix-2.0.pc
3492 gio-windows-2.0.pc
3493 glib-zip
3494 glib-gettextize
3495 Makefile
3496 build/Makefile
3497 build/win32/Makefile
3498 build/win32/dirent/Makefile
3499 build/win32/vs9/Makefile
3500 build/win32/vs10/Makefile
3501 glib/Makefile
3502 glib/glib.stp
3503 glib/libcharset/Makefile
3504 glib/gnulib/Makefile
3505 glib/pcre/Makefile
3506 glib/update-pcre/Makefile
3507 glib/tests/Makefile
3508 gmodule/Makefile
3509 gmodule/gmoduleconf.h
3510 gobject/Makefile
3511 gobject/gobject.stp
3512 gobject/glib-mkenums
3513 gobject/tests/Makefile
3514 gthread/Makefile
3515 gio/Makefile
3516 gio/gdbus-2.0/codegen/Makefile
3517 gio/gdbus-2.0/codegen/config.py
3518 gio/xdgmime/Makefile
3519 gio/inotify/Makefile
3520 gio/fen/Makefile
3521 gio/fam/Makefile
3522 gio/win32/Makefile
3523 gio/tests/Makefile
3524 gio/tests/gdbus-object-manager-example/Makefile
3525 po/Makefile.in
3526 docs/Makefile
3527 docs/reference/Makefile
3528 docs/reference/glib/Makefile
3529 docs/reference/glib/version.xml
3530 docs/reference/gobject/Makefile
3531 docs/reference/gobject/version.xml
3532 docs/reference/gio/Makefile
3533 docs/reference/gio/gdbus-object-manager-example/Makefile
3534 docs/reference/gio/version.xml
3535 tests/Makefile
3536 tests/gobject/Makefile
3537 tests/refcount/Makefile
3538 m4macros/Makefile
3539 ])
3540
3541 AC_CONFIG_COMMANDS([chmod-scripts],
3542 [chmod 0755 glib-zip
3543 chmod 0755 glib-gettextize
3544 chmod 0755 gobject/glib-mkenums])
3545
3546 # we want to invoke this macro solely so that the config.status script
3547 # and automake generated makefiles know about these generated files.
3548 # They are only needed to distcheck the package
3549 if false; then
3550   AC_CONFIG_FILES([
3551     INSTALL
3552     README
3553     config.h.win32
3554     glib/glibconfig.h.win32
3555     glib/makefile.msc
3556     glib/glib.rc
3557     gmodule/makefile.msc
3558     gmodule/gmodule.rc
3559     gobject/makefile.msc
3560     gobject/gobject.rc
3561     gthread/makefile.msc
3562     gthread/gthread.rc
3563     gio/gio.rc
3564     tests/makefile.msc
3565   ])
3566 fi
3567
3568 AC_OUTPUT