configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  52 dnl versions are explictly not supported.
  53 if test "x$GCC" = xyes; then
  54     AC_MSG_CHECKING([whether gcc version is sufficient])
  55     major=0
  56     minor=0
  57
  58     GCC_VERSION=`$CC -dumpversion`
  59     if test $? -eq 0; then
  60         major=`echo $GCC_VERSION | cut -d. -f1`
  61         minor=`echo $GCC_VERSION | cut -d. -f1`
  62     fi
  63
  64     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  65         AC_MSG_RESULT([no])
  66         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  67     else
  68         AC_MSG_RESULT([yes])
  69     fi
  70 fi
  71
  72
  73 MKDEP_OPTIONS=-fdepend
  74 dnl Ask gcc where it's keeping its secret headers
  75 if test "x$GCC" = xyes; then
  76     for dir in include include-fixed; do
  77         GCC_INCLUDES=`$CC -print-file-name=$dir`
  78         if test "x$GCC_INCLUDES" != x && \
  79            test "$GCC_INCLUDES" != "$dir" && \
  80            test -d "$GCC_INCLUDES"; then
  81             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  82         fi
  83     done
  84 fi
  85 AC_SUBST([MKDEP_OPTIONS])
  86
  87 dnl Make sure the pkg-config macros are defined
  88 m4_ifndef([PKG_PROG_PKG_CONFIG],
  89     [m4_fatal([Could not locate the pkg-config autoconf macros.
  90   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
  91   are in a different location, try setting the environment variable
  92   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
  93 PKG_PROG_PKG_CONFIG()
  94
  95 dnl LIB_DIR - library basename
  96 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
  97 AC_SUBST([LIB_DIR])
  98
  99 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 100 _SAVE_LDFLAGS="$LDFLAGS"
 101 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 102 AC_SUBST([EXTRA_LIB_PATH])
 103
 104 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 105 _SAVE_CPPFLAGS="$CPPFLAGS"
 106 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 107 AC_SUBST([X11_INCLUDES])
 108
 109 dnl Compiler macros
 110 DEFINES=""
 111 AC_SUBST([DEFINES])
 112 case "$host_os" in
 113 linux*|*-gnu*|gnu*)
 114     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 115     ;;
 116 solaris*)
 117     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 118     ;;
 119 cygwin*)
 120     DEFINES="$DEFINES -DPTHREADS"
 121     ;;
 122 esac
 123
 124 dnl Add flags for gcc and g++
 125 if test "x$GCC" = xyes; then
 126     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99 -ffast-math"
 127
 128     # Enable -fvisibility=hidden if using a gcc that supports it
 129     save_CFLAGS="$CFLAGS"
 130     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 131     CFLAGS="$CFLAGS -fvisibility=hidden"
 132     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 133                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 134
 135     # Work around aliasing bugs - developers should comment this out
 136     CFLAGS="$CFLAGS -fno-strict-aliasing"
 137 fi
 138 if test "x$GXX" = xyes; then
 139     CXXFLAGS="$CXXFLAGS -Wall"
 140
 141     # Work around aliasing bugs - developers should comment this out
 142     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 143 fi
 144
 145 dnl These should be unnecessary, but let the user set them if they want
 146 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 147     Default is to use CFLAGS.])
 148 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 149     compiler. Default is to use CFLAGS.])
 150 AC_SUBST([OPT_FLAGS])
 151 AC_SUBST([ARCH_FLAGS])
 152
 153 dnl
 154 dnl Hacks to enable 32 or 64 bit build
 155 dnl
 156 AC_ARG_ENABLE([32-bit],
 157     [AS_HELP_STRING([--enable-32-bit],
 158         [build 32-bit libraries @<:@default=auto@:>@])],
 159     [enable_32bit="$enableval"],
 160     [enable_32bit=auto]
 161 )
 162 if test "x$enable_32bit" = xyes; then
 163     if test "x$GCC" = xyes; then
 164         CFLAGS="$CFLAGS -m32"
 165         ARCH_FLAGS="$ARCH_FLAGS -m32"
 166     fi
 167     if test "x$GXX" = xyes; then
 168         CXXFLAGS="$CXXFLAGS -m32"
 169     fi
 170 fi
 171 AC_ARG_ENABLE([64-bit],
 172     [AS_HELP_STRING([--enable-64-bit],
 173         [build 64-bit libraries @<:@default=auto@:>@])],
 174     [enable_64bit="$enableval"],
 175     [enable_64bit=auto]
 176 )
 177 if test "x$enable_64bit" = xyes; then
 178     if test "x$GCC" = xyes; then
 179         CFLAGS="$CFLAGS -m64"
 180     fi
 181     if test "x$GXX" = xyes; then
 182         CXXFLAGS="$CXXFLAGS -m64"
 183     fi
 184 fi
 185
 186 dnl
 187 dnl shared/static libraries, mimic libtool options
 188 dnl
 189 AC_ARG_ENABLE([static],
 190     [AS_HELP_STRING([--enable-static],
 191         [build static libraries @<:@default=disabled@:>@])],
 192     [enable_static="$enableval"],
 193     [enable_static=no]
 194 )
 195 case "x$enable_static" in
 196 xyes|xno ) ;;
 197 x ) enable_static=no ;;
 198 * )
 199     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 200     ;;
 201 esac
 202 AC_ARG_ENABLE([shared],
 203     [AS_HELP_STRING([--disable-shared],
 204         [build shared libraries @<:@default=enabled@:>@])],
 205     [enable_shared="$enableval"],
 206     [enable_shared=yes]
 207 )
 208 case "x$enable_shared" in
 209 xyes|xno ) ;;
 210 x ) enable_shared=yes ;;
 211 * )
 212     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 213     ;;
 214 esac
 215
 216 dnl Can't have static and shared libraries, default to static if user
 217 dnl explicitly requested. If both disabled, set to static since shared
 218 dnl was explicitly requirested.
 219 case "x$enable_static$enable_shared" in
 220 xyesyes )
 221     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 222     enable_shared=no
 223     ;;
 224 xnono )
 225     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 226     enable_static=yes
 227     ;;
 228 esac
 229
 230 dnl
 231 dnl mklib options
 232 dnl
 233 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 234 if test "$enable_static" = yes; then
 235     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 236 fi
 237 AC_SUBST([MKLIB_OPTIONS])
 238
 239 dnl
 240 dnl other compiler options
 241 dnl
 242 AC_ARG_ENABLE([debug],
 243     [AS_HELP_STRING([--enable-debug],
 244         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 245     [enable_debug="$enableval"],
 246     [enable_debug=no]
 247 )
 248 if test "x$enable_debug" = xyes; then
 249     DEFINES="$DEFINES -DDEBUG"
 250     if test "x$GCC" = xyes; then
 251         CFLAGS="$CFLAGS -g"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -g"
 255     fi
 256 fi
 257
 258 dnl
 259 dnl library names
 260 dnl
 261 if test "$enable_static" = yes; then
 262     LIB_EXTENSION='a'
 263 else
 264     case "$host_os" in
 265     darwin* )
 266         LIB_EXTENSION='dylib' ;;
 267     cygwin* )
 268         LIB_EXTENSION='dll.a' ;;
 269     aix* )
 270         LIB_EXTENSION='a' ;;
 271     * )
 272         LIB_EXTENSION='so' ;;
 273     esac
 274 fi
 275
 276 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 277 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 278 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 279 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 280 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 281 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 282 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 283 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 284 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 285
 286 GL_LIB_GLOB='lib$(GL_LIB).*'${LIB_EXTENSION}'*'
 287 GLU_LIB_GLOB='lib$(GLU_LIB).*'${LIB_EXTENSION}'*'
 288 GLUT_LIB_GLOB='lib$(GLUT_LIB).*'${LIB_EXTENSION}'*'
 289 GLW_LIB_GLOB='lib$(GLW_LIB).*'${LIB_EXTENSION}'*'
 290 OSMESA_LIB_GLOB='lib$(OSMESA_LIB).*'${LIB_EXTENSION}'*'
 291 EGL_LIB_GLOB='lib$(EGL_LIB).*'${LIB_EXTENSION}'*'
 292 GLESv1_CM_LIB_GLOB='lib$(GLESv1_CM_LIB).*'${LIB_EXTENSION}'*'
 293 GLESv2_LIB_GLOB='lib$(GLESv2_LIB).*'${LIB_EXTENSION}'*'
 294 VG_LIB_GLOB='lib$(VG_LIB).*'${LIB_EXTENSION}'*'
 295
 296 AC_SUBST([GL_LIB_NAME])
 297 AC_SUBST([GLU_LIB_NAME])
 298 AC_SUBST([GLUT_LIB_NAME])
 299 AC_SUBST([GLW_LIB_NAME])
 300 AC_SUBST([OSMESA_LIB_NAME])
 301 AC_SUBST([EGL_LIB_NAME])
 302 AC_SUBST([GLESv1_CM_LIB_NAME])
 303 AC_SUBST([GLESv2_LIB_NAME])
 304 AC_SUBST([VG_LIB_NAME])
 305
 306 AC_SUBST([GL_LIB_GLOB])
 307 AC_SUBST([GLU_LIB_GLOB])
 308 AC_SUBST([GLUT_LIB_GLOB])
 309 AC_SUBST([GLW_LIB_GLOB])
 310 AC_SUBST([OSMESA_LIB_GLOB])
 311 AC_SUBST([EGL_LIB_GLOB])
 312 AC_SUBST([GLESv1_CM_LIB_GLOB])
 313 AC_SUBST([GLESv2_LIB_GLOB])
 314 AC_SUBST([VG_LIB_GLOB])
 315
 316 dnl
 317 dnl Arch/platform-specific settings
 318 dnl
 319 AC_ARG_ENABLE([asm],
 320     [AS_HELP_STRING([--disable-asm],
 321         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 322     [enable_asm="$enableval"],
 323     [enable_asm=yes]
 324 )
 325 asm_arch=""
 326 ASM_FLAGS=""
 327 MESA_ASM_SOURCES=""
 328 GLAPI_ASM_SOURCES=""
 329 AC_MSG_CHECKING([whether to enable assembly])
 330 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 331 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 332 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 333     case "$host_cpu" in
 334     i?86 | x86_64)
 335         enable_asm=no
 336         AC_MSG_RESULT([no, cross compiling])
 337         ;;
 338     esac
 339 fi
 340 # check for supported arches
 341 if test "x$enable_asm" = xyes; then
 342     case "$host_cpu" in
 343     i?86)
 344         case "$host_os" in
 345         linux* | *freebsd* | dragonfly*)
 346             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 347             ;;
 348         esac
 349         ;;
 350     x86_64)
 351         case "$host_os" in
 352         linux* | *freebsd* | dragonfly*)
 353             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 354             ;;
 355         esac
 356         ;;
 357     powerpc)
 358         case "$host_os" in
 359         linux*)
 360             asm_arch=ppc
 361             ;;
 362         esac
 363         ;;
 364     sparc*)
 365         case "$host_os" in
 366         linux*)
 367             asm_arch=sparc
 368             ;;
 369         esac
 370         ;;
 371     esac
 372
 373     case "$asm_arch" in
 374     x86)
 375         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 376         MESA_ASM_SOURCES='$(X86_SOURCES)'
 377         GLAPI_ASM_SOURCES='$(X86_API)'
 378         AC_MSG_RESULT([yes, x86])
 379         ;;
 380     x86_64)
 381         ASM_FLAGS="-DUSE_X86_64_ASM"
 382         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 383         GLAPI_ASM_SOURCES='$(X86-64_API)'
 384         AC_MSG_RESULT([yes, x86_64])
 385         ;;
 386     ppc)
 387         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 388         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 389         AC_MSG_RESULT([yes, ppc])
 390         ;;
 391     sparc)
 392         ASM_FLAGS="-DUSE_SPARC_ASM"
 393         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 394         GLAPI_ASM_SOURCES='$(SPARC_API)'
 395         AC_MSG_RESULT([yes, sparc])
 396         ;;
 397     *)
 398         AC_MSG_RESULT([no, platform not supported])
 399         ;;
 400     esac
 401 fi
 402 AC_SUBST([ASM_FLAGS])
 403 AC_SUBST([MESA_ASM_SOURCES])
 404 AC_SUBST([GLAPI_ASM_SOURCES])
 405
 406 dnl PIC code macro
 407 MESA_PIC_FLAGS
 408
 409 dnl Check to see if dlopen is in default libraries (like Solaris, which
 410 dnl has it in libc), or if libdl is needed to get it.
 411 AC_CHECK_FUNC([dlopen], [],
 412     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 413
 414 dnl See if posix_memalign is available
 415 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 416
 417 dnl SELinux awareness.
 418 AC_ARG_ENABLE([selinux],
 419     [AS_HELP_STRING([--enable-selinux],
 420         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 421     [MESA_SELINUX="$enableval"],
 422     [MESA_SELINUX=no])
 423 if test "x$enable_selinux" = "xyes"; then
 424     AC_CHECK_HEADER([selinux/selinux.h],[],
 425                     [AC_MSG_ERROR([SELinux headers not found])])
 426     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 427                  [AC_MSG_ERROR([SELinux library not found])])
 428     SELINUX_LIBS="-lselinux"
 429     DEFINES="$DEFINES -DMESA_SELINUX"
 430 fi
 431
 432 dnl
 433 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 434 dnl More later: fbdev, ...
 435 dnl
 436 default_driver="xlib"
 437
 438 case "$host_os" in
 439 linux*)
 440     case "$host_cpu" in
 441     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 442     esac
 443     ;;
 444 *freebsd* | dragonfly*)
 445     case "$host_cpu" in
 446     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 447     esac
 448     ;;
 449 esac
 450
 451 AC_ARG_WITH([driver],
 452     [AS_HELP_STRING([--with-driver=DRIVER],
 453         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 454     [mesa_driver="$withval"],
 455     [mesa_driver="$default_driver"])
 456 dnl Check for valid option
 457 case "x$mesa_driver" in
 458 xxlib|xdri|xosmesa)
 459     ;;
 460 *)
 461     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 462     ;;
 463 esac
 464
 465 dnl
 466 dnl Driver specific build directories
 467 dnl
 468
 469 dnl this variable will be prepended to SRC_DIRS and is not exported
 470 CORE_DIRS="mapi/glapi glsl mesa"
 471
 472 SRC_DIRS="glew"
 473 GLU_DIRS="sgi"
 474 GALLIUM_DIRS="auxiliary drivers state_trackers"
 475 GALLIUM_TARGET_DIRS=""
 476 GALLIUM_WINSYS_DIRS="sw"
 477 GALLIUM_DRIVERS_DIRS="softpipe failover trace rbug identity"
 478 GALLIUM_STATE_TRACKERS_DIRS=""
 479
 480 case "$mesa_driver" in
 481 xlib)
 482     DRIVER_DIRS="x11"
 483     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 484     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 485     ;;
 486 dri)
 487     SRC_DIRS="$SRC_DIRS glx"
 488     DRIVER_DIRS="dri"
 489     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri sw/drm"
 490     ;;
 491 osmesa)
 492     DRIVER_DIRS="osmesa"
 493     ;;
 494 esac
 495 AC_SUBST([SRC_DIRS])
 496 AC_SUBST([GLU_DIRS])
 497 AC_SUBST([DRIVER_DIRS])
 498 AC_SUBST([GALLIUM_DIRS])
 499 AC_SUBST([GALLIUM_TARGET_DIRS])
 500 AC_SUBST([GALLIUM_WINSYS_DIRS])
 501 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 502 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 503 AC_SUBST([MESA_LLVM])
 504
 505 dnl
 506 dnl User supplied program configuration
 507 dnl
 508 if test -d "$srcdir/progs/demos"; then
 509     default_demos=yes
 510 else
 511     default_demos=no
 512 fi
 513 AC_ARG_WITH([demos],
 514     [AS_HELP_STRING([--with-demos@<:@=DIRS...@:>@],
 515         [optional comma delimited demo directories to build
 516         @<:@default=auto if source available@:>@])],
 517     [with_demos="$withval"],
 518     [with_demos="$default_demos"])
 519 if test "x$with_demos" = x; then
 520     with_demos=no
 521 fi
 522
 523 dnl If $with_demos is yes, directories will be added as libs available
 524 PROGRAM_DIRS=""
 525 case "$with_demos" in
 526 no) ;;
 527 yes)
 528     # If the driver isn't osmesa, we have libGL and can build xdemos
 529     if test "$mesa_driver" != osmesa; then
 530         PROGRAM_DIRS="xdemos"
 531     fi
 532     ;;
 533 *)
 534     # verify the requested demos directories exist
 535     demos=`IFS=,; echo $with_demos`
 536     for demo in $demos; do
 537         test -d "$srcdir/progs/$demo" || \
 538             AC_MSG_ERROR([Program directory '$demo' doesn't exist])
 539     done
 540     PROGRAM_DIRS="$demos"
 541     ;;
 542 esac
 543
 544 dnl
 545 dnl Find out if X is available. The variable have_x is set if libX11 is
 546 dnl found to mimic AC_PATH_XTRA.
 547 dnl
 548 if test -n "$PKG_CONFIG"; then
 549     AC_MSG_CHECKING([pkg-config files for X11 are available])
 550     PKG_CHECK_EXISTS([x11],[
 551         x11_pkgconfig=yes
 552         have_x=yes
 553         ],[
 554         x11_pkgconfig=no
 555     ])
 556     AC_MSG_RESULT([$x11_pkgconfig])
 557 else
 558     x11_pkgconfig=no
 559 fi
 560 dnl Use the autoconf macro if no pkg-config files
 561 if test "$x11_pkgconfig" = yes; then
 562     PKG_CHECK_MODULES([X11], [x11])
 563 else
 564     AC_PATH_XTRA
 565     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 566     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 567     AC_SUBST([X11_CFLAGS])
 568     AC_SUBST([X11_LIBS])
 569 fi
 570
 571 dnl Try to tell the user that the --x-* options are only used when
 572 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 573 m4_divert_once([HELP_BEGIN],
 574 [These options are only used when the X libraries cannot be found by the
 575 pkg-config utility.])
 576
 577 dnl We need X for xlib and dri, so bomb now if it's not found
 578 case "$mesa_driver" in
 579 xlib|dri)
 580     if test "$no_x" = yes; then
 581         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 582     fi
 583     ;;
 584 esac
 585
 586 dnl XCB - this is only used for GLX right now
 587 AC_ARG_ENABLE([xcb],
 588     [AS_HELP_STRING([--enable-xcb],
 589         [use XCB for GLX @<:@default=disabled@:>@])],
 590     [enable_xcb="$enableval"],
 591     [enable_xcb=no])
 592 if test "x$enable_xcb" = xyes; then
 593     DEFINES="$DEFINES -DUSE_XCB"
 594 else
 595     enable_xcb=no
 596 fi
 597
 598 dnl
 599 dnl libGL configuration per driver
 600 dnl
 601 case "$mesa_driver" in
 602 xlib)
 603     if test "$x11_pkgconfig" = yes; then
 604         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 605         GL_PC_REQ_PRIV="x11 xext"
 606         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 607         GL_LIB_DEPS="$XLIBGL_LIBS"
 608     else
 609         # should check these...
 610         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 611         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 612         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 613         GL_PC_CFLAGS="$X11_INCLUDES"
 614     fi
 615     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread"
 616     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 617
 618     # if static, move the external libraries to the programs
 619     # and empty the libraries for libGL
 620     if test "$enable_static" = yes; then
 621         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 622         GL_LIB_DEPS=""
 623     fi
 624     ;;
 625 dri)
 626     # DRI must be shared, I think
 627     if test "$enable_static" = yes; then
 628         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 629     fi
 630
 631     # Check for libdrm
 632     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 633     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 634     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 635     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 636     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 637
 638     # find the DRI deps for libGL
 639     if test "$x11_pkgconfig" = yes; then
 640         # add xcb modules if necessary
 641         dri_modules="x11 xext xxf86vm xdamage xfixes"
 642         if test "$enable_xcb" = yes; then
 643             dri_modules="$dri_modules x11-xcb xcb-glx"
 644         fi
 645
 646         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 647         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 648         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 649         GL_LIB_DEPS="$DRIGL_LIBS"
 650     else
 651         # should check these...
 652         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 653         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 654         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 655         GL_PC_CFLAGS="$X11_INCLUDES"
 656
 657         # XCB can only be used from pkg-config
 658         if test "$enable_xcb" = yes; then
 659             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 660             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 661             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 662             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 663         fi
 664     fi
 665
 666     # need DRM libs, -lpthread, etc.
 667     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 668     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 669     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 670     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 671     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 672     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 673     ;;
 674 osmesa)
 675     # No libGL for osmesa
 676     GL_LIB_DEPS=""
 677     ;;
 678 esac
 679 AC_SUBST([GL_LIB_DEPS])
 680 AC_SUBST([GL_PC_REQ_PRIV])
 681 AC_SUBST([GL_PC_LIB_PRIV])
 682 AC_SUBST([GL_PC_CFLAGS])
 683 AC_SUBST([DRI_PC_REQ_PRIV])
 684 AC_SUBST([GLESv1_LIB_DEPS])
 685 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 686 AC_SUBST([GLESv2_LIB_DEPS])
 687 AC_SUBST([GLESv2_PC_LIB_PRIV])
 688
 689
 690 dnl
 691 dnl More X11 setup
 692 dnl
 693 if test "$mesa_driver" = xlib; then
 694     DEFINES="$DEFINES -DUSE_XSHM"
 695 fi
 696
 697 dnl
 698 dnl More DRI setup
 699 dnl
 700 AC_ARG_ENABLE([glx-tls],
 701     [AS_HELP_STRING([--enable-glx-tls],
 702         [enable TLS support in GLX @<:@default=disabled@:>@])],
 703     [GLX_USE_TLS="$enableval"],
 704     [GLX_USE_TLS=no])
 705 dnl Directory for DRI drivers
 706 AC_ARG_WITH([dri-driverdir],
 707     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 708         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 709     [DRI_DRIVER_INSTALL_DIR="$withval"],
 710     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 711 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 712 dnl Extra search path for DRI drivers
 713 AC_ARG_WITH([dri-searchpath],
 714     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 715         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 716     [DRI_DRIVER_SEARCH_DIR="$withval"],
 717     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 718 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 719 dnl Direct rendering or just indirect rendering
 720 AC_ARG_ENABLE([driglx-direct],
 721     [AS_HELP_STRING([--disable-driglx-direct],
 722         [enable direct rendering in GLX for DRI @<:@default=enabled@:>@])],
 723     [driglx_direct="$enableval"],
 724     [driglx_direct="yes"])
 725 dnl Which drivers to build - default is chosen by platform
 726 AC_ARG_WITH([dri-drivers],
 727     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 728         [comma delimited DRI drivers list, e.g.
 729         "swrast,i965,radeon" @<:@default=auto@:>@])],
 730     [with_dri_drivers="$withval"],
 731     [with_dri_drivers=yes])
 732 if test "x$with_dri_drivers" = x; then
 733     with_dri_drivers=no
 734 fi
 735
 736 dnl Determine which APIs to support
 737 AC_ARG_ENABLE([opengl],
 738     [AS_HELP_STRING([--disable-opengl],
 739         [disable support for standard OpenGL API @<:@default=no@:>@])],
 740     [enable_opengl="$enableval"],
 741     [enable_opengl=yes])
 742 AC_ARG_ENABLE([gles1],
 743     [AS_HELP_STRING([--enable-gles1],
 744         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 745     [enable_gles1="$enableval"],
 746     [enable_gles1=no])
 747 AC_ARG_ENABLE([gles2],
 748     [AS_HELP_STRING([--enable-gles2],
 749         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 750     [enable_gles2="$enableval"],
 751     [enable_gles2=no])
 752 AC_ARG_ENABLE([gles-overlay],
 753     [AS_HELP_STRING([--enable-gles-overlay],
 754         [build separate OpenGL ES only libraries @<:@default=no@:>@])],
 755     [enable_gles_overlay="$enableval"],
 756     [enable_gles_overlay=no])
 757
 758 API_DEFINES=""
 759 APIS=""
 760 GLES_OVERLAY=0
 761 if test "x$enable_opengl" = xno; then
 762     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 763 else
 764     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 765     APIS="$APIS gl"
 766 fi
 767 if test "x$enable_gles1" = xyes; then
 768     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 769     APIS="$APIS es1"
 770 fi
 771 if test "x$enable_gles2" = xyes; then
 772     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 773     APIS="$APIS es2"
 774 fi
 775 if test "x$enable_gles_overlay" = xyes -o \
 776     "x$enable_gles1" = xyes -o "x$enable_gles2" = xyes; then
 777     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
 778     if test "x$enable_gles_overlay" = xyes; then
 779         GLES_OVERLAY=1
 780     fi
 781 fi
 782 AC_SUBST([API_DEFINES])
 783 AC_SUBST([APIS])
 784 AC_SUBST([GLES_OVERLAY])
 785
 786 dnl If $with_dri_drivers is yes, directories will be added through
 787 dnl platform checks
 788 DRI_DIRS=""
 789 case "$with_dri_drivers" in
 790 no) ;;
 791 yes)
 792     DRI_DIRS="yes"
 793     ;;
 794 *)
 795     # verify the requested driver directories exist
 796     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 797     for driver in $dri_drivers; do
 798         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 799             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 800     done
 801     DRI_DIRS="$dri_drivers"
 802     ;;
 803 esac
 804
 805 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 806 if test "$mesa_driver" = dri; then
 807     # Use TLS in GLX?
 808     if test "x$GLX_USE_TLS" = xyes; then
 809         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 810     fi
 811
 812     # Platform specific settings and drivers to build
 813     case "$host_os" in
 814     linux*)
 815         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 816         if test "x$driglx_direct" = xyes; then
 817             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 818         fi
 819         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 820
 821         case "$host_cpu" in
 822         x86_64)
 823             # sis is missing because they have not be converted to use
 824             # the new interface.  i810 are missing because there is no
 825             # x86-64 system where they could *ever* be used.
 826             if test "x$DRI_DIRS" = "xyes"; then
 827                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 828                     savage tdfx unichrome swrast"
 829             fi
 830             ;;
 831         powerpc*)
 832             # Build only the drivers for cards that exist on PowerPC.
 833             # At some point MGA will be added, but not yet.
 834             if test "x$DRI_DIRS" = "xyes"; then
 835                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 836             fi
 837             ;;
 838         sparc*)
 839             # Build only the drivers for cards that exist on sparc`
 840             if test "x$DRI_DIRS" = "xyes"; then
 841                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 842             fi
 843             ;;
 844         esac
 845         ;;
 846     freebsd* | dragonfly*)
 847         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 848         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 849         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 850         if test "x$driglx_direct" = xyes; then
 851             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 852         fi
 853         if test "x$GXX" = xyes; then
 854             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 855         fi
 856
 857         if test "x$DRI_DIRS" = "xyes"; then
 858             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 859                 unichrome savage sis swrast"
 860         fi
 861         ;;
 862     gnu*)
 863         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 864         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 865         ;;
 866     solaris*)
 867         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 868         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 869         if test "x$driglx_direct" = xyes; then
 870             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 871         fi
 872         ;;
 873     esac
 874
 875     # default drivers
 876     if test "x$DRI_DIRS" = "xyes"; then
 877         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 878             savage sis tdfx unichrome swrast"
 879     fi
 880
 881     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 882
 883     # Check for expat
 884     EXPAT_INCLUDES=""
 885     EXPAT_LIB=-lexpat
 886     AC_ARG_WITH([expat],
 887         [AS_HELP_STRING([--with-expat=DIR],
 888             [expat install directory])],[
 889         EXPAT_INCLUDES="-I$withval/include"
 890         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 891         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 892         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 893         ])
 894     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 895     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 896         [AC_MSG_ERROR([Expat required for DRI.])])
 897
 898     # put all the necessary libs together
 899     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
 900 fi
 901 AC_SUBST([DRI_DIRS])
 902 AC_SUBST([EXPAT_INCLUDES])
 903 AC_SUBST([DRI_LIB_DEPS])
 904
 905 case $DRI_DIRS in
 906 *i915*|*i965*)
 907     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.19])
 908     ;;
 909 esac
 910
 911 case $DRI_DIRS in
 912 *radeon*|*r200*|*r300*|*r600*)
 913     PKG_CHECK_MODULES([LIBDRM_RADEON],
 914                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 915                       HAVE_LIBDRM_RADEON=yes,
 916                       HAVE_LIBDRM_RADEON=no)
 917
 918     if test "$HAVE_LIBDRM_RADEON" = yes; then
 919         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 920         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 921     fi
 922     ;;
 923 esac
 924 AC_SUBST([RADEON_CFLAGS])
 925 AC_SUBST([RADEON_LDFLAGS])
 926
 927
 928 dnl
 929 dnl OSMesa configuration
 930 dnl
 931 if test "$mesa_driver" = xlib; then
 932     default_gl_osmesa=yes
 933 else
 934     default_gl_osmesa=no
 935 fi
 936 AC_ARG_ENABLE([gl-osmesa],
 937     [AS_HELP_STRING([--enable-gl-osmesa],
 938         [enable OSMesa on libGL @<:@default=enabled for xlib driver@:>@])],
 939     [gl_osmesa="$enableval"],
 940     [gl_osmesa="$default_gl_osmesa"])
 941 if test "x$gl_osmesa" = xyes; then
 942     if test "$mesa_driver" = osmesa; then
 943         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 944     else
 945         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 946     fi
 947 fi
 948
 949 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 950 AC_ARG_WITH([osmesa-bits],
 951     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 952         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 953     [osmesa_bits="$withval"],
 954     [osmesa_bits=8])
 955 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 956     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 957     osmesa_bits=8
 958 fi
 959 case "x$osmesa_bits" in
 960 x8)
 961     OSMESA_LIB=OSMesa
 962     ;;
 963 x16|x32)
 964     OSMESA_LIB="OSMesa$osmesa_bits"
 965     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 966     ;;
 967 *)
 968     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 969     ;;
 970 esac
 971 AC_SUBST([OSMESA_LIB])
 972
 973 case "$mesa_driver" in
 974 osmesa)
 975     # only link libraries with osmesa if shared
 976     if test "$enable_static" = no; then
 977         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 978     else
 979         OSMESA_LIB_DEPS=""
 980     fi
 981     OSMESA_MESA_DEPS=""
 982     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
 983     ;;
 984 *)
 985     # Link OSMesa to libGL otherwise
 986     OSMESA_LIB_DEPS=""
 987     # only link libraries with osmesa if shared
 988     if test "$enable_static" = no; then
 989         OSMESA_MESA_DEPS='-l$(GL_LIB)'
 990     else
 991         OSMESA_MESA_DEPS=""
 992     fi
 993     OSMESA_PC_REQ="gl"
 994     ;;
 995 esac
 996 OSMESA_PC_LIB_PRIV="$OSMESA_PC_LIB_PRIV"
 997 AC_SUBST([OSMESA_LIB_DEPS])
 998 AC_SUBST([OSMESA_MESA_DEPS])
 999 AC_SUBST([OSMESA_PC_REQ])
