configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [29])
  30 m4_define([glib_micro_version], [19])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AC_CANONICAL_HOST
 112
 113 AC_MSG_CHECKING([for the BeOS])
 114 case $host in
 115   *-*-beos*)
 116     glib_native_beos="yes"
 117     ;;
 118   *)
 119     glib_native_beos="no"
 120     ;;
 121 esac
 122 AC_MSG_RESULT([$glib_native_beos])
 123
 124 dnl
 125
 126 AC_MSG_CHECKING([for Win32])
 127 LIB_EXE_MACHINE_FLAG=X86
 128 case "$host" in
 129   *-*-mingw*)
 130     glib_native_win32=yes
 131     glib_pid_type='void *'
 132     glib_cv_stack_grows=no
 133     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 134     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 135     # (Sorry, I don't know exactly what is the problem, but it is related to
 136     # floating point formatting and decimal point vs. comma.)
 137     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 138     # rigorous enough to notice, though.
 139     # So preset the autoconf cache variables.
 140     ac_cv_func_vsnprintf_c99=no
 141     ac_cv_func_snprintf_c99=no
 142     case "$host" in
 143     x86_64-*-*)
 144       LIB_EXE_MACHINE_FLAG=X64
 145       ;;
 146     esac
 147     ;;
 148   *)
 149     glib_native_win32=no
 150     glib_pid_type=int
 151     ;;
 152 esac
 153 case $host in
 154   *-*-linux*)
 155     glib_os_linux=yes
 156     ;;
 157 esac
 158
 159 AC_MSG_RESULT([$glib_native_win32])
 160
 161 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 162
 163 glib_have_carbon=no
 164 AC_MSG_CHECKING([for Mac OS X Carbon support])
 165 AC_TRY_CPP([
 166 #include <Carbon/Carbon.h>
 167 #include <CoreServices/CoreServices.h>
 168 ], glib_have_carbon=yes)
 169
 170 AC_MSG_RESULT([$glib_have_carbon])
 171
 172 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 173 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 174 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 175 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 176 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 177
 178 if test "$glib_native_win32" = "yes"; then
 179   AC_CHECK_TOOL(WINDRES, windres, no)
 180   if test "$WINDRES" = no; then
 181     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 182   fi
 183   AC_CHECK_TOOL(NM, nm, no)
 184   if test "$NM" = no; then
 185     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 186   fi
 187   AC_CHECK_TOOL(RANLIB, ranlib, :)
 188   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 189 fi
 190 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 191
 192 if test "$glib_native_win32" != yes; then
 193     # libtool option to control which symbols are exported
 194     # right now, symbols starting with _ are not exported
 195     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 196 else
 197     # We currently use .def files on Windows
 198     LIBTOOL_EXPORT_OPTIONS=
 199 fi
 200 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 201
 202 if test "x$glib_have_carbon" = "xyes"; then
 203   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 204   LDFLAGS="$LDFLAGS -framework Carbon"
 205 fi
 206
 207 gl_GLIBC21
 208 if test "x$GLIBC21" = "xyes"; then
 209   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 210 fi
 211
 212 dnl declare --enable-* args and collect ac_help strings
 213 AC_ARG_ENABLE(debug,
 214               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 215                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 216               enable_debug=glib_debug_default)
 217
 218 AC_ARG_ENABLE(gc_friendly,
 219               [AC_HELP_STRING([--enable-gc-friendly],
 220                               [turn on garbage collector friendliness [default=no]])],,
 221               [enable_gc_friendly=no])
 222 AC_ARG_ENABLE(mem_pools,
 223               [AC_HELP_STRING([--disable-mem-pools],
 224                               [disable all glib memory pools])],,
 225               [disable_mem_pools=no])
 226 AC_ARG_ENABLE(threads,
 227               [AC_HELP_STRING([--enable-threads],
 228                               [turn on basic thread support [default=yes]
 229 ([=no] will override --with-threads)])],,
 230               [enable_threads=yes])
 231 AC_ARG_ENABLE(rebuilds,
 232               [AC_HELP_STRING([--disable-rebuilds],
 233                               [disable all source autogeneration rules])],,
 234               [enable_rebuilds=yes])
 235
 236 if test "x$enable_threads" != "xyes"; then
 237   enable_threads=no
 238 fi
 239
 240 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 241 if test "x$enable_gc_friendly" = "xyes"; then
 242   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 243   AC_MSG_RESULT([yes])
 244 else
 245   AC_MSG_RESULT([no])
 246 fi
 247
 248 AC_MSG_CHECKING([whether to disable memory pools])
 249 if test "x$disable_mem_pools" = "xno"; then
 250   AC_MSG_RESULT([no])
 251 else
 252   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 253   AC_SUBST(DISABLE_MEM_POOLS)
 254   AC_MSG_RESULT([yes])
 255 fi
 256
 257 dnl location to install runtime libraries, e.g. ../../lib to install
 258 dnl to /lib if libdir is /usr/lib
 259 AC_ARG_WITH(runtime-libdir,
 260            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 261                            [Install runtime libraries relative to libdir])],
 262            [],
 263            [with_runtime_libdir=""])
 264 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 265 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 266 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 267 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 268 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 269
 270 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 271 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 272 AC_LANG_SAVE
 273 AC_LANG_CPLUSPLUS
 274 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 275 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 276 AC_LANG_RESTORE
 277
 278 AM_PROG_CC_STDC
 279 AM_PROG_CC_C_O
 280 AC_PROG_INSTALL
 281
 282 AC_SYS_LARGEFILE
 283
 284 PKG_PROG_PKG_CONFIG(0.16)
 285
 286 if test "x$enable_debug" = "xyes"; then
 287   if test x$cflags_set != xset ; then
 288       case " $CFLAGS " in
 289       *[[\ \    ]]-g[[\ \       ]]*) ;;
 290       *) CFLAGS="$CFLAGS -g" ;;
 291       esac
 292   fi
 293
 294   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 295 else
 296   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 297
 298   if test "x$enable_debug" = "xno"; then
 299     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 300   fi
 301 fi
 302
 303 # Ensure MSVC-compatible struct packing convention is used when
 304 # compiling for Win32 with gcc.
 305 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 306 # gcc2 uses "-fnative-struct".
 307 if test x"$glib_native_win32" = xyes; then
 308   if test x"$GCC" = xyes; then
 309     msnative_struct=''
 310     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 311     if test -z "$ac_cv_prog_CC"; then
 312       our_gcc="$CC"
 313     else
 314       our_gcc="$ac_cv_prog_CC"
 315     fi
 316     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 317       2.)
 318         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 319           msnative_struct='-fnative-struct'
 320         fi
 321         ;;
 322       *)
 323         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 324           msnative_struct='-mms-bitfields'
 325         fi
 326         ;;
 327     esac
 328     if test x"$msnative_struct" = x ; then
 329       AC_MSG_RESULT([no way])
 330       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 331     else
 332       CFLAGS="$CFLAGS $msnative_struct"
 333       AC_MSG_RESULT([${msnative_struct}])
 334     fi
 335   fi
 336 fi
 337 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 338 AC_SUBST(GLIB_EXTRA_CFLAGS)
 339
 340 AC_EXEEXT
 341
 342 # define a MAINT-like variable REBUILD which is set if Perl
 343 # and awk are found, so autogenerated sources can be rebuilt
 344 AC_PROG_AWK
 345 AC_CHECK_PROGS(PERL, [perl5 perl])
 346 # We would like indent, but don't require it.
 347 AC_CHECK_PROG(INDENT, indent, indent)
 348 REBUILD=\#
 349 if test "x$enable_rebuilds" = "xyes" && \
 350      test -n "$PERL" && \
 351      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 352      test -n "$AWK" ; then
 353   REBUILD=
 354 fi
 355 AC_SUBST(REBUILD)
 356
 357 # Need full path to Perl for glib-mkenums
 358 #
 359 if test "x$PERL" != x ; then
 360   AC_PATH_PROG(PERL_PATH, [$PERL])
 361 fi
 362 if test "x$PERL_PATH" = x ; then
 363   PERL_PATH="/usr/bin/env perl"
 364 fi
 365 AC_SUBST(PERL_PATH)
 366
 367 # Need suitable python path for greport
 368 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 369
 370
 371 dnl ***********************
 372 dnl *** Tests for iconv ***
 373 dnl ***********************
 374 dnl
 375 dnl We do this before the gettext checks, to avoid distortion
 376
 377 dnl On Windows we use a native implementation
 378
 379 if test x"$glib_native_win32" = xyes; then
 380   with_libiconv=native
 381 else
 382   AC_ARG_WITH(libiconv,
 383               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 384                               [use the libiconv library])],,
 385               [with_libiconv=maybe])
 386
 387   found_iconv=no
 388   case $with_libiconv in
 389     maybe)
 390       # Check in the C library first
 391       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 392       # Check if we have GNU libiconv
 393       if test $found_iconv = "no"; then
 394         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 395       fi
 396       # Check if we have a iconv in -liconv, possibly from vendor
 397       if test $found_iconv = "no"; then
 398         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 399       fi
 400       ;;
 401     no)
 402       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 403       ;;
 404     gnu|yes)
 405       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 406       ;;
 407     native)
 408       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 409       ;;
 410   esac
 411
 412   if test "x$found_iconv" = "xno" ; then
 413      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 414   fi
 415 fi
 416
 417 AC_ARG_ENABLE(iconv-cache,
 418               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 419                               [cache iconv descriptors [default=auto]])],,
 420               [enable_iconv_cache=auto])
 421
 422 AC_MSG_CHECKING([whether to cache iconv descriptors])
 423 case $enable_iconv_cache in
 424   auto)
 425     if test $ac_cv_gnu_library_2_1 = yes; then
 426       enable_iconv_cache=no
 427     else
 428       enable_iconv_cache=yes
 429     fi
 430   ;;
 431   yes|no)
 432   ;;
 433   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 434   ;;
 435 esac
 436
 437 if test $enable_iconv_cache = yes; then
 438    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 439 fi
 440
 441 AC_MSG_RESULT($enable_iconv_cache)
 442
 443
 444 dnl
 445 dnl zlib support
 446 dnl
 447 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 448 if test "x$found_zlib" = "xno" ; then
 449   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 450   if test "x$found_zlib" = "xno" ; then
 451     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 452   fi
 453   ZLIB_LIBS='-lz'
 454   AC_SUBST(ZLIB_LIBS)
 455 fi
 456
 457 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 458 AC_SUBST(LIBFFI_CFLAGS)
 459 AC_SUBST(LIBFFI_LIBS)
 460
 461 dnl
 462 dnl gettext support
 463 dnl
 464
 465 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 466 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 467 GLIB_GNU_GETTEXT
 468
 469 if test "$gt_cv_have_gettext" != "yes" ; then
 470   AC_MSG_ERROR([
 471 *** You must have either have gettext support in your C library, or use the
 472 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 473 ])
 474 fi
 475
 476 LIBS="$INTLLIBS $LIBS"
 477
 478 GETTEXT_PACKAGE=glib20
 479 AC_SUBST(GETTEXT_PACKAGE)
 480 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 481   [Define the gettext package to be used])
 482
 483 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 484
 485 dnl
 486 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 487 dnl
 488
 489 if test x"$glib_native_win32" != xyes; then
 490   if test x$with_libiconv != xno ; then
 491     case " $INTLLIBS " in
 492     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 493     *) ICONV_LIBS="-liconv" ;;
 494     esac
 495   fi
 496 fi
 497 AC_SUBST(ICONV_LIBS)
 498
 499 case $with_libiconv in
 500   gnu)
 501     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 502     ;;
 503   native)
 504     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 505     ;;
 506 esac
 507
 508 dnl Initialize libtool
 509 LT_PREREQ([2.2])
 510 LT_INIT([disable-static win32-dll])
 511 dnl when using libtool 2.x create libtool early, because it's used in configure
 512 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 513
 514
 515 if test "x$GCC" = "xyes"; then
 516   case " $CFLAGS " in
 517   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 518   *) CFLAGS="$CFLAGS -Wall" ;;
 519   esac
 520 fi
 521
 522 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 523
 524 if test "$glib_native_win32" = "yes"; then
 525   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 526     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 527   fi
 528   if test x$enable_static = xyes; then
 529     glib_win32_static_compilation=yes
 530     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 531 #define GOBJECT_STATIC_COMPILATION 1"
 532     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 533   fi
 534 fi
 535 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 536
 537 dnl
 538 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 539 dnl
 540 if test $cross_compiling != yes ; then
 541     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 542     glib_save_LIBS=$LIBS
 543     LIBS="$LIBS -lm"
 544     AC_TRY_RUN([#include <math.h>
 545                  int main (void) { return (log(1) != log(1.)); }],
 546          AC_MSG_RESULT(none needed),
 547          glib_save_CFLAGS=$CFLAGS
 548          CFLAGS="$CFLAGS -std1"
 549          AC_TRY_RUN([#include <math.h>
 550                      int main (void) { return (log(1) != log(1.)); }],
 551              AC_MSG_RESULT(-std1),
 552              AC_MSG_RESULT()
 553              CFLAGS=$glib_save_CFLAGS
 554              AC_MSG_WARN(
 555                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 556          )
 557     )
 558     LIBS=$glib_save_LIBS
 559 fi
 560
 561 dnl NeXTStep cc seems to need this
 562 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 563 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 564   AC_MSG_RESULT(none needed),
 565   glib_save_CFLAGS=$CFLAGS
 566   CFLAGS="$CFLAGS -posix"
 567   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 568     AC_MSG_RESULT(-posix),
 569     AC_MSG_RESULT()
 570     CFLAGS=$glib_save_CFLAGS
 571     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 572
 573 # Checks for header files.
 574 AC_HEADER_STDC
 575
 576 # Checks for library functions.
 577 AC_FUNC_VPRINTF
 578 AC_FUNC_ALLOCA
 579 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 580 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 581
 582 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 583 dnl be automatically defined, which we don't want to do
 584 dnl until we have checked this function is actually usable
 585 AC_CHECK_FUNC([qsort_r])
 586
 587 # BSD has a qsort_r with wrong argument order
 588 if test x$ac_cv_func_qsort_r = xyes ; then
 589   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 590   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 591   #define _GNU_SOURCE
 592   #include <stdlib.h>
 593
 594   static int
 595   cmp (const void *a, const void *b, void *c)
 596   {
 597     const int *ia = a;
 598     const int *ib = b;
 599
 600     if (*ia < *ib)
 601       return -1;
 602     else if (*ia > *ib)
 603       return 1;
 604     else
 605       return 0;
 606   }
 607
 608   int
 609   main (int argc, char **argv)
 610   {
 611     int arr[3] = { 1, 2, 0 };
 612     int d = 3;
 613
 614     qsort_r (arr, 3, sizeof (int), cmp, &d);
 615
 616     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 617       return 0;
 618     else
 619       return 1;
 620   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 621 fi
 622
 623 if test x$glib_cv_have_qsort_r = xyes ; then
 624   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 625 fi
 626
 627 AC_CHECK_SIZEOF(char)
 628 AC_CHECK_SIZEOF(short)
 629 AC_CHECK_SIZEOF(long)
 630 AC_CHECK_SIZEOF(int)
 631 AC_CHECK_SIZEOF(void *)
 632 AC_CHECK_SIZEOF(long long)
 633 AC_CHECK_SIZEOF(__int64)
 634
 635 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 636   :
 637 else
 638   AC_MSG_ERROR([
 639 *** GLib requires a 64 bit type. You might want to consider
 640 *** using the GNU C compiler.
 641 ])
 642 fi
 643
 644 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 645         # long long is a 64 bit integer.
 646         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 647         AC_CACHE_VAL(glib_cv_long_long_format,[
 648                 for format in ll q I64; do
 649                   AC_TRY_RUN([#include <stdio.h>
 650                         int main()
 651                         {
 652                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 653                           char buffer[1000];
 654                           sprintf (buffer, "%${format}u", a);
 655                           sscanf (buffer, "%${format}u", &b);
 656                           exit (b!=a);
 657                         }
 658                         ],
 659                         [glib_cv_long_long_format=${format}
 660                         break],
 661                         [],[:])
 662                 done])
 663         if test -n "$glib_cv_long_long_format"; then
 664           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 665           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 666           if test x"$glib_cv_long_long_format" = xI64; then
 667             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 668           fi
 669         else
 670           AC_MSG_RESULT(none)
 671         fi
 672 elif test x$ac_cv_sizeof___int64 = x8; then
 673         # __int64 is a 64 bit integer.
 674         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 675         # We know this is MSVCRT.DLL, and what the formats are
 676         glib_cv_long_long_format=I64
 677         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 678         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 679         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 680 fi
 681
 682 dnl long doubles were not used, and a portability problem
 683 dnl AC_C_LONG_DOUBLE
 684 AC_C_CONST
 685
 686 dnl ok, here we try to check whether the systems prototypes for
 687 dnl malloc and friends actually match the prototypes provided
 688 dnl by gmem.h (keep in sync). i currently only know how to check
 689 dnl this reliably with gcc (-Werror), improvements for other
 690 dnl compilers are apprechiated.
 691 SANE_MALLOC_PROTOS=no
 692 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 693 glib_save_CFLAGS=$CFLAGS
 694 if test "x$GCC" = "xyes"; then
 695   CFLAGS="$CFLAGS -Werror"
 696   AC_TRY_COMPILE([#include <stdlib.h>], [
 697     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 698     void* (*my_malloc_p)  (size_t)         = malloc;
 699     void  (*my_free_p)    (void*)          = free;
 700     void* (*my_realloc_p) (void*, size_t)  = realloc;
 701     my_calloc_p = 0;
 702     my_malloc_p = 0;
 703     my_free_p = 0;
 704     my_realloc_p = 0;
 705   ],
 706     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 707       [Define if you have correct malloc prototypes])
 708     SANE_MALLOC_PROTOS=yes)
 709 fi
 710 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 711 CFLAGS=$glib_save_CFLAGS
 712
 713 dnl
 714 dnl check in which direction the stack grows
 715 dnl
 716 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 717         AC_TRY_RUN([
 718         volatile int *a = 0, *b = 0;
 719         void foo (void);
 720         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 721         void foo (void) { volatile int x = 5; b = &x; }
 722         ],
 723         glib_cv_stack_grows=no
 724         ,
 725         glib_cv_stack_grows=yes
 726         ,)
 727 ])
 728
 729 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 730 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 731 dnl actually supported.
 732 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 733         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 734         __inline int foo () { return 0; }
 735         int main () { return foo (); }
 736         ]])],
 737         glib_cv_has__inline=yes
 738         ,
 739         glib_cv_has__inline=no
 740         ,)
 741 ])
 742 case x$glib_cv_has__inline in
 743 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 744 esac
 745 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 746         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 747         __inline__ int foo () { return 0; }
 748         int main () { return foo (); }
 749         ]])],
 750         glib_cv_has__inline__=yes
 751         ,
 752         glib_cv_has__inline__=no
 753         ,)
 754 ])
 755 case x$glib_cv_has__inline__ in
 756 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 757 esac
 758 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 759         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 760         #undef inline
 761         inline int foo () { return 0; }
 762         int main () { return foo (); }
 763         ]])],
 764         glib_cv_hasinline=yes
 765         ,
 766         glib_cv_hasinline=no
 767         ,)
 768 ])
 769 case x$glib_cv_hasinline in
 770 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 771 esac
 772
 773 # if we can use inline functions in headers
 774 AC_MSG_CHECKING(if inline functions in headers work)
 775 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 776 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 777 #  undef inline
 778 #  define inline __inline__
 779 #elif !defined (G_HAVE_INLINE)
 780 #  undef inline
 781 #  if defined (G_HAVE___INLINE__)
 782 #    define inline __inline__
 783 #  elif defined (G_HAVE___INLINE)
 784 #    define inline __inline
 785 #  endif
 786 #endif
 787
 788 int glib_test_func2 (int);
 789
 790 static inline int
 791 glib_test_func1 (void) {
 792   return glib_test_func2 (1);
 793 }
 794
 795 int
 796 main (void) {
 797   int i = 1;
 798 }]])],[g_can_inline=yes],[g_can_inline=no])
 799 AC_MSG_RESULT($g_can_inline)
 800
 801 dnl *** check for working do while(0) macros ***
 802 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 803         AC_TRY_COMPILE([],[
 804         #define STMT_START do
 805         #define STMT_END while(0)
 806         #define STMT_TEST STMT_START { i = 0; } STMT_END
 807         int main(void) { int i = 1; STMT_TEST; return i; }],
 808         [g_cv_support_dowhile_macros=yes],
 809         [g_cv_support_dowhile_macros=no],
 810         [g_cv_support_dowhile_macros=yes])
 811 ])
 812 if test x$g_cv_support_dowhile_macros = xyes; then
 813   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 814 fi
 815
 816 # check for flavours of varargs macros
 817 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 818 AC_TRY_COMPILE([],[
 819 int a(int p1, int p2, int p3);
 820 #define call_a(...) a(1,__VA_ARGS__)
 821 call_a(2,3);
 822 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 823 AC_MSG_RESULT($g_have_iso_c_varargs)
 824
 825 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 826 if test "$CXX" = ""; then
 827 dnl No C++ compiler
 828   g_have_iso_cxx_varargs=no
 829 else
 830   AC_LANG_CPLUSPLUS
 831   AC_TRY_COMPILE([],[
 832 int a(int p1, int p2, int p3);
 833 #define call_a(...) a(1,__VA_ARGS__)
 834 call_a(2,3);
 835 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 836   AC_LANG_C
 837 fi
 838 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 839
 840 AC_MSG_CHECKING(for GNUC varargs macros)
 841 AC_TRY_COMPILE([],[
 842 int a(int p1, int p2, int p3);
 843 #define call_a(params...) a(1,params)
 844 call_a(2,3);
 845 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 846 AC_MSG_RESULT($g_have_gnuc_varargs)
 847
 848 # check for GNUC visibility support
 849 AC_MSG_CHECKING(for GNUC visibility attribute)
 850 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 851 void
 852 __attribute__ ((visibility ("hidden")))
 853      f_hidden (void)
 854 {
 855 }
 856 void
 857 __attribute__ ((visibility ("internal")))
 858      f_internal (void)
 859 {
 860 }
 861 void
 862 __attribute__ ((visibility ("protected")))
 863      f_protected (void)
 864 {
 865 }
 866 void
 867 __attribute__ ((visibility ("default")))
 868      f_default (void)
 869 {
 870 }
 871 int main (int argc, char **argv)
 872 {
 873         f_hidden();
 874         f_internal();
 875         f_protected();
 876         f_default();
 877         return 0;
 878 }
 879 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 880 AC_MSG_RESULT($g_have_gnuc_visibility)
 881 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 882
 883 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 884 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 885 #else
 886 # include "error: this is not Sun Studio."
 887 #endif
 888 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 889 AC_MSG_RESULT($g_have_sunstudio_visibility)
 890 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 891
 892 # check for bytesex stuff
 893 AC_C_BIGENDIAN
 894 if test x$ac_cv_c_bigendian = xuniversal ; then
 895 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 896 #else
 897 #error Not a big endian.
 898 #endif],
 899     ac_cv_c_bigendian=yes
 900     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 901 #else
 902 #error Not a little endian.
 903 #endif],
 904     ac_cv_c_bigendian=no
 905     ,AC_MSG_WARN([Could not determine endianness.])))
 906 fi
 907
 908
 909 # check for header files
 910 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 911 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 912 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 913 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 914 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 915 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 916 AC_CHECK_HEADERS([linux/magic.h])
 917
 918 # check for structure fields
 919 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 920 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 921 #include <sys/stat.h>
 922 #include <unistd.h>
 923 #ifdef HAVE_SYS_STATFS_H
 924 #include <sys/statfs.h>
 925 #endif
 926 #ifdef HAVE_SYS_PARAM_H
 927 #include <sys/param.h>
 928 #endif
 929 #ifdef HAVE_SYS_MOUNT_H
 930 #include <sys/mount.h>
 931 #endif])
 932 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 933 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 934 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 935
 936 # Checks for libcharset
 937 AM_LANGINFO_CODESET
 938 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 939 AC_CHECK_FUNCS(setlocale)
 940
 941 # check additional type sizes
 942 AC_CHECK_SIZEOF(size_t)
 943
 944 dnl Try to figure out whether gsize, gssize should be long or int
 945 AC_MSG_CHECKING([for the appropriate definition for size_t])
 946
 947 case $ac_cv_sizeof_size_t in
 948   $ac_cv_sizeof_short)
 949       glib_size_type=short
 950       ;;
 951   $ac_cv_sizeof_int)
 952       glib_size_type=int
 953       ;;
 954   $ac_cv_sizeof_long)
 955       glib_size_type=long
 956       ;;
 957   $ac_cv_sizeof_long_long)
 958       glib_size_type='long long'
 959       ;;
 960   $ac_cv_sizeof__int64)
 961       glib_size_type='__int64'
 962       ;;
 963   *)  AC_MSG_ERROR([No type matching size_t in size])
 964       ;;
 965 esac
 966
 967 dnl If int/long are the same size, we see which one produces
 968 dnl warnings when used in the location as size_t. (This matters
 969 dnl on AIX with xlc)
 970 dnl
 971 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 972    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 973   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 974 #if defined(_AIX) && !defined(__GNUC__)
 975 #pragma options langlvl=stdc89
 976 #endif
 977 #include <stddef.h>
 978 int main ()
 979 {
 980   size_t s = 1;
 981   unsigned int *size_int = &s;
 982   return (int)*size_int;
 983 }
 984     ]])],glib_size_type=int,
 985       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 986 #if defined(_AIX) && !defined(__GNUC__)
 987 #pragma options langlvl=stdc89
 988 #endif
 989 #include <stddef.h>
 990 int main ()
 991 {
 992    size_t s = 1;
 993    unsigned long *size_long = &s;
 994    return (int)*size_long;
 995 }
 996         ]])],glib_size_type=long)])
 997 fi
 998
 999 AC_MSG_RESULT(unsigned $glib_size_type)
