configure.ac

   1 m4_define(LIBUSB_MAJOR, [1])
   2 m4_define(LIBUSB_MINOR, [0])
   3 m4_define(LIBUSB_MICRO, [8])
   4
   5 AC_INIT([libusb], LIBUSB_MAJOR.LIBUSB_MINOR.LIBUSB_MICRO, [libusb-devel@lists.sourceforge.net], [libusb], [http://www.libusb.org/])
   6
   7 AC_SUBST([LIBUSB_VERSION_MAJOR], [LIBUSB_MAJOR])
   8 AC_SUBST([LIBUSB_VERSION_MINOR], [LIBUSB_MINOR])
   9 AC_SUBST([LIBUSB_VERSION_MICRO], [LIBUSB_MICRO])
  10
  11 AM_INIT_AUTOMAKE
  12 AC_CONFIG_SRCDIR([libusb/core.c])
  13 AC_CONFIG_MACRO_DIR([m4])
  14 AM_CONFIG_HEADER([config.h])
  15 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  16
  17 AC_PREREQ([2.50])
  18 AC_PROG_CC
  19 AC_PROG_LIBTOOL
  20 AC_C_INLINE
  21 AM_PROG_CC_C_O
  22 AC_DEFINE([_GNU_SOURCE], [], [Use GNU extensions])
  23
  24 AM_MAINTAINER_MODE
  25
  26 AC_MSG_CHECKING([operating system])
  27 case $host in
  28 *-linux*)
  29         AC_DEFINE(OS_LINUX, [], [Linux backend])
  30         AC_SUBST(OS_LINUX)
  31         AC_DEFINE([THREADS_POSIX], [], [Use Posix Threads])
  32         AC_MSG_RESULT([Linux])
  33         backend="linux"
  34         AC_CHECK_LIB(rt, clock_gettime)
  35         threads="posix"
  36         THREAD_CFLAGS="-pthread"
  37         AM_LDFLAGS=""
  38         ;;
  39 *-darwin*)
  40         AC_DEFINE(OS_DARWIN, [], [Darwin backend])
  41         AC_SUBST(OS_DARWIN)
  42         AC_DEFINE([THREADS_POSIX], [], [Use Posix Threads])
  43         AC_DEFINE(USBI_OS_HANDLES_TIMEOUT, [], [Backend handles timeout])
  44         AC_MSG_RESULT([Darwin/MacOS X])
  45         backend="darwin"
  46         threads="posix"
  47         THREAD_CFLAGS="-pthread"
  48         AM_LDFLAGS="-Wl,-framework -Wl,IOKit -Wl,-framework -Wl,CoreFoundation -Wl,-prebind -no-undefined"
  49         ;;
  50 *-mingw*)
  51         AC_DEFINE(OS_WINDOWS, [], [Windows backend])
  52         AC_SUBST(OS_WINDOWS)
  53         AC_MSG_RESULT([Windows])
  54         backend="windows"
  55         threads="windows"
  56         LIBS="-lsetupapi -lole32 -ladvapi32"
  57         # -avoid-version to avoid a naming scheme such as libusb-0.dll
  58         AM_LDFLAGS="-no-undefined -avoid-version"
  59         AC_CHECK_TOOL(RC, windres, no)
  60         ;;
  61 *-cygwin*)
  62         AC_DEFINE(OS_WINDOWS, [], [Windows backend])
  63         AC_SUBST(OS_WINDOWS)
  64         AC_DEFINE([THREADS_POSIX], [], [Use Posix Threads])
  65         AC_MSG_RESULT([Windows])
  66         backend="windows"
  67         threads="posix"
  68         LIBS="-lsetupapi -lole32 -ladvapi32"
  69         AM_LDFLAGS="-no-undefined -avoid-version"
  70         AC_CHECK_TOOL(RC, windres, no)
  71         ;;
  72 *)
  73         AC_MSG_ERROR([unsupported operating system])
  74 esac
  75
  76 AM_CONDITIONAL([OS_LINUX], [test "x$backend" = "xlinux"])
  77 AM_CONDITIONAL([OS_DARWIN], [test "x$backend" = "xdarwin"])
  78 AM_CONDITIONAL([OS_WINDOWS], [test "x$backend" = "xwindows"])
  79 AM_CONDITIONAL([THREADS_POSIX], [test "x$threads" = "xposix"])
  80
  81 # Library versioning
  82 lt_major="0"
  83 lt_revision="0"
  84 lt_age="0"
  85 AC_SUBST(lt_major)
  86 AC_SUBST(lt_revision)
  87 AC_SUBST(lt_age)
  88
  89 # timerfd
  90 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
  91 AC_ARG_ENABLE([timerfd],
  92         [AS_HELP_STRING([--enable-timerfd],
  93                 [use timerfd for timing (default auto)])],
  94         [use_timerfd=$enableval], [use_timerfd='auto'])
  95
  96 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
  97         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
  98 fi
  99
 100 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 101 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 102         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 103 fi
 104
 105 AC_MSG_CHECKING([whether to use timerfd for timing])
 106 if test "x$use_timerfd" = "xno"; then
 107         AC_MSG_RESULT([no (disabled by user)])
 108 else
 109         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 110                 AC_MSG_RESULT([yes])
 111                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, [], [timerfd headers available])
 112         else
 113                 AC_MSG_RESULT([no (header not available)])
 114         fi
 115 fi
 116
 117 AC_CHECK_TYPES(struct timespec)
 118
 119 # Message logging
 120 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 121         [log_enabled=$enableval],
 122         [log_enabled='yes'])
 123 if test "x$log_enabled" != "xno"; then
 124         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 125 fi
 126
 127 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 128         [enable debug logging (default n)])],
 129         [debug_log_enabled=$enableval],
 130         [debug_log_enabled='no'])
 131 if test "x$debug_log_enabled" != "xno"; then
 132         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
 133 fi
 134
 135 # Examples build
 136 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 137         [build example applications (default n)])],
 138         [build_examples=$enableval],
 139         [build_examples='no'])
 140 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 141
 142 # Restore gnu89 inline semantics on gcc 4.3 and newer
 143 saved_cflags="$CFLAGS"
 144 CFLAGS="$CFLAGS -fgnu89-inline"
 145 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), inline_cflags="-fgnu89-inline", inline_cflags="")
 146 CFLAGS="$saved_cflags"
 147
 148 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 149 saved_cflags="$CFLAGS"
 150 # -Werror required for cygwin
 151 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 152 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 153         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 154          AC_DEFINE([API_EXPORTED], [__attribute__((visibility("default")))], [Default visibility]) ],
 155         [ VISIBILITY_CFLAGS=""
 156          AC_DEFINE([API_EXPORTED], [], [Default visibility]) ],
 157         ])
 158 CFLAGS="$saved_cflags"
 159
 160 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 161 saved_cflags="$CFLAGS"
 162 CFLAGS="$CFLAGS -Wno-pointer-sign"
 163 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 164         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 165 CFLAGS="$saved_cflags"
 166
 167 # sigaction not available on MinGW
 168 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 169 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 170
 171 # headers not available on all platforms but required on others
 172 AC_CHECK_HEADERS([sys/time.h])
 173
 174 AC_SUBST([THREAD_CFLAGS])
 175
 176 AM_CFLAGS="-std=gnu99 $inline_cflags -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 177
 178 AC_SUBST(VISIBILITY_CFLAGS)
 179 AC_SUBST(AM_CFLAGS)
 180 AC_SUBST(AM_LDFLAGS)
 181
 182 AC_CONFIG_FILES([libusb-1.0.pc] [Makefile] [libusb/Makefile] [libusb/libusb-1.0.rc] [examples/Makefile] [doc/Makefile] [doc/doxygen.cfg])
 183 AC_OUTPUT
 184