configure.ac

   1 dnl autoconf configuration file for gst-plugins
   2 AC_INIT
   3 AC_CANONICAL_TARGET
   4
   5 dnl We disable static building for development, for time savings
   6 dnl this goes before AS_LIBTOOL to appease autoconf
   7 dnl *NOTE*: dnl this line before release, so release does static too
   8 AM_DISABLE_STATIC
   9
  10 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  11 AM_MAINTAINER_MODE
  12
  13 dnl when going to/from release please set the nano (fourth number) right !
  14 dnl releases only do Wall, cvs and prerelease does Werror too
  15 AS_VERSION(gst-plugins, GST_PLUGINS_VERSION, 0, 8, 3, 0, GST_CVS="no", GST_CVS="yes")
  16
  17 AM_INIT_AUTOMAKE($PACKAGE,$VERSION)
  18
  19 dnl our libraries and install dirs use major.minor as a version
  20 GST_MAJORMINOR=$GST_PLUGINS_VERSION_MAJOR.$GST_PLUGINS_VERSION_MINOR
  21 dnl we override it here if we need to for the release candidate
  22 #GST_MAJORMINOR=0.8
  23 AC_SUBST(GST_MAJORMINOR)
  24
  25 dnl CURRENT, REVISION, AGE
  26 dnl - library source changed -> increment REVISION
  27 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  28 dnl - interfaces added -> increment AGE
  29 dnl - interfaces removed -> AGE = 0
  30 dnl for 0.8.3 release, gst_play_get_all_by_interface was added, so update
  31 AS_LIBTOOL(GST_PLUGINS, 1, 0, 1)
  32 AM_PROG_LIBTOOL
  33
  34 dnl FIXME take something else ?
  35 AC_CONFIG_SRCDIR([gst/law/alaw.c])
  36 AM_CONFIG_HEADER(config.h)
  37
  38 dnl Add parameters for aclocal
  39 dnl (This must come after AM_INIT_AUTOMAKE, since it modifies ACLOCAL)
  40 ACLOCAL_FLAGS="-I m4 -I common/m4"
  41 AC_SUBST(ACLOCAL_AMFLAGS, $ACLOCAL_FLAGS)
  42
  43 AC_PROG_CC
  44 AM_PROG_CC_STDC
  45 AM_PROG_AS
  46 AS="${CC}"
  47 AS_PROG_OBJC
  48
  49 dnl the gettext stuff needed
  50 AM_GNU_GETTEXT_VERSION(0.11.5)
  51 AM_GNU_GETTEXT([external])
  52
  53 GETTEXT_PACKAGE=gst-plugins-$GST_MAJORMINOR
  54 AC_SUBST(GETTEXT_PACKAGE)
  55 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], "$GETTEXT_PACKAGE",
  56                    [gettext package name])
  57
  58 dnl define LOCALEDIR in config.h
  59 AS_AC_EXPAND(LOCALEDIR, $datadir/locale)
  60 AC_DEFINE_UNQUOTED([LOCALEDIR], "$LOCALEDIR",
  61                    [gettext locale dir])
  62
  63 dnl decide on error flags
  64 AS_COMPILER_FLAG(-Wall, GST_WALL="yes", GST_WALL="no")
  65
  66 if test "x$GST_WALL" = "xyes"; then
  67    GST_ERROR="$GST_ERROR -Wall"
  68
  69    if test "x$GST_CVS" = "xyes"; then
  70      AS_COMPILER_FLAG(-Werror,GST_ERROR="$GST_ERROR -Werror",GST_ERROR="$GST_ERROR")
  71    fi
  72 fi
  73
  74 dnl determine c++ compiler
  75 AC_PROG_CXX
  76 dnl determine if c++ is available on this system
  77 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
  78 dnl determine c++ preprocessor
  79 AC_PROG_CXXCPP
  80 AC_ISC_POSIX
  81
  82 AC_HEADER_STDC([])
  83 AC_C_INLINE
  84 AX_CREATE_STDINT_H
  85
  86 dnl Check for malloc.h
  87 AC_CHECK_HEADER(malloc.h,[
  88   AC_DEFINE(HAVE_MALLOC_H, 1, [whether malloc.h available])
  89 ])
  90
  91 dnl Check for a way to display the function name in debug output
  92 GST_CHECK_FUNCTION()
  93
  94 dnl define correct errorlevel for debugging messages. We want to have GST_ERROR
  95 dnl messages printed when running cvs builds
  96 if test "x$GST_CVS" = "xyes"; then
  97   AC_DEFINE(GST_LEVEL_DEFAULT, GST_LEVEL_ERROR, [Default errorlevel to use])
  98 fi
  99
 100 dnl Check for FIONREAD ioctl declaration :
 101 GST_CHECK_FIONREAD()
 102
 103 dnl ############################################
 104 dnl # Super Duper options for plug-in building #
 105 dnl ############################################
 106
 107 dnl ext plug-ins; plug-ins that have external dependencies
 108 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 109 [HAVE_EXTERNAL=yes],enabled,
 110 [
 111   AC_MSG_WARN(building external plug-ins)
 112   BUILD_EXTERNAL="yes"
 113 ],[
 114   AC_MSG_WARN(all plug-ins with external dependencies will not be built)
 115   BUILD_EXTERNAL="no"
 116 ])
 117 # make BUILD_EXTERNAL available to Makefile.am
 118 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 119
 120 dnl experimental plug-ins; stuff that hasn't had the dust settle yet
 121 dnl read 'builds, but might not work'UTO
 122 GST_CHECK_FEATURE(EXPERIMENTAL, [enable building of experimental plug-ins],,
 123 [HAVE_EXPERIMENTAL=yes],disabled,
 124 [
 125   AC_MSG_WARN(building experimental plug-ins)
 126   USE_TARKIN="yes"
 127 ],[
 128   AC_MSG_NOTICE(not building experimental plug-ins)
 129   USE_TARKIN="no"
 130 ])
 131
 132 dnl broken plug-ins; stuff that doesn't seem to build at the moment
 133 GST_CHECK_FEATURE(BROKEN, [enable building of broken plug-ins],,
 134 HAVE_BROKEN=yes,disabled,
 135 [
 136   AC_MSG_WARN([building broken plug-ins -- no bug reports on these, only patches :)])
 137 ],[
 138   AC_MSG_NOTICE([not building broken plug-ins])
 139 ])
 140
 141 dnl ##############################
 142 dnl # Do automated configuration #
 143 dnl ##############################
 144
 145 dnl Check for tools:
 146 dnl ================
 147
 148 dnl allow for different autotools
 149 AS_AUTOTOOLS_ALTERNATE()
 150
 151 dnl modify pkg-config path
 152 AC_ARG_WITH(pkg-config-path,
 153    AC_HELP_STRING([--with-pkg-config-path],[colon-separated list of pkg-config(1) dirs]),
 154    [export PKG_CONFIG_PATH=${withval}])
 155
 156 dnl check architecture
 157 GST_ARCH()
 158
 159 dnl Check for nasm
 160 AC_PATH_PROG(NASM_PATH, nasm, no)
 161 AC_SUBST(NASM_PATH)
 162 if test x$NASM_PATH = xno; then
 163   AC_MSG_WARN(Couldn't find nasm)
 164   HAVE_NASM="no"
 165 else
 166   AC_DEFINE(HAVE_NASM, 1, [Define if NASM, the netwide assembler, is available])
 167   HAVE_NASM="yes"
 168 fi
 169
 170 dnl check for gconftool-2
 171 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONFTOOL, true)
 172 GST_CHECK_FEATURE(GCONFTOOL, [GConf schemas], , [
 173   AC_PATH_PROG(GCONFTOOL, gconftool-2, no)
 174   if test x$GCONFTOOL = xno; then
 175     AC_MSG_WARN(Not installing GConf schemas)
 176     HAVE_GCONFTOOL="no"
 177   else
 178     AM_GCONF_SOURCE_2
 179     HAVE_GCONFTOOL="yes"
 180   fi
 181   AC_SUBST(HAVE_GCONFTOOL)
 182 ])
 183
 184 dnl check for GConf libraries
 185 translit(dnm, m, l) AM_CONDITIONAL(USE_GCONF, true)
 186 GST_CHECK_FEATURE(GCONF, [GConf libraries], , [
 187   PKG_CHECK_MODULES(GCONF, gconf-2.0, HAVE_GCONF="yes", HAVE_GCONF="no")
 188   AC_SUBST(GCONF_CFLAGS)
 189   AC_SUBST(GCONF_LIBS)
 190 ])
 191
 192 dnl check for gstreamer
 193 dnl uninstalled is selected preferentially -- see pkg-config(1)
 194 GST_REQ=0.8.4
 195 PKG_CHECK_MODULES(GST, gstreamer-$GST_MAJORMINOR >= $GST_REQ,
 196   HAVE_GST="yes", HAVE_GST="no")
 197
 198 if test "x$HAVE_GST" = "xno"; then
 199   AC_MSG_ERROR(no GStreamer found)
 200 fi
 201
 202 GST_TOOLS_DIR=`pkg-config --variable=toolsdir gstreamer-$GST_MAJORMINOR`
 203 if test -z $GST_TOOLS_DIR; then
 204   AC_MSG_ERROR([no tools dir defined in GStreamer pkg-config file; core upgrade needed.])
 205 fi
 206 AC_SUBST(GST_TOOLS_DIR)
 207
 208 dnl check for gstreamer-control; uninstalled is selected preferentially
 209 PKG_CHECK_MODULES(GST_CONTROL, gstreamer-control-$GST_MAJORMINOR >= $GST_REQ,
 210   HAVE_GST_CONTROL="yes", HAVE_GST_CONTROL="no")
 211
 212 if test "x$HAVE_GST_CONTROL" = "xno"; then
 213   AC_MSG_ERROR(no GStreamer Control Libs found)
 214 fi
 215
 216 AC_SUBST(GST_CONTROL_LIBS)
 217
 218 dnl Determine endianness
 219 AC_C_BIGENDIAN
 220
 221 dnl Check for fast float to int casting as defined in C99
 222 AC_C99_FUNC_LRINT()
 223 AC_C99_FUNC_LRINTF()
 224
 225 dnl Check for essential libraries first:
 226 dnl ====================================
 227
 228 GST_GLIB2_CHECK()
 229
 230 dnl Check for additional libraries that we might use:
 231 dnl =================================================
 232 dnl GTK
 233 HAVE_GTK=NO
 234 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 235 if test "x$HAVE_GTK_22" = "xyes"; then
 236   HAVE_GTK=yes
 237   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 238   AC_SUBST(GTK_VERSION)
 239   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 240   GDK_PIXBUF_LIBDIR=`$PKG_CONFIG --variable=libdir gdk-pixbuf-2.0`
 241   GDK_PIXBUF_PREFIXDIR=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 242   AC_SUBST(GTK_BASE_DIR)
 243 else
 244   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 245 fi
 246 if test "x$HAVE_GTK_20" = "xyes"; then
 247   HAVE_GTK=yes
 248 fi
 249 GTK_CFLAGS=$GTK2_CFLAGS
 250 GTK_LIBS=$GTK2_LIBS
 251 AC_SUBST(GTK_LIBS)
 252 AC_SUBST(GTK_CFLAGS)
 253 AC_SUBST(HAVE_GTK)
 254
 255 # gdk_pixbuf gstreamer loader is considered experimental, so disable
 256 # by default
 257 if test "x$HAVE_GTK_22" = "xyes"; then
 258   HAVE_GDK_LOADERS=yes
 259 else
 260   HAVE_GDK_LOADERS=no
 261 fi
 262
 263 # we set the defaults always to make sure we have non-empty variables
 264 # for the Makefile
 265
 266 # by default, stick to prefix
 267 GDK_PIXBUF_LOADER_DIR=${libdir}/gtk-2.0/\${GTK_VERSION}/loaders
 268 GDK_PIXBUF_CONF_DIR=${sysconfdir}/gtk-2.0
 269
 270
 271 AC_ARG_ENABLE(gdk-pixbuf-loader,
 272   AC_HELP_STRING([--enable-gdk-pixbuf-loader],
 273               [whether to enable building of gdk_pixbuf loader]),
 274               :, HAVE_GDK_LOADERS="no")
 275
 276 if test "x$HAVE_GDK_LOADERS" = "xyes"; then
 277   AC_PATH_PROG(QUERYLOADERS, gdk-pixbuf-query-loaders, no)
 278   # allow customization of pixbuf loader install location
 279   # when nothing specified, adhere to prefix settings
 280   # when called without any option with this argument, autodetect
 281   # when called with a path, set to the given path
 282
 283   AC_ARG_WITH(gdk-pixbuf-loader-dir,
 284      AC_HELP_STRING([--with-gdk-pixbuf-loader-dir],
 285         [directory to install the gdk_pixbuf loader (none for pkg-config default)]),
 286      [
 287       if test "x${withval}" != xyes ; then
 288         GDK_PIXBUF_LOADER_DIR="${withval}"
 289       else
 290         GDK_PIXBUF_LOADER_DIR="$GDK_PIXBUF_LIBDIR/gtk-2.0/\$GTK_VERSION/loaders"
 291       fi
 292      ]
 293   )
 294   AS_AC_EXPAND(GDK_PIXBUF_LOADER_DIR, $GDK_PIXBUF_LOADER_DIR)
 295   AC_SUBST(GDK_PIXBUF_LOADER_DIR)
 296   AC_MSG_NOTICE([Putting GTK+-2 pixbuf loaders in $GDK_PIXBUF_LOADER_DIR])
 297
 298   # allow customization of pixbuf loader configuration file
 299   # when nothing specified, adhere to prefix settings
 300   # when called without any option with this argument, autodetect
 301   # when called with a path, set to the given path
 302
 303   AC_ARG_WITH(gdk-pixbuf-conf-dir,
 304      AC_HELP_STRING([--with-gdk-pixbuf-conf-dir],
 305         [directory to install the gdk_pixbuf config (none for pkg-config default)]),
 306      [
 307       if test "x${withval}" != xyes ; then
 308         GDK_PIXBUF_CONF_DIR="${withval}"
 309       else
 310         GDK_PIXBUF_CONF_DIR="$GDK_PIXBUF_PREFIXDIR/etc/gtk-2.0/"
 311       fi
 312      ]
 313   )
 314   AS_AC_EXPAND(GDK_PIXBUF_CONF_DIR, $GDK_PIXBUF_CONF_DIR)
 315   AC_SUBST(GDK_PIXBUF_CONF_DIR)
 316   AC_MSG_NOTICE([Putting GTK+-2 pixbuf loader config in $GDK_PIXBUF_CONF_DIR])
 317 fi
 318 AM_CONDITIONAL(HAVE_GDK_LOADERS, test "x$HAVE_GDK_LOADERS" = "xyes")
 319
 320 PKG_CHECK_MODULES(LIBOIL, liboil-0.1, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 321 AC_SUBST(LIBOIL_CFLAGS)
 322 AC_SUBST(LIBOIL_LIBS)
 323 if test "x${HAVE_LIBOIL}" = xyes ; then
 324   #AC_DEFINE_UNQUOTED(HAVE_LIBOIL, 1, [Define if liboil is being used])
 325   true
 326 fi
 327
 328 dnl ===========================================================================
 329 dnl ============================= gst plug-ins ================================
 330 dnl ===========================================================================
 331
 332 plugindir="\$(libdir)/gstreamer-$GST_MAJORMINOR"
 333 AC_SUBST(plugindir)
 334
 335 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '[_]*(gst_|Gst|GST_).*' $GST_LIBS"
 336 AC_SUBST(GST_PLUGIN_LDFLAGS)
 337
 338 dnl these are all the gst plug-ins, compilable without additional libs
 339 GST_PLUGINS_ALL="\
 340         ac3parse \
 341         adder \
 342         alpha \
 343         asfdemux \
 344         audioconvert \
 345         audioscale \
 346         audiorate \
 347         auparse \
 348         avi \
 349         cdxaparse \
 350         chart \
 351         colorspace \
 352         cutter \
 353         debug \
 354         deinterlace \
 355         effectv \
 356         festival \
 357         ffmpegcolorspace \
 358         filter \
 359         flx \
 360         goom \
 361         interleave \
 362         law \
 363         level \
 364         matroska \
 365         median \
 366         mixmatrix \
 367         mpeg1sys \
 368         mpeg1videoparse \
 369         mpeg2sub \
 370         mpegaudio \
 371         mpegaudioparse \
 372         mpegstream \
 373         monoscope \
 374         multifilesink \
 375         multipart \
 376         overlay \
 377         passthrough \
 378         playback \
 379         playondemand \
 380         qtdemux \
 381         realmedia \
 382         rtjpeg \
 383         rtp \
 384         silence \
 385         sine \
 386         smooth \
 387         smpte \
 388         spectrum \
 389         speed \
 390         stereo \
 391         switch \
 392         synaesthesia \
 393         tags \
 394         tcp \
 395         typefind \
 396         udp \
 397         vbidec \
 398         videobox \
 399         videocrop \
 400         videodrop \
 401         videoflip \
 402         videofilter \
 403         videomixer \
 404         videorate \
 405         videoscale \
 406         videotestsrc \
 407         volenv \
 408         volume \
 409         wavenc \
 410         wavparse \
 411         y4m"
 412
 413 dnl see if we can build C++ plug-ins
 414 if test "x$HAVE_CXX" = "xyes"; then
 415   GST_PLUGINS_ALL="$GST_PLUGINS_ALL \
 416                   modplug"
 417 else
 418   AC_MSG_WARN([Not compiling plug-ins requiring C++ compiler])
 419 fi
 420
 421 AC_SUBST(GST_PLUGINS_ALL)
 422
 423 GST_PLUGINS_SELECTED=""
 424
 425 AC_ARG_WITH(plugins,
 426     AC_HELP_STRING([--with-plugins],[comma-separated list of plug-ins to compile]),
 427     [for i in `echo $withval | tr , ' '`; do
 428         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 429         then
 430             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 431         else
 432             echo "plug-in $i not recognized, ignoring..."
 433         fi
 434     done],
 435     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 436
 437 AC_SUBST(GST_PLUGINS_SELECTED)
 438
 439 dnl ==========================================================================
 440 dnl ============================= sys plug-ins ================================
 441 dnl ==========================================================================
 442
 443 dnl *** DXR3 card ***
 444 translit(dnm, m, l) AM_CONDITIONAL(USE_DXR3, true)
 445 GST_CHECK_FEATURE(DXR3, [DXR3 hardware MPEG DVD decoder],
 446   dxr3videosink dxr3audiosink dxr3spusink, [
 447   HAVE_DXR3=yes
 448   AC_CHECK_HEADER(linux/em8300.h, ,
 449                   [ AC_MSG_WARN([DXR3/em8300 header file not found]) &&
 450                     HAVE_DXR3=no ] )
 451   AC_CHECK_HEADER(linux/soundcard.h, ,
 452                   [ AC_MSG_WARN([Generic sound header file not found]) &&
 453                     HAVE_DXR3=no ] )
 454 ])
 455
 456 dnl *** OSS audio *** (Linux, *BSD)
 457 translit(dnm, m, l) AM_CONDITIONAL(USE_OSS, true)
 458 GST_CHECK_FEATURE(OSS, [OSS audio], osssrc osssink, [
 459   HAVE_OSS="yes"
 460   dnl Linux and newer BSD versions :
 461   AC_CHECK_HEADER(sys/soundcard.h, [
 462     AC_DEFINE(HAVE_OSS_INCLUDE_IN_SYS,, [Define if OSS includes are in /sys/])
 463     ] , [
 464     dnl Some old BSD versions :
 465     AC_CHECK_HEADER(soundcard.h, [
 466       AC_DEFINE(HAVE_OSS_INCLUDE_IN_ROOT,, [Define if OSS includes are in /])
 467       ], [
 468       dnl Some old BSD versions :
 469       AC_CHECK_HEADER(machine/soundcard.h, [
 470         AC_DEFINE(HAVE_OSS_INCLUDE_IN_MACHINE,, [Define if OSS includes are in /machine/])
 471         ], [
 472         HAVE_OSS="no"
 473       ])
 474     ])
 475   ])
 476 ])
 477
 478 dnl *** OS X audio ***
 479 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_AUDIO, true)
 480 GST_CHECK_FEATURE(OSX_AUDIO, [OSX audio], osxaudiosrc osxaudiosink, [
 481   AC_CHECK_HEADER(CoreAudio/CoreAudio.h, HAVE_OSX_AUDIO="yes", HAVE_OSX_AUDIO="no")
 482 ])
 483
 484 dnl *** OS X video ***
 485 translit(dnm, m, l) AM_CONDITIONAL(USE_OSX_VIDEO, true)
 486 HAVE_OSX_VIDEO="no"
 487 GST_CHECK_FEATURE(OSX_VIDEO, [OSX video], osxvideosink, [
 488   AC_CHECK_HEADER(OpenGL/gl.h, HAVE_OSX_VIDEO="yes", HAVE_OSX_VIDEO="no")
 489 ])
 490 dnl in case header OpenGL/gl.h is found on other platforms
 491 case "$host" in
 492   *-*darwin*)
 493     dnl do nothing
 494     ;;
 495   *)
 496     HAVE_OSX_VIDEO="no"
 497     ;;
 498 esac
 499
 500 dnl *** QuickCam ***
 501 translit(dnm, m, l) AM_CONDITIONAL(USE_QCAM, true)
 502 GST_CHECK_FEATURE(QCAM, [QuickCam], qcamsrc, [
 503   if test "x$HAVE_CPU_I386" != "xyes";
 504   then
 505     HAVE_QCAM="no"
 506   else
 507     AC_CHECK_HEADER(sys/io.h, HAVE_QCAM="yes", HAVE_QCAM="no")
 508   fi
 509   if test "x$HAVE_QCAM" != "xyes";
 510   then
 511     AC_MSG_WARN([QuickCam only works on i386-linux])
 512   fi
 513 ])
 514
 515 dnl *** Sun Audio ***
 516 translit(dnm, m, l) AM_CONDITIONAL(USE_SUNAUDIO, true)
 517 GST_CHECK_FEATURE(SUNAUDIO, [Sun Audio], sunaudiosink, [
 518   AC_CHECK_HEADER(sys/audioio.h, HAVE_SUNAUDIO="yes", HAVE_SUNAUDIO="no")
 519 ])
 520
 521 dnl *** Video CD ***
 522 translit(dnm, m, l) AM_CONDITIONAL(USE_VCD, true)
 523 GST_CHECK_FEATURE(VCD, [Video CD], vcdsrc, [
 524   AC_CHECK_HEADER(linux/cdrom.h, HAVE_VCD="yes", HAVE_VCD="no")
 525 ])
 526
 527 dnl *** CDROM Audio ***
 528 translit(dnm, m, l) AM_CONDITIONAL(USE_CDROM, true)
 529
 530 GST_CHECK_FEATURE(CDROM, [CDROM Audio], cdrom, [
 531   AC_CHECK_HEADERS(linux/cdrom.h) dnl linux
 532   AC_CHECK_HEADERS(sys/cdio.h) dnl almost everything else
 533 dnl  AC_CHECK_HEADERS(dmedia/cdaudio.h) dnl irix
 534
 535   if test "${ac_cv_header_linux_cdrom_h}" = "yes" || test "${ac_cv_header_sys_cdio_h}" = "yes" || test "${ac_cv_header_dmedia_cdaudio_h}" = "yes"; then
 536         case "$host" in
 537                 *-sun-* | *-*-linux*)
 538                         AC_DEFINE(HAVE_CDROM_SOLARIS,, [Define if cdrom access is in Solaris style])
 539                 ;;
 540                 *-*-freebsd*)
 541                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 542                 ;;
 543                 *-*-netbsd* | *-*-openbsd*)
 544                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 545                         AC_DEFINE(HAVE_CDROM_BSD_NETBSD,, [Define if cdrom access uses NetBSD variant])
 546                 ;;
 547                 *-*darwin*)
 548                         AC_DEFINE(HAVE_CDROM_BSD,, [Define if cdrom access is in BSD style])
 549                         AC_DEFINE(HAVE_CDROM_BSD_DARWIN,, [Define if cdrom access uses Darwin variant])
 550                 ;;
 551 dnl             *-irix-*)
 552 dnl                     AC_DEFINE(HAVE_CDROM_IRIX,, [Define if cdrom access is in Irix DMedia style])
 553 dnl             ;;
 554     esac
 555
 556         HAVE_CDROM="yes"
 557   else
 558         HAVE_CDROM="no"
 559   fi
 560 ])
 561
 562 dnl Check for X11
 563 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 564 GST_CHECK_FEATURE(X, [X libraries and plugins],
 565                   [ximagesink], [
 566   AC_PATH_XTRA
 567   dnl now try to find the HEADER
 568   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 569
 570   if test "x$HAVE_X" = "xno"
 571   then
 572     AC_MSG_NOTICE([cannot find X11 development files])
 573   else
 574     dnl this is much more than we want
 575     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 576     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 577     dnl it does not add the libs; therefore we add them here
 578     X_LIBS="$X_LIBS -lX11"
 579     AC_SUBST(X_CFLAGS)
 580     AC_SUBST(X_LIBS)
 581   fi
 582   AC_SUBST(HAVE_X)
 583 ])
 584
 585 dnl *** XVideo ***
 586 dnl Look for the PIC library first, Debian requires it.
 587 dnl Check debian-devel archives for gory details.
 588 dnl 20020110:
 589 dnl At the moment XFree86 doesn't distribute shared libXv due
 590 dnl to unstable API.  On many platforms you CAN NOT link a shared
 591 dnl lib to a static non-PIC lib.  This is what the xvideo GStreamer
 592 dnl plug-in wants to do.  So Debian distributes a PIC compiled
 593 dnl version of the static lib for plug-ins to link to when it is
 594 dnl inappropriate to link the main application to libXv directly.
 595 dnl FIXME: add check if this platform can support linking to a
 596 dnl        non-PIC libXv, if not then don not use Xv.
 597 dnl FIXME: perhaps warn user if they have a shared libXv since
 598 dnl        this is an error until XFree86 starts shipping one
 599
 600 dnl Check for Xv extension
 601 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 602 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 603                   [xvimagesink], [
 604   if test x$HAVE_X = xyes; then
 605     AC_CHECK_LIB(Xv_pic, XvQueryExtension,
 606                  HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 607                  $X_LIBS -lXext)
 608
 609     if test x$HAVE_XVIDEO = xyes; then
 610       XVIDEO_LIBS="-lXv_pic -lXext"
 611       AC_SUBST(XVIDEO_LIBS)
 612     else
 613       dnl try again using something else if we didn't find it first
 614       if test x$HAVE_XVIDEO = xno; then
 615         AC_CHECK_LIB(Xv, XvQueryExtension,
 616                    HAVE_XVIDEO="yes", HAVE_XVIDEO="no",
 617                    $X_LIBS -lXext)
 618
 619         if test x$HAVE_XVIDEO = xyes; then
 620           XVIDEO_LIBS="-lXv -lXext"
 621           AC_SUBST(XVIDEO_LIBS)
 622         fi
 623       fi
 624     fi
 625   fi
 626 ])
 627
 628 dnl check for X Shm
 629 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 630 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], xshm, [
 631   if test x$HAVE_X = xyes; then
 632     AC_CHECK_LIB(Xext, XShmAttach,
 633                  HAVE_XSHM="yes", HAVE_XSHM="no",
 634                  $X_LIBS)
 635     if test "x$HAVE_XSHM" = "xyes"; then
 636       XSHM_LIBS="-lXext"
 637     else
 638       dnl On AIX, it is in XextSam instead, but we still need -lXext
 639       AC_CHECK_LIB(XextSam, XShmAttach,
 640                    HAVE_XSHM="yes", HAVE_XSHM="no",
 641                    $X_LIBS)
 642       if test "x$HAVE_XSHM" = "xyes"; then
 643         XSHM_LIBS="-lXext -lXextSam"
 644       fi
 645     fi
 646   fi
 647 ], , [
 648   AC_SUBST(HAVE_XSHM)
 649   AC_SUBST(XSHM_LIBS)
 650 ] )
 651
 652 dnl v4l/v4l2 checks have been moved down because they require X
 653
 654 dnl *** Video 4 Linux ***
 655 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 656 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L, true)
 657 GST_CHECK_FEATURE(V4L, [Video 4 Linux], v4lsrc v4lmjpegsrc v4lmjpegsink, [
 658   # first check X
 659   HAVE_V4L="no"
 660   if test "$HAVE_X" = "yes"
 661   then
 662     AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_V4L="yes", HAVE_V4L="no", [
 663 #include <sys/types.h>
 664 #define _LINUX_TIME_H
 665 #include <linux/videodev.h>
 666     ])
 667   fi
 668 ])
 669
 670 dnl *** Video 4 Linux 2 ***
 671 dnl for information about the header/define, see sys/v4l2/gstv4l2element.h
 672 translit(dnm, m, l) AM_CONDITIONAL(USE_V4L2, true)
 673 GST_CHECK_FEATURE(V4L2, [Video 4 Linux 2], v4l2src, [
 674   HAVE_V4L2="no"
 675   if test "$HAVE_X" = "yes"
 676   then
 677     AC_MSG_CHECKING([Checking for uptodate v4l2 installation])
 678     AC_TRY_COMPILE([
 679 #include <sys/types.h>
 680 #include <linux/types.h>
 681 #define _LINUX_TIME_H
 682 #include <linux/videodev2.h>
 683 #if defined(V4L2_MAJOR_VERSION) || defined(V4L2_MINOR_VERSION)
 684 #error too early v4l2 version or no v4l2 at all
 685 #endif
 686     ], [
 687 return 0;
 688     ], [ HAVE_V4L2="yes" && AC_MSG_RESULT(yes)],
 689        [ HAVE_V4L2="no"  && AC_MSG_RESULT(no) &&
 690          AC_CHECK_HEADER(linux/videodev2.h,
 691                          [ AC_MSG_WARN([video4linux2 headers were found, but they're old. Please update v4l2 to compile the v4l2 plugins])],
 692                          [ AC_MSG_WARN([video4linux2 was not found])])
 693        ])
 694   fi
 695   dnl check for missing v4l2_buffer declaration (see #135919)
 696   if [ test x$HAVE_V4L2 = xyes ]; then
 697     MISSING_DECL=0
 698     AC_MSG_CHECKING(struct v4l2_buffer declaration)
 699     AC_TRY_COMPILE([
 700 #include <sys/types.h>
 701 #include <linux/types.h>
 702 #define _LINUX_TIME_H
 703 #include <linux/videodev2.h>
 704     ],[
 705 struct v4l2_buffer buf;
 706 buf.index = 0;
 707 return 0;
 708     ], [ AC_MSG_RESULT(yes) ], [ MISSING_DECL=1 && AC_MSG_RESULT(no) ])
 709     if [ test x$MISSING_DECL = x1 ]; then
 710       AC_DEFINE(GST_V4L2_MISSING_BUFDECL, 1, [struct v4l2_buffer missing])
 711     fi
 712   fi
 713 ])
 714
 715 dnl Next, check for the optional libraries:
 716 dnl These are all libraries used in building plug-ins
 717 dnl ================================================
 718 dnl let's try and sort them alphabetically, shall we ?
 719
 720 if test "x$BUILD_EXTERNAL" = "xyes"; then
 721
 722 AC_MSG_NOTICE(Checking for plug-in dependency libraries)
 723
 724 dnl *** a52dec ***
 725 translit(dnm, m, l) AM_CONDITIONAL(USE_A52DEC, true)
 726 GST_CHECK_FEATURE(A52DEC, [a52dec], a52dec, [
 727   AC_CHECK_A52DEC(HAVE_A52DEC=yes, HAVE_A52DEC=no)
 728 ])
 729
 730 dnl *** aalib ***
 731 translit(dnm, m, l) AM_CONDITIONAL(USE_AALIB, true)
 732 GST_CHECK_FEATURE(AALIB, [aasink plug-in], aasink, [
 733   AM_PATH_AALIB(, HAVE_AALIB=yes, HAVE_AALIB=no)
 734   AS_SCRUB_INCLUDE(AALIB_CFLAGS)
 735 ])
 736
 737 dnl *** alsa ***
 738 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 739 GST_CHECK_FEATURE(ALSA, [alsa plug-ins], gstalsa, [
 740   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 741     HAVE_ALSA="yes"
 742     AC_SUBST(ALSA_CFLAGS)
 743     AC_SUBST(ALSA_LIBS)
 744   ], [
 745     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 746   ])
 747 ])
 748
 749 dnl *** arts ***
 750 dnl if mcopidl can't be found there's no use in compiling it
 751 AC_CHECK_PROG(MCOPIDL, mcopidl, yes, no)
 752 if test "x$HAVE_MCOPIDL" = "xno";
 753 then
 754   USE_ARTS=no
 755 fi
 756
 757 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTS, true)
 758 GST_CHECK_FEATURE(ARTS, [arts plug-ins], arts, [
 759   AM_PATH_ARTS(, HAVE_ARTS=yes, HAVE_ARTS=no)
 760 ])
 761
 762 dnl *** artsc ***
 763 translit(dnm, m, l) AM_CONDITIONAL(USE_ARTSC, true)
 764 GST_CHECK_FEATURE(ARTSC, [artsd plug-ins], artsdsink, [
 765   GST_CHECK_ARTSC()
 766 ])
 767
 768 dnl *** audiofile ***
 769 dnl this check uses the GST_CHECK_CONFIGPROG macro
 770 translit(dnm, m, l) AM_CONDITIONAL(USE_AUDIOFILE, true)
 771 GST_CHECK_FEATURE(AUDIOFILE, [audiofile], afsink afsrc, [
 772   translit(dnm, m, l) AC_SUBST(AUDIOFILE_LIBS)
 773   translit(dnm, m, l) AC_SUBST(AUDIOFILE_CFLAGS)
 774   dnl check with pkg-config first
 775   PKG_CHECK_MODULES(AUDIOFILE, audiofile, HAVE_AUDIOFILE="yes", HAVE_AUDIOFILE="no")
 776   if test "x$HAVE_AUDIOFILE" = "xno"; then
 777     GST_CHECK_CONFIGPROG(AUDIOFILE, audiofile-config)
 778     dnl we need this function
 779     AC_CHECK_LIB(audiofile, afOpenVirtualFile, , HAVE_AUDIOFILE="no")
 780     AC_CHECK_LIB(audiofile, af_virtual_file_new, , HAVE_AUDIOFILE="no")
 781   fi])
 782
 783 dnl *** CDParanoia ***
 784 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 785 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 786   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 787                       cdda_open, -lm,
 788                       cdda_interface.h,
 789                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 790                       HEADER_DIR="no"
 791                       FOUND_CDPARANOIA="yes")
 792   if test "x$FOUND_CDPARANOIA" != "xyes";
 793   then
 794     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 795                         cdda_open, -lm,
 796                         cdda/cdda_interface.h,
 797                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 798                         HEADER_DIR="yes"
 799                         FOUND_CDPARANOIA="yes")
 800   fi
 801   if test "x$HEADER_DIR" = "xyes";
 802   then
 803     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 804                        defined if cdda headers are in a cdda/ directory)
 805   fi
 806   AC_SUBST(CDPARANOIA_LIBS)
 807 ])
 808 dnl FIXME : add second check somehow if that is necessary
 809 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 810 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 811
 812 dnl *** dirac ***
 813 translit(dnm, m, l) AM_CONDITIONAL(USE_DIRAC, true)
 814 GST_CHECK_FEATURE(DIRAC, [dirac plug-ins], dirac, [
 815   PKG_CHECK_MODULES(DIRAC, dirac, HAVE_DIRAC="yes", HAVE_DIRAC="no")
 816   AC_SUBST(DIRAC_CFLAGS)
 817   AC_SUBST(DIRAC_LIBS)
 818 ])
 819
 820 dnl *** DIVX ***
 821 translit(dnm, m, l) AM_CONDITIONAL(USE_DIVX, true)
 822 GST_CHECK_FEATURE(DIVX, [divx plugins], divx, [
 823   HAVE_DIVX=yes
 824   AC_CHECK_HEADER(encore2.h, ,
 825                   [ AC_MSG_WARN([Divx4linux encore headers not found]) &&
 826                     HAVE_DIVX=no ] )
 827   if [ test x$HAVE_DIVX = xyes ]; then
 828     AC_MSG_CHECKING([Checking for valid divx4linux encore version])
 829     AC_TRY_COMPILE([
 830 #include <encore2.h>
 831 #if ENCORE_VERSION != 20021024
 832 #error Wrong version of divx encore libraries
 833 #endif
 834     ], [
 835 return 0;
 836     ], [ HAVE_DIVX=yes && AC_MSG_RESULT(yes)],
 837        [ HAVE_DIVX=no  && AC_MSG_RESULT(no) &&
 838          AC_MSG_WARN([Wrong version of divx4linux installed]) ])
 839   fi
 840   if [ test x$HAVE_DIVX = xyes ]; then
 841     AC_CHECK_HEADER(decore.h, ,
 842                     [ AC_MSG_WARN([Divx4linux decoder headers not found]) &&
 843                       HAVE_DIVX=no ] )
 844   fi
 845   if [ test x$HAVE_DIVX = xyes ]; then
 846     AC_MSG_CHECKING([Checking for valid divx4linux decore version])
 847     AC_TRY_COMPILE([
 848 #include <decore.h>
 849 #if DECORE_VERSION != 20021112
 850 #error Wrong version of divx decore libraries
 851 #endif
 852     ], [
 853 return 0;
 854     ], [ HAVE_DIVX=yes && AC_MSG_RESULT(yes)],
 855        [ HAVE_DIVX=no  && AC_MSG_RESULT(no) &&
 856          AC_MSG_WARN([Wrong version of divx4linux installed]) ])
 857   fi
 858   LIBS="-lm"
 859   if test x$HAVE_DIVX = xyes; then
 860     AC_CHECK_LIB(divxencore, encore, ,
 861                  [ AC_MSG_WARN([Divx4linux encore libs not found]) &&
 862                    HAVE_DIVX=no ] )
 863   fi
 864   if test x$HAVE_DIVX = xyes; then
 865     AC_CHECK_LIB(divxdecore, decore, ,
 866                  [ AC_MSG_WARN([Divx4linux decore libs not found]) &&
 867                    HAVE_DIVX=no ] )
 868   fi
 869   if test x$HAVE_DIVX = xyes; then
 870     DIVXENC_LIBS="-ldivxencore -lm"
 871     DIVXDEC_LIBS="-ldivxdecore -lm"
 872     AC_SUBST(DIVXENC_LIBS)
 873     AC_SUBST(DIVXDEC_LIBS)
 874   fi
 875 ])
 876
 877 dnl *** DTS ***
 878 translit(dnm, m, l) AM_CONDITIONAL(USE_DTS, true)
 879 GST_CHECK_FEATURE(DTS, [dts library], dtsdec, [
 880   GST_CHECK_LIBHEADER(DTS, dts_pic, dts_init, -lm, dts.h, DTS_LIBS="-ldts_pic -lm")
 881   AC_SUBST(DTS_LIBS)
 882 ])
 883
 884 dnl *** dvdread ***
 885 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDREAD, true)
 886 GST_CHECK_FEATURE(DVDREAD, [dvdread library], dvdreadsrc, [
 887   GST_CHECK_LIBHEADER(DVDREAD, dvdread, DVDOpen, , dvdread/dvd_reader.h, DVDREAD_LIBS="-ldvdread")
 888   AC_SUBST(DVDREAD_LIBS)
 889 ])
 890
 891 dnl *** dvdnav ***
 892 translit(dnm, m, l) AM_CONDITIONAL(USE_DVDNAV, true)
 893 GST_CHECK_FEATURE(DVDNAV, [dvdnav library], dvdnavsrc, [
 894   translit(dnm, m, l) AC_SUBST(DVDNAV_LIBS)
 895   translit(dnm, m, l) AC_SUBST(DVDNAV_CFLAGS)
 896   GST_CHECK_CONFIGPROG(DVDNAV, dvdnav-config)
 897   if test x"$HAVE_DVDNAV" = x"yes"; then
 898     dnl check version
 899     DVDNAV_VERSION=`dvdnav-config --version|head -n 1|sed 's/^.*) //'|sed 's/ (.*)//'`
 900     DVDNAV_MAJOR=`echo $DVDNAV_VERSION | cut -d. -f1 | sed s/[a-zA-Z\-].*//g`
 901     DVDNAV_MINOR=`echo $DVDNAV_VERSION | cut -d. -f2 | sed s/[a-zA-Z\-].*//g`
 902     DVDNAV_MICRO=`echo $DVDNAV_VERSION | cut -d. -f3 | sed s/[a-zA-Z\-].*//g`
 903     if [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 904        [[ "$DVDNAV_MINOR" -lt "1" ]]; then
 905       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 906       HAVE_DVDNAV="no"
 907     elif [[ "$DVDNAV_MAJOR" -eq "0" ]] && \
 908          [[ "$DVDNAV_MINOR" -eq "1" ]] && \
 909          [[ "$DVDNAV_MICRO" -lt "7" ]]; then
 910       AC_MSG_WARN([libdvdnav >= 0.1.7 is required, you have $DVDNAV_VERSION])
 911       HAVE_DVDNAV="no"
 912     fi
 913   fi
 914   dnl now check for dvdread/nav_print.h - see #133002
 915   AC_CHECK_HEADER(dvdread/nav_print.h, , [
 916       AC_MSG_WARN([header dvdread/nav_print.h from dvdread missing])
 917       HAVE_DVDNAV="no"
 918   ])
 919   AS_SCRUB_INCLUDE(DVDNAV_CFLAGS)
 920 ])
 921
 922 dnl **** ESound ****
 923 translit(dnm, m, l) AM_CONDITIONAL(USE_ESD, true)
 924 GST_CHECK_FEATURE(ESD, [esound plug-ins], esdsink esdmon, [
 925   PKG_CHECK_MODULES(ESD, esound >= 0.2.12, [
 926     HAVE_ESD="yes"
 927     AC_SUBST(ESD_CFLAGS)
 928     AC_SUBST(ESD_LIBS)
 929   ], [
 930     AM_PATH_ESD(0.2.12, HAVE_ESD="yes", HAVE_ESD="no")
 931     AS_SCRUB_INCLUDE(ESD_CFLAGS)
 932   ])
 933 ])
 934
 935 dnl **** Free AAC Encoder (FAAC) ****
 936 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAC, true)
 937 GST_CHECK_FEATURE(FAAC, [AAC encoder plug-in], faac, [
 938   GST_CHECK_LIBHEADER(FAAC, faac, faacEncOpen, -lm, faac.h, FAAC_LIBS="-lfaac -lm")
 939   AS_SCRUB_INCLUDE(FAAC_CFLAGS)
 940   AC_SUBST(FAAC_LIBS)
 941 ])
 942
 943 dnl **** Free AAC Decoder (FAAD) ****
 944 translit(dnm, m, l) AM_CONDITIONAL(USE_FAAD, true)
 945 GST_CHECK_FEATURE(FAAD, [AAC decoder plug-in], faad, [
 946   HAVE_FAAD="yes"
 947   GST_CHECK_LIBHEADER(FAAD, faad, faacDecOpen, -lm, faad.h, FAAD_LIBS="-lfaad -lm", HAVE_FAAD="no")
 948   if test $HAVE_FAAD = "yes"; then
 949     AC_MSG_CHECKING([Checking for FAAD >= 2])
 950     AC_TRY_COMPILE([
 951 #include <faad.h>
 952 #if !defined(FAAD2_VERSION) || !defined(FAAD_FMT_DOUBLE)
 953 #error Not faad2
 954 #endif
 955     ], [ return 0; ],
 956        [ HAVE_FAAD="yes" && AC_MSG_RESULT(yes)],
 957        [ HAVE_FAAD="no"  && AC_MSG_RESULT(no)])
 958   fi;
 959   AS_SCRUB_INCLUDE(FAAD_CFLAGS)
 960   AC_SUBST(FAAD_LIBS)
 961 ])
 962
 963 dnl **** festival ****
 964 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_FESTIVAL, true)
 965 dnl GST_CHECK_FEATURE(FESTIVAL, [festival plug-ins], festivalsrc, [
 966   dnl NOTE: just using local net connection now, add this lib check
 967   dnl       in the future if needed
 968   dnl AC_LANG_PUSH(C++)
 969   dnl dnl FIXME: took out func to check for
 970   dnl dnl This check puts festival_tidy_up in extern "C".
 971   dnl dnl But, at least on Debian as of 20020110, it is compiled with name
 972   dnl dnl mangling C++ nonsense and symbols can't resolve
 973   dnl dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, festival_tidy_up, , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 974   dnl GST_CHECK_LIBHEADER(FESTIVAL, Festival, , , festival/festival.h, FESTIVAL_LIBS="-lFestival")
 975   dnl AC_LANG_POP(C++)
 976   dnl AC_SUBST(FESTIVAL_LIBS)
 977 dnl  HAVE_FESTIVAL=yes
 978 dnl])
 979
 980 dnl *** FLAC ***
 981 translit(dnm, m, l) AM_CONDITIONAL(USE_FLAC, true)
 982 GST_CHECK_FEATURE(FLAC, [FLAC lossless audio], flacenc flacdec, [
 983   GST_CHECK_LIBHEADER(FLAC, FLAC, FLAC__seekable_stream_encoder_new, -lm, FLAC/all.h, FLAC_LIBS="-lFLAC")
 984   AC_SUBST(FLAC_LIBS)
 985 ])
 986
 987 dnl *** GDK pixbuf ***
 988 translit(dnm, m, l) AM_CONDITIONAL(USE_GDK_PIXBUF, true)
 989 GST_CHECK_FEATURE(GDK_PIXBUF, [GDK pixbuf], gdkpixbufsrc, [
 990   if test $HAVE_GTK_22 = "yes"; then HAVE_GDK_PIXBUF=yes; fi;
 991 ])
 992
 993 dnl *** Gnome VFS ***
 994 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 995 GST_CHECK_FEATURE(GNOME_VFS, [Gnome VFS], gnomevfssrc, [
 996   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, HAVE_GNOME_VFS="yes", HAVE_GNOME_VFS="no")
 997   AC_SUBST(GNOME_VFS_CFLAGS)
 998   AC_SUBST(GNOME_VFS_LIBS)
 999 ])