1000 AC_SUBST([OSMESA_PC_LIB_PRIV])
1001
1002 dnl
1003 dnl EGL configuration
1004 dnl
1005 AC_ARG_ENABLE([egl],
1006     [AS_HELP_STRING([--disable-egl],
1007         [disable EGL library @<:@default=enabled@:>@])],
1008     [enable_egl="$enableval"],
1009     [enable_egl=yes])
1010 if test "x$enable_egl" = xyes; then
1011     SRC_DIRS="$SRC_DIRS egl"
1012     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1013     EGL_DRIVERS_DIRS=""
1014     if test "$enable_static" != yes; then
1015         # build egl_glx when libGL is built
1016         if test "$mesa_driver" != osmesa; then
1017             EGL_DRIVERS_DIRS="glx"
1018         fi
1019
1020         # build egl_dri2 when xcb-dri2 is available
1021         PKG_CHECK_MODULES([EGL_DRI2], [x11-xcb xcb-dri2 xcb-xfixes libdrm],
1022                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1023         if test "$have_xcb_dri2" = yes; then
1024             EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS dri2"
1025         fi
1026     fi
1027
1028     if test "$with_demos" = yes; then
1029         PROGRAM_DIRS="$PROGRAM_DIRS egl/eglut egl/opengl"
1030     fi
1031 fi
1032 AC_SUBST([EGL_LIB_DEPS])
1033 AC_SUBST([EGL_DRIVERS_DIRS])
1034
1035 dnl
1036 dnl GLU configuration
1037 dnl
1038 AC_ARG_ENABLE([glu],
1039     [AS_HELP_STRING([--disable-glu],
1040         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1041     [enable_glu="$enableval"],
1042     [enable_glu=yes])
1043 if test "x$enable_glu" = xyes; then
1044     SRC_DIRS="$SRC_DIRS glu"
1045
1046     case "$mesa_driver" in
1047     osmesa)
1048         # If GLU is available and we have libOSMesa (not 16 or 32),
1049         # we can build the osdemos
1050         if test "$with_demos" = yes && test "$osmesa_bits" = 8; then
1051             PROGRAM_DIRS="$PROGRAM_DIRS osdemos"
1052         fi
1053
1054         # Link libGLU to libOSMesa instead of libGL
1055         GLU_LIB_DEPS=""
1056         GLU_PC_REQ="osmesa"
1057         if test "$enable_static" = no; then
1058             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1059         else
1060             GLU_MESA_DEPS=""
1061         fi
1062         ;;
1063     *)
1064         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1065         GLU_PC_REQ="gl"
1066         GLU_PC_LIB_PRIV="-lm"
1067         if test "$enable_static" = no; then
1068             GLU_LIB_DEPS="-lm"
1069             GLU_MESA_DEPS='-l$(GL_LIB)'
1070         else
1071             GLU_LIB_DEPS=""
1072             GLU_MESA_DEPS=""
1073             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1074         fi
1075         ;;
1076     esac
1077 fi
1078 if test "$enable_static" = no; then
1079     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1080 fi
1081 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1082 AC_SUBST([GLU_LIB_DEPS])
1083 AC_SUBST([GLU_MESA_DEPS])
1084 AC_SUBST([GLU_PC_REQ])
1085 AC_SUBST([GLU_PC_REQ_PRIV])
1086 AC_SUBST([GLU_PC_LIB_PRIV])
1087 AC_SUBST([GLU_PC_CFLAGS])
1088
1089 dnl
1090 dnl GLw configuration
1091 dnl
1092 AC_ARG_ENABLE([glw],
1093     [AS_HELP_STRING([--disable-glw],
1094         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1095     [enable_glw="$enableval"],
1096     [enable_glw=yes])
1097 dnl Don't build GLw on osmesa
1098 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1099     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1100     enable_glw=no
1101 fi
1102 AC_ARG_ENABLE([motif],
1103     [AS_HELP_STRING([--enable-motif],
1104         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1105     [enable_motif="$enableval"],
1106     [enable_motif=no])
1107
1108 if test "x$enable_glw" = xyes; then
1109     SRC_DIRS="$SRC_DIRS glw"
1110     if test "$x11_pkgconfig" = yes; then
1111         PKG_CHECK_MODULES([GLW],[x11 xt])
1112         GLW_PC_REQ_PRIV="x11 xt"
1113         GLW_LIB_DEPS="$GLW_LIBS"
1114     else
1115         # should check these...
1116         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1117         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1118         GLW_PC_CFLAGS="$X11_INCLUDES"
1119     fi
1120
1121     GLW_SOURCES="GLwDrawA.c"
1122     MOTIF_CFLAGS=
1123     if test "x$enable_motif" = xyes; then
1124         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1125         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1126         if test "x$MOTIF_CONFIG" != xno; then
1127             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1128             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1129         else
1130             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1131                 [AC_MSG_ERROR([Can't locate Motif headers])])
1132             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1133                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1134         fi
1135         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1136         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1137         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1138         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1139     fi
1140
1141     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1142     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1143     if test "$enable_static" = no; then
1144         GLW_MESA_DEPS='-l$(GL_LIB)'
1145         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1146     else
1147         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1148         GLW_LIB_DEPS=""
1149         GLW_MESA_DEPS=""
1150     fi
1151 fi
1152 AC_SUBST([GLW_LIB_DEPS])
1153 AC_SUBST([GLW_MESA_DEPS])
1154 AC_SUBST([GLW_SOURCES])
1155 AC_SUBST([MOTIF_CFLAGS])
1156 AC_SUBST([GLW_PC_REQ_PRIV])
1157 AC_SUBST([GLW_PC_LIB_PRIV])
1158 AC_SUBST([GLW_PC_CFLAGS])
1159
1160 dnl
1161 dnl GLUT configuration
1162 dnl
1163 if test -f "$srcdir/include/GL/glut.h"; then
1164     default_glut=yes
1165 else
1166     default_glut=no
1167 fi
1168 AC_ARG_ENABLE([glut],
1169     [AS_HELP_STRING([--disable-glut],
1170         [enable GLUT library @<:@default=enabled if source available@:>@])],
1171     [enable_glut="$enableval"],
1172     [enable_glut="$default_glut"])
1173
1174 dnl Can't build glut if GLU not available
1175 if test "x$enable_glu$enable_glut" = xnoyes; then
1176     AC_MSG_WARN([Disabling glut since GLU is disabled])
1177     enable_glut=no
1178 fi
1179 dnl Don't build glut on osmesa
1180 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1181     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1182     enable_glut=no
1183 fi
1184
1185 if test "x$enable_glut" = xyes; then
1186     SRC_DIRS="$SRC_DIRS glut/glx"
1187     GLUT_CFLAGS=""
1188     if test "x$GCC" = xyes; then
1189         GLUT_CFLAGS="-fexceptions"
1190     fi
1191     if test "$x11_pkgconfig" = yes; then
1192         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1193         GLUT_PC_REQ_PRIV="x11 xmu xi"
1194         GLUT_LIB_DEPS="$GLUT_LIBS"
1195     else
1196         # should check these...
1197         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1198         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1199         GLUT_PC_CFLAGS="$X11_INCLUDES"
1200     fi
1201     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1202     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1203
1204     # If glut is available, we can build most programs
1205     if test "$with_demos" = yes; then
1206         PROGRAM_DIRS="$PROGRAM_DIRS demos redbook samples glsl"
1207     fi
1208
1209     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1210     if test "$enable_static" = no; then
1211         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1212     else
1213         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1214         GLUT_LIB_DEPS=""
1215         GLUT_MESA_DEPS=""
1216     fi
1217 fi
1218 AC_SUBST([GLUT_LIB_DEPS])
1219 AC_SUBST([GLUT_MESA_DEPS])
1220 AC_SUBST([GLUT_CFLAGS])
1221 AC_SUBST([GLUT_PC_REQ_PRIV])
1222 AC_SUBST([GLUT_PC_LIB_PRIV])
1223 AC_SUBST([GLUT_PC_CFLAGS])
1224
1225 dnl
1226 dnl Program library dependencies
1227 dnl    Only libm is added here if necessary as the libraries should
1228 dnl    be pulled in by the linker
1229 dnl
1230 if test "x$APP_LIB_DEPS" = x; then
1231     case "$host_os" in
1232     solaris*)
1233         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1234         ;;
1235     cygwin*)
1236         APP_LIB_DEPS="-lX11"
1237         ;;
1238     *)
1239         APP_LIB_DEPS="-lm"
1240         ;;
1241     esac
1242 fi
1243 AC_SUBST([APP_LIB_DEPS])
1244 AC_SUBST([PROGRAM_DIRS])
1245
1246 dnl
1247 dnl Gallium configuration
1248 dnl
1249 AC_ARG_ENABLE([gallium],
1250     [AS_HELP_STRING([--disable-gallium],
1251         [build gallium @<:@default=enabled@:>@])],
1252     [enable_gallium="$enableval"],
1253     [enable_gallium=yes])
1254 if test "x$enable_gallium" = xyes; then
1255     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1256     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1257                 [HAS_UDIS86="no"])
1258     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1259 fi
1260
1261 AC_SUBST([LLVM_CFLAGS])
1262 AC_SUBST([LLVM_LIBS])
1263 AC_SUBST([LLVM_LDFLAGS])
1264 AC_SUBST([LLVM_VERSION])
1265
1266 VG_LIB_DEPS=""
1267 EGL_CLIENT_APIS='$(GL_LIB)'
1268 if test "x$enable_gles_overlay" = xyes; then
1269     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1270 fi
1271
1272 dnl
1273 dnl Gallium state trackers configuration
1274 dnl
1275 AC_ARG_WITH([state-trackers],
1276     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1277         [comma delimited state_trackers list, e.g.
1278         "egl,glx" @<:@default=auto@:>@])],
1279     [with_state_trackers="$withval"],
1280     [with_state_trackers=yes])
1281
1282 case "$with_state_trackers" in
1283 no)
1284     GALLIUM_STATE_TRACKERS_DIRS=""
1285     ;;
1286 yes)
1287     # look at what else is built
1288     case "$mesa_driver" in
1289     xlib)
1290         GALLIUM_STATE_TRACKERS_DIRS=glx
1291         ;;
1292     dri)
1293         GALLIUM_STATE_TRACKERS_DIRS="dri"
1294         HAVE_ST_DRI="yes"
1295         if test "x$enable_egl" = xyes; then
1296             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1297             HAVE_ST_EGL="yes"
1298         fi
1299         # Have only tested st/xorg on 1.6.0 servers
1300         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1301             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1302             HAVE_ST_XORG="no")
1303         ;;
1304     esac
1305     ;;
1306 *)
1307     # verify the requested state tracker exist
1308     state_trackers=""
1309     _state_trackers=`IFS=', '; echo $with_state_trackers`
1310     for tracker in $_state_trackers; do
1311         case "$tracker" in
1312         dri)
1313             if test "x$mesa_driver" != xdri; then
1314                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1315             fi
1316             HAVE_ST_DRI="yes"
1317             ;;
1318         egl)
1319             if test "x$enable_egl" != xyes; then
1320                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1321             fi
1322             HAVE_ST_EGL="yes"
1323             ;;
1324         xorg)
1325             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1326             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1327             HAVE_ST_XORG="yes"
1328             ;;
1329         es)
1330             AC_MSG_WARN([state tracker 'es' has been replaced by --enable-gles-overlay])
1331
1332             if test "x$enable_gles_overlay" != xyes; then
1333                 if test "x$enable_gles1" != xyes -a "x$enable_gles2" != xyes; then
1334                     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
1335                 fi
1336                 GLES_OVERLAY=1
1337                 EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1338             fi
1339             tracker=""
1340             ;;
1341         vega)
1342             CORE_DIRS="$CORE_DIRS mapi/vgapi"
1343             VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1344             EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1345             ;;
1346         esac
1347
1348         if test -n "$tracker"; then
1349             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1350                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1351             if test -n "$state_trackers"; then
1352                 state_trackers="$state_trackers $tracker"
1353             else
1354                 state_trackers="$tracker"
1355             fi
1356         fi
1357     done
1358     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1359     ;;
1360 esac
1361
1362 AC_SUBST([VG_LIB_DEPS])
1363 AC_SUBST([EGL_CLIENT_APIS])
1364
1365 if test "x$HAVE_ST_EGL" = xyes; then
1366         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-apis"
1367 fi
1368
1369 if test "x$HAVE_ST_XORG" = xyes; then
1370     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1371         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1372         HAVE_XEXTPROTO_71="no")
1373 fi
1374
1375 AC_ARG_WITH([egl-displays],
1376     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1377         [comma delimited native displays libEGL supports, e.g.
1378         "x11,kms" @<:@default=auto@:>@])],
1379     [with_egl_displays="$withval"],
1380     [with_egl_displays=yes])
1381
1382 EGL_DISPLAYS=""
1383 case "$with_egl_displays" in
1384 yes)
1385     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1386         EGL_DISPLAYS="x11"
1387     fi
1388     ;;
1389 *)
1390     if test "x$enable_egl" != xyes; then
1391         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1392     fi
1393     # verify the requested driver directories exist
1394     egl_displays=`IFS=', '; echo $with_egl_displays`
1395     for dpy in $egl_displays; do
1396         test -d "$srcdir/src/gallium/state_trackers/egl/$dpy" || \
1397             AC_MSG_ERROR([EGL display '$dpy' does't exist])
1398     done
1399     EGL_DISPLAYS="$egl_displays"
1400     ;;
1401 esac
1402 AC_SUBST([EGL_DISPLAYS])
1403
1404 AC_ARG_WITH([egl-driver-dir],
1405     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1406                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1407     [EGL_DRIVER_INSTALL_DIR="$withval"],
1408     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1409 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1410
1411 AC_ARG_WITH([xorg-driver-dir],
1412     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1413                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1414     [XORG_DRIVER_INSTALL_DIR="$withval"],
1415     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1416 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1417
1418 AC_ARG_WITH([max-width],
1419     [AS_HELP_STRING([--with-max-width=N],
1420                     [Maximum framebuffer width (4096)])],
1421     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1422      AS_IF([test "${withval}" -gt "4096"],
1423            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1424 )
1425 AC_ARG_WITH([max-height],
1426     [AS_HELP_STRING([--with-max-height=N],
1427                     [Maximum framebuffer height (4096)])],
1428     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1429      AS_IF([test "${withval}" -gt "4096"],
1430            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1431 )
1432
1433 dnl
1434 dnl Gallium LLVM
1435 dnl
1436 AC_ARG_ENABLE([gallium-llvm],
1437     [AS_HELP_STRING([--enable-gallium-llvm],
1438         [build gallium LLVM support @<:@default=disabled@:>@])],
1439     [enable_gallium_llvm="$enableval"],
1440     [enable_gallium_llvm=auto])
1441 if test "x$enable_gallium_llvm" = xyes; then
1442     if test "x$LLVM_CONFIG" != xno; then
1443         LLVM_VERSION=`$LLVM_CONFIG --version`
1444         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1445         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1446
1447         if test "x$HAS_UDIS86" != xno; then
1448             LLVM_LIBS="$LLVM_LIBS -ludis86"
1449             DEFINES="$DEFINES -DHAVE_UDIS86"
1450         fi
1451         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1452         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1453         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1454         MESA_LLVM=1
1455     else
1456         MESA_LLVM=0
1457     fi
1458 else
1459     MESA_LLVM=0
1460 fi
1461
1462 dnl
1463 dnl Gallium helper functions
1464 dnl
1465 gallium_check_st() {
1466     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_EGL" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1467          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1468     fi
1469     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1470          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1471     fi
1472     if test "x$HAVE_ST_EGL" = xyes && test "x$3" != x; then
1473          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1474     fi
1475     if test "x$HAVE_ST_XORG" = xyes && test "x$4" != x; then
1476          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1477     fi
1478 }
1479
1480
1481 dnl
1482 dnl Gallium SVGA configuration
1483 dnl
1484 AC_ARG_ENABLE([gallium-svga],
1485     [AS_HELP_STRING([--enable-gallium-svga],
1486         [build gallium SVGA @<:@default=disabled@:>@])],
1487     [enable_gallium_svga="$enableval"],
1488     [enable_gallium_svga=auto])
1489 if test "x$enable_gallium_svga" = xyes; then
1490     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1491     gallium_check_st "svga/drm" "dri-vmwgfx" "egl-vmwgfx" "xorg-vmwgfx"
1492 elif test "x$enable_gallium_svga" = xauto; then
1493     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1494 fi
1495
1496 dnl
1497 dnl Gallium Intel configuration
1498 dnl
1499 AC_ARG_ENABLE([gallium-intel],
1500     [AS_HELP_STRING([--enable-gallium-intel],
1501         [build gallium intel @<:@default=disabled@:>@])],
1502     [enable_gallium_intel="$enableval"],
1503     [enable_gallium_intel=auto])
1504 if test "x$enable_gallium_intel" = xyes; then
1505     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1506     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1507     gallium_check_st "i915/drm i965/drm" "dri-i915 dri-i965" "egl-i915 egl-i965" "xorg-i915 xorg-i965"
1508 elif test "x$enable_gallium_intel" = xauto; then
1509     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1510     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 i965"
1511 fi
1512
1513 dnl
1514 dnl Gallium Radeon configuration
1515 dnl
1516 AC_ARG_ENABLE([gallium-radeon],
1517     [AS_HELP_STRING([--enable-gallium-radeon],
1518         [build gallium radeon @<:@default=disabled@:>@])],
1519     [enable_gallium_radeon="$enableval"],
1520     [enable_gallium_radeon=auto])
1521 if test "x$enable_gallium_radeon" = xyes; then
1522     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1523     gallium_check_st "radeon/drm" "dri-radeong" "egl-radeon" "xorg-radeon"
1524 elif test "x$enable_gallium_radeon" = xauto; then
1525     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1526 fi
1527
1528 dnl
1529 dnl Gallium Nouveau configuration
1530 dnl
1531 AC_ARG_ENABLE([gallium-nouveau],
1532     [AS_HELP_STRING([--enable-gallium-nouveau],
1533         [build gallium nouveau @<:@default=disabled@:>@])],
1534     [enable_gallium_nouveau="$enableval"],
1535     [enable_gallium_nouveau=no])
1536 if test "x$enable_gallium_nouveau" = xyes; then
1537     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1538     gallium_check_st "nouveau/drm" "dri-nouveau" "egl-nouveau" "xorg-nouveau"
1539 fi
1540
1541 dnl
1542 dnl Gallium swrast configuration
1543 dnl
1544 AC_ARG_ENABLE([gallium-swrast],
1545     [AS_HELP_STRING([--enable-gallium-swrast],
1546         [build gallium swrast @<:@default=auto@:>@])],
1547     [enable_gallium_swrast="$enableval"],
1548     [enable_gallium_swrast=auto])
1549 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1550     if test "x$HAVE_ST_DRI" = xyes; then
1551         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1552     fi
1553     if test "x$HAVE_ST_EGL" = xyes; then
1554         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-swrast"
1555     fi
1556 fi
1557
1558 dnl prepend CORE_DIRS to SRC_DIRS
1559 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1560
1561 dnl Restore LDFLAGS and CPPFLAGS
1562 LDFLAGS="$_SAVE_LDFLAGS"
1563 CPPFLAGS="$_SAVE_CPPFLAGS"
1564
1565 dnl Substitute the config
1566 AC_CONFIG_FILES([configs/autoconf])
1567
1568 dnl Replace the configs/current symlink
1569 AC_CONFIG_COMMANDS([configs],[
1570 if test -f configs/current || test -L configs/current; then
1571     rm -f configs/current
1572 fi
1573 ln -s autoconf configs/current
1574 ])
1575
1576 AC_OUTPUT
1577
1578 dnl
1579 dnl Output some configuration info for the user
1580 dnl
1581 echo ""
1582 echo "        prefix:          $prefix"
1583 echo "        exec_prefix:     $exec_prefix"
1584 echo "        libdir:          $libdir"
1585 echo "        includedir:      $includedir"
1586
1587 dnl Driver info
1588 echo ""
1589 echo "        Driver:          $mesa_driver"
1590 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1591     echo "        OSMesa:          lib$OSMESA_LIB"
1592 else
1593     echo "        OSMesa:          no"
1594 fi
1595 if test "$mesa_driver" = dri; then
1596     # cleanup the drivers var
1597     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1598 if test "x$DRI_DIRS" = x; then
1599     echo "        DRI drivers:     no"
1600 else
1601     echo "        DRI drivers:     $dri_dirs"
1602 fi
1603     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1604 fi
1605 echo "        Use XCB:         $enable_xcb"
1606
1607 echo ""
1608 if test "x$MESA_LLVM" == x1; then
1609     echo "        llvm:            yes"
1610     echo "        llvm-config:     $LLVM_CONFIG"
1611     echo "        llvm-version:    $LLVM_VERSION"
1612 else
1613     echo "        llvm:            no"
1614 fi
1615
1616 echo ""
1617 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1618     echo "        Gallium:         yes"
1619     echo "        Gallium dirs:    $GALLIUM_DIRS"
1620     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1621     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1622     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1623     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1624     if test "x$HAVE_ST_EGL" = xyes; then
1625         echo "        EGL client APIs: $EGL_CLIENT_APIS"
1626     fi
1627 else
1628     echo "        Gallium:         no"
1629 fi
1630
1631 dnl Libraries
1632 echo ""
1633 echo "        Shared libs:     $enable_shared"
1634 echo "        Static libs:     $enable_static"
1635 if test "$enable_egl" = yes; then
1636     echo "        EGL:             $EGL_DRIVERS_DIRS"
1637     echo "        EGL displays:    $EGL_DISPLAYS"
1638 else
1639     echo "        EGL:             no"
1640 fi
1641 echo "        GLU:             $enable_glu"
1642 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1643 echo "        glut:            $enable_glut"
1644
1645 dnl Programs
1646 # cleanup the programs var for display
1647 program_dirs=`echo $PROGRAM_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1648 if test "x$program_dirs" = x; then
1649     echo "        Demos:           no"
1650 else
1651     echo "        Demos:           $program_dirs"
1652 fi
1653
1654 dnl Compiler options
1655 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1656 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1657     $SED 's/^ *//;s/  */ /;s/ *$//'`
1658 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1659     $SED 's/^ *//;s/  */ /;s/ *$//'`
1660 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1661 echo ""
1662 echo "        CFLAGS:          $cflags"
1663 echo "        CXXFLAGS:        $cxxflags"
1664 echo "        Macros:          $defines"
1665
1666 echo ""
1667 echo "        Run '${MAKE-make}' to build Mesa"
1668 echo ""