configure.ac

   1 # vim:set et ts=4:
   2 #
   3 # ibus-pinyin - The Chinese PinYin engine for IBus
   4 #
   5 # Copyright (c) 2007-2008 Peng Huang <shawn.p.huang@gmail.com>
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  20
  21 # if not 1, append datestamp to the version number.
  22 m4_define([ibus_released], [1])
  23 m4_define([ibus_major_version], [1])
  24 m4_define([ibus_minor_version], [3])
  25 m4_define([ibus_micro_version], [3])
  26 m4_define(ibus_maybe_datestamp,
  27     m4_esyscmd([if test x]ibus_released[ != x1; then date +.%Y%m%d | tr -d '\n\r'; fi]))
  28
  29 m4_define([ibus_version],
  30     ibus_major_version.ibus_minor_version.ibus_micro_version[]ibus_maybe_datestamp)
  31
  32 AC_INIT([ibus-pinyin], [ibus_version], [http://code.google.com/p/ibus/issues/entry],[ibus-pinyin])
  33 AM_INIT_AUTOMAKE([1.10])
  34 AC_GNU_SOURCE
  35
  36 AC_CONFIG_HEADERS([config.h])
  37 AC_CONFIG_MACRO_DIR([m4])
  38 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  39
  40 # define PACKAGE_VERSION_* variables
  41 AS_VERSION
  42 AS_NANO
  43 AM_SANITY_CHECK
  44 AM_MAINTAINER_MODE
  45 AM_DISABLE_STATIC
  46 AC_PROG_CC
  47 AC_PROG_CXX
  48 AM_PROG_CC_C_O
  49 AC_ISC_POSIX
  50 AC_HEADER_STDC
  51 IT_PROG_INTLTOOL([0.35.0])
  52 AM_PROG_LIBTOOL
  53
  54 # check ibus
  55 PKG_CHECK_MODULES(IBUS, [
  56     ibus-1.0
  57 ])
  58
  59 # check sqlite
  60 PKG_CHECK_MODULES(SQLITE, [
  61     sqlite3
  62 ])
  63 AC_PATH_PROG(SQLITE3, sqlite3)
  64
  65 # check uuid
  66 AC_CHECK_FUNCS([uuid_create], [], [
  67     PKG_CHECK_MODULES(LIBUUID, uuid, [
  68         # uuid.pc exist
  69         AC_DEFINE(HAVE_LIBUUID, 1, [Define if found libuuid])
  70         HAVE_LIBUUID=yes
  71     ], [
  72         # uuid.pc does not exist
  73         uuid_old_LIBS=$LIBS
  74         AC_CHECK_HEADERS(uuid/uuid.h, [
  75             AC_SEARCH_LIBS(uuid_generate, uuid, [
  76                 test x"$ac_cv_search_uuid_generate" != x"none required" && LIBUUID_LIBS=$ac_cv_search_uuid_generate
  77                 AC_DEFINE(HAVE_LIBUUID, 1, [Define if found libuuid])
  78                 HAVE_LIBUUID=yes
  79             ], [
  80                 AC_MSG_ERROR([Can not find uuid_create and uuid_generate in libc or libuuid])
  81             ])
  82         ], [
  83             AC_MSG_ERROR([Can not find uuid_create and uuid_generate in libc or libuuid])
  84         ])
  85         LIBS=$uuid_old_LIBS
  86     ])
  87 ])
  88
  89 AM_CONDITIONAL(WITH_LIBUUID, test x"$HAVE_LIBUUID" = x"yes")
  90
  91 # check boost
  92 BOOST_REQUIRE([1.39])
  93
  94 # check sigc
  95 # PKG_CHECK_MODULES(SIGC, [
  96 #     sigc++-2.0
  97 # ])
  98
  99 # check env
 100 AC_PATH_PROG(ENV, env)
 101 AC_SUBST(ENV)
 102
 103 #check python
 104 AM_PATH_PYTHON([2.5])
 105
 106 # define GETTEXT_* variables
 107 GETTEXT_PACKAGE=ibus-pinyin
 108 AC_SUBST(GETTEXT_PACKAGE)
 109 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Gettext package])
 110
 111 AM_GLIB_GNU_GETTEXT
 112
 113 # --enable-db-android
 114 AC_ARG_ENABLE(db-android,
 115     AS_HELP_STRING([--disable-db-android],
 116         [do not build database from pinyin in android]),
 117     [enable_db_android=$enableval],
 118     [enable_db_android=yes]
 119 )
 120 AM_CONDITIONAL(IBUS_BUILD_DB_ANDROID, [test x"$enable_db_android" = x"yes" ])
 121
 122 # --enable-db-open-phrase
 123 AC_ARG_ENABLE(db-open-phrase,
 124     AS_HELP_STRING([--enable-db-open-phrase],
 125         [build open-phrase database]),
 126     [enable_db_open_phrase=$enableval],
 127     [enable_db_open_phrase=no]
 128 )
 129 AM_CONDITIONAL(IBUS_BUILD_DB_OPEN_PHRASE, [test x"$enable_db_open_phrase" = x"yes" ])
 130
 131 # OUTPUT files
 132 AC_CONFIG_FILES([ po/Makefile.in
 133 Makefile
 134 ibus-pinyin.spec
 135 src/Makefile
 136 src/pinyin.xml.in
 137 setup/Makefile
 138 setup/ibus-setup-pinyin
 139 setup/version.py
 140 data/Makefile
 141 data/db/Makefile
 142 data/db/android/Makefile
 143 data/db/open-phrase/Makefile
 144 data/icons/Makefile
 145 m4/Makefile
 146 ])
 147
 148 AC_OUTPUT
 149
 150 AC_MSG_RESULT([
 151 Build options:
 152     Version                     $VERSION
 153     Install prefix              $prefix
 154     Build database android      $enable_db_android
 155     Build database open-phrase  $enable_db_open_phrase
 156 ])
 157