1000
1001 dnl *** gsm ***
1002 translit(dnm, m, l) AM_CONDITIONAL(USE_GSM, true)
1003 GST_CHECK_FEATURE(GSM, [GSM library], gsmenc gsmdec, [
1004   GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm.h, GSM_LIBS="-lgsm")
1005   if test $HAVE_GSM != "yes"; then
1006     GST_CHECK_LIBHEADER(GSM, gsm, gsm_create, , gsm/gsm.h, GSM_LIBS="-lgsm")
1007     if test $HAVE_GSM = "yes"; then
1008       AC_DEFINE(GSM_HEADER_IN_SUBDIR, 1, [Define if GSM header in gsm/ subdir])
1009     fi
1010   fi
1011   AC_SUBST(GSM_LIBS)
1012 ])
1013
1014 dnl *** Hermes ***
1015 translit(dnm, m, l) AM_CONDITIONAL(USE_HERMES, true)
1016 GST_CHECK_FEATURE(HERMES, [Hermes library], hermescolorspace, [
1017   GST_CHECK_LIBHEADER(HERMES, Hermes, Hermes_ConverterInstance, , Hermes/Hermes.h, HERMES_LIBS="-lHermes")
1018 ], AC_SUBST(HERMES_LIBS))
1019
1020 dnl *** http ***
1021 dnl translit(dnm, m, l) AM_CONDITIONAL(USE_HTTP, true)
1022 dnl GST_CHECK_FEATURE(HTTP, [http plug-ins], gsthttpsrc, [
1023 dnl  dnl FIXME: need to check for header
1024 dnl  GHTTP_LIBS=
1025 dnl  GST_HTTPSRC_GET_TYPE=
1026 dnl  if test x$USE_GLIB2 = xyes; then
1027 dnl    AC_MSG_WARN(ghttp disabled for glib2.0)
1028 dnl  else
1029 dnl    AC_CHECK_LIB(ghttp, ghttp_request_new,
1030 dnl      [HTTP_LIBS="-lghttp"
1031 dnl       GST_HTTPSRC_GET_TYPE="gst_httpsrc_get_type"
1032 dnl       HAVE_HTTP=yes
1033 dnl      ], :, $LIBS)
1034 dnl  fi
1035 dnl  AC_SUBST(HTTP_LIBS)
1036 dnl  AC_SUBST(GST_HTTPSRC_GET_TYPE)
1037 dnl ])
1038
1039 dnl *** ivorbis ***
1040 dnl AM_PATH_IVORBIS only takes two options
1041 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
1042 GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
1043   IVORBIS_LIBS=
1044   IVORBIS_CFLAGS=
1045   AC_CHECK_LIB(vorbisidec, vorbis_block_init,
1046     [IVORBIS_LIBS=-lvorbisidec
1047      HAVE_IVORBIS=yes],
1048     HAVE_IVORBIS=no)
1049   AC_SUBST(IVORBIS_LIBS)
1050   AC_SUBST(IVORBIS_CFLAGS)
1051 ])
1052
1053 dnl *** Jack ***
1054 translit(dnm, m, l) AM_CONDITIONAL(USE_JACK, true)
1055 GST_CHECK_FEATURE(JACK, Jack, jack, [
1056   PKG_CHECK_MODULES(JACK, jack >= 0.29.0, HAVE_JACK="yes", HAVE_JACK="no")
1057   AC_SUBST(JACK_CFLAGS)
1058   AC_SUBST(JACK_LIBS)
1059 ])
1060
1061 dnl *** jpeg ***
1062 dnl FIXME: we could use header checks here as well IMO
1063 translit(dnm, m, l) AM_CONDITIONAL(USE_JPEG, true)
1064 GST_CHECK_FEATURE(JPEG, [jpeg], jpegenc jpegdec, [
1065   AC_ARG_WITH(jpeg-mmx,
1066     [  --with-jpeg-mmx, path to MMX'ified JPEG library])
1067   OLD_LIBS="$LIBS"
1068   if test x$with_jpeg_mmx != x; then
1069     LIBS="$LIBS -L$with_jpeg_mmx"
1070   fi
1071   AC_CHECK_LIB(jpeg-mmx, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
1072   JPEG_LIBS="$LIBS -ljpeg-mmx"
1073   LIBS="$OLD_LIBS"
1074   if test x$HAVE_JPEG != xyes; then
1075     AC_CHECK_LIB(jpeg, jpeg_set_defaults, HAVE_JPEG="yes", HAVE_JPEG="no")
1076     JPEG_LIBS="-ljpeg"
1077   fi
1078   AC_SUBST(JPEG_LIBS)
1079 ])
1080
1081 dnl *** KDE / Qt ***
1082
1083 dnl * Qt *
1084
1085 qt_dirs="$QTDIR /usr/lib/qt3 /usr/lib/qt /usr/share/qt3 /usr/local/qt"
1086
1087 dnl Build include path search path from the list of Qt dirs
1088
1089 qt_include_dirs=""
1090 for dir in $qt_dirs; do
1091   qt_include_dirs="$qt_include_dirs $dir/include $dir"
1092 done
1093
1094 qt_include_dirs="$qt_include_dirs /usr/include/qt /usr/include /usr/X11R6/include/X11/qt /usr/X11R6/include/qt /usr/include/qt3"
1095
1096 for dir in $qt_include_dirs; do
1097   if test -r "$dir/qglobal.h"; then
1098     qt_include_dir=$dir
1099     break
1100   fi
1101 done
1102
1103 for dir in $qt_dirs; do
1104   qt_lib_dirs="$qt_lib_dirs $dir/lib $dir"
1105 done
1106
1107 qt_lib_dirs="$qt_lib_dirs /usr/X11R6/lib /usr/lib"
1108
1109 for dir in $qt_lib_dirs; do
1110   try="ls -1 $dir/libqt-mt.*"
1111   if test -n "`$try 2> /dev/null`"; then
1112     qt_lib_dir=$dir
1113     break
1114   fi
1115 done
1116
1117 dnl * KDE *
1118
1119 translit(dnm, m, l) AM_CONDITIONAL(USE_KIO, true)
1120 GST_CHECK_FEATURE(KIO, [kio], kio, [
1121   AC_PATH_PROG(KDE_MOC, moc, no)
1122   if test x$KDE_MOC = xno; then
1123     HAVE_KIO="no"
1124   else
1125     AC_PATH_PROG(KDE_CONFIG, kde-config, no)
1126
1127     if test x$KDE_CONFIG != xno; then
1128       KDE_PREFIX=`$KDE_CONFIG --prefix`
1129     fi
1130
1131     kde_include_dirs="/usr/lib/kde/include /usr/local/kde/include /usr/local/include /usr/kde/include /usr/include/kde /usr/include /opt/kde3/include /opt/kde/include"
1132     kde_lib_dirs="/usr/lib/kde/lib /usr/local/kde/lib /usr/kde/lib /usr/lib/kde /usr/lib/kde3 /usr/lib /usr/X11R6/lib /usr/local/lib /opt/kde3/lib /opt/kde/lib /usr/X11R6/kde/lib"
1133
1134     if test -n "$KDE_PREFIX"; then
1135       kde_include_dirs="$KDE_PREFIX/include $KDE_PREFIX/include/kde $KDE_PREFIX $kde_include_dirs"
1136       kde_lib_dirs="$KDE_PREFIX/lib $KDE_PREFIX $kde_lib_dirs"
1137     fi
1138     if test -n "$KDEDIR"; then
1139       kde_include_dirs="$KDEDIR/include $KDEDIR/include/kde $KDEDIR $kde_include_dirs"
1140       kde_lib_dirs="$KDEDIR/lib $KDEDIR $kde_lib_dirs"
1141     fi
1142
1143     for dir in $kde_include_dirs; do
1144       if test -r "$dir/kglobal.h" && test -r "$dir/kdemacros.h"; then
1145         kde_include_dir=$dir
1146         break
1147       fi
1148     done
1149
1150     for dir in $kde_lib_dirs; do
1151       try="ls -1 $dir/libkio.*"
1152       if test -n "`$try 2> /dev/null`"; then
1153         kde_lib_dir=$dir
1154         break
1155       fi
1156     done
1157
1158     if test -n $kde_include_dir && test -n $kde_lib_dir; then
1159       KIO_CFLAGS="-I$kde_include_dir -I$qt_include_dir"
1160       KIO_LIBS="-L$KDE_PREFIX/lib -L$qt_lib_dir -lkio -lqt-mt"
1161       AC_LANG_PUSH(C++)
1162       save_LIBS="$LIBS"
1163       save_CPPFLAGS="$CPPFLAGS"
1164       LIBS="$LIBS $KIO_LIBS"
1165       CPPFLAGS="$CPPFLAGS $KIO_CFLAGS"
1166       AC_TRY_LINK([
1167 #include <kio/job.h>
1168                    ], [
1169   KIO::get ("bla")
1170                    ], HAVE_KIO="yes", HAVE_KIO="no")
1171       LIBS="$save_LIBS"
1172       CPPFLAGS="$save_CPPFLAGS"
1173       AC_LANG_POP(C++)
1174       AC_SUBST(KIO_CFLAGS)
1175       AC_SUBST(KIO_LIBS)
1176     else
1177       HAVE_KIO="no"
1178     fi
1179   fi
1180 ])
1181
1182 dnl *** ladspa ***
1183 translit(dnm, m, l) AM_CONDITIONAL(USE_LADSPA, true)
1184 GST_CHECK_FEATURE(LADSPA, [ladspa], ladspa, [
1185   AC_CHECK_HEADER(ladspa.h, HAVE_LADSPA="yes", HAVE_LADSPA="no")
1186 ])
1187
1188 dnl *** lame ***
1189 translit(dnm, m, l) AM_CONDITIONAL(USE_LAME, true)
1190 GST_CHECK_FEATURE(LAME, [lame mp3 encoder library], lame, [
1191   GST_CHECK_LIBHEADER(LAME, mp3lame, lame_init, -lm, lame/lame.h, HAVE_LAME="yes" LAME_LIBS="-lmp3lame")
1192 ])
1193 AC_SUBST(LAME_LIBS)
1194
1195 dnl *** libcaca ***
1196 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBCACA, true)
1197 GST_CHECK_FEATURE(LIBCACA, [libcaca], libcaca, [
1198   GST_CHECK_CONFIGPROG(LIBCACA, caca-config)
1199   AC_SUBST(LIBCACA_CFLAGS)
1200   AC_SUBST(LIBCACA_LIBS)
1201 ])
1202
1203 dnl *** libcolorspace ***
1204 translit(dnm, m, l) AM_CONDITIONAL(USE_LCS, true)
1205 GST_CHECK_FEATURE(LCS, Lcs, lcs, [
1206   PKG_CHECK_MODULES(LCS, lcs, HAVE_LCS="yes", HAVE_LCS="no")
1207   AC_SUBST(LCS_CFLAGS)
1208   AC_SUBST(LCS_LIBS)
1209 ])
1210
1211 dnl *** libdv ***
1212 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBDV, true)
1213 GST_CHECK_FEATURE(LIBDV, [libdv DV/video decoder], dvdec, [
1214   PKG_CHECK_MODULES(LIBDV, libdv >= 0.100, HAVE_LIBDV="yes", HAVE_LIBDV="no")
1215   AC_SUBST(LIBDV_CFLAGS)
1216   AC_SUBST(LIBDV_LIBS)
1217 ])
1218
1219 dnl *** libfame ***
1220 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBFAME, true)
1221 GST_CHECK_FEATURE(LIBFAME, [libfame MPEG1/4 encoder], libfame, [
1222   AM_PATH_LIBFAME(0.9.0, HAVE_LIBFAME="yes", HAVE_LIBFAME="no")
1223   AC_SUBST(LIBFAME_CFLAGS)
1224   AC_SUBST(LIBFAME_LIBS)
1225 ])
1226
1227 dnl *** libpng ***
1228 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
1229 GST_CHECK_FEATURE(LIBPNG, [libpng PNG encoder], pngenc, [
1230   PKG_CHECK_MODULES(LIBPNG, libpng12, HAVE_LIBPNG="yes", HAVE_LIBPNG="no")
1231   AC_SUBST(LIBPNG_CFLAGS)
1232   AC_SUBST(LIBPNG_LIBS)
1233 ])
1234
1235 dnl *** librfb ***
1236 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBRFB, true)
1237 GST_CHECK_FEATURE(LIBRFB, [librfb Remote Framebuffer], rfbsrc, [
1238   PKG_CHECK_MODULES(LIBRFB, librfb-0.1, HAVE_LIBRFB="yes", HAVE_LIBRFB="no")
1239   AC_SUBST(LIBRFB_CFLAGS)
1240   AC_SUBST(LIBRFB_LIBS)
1241 ])
1242
1243 dnl *** libvisual ***
1244 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
1245 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization plugins], libvisual, [
1246   PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.1.1, HAVE_LIBVISUAL="yes", HAVE_LIBVISUAL="no")
1247   AC_SUBST(LIBVISUAL_CFLAGS)
1248   AC_SUBST(LIBVISUAL_LIBS)
1249 ])
1250
1251 dnl *** mad ***
1252 dnl FIXME: we could use header checks here as well IMO
1253 translit(dnm, m, l) AM_CONDITIONAL(USE_MAD, true)
1254 GST_CHECK_FEATURE(MAD, [mad mp3 decoder], mad, [
1255   dnl check with pkg-config first
1256   PKG_CHECK_MODULES(MAD, mad >= 0.15 id3tag >= 0.15, HAVE_MAD="yes", HAVE_MAD="no")
1257   if test "x$HAVE_MAD" = "xno"; then
1258     dnl fall back to oldskool detection
1259     AC_CHECK_LIB(mad, mad_decoder_finish, HAVE_MAD="yes" MAD_LIBS="-lmad")
1260     if test "x$HAVE_MAD" = "xyes"; then
1261       HAVE_MAD="no"
1262       save_LIBS=$LIBS
1263       LIBS="-lz"
1264       AC_CHECK_LIB(id3tag, id3_tag_options, HAVE_MAD="yes" MAD_LIBS="-lmad -lid3tag -lz")
1265       LIBS=$save_LIBS
1266     fi
1267   fi
1268 ])
1269 AC_SUBST(MAD_LIBS)
1270
1271 dnl *** mikmod ***
1272 translit(dnm, m, l) AM_CONDITIONAL(USE_MIKMOD, true)
1273 GST_CHECK_FEATURE(MIKMOD, [mikmod plug-in], mikmod, [
1274   AM_PATH_LIBMIKMOD(, HAVE_MIKMOD=yes, HAVE_MIKMOD=no)
1275   AC_SUBST(MIKMOD_LIBS, "$LIBMIKMOD_LIBS")
1276   AC_SUBST(MIKMOD_CFLAGS, "$LIBMIKMODCFLAGS")
1277 ])
1278
1279 dnl *** mpeg2dec ***
1280 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2DEC, true)
1281 GST_CHECK_FEATURE(MPEG2DEC, [mpeg2dec], mpeg2dec, [
1282   PKG_CHECK_MODULES(MPEG2DEC, libmpeg2 >= 0.4.0,
1283       HAVE_MPEG2DEC="yes", HAVE_MPEG2DEC="no")
1284   AC_SUBST(MPEG2DEC_CFLAGS)
1285   AC_SUBST(MPEG2DEC_LIBS)
1286 ])
1287
1288 dnl *** mpeg2enc ***
1289 translit(dnm, m, l) AM_CONDITIONAL(USE_MPEG2ENC, true)
1290 GST_CHECK_FEATURE(MPEG2ENC, [mpeg2enc], mpeg2enc, [
1291   HAVE_MPEG2ENC="no"
1292   dnl we require a c++ compiler for this one
1293   if [ test x$HAVE_CXX = xyes ]; then
1294     dnl libmpeg2enc was first included in mjpegtools-1.6.2-rc3 (1.6.1.92)
1295     dnl since many distros include mjpegtools specifically without mplex
1296     dnl and mpeg2enc, we check for mpeg2enc on its own, too.
1297     PKG_CHECK_MODULES(MPEG2ENC, mjpegtools >= 1.6.1.93, [
1298       dnl switch over to c++ to test things
1299       AC_LANG_CPLUSPLUS
1300       OLD_CPPFLAGS="$CPPFLAGS"
1301       CPPFLAGS="$CPPFLAGS $MPEG2ENC_CFLAGS"
1302       AC_CHECK_HEADER(mpeg2encoder.hh, [
1303         MPEG2ENC_LIBS="$MPEG2ENC_LIBS -lmpeg2encpp -lm -lpthread"
1304         OLD_LIBS="$LIBS"
1305         LIBS="$LIBS $MPEG2ENC_LIBS"
1306         AC_MSG_CHECKING([for valid mpeg2enc objects])
1307         AC_TRY_RUN([
1308 #include <mpeg2encoder.hh>
1309 #include <mpeg2encoptions.hh>
1310
1311 int
1312 main (int   argc,
1313       char *argv[])
1314 {
1315   MPEG2EncOptions *options = new MPEG2EncOptions ();
1316   MPEG2Encoder encoder (*options);
1317   return 0;
1318 }
1319         ],[
1320           HAVE_MPEG2ENC="yes"
1321           AC_SUBST(MPEG2ENC_CFLAGS)
1322           AC_SUBST(MPEG2ENC_LIBS)
1323           AC_MSG_RESULT(yes)
1324         ], AC_MSG_RESULT(no))
1325         LIBS="$OLD_LIBS"
1326       ])
1327       CPPFLAGS="$OLD_CPPFLAGS"
1328       AC_LANG_C
1329     ],
1330     HAVE_MPEG2ENC="no")
1331   fi
1332 ])
1333
1334 dnl *** mplex ***
1335 translit(dnm, m, l) AM_CONDITIONAL(USE_MPLEX, true)
1336 GST_CHECK_FEATURE(MPLEX, [mplex], mplex, [
1337   HAVE_MPLEX="no"
1338   dnl we require a c++ compiler for this one
1339   if [ test x$HAVE_CXX = xyes ]; then
1340     dnl libmplex was first included in mjpegtools-1.6.2-rc4 (1.6.1.93)
1341     dnl since many distros include mjpegtools specifically without mplex
1342     dnl and mpeg2enc, we check for mplex on its own, too.
1343     PKG_CHECK_MODULES(MPLEX, mjpegtools >= 1.6.1.93, [
1344       dnl switch over to c++ to test things
1345       AC_LANG_CPLUSPLUS
1346       OLD_CPPFLAGS="$CPPFLAGS"
1347       CPPFLAGS="$CPPFLAGS $MPLEX_CFLAGS"
1348       AC_CHECK_HEADER(interact.hpp, [
1349         MPLEX_LIBS="$MPLEX_LIBS -lmplex2 -lm"
1350         OLD_LIBS="$LIBS"
1351         LIBS="$LIBS $MPLEX_LIBS"
1352         AC_MSG_CHECKING([for valid mplex objects])
1353         AC_TRY_RUN([
1354 #include <interact.hpp>
1355 #include <outputstrm.hpp>
1356 #include <multiplexor.hpp>
1357
1358 int
1359 main (int   argc,
1360       char *argv[])
1361 {
1362   class TestOutputStream : public OutputStream {
1363   public:
1364     TestOutputStream () : OutputStream () { }
1365     void Write (uint8_t *a, unsigned int b) { }
1366     void NextSegment () { }
1367     off_t SegmentSize () { }
1368     void Close () { }
1369     int Open () { }
1370   };
1371   MultiplexJob *job = new MultiplexJob ();
1372   vector<IBitStream *> inputs;
1373   job->SetupInputStreams (inputs);
1374   TestOutputStream *out = new TestOutputStream ();
1375   Multiplexor mux (*job, *out);
1376   return 0;
1377 }
1378         ],[
1379           HAVE_MPLEX="yes"
1380           AC_SUBST(MPLEX_CFLAGS)
1381           AC_SUBST(MPLEX_LIBS)
1382           AC_MSG_RESULT(yes)
1383         ], AC_MSG_RESULT(no))
1384         LIBS="$OLD_LIBS"
1385       ])
1386       CPPFLAGS="$OLD_CPPFLAGS"
1387       AC_LANG_C
1388     ], HAVE_MPLEX="no")
1389   fi
1390 ])
1391
1392 dnl *** musicbrainz ***
1393 dnl libmusicbrainz <= 2.0.2 has symbol clashes with ffmpeg
1394 dnl however, our ffmpeg patch was accepted upstream
1395 translit(dnm, m, l) AM_CONDITIONAL(USE_MUSICBRAINZ, true)
1396 GST_CHECK_FEATURE(MUSICBRAINZ, [musicbrainz], musicbrainz, [
1397   PKG_CHECK_MODULES(MUSICBRAINZ, libmusicbrainz >= 2.0.2,
1398       HAVE_MUSICBRAINZ="yes", HAVE_MUSICBRAINZ="no")
1399   AC_SUBST(MUSICBRAINZ_CFLAGS)
1400   AC_SUBST(MUSICBRAINZ_LIBS)
1401 ])
1402
1403 dnl *** nas ***
1404 translit(dnm, m, l) AM_CONDITIONAL(USE_NAS, true)
1405 GST_CHECK_FEATURE(NAS, [nas plug-in], nassink, [
1406   HAVE_NAS="no"
1407   if test "x$HAVE_X" = "xyes"; then
1408     save_cppflags=$CFLAGS
1409     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1410     GST_CHECK_LIBHEADER(NAS, audio, AuOpenServer, $X_LIBS, audio/audiolib.h,
1411       NAS_LIBS="$X_LIBS -laudio" NAS_CFLAGS="$X_CFLAGS")
1412     CPPFLAGS="$save_cppflags"
1413   fi
1414   AC_SUBST(NAS_CFLAGS)
1415   AC_SUBST(NAS_LIBS)
1416 ])
1417
1418 dnl *** pango ***
1419 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
1420 GST_CHECK_FEATURE(PANGO, [pango], pango, [
1421   PKG_CHECK_MODULES(PANGO, pango pangoft2,
1422       HAVE_PANGO="yes", HAVE_PANGO="no")
1423   AC_SUBST(PANGO_CFLAGS)
1424   AC_SUBST(PANGO_LIBS)
1425 ])
1426
1427 dnl *** raw1394 ***
1428 translit(dnm, m, l) AM_CONDITIONAL(USE_RAW1394, true)
1429 GST_CHECK_FEATURE(RAW1394, [raw1394 library], dv1394src, [
1430   GST_CHECK_LIBHEADER(RAW1394, raw1394, raw1394_new_handle,, libraw1394/raw1394.h, RAW1394_LIBS="-lraw1394")
1431   AC_SUBST(RAW1394_LIBS)
1432 ])
1433
1434 dnl *** SDL ***
1435 translit(dnm, m, l) AM_CONDITIONAL(USE_SDL, true)
1436 GST_CHECK_FEATURE(SDL, [SDL plug-in], sdlvideosink, [
1437   dnl sdlvideosink depends on the xoverlay interface, which depends on X
1438   if test x$HAVE_X = xyes; then
1439     AM_PATH_SDL(, HAVE_SDL=yes, HAVE_SDL=no)
1440   fi
1441 ])
1442
1443 dnl *** shout ***
1444 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT, true)
1445 GST_CHECK_FEATURE(SHOUT, [shout plug-in], icecastsend, [
1446   GST_CHECK_LIBHEADER(SHOUT, shout, shout_init_connection,, shout/shout.h, SHOUT_LIBS="-lshout")
1447   AC_SUBST(SHOUT_LIBS)
1448 ])
1449
1450 dnl *** shout2 ***
1451 translit(dnm, m, l) AM_CONDITIONAL(USE_SHOUT2, true)
1452 GST_CHECK_FEATURE(SHOUT2, [shout2 plug-in], shout2send, [
1453   PKG_CHECK_MODULES(SHOUT2, shout >= 2.0, [
1454     HAVE_SHOUT2="yes"
1455     AC_SUBST(SHOUT2_CFLAGS)
1456     AC_SUBST(SHOUT2_LIBS)
1457   ], [
1458     AM_PATH_SHOUT2(HAVE_SHOUT2="yes", HAVE_SHOUT2="no")
1459     AC_SUBST(SHOUT2_CFLAGS)
1460     AC_SUBST(SHOUT2_LIBS)
1461   ])
1462 ])
1463
1464 dnl *** sidplay ***
1465 translit(dnm, m, l) AM_CONDITIONAL(USE_SIDPLAY, true)
1466 GST_CHECK_FEATURE(SIDPLAY, [sidplay plug-in], sidplay, [
1467   GST_PATH_SIDPLAY()
1468 ])
1469
1470 dnl *** smoothwave ***
1471 translit(dnm, m, l) AM_CONDITIONAL(USE_SMOOTHWAVE, true)
1472 GST_CHECK_FEATURE(SMOOTHWAVE, [smoothwave plug-in], smoothwave, [
1473   if test $HAVE_GTK = "yes"; then HAVE_SMOOTHWAVE=yes; fi;
1474 ])
1475
1476
1477 dnl *** snapshot ***
1478 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBPNG, true)
1479 GST_CHECK_FEATURE(LIBPNG, [snapshot plug-in], snapshot, [
1480   GST_CHECK_LIBHEADER(LIBPNG, png, png_read_info, -lz -lm, png.h, LIBPNG_LIBS="-lpng -lz -lm")
1481   AC_SUBST(LIBPNG_LIBS)
1482 ])
1483
1484 dnl *** speex 1.0.x or >= 1.1.5 (1.1.4 and earlier were not API/ABI compatible ***
1485 dnl speex_jitter.h is 1.1 only
1486 translit(dnm, m, l) AM_CONDITIONAL(USE_SPEEX, true)
1487 GST_CHECK_FEATURE(SPEEX, [speex plug-in], speex, [
1488   GST_CHECK_LIBHEADER(SPEEX, speex, speex_bits_init, , speex.h, [
1489     AC_CHECK_HEADER(speex_jitter.h, [
1490       dnl speex 1.1.x :
1491       GST_CHECK_LIBHEADER(SPEEX, speex, speex_encode_int, , speex.h, [
1492         dnl speex 1.1.5 or + :
1493         HAVE_SPEEX="yes"
1494         SPEEX_LIBS="-lspeex"
1495         AC_SUBST(SPEEX_CFLAGS)
1496         AC_SUBST(SPEEX_LIBS)
1497       ],[
1498         HAVE_SPEEX="no"
1499       ])
1500     ], [
1501       dnl speex 1.0.x :
1502       HAVE_SPEEX="yes"
1503       SPEEX_LIBS="-lspeex"
1504       AC_SUBST(SPEEX_CFLAGS)
1505       AC_SUBST(SPEEX_LIBS)
1506     ])
1507   ])
1508 ])
1509
1510 dnl *** sndfile ***
1511 translit(dnm, m, l) AM_CONDITIONAL(USE_SNDFILE, true)
1512 GST_CHECK_FEATURE(SNDFILE, [sndfile plug-in], sfsrc sfsink, [
1513   PKG_CHECK_MODULES(SNDFILE, sndfile >= 1.0.0, HAVE_SNDFILE="yes", HAVE_SNDFILE="no")
1514   AC_SUBST(SNDFILE_CFLAGS)
1515   AC_SUBST(SNDFILE_LIBS)
1516 ])
1517
1518 dnl *** swfdec ***
1519 translit(dnm, m, l) AM_CONDITIONAL(USE_SWFDEC, true)
1520 GST_CHECK_FEATURE(SWFDEC, [swfdec plug-in], swfdec, [
1521   PKG_CHECK_MODULES(SWFDEC, swfdec >= 0.1.3.1, HAVE_SWFDEC=yes, HAVE_SWFDEC=no)
1522   AC_SUBST(SWFDEC_CFLAGS)
1523   AC_SUBST(SWFDEC_LIBS)
1524 ])
1525
1526 dnl *** tarkin ***
1527 dnl for now the sources are included in the plug-in
1528 dnl and should be moved to ext-libs/ perhaps
1529 translit(dnm, m, l) AM_CONDITIONAL(USE_TARKIN, true)
1530 GST_CHECK_FEATURE(TARKIN, [tarkinenc tarkindec], tarkin, [
1531   HAVE_TARKIN="yes"
1532 ])
1533
1534 dnl *** ogg ***
1535 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
1536 GST_CHECK_FEATURE(OGG, [ogg de/encoder], oggdemux oggmux, [
1537   PKG_CHECK_MODULES(OGG, ogg >= 1.0, [
1538     HAVE_OGG="yes"
1539     AC_SUBST(OGG_CFLAGS)
1540     AC_SUBST(OGG_LIBS)
1541   ], [
1542     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
1543     AS_SCRUB_INCLUDE(OGG_CFLAGS)
1544   ])
1545 ])
1546
1547 dnl *** theora ***
1548 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
1549 GST_CHECK_FEATURE(THEORA, [ogg theora codec], theoradec theoraenc, [
1550   PKG_CHECK_MODULES(THEORA, theora, [
1551     HAVE_THEORA="yes"
1552     AC_SUBST(THEORA_LIBS)
1553     AC_SUBST(THEORA_CFLAGS)
1554   ], [
1555     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
1556     AC_SUBST(THEORA_LIBS)
1557   ])
1558 ])
1559
1560 dnl *** vorbis ***
1561 dnl AM_PATH_VORBIS only takes two options
1562 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
1563 GST_CHECK_FEATURE(VORBIS, [vorbis plug-in], vorbisenc vorbisdec, [
1564   PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0, [
1565     HAVE_VORBIS="yes"
1566   ], [
1567     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
1568     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
1569   ])
1570 ])
1571 if test "x$HAVE_VORBIS" = "xyes"; then
1572   ac_cflags_save="$CFLAGS"
1573   dnl FIXME: does this work on non-gcc? -- Company
1574   CFLAGS="-Wall -Werror"
1575   AC_COMPILE_IFELSE(
1576     AC_LANG_PROGRAM([
1577 #include <vorbis/codec.h>
1578                      ],[
1579 vorbis_dsp_state *v;
1580
1581 vorbis_synthesis_restart (v);
1582                      ]), HAVE_VSR=yes, HAVE_VSR=no)
1583   if test "x$HAVE_VSR" = "xyes"; then
1584     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
1585                        [defined if vorbis_synthesis_restart is present])
1586   fi
1587   CFLAGS="$ac_cflags_save"
1588 fi
1589
1590 dnl *** xine ***
1591 translit(dnm, m, l) AM_CONDITIONAL(USE_XINE, true)
1592 GST_CHECK_FEATURE(XINE, [xine wrapper], xine, [
1593   PKG_CHECK_MODULES(XINE, libxine >= 1.0.0, HAVE_XINE=yes, HAVE_XINE=no)
1594   AC_SUBST(XINE_CFLAGS)
1595   AC_SUBST(XINE_LIBS)
1596 ],disabled)
1597
1598 dnl *** XVID ***
1599 translit(dnm, m, l) AM_CONDITIONAL(USE_XVID, true)
1600 GST_CHECK_FEATURE(XVID, [xvid plugins], xvid, [
1601   HAVE_XVID=no
1602   AC_CHECK_HEADER(xvid.h, [
1603     OLD_LIBS="$LIBS"
1604     LIBS="-lm"
1605     AC_CHECK_LIB(xvidcore, xvid_encore, [
1606       AC_CHECK_LIB(xvidcore, xvid_decore, [
1607         AC_CHECK_LIB(xvidcore, xvid_global, [
1608           AC_MSG_CHECKING([for uptodate XviD API version])
1609           AC_TRY_RUN([
1610 #include <xvid.h>
1611 #if XVID_API != XVID_MAKE_API(4,0)
1612 #error "Incompatible XviD API version"
1613 #endif
1614 int main () { return 0; }
1615           ],[ AC_MSG_RESULT(yes)
1616             XVID_LIBS="-lxvidcore -lm"
1617             AC_SUBST(XVID_LIBS)
1618             HAVE_XVID=yes
1619           ], AC_MSG_RESULT(no) )
1620         ], )
1621       ], )
1622     ], )
1623     LIBS="$OLD_LIBS"
1624   ], )
1625 ])
1626
1627
1628 fi dnl of EXT plugins
1629
1630 dnl Check for atomic.h
1631 dnl Note: use AC_CHECK_HEADER not AC_CHECK_HEADERS, because the latter
1632 dnl defines the wrong default symbol as well (HAVE_ASM_ATOMIC_H)
1633 AC_CHECK_HEADER(asm/atomic.h, HAVE_ATOMIC_H=yes, HAVE_ATOMIC_H=no)
1634 dnl Do a compile to check that it has atomic_set (eg, linux 2.0 didn't)
1635 if test x$HAVE_ATOMIC_H = xyes; then
1636   AC_TRY_RUN([
1637 #include "asm/atomic.h"
1638 main() { atomic_t t; atomic_set(&t,0); atomic_inc(&t); atomic_add(1,&t);return 0;}
1639   ],, [
1640     # Not successful
1641     if test x$HAVE_ATOMIC_H = xyes; then
1642       AC_MSG_WARN(Atomic reference counting is out of date: doing without.)
1643     fi
1644     HAVE_ATOMIC_H=no
1645   ], [
1646     # Cross compiling
1647     AC_MSG_RESULT(yes)
1648     AC_MSG_WARN(Can't check properly for atomic reference counting.  Assuming OK.)
1649   ])
1650 fi
1651
1652
1653 dnl ######################################################################
1654 dnl # Check command line parameters, and set shell variables accordingly #
1655 dnl ######################################################################
1656
1657 AC_ARG_ENABLE(libmmx,
1658   AC_HELP_STRING([--enable-libmmx],[use libmmx, if available]),
1659 [case "${enableval}" in
1660   yes) USE_LIBMMX=$HAVE_LIBMMX ;;
1661   no)  USE_LIBMMX=no ;;
1662   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libmmx) ;;
1663 esac],
1664 [USE_LIBMMX=$HAVE_LIBMMX]) dnl Default value
1665
1666 AC_ARG_ENABLE(atomic,
1667   AC_HELP_STRING([--enable-atomic],[use atomic reference counting header]),
1668 [case "${enableval}" in
1669   yes) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
1670   noset) USE_ATOMIC_H=$HAVE_ATOMIC_H;;
1671   no)  USE_ATOMIC_H=no;;
1672   *) AC_MSG_ERROR(bad value ${enableval} for --enable-atomic) ;;
1673 esac],
1674 [USE_ATOMIC_H=$HAVE_ATOMIC_H]) dnl Default value
1675
1676 AC_ARG_ENABLE(profiling,
1677   AC_HELP_STRING([--enable-profiling],
1678                  [-pg to compiler commandline, for profiling]),
1679 [case "${enableval}" in
1680   yes) USE_PROFILING=yes ;;
1681   no)  UES_PROFILING=no ;;
1682   *) AC_MSG_ERROR(bad value ${enableval} for --enable-profiling) ;;
1683 esac],
1684 [USE_PROFILING=no]) dnl Default value
1685
1686 AC_ARG_ENABLE(tests,
1687   AC_HELP_STRING([--disable-tests],[disable building test apps]),
1688 [case "${enableval}" in
1689   yes) BUILD_TESTS=yes ;;
1690   no)  BUILD_TESTS=no ;;
1691   *) AC_MSG_ERROR(bad value ${enableval} for --disable-tests) ;;
1692 esac],
1693 [BUILD_TESTS=yes]) dnl Default value
1694
1695 AC_ARG_ENABLE(examples,
1696   AC_HELP_STRING([--disable-examples],[disable building examples]),
1697 [case "${enableval}" in
1698   yes) BUILD_EXAMPLES=yes ;;
1699   no)  BUILD_EXAMPLES=no ;;
1700   *) AC_MSG_ERROR(bad value ${enableval} for --disable-examples) ;;
1701 esac],
1702 [BUILD_EXAMPLES=yes]) dnl Default value
1703
1704 dnl seeking needs freetype, so check for it here
1705 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
1706   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
1707 ])
1708 dnl make the HAVE_FT2 variable available to automake and Makefile.am
1709 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
1710 AC_SUBST(FT2_CFLAGS)
1711 AC_SUBST(FT2_LIBS)
1712
1713 dnl ################################################
1714 dnl # Set defines according to variables set above #
1715 dnl ################################################
1716
1717
1718 if test "x$USE_LIBMMX" = xyes; then
1719   AC_DEFINE(HAVE_LIBMMX, 1, [Define if libmmx is available])
1720 fi
1721
1722 if test "x$USE_ATOMIC_H" = xyes; then
1723   AC_DEFINE(HAVE_ATOMIC_H, 1, [Define if atomic.h header file is available])
1724 fi
1725
1726 # do not use deprecated stuff
1727 GST_CFLAGS="$GST_CFLAGS -DGST_DISABLE_DEPRECATED"
1728
1729 if test "x$USE_DEBUG" = xyes; then
1730   GST_CFLAGS="$GST_CFLAGS -g"
1731 fi
1732
1733 dnl #############################
1734 dnl # Set automake conditionals #
1735 dnl #############################
1736
1737 dnl These should be "USE_*" instead of "HAVE_*", but some packages expect
1738 dnl HAVE_ and it is likely to be easier to stick with the old name
1739 AM_CONDITIONAL(HAVE_LIBMMX,         test "x$USE_LIBMMX" = "xyes")
1740
1741 AM_CONDITIONAL(HAVE_ATOMIC_H,       test "x$USE_ATOMIC_H" = "xyes")
1742
1743 AM_CONDITIONAL(EXPERIMENTAL,        test "$EXPERIMENTAL" = "$xyes")
1744 AM_CONDITIONAL(BROKEN,              test "$BROKEN" = "$xyes")
1745
1746 AM_CONDITIONAL(HAVE_NASM,           test "x$HAVE_NASM" = "xyes")
1747 AM_CONDITIONAL(HAVE_GTK,            test "x$HAVE_GTK" = "xyes")
1748 AM_CONDITIONAL(HAVE_GTK_DOC,        $HAVE_GTK_DOC)
1749 AM_CONDITIONAL(BUILD_DOCS,          test "x$BUILD_DOCS" = "xyes")
1750 AM_CONDITIONAL(BUILD_TESTS,         test "x$BUILD_TESTS" = "xyes")
1751 AM_CONDITIONAL(BUILD_EXAMPLES,      test "x$BUILD_EXAMPLES" = "xyes")
1752 AM_CONDITIONAL(BUILD_PLUGIN_DOCS,   test "x$BUILD_PLUGIN_DOCS" = "xyes")
1753 AM_CONDITIONAL(HAVE_FIG2DEV_PNG,    $HAVE_FIG2DEV_PNG)
1754 AM_CONDITIONAL(HAVE_FIG2DEV_PDF,    $HAVE_FIG2DEV_PDF)
1755 AM_CONDITIONAL(HAVE_RAW1394,        test "x$HAVE_RAW1394" = "xyes")
1756
1757 dnl prefer internal headers to already installed ones
1758 dnl also add builddir include for enumtypes and marshal
1759 GST_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs $GST_CFLAGS $GST_ERROR"
1760
1761 AC_SUBST(GST_LIBS)
1762 AC_SUBST(GST_CFLAGS)
1763
1764 dnl ###########################
1765 dnl # Configure external libs #
1766 dnl ###########################
1767
1768 dnl ############################
1769 dnl # Set up some more defines #
1770 dnl ############################
1771
1772 dnl set license and copyright notice
1773 AC_DEFINE(GST_LICENSE, "LGPL", [GStreamer license])
1774 dnl package name in plugins
1775 AC_ARG_WITH(package-name,
1776 AC_HELP_STRING([--with-package-name],[specify package name to use in plugins]),
1777 [case "${withval}" in
1778   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
1779   no) AC_MSG_ERROR(bad value ${withval} for --with-package-name) ;;
1780   *) GST_PACKAGE="${withval}" ;;
1781 esac],
1782 [GST_PACKAGE="GStreamer Plugins"]) dnl Default value
1783 AC_MSG_NOTICE(Using $GST_PACKAGE as package name)
1784 AC_DEFINE_UNQUOTED(GST_PACKAGE, "$GST_PACKAGE", [package name in plugins])
1785 dnl package origin URL
1786 AC_ARG_WITH(package-origin,
1787 AC_HELP_STRING([--with-package-origin],[specify package origin URL to use in plugins]),
1788 [case "${withval}" in
1789   yes) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
1790   no) AC_MSG_ERROR(bad value ${withval} for --with-package-origin) ;;
1791   *) GST_ORIGIN="${withval}" ;;
1792 esac],
1793 [GST_ORIGIN="http://gstreamer.net/"]) dnl Default value
1794 AC_MSG_NOTICE(Using $GST_ORIGIN as package origin)
1795 AC_DEFINE_UNQUOTED(GST_ORIGIN, "$GST_ORIGIN", [package origin])
1796
1797 dnl #########################
1798 dnl # Make the output files #
1799 dnl #########################
1800
1801 AC_CONFIG_FILES(
1802 Makefile
1803 gst-plugins.spec
1804 gst/Makefile
1805 gst/ac3parse/Makefile
1806 gst/adder/Makefile
1807 gst/alpha/Makefile
1808 gst/audioconvert/Makefile
1809 gst/audioscale/Makefile
1810 gst/audiorate/Makefile
1811 gst/auparse/Makefile
1812 gst/avi/Makefile
1813 gst/asfdemux/Makefile
1814 gst/cdxaparse/Makefile
1815 gst/chart/Makefile
1816 gst/colorspace/Makefile
1817 gst/cutter/Makefile
1818 gst/debug/Makefile
1819 gst/deinterlace/Makefile
1820 gst/effectv/Makefile
1821 gst/festival/Makefile
1822 gst/ffmpegcolorspace/Makefile
1823 gst/filter/Makefile
1824 gst/flx/Makefile
1825 gst/goom/Makefile
1826 gst/interleave/Makefile
1827 gst/law/Makefile
1828 gst/level/Makefile
1829 gst/matroska/Makefile
1830 gst/median/Makefile
1831 gst/mixmatrix/Makefile
1832 gst/mpeg1sys/Makefile
1833 gst/mpeg1videoparse/Makefile
1834 gst/mpeg2sub/Makefile
1835 gst/mpegaudio/Makefile
1836 gst/mpegaudioparse/Makefile
1837 gst/mpegstream/Makefile
1838 gst/modplug/Makefile
1839 gst/modplug/libmodplug/Makefile
1840 gst/monoscope/Makefile
1841 gst/multifilesink/Makefile
1842 gst/multipart/Makefile
1843 gst/overlay/Makefile
1844 gst/passthrough/Makefile
1845 gst/playback/Makefile
1846 gst/playondemand/Makefile
1847 gst/qtdemux/Makefile
1848 gst/realmedia/Makefile
1849 gst/rtjpeg/Makefile
1850 gst/rtp/Makefile
1851 gst/silence/Makefile
1852 gst/sine/Makefile
1853 gst/smooth/Makefile
1854 gst/smpte/Makefile
1855 gst/spectrum/Makefile
1856 gst/speed/Makefile
1857 gst/stereo/Makefile
1858 gst/switch/Makefile
1859 gst/synaesthesia/Makefile
1860 gst/tags/Makefile
1861 gst/tcp/Makefile
1862 gst/typefind/Makefile
1863 gst/udp/Makefile
1864 gst/vbidec/Makefile
1865 gst/videobox/Makefile
1866 gst/videocrop/Makefile
1867 gst/videodrop/Makefile
1868 gst/videofilter/Makefile
1869 gst/videoflip/Makefile
1870 gst/videomixer/Makefile
1871 gst/videorate/Makefile
1872 gst/videoscale/Makefile
1873 gst/videotestsrc/Makefile
1874 gst/volenv/Makefile
1875 gst/volume/Makefile
1876 gst/wavenc/Makefile
1877 gst/wavparse/Makefile
1878 gst/y4m/Makefile
1879 sys/Makefile
1880 sys/cdrom/Makefile
1881 sys/dxr3/Makefile
1882 sys/glsink/Makefile
1883 sys/oss/Makefile
1884 sys/osxaudio/Makefile
1885 sys/osxvideo/Makefile
1886 sys/qcam/Makefile
1887 sys/sunaudio/Makefile
1888 sys/v4l/Makefile
1889 sys/v4l2/Makefile
1890 sys/vcd/Makefile
1891 sys/ximage/Makefile
1892 sys/xvimage/Makefile
1893 ext/Makefile
1894 ext/a52dec/Makefile
1895 ext/aalib/Makefile
1896 ext/alsa/Makefile
1897 ext/arts/Makefile
1898 ext/artsd/Makefile
1899 ext/audiofile/Makefile
1900 ext/cdparanoia/Makefile
1901 ext/dirac/Makefile
1902 ext/divx/Makefile
1903 ext/dts/Makefile
1904 ext/dv/Makefile
1905 ext/dvdread/Makefile
1906 ext/dvdnav/Makefile
1907 ext/esd/Makefile
1908 ext/faac/Makefile
1909 ext/faad/Makefile
1910 ext/flac/Makefile
1911 ext/gdk_pixbuf/Makefile
1912 ext/gnomevfs/Makefile
1913 ext/gsm/Makefile
1914 ext/hermes/Makefile
1915 dnl ext/http/Makefile
1916 ext/jack/Makefile
1917 ext/jpeg/Makefile
1918 ext/kio/Makefile
1919 ext/ladspa/Makefile
1920 ext/lame/Makefile
1921 ext/ivorbis/Makefile
1922 ext/lcs/Makefile
1923 ext/libcaca/Makefile
1924 ext/libfame/Makefile
1925 ext/libpng/Makefile
1926 ext/librfb/Makefile
1927 ext/libvisual/Makefile
1928 ext/mad/Makefile
1929 ext/mikmod/Makefile
1930 ext/mpeg2dec/Makefile
1931 ext/mpeg2enc/Makefile
1932 ext/mplex/Makefile
1933 ext/musicbrainz/Makefile
1934 ext/nas/Makefile
1935 ext/ogg/Makefile
1936 ext/pango/Makefile
1937 ext/raw1394/Makefile
1938 ext/sdl/Makefile
1939 ext/shout/Makefile
1940 ext/shout2/Makefile
1941 ext/sidplay/Makefile
1942 ext/smoothwave/Makefile
1943 ext/snapshot/Makefile
1944 ext/speex/Makefile
1945 ext/sndfile/Makefile
1946 ext/swfdec/Makefile
1947 ext/tarkin/Makefile
1948 ext/theora/Makefile
1949 ext/vorbis/Makefile
1950 ext/xine/Makefile
1951 ext/xvid/Makefile
1952 gst-libs/Makefile
1953 gst-libs/gst/Makefile
1954 gst-libs/gst/audio/Makefile
1955 gst-libs/gst/colorbalance/Makefile
1956 gst-libs/gst/floatcast/Makefile
1957 gst-libs/gst/gconf/Makefile
1958 gst-libs/gst/idct/Makefile
1959 gst-libs/gst/media-info/Makefile
1960 gst-libs/gst/mixer/Makefile
1961 gst-libs/gst/navigation/Makefile
1962 gst-libs/gst/play/Makefile
1963 gst-libs/gst/propertyprobe/Makefile
1964 gst-libs/gst/resample/Makefile
1965 gst-libs/gst/riff/Makefile
1966 gst-libs/gst/tag/Makefile
1967 gst-libs/gst/tuner/Makefile
1968 gst-libs/gst/video/Makefile
1969 gst-libs/gst/xoverlay/Makefile
1970 gst-libs/gst/xwindowlistener/Makefile
1971 gst-libs/ext/Makefile
1972 examples/dynparams/Makefile
1973 examples/capsfilter/Makefile
1974 examples/seeking/Makefile
1975 examples/indexing/Makefile
1976 examples/gstplay/Makefile
1977 examples/switch/Makefile
1978 examples/Makefile
1979 testsuite/spider/Makefile
1980 testsuite/alsa/Makefile
1981 testsuite/multifilesink/Makefile
1982 testsuite/Makefile
1983 tools/Makefile
1984 gconf/Makefile
1985 gconf/gstreamer.schemas
1986 pkgconfig/Makefile
1987 pkgconfig/gstreamer-gconf.pc
1988 pkgconfig/gstreamer-gconf-uninstalled.pc
1989 pkgconfig/gstreamer-interfaces.pc
1990 pkgconfig/gstreamer-interfaces-uninstalled.pc
1991 pkgconfig/gstreamer-libs.pc
1992 pkgconfig/gstreamer-libs-uninstalled.pc
1993 pkgconfig/gstreamer-media-info.pc
1994 pkgconfig/gstreamer-media-info-uninstalled.pc
1995 pkgconfig/gstreamer-play.pc
1996 pkgconfig/gstreamer-play-uninstalled.pc
1997 pkgconfig/gstreamer-plugins.pc
1998 pkgconfig/gstreamer-plugins-uninstalled.pc
1999 po/Makefile.in
2000 common/Makefile
2001 common/m4/Makefile
2002 m4/Makefile
2003 )
2004 AC_OUTPUT
2005
2006 echo -n "configure: *** Plug-ins that will be built :"
2007 echo -e "$GST_PLUGINS_YES" | sort
2008 echo
2009 echo -n "configure: *** Plug-ins that will not be built :"
2010 echo -e "$GST_PLUGINS_NO" | sort
2011 echo
2012 if test "x$BUILD_EXTERNAL" = "xno"; then
2013   echo "configure: *** No external plug-ins will be built"
2014 fi