configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [5])
   6 m4_define([folks_micro_version], [2])
   7 m4_define([folks_nano_version], [1])
   8
   9 # If library source has changed since last release, increment revision
  10 # If interfaces have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If interfaces have been added since last release, increment age
  13 # If interfaces have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [24])
  15 m4_define([folks_lt_revision], [1])
  16 m4_define([folks_lt_age], [0])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54
  55 AC_SUBST([CFLAGS])
  56 AC_SUBST([CPPFLAGS])
  57 AC_SUBST([LDFLAGS])
  58
  59 LT_CURRENT=folks_lt_current
  60 LT_REVISION=folks_lt_revision
  61 LT_AGE=folks_lt_age
  62 AC_SUBST([LT_CURRENT])
  63 AC_SUBST([LT_REVISION])
  64 AC_SUBST([LT_AGE])
  65
  66 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  67 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  68
  69 API_VERSION=0.6
  70 AC_SUBST([API_VERSION])
  71
  72 AC_ARG_ENABLE(tracker-backend,
  73         AC_HELP_STRING([--enable-tracker-backend],
  74                        [ build the Tracker backend]),
  75         enable_tracker_backend=$enableval,
  76         enable_tracker_backend=no )
  77
  78 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  79
  80 AC_ARG_ENABLE(eds-backend,
  81         AC_HELP_STRING([--enable-eds-backend],
  82                        [ build the E-D-S backend]),
  83         enable_eds_backend=$enableval,
  84         enable_eds_backend=no )
  85
  86 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
  87
  88 # Automatically check the dependencies for the libsocialweb backend
  89 SW_CLIENT_REQUIRED=0.25.15
  90 AC_ARG_ENABLE(libsocialweb-backend,
  91         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
  92                        [build the Libsocialweb backend (default: auto)]),
  93         enable_libsocialweb_backend=$enableval,
  94         enable_libsocialweb_backend=auto )
  95
  96 if test "x$enable_libsocialweb_backend" != "xno"; then
  97   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
  98       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
  99   if test "x$have_libsocialweb_backend" = "xyes" -a \
 100           "x$enable_vala" = "xyes"; then
 101     VALA_CHECK_PACKAGES([telepathy-glib
 102                          gio-2.0
 103                          gee-1.0
 104                          libsocialweb-client],
 105         ,
 106         have_libsocialweb_backend="no")
 107   fi
 108
 109   if test "x$have_libsocialweb_backend" = "xyes"; then
 110     AC_DEFINE(HAVE_LIBSOCIALWEB, [],
 111               [Define if you have the libsocialweb backend])
 112   fi
 113 else
 114    have_libsocialweb_backend=no
 115 fi
 116
 117 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 118   "x$have_libsocialweb_backend" != "xyes"; then
 119     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 120 fi
 121
 122 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 123         [test "x$have_libsocialweb_backend" = "xyes"])
 124
 125 # -----------------------------------------------------------
 126 # Dependencies
 127 # -----------------------------------------------------------
 128
 129 GLIB_REQUIRED=2.24.0
 130 TP_GLIB_REQUIRED=0.13.1
 131 VALA_REQUIRED=0.12.0
 132 VALADOC_REQUIRED=0.2.1
 133 TRACKER_SPARQL_REQUIRED=0.10
 134 GCONF2_REQUIRED=2.31
 135 EBOOK_REQUIRED=3.0.1
 136 EDATASERVER_REQUIRED=3.0.1
 137
 138 PKG_CHECK_MODULES([GLIB],
 139                   [glib-2.0 >= $GLIB_REQUIRED
 140                    gobject-2.0 >= $GLIB_REQUIRED])
 141 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 142 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 143 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
 144 PKG_CHECK_MODULES([GCONF2], [gconf-2.0 >= $GCONF2_REQUIRED])
 145
 146 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
 147 PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7])
 148 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 149
 150 if test x$enable_tracker_backend = xyes; then
 151         PKG_CHECK_MODULES([TRACKER_SPARQL],
 152                           [tracker-sparql-0.10 >= $TRACKER_SPARQL_REQUIRED])
 153 fi
 154
 155 if test x$enable_eds_backend = xyes; then
 156         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 157         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 158 fi
 159
 160 #
 161 # Vala building options -- allows tarball builds without installing Vala
 162 #
 163 AC_ARG_ENABLE([vala],
 164               AS_HELP_STRING([--enable-vala],
 165                              [Enable building from the Vala sources]),
 166               [enable_vala=$enableval],
 167               [enable_vala=no])
 168
 169 # will be re-set as necessary below
 170 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 171 sd=${srcdir}/
 172
 173 # Force Vala for non-release builds
 174 m4_if(folks_released, [1], [],
 175     [
 176         enable_vala=yes
 177         echo "Vala compiler required for non-release builds; requiring Vala..."
 178     ])
 179
 180 # Force Vala if generated source is missing or outdated
 181 if test \
 182         ! -e ${sd}tools/folks_import_vala.stamp -o \
 183         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 184         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 185         ! -e ${sd}tests/folks/field_details_vala.stamp -o \
 186         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 187         ! -e ${sd}tests/lib/folks-test.vapi -o \
 188         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 189         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 190         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 191         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 192         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 193         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 194         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 195         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 196         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 197         ! -e ${sd}backends/key-file/libfolks_backend_key_file_la_vala.stamp -o \
 198         ! -e ${sd}backends/telepathy/libfolks_backend_telepathy_la_vala.stamp \
 199                 -o \
 200         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 201         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 202         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 203         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 204         ! -e ${sd}folks/folks.vapi -o \
 205         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 206         enable_vala=yes
 207         echo "Vala source needs to be re-compiled; requiring Vala..."
 208 fi
 209
 210 if test "x$enable_vala" = "xyes" ; then
 211         AM_PROG_VALAC([$VALA_REQUIRED])
 212         if test "x$VALAC" = "x"; then
 213               AC_MSG_ERROR([Vala requested but valac is not installed])
 214         fi
 215
 216         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 217         if test "x$VAPIGEN" = "x"; then
 218               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 219         fi
 220
 221         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 222         # automatically
 223         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 224         AC_SUBST([VALAFLAGS])
 225         AC_SUBST([VAPIGENFLAGS])
 226         AC_SUBST([VAPIDIR])
 227
 228         VALA_CHECK_PACKAGES([telepathy-glib
 229                              gio-2.0
 230                              gee-1.0])
 231
 232         if test x$enable_tracker_backend = xyes; then
 233           VALA_CHECK_PACKAGES([tracker-sparql-0.10])
 234         fi
 235
 236         if test x$enable_eds_backend = xyes; then
 237           VALA_CHECK_PACKAGES([libxml-2.0])
 238         fi
 239 fi
 240
 241 # this will set HAVE_INTROSPECTION
 242 GOBJECT_INTROSPECTION_REQUIRE([0.9.12])
 243
 244 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 245
 246 # Various functions that we need (used in C code generated from Vala)
 247 AC_CHECK_FUNCS([memset])
 248 AC_CHECK_FUNCS([strstr])
 249
 250 # -----------------------------------------------------------
 251 # Backends
 252 # -----------------------------------------------------------
 253
 254 FOLKS_MODULE_VERSION=folks_module_version
 255 AC_SUBST([FOLKS_MODULE_VERSION])
 256 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 257
 258 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 259 AC_SUBST([BACKEND_DIR])
 260
 261 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/libfolks-backend-key-file.so'
 262 AC_SUBST([BACKEND_KF])
 263 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/libfolks-backend-telepathy.so'
 264 AC_SUBST([BACKEND_TP])
 265 BACKEND_EDS='$(top_builddir)/backends/eds/.libs/libfolks-backend-eds.so'
 266 AC_SUBST([BACKEND_EDS])
 267
 268 if test x$have_libsocialweb_backend = xyes; then
 269   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libfolks-backend-libsocialweb.so'
 270   AC_SUBST([BACKEND_LIBSOCIALWEB])
 271 fi
 272
 273 if test x$enable_tracker_backend = xyes; then
 274   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/libfolks-backend-tracker.so'
 275   AC_SUBST([BACKEND_TRACKER])
 276 fi
 277
 278 if test x$enable_eds_backend = xyes; then
 279   BACKEND_EDS='$(top_builddir)/backends/eds/.libs/libfolks-backend-eds.so'
 280   AC_SUBST([BACKEND_EDS])
 281 fi
 282
 283 # All of the backend libraries in our tree; to be used by the tests
 284 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 285 if test x$have_libsocialweb_backend = xyes; then
 286   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 287   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 288 fi
 289 if test x$enable_tracker_backend = xyes; then
 290   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 291   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 292 fi
 293 if test x$enable_eds_backend = xyes; then
 294   EDS_BACKEND_UNINST_PATH='$(BACKEND_EDS)'
 295   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$EDS_BACKEND_UNINST_PATH"
 296 fi
 297 AC_SUBST([BACKEND_UNINST_PATH])
 298
 299 # -----------------------------------------------------------
 300 # Tools
 301 # -----------------------------------------------------------
 302
 303 AC_ARG_ENABLE([import-tool],
 304               AS_HELP_STRING([--enable-import-tool],
 305                              [Enable building the meta-contact import tool]),
 306               [enable_import_tool=$enableval with_import_tool=$enableval],
 307               [enable_import_tool=maybe with_import_tool=no])
 308 AS_IF([test "$enable_import_tool" != "no"],
 309       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 310                          [with_import_tool=yes], [with_import_tool=no])])
 311 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 312       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 313 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 314
 315 # Readline's required for the folks-inspect program
 316 AC_ARG_ENABLE([inspect-tool],
 317               AS_HELP_STRING([--enable-inspect-tool],
 318                              [Enable building the data inspection tool]),
 319               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 320               [enable_inspect_tool=maybe with_inspect_tool=no])
 321 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 322       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 323                      using --enable-vala])])
 324 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 325       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 326                       --enable-vala])])
 327 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 328       [AC_CHECK_LIB([readline], [main],
 329                     [with_inspect_tool=yes], [with_inspect_tool=no],
 330                     [-lncurses])])
 331 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 332        "x$enable_vala" = "xyes"],
 333       [VALA_CHECK_PACKAGES([readline])
 334        LIBREADLINE="-lreadline -lncurses"
 335        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 336        AC_SUBST([LIBREADLINE])])
 337 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 338       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 339 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 340
 341 # -----------------------------------------------------------
 342 # Documentation
 343 # -----------------------------------------------------------
 344
 345 AC_ARG_ENABLE([docs],
 346               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 347               [enable_docs=$enableval], [enable_docs=no])
 348 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 349
 350 have_valadoc=no
 351 AS_IF([test "x$enable_docs" != xno],
 352       [AC_PATH_PROG([VALADOC], [valadoc], [:])
 353        AS_IF([test "$VALADOC" != :], have_valadoc=yes)])
 354 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 355
 356 if test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"; then
 357     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 358 fi
 359
 360 # -----------------------------------------------------------
 361 # Gettext
 362 # -----------------------------------------------------------
 363
 364 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 365 AC_SUBST(GETTEXT_PACKAGE)
 366 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 367 IT_PROG_INTLTOOL([0.35.0])
 368
 369 # -----------------------------------------------------------
 370 # Error flags
 371 # -----------------------------------------------------------
 372
 373 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 374 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 375
 376 AC_ARG_ENABLE([debug],
 377               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 378               [enable_debug=$enableval], [enable_debug=yes])
 379
 380 AC_ARG_ENABLE([Werror],
 381               AS_HELP_STRING([--disable-Werror],
 382                              [compile without -Werror (normally enabled in
 383                               development builds)]),
 384               [werror=$enableval], [werror=yes])
 385
 386 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 387 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 388                  [wno_missing_field_initializers=yes],
 389                  [wno_missing_field_initializers=no])
 390 AS_COMPILER_FLAG([-Wno-unused-parameter],
 391                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 392
 393 m4_if(folks_released, [1], [],
 394     [
 395         if test x$werror = xyes; then
 396             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 397         fi
 398         if test x$wextra = xyes -a \
 399             x$wno_missing_field_initializers = xyes -a \
 400             x$wno_unused_parameter = xyes; then
 401             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 402                 -Wno-missing-field-initializers -Wno-unused-parameter"
 403         fi
 404     ])
 405
 406 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 407 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 408 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 409 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 410                                           -Wmissing-prototypes"])
 411 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 412                                             -Wmissing-declarations"])
 413 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 414                                          -Wstrict-prototypes"])
 415
 416 AC_SUBST([ERROR_CFLAGS])
 417
 418 # Vala-related flags
 419 AS_IF([test "x$enable_vala" = "xyes"],
 420       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 421                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 422        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 423
 424 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 425 AC_SUBST([ERROR_VALAFLAGS])
 426
 427 # -----------------------------------------------------------
 428 # Final output
 429 # -----------------------------------------------------------
 430
 431 AC_CONFIG_FILES([
 432     backends/telepathy/lib/folks-telepathy.pc
 433     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 434     backends/tracker/lib/folks-tracker.pc
 435     backends/tracker/lib/folks-tracker-uninstalled.pc
 436     backends/eds/lib/folks-eds.pc
 437     backends/eds/lib/folks-eds-uninstalled.pc
 438     folks/folks.pc
 439     folks/folks-uninstalled.pc
 440     Makefile
 441     backends/Makefile
 442     backends/key-file/Makefile
 443     backends/libsocialweb/Makefile
 444     backends/libsocialweb/lib/Makefile
 445     backends/libsocialweb/lib/folks-libsocialweb.pc
 446     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 447     backends/telepathy/Makefile
 448     backends/telepathy/lib/Makefile
 449     backends/tracker/Makefile
 450     backends/tracker/lib/Makefile
 451     backends/eds/Makefile
 452     backends/eds/lib/Makefile
 453     folks/Makefile
 454     docs/Makefile
 455     po/Makefile.in
 456     tests/Makefile
 457     tests/data/Makefile
 458     tests/data/gconf.path
 459     tests/folks/Makefile
 460     tests/key-file/Makefile
 461     tests/libsocialweb/Makefile
 462     tests/telepathy/Makefile
 463     tests/tracker/Makefile
 464     tests/lib/Makefile
 465     tests/lib/folks-test-uninstalled.pc
 466     tests/lib/key-file/Makefile
 467     tests/lib/libsocialweb/Makefile
 468     tests/lib/libsocialweb/session.conf
 469     tests/eds/Makefile
 470     tests/lib/eds/Makefile
 471     tests/lib/telepathy/Makefile
 472     tests/lib/tracker/Makefile
 473     tests/lib/telepathy/contactlist/Makefile
 474     tests/lib/telepathy/contactlist/session.conf
 475     tests/tools/Makefile
 476     tools/Makefile
 477     tools/inspect/Makefile
 478 ])
 479
 480 AC_OUTPUT
 481
 482 echo "
 483 Configure summary:
 484
 485         Vala........................:  ${enable_vala}
 486         Vala Compiler...............:  ${VALAC}
 487         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS}
 488         Prefix......................:  ${prefix}
 489         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 490         Documentation...............:  ${have_valadoc}
 491         Import tool.................:  ${with_import_tool}
 492         Inspector tool..............:  ${with_inspect_tool}
 493         Tracker backend.............:  ${enable_tracker_backend}
 494         Libsocialweb backend........:  ${have_libsocialweb_backend}
 495         E-D-S backend...............:  ${enable_eds_backend}
 496
 497 "