configure.ac

   1 AC_PREREQ(2.62)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Ugly Plug-ins, 0.11.99,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-ugly)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.11 no-dist-gzip dist-xz tar-ustar])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([ext/mad/gstmad.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER(config.h)
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE([enable])
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use GST_API_VERSION in the filename
  41 dnl to allow side-by-side installation of different API versions
  42 GST_API_VERSION=1.0
  43 AC_SUBST(GST_API_VERSION)
  44 AC_DEFINE_UNQUOTED(GST_API_VERSION, "$GST_API_VERSION",
  45   [GStreamer API Version])
  46
  47 AS_LIBTOOL(GST, 0, 0, 0)
  48
  49 dnl *** required versions of GStreamer stuff ***
  50 GST_REQ=0.11.99
  51 GSTPB_REQ=0.11.99
  52
  53 dnl *** autotools stuff ****
  54
  55 dnl allow for different autotools
  56 AS_AUTOTOOLS_ALTERNATE
  57
  58 dnl Add parameters for aclocal
  59 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  60
  61 dnl set up gettext
  62 dnl the version check needs to stay here because autopoint greps for it
  63 AM_GNU_GETTEXT_VERSION(0.17)
  64 AM_GNU_GETTEXT([external])
  65 AG_GST_GETTEXT([gst-plugins-ugly-$GST_API_VERSION])
  66
  67 dnl *** check for arguments to configure ***
  68
  69 AG_GST_ARG_DISABLE_FATAL_WARNINGS
  70
  71 AG_GST_ARG_DEBUG
  72 AG_GST_ARG_PROFILING
  73 AG_GST_ARG_VALGRIND
  74 AG_GST_ARG_GCOV
  75
  76 AG_GST_ARG_EXAMPLES
  77
  78 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  79 AG_GST_ARG_WITH_PACKAGE_NAME
  80 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  81
  82 AG_GST_ARG_WITH_PLUGINS
  83
  84 AG_GST_ARG_ENABLE_EXTERNAL
  85
  86 AG_GST_ARG_ENABLE_EXPERIMENTAL
  87
  88 dnl *** checks for platform ***
  89
  90 dnl * hardware/architecture *
  91
  92 dnl common/m4/gst-arch.m4
  93 dnl check CPU type
  94 AG_GST_ARCH
  95
  96 dnl Determine endianness
  97 AC_C_BIGENDIAN
  98
  99 dnl *** checks for programs ***
 100
 101 dnl find a compiler
 102 AC_PROG_CC
 103 AC_PROG_CC_STDC
 104
 105 dnl determine c++ compiler
 106 AC_PROG_CXX
 107 dnl determine if c++ is available on this system
 108 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 109
 110 dnl check if the compiler supports '-c' and '-o' options
 111 AM_PROG_CC_C_O
 112
 113 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 114 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 115
 116 dnl check if the compiler supports do while(0) macros
 117 AG_GST_CHECK_DOWHILE_MACROS
 118
 119 dnl check for documentation tools
 120 GTK_DOC_CHECK([1.12])
 121 AS_PATH_PYTHON([2.1])
 122 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 123
 124 dnl *** checks for libraries ***
 125
 126 dnl check for libm, for sin()
 127 LT_LIB_M
 128 AC_SUBST(LIBM)
 129
 130 dnl *** checks for header files ***
 131
 132 dnl used by ext/a52dec
 133 AX_CREATE_STDINT_H
 134
 135 dnl Check for malloc.h
 136 AC_CHECK_HEADERS([malloc.h])
 137
 138 dnl *** checks for types/defines ***
 139
 140 dnl *** checks for structures ***
 141
 142 dnl *** checks for compiler characteristics ***
 143
 144 dnl *** checks for library functions ***
 145
 146 dnl Check for a way to display the function name in debug output
 147 AG_GST_CHECK_FUNCTION
 148
 149 dnl *** checks for dependency libraries ***
 150
 151 dnl GLib is required
 152 GLIB_REQ=2.32.0
 153 AG_GST_GLIB_CHECK([$GLIB_REQ])
 154
 155 ORC_CHECK([0.4.16])
 156
 157 dnl checks for gstreamer
 158 dnl uninstalled is selected preferentially -- see pkg-config(1)
 159 AG_GST_CHECK_GST($GST_API_VERSION, [$GST_REQ], yes)
 160 AG_GST_CHECK_GST_BASE($GST_API_VERSION, [$GST_REQ], yes)
 161 AG_GST_CHECK_GST_CHECK($GST_API_VERSION, [$GST_REQ], no)
 162 AG_GST_CHECK_GST_PLUGINS_BASE($GST_API_VERSION, [$GSTPB_REQ], yes)
 163 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 164
 165 dnl Check for documentation xrefs
 166 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 167 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_API_VERSION`"
 168 GSTPB_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-plugins-base-$GST_API_VERSION`"
 169 AC_SUBST(GLIB_PREFIX)
 170 AC_SUBST(GST_PREFIX)
 171 AC_SUBST(GSTPB_PREFIX)
 172
 173 dnl *** set variables based on configure arguments ***
 174
 175 dnl set license and copyright notice
 176 GST_LICENSE="LGPL"
 177 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 178 AC_SUBST(GST_LICENSE)
 179
 180 dnl set location of plugin directory
 181 AG_GST_SET_PLUGINDIR
 182
 183 dnl set release date/time
 184 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 185   ["${srcdir}/gst-plugins-ugly.doap"],
 186   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 187
 188 dnl define an ERROR_CFLAGS Makefile variable
 189 AG_GST_SET_ERROR_CFLAGS($FATAL_WARNINGS, [
 190     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls
 191     -Wwrite-strings -Wformat-nonliteral -Wformat-security -Wold-style-definition
 192     -Winit-self -Wmissing-include-dirs -Waddress
 193     -Waggregate-return -Wno-multichar -Wnested-externs ])
 194
 195 dnl define an ERROR_CXXFLAGS Makefile variable
 196 AG_GST_SET_ERROR_CXXFLAGS($FATAL_WARNINGS, [
 197     -Wmissing-declarations -Wredundant-decls
 198     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 199     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 200     -Wno-multichar])
 201
 202 dnl define correct level for debugging messages
 203 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 204
 205 dnl used in examples
 206 AG_GST_DEFAULT_ELEMENTS
 207
 208 dnl *** plug-ins to include ***
 209
 210 dnl Non ported plugins (non-dependant, then dependant)
 211 dnl Make sure you have a space before and after all plugins
 212 GST_PLUGINS_NONPORTED=" "
 213 AC_SUBST(GST_PLUGINS_NONPORTED)
 214
 215 dnl these are all the gst plug-ins, compilable without additional libs
 216 AG_GST_CHECK_PLUGIN(asfdemux)
 217 AG_GST_CHECK_PLUGIN(dvdlpcmdec)
 218 AG_GST_CHECK_PLUGIN(dvdsub)
 219 AG_GST_CHECK_PLUGIN(xingmux)
 220 AG_GST_CHECK_PLUGIN(realmedia)
 221
 222 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 223
 224 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 225   WIN32_LIBS="-lws2_32"
 226   AC_SUBST(WIN32_LIBS)
 227 fi
 228
 229 dnl *** ext plug-ins ***
 230 dnl keep this list sorted alphabetically !
 231
 232 if test "x$BUILD_EXTERNAL" = "xyes"; then
 233
 234 echo
 235 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 236 echo
 237
 238 dnl *** a52dec ***
 239 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 240 AG_GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 241   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 242 ])
 243
 244 dnl *** amr-nb ***
 245 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRNB, true)
 246 AG_GST_CHECK_FEATURE(AMRNB, [amrnb library], amrnb, [
 247   PKG_CHECK_MODULES(AMRNB, opencore-amrnb, [
 248     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrnb; then
 249       AC_DEFINE(HAVE_OPENCORE_AMRNB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrnb])
 250     fi
 251     HAVE_AMRNB="yes"
 252   ], [
 253     HAVE_AMRNB="no"
 254   ])
 255   AC_SUBST(AMRNB_CFLAGS)
 256   AC_SUBST(AMRNB_LIBS)
 257 ])
 258
 259 dnl *** amr-wb dec ***
 260 translit(dnm, m, l) AM_CONDITIONAL(USE_AMRWB, true)
 261 AG_GST_CHECK_FEATURE(AMRWB, [amrwb library], amrwbdec, [
 262   PKG_CHECK_MODULES(AMRWB, opencore-amrwb, [
 263     if $PKG_CONFIG --atleast-version=0.1.3 opencore-amrwb; then
 264       AC_DEFINE(HAVE_OPENCORE_AMRWB_0_1_3_OR_LATER, 1, [Defined for newer opencore-amrwb])
 265     fi
 266     HAVE_AMRWB="yes"
 267   ], [
 268     HAVE_AMRWB="no"
 269   ])
 270   AC_SUBST(AMRWB_CFLAGS)
 271   AC_SUBST(AMRWB_LIBS)
 272 ])
 273
 274 dnl *** cdio ***
 275 translit(dnm, m, l) AM_CONDITIONAL(USE_CDIO, true)
 276 AG_GST_CHECK_FEATURE(CDIO, [cdio library], cdio, [
 277   AG_GST_PKG_CHECK_MODULES(CDIO, libcdio >= 0.76)
 278 ])
 279
 280 dnl *** dvdread ***
 281 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 282 AG_GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 283   AG_GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 284   AC_SUBST(DVDREAD_LIBS)
 285 ])
 286
 287 dnl *** lame ***
 288 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
 289 AG_GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
 290   AG_GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, $LIBM, lame/lame.h,
 291   [
 292     HAVE_LAME="yes"
 293     LAME_LIBS="-lmp3lame $LIBM"
 294     dnl is lame presets available
 295     LAME_CFLAGS=""
 296     AC_TRY_COMPILE([#include <lame/lame.h>], [ int preset = MEDIUM ],
 297       [LAME_CFLAGS="-DGSTLAME_PRESET"],
 298       [LAME_CFLAGS=""]
 299     )
 300     AC_TRY_COMPILE([#include <lame/lame.h>], [
 301         void *ptr = &lame_set_VBR_quality
 302       ],
 303       [LAME_CFLAGS="$LAME_CFLAGS -DHAVE_LAME_SET_VBR_QUALITY"],
 304       [LAME_CFLAGS="$LAME_CFLAGS"]
 305     )
 306   AC_SUBST(LAME_CFLAGS)
 307   AC_SUBST(LAME_LIBS)
 308   ])
 309 ])
 310
 311 dnl *** mad ***
 312 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
 313 AG_GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
 314
 315   dnl check with pkg-config first
 316   AG_GST_PKG_CHECK_MODULES(MAD, mad >= 0.15)
 317   MAD_LIBS="$MAD_LIBS"
 318   if test "x$HAVE_MAD" = "xno"; then
 319     dnl fall back to oldskool detection
 320     AC_CHECK_HEADER(mad.h, [
 321       AC_CHECK_LIB(mad, mad_decoder_finish,
 322         HAVE_MAD="yes" MAD_LIBS="-lmad")
 323     ])
 324   fi
 325 ])
 326 AC_SUBST(MAD_LIBS)
 327
 328 dnl *** mpeg2dec ***
 329 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
 330 AG_GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
 331   AG_GST_PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0)
 332 ])
 333
 334 dnl *** sidplay : works with libsidplay 1.36.x (not 2.x.x) ***
 335 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
 336 AG_GST_CHECK_FEATURE(SIDPLAY, [libsidplay], sid, [
 337   GST_PATH_SIDPLAY()
 338 ])
 339
 340 dnl *** twolame ***
 341 translit(dnm, m, l) AM_CONDITIONAL(USE_TWOLAME, true)
 342 AG_GST_CHECK_FEATURE(TWOLAME, [twolame], twolame, [
 343   PKG_CHECK_MODULES(TWOLAME, twolame >= 0.3.10, [
 344       HAVE_TWOLAME="yes"], [
 345       HAVE_TWOLAME="no"
 346   ])
 347   AC_SUBST(TWOLAME_CFLAGS)
 348   AC_SUBST(TWOLAME_LIBS)
 349 ])
 350
 351 dnl *** x264 (MPEG-4 part 10/h.264/AVC encoder) ***
 352 translit(dnm, m, l) AM_CONDITIONAL(USE_X264, true)
 353 AG_GST_CHECK_FEATURE(X264, [x264 plug-in], x264, [
 354   AG_GST_PKG_CHECK_MODULES(X264, x264 >= 0.120.0)
 355 ])
 356
 357 else
 358
 359 dnl not building plugins with external dependencies,
 360 dnl but we still need to set the conditionals
 361
 362 AM_CONDITIONAL(USE_A52DEC, false)
 363 AM_CONDITIONAL(USE_AMRNB, false)
 364 AM_CONDITIONAL(USE_AMRWB, false)
 365 AM_CONDITIONAL(USE_CDIO, false)
 366 AM_CONDITIONAL(USE_DVDREAD, false)
 367 AM_CONDITIONAL(USE_LAME, false)
 368 AM_CONDITIONAL(USE_MAD, false)
 369 AM_CONDITIONAL(USE_MPEG2DEC, false)
 370 AM_CONDITIONAL(USE_SIDPLAY, false)
 371 AM_CONDITIONAL(USE_TWOLAME, false)
 372 AM_CONDITIONAL(USE_X264, false)
 373
 374 fi dnl of EXT plugins
 375
 376 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 377
 378 dnl Overview:
 379 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 380 dnl GST_*:              flags shared by built objects to link against GStreamer
 381 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 382 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 383 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 384 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 385
 386 dnl GST_OPTION_CFLAGS
 387 if test "x$USE_DEBUG" = xyes; then
 388    PROFILE_CFLAGS="-g"
 389 fi
 390 AC_SUBST(PROFILE_CFLAGS)
 391
 392 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 393   dnl Define _only_ during CVS (not pre-releases or releases)
 394   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 395 else
 396   DEPRECATED_CFLAGS=""
 397 fi
 398 AC_SUBST(DEPRECATED_CFLAGS)
 399
 400 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 401 dnl at make time with e.g. make ERROR_CFLAGS=""
 402 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 403 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 404 AC_SUBST(GST_OPTION_CFLAGS)
 405 AC_SUBST(GST_OPTION_CXXFLAGS)
 406
 407 dnl FIXME: do we want to rename to GST_ALL_* ?
 408 dnl prefer internal headers to already installed ones
 409 dnl also add builddir include for enumtypes and marshal
 410 dnl add GST_OPTION_CFLAGS, but overridable
 411 GST_CFLAGS="$GST_CFLAGS"
 412 GST_CXXFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 413 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 414 AC_SUBST(GST_CFLAGS)
 415 AC_SUBST(GST_CXXFLAGS)
 416 AC_SUBST(GST_LIBS)
 417
 418 dnl LDFLAGS really should only contain flags, not libs - they get added before
 419 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 420 GST_ALL_LDFLAGS="-no-undefined"
 421 AC_SUBST(GST_ALL_LDFLAGS)
 422
 423 dnl this really should only contain flags, not libs - they get added before
 424 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 425 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 426 AC_SUBST(GST_PLUGIN_LDFLAGS)
 427
 428 dnl *** output files ***
 429
 430 AC_CONFIG_FILES(
 431 Makefile
 432 common/Makefile
 433 common/m4/Makefile
 434 gst-libs/Makefile
 435 gst-libs/gst/Makefile
 436 gst/Makefile
 437 gst/asfdemux/Makefile
 438 gst/dvdlpcmdec/Makefile
 439 gst/dvdsub/Makefile
 440 gst/realmedia/Makefile
 441 gst/xingmux/Makefile
 442 ext/Makefile
 443 ext/a52dec/Makefile
 444 ext/amrnb/Makefile
 445 ext/amrwbdec/Makefile
 446 ext/cdio/Makefile
 447 ext/dvdread/Makefile
 448 ext/lame/Makefile
 449 ext/mad/Makefile
 450 ext/mpeg2dec/Makefile
 451 ext/sidplay/Makefile
 452 ext/twolame/Makefile
 453 ext/x264/Makefile
 454 docs/Makefile
 455 docs/plugins/Makefile
 456 docs/version.entities
 457 tests/Makefile
 458 tests/check/Makefile
 459 m4/Makefile
 460 po/Makefile.in
 461 pkgconfig/Makefile
 462 pkgconfig/gstreamer-plugins-ugly-uninstalled.pc
 463 gst-plugins-ugly.spec
 464 )
 465
 466 dnl Create the config.h file for Visual Studio builds
 467 dnl Beware of spaces and /'s in some of the shell variable contents.
 468 sed \
 469     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"\n\n/' \
 470     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 471     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 472     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 473     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 474     -e 's/.* GST_API_VERSION$/#define GST_API_VERSION "'$GST_API_VERSION'"/' \
 475     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 476     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 477     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 478     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 479     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 480     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 481     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 482     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 483     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 484     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 485     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 486     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 487     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 488     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 489     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 490     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 491     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 492     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 493     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 494     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 495     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 496     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 497     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 498     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 499     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 500     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 501     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
 502     -e "s/.* DEFAULT_AUDIOSRC$/#define DEFAULT_AUDIOSRC \"audiotestsrc\"/" \
 503     -e "s/.* DEFAULT_VIDEOSRC$/#define DEFAULT_VIDEOSRC \"videotestsrc\"/" \
 504     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
 505     config.h.in >win32/common/config.h-new
 506
 507 AC_OUTPUT
 508
 509 AG_GST_OUTPUT_PLUGINS
 510
 511 ORC_OUTPUT