1000
1001 # Check for some functions
1002 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
1003 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
1004 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getmntinfo)
1005 # Check for high-resolution sleep functions
1006 AC_CHECK_FUNCS(splice)
1007
1008 # To avoid finding a compatibility unusable statfs, which typically
1009 # successfully compiles, but warns to use the newer statvfs interface:
1010 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1011 AS_IF([test $ac_cv_header_sys_statfs_h  = yes], [AC_CHECK_FUNCS([statfs])])
1012
1013 AC_MSG_CHECKING([whether to use statfs or statvfs])
1014 # Some systems have both statfs and statvfs, pick the most "native" for these
1015 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1016    [
1017    # on solaris and irix, statfs doesn't even have the f_bavail field
1018    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1019       [ac_cv_func_statfs=no],
1020    # else, at least on linux, statfs is the actual syscall
1021       [ac_cv_func_statvfs=no])
1022    ])
1023
1024 AS_IF([test x$ac_cv_func_statfs = xyes],
1025       [
1026          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1027          AC_MSG_RESULT([statfs])
1028       ],
1029       [test x$ac_cv_func_statvfs = xyes],
1030       [
1031          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1032          AC_MSG_RESULT([statvfs])
1033       ],
1034       [  AC_MSG_RESULT([neither])])
1035
1036 AC_CHECK_HEADERS(crt_externs.h)
1037 AC_CHECK_FUNCS(_NSGetEnviron)
1038
1039 AC_FUNC_VSNPRINTF_C99
1040 AC_FUNC_PRINTF_UNIX98
1041
1042 # Internet address families
1043 if test $glib_native_win32 = yes; then
1044   glib_inet_includes=["
1045 #include <winsock2.h>
1046   "]
1047 else
1048   glib_inet_includes=["
1049 #include <sys/types.h>
1050 #include <sys/socket.h>
1051   "]
1052 fi
1053
1054 glib_failed=false
1055 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1056 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1057 # winsock defines this even though it doesn't support it
1058 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1059 if $glib_failed ; then
1060   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1061 fi
1062
1063 glib_failed=false
1064 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1065 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1066 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1067 if $glib_failed ; then
1068   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1069 fi
1070
1071 AC_CHECK_FUNCS(getprotobyname_r endservent)
1072 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1073
1074 # For gio/libasyncns
1075 AC_CHECK_FUNCS(strndup setresuid setreuid)
1076 AC_CHECK_HEADERS(sys/prctl.h)
1077
1078 # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1079 NETWORK_LIBS=""
1080 AC_MSG_CHECKING([for res_query])
1081 AC_TRY_LINK([#include <sys/types.h>
1082              #include <netinet/in.h>
1083              #include <arpa/nameser.h>
1084              #include <resolv.h>
1085             ],[
1086              res_query("test", 0, 0, (void *)0, 0);
1087             ],[AC_MSG_RESULT([yes])],
1088             [save_libs="$LIBS"
1089              LIBS="-lresolv $LIBS"
1090              AC_TRY_LINK([#include <sys/types.h>
1091                           #include <netinet/in.h>
1092                           #include <arpa/nameser.h>
1093                           #include <resolv.h>
1094                          ],[
1095                           res_query("test", 0, 0, (void *)0, 0);
1096                          ],[AC_MSG_RESULT([in -lresolv])
1097                             NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1098                          [LIBS="-lbind $save_libs"
1099                           AC_TRY_LINK([#include <resolv.h>],
1100                                       [res_query("test", 0, 0, (void *)0, 0);],
1101                                       [AC_MSG_RESULT([in -lbind])
1102                                        NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1103                                       [AC_MSG_ERROR(not found)])])
1104              LIBS="$save_libs"])
1105 AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1106                                       [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1107                                       [AC_MSG_ERROR(Could not find socket())]))
1108 AC_SUBST(NETWORK_LIBS)
1109
1110 case $host in
1111   *-*-solaris* )
1112      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1113      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1114      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1115      ;;
1116 esac
1117
1118 dnl
1119 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1120 dnl
1121 if test "$ac_cv_func_statfs" = yes ; then
1122   AC_MSG_CHECKING([number of arguments to statfs()])
1123   AC_TRY_COMPILE([#include <unistd.h>
1124   #ifdef HAVE_SYS_PARAM_H
1125   #include <sys/param.h>
1126   #endif
1127   #ifdef HAVE_SYS_VFS_H
1128   #include <sys/vfs.h>
1129   #endif
1130   #ifdef HAVE_SYS_MOUNT_H
1131   #include <sys/mount.h>
1132   #endif
1133   #ifdef HAVE_SYS_STATFS_H
1134   #include <sys/statfs.h>
1135   #endif], [struct statfs st;
1136   statfs(NULL, &st);],[
1137     AC_MSG_RESULT([2])
1138     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1139     AC_TRY_COMPILE([#include <unistd.h>
1140   #ifdef HAVE_SYS_PARAM_H
1141   #include <sys/param.h>
1142   #endif
1143   #ifdef HAVE_SYS_VFS_H
1144   #include <sys/vfs.h>
1145   #endif
1146   #ifdef HAVE_SYS_MOUNT_H
1147   #include <sys/mount.h>
1148   #endif
1149   #ifdef HAVE_SYS_STATFS_H
1150   #include <sys/statfs.h>
1151   #endif], [struct statfs st;
1152   statfs(NULL, &st, sizeof (st), 0);],[
1153       AC_MSG_RESULT([4])
1154       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1155       AC_MSG_RESULT(unknown)
1156       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1157 fi
1158
1159 #
1160 # Check whether to use an included printf
1161 #
1162
1163 AC_ARG_ENABLE(included-printf,
1164               [AC_HELP_STRING([--enable-included-printf],
1165                               [use included printf [default=auto]])],
1166               enable_included_printf="$enableval")
1167
1168 need_included_printf=no
1169 if test "x$enable_included_printf" = "xyes" ; then
1170   need_included_printf=yes
1171 fi
1172 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1173   need_included_printf=yes
1174 fi
1175 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1176   need_included_printf=yes
1177 fi
1178 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1179    test -z "$glib_cv_long_long_format" ; then
1180   need_included_printf=yes
1181 fi
1182
1183 if test "x$enable_included_printf" = "xno" &&
1184    test "x$need_included_printf" = "xyes" ; then
1185   AC_MSG_ERROR([
1186 *** Your C library's printf doesn't appear to have the features that
1187 *** GLib needs, but you specified --enable-included-printf=no.])
1188 fi
1189
1190 enable_included_printf=$need_included_printf
1191
1192 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1193 if test "$enable_included_printf" != "yes" ; then
1194   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1195 else
1196   if test -z "$glib_cv_long_long_format" ; then
1197     glib_cv_long_long_format="ll"
1198   fi
1199   AC_DEFINE(HAVE_VASPRINTF,1)
1200 fi
1201
1202 # Checks needed for gnulib vasnprintf
1203 bh_C_SIGNED
1204 jm_AC_TYPE_LONG_LONG
1205 gt_TYPE_LONGDOUBLE
1206 gt_TYPE_WCHAR_T
1207 gt_TYPE_WINT_T
1208 AC_TYPE_SIZE_T
1209 AC_CHECK_TYPES(ptrdiff_t)
1210 jm_AC_TYPE_INTMAX_T
1211 AC_CHECK_FUNCS([snprintf wcslen])
1212 AC_FUNC_SNPRINTF_C99
1213
1214 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1215 # The check is borrowed from the PERL Configure script.
1216 if test "$ac_cv_func_memmove" != "yes"; then
1217   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1218     glib_cv_working_bcopy,[AC_TRY_RUN([
1219       int main() {
1220         char buf[128], abc[128], *b;
1221         int len, off, align;
1222         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1223         for (align = 7; align >= 0; align--) {
1224           for (len = 36; len; len--) {
1225             b = buf+align; bcopy(abc, b, len);
1226             for (off = 1; off <= len; off++) {
1227               bcopy(b, b+off, len); bcopy(b+off, b, len);
1228                 if (bcmp(b, abc, len)) return(1);
1229             }
1230           }
1231         }
1232         return(0);
1233       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1234
1235   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1236   if test "$glib_cv_working_bcopy" = "yes"; then
1237     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1238   fi
1239 fi
1240
1241 # Check for sys_errlist
1242 AC_MSG_CHECKING(for sys_errlist)
1243 AC_TRY_LINK(, [
1244 extern char *sys_errlist[];
1245 extern int sys_nerr;
1246 sys_errlist[sys_nerr-1][0] = 0;
1247 ], glib_ok=yes, glib_ok=no)
1248 AC_MSG_RESULT($glib_ok)
1249 if test "$glib_ok" = "no"; then
1250     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1251 fi
1252
1253 # Check for sys_siglist
1254 AC_MSG_CHECKING(for sys_siglist)
1255 AC_TRY_LINK(, [
1256 extern char *sys_siglist[];
1257 exit (sys_siglist[0]);
1258 ], glib_ok=yes, glib_ok=no)
1259 AC_MSG_RESULT($glib_ok)
1260 if test "$glib_ok" = "no"; then
1261     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1262 fi
1263
1264 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1265 AC_MSG_CHECKING(for sys_siglist declaration)
1266 AC_TRY_COMPILE([#include <signal.h>], [
1267 strlen (sys_siglist[0]);
1268 ], glib_ok=yes, glib_ok=no)
1269 AC_MSG_RESULT($glib_ok)
1270 if test "$glib_ok" = "no"; then
1271     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1272 fi
1273
1274 # Check if <sys/select.h> needs to be included for fd_set
1275 AC_MSG_CHECKING([for fd_set])
1276 AC_TRY_COMPILE([#include <sys/types.h>],
1277         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1278 if test "$gtk_ok" = "yes"; then
1279     AC_MSG_RESULT([yes, found in sys/types.h])
1280 else
1281     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1282     if test "$gtk_ok" = "yes"; then
1283         # *** FIXME: give it a different name
1284         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1285         AC_MSG_RESULT([yes, found in sys/select.h])
1286     else
1287         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1288         AC_MSG_RESULT(no)
1289     fi
1290 fi
1291
1292 dnl *** check for sane realloc() ***
1293 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1294         AC_TRY_RUN([#include <stdlib.h>
1295         int main() {
1296           return realloc (0, sizeof (int)) == 0;
1297         }],
1298         [glib_cv_sane_realloc=yes],
1299         [glib_cv_sane_realloc=no],
1300         [glib_cv_sane_realloc=yes])
1301 ])
1302 if test x$glib_cv_sane_realloc = xyes; then
1303   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1304 fi
1305
1306 dnl Check for nl_langinfo and CODESET
1307 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1308         AC_TRY_COMPILE([#include <langinfo.h>],
1309                 [char *codeset = nl_langinfo (CODESET);],
1310                 [glib_cv_langinfo_codeset=yes],
1311                 [glib_cv_langinfo_codeset=no])])
1312 if test x$glib_cv_langinfo_codeset = xyes; then
1313   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1314 fi
1315
1316 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1317 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1318         AC_TRY_COMPILE([#include <langinfo.h>],
1319                 [char *str;
1320                  str = nl_langinfo (PM_STR);
1321                  str = nl_langinfo (D_FMT);
1322                  str = nl_langinfo (T_FMT);
1323                  str = nl_langinfo (MON_1);
1324                  str = nl_langinfo (ABMON_12);
1325                  str = nl_langinfo (DAY_1);
1326                  str = nl_langinfo (ABDAY_7);],
1327                 [glib_cv_langinfo_time=yes],
1328                 [glib_cv_langinfo_time=no])])
1329 if test x$glib_cv_langinfo_time = xyes; then
1330   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1331 fi
1332
1333 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1334 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1335         AC_TRY_COMPILE([#include <langinfo.h>],
1336                 [char *str;
1337                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1338                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1339                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1340                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1341                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1342                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1343                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1344                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1345                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1346                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1347                 [glib_cv_langinfo_outdigit=yes],
1348                 [glib_cv_langinfo_outdigit=no])])
1349 if test x$glib_cv_langinfo_outdigit = xyes; then
1350   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1351 fi
1352
1353 dnl ****************************************
1354 dnl *** posix_memalign                   ***
1355 dnl ****************************************
1356 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1357 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1358     glib_cv_compliant_posix_memalign=0
1359     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1360         AC_TRY_RUN([
1361                 #define _XOPEN_SOURCE 600
1362                 #include <stdlib.h> /* posix_memalign() should be defined here */
1363                 /* some systems break if #include <malloc.h> used */
1364                 static void test_memalign (size_t boundary, size_t size) {
1365                     void *mem = 0;
1366                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1367                         exit (1);
1368                     else
1369                       free (mem);
1370                 }
1371                 int main() {
1372                     test_memalign (  128,   128 - 2 * sizeof (void*));
1373                     test_memalign (  256,   256 - 2 * sizeof (void*));
1374                     test_memalign (  512,   512 - 2 * sizeof (void*));
1375                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1376                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1377                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1378                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1379                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1380                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1381                     exit (0); /* success */
1382                 }
1383                 ],
1384             [glib_cv_compliant_posix_memalign=1], [], [:])
1385       :
1386     fi
1387     ])
1388 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1389     AC_MSG_RESULT(yes)
1390     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1391 else
1392     AC_MSG_RESULT(no)
1393 fi
1394
1395
1396 dnl ****************************************
1397 dnl *** strlcpy/strlcat                  ***
1398 dnl ****************************************
1399 # Check for strlcpy
1400 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1401 AC_TRY_RUN([#include <stdlib.h>
1402 #include <string.h>
1403 int main() {
1404   char p[10];
1405   (void) strlcpy (p, "hi", 10);
1406   if (strlcat (p, "bye", 0) != 3)
1407     return 1;
1408   return 0;
1409 }], glib_cv_have_strlcpy=yes,
1410     glib_cv_have_strlcpy=no,
1411     glib_cv_have_strlcpy=no)])
1412 if test "$glib_cv_have_strlcpy" = "yes"; then
1413     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1414 fi
1415
1416
1417 dnl **********************
1418 dnl *** va_copy checks ***
1419 dnl **********************
1420 dnl we currently check for all three va_copy possibilities, so we get
1421 dnl all results in config.log for bug reports.
1422 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1423         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1424 #include <stdlib.h>
1425         void f (int i, ...) {
1426         va_list args1, args2;
1427         va_start (args1, i);
1428         va_copy (args2, args1);
1429         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1430           exit (1);
1431         va_end (args1); va_end (args2);
1432         }
1433         int main() {
1434           f (0, 42);
1435           return 0;
1436         }]])],
1437         [glib_cv_va_copy=yes],
1438         [glib_cv_va_copy=no])
1439 ])
1440 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1441         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1442 #include <stdlib.h>
1443         void f (int i, ...) {
1444         va_list args1, args2;
1445         va_start (args1, i);
1446         __va_copy (args2, args1);
1447         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1448           exit (1);
1449         va_end (args1); va_end (args2);
1450         }
1451         int main() {
1452           f (0, 42);
1453           return 0;
1454         }]])],
1455         [glib_cv___va_copy=yes],
1456         [glib_cv___va_copy=no])
1457 ])
1458
1459 if test "x$glib_cv_va_copy" = "xyes"; then
1460   g_va_copy_func=va_copy
1461 else if test "x$glib_cv___va_copy" = "xyes"; then
1462   g_va_copy_func=__va_copy
1463 fi
1464 fi
1465
1466 if test -n "$g_va_copy_func"; then
1467   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1468 fi
1469
1470 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1471         AC_TRY_RUN([#include <stdarg.h>
1472 #include <stdlib.h>
1473         void f (int i, ...) {
1474         va_list args1, args2;
1475         va_start (args1, i);
1476         args2 = args1;
1477         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1478           exit (1);
1479         va_end (args1); va_end (args2);
1480         }
1481         int main() {
1482           f (0, 42);
1483           return 0;
1484         }],
1485         [glib_cv_va_val_copy=yes],
1486         [glib_cv_va_val_copy=no],
1487         [glib_cv_va_val_copy=yes])
1488 ])
1489
1490 if test "x$glib_cv_va_val_copy" = "xno"; then
1491   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1492 fi
1493
1494 dnl ***********************
1495 dnl *** g_module checks ***
1496 dnl ***********************
1497 G_MODULE_LIBS=
1498 G_MODULE_LIBS_EXTRA=
1499 G_MODULE_PLUGIN_LIBS=
1500 if test x"$glib_native_win32" = xyes; then
1501   dnl No use for this on Win32
1502   G_MODULE_LDFLAGS=
1503 else
1504   export SED
1505   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1506 fi
1507 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1508 G_MODULE_NEED_USCORE=0
1509 G_MODULE_BROKEN_RTLD_GLOBAL=0
1510 G_MODULE_HAVE_DLERROR=0
1511 dnl *** force native WIN32 shared lib loader
1512 if test -z "$G_MODULE_IMPL"; then
1513   case "$host" in
1514   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1515   esac
1516 fi
1517 dnl *** force native AIX library loader
1518 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1519 if test -z "$G_MODULE_IMPL"; then
1520   case "$host" in
1521   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1522   esac
1523 fi
1524 dnl *** dlopen() and dlsym() in system libraries
1525 if test -z "$G_MODULE_IMPL"; then
1526         AC_CHECK_FUNC(dlopen,
1527                       [AC_CHECK_FUNC(dlsym,
1528                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1529                       [])
1530 fi
1531 dnl *** load_image (BeOS)
1532 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1533   AC_CHECK_LIB(root, load_image,
1534       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1535       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1536       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1537       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1538       [])
1539 fi
1540 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1541 if test -z "$G_MODULE_IMPL"; then
1542         AC_CHECK_FUNC(NSLinkModule,
1543                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1544                        G_MODULE_NEED_USCORE=1],
1545                       [])
1546 fi
1547 dnl *** dlopen() and dlsym() in libdl
1548 if test -z "$G_MODULE_IMPL"; then
1549         AC_CHECK_LIB(dl, dlopen,
1550                      [AC_CHECK_LIB(dl, dlsym,
1551                                    [G_MODULE_LIBS=-ldl
1552                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1553                      [])
1554 fi
1555 dnl *** shl_load() in libdld (HP-UX)
1556 if test -z "$G_MODULE_IMPL"; then
1557         AC_CHECK_LIB(dld, shl_load,
1558                 [G_MODULE_LIBS=-ldld
1559                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1560                 [])
1561 fi
1562 dnl *** additional checks for G_MODULE_IMPL_DL
1563 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1564         LIBS_orig="$LIBS"
1565         LDFLAGS_orig="$LDFLAGS"
1566         LIBS="$G_MODULE_LIBS $LIBS"
1567         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1568 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1569         echo "void glib_plugin_test(void) { }" > plugin.c
1570         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1571                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1572         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1573                 glib_cv_rtldglobal_broken,[
1574                 AC_TRY_RUN([
1575 #include <dlfcn.h>
1576 #ifndef RTLD_GLOBAL
1577 #  define RTLD_GLOBAL 0
1578 #endif
1579 #ifndef RTLD_LAZY
1580 #  define RTLD_LAZY 0
1581 #endif
1582 int glib_plugin_test;
1583 int main () {
1584     void *handle, *global, *local;
1585     global = &glib_plugin_test;
1586     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1587     if (!handle) return 0;
1588     local = dlsym (handle, "glib_plugin_test");
1589     return global == local;
1590 }                       ],
1591                         [glib_cv_rtldglobal_broken=no],
1592                         [glib_cv_rtldglobal_broken=yes],
1593                         [glib_cv_rtldglobal_broken=no])
1594                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1595                 rmdir .libs 2>/dev/null
1596         ])
1597         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1598                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1599         else
1600                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1601         fi
1602 dnl *** check whether we need preceeding underscores
1603         AC_CACHE_CHECK([for preceeding underscore in symbols],
1604                 glib_cv_uscore,[
1605                 AC_TRY_RUN([#include <dlfcn.h>
1606                 int glib_underscore_test (void) { return 42; }
1607                 int main() {
1608                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1609                   handle = dlopen ((void*)0, 0);
1610                   if (handle) {
1611                     f1 = dlsym (handle, "glib_underscore_test");
1612                     f2 = dlsym (handle, "_glib_underscore_test");
1613                   } return (!f2 || f1);
1614                 }],
1615                         [glib_cv_uscore=yes],
1616                         [glib_cv_uscore=no],
1617                         [])
1618                 rm -f plugin.c plugin.$ac_objext plugin.lo
1619         ])
1620         GLIB_ASSERT_SET(glib_cv_uscore)
1621         if test "x$glib_cv_uscore" = "xyes"; then
1622                 G_MODULE_NEED_USCORE=1
1623         else
1624                 G_MODULE_NEED_USCORE=0
1625         fi
1626
1627         LDFLAGS="$LDFLAGS_orig"
1628 dnl *** check for having dlerror()
1629         AC_CHECK_FUNC(dlerror,
1630                 [G_MODULE_HAVE_DLERROR=1],
1631                 [G_MODULE_HAVE_DLERROR=0])
1632         LIBS="$LIBS_orig"
1633 fi
1634 dnl *** done, have we got an implementation?
1635 if test -z "$G_MODULE_IMPL"; then
1636         G_MODULE_IMPL=0
1637         G_MODULE_SUPPORTED=false
1638 else
1639         G_MODULE_SUPPORTED=true
1640 fi
1641
1642 AC_MSG_CHECKING(for the suffix of module shared libraries)
1643 export SED
1644 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1645 eval $shrext_cmds
1646 module=yes eval std_shrext=$shrext_cmds
1647 # chop the initial dot
1648 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1649 AC_MSG_RESULT(.$glib_gmodule_suffix)
1650 # any reason it may fail?
1651 if test "x$glib_gmodule_suffix" = x; then
1652         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1653 fi
1654
1655 AC_SUBST(G_MODULE_SUPPORTED)
1656 AC_SUBST(G_MODULE_IMPL)
1657 AC_SUBST(G_MODULE_LIBS)
1658 AC_SUBST(G_MODULE_LIBS_EXTRA)
1659 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1660 AC_SUBST(G_MODULE_LDFLAGS)
1661 AC_SUBST(G_MODULE_HAVE_DLERROR)
1662 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1663 AC_SUBST(G_MODULE_NEED_USCORE)
1664 AC_SUBST(GLIB_DEBUG_FLAGS)
1665
1666 dnl **********************
1667 dnl *** g_spawn checks ***
1668 dnl **********************
1669
1670 AC_MSG_CHECKING(for gspawn implementation)
1671 case "$host" in
1672   *-*-mingw*)
1673     GSPAWN=gspawn-win32.lo
1674     ;;
1675   *)
1676     GSPAWN=gspawn.lo
1677     ;;
1678 esac
1679 AC_MSG_RESULT($GSPAWN)
1680 AC_SUBST(GSPAWN)
1681
1682 dnl *************************
1683 dnl *** GIOChannel checks ***
1684 dnl *************************
1685
1686 AC_MSG_CHECKING(for GIOChannel implementation)
1687 case "$host" in
1688   *-*-mingw*)
1689     GIO=giowin32.lo
1690     ;;
1691   *)
1692     GIO=giounix.lo
1693     ;;
1694 esac
1695 AC_MSG_RESULT($GIO)
1696 AC_SUBST(GIO)
1697
1698 dnl *********************************
1699 dnl *** Directory for GIO modules ***
1700 dnl *********************************
1701
1702 AC_ARG_WITH(gio-module-dir,
1703            [AC_HELP_STRING([--with-gio-module-dir=PATH],
1704                            [Load gio modules from this directory [LIBDIR/gio/modules]])],
1705            [],
1706            [with_gio_module_dir='${libdir}/gio/modules'])
1707 GIO_MODULE_DIR=$with_gio_module_dir
1708 AC_SUBST(GIO_MODULE_DIR)
1709
1710 dnl **********************************
1711 dnl *** Check for libselinux (GIO) ***
1712 dnl **********************************
1713 AC_ARG_ENABLE(selinux, [  --disable-selinux       build without selinux support])
1714 msg_selinux=no
1715 SELINUX_LIBS=
1716 if test "x$enable_selinux" != "xno"; then
1717
1718  AC_CHECK_LIB(selinux, is_selinux_enabled,
1719    [AC_CHECK_HEADERS(selinux/selinux.h,
1720      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1721        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1722         SELINUX_LIBS="-lselinux"
1723         msg_selinux=yes])
1724      ])
1725    ])
1726 fi
1727 AC_SUBST(SELINUX_LIBS)
1728
1729 dnl *****************************
1730 dnl ** Check for inotify (GIO) **
1731 dnl *****************************
1732 inotify_support=no
1733 AC_CHECK_HEADERS([sys/inotify.h],
1734 [
1735         inotify_support=yes
1736         AC_CHECK_FUNCS(inotify_init1)
1737 ])
1738
1739 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1740
1741 dnl *********************************
1742 dnl ** Check for Solaris FEN (GIO) **
1743 dnl *********************************
1744 fen_support=no
1745 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1746 #include <port.h>
1747 #ifndef PORT_SOURCE_FILE
1748 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1749 #endif
1750 int main() { return 0; } ]])],
1751 [
1752         fen_support=yes
1753 ],)
1754
1755 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1756
1757 dnl ****************************
1758 dnl *** Checks for FAM (GIO) ***
1759 dnl ****************************
1760
1761 should_disable_fam=no
1762
1763 AC_ARG_ENABLE(fam, [  --disable-fam          build without enabling fam for file system monitoring],
1764                          [
1765                                 if test "x$enable_fam" = "xno"; then
1766                                         should_disable_fam=yes
1767                                         echo "Not building FAM support"
1768                                 fi
1769                          ]
1770                          )
1771 fam_support=no
1772 FAM_LIBS=
1773 if test "x$should_disable_fam" = "xno"; then
1774 AC_CHECK_LIB(fam, FAMOpen,
1775   [AC_CHECK_HEADERS(fam.h,
1776     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1777      AC_CHECK_LIB(fam, FAMNoExists,
1778                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1779      FAM_LIBS="-lfam"]
1780      fam_support=yes,
1781     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1782   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1783 AC_SUBST(FAM_LIBS)
1784 fi
1785 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1786
1787
1788 dnl *****************************
1789 dnl *** Check for xattr (GIO) ***
1790 dnl *****************************
1791 AC_ARG_ENABLE(xattr, [  --disable-xattr           build without xattr support])
1792 msg_xattr=no
1793 XATTR_LIBS=
1794 if test "x$enable_xattr" != "xno"; then
1795
1796 dnl either glibc or libattr can provide xattr support
1797
1798 dnl for both of them, we check for getxattr being in
1799 dnl the library and a valid xattr header.
1800
1801 dnl try glibc
1802  AC_CHECK_LIB(c, getxattr,
1803    [AC_CHECK_HEADERS(sys/xattr.h,
1804      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1805       msg_xattr=yes])
1806    ])
1807
1808   if test "x$msg_xattr" != "xyes"; then
1809 dnl   failure. try libattr
1810    AC_CHECK_LIB(attr, getxattr,
1811       [AC_CHECK_HEADERS(attr/xattr.h,
1812        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1813         XATTR_LIBS="-lattr"
1814         msg_xattr=yes])
1815       ])
1816   fi
1817
1818   if test "x$msg_xattr" = "xyes"; then
1819     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1820     AC_TRY_COMPILE([
1821       #include <stdio.h>
1822       #ifdef HAVE_SYS_TYPES_H
1823       #include <sys/types.h>
1824       #endif
1825       #ifdef HAVE_SYS_XATTR_H
1826       #include <sys/xattr.h>
1827       #elif HAVE_ATTR_XATTR_H
1828       #include <attr/xattr.h>
1829       #endif
1830     ],
1831     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1832     [
1833       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1834       AC_MSG_RESULT([yes])
1835     ],
1836     [AC_MSG_RESULT([no])]
1837     )
1838   fi
1839
1840 fi
1841 AC_SUBST(XATTR_LIBS)
1842
1843 dnl ****************************************
1844 dnl *** platform dependent source checks ***
1845 dnl ****************************************
1846
1847 AC_MSG_CHECKING(for platform-dependent source)
1848 case "$host" in
1849   *-*-cygwin*|*-*-mingw*)
1850     PLATFORMDEP=gwin32.lo
1851     ;;
1852   *)
1853     PLATFORMDEP=
1854     ;;
1855 esac
1856 AC_MSG_RESULT($PLATFORMDEP)
1857 AC_SUBST(PLATFORMDEP)
1858
1859 AC_MSG_CHECKING([whether to compile timeloop])
1860 case "$host" in
1861   *-*-cygwin*|*-*-mingw*|*-*-minix)
1862     enable_timeloop=no
1863     ;;
1864   *)
1865     enable_timeloop=yes
1866     ;;
1867 esac
1868 AC_MSG_RESULT($enable_timeloop)
1869 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1870
1871 AC_MSG_CHECKING([if building for some Win32 platform])
1872 case "$host" in
1873   *-*-mingw*|*-*-cygwin*)
1874     platform_win32=yes
1875     ;;
1876   *)
1877     platform_win32=no
1878     ;;
1879 esac
1880 AC_MSG_RESULT($platform_win32)
1881 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1882
1883 dnl ***********************
1884 dnl *** g_thread checks ***
1885 dnl ***********************
1886
1887 AC_ARG_WITH(threads,
1888            [AC_HELP_STRING([--with-threads=@<:@none/posix/dce/win32@:>@],
1889                            [specify a thread implementation to use])],
1890            [if test "x$with_threads" = x; then
1891                 want_threads=yes
1892             else
1893                 want_threads=$with_threads
1894             fi],
1895            [want_threads=yes])
1896 if test "x$enable_threads" = "xno"; then
1897         want_threads=no
1898 fi
1899
1900 dnl error and warning message
1901 dnl *************************
1902
1903 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1904                 computer. GLib will not have a default thread implementation."
1905
1906 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1907                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1908                 compilation now, but then your programs might not work.
1909                 Please provide information on how it is done on your system."
1910
1911 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1912                 "
1913
1914 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1915                 provide information on your thread implementation.
1916                 You can also run 'configure --disable-threads'
1917                 to compile without thread support."
1918
1919 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1920                 functions will not be MT-safe during their first call because
1921                 there is no working 'getpwuid_r' on your system."
1922
1923 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1924                 because there is no 'localtime_r' on your system."
1925
1926 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1927                 crude surrogate will be used. If you happen to know a
1928                 yield function for your system, please inform the GLib
1929                 developers."
1930
1931 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1932                 threads on your system. Thus threads can only have the default
1933                 priority. If you happen to know these main/max
1934                 priorities, please inform the GLib developers."
1935
1936 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1937                 linking threaded applications. As GLib cannot do that
1938                 automatically, you will get an linkg error everytime you are
1939                 not using the right compiler. In that case you have to relink
1940                 with the right compiler. Ususally just '_r' is appended
1941                 to the compiler name."
1942
1943 dnl determination of thread implementation
1944 dnl ***************************************
1945
1946 # have_threads=no   means no thread support
1947 # have_threads=none means no default thread implementation
1948
1949 have_threads=no
1950 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1951                                 || test "x$want_threads" = xdce; then
1952         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1953         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1954         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1955         glib_save_CPPFLAGS="$CPPFLAGS"
1956         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1957         if test "x$have_threads" = xno; then
1958                 AC_TRY_COMPILE([#include <pthread.h>],
1959                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1960                         have_threads=posix)
1961         fi
1962         if test "x$have_threads" = xno; then
1963                 AC_TRY_COMPILE([#include <pthread.h>],
1964                         [pthread_mutex_t m;
1965                          pthread_mutex_init (&m, pthread_mutexattr_default);],
1966                         have_threads=dce)
1967         fi
1968         # Tru64Unix requires -pthread to find pthread.h. See #103020
1969         CPPFLAGS="$CPPFLAGS -pthread"
1970         if test "x$have_threads" = xno; then
1971         AC_TRY_COMPILE([#include <pthread.h>],
1972                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1973                        have_threads=posix)
1974         fi
1975         CPPFLAGS="$glib_save_CPPFLAGS"
1976 fi
1977 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1978         case $host in
1979                 *-*-mingw*)
1980                 have_threads=win32
1981                 ;;
1982         esac
1983 fi
1984 if test "x$want_threads" = xnone; then
1985         have_threads=none
1986 fi
1987
1988 AC_MSG_CHECKING(for thread implementation)
1989
1990 if test "x$have_threads" = xno && test "x$want_threads" != xno; then
1991         AC_MSG_RESULT(none available)
1992         AC_MSG_WARN($THREAD_NO_IMPLEMENTATION)
1993 else
1994         AC_MSG_RESULT($have_threads)
1995 fi
1996
1997
1998 dnl determination of G_THREAD_CFLAGS
1999 dnl ********************************
2000
2001 G_THREAD_LIBS=
2002 G_THREAD_LIBS_EXTRA=
2003 G_THREAD_CFLAGS=
2004
2005 dnl
2006 dnl Test program for basic POSIX threads functionality
2007 dnl
2008 m4_define([glib_thread_test],[
2009 #include <pthread.h>
2010 int check_me = 0;
2011 void* func(void* data) {check_me = 42; return &check_me;}
2012 int main()
2013  { pthread_t t;
2014    void *ret;
2015    pthread_create (&t, $1, func, 0);
2016    pthread_join (t, &ret);
2017    return (check_me != 42 || ret != &check_me);
2018 }])
2019
2020 dnl
2021 dnl Test program for sched_get_priority_min()
2022 dnl
2023 m4_define([glib_sched_priority_test],[
2024 #include <sched.h>
2025 #include <errno.h>
2026 int main() {
2027     errno = 0;
2028     return sched_get_priority_min(SCHED_OTHER)==-1
2029            && errno != 0;
2030 }])
2031
2032 if test x"$have_threads" != xno; then
2033
2034   if test x"$have_threads" = xposix; then
2035     # First we test for posix, whether -pthread or -pthreads do the trick as
2036     # both CPPFLAG and LIBS.
2037     # One of them does for most gcc versions and some other platforms/compilers
2038     # too and could be considered as the canonical way to go.
2039     case $host in
2040       *-*-cygwin*|*-*-darwin*)
2041          # skip cygwin and darwin -pthread or -pthreads test
2042          ;;
2043       *-solaris*)
2044         # These compiler/linker flags work with both Sun Studio and gcc
2045         # Sun Studio expands -mt to -D_REENTRANT and -lthread
2046         # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2047         G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2048         G_THREAD_LIBS="-lpthread -lthread"
2049         ;;
2050       *)
2051         for flag in pthread pthreads mt; do
2052           glib_save_CFLAGS="$CFLAGS"
2053           CFLAGS="$CFLAGS -$flag"
2054           AC_TRY_RUN(glib_thread_test(0),
2055                      glib_flag_works=yes,
2056                      glib_flag_works=no,
2057                      [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2058                                      glib_flag_works=yes,
2059                                      glib_flag_works=no)])
2060           CFLAGS="$glib_save_CFLAGS"
2061           if test $glib_flag_works = yes ; then
2062              G_THREAD_CFLAGS=-$flag
2063              G_THREAD_LIBS=-$flag
2064              break;
2065           fi
2066         done
2067          ;;
2068     esac
2069   fi
2070
2071   if test x"$G_THREAD_CFLAGS" = x; then
2072
2073     # The canonical -pthread[s] does not work. Try something different.
2074
2075     case $host in
2076         *-aix*)
2077                 if test x"$GCC" = xyes; then
2078                         # GCC 3.0 and above needs -pthread.
2079                         # Should be coverd by the case above.
2080                         # GCC 2.x and below needs -mthreads
2081                         G_THREAD_CFLAGS="-mthreads"
2082                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2083                 else
2084                         # We are probably using the aix compiler. Normaly a
2085                         # program would have to be compiled with the _r variant
2086                         # of the corresponding compiler, but we as GLib cannot
2087                         # do that: but the good news is that for compiling the
2088                         # only difference is the added -D_THREAD_SAFE compile
2089                         # option. This is according to the "C for AIX User's
2090                         # Guide".
2091                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2092                 fi
2093                 ;;
2094         *-dg-dgux*)  # DG/UX
2095                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2096                 ;;
2097         *-osf*)
2098                 # So we are using dce threads. posix threads are already
2099                 # catched above.
2100                 G_THREAD_CFLAGS="-threads"
2101                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2102                 ;;
2103         *-sysv5uw7*) # UnixWare 7
2104                 # We are not using gcc with -pthread. Catched above.
2105                 G_THREAD_CFLAGS="-Kthread"
2106                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2107                 ;;
2108         *-mingw*)
2109                 # No flag needed when using MSVCRT.DLL
2110                 G_THREAD_CFLAGS=""
2111                 ;;
2112         *)
2113                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2114                 ;;
2115     esac
2116
2117   fi
2118
2119     # if we are not finding the localtime_r function, then we probably are
2120     # not using the proper multithread flag
2121
2122     glib_save_CPPFLAGS="$CPPFLAGS"
2123     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2124
2125     # First we test, whether localtime_r is declared in time.h
2126     # directly. Then we test whether a macro localtime_r exists, in
2127     # which case localtime_r in the test program is replaced and thus
2128     # if we still find localtime_r in the output, it is not defined as
2129     # a macro.
2130
2131     AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2132       [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2133                                                            localtime_r(a,b)],
2134                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2135
2136     CPPFLAGS="$glib_save_CPPFLAGS"
2137
2138     AC_MSG_CHECKING(thread related cflags)
2139     AC_MSG_RESULT($G_THREAD_CFLAGS)
2140     CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2141 fi
2142
2143 dnl determination of G_THREAD_LIBS
2144 dnl ******************************
2145
2146 mutex_has_default=no
2147 case $have_threads in
2148         posix|dce)
2149           glib_save_CPPFLAGS="$CPPFLAGS"
2150           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2151           if test x"$G_THREAD_LIBS" = x; then
2152             case $host in
2153               *-aix*)
2154                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2155                 # probably using the aix compiler.
2156                 AC_MSG_WARN($AIX_COMPILE_INFO)
2157                 ;;
2158               *)
2159                 G_THREAD_LIBS=error
2160                 glib_save_LIBS="$LIBS"
2161                 for thread_lib in "" pthread pthread32 pthreads thread dce; do
2162                         if test x"$thread_lib" = x; then
2163                                 add_thread_lib=""
2164                                 IN=""
2165                         else
2166                                 add_thread_lib="-l$thread_lib"
2167                                 IN=" in -l$thread_lib"
2168                         fi
2169                         if test x"$have_threads" = xposix; then
2170                                 defattr=0
2171                         else
2172                                 defattr=pthread_attr_default
2173                         fi
2174
2175                         LIBS="$add_thread_lib $glib_save_LIBS"
2176
2177                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2178                         AC_TRY_RUN(glib_thread_test($defattr),
2179                                    glib_result=yes,
2180                                    glib_result=no,
2181                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2182                                                    glib_result=yes,
2183                                                    glib_result=no)])
2184                         AC_MSG_RESULT($glib_result)
2185
2186                         if test "$glib_result" = "yes" ; then
2187                           G_THREAD_LIBS="$add_thread_lib"
2188                           break
2189                         fi
2190                 done
2191                 if test "x$G_THREAD_LIBS" = xerror; then
2192                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2193                 fi
2194                 LIBS="$glib_save_LIBS"
2195                 ;;
2196             esac
2197           fi
2198
2199           glib_save_LIBS="$LIBS"
2200           for thread_lib in "" rt rte; do
2201             if test x"$thread_lib" = x; then
2202               add_thread_lib=""
2203               IN=""
2204             else
2205               add_thread_lib="-l$thread_lib"
2206               IN=" in -l$thread_lib"
2207             fi
2208             LIBS="$add_thread_lib $glib_save_LIBS"
2209
2210             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2211             AC_TRY_RUN(glib_sched_priority_test,
2212                        glib_result=yes,
2213                        glib_result=no,
2214                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2215                                        glib_result=yes,
2216                                        glib_result=no)])
2217             AC_MSG_RESULT($glib_result)
2218
2219             if test "$glib_result" = "yes" ; then
2220                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2221                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2222                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2223                break
2224             fi
2225           done
2226           LIBS="$glib_save_LIBS"
2227           mutex_has_default=yes
2228           mutex_default_type='pthread_mutex_t'
2229           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2230           mutex_header_file='pthread.h'
2231           if test "x$have_threads" = "xposix"; then
2232             g_threads_impl="POSIX"
2233           else
2234             g_threads_impl="DCE"
2235             have_threads="posix"
2236           fi
2237           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2238           CPPFLAGS="$glib_save_CPPFLAGS"
2239           ;;
2240         win32)
2241            g_threads_impl="WIN32"
2242            ;;
2243         none|no)
2244            g_threads_impl="NONE"
2245            ;;
2246         *)
2247            g_threads_impl="NONE"
2248            G_THREAD_LIBS=error
2249            ;;
2250 esac
2251
2252 if test "x$G_THREAD_LIBS" = xerror; then
2253         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2254 fi
2255
2256 case $host in
2257   *-*-beos*)
2258     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2259     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2260     ;;
2261   *)
2262     ;;
2263 esac
2264
2265 AC_MSG_CHECKING(thread related libraries)
2266 AC_MSG_RESULT($G_THREAD_LIBS)
2267
2268 dnl check for mt safe function variants and some posix functions
2269 dnl ************************************************************
2270
2271 if test x"$have_threads" != xno; then
2272         glib_save_LIBS="$LIBS"
2273         # we are not doing the following for now, as this might require glib
2274         # to always be linked with the thread libs on some platforms.
2275         # LIBS="$LIBS $G_THREAD_LIBS"
2276         AC_CHECK_FUNCS(localtime_r gmtime_r)
2277         if test "$ac_cv_header_pwd_h" = "yes"; then
2278                 AC_CACHE_CHECK([for posix getpwuid_r],
2279                         ac_cv_func_posix_getpwuid_r,
2280                         [AC_TRY_RUN([
2281 #include <errno.h>
2282 #include <pwd.h>
2283 int main () {
2284     char buffer[10000];
2285     struct passwd pwd, *pwptr = &pwd;
2286     int error;
2287     errno = 0;
2288     error = getpwuid_r (0, &pwd, buffer,
2289                         sizeof (buffer), &pwptr);
2290    return (error < 0 && errno == ENOSYS)
2291            || error == ENOSYS;
2292 }                               ],
2293                                 [ac_cv_func_posix_getpwuid_r=yes],
2294                                 [ac_cv_func_posix_getpwuid_r=no])])
2295                 GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2296                 if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2297                         AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2298                                 [Have POSIX function getpwuid_r])
2299                 else
2300                         AC_CACHE_CHECK([for nonposix getpwuid_r],
2301                                 ac_cv_func_nonposix_getpwuid_r,
2302                                 [AC_TRY_LINK([#include <pwd.h>],
2303                                         [char buffer[10000];
2304                                         struct passwd pwd;
2305                                         getpwuid_r (0, &pwd, buffer,
2306                                                         sizeof (buffer));],
2307                                         [ac_cv_func_nonposix_getpwuid_r=yes],
2308                                         [ac_cv_func_nonposix_getpwuid_r=no])])
2309                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2310                         if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2311                                 AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2312                                         [Have non-POSIX function getpwuid_r])
2313                         fi
2314                 fi
2315         fi
2316         if test "$ac_cv_header_grp_h" = "yes"; then
2317                 AC_CACHE_CHECK([for posix getgrgid_r],
2318                         ac_cv_func_posix_getgrgid_r,
2319                         [AC_TRY_RUN([
2320 #include <errno.h>
2321 #include <grp.h>
2322 int main () {
2323     char buffer[10000];
2324     struct group grp, *grpptr = &grp;
2325     int error;
2326     errno = 0;
2327     error = getgrgid_r (0, &grp, buffer,
2328                         sizeof (buffer), &grpptr);
2329    return (error < 0 && errno == ENOSYS)
2330            || error == ENOSYS;
2331 }                              ],
2332                                [ac_cv_func_posix_getgrgid_r=yes],
2333                                [ac_cv_func_posix_getgrgid_r=no])])
2334                 GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2335                 if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2336                         AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2337                                 [Have POSIX function getgrgid_r])
2338                 else
2339                         AC_CACHE_CHECK([for nonposix getgrgid_r],
2340                                 ac_cv_func_nonposix_getgrgid_r,
2341                                 [AC_TRY_LINK([#include <grp.h>],
2342                                         [char buffer[10000];
2343                                         struct group grp;
2344                                         getgrgid_r (0, &grp, buffer,
2345                                         sizeof (buffer));],
2346                                 [ac_cv_func_nonposix_getgrgid_r=yes],
2347                                 [ac_cv_func_nonposix_getgrgid_r=no])])
2348                         GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2349                         if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2350                                 AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2351                                         [Have non-POSIX function getgrgid_r])
2352                         fi
2353                 fi
2354         fi
2355         LIBS="$G_THREAD_LIBS $LIBS"
2356         if test x"$have_threads" = xposix; then
2357                 glib_save_CPPFLAGS="$CPPFLAGS"
2358                 CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2359                 dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2360                 GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2361                 # This is not AC_CHECK_FUNC to also work with function
2362                 # name mangling in header files.
2363                 AC_MSG_CHECKING(for pthread_attr_setstacksize)
2364                 AC_TRY_LINK([#include <pthread.h>],
2365                         [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2366                         [AC_MSG_RESULT(yes)
2367                         AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2368                                   [Have function pthread_attr_setstacksize])],
2369                         [AC_MSG_RESULT(no)])
2370                 AC_MSG_CHECKING(for minimal/maximal thread priority)
2371                 if test x"$posix_priority_min" = x; then
2372                         AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2373                                 PX_PRIO_MIN],,[
2374                                 posix_priority_min=PX_PRIO_MIN
2375                                 posix_priority_max=PX_PRIO_MAX])
2376                 fi
2377                 if test x"$posix_priority_min" = x; then
2378                         # AIX
2379                         AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2380                                 PTHREAD_PRIO_MIN],,[
2381                                 posix_priority_min=PTHREAD_PRIO_MIN
2382                                 posix_priority_max=PTHREAD_PRIO_MAX])
2383                 fi
2384                 if test x"$posix_priority_min" = x; then
2385                         AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2386                                 PRI_OTHER_MIN],,[
2387                                 posix_priority_min=PRI_OTHER_MIN
2388                                 posix_priority_max=PRI_OTHER_MAX])
2389                 fi
2390                 if test x"$posix_priority_min" = x; then
2391                         AC_MSG_RESULT(none found)
2392                         AC_MSG_WARN($POSIX_NO_PRIORITIES)
2393                         posix_priority_min=-1
2394                         posix_priority_max=-1
2395                 else
2396                         AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2397                         AC_MSG_CHECKING(for pthread_setschedparam)
2398                         AC_TRY_LINK([#include <pthread.h>],
2399                           [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2400                           [AC_MSG_RESULT(yes)
2401                         AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2402                            AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2403                           [AC_MSG_RESULT(no)
2404                            AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2405                 fi
2406                 posix_yield_func=none
2407                 AC_MSG_CHECKING(for posix yield function)
2408                 for yield_func in sched_yield pthread_yield_np pthread_yield \
2409                                                         thr_yield; do
2410                         AC_TRY_LINK([#include <pthread.h>],
2411                                 [$yield_func()],
2412                                 [posix_yield_func="$yield_func"
2413                                 break])
2414                 done
2415                 if test x"$posix_yield_func" = xnone; then
2416                         AC_MSG_RESULT(none found)
2417                         AC_MSG_WARN($POSIX_NO_YIELD)
2418                         posix_yield_func="g_usleep(1000)"
2419                 else
2420                         AC_MSG_RESULT($posix_yield_func)
2421                         posix_yield_func="$posix_yield_func()"
2422                 fi
2423                 AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2424                 CPPFLAGS="$glib_save_CPPFLAGS"
2425
2426         elif test x"$have_threads" = xwin32; then
2427                 # It's a pointer to a private struct
2428                 GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2429         fi
2430
2431         LIBS="$glib_save_LIBS"
2432
2433         # now spit out all the warnings.
2434         if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2435            test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2436                 AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2437         fi
2438         if test "$ac_cv_func_localtime_r" != "yes"; then
2439                 AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2440         fi
2441 fi
2442
2443 if test x"$glib_cv_sizeof_system_thread" = x; then
2444    # use a pointer as a fallback.
2445    GLIB_SIZEOF(,void *, system_thread)
2446 fi
2447
2448 #
2449 # Hack to deal with:
2450 #
2451 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2452 #     building shared libraries with linux.
2453 #  b) FreeBSD doesn't do this either.
2454 #
2455 case $host in
2456   *-*-freebsd*|*-*-linux*)
2457     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2458     ;;
2459   *)
2460     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2461     ;;
2462 esac
2463
2464 AM_CONDITIONAL(HAVE_THREADS, [test "$have_threads" != "none"])
2465 AC_DEFINE_UNQUOTED(G_THREAD_SOURCE,"gthread-$have_threads.c",
2466                    [Source file containing theread implementation])
2467 AC_SUBST(G_THREAD_CFLAGS)
2468 AC_SUBST(G_THREAD_LIBS)
2469 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2470 AC_SUBST(G_THREAD_LIBS_EXTRA)
2471
2472 dnl **********************************************
2473 dnl *** GDefaultMutex setup and initialization ***
2474 dnl **********************************************
2475 dnl
2476 dnl if mutex_has_default = yes, we also got
2477 dnl mutex_default_type, mutex_default_init and mutex_header_file
2478 if test $mutex_has_default = yes ; then
2479         glib_save_CPPFLAGS="$CPPFLAGS"
2480         glib_save_LIBS="$LIBS"
2481         LIBS="$G_THREAD_LIBS $LIBS"
2482         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2483         GLIB_SIZEOF([#include <$mutex_header_file>],
2484                     $mutex_default_type,
2485                     gmutex)
2486         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2487                            $mutex_default_type,
2488                            gmutex,
2489                            $glib_cv_sizeof_gmutex,
2490                            $mutex_default_init)
2491         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2492                 mutex_has_default=no
2493         fi
2494         CPPFLAGS="$glib_save_CPPFLAGS"
2495         LIBS="$glib_save_LIBS"
2496 fi
2497
2498 AC_CHECK_FUNCS(clock_gettime, [], [
2499   AC_CHECK_LIB(rt, clock_gettime, [
2500     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2501     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2502     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2503     GLIB_RT_LIBS="-lrt"
2504   ])
2505 ])
2506 AC_SUBST(GLIB_RT_LIBS)
2507
2508 AC_CACHE_CHECK(for monotonic clocks,
2509     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2510 #include <time.h>
2511 #include <unistd.h>
2512 int main() {
2513 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2514         #error No monotonic clock
2515 #endif
2516         return 0;
2517 }
2518 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2519 if test "$glib_cv_monotonic_clock" = "yes"; then
2520   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2521 fi
2522
2523
2524 dnl ************************
2525 dnl *** g_atomic_* tests ***
2526 dnl ************************
2527
2528 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2529     case $host_cpu in
2530       i386)
2531         AC_MSG_RESULT([none])
2532         glib_memory_barrier_needed=no
2533         ;;
2534       i?86)
2535         AC_MSG_RESULT([i486])
2536         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2537                            [i486 atomic implementation])
2538         glib_memory_barrier_needed=no
2539         ;;
2540       sparc*)
2541         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2542                          when you are using a sparc with v9 instruction set (most
2543                          sparcs nowadays). This will make the code for atomic
2544                          operations much faster. The resulting code will not run
2545                          on very old sparcs though."
2546
2547         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2548           main ()
2549           {
2550             int tmp1, tmp2, tmp3;
2551             __asm__ __volatile__("casx [%2], %0, %1"
2552                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2553           }]])],
2554           AC_MSG_RESULT([sparcv9])
2555           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2556                              [sparcv9 atomic implementation]),
2557           AC_MSG_RESULT([no])
2558           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2559         glib_memory_barrier_needed=yes
2560         ;;
2561       alpha*)
2562         AC_MSG_RESULT([alpha])
2563         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2564                            [alpha atomic implementation])
2565         glib_memory_barrier_needed=yes
2566         ;;
2567       x86_64)
2568         AC_MSG_RESULT([x86_64])
2569         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2570                            [x86_64 atomic implementation])
2571         glib_memory_barrier_needed=no
2572        ;;
2573       powerpc*)
2574         AC_MSG_RESULT([powerpc])
2575         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2576                            [powerpc atomic implementation])
2577         glib_memory_barrier_needed=yes
2578         AC_MSG_CHECKING([whether asm supports numbered local labels])
2579         AC_TRY_COMPILE(
2580                        ,[
2581                        __asm__ __volatile__ ("1:       nop\n"
2582                                "         bne-    1b")
2583                        ],[
2584                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2585                        AC_MSG_RESULT([yes])
2586                        ],[
2587                        AC_MSG_RESULT([no])
2588                        ])
2589         ;;
2590       ia64)
2591         AC_MSG_RESULT([ia64])
2592         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2593                            [ia64 atomic implementation])
2594         glib_memory_barrier_needed=yes
2595         ;;
2596       s390|s390x)
2597         AC_MSG_RESULT([s390])
2598         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2599                            [s390 atomic implementation])
2600         glib_memory_barrier_needed=no
2601         ;;
2602       arm*)
2603         AC_MSG_RESULT([arm])
2604         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2605                            [arm atomic implementation])
2606         glib_memory_barrier_needed=no
2607         ;;
2608       crisv32*|etraxfs*)
2609         AC_MSG_RESULT([crisv32])
2610         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2611                            [crisv32 atomic implementation])
2612         glib_memory_barrier_needed=no
2613         ;;
2614       cris*|etrax*)
2615         AC_MSG_RESULT([cris])
2616         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2617                            [cris atomic implementation])
2618         glib_memory_barrier_needed=no
2619         ;;
2620       *)
2621         AC_MSG_RESULT([none])
2622         glib_memory_barrier_needed=yes
2623         ;;
2624     esac
2625
2626 glib_cv_gcc_has_builtin_atomic_operations=no
2627 if test x"$GCC" = xyes; then
2628   AC_MSG_CHECKING([whether GCC supports built-in atomic intrinsics])
2629   AC_TRY_LINK([],
2630               [int i;
2631                __sync_synchronize ();
2632                __sync_bool_compare_and_swap (&i, 0, 1);
2633                __sync_fetch_and_add (&i, 1);
2634               ],
2635               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2636               [glib_cv_gcc_has_builtin_atomic_operations=no])
2637
2638   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2639 fi
2640 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2641                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2642
2643 AC_MSG_CHECKING([for Win32 atomic intrinsics])
2644 glib_cv_has_win32_atomic_operations=no
2645 AC_TRY_LINK([],
2646         [int i; _InterlockedExchangeAdd (&i, 0);],
2647         [glib_cv_has_win32_atomic_operations=yes],
2648         [glib_cv_has_win32_atomic_operations=no])
2649 AC_MSG_RESULT($glib_cv_has_win32_atomic_operations)
2650 if test "x$glib_cv_has_win32_atomic_operations" = xyes; then
2651         AC_DEFINE(HAVE_WIN32_BUILTINS_FOR_ATOMIC_OPERATIONS,1,[Have Win32 atomic intrinsics])
2652 fi
2653
2654 dnl ************************
2655 dnl ** Check for futex(2) **
2656 dnl ************************
2657 AC_CACHE_CHECK(for futex(2) system call,
2658     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2659 #include <linux/futex.h>
2660 #include <sys/syscall.h>
2661 #include <unistd.h>
2662 ],[
2663 int
2664 main (void)
2665 {
2666   /* it is not like this actually runs or anything... */
2667   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2668   return 0;
2669 }
2670 ])],glib_cv_futex=yes,glib_cv_futex=no))
2671 if test x"$glib_cv_futex" = xyes; then
2672   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2673 fi
2674
2675 AC_CACHE_CHECK(for eventfd(2) system call,
2676     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2677 #include <sys/eventfd.h>
2678 #include <unistd.h>
2679 ],[
2680 int
2681 main (void)
2682 {
2683   eventfd (0, EFD_CLOEXEC);
2684   return 0;
2685 }
2686 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2687 if test x"$glib_cv_eventfd" = x"yes"; then
2688   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2689 fi
2690 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2691
2692 dnl ****************************************
2693 dnl *** GLib POLL* compatibility defines ***
2694 dnl ****************************************
2695
2696 glib_poll_includes=["
2697 #include <sys/types.h>
2698 #include <sys/poll.h>
2699 "]
2700
2701 if test $ac_cv_header_sys_types_h = yes &&
2702    test $ac_cv_header_sys_poll_h = yes ; then
2703   glib_failed=false
2704   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2705   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2706   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2707   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2708   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2709   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2710   if $glib_failed ; then
2711     AC_MSG_ERROR([Could not determine values for POLL* constants])
2712   fi
2713 else
2714   glib_cv_value_POLLIN=1
2715   glib_cv_value_POLLOUT=4
2716   glib_cv_value_POLLPRI=2
2717   glib_cv_value_POLLERR=8
2718   glib_cv_value_POLLHUP=16
2719   glib_cv_value_POLLNVAL=32
2720 fi
2721
2722 AC_MSG_CHECKING([for broken poll])
2723 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2724         #include <stdlib.h>
2725         #include <fcntl.h>
2726         #include <poll.h>
2727         #ifdef HAVE_SYS_POLL_H
2728         #include <sys/poll.h>
2729         #endif
2730         int main(void) {
2731           struct pollfd fds[1];
2732           int fd;
2733           fd = open("/dev/null", 1);
2734           fds[0].fd = fd;
2735           fds[0].events = POLLIN;
2736           fds[0].revents = 0;
2737           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2738                 exit(1);  /* Does not work for devices -- fail */
2739           }
2740           exit(0);
2741         }]])],
2742   [broken_poll=no],
2743   [broken_poll=yes
2744    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2745   [broken_poll="no (cross compiling)"])
2746 AC_MSG_RESULT($broken_poll)
2747
2748 dnl *********************
2749 dnl *** GRegex checks ***
2750 dnl *********************
2751 PCRE_REQUIRED_VERSION=8.11
2752
2753 # Check if we should compile GRegex
2754 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2755               [disable the compilation of GRegex]),
2756 [case "${enableval}" in
2757   yes) enable_regex=true ;;
2758   no)  enable_regex=false ;;
2759   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2760 esac],
2761 [enable_regex=true])
2762
2763 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2764
2765 if test x$enable_regex = xtrue; then
2766   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2767   # Check if we should use the internal or the system-supplied pcre
2768   AC_ARG_WITH(pcre,
2769              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2770                              [specify whether to use the internal or the
2771                               system-supplied PCRE library])])
2772
2773   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2774
2775   if test "x$with_pcre" = xsystem; then
2776     PKG_CHECK_MODULES(PCRE,
2777                       libpcre >= $PCRE_REQUIRED_VERSION)
2778     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2779                    glib_save_CFLAGS="$CFLAGS"
2780                    glib_save_LIBS="$LIBS"
2781                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2782                    AC_TRY_RUN([#include <pcre.h>
2783                                int main () {
2784                                  int support;
2785                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2786                                  if (!support)
2787                                    return 1;
2788                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2789                                  if (!support)
2790                                    return 1;
2791                                  return 0;
2792                                }],
2793                    glib_cv_pcre_has_unicode=yes,
2794                    glib_cv_pcre_has_unicode=no,
2795                    glib_cv_pcre_has_unicode=yes)
2796                    CFLAGS="$glib_save_CFLAGS"
2797                    LIBS="$glib_save_LIBS"
2798         ])
2799     if test "$glib_cv_pcre_has_unicode" = "no"; then
2800       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2801     fi
2802     AC_SUBST(PCRE_CFLAGS)
2803     AC_SUBST(PCRE_LIBS)
2804     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2805     PCRE_REQUIRES=libpcre
2806     AC_SUBST(PCRE_REQUIRES)
2807   else
2808     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2809     if test x"$GCC" = xyes; then
2810       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2811       save_CFLAGS="$CFLAGS"
2812       CFLAGS="$CFLAGS -Wno-pointer-sign"
2813       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2814                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2815       CFLAGS="$save_CFLAGS"
2816     fi
2817   fi
2818   AC_SUBST(PCRE_WARN_CFLAGS)
2819 else
2820   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2821 fi
2822
2823 dnl **********************
2824 dnl *** Win32 API libs ***
2825 dnl **********************
2826
2827 case $host in
2828   *-*-cygwin*)
2829         G_LIBS_EXTRA="-luser32 -lkernel32"
2830     ;;
2831   *-*-mingw*)
2832         G_LIBS_EXTRA="-lws2_32 -lole32"
2833     ;;
2834   *)
2835         G_LIBS_EXTRA=""
2836     ;;
2837 esac
2838 AC_SUBST(G_LIBS_EXTRA)
2839
2840 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2841 dnl since we need it for g_iconv()
2842
2843 AC_MSG_CHECKING([for EILSEQ])
2844 AC_TRY_COMPILE([
2845 #include <errno.h>
2846 ],
2847 [
2848 int error = EILSEQ;
2849 ], have_eilseq=yes, have_eilseq=no);
2850 AC_MSG_RESULT($have_eilseq)
2851
2852 dnl ******************************************************************
2853 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2854 dnl *** glib-compile-schemas in PATH                               ***
2855 dnl ******************************************************************
2856
2857 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2858
2859 if test $cross_compiling = yes; then
2860   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2861   if test x$GLIB_GENMARSHAL = xno; then
2862     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2863   fi
2864
2865   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2866   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2867     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2868   fi
2869 fi
2870
2871 dnl **************************
2872 dnl *** Checks for gtk-doc ***
2873 dnl **************************
2874
2875 GTK_DOC_CHECK([1.15])
2876
2877 AC_ARG_ENABLE(man,
2878               [AC_HELP_STRING([--enable-man],
2879                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2880               enable_man=no)
2881
2882 if test "${enable_man}" != no; then
2883 dnl
2884 dnl Check for xsltproc
2885 dnl
2886 AC_PATH_PROG([XSLTPROC], [xsltproc])
2887   if test -z "$XSLTPROC"; then
2888     enable_man=no
2889   fi
2890
2891   dnl check for DocBook DTD and stylesheets in the local catalog.
2892   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2893      [DocBook XML DTD V4.1.2],,enable_man=no)
2894   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2895      [DocBook XSL Stylesheets],,enable_man=no)
2896 fi
2897
2898 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2899
2900 dnl
2901 dnl Tracing
2902 dnl
2903
2904 AC_ARG_ENABLE([dtrace],
2905              [AS_HELP_STRING([--enable-dtrace],
2906                               [Enable inclusion of dtrace trace support])])
2907 have_dtrace=no
2908 AC_MSG_CHECKING([whether to include dtrace tracing support])
2909 if test "x$enable_dtrace" != xno; then
2910   if test x$glib_have_carbon = xyes; then
2911     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2912   else
2913     AC_MSG_RESULT([yes])
2914     AC_CHECK_PROGS(DTRACE, dtrace)
2915     if test -z "$DTRACE"; then
2916       if test "x$enable_dtrace" = xyes; then
2917         AC_MSG_ERROR([dtrace not found])
2918       fi
2919     else
2920       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2921                       [if test "x$enable_dtrace" = xyes; then
2922                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2923                        fi])
2924     fi
2925   fi
2926 else
2927   AC_MSG_RESULT([no])
2928 fi
2929 if test "x$have_dtrace" = xyes; then
2930   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2931 fi
2932 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2933
2934 AC_MSG_CHECKING([whether to include systemtap tracing support])
2935 AC_ARG_ENABLE([systemtap],
2936              [AS_HELP_STRING([--enable-systemtap],
2937                               [Enable inclusion of systemtap trace support])])
2938 have_systemtap=no
2939 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2940   have_systemtap=yes
2941 fi
2942 AC_MSG_RESULT(${have_systemtap})
2943
2944 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2945
2946 AC_ARG_WITH([tapset-install-dir],
2947             [AS_HELP_STRING([--with-tapset-install-dir],
2948             [The absolute path where the systemtap tapsets will be installed])],
2949             [if test "x${withval}" = x; then
2950                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2951              else
2952                ABS_TAPSET_DIR="${withval}"
2953               fi],
2954             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2955 AC_SUBST(ABS_TAPSET_DIR)
2956
2957 dnl ************************************
2958 dnl *** Enable lcov coverage reports ***
2959 dnl ************************************
2960
2961 AC_ARG_ENABLE(gcov,
2962   AS_HELP_STRING([--enable-gcov],
2963                  [Enable gcov]),
2964   [use_gcov=$enableval], [use_gcov=no])
2965
2966 if test "x$use_gcov" = "xyes"; then
2967   dnl we need gcc:
2968   if test "$GCC" != "yes"; then
2969     AC_MSG_ERROR([GCC is required for --enable-gcov])
2970   fi
2971
2972   dnl Check if ccache is being used
2973   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2974   case `$SHTOOL path $CC` in
2975     *ccache*[)] gcc_ccache=yes;;
2976     *[)] gcc_ccache=no;;
2977   esac
2978
2979   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2980     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2981   fi
2982
2983   ltp_version_list="1.6 1.7 1.8 1.9"
2984   AC_CHECK_PROG(LTP, lcov, lcov)
2985   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2986
2987   if test "$LTP"; then
2988     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2989       glib_cv_ltp_version=invalid
2990       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2991       for ltp_check_version in $ltp_version_list; do
2992         if test "$ltp_version" = "$ltp_check_version"; then
2993           glib_cv_ltp_version="$ltp_check_version (ok)"
2994         fi
2995       done
2996     ])
2997   else
2998     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2999     AC_MSG_ERROR([$ltp_msg])
3000   fi
3001
3002   case $glib_cv_ltp_version in
3003     ""|invalid[)]
3004       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
3005       AC_MSG_ERROR([$ltp_msg])
3006       LTP="exit 0;"
3007       ;;
3008   esac
3009
3010   if test -z "$LTP_GENHTML"; then
3011     AC_MSG_ERROR([Could not find genhtml from the LTP package])
3012   fi
3013
3014   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
3015
3016   dnl Remove all optimization flags from CFLAGS
3017   changequote({,})
3018   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
3019   changequote([,])
3020
3021   dnl Add the special gcc flags
3022   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
3023   LDFLAGS="$LDFLAGS -lgcov"
3024 fi
3025
3026 dnl ******************************
3027 dnl *** output the whole stuff ***
3028 dnl ******************************
3029
3030 dnl this section will only be run if config.status is invoked with no
3031 dnl arguments, or with "glib/glibconfig.h" as an argument.
3032 AC_CONFIG_COMMANDS([glib/glibconfig.h],
3033 [
3034         outfile=glib/glibconfig.h-tmp
3035         cat > $outfile <<\_______EOF
3036 /* glibconfig.h
3037  *
3038  * This is a generated file.  Please modify 'configure.ac'
3039  */
3040
3041 #ifndef __G_LIBCONFIG_H__
3042 #define __G_LIBCONFIG_H__
3043
3044 #include <glib/gmacros.h>
3045
3046 _______EOF
3047
3048         if test x$glib_limits_h = xyes; then
3049           echo '#include <limits.h>' >> $outfile
3050         fi
3051         if test x$glib_float_h = xyes; then
3052           echo '#include <float.h>' >> $outfile
3053         fi
3054         if test x$glib_values_h = xyes; then
3055           echo '#include <values.h>' >> $outfile
3056         fi
3057         if test "$glib_header_alloca_h" = "yes"; then
3058           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
3059         fi
3060         if test x$glib_sys_poll_h = xyes; then
3061           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
3062         fi
3063         if test x$glib_included_printf != xyes; then
3064           echo "
3065 /* Specifies that GLib's g_print*() functions wrap the
3066  * system printf functions.  This is useful to know, for example,
3067  * when using glibc's register_printf_function().
3068  */" >> $outfile
3069           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
3070         fi
3071
3072         cat >> $outfile <<_______EOF
3073
3074 G_BEGIN_DECLS
3075
3076 #define G_MINFLOAT      $glib_mf
3077 #define G_MAXFLOAT      $glib_Mf
3078 #define G_MINDOUBLE     $glib_md
3079 #define G_MAXDOUBLE     $glib_Md
3080 #define G_MINSHORT      $glib_ms
3081 #define G_MAXSHORT      $glib_Ms
3082 #define G_MAXUSHORT     $glib_Mus
3083 #define G_MININT        $glib_mi
3084 #define G_MAXINT        $glib_Mi
3085 #define G_MAXUINT       $glib_Mui
3086 #define G_MINLONG       $glib_ml
3087 #define G_MAXLONG       $glib_Ml
3088 #define G_MAXULONG      $glib_Mul
3089
3090 _______EOF
3091
3092
3093         ### this should always be true in a modern C/C++ compiler
3094         cat >>$outfile <<_______EOF
3095 typedef signed char gint8;
3096 typedef unsigned char guint8;
3097 _______EOF
3098
3099
3100         if test -n "$gint16"; then
3101           cat >>$outfile <<_______EOF
3102 typedef signed $gint16 gint16;
3103 typedef unsigned $gint16 guint16;
3104 #define G_GINT16_MODIFIER $gint16_modifier
3105 #define G_GINT16_FORMAT $gint16_format
3106 #define G_GUINT16_FORMAT $guint16_format
3107 _______EOF
3108         fi
3109
3110
3111         if test -n "$gint32"; then
3112           cat >>$outfile <<_______EOF
3113 typedef signed $gint32 gint32;
3114 typedef unsigned $gint32 guint32;
3115 #define G_GINT32_MODIFIER $gint32_modifier
3116 #define G_GINT32_FORMAT $gint32_format
3117 #define G_GUINT32_FORMAT $guint32_format
3118 _______EOF
3119         fi
3120
3121         cat >>$outfile <<_______EOF
3122 #define G_HAVE_GINT64 1          /* deprecated, always true */
3123
3124 ${glib_extension}typedef signed $gint64 gint64;
3125 ${glib_extension}typedef unsigned $gint64 guint64;
3126
3127 #define G_GINT64_CONSTANT(val)  $gint64_constant
3128 #define G_GUINT64_CONSTANT(val) $guint64_constant
3129 _______EOF
3130
3131         if test x$gint64_format != x ; then
3132           cat >>$outfile <<_______EOF
3133 #define G_GINT64_MODIFIER $gint64_modifier
3134 #define G_GINT64_FORMAT $gint64_format
3135 #define G_GUINT64_FORMAT $guint64_format
3136 _______EOF
3137         else
3138           cat >>$outfile <<_______EOF
3139 #undef G_GINT64_MODIFIER
3140 #undef G_GINT64_FORMAT
3141 #undef G_GUINT64_FORMAT
3142 _______EOF
3143         fi
3144
3145         cat >>$outfile <<_______EOF
3146
3147 #define GLIB_SIZEOF_VOID_P $glib_void_p
3148 #define GLIB_SIZEOF_LONG   $glib_long
3149 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3150
3151 _______EOF
3152
3153         cat >>$outfile <<_______EOF
3154 typedef signed $glib_size_type_define gssize;
3155 typedef unsigned $glib_size_type_define gsize;
3156 #define G_GSIZE_MODIFIER $gsize_modifier
3157 #define G_GSSIZE_FORMAT $gssize_format
3158 #define G_GSIZE_FORMAT $gsize_format
3159
3160 #define G_MAXSIZE       G_MAXU$glib_msize_type
3161 #define G_MINSSIZE      G_MIN$glib_msize_type
3162 #define G_MAXSSIZE      G_MAX$glib_msize_type
3163
3164 typedef gint64 goffset;
3165 #define G_MINOFFSET     G_MININT64
3166 #define G_MAXOFFSET     G_MAXINT64
3167
3168 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3169 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3170 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3171
3172 _______EOF
3173
3174         if test -z "$glib_unknown_void_p"; then
3175           cat >>$outfile <<_______EOF
3176
3177 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3178 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3179
3180 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3181 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3182
3183 typedef signed $glib_intptr_type_define gintptr;
3184 typedef unsigned $glib_intptr_type_define guintptr;
3185
3186 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3187 #define G_GINTPTR_FORMAT        $gintptr_format
3188 #define G_GUINTPTR_FORMAT       $guintptr_format
3189 _______EOF
3190         else
3191           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3192         fi
3193
3194
3195
3196         cat >>$outfile <<_______EOF
3197 $glib_atexit
3198 $glib_memmove
3199 $glib_defines
3200 $glib_os
3201 $glib_static_compilation
3202
3203 $glib_vacopy
3204
3205 #ifdef  __cplusplus
3206 #define G_HAVE_INLINE   1
3207 #else   /* !__cplusplus */
3208 $glib_inline
3209 #endif  /* !__cplusplus */
3210
3211 #ifdef  __cplusplus
3212 #define G_CAN_INLINE    1
3213 _______EOF
3214
3215         if test x$g_can_inline = xyes ; then
3216                 cat >>$outfile <<_______EOF
3217 #else   /* !__cplusplus */
3218 #define G_CAN_INLINE    1
3219 _______EOF
3220         fi
3221
3222         cat >>$outfile <<_______EOF
3223 #endif
3224
3225 _______EOF
3226
3227         if test x$g_have_iso_c_varargs = xyes ; then
3228                 cat >>$outfile <<_______EOF
3229 #ifndef __cplusplus
3230 # define G_HAVE_ISO_VARARGS 1
3231 #endif
3232 _______EOF
3233         fi
3234         if test x$g_have_iso_cxx_varargs = xyes ; then
3235                 cat >>$outfile <<_______EOF
3236 #ifdef __cplusplus
3237 # define G_HAVE_ISO_VARARGS 1
3238 #endif
3239 _______EOF
3240         fi
3241         if test x$g_have_gnuc_varargs = xyes ; then
3242                 cat >>$outfile <<_______EOF
3243
3244 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3245  * is passed ISO vararg support is turned off, and there is no work
3246  * around to turn it on, so we unconditionally turn it off.
3247  */
3248 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3249 #  undef G_HAVE_ISO_VARARGS
3250 #endif
3251
3252 #define G_HAVE_GNUC_VARARGS 1
3253 _______EOF
3254         fi
3255
3256         case x$g_stack_grows in
3257         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3258         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3259         esac
3260
3261
3262         echo >>$outfile
3263         if test x$g_have_eilseq = xno; then
3264                 cat >>$outfile <<_______EOF
3265 #ifndef EILSEQ
3266 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3267  * The correspondence between this and the corresponding definition
3268  * in libiconv is essential.
3269  */
3270 #  define EILSEQ ENOENT
3271 #endif
3272 _______EOF
3273
3274         fi
3275
3276         if test x$g_have_gnuc_visibility = xyes; then
3277                 cat >>$outfile <<_______EOF
3278 #define G_HAVE_GNUC_VISIBILITY 1
3279 _______EOF
3280         fi
3281                 cat >>$outfile <<_______EOF
3282 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3283 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3284 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3285 #define G_GNUC_INTERNAL __hidden
3286 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3287 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3288 #else
3289 #define G_GNUC_INTERNAL
3290 #endif
3291 _______EOF
3292
3293
3294         echo >>$outfile
3295         if test x$g_mutex_has_default = xyes; then
3296                 cat >>$outfile <<_______EOF
3297 $g_enable_threads_def G_THREADS_ENABLED
3298 #define G_THREADS_IMPL_$g_threads_impl_def
3299 typedef struct _GStaticMutex GStaticMutex;
3300 struct _GStaticMutex
3301 {
3302   struct _GMutex *runtime_mutex;
3303   union {
3304     char   pad[[$g_mutex_sizeof]];
3305     double dummy_double;
3306     void  *dummy_pointer;
3307     long   dummy_long;
3308   } static_mutex;
3309 };
3310 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3311 #define g_static_mutex_get_mutex(mutex) \\
3312   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3313    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3314 _______EOF
3315         else
3316                 cat >>$outfile <<_______EOF
3317 $g_enable_threads_def G_THREADS_ENABLED
3318 #define G_THREADS_IMPL_$g_threads_impl_def
3319 typedef struct _GMutex* GStaticMutex;
3320 #define G_STATIC_MUTEX_INIT NULL
3321 #define g_static_mutex_get_mutex(mutex) \\
3322   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3323 _______EOF
3324         fi
3325
3326         cat >>$outfile <<_______EOF
3327 /* This represents a system thread as used by the implementation. An
3328  * alien implementaion, as loaded by g_thread_init can only count on
3329  * "sizeof (gpointer)" bytes to store their info. We however need more
3330  * for some of our native implementations. */
3331 typedef union _GSystemThread GSystemThread;
3332 union _GSystemThread
3333 {
3334   char   data[[$g_system_thread_sizeof]];
3335   double dummy_double;
3336   void  *dummy_pointer;
3337   long   dummy_long;
3338 };
3339 _______EOF
3340         if test x"$g_memory_barrier_needed" != xno; then
3341           echo >>$outfile
3342           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3343         fi
3344         if test x"$g_gcc_atomic_ops" != xno; then
3345           echo >>$outfile
3346           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3347         fi
3348         echo >>$outfile
3349         g_bit_sizes="16 32 64"
3350         for bits in $g_bit_sizes; do
3351           cat >>$outfile <<_______EOF
3352 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3353 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3354 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3355 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3356 _______EOF
3357         done
3358
3359         cat >>$outfile <<_______EOF
3360 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3361 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3362 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3363 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3364 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3365 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3366 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3367 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3368 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3369 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3370 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3371 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3372 #define G_BYTE_ORDER $g_byte_order
3373
3374 #define GLIB_SYSDEF_POLLIN =$g_pollin
3375 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3376 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3377 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3378 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3379 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3380
3381 #define G_MODULE_SUFFIX "$g_module_suffix"
3382
3383 /* A GPid is an abstraction for a process "handle". It is *not* an
3384  * abstraction for a process identifier in general. GPid is used in
3385  * GLib only for descendant processes spawned with the g_spawn*
3386  * functions. On POSIX there is no "process handle" concept as such,
3387  * but on Windows a GPid is a handle to a process, a kind of pointer,
3388  * not a process identifier.
3389  */
3390 typedef $g_pid_type GPid;
3391
3392 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3393 #define GLIB_SYSDEF_AF_INET $g_af_inet
3394 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3395
3396 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3397 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3398 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3399
3400 G_END_DECLS
3401
3402 #endif /* GLIBCONFIG_H */
3403 _______EOF
3404
3405
3406         if cmp -s $outfile glib/glibconfig.h; then
3407           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3408           rm -f $outfile
3409         else
3410           mv $outfile glib/glibconfig.h
3411         fi
3412 ],[
3413
3414 # Note that if two cases are the same, case goes with the first one.
3415 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3416 # on variable expansion in case labels.  Look at the generated config.status
3417 # for a hint.
3418
3419 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3420   glib_header_alloca_h="$ac_cv_working_alloca_h"
3421 else
3422   glib_header_alloca_h="$ac_cv_header_alloca_h"
3423 fi
3424
3425 case xyes in
3426 x$ac_cv_header_float_h)
3427   glib_float_h=yes
3428   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3429   glib_md=DBL_MIN glib_Md=DBL_MAX
3430   ;;
3431 x$ac_cv_header_values_h)
3432   glib_values_h=yes
3433   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3434   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3435   ;;
3436 esac
3437
3438 case xyes in
3439 x$ac_cv_header_limits_h)
3440   glib_limits_h=yes
3441   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3442   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3443   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3444   ;;
3445 x$ac_cv_header_values_h)
3446   glib_values_h=yes
3447   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3448   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3449   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3450   ;;
3451 esac
3452
3453 if test x$ac_cv_header_sys_poll_h = xyes ; then
3454   glib_sys_poll_h=yes
3455 fi
3456
3457 if test x$enable_included_printf = xyes ; then
3458   glib_included_printf=yes
3459 fi
3460
3461 case 2 in
3462 $ac_cv_sizeof_short)
3463   gint16=short
3464   gint16_modifier='"h"'
3465   gint16_format='"hi"'
3466   guint16_format='"hu"'
3467   ;;
3468 $ac_cv_sizeof_int)
3469   gint16=int
3470   gint16_modifier='""'
3471   gint16_format='"i"'
3472   guint16_format='"u"'
3473   ;;
3474 esac
3475 case 4 in
3476 $ac_cv_sizeof_short)
3477   gint32=short
3478   gint32_modifier='"h"'
3479   gint32_format='"hi"'
3480   guint32_format='"hu"'
3481   ;;
3482 $ac_cv_sizeof_int)
3483   gint32=int
3484   gint32_modifier='""'
3485   gint32_format='"i"'
3486   guint32_format='"u"'
3487   ;;
3488 $ac_cv_sizeof_long)
3489   gint32=long
3490   gint32_modifier='"l"'
3491   gint32_format='"li"'
3492   guint32_format='"lu"'
3493   ;;
3494 esac
3495 case 8 in
3496 $ac_cv_sizeof_int)
3497   gint64=int
3498   gint64_modifier='""'
3499   gint64_format='"i"'
3500   guint64_format='"u"'
3501   glib_extension=
3502   gint64_constant='(val)'
3503   guint64_constant='(val)'
3504   ;;
3505 $ac_cv_sizeof_long)
3506   gint64=long
3507   gint64_modifier='"l"'
3508   gint64_format='"li"'
3509   guint64_format='"lu"'
3510   glib_extension=
3511   gint64_constant='(val##L)'
3512   guint64_constant='(val##UL)'
3513   ;;
3514 $ac_cv_sizeof_long_long)
3515   gint64='long long'
3516   if test -n "$glib_cv_long_long_format"; then
3517     gint64_modifier='"'$glib_cv_long_long_format'"'
3518     gint64_format='"'$glib_cv_long_long_format'i"'
3519     guint64_format='"'$glib_cv_long_long_format'u"'
3520   fi
3521   glib_extension='G_GNUC_EXTENSION '
3522   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3523   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3524   ;;
3525 $ac_cv_sizeof___int64)
3526   gint64='__int64'
3527   if test -n "$glib_cv_long_long_format"; then
3528     gint64_modifier='"'$glib_cv_long_long_format'"'
3529     gint64_format='"'$glib_cv_long_long_format'i"'
3530     guint64_format='"'$glib_cv_long_long_format'u"'
3531   fi
3532   glib_extension=
3533   gint64_constant='(val##i64)'
3534   guint64_constant='(val##ui64)'
3535   ;;
3536 esac
3537 glib_size_t=$ac_cv_sizeof_size_t
3538 glib_size_type_define="$glib_size_type"
3539 glib_void_p=$ac_cv_sizeof_void_p
3540 glib_long=$ac_cv_sizeof_long
3541
3542 case "$glib_size_type" in
3543 short)
3544   gsize_modifier='"h"'
3545   gsize_format='"hu"'
3546   gssize_format='"hi"'
3547   glib_msize_type='SHRT'
3548   ;;
3549 int)
3550   gsize_modifier='""'
3551   gsize_format='"u"'
3552   gssize_format='"i"'
3553   glib_msize_type='INT'
3554   ;;
3555 long)
3556   gsize_modifier='"l"'
3557   gsize_format='"lu"'
3558   gssize_format='"li"'
3559   glib_msize_type='LONG'
3560   ;;
3561 "long long"|__int64)
3562   gsize_modifier='"I64"'
3563   gsize_format='"I64u"'
3564   gssize_format='"I64i"'
3565   glib_msize_type='INT64'
3566   ;;
3567 esac
3568
3569 gintbits=`expr $ac_cv_sizeof_int \* 8`
3570 glongbits=`expr $ac_cv_sizeof_long \* 8`
3571 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3572
3573 case $ac_cv_sizeof_void_p in
3574 $ac_cv_sizeof_int)
3575   glib_intptr_type_define=int
3576   gintptr_modifier='""'
3577   gintptr_format='"i"'
3578   guintptr_format='"u"'
3579   glib_gpi_cast=''
3580   glib_gpui_cast=''
3581   ;;
3582 $ac_cv_sizeof_long)
3583   glib_intptr_type_define=long
3584   gintptr_modifier='"l"'
3585   gintptr_format='"li"'
3586   guintptr_format='"lu"'
3587   glib_gpi_cast='(glong)'
3588   glib_gpui_cast='(gulong)'
3589   ;;
3590 $ac_cv_sizeof_long_long)
3591   glib_intptr_type_define='long long'
3592   gintptr_modifier='"I64"'
3593   gintptr_format='"I64i"'
3594   guintptr_format='"I64u"'
3595   glib_gpi_cast='(gint64)'
3596   glib_gpui_cast='(guint64)'
3597   ;;
3598 $ac_cv_sizeof___int64)
3599   glib_intptr_type_define=__int64
3600   gintptr_modifier='"I64"'
3601   gintptr_format='"I64i"'
3602   guintptr_format='"I64u"'
3603   glib_gpi_cast='(gint64)'
3604   glib_gpui_cast='(guint64)'
3605   ;;
3606 *)
3607   glib_unknown_void_p=yes
3608   ;;
3609 esac
3610
3611
3612 case xyes in
3613 x$ac_cv_func_atexit)
3614   glib_atexit="
3615 #ifdef NeXT /* @#%@! NeXTStep */
3616 # define g_ATEXIT(proc) (!atexit (proc))
3617 #else
3618 # define g_ATEXIT(proc) (atexit (proc))
3619 #endif"
3620   ;;
3621 x$ac_cv_func_on_exit)
3622   glib_atexit="
3623 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3624   ;;
3625 esac
3626
3627 case xyes in
3628 x$ac_cv_func_memmove)
3629   glib_memmove='
3630 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3631   ;;
3632 x$glib_cv_working_bcopy)
3633   glib_memmove="
3634 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3635 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3636   ;;
3637 *)
3638   glib_memmove="
3639 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3640  * so we have to roll our own copy routine. */
3641 void g_memmove (void* dest, const void * src, unsigned long len);"
3642   ;;
3643 esac
3644
3645 glib_defines="
3646 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3647 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3648 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3649 "
3650
3651 case xyes in
3652 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3653 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3654 *)                      glib_vacopy=''
3655 esac
3656
3657 if test x$glib_cv_va_val_copy = xno; then
3658   glib_vacopy="\$glib_vacopy
3659 #define G_VA_COPY_AS_ARRAY 1"
3660 fi
3661
3662 if test x$glib_cv_hasinline = xyes; then
3663     glib_inline='#define G_HAVE_INLINE 1'
3664 fi
3665 if test x$glib_cv_has__inline = xyes; then
3666     glib_inline="\$glib_inline
3667 #define G_HAVE___INLINE 1"
3668 fi
3669 if test x$glib_cv_has__inline__ = xyes; then
3670     glib_inline="\$glib_inline
3671 #define G_HAVE___INLINE__ 1"
3672 fi
3673
3674 g_have_gnuc_varargs=$g_have_gnuc_varargs
3675 g_have_iso_c_varargs=$g_have_iso_c_varargs
3676 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3677
3678 g_can_inline=$g_can_inline
3679 g_have_gnuc_visibility=$g_have_gnuc_visibility
3680 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3681
3682 if test x$ac_cv_c_bigendian = xyes; then
3683   g_byte_order=G_BIG_ENDIAN
3684   g_bs_native=BE
3685   g_bs_alien=LE
3686 else
3687   g_byte_order=G_LITTLE_ENDIAN
3688   g_bs_native=LE
3689   g_bs_alien=BE
3690 fi
3691
3692 g_pollin=$glib_cv_value_POLLIN
3693 g_pollout=$glib_cv_value_POLLOUT
3694 g_pollpri=$glib_cv_value_POLLPRI
3695 g_pollhup=$glib_cv_value_POLLHUP
3696 g_pollerr=$glib_cv_value_POLLERR
3697 g_pollnval=$glib_cv_value_POLLNVAL
3698
3699 g_af_unix=$glib_cv_value_AF_UNIX
3700 g_af_inet=$glib_cv_value_AF_INET
3701 g_af_inet6=$glib_cv_value_AF_INET6
3702
3703 g_msg_peek=$glib_cv_value_MSG_PEEK
3704 g_msg_oob=$glib_cv_value_MSG_OOB
3705 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3706
3707 g_stack_grows=$glib_cv_stack_grows
3708
3709 g_have_eilseq=$have_eilseq
3710
3711 case x$have_threads in
3712 xno)    g_enable_threads_def="#undef";;
3713 *)      g_enable_threads_def="#define";;
3714 esac
3715
3716 g_threads_impl_def=$g_threads_impl
3717
3718 g_mutex_has_default="$mutex_has_default"
3719 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3720 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3721 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3722
3723 g_memory_barrier_needed="$glib_memory_barrier_needed"
3724 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3725
3726 g_module_suffix="$glib_gmodule_suffix"
3727
3728 g_pid_type="$glib_pid_type"
3729 case $host in
3730   *-*-beos*)
3731     glib_os="#define G_OS_BEOS"
3732     ;;
3733   *-*-cygwin*)
3734     glib_os="#define G_OS_UNIX
3735 #define G_PLATFORM_WIN32
3736 #define G_WITH_CYGWIN"
3737     ;;
3738   *-*-mingw*)
3739     glib_os="#define G_OS_WIN32
3740 #define G_PLATFORM_WIN32"
3741     ;;
3742   *)
3743     glib_os="#define G_OS_UNIX"
3744     ;;
3745 esac
3746 glib_static_compilation=""
3747 if test x$glib_win32_static_compilation = xyes; then
3748   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3749 #define GOBJECT_STATIC_COMPILATION 1"
3750 fi
3751 ])
3752
3753 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3754 #
3755 # 1.2.14 required for dbus_message_set_serial
3756 PKG_CHECK_MODULES(DBUS1,
3757                   dbus-1 >= 1.2.14,
3758                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3759                   have_dbus1=no)
3760 AC_SUBST(DBUS1_CFLAGS)
3761 AC_SUBST(DBUS1_LIBS)
3762 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3763
3764 dnl
3765 dnl Check for -Bsymbolic-functions linker flag used to avoid
3766 dnl intra-library PLT jumps, if available.
3767 dnl
3768
3769 AC_ARG_ENABLE(Bsymbolic,
3770               [AC_HELP_STRING([--disable-Bsymbolic],
3771                               [avoid linking with -Bsymbolic])],,
3772               [SAVED_LDFLAGS="${LDFLAGS}"
3773                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3774                LDFLAGS=-Wl,-Bsymbolic-functions
3775                AC_TRY_LINK([], [int main (void) { return 0; }],
3776                            AC_MSG_RESULT(yes)
3777                            enable_Bsymbolic=yes,
3778                            AC_MSG_RESULT(no)
3779                            enable_Bsymbolic=no)
3780                LDFLAGS="${SAVED_LDFLAGS}"])
3781
3782 if test "x${enable_Bsymbolic}" == "xyes"; then
3783   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3784 fi
3785
3786 AC_SUBST(GLIB_LINK_FLAGS)
3787
3788 #
3789 # Define variables corresponding to the correct include paths to use for
3790 # in-tree building.
3791 #
3792
3793 # for config.h:
3794 config_h_INCLUDES='-I$(top_builddir)'
3795 AC_SUBST(config_h_INCLUDES)
3796
3797 # glib:
3798 #   config.h
3799 #   $(top_builddir)/glib: for glibconfig.h
3800 #   $(top_srcdir)/glib:   for glib.h
3801 #   $(top_srcdir):        for everything
3802 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3803 AC_SUBST(glib_INCLUDES)
3804
3805 # gthread:
3806 #   same as glib
3807 gthread_INCLUDES='$(glib_INCLUDES)'
3808 AC_SUBST(gthread_INCLUDES)
3809
3810 # gobject:
3811 #   same as gthread
3812 gobject_INCLUDES='$(gthread_INCLUDES)'
3813 AC_SUBST(gobject_INCLUDES)
3814
3815 # gmodule:
3816 #   glib includes
3817 #   $(top_srcdir)/gmodule: for gmodule.h
3818 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3819 AC_SUBST(gmodule_INCLUDES)
3820
3821 # gio:
3822 #   same as gmodule
3823 gio_INCLUDES='$(gmodule_INCLUDES)'
3824 AC_SUBST(gio_INCLUDES)
3825
3826
3827 AC_CONFIG_FILES([
3828 glib-2.0.pc
3829 glib-2.0-uninstalled.pc
3830 gmodule-2.0.pc
3831 gmodule-export-2.0.pc
3832 gmodule-no-export-2.0.pc
3833 gmodule-2.0-uninstalled.pc
3834 gmodule-no-export-2.0-uninstalled.pc
3835 gthread-2.0.pc
3836 gthread-2.0-uninstalled.pc
3837 gobject-2.0.pc
3838 gobject-2.0-uninstalled.pc
3839 gio-2.0.pc
3840 gio-unix-2.0.pc
3841 gio-windows-2.0.pc
3842 gio-2.0-uninstalled.pc
3843 gio-unix-2.0-uninstalled.pc
3844 glib-zip
3845 glib-gettextize
3846 Makefile
3847 build/Makefile
3848 build/win32/Makefile
3849 build/win32/dirent/Makefile
3850 build/win32/vs9/Makefile
3851 build/win32/vs10/Makefile
3852 glib/Makefile
3853 glib/glib.stp
3854 glib/libcharset/Makefile
3855 glib/gnulib/Makefile
3856 glib/pcre/Makefile
3857 glib/update-pcre/Makefile
3858 glib/tests/Makefile
3859 gmodule/Makefile
3860 gmodule/gmoduleconf.h
3861 gobject/Makefile
3862 gobject/gobject.stp
3863 gobject/glib-mkenums
3864 gobject/tests/Makefile
3865 gthread/Makefile
3866 gthread/tests/Makefile
3867 gio/Makefile
3868 gio/gdbus-2.0/codegen/Makefile
3869 gio/gdbus-2.0/codegen/config.py
3870 gio/xdgmime/Makefile
3871 gio/inotify/Makefile
3872 gio/libasyncns/Makefile
3873 gio/fen/Makefile
3874 gio/fam/Makefile
3875 gio/win32/Makefile
3876 gio/tests/Makefile
3877 gio/tests/gdbus-object-manager-example/Makefile
3878 po/Makefile.in
3879 docs/Makefile
3880 docs/reference/Makefile
3881 docs/reference/glib/Makefile
3882 docs/reference/glib/version.xml
3883 docs/reference/gobject/Makefile
3884 docs/reference/gobject/version.xml
3885 docs/reference/gio/Makefile
3886 docs/reference/gio/gdbus-object-manager-example/Makefile
3887 docs/reference/gio/version.xml
3888 tests/Makefile
3889 tests/gobject/Makefile
3890 tests/refcount/Makefile
3891 m4macros/Makefile
3892 ])
3893
3894 AC_CONFIG_COMMANDS([chmod-scripts],
3895 [chmod 0755 glib-zip
3896 chmod 0755 glib-gettextize
3897 chmod 0755 gobject/glib-mkenums])
3898
3899 # we want to invoke this macro solely so that the config.status script
3900 # and automake generated makefiles know about these generated files.
3901 # They are only needed to distcheck the package
3902 if false; then
3903   AC_CONFIG_FILES([
3904     INSTALL
3905     README
3906     config.h.win32
3907     glib/glibconfig.h.win32
3908     glib/makefile.msc
3909     glib/glib.rc
3910     gmodule/makefile.msc
3911     gmodule/gmodule.rc
3912     gobject/makefile.msc
3913     gobject/gobject.rc
3914     gthread/makefile.msc
3915     gthread/gthread.rc
3916     gio/gio.rc
3917     tests/makefile.msc
3918   ])
3919 fi
3920
3921 AC_OUTPUT