configure.ac

   1 AC_PREREQ(2.59)
   2 AC_INIT([EXIF library], [0.6.19.1], [libexif-devel@lists.sourceforge.net], [libexif])
   3 AC_CONFIG_SRCDIR([libexif/exif-data.h])
   4 AC_CONFIG_HEADERS([config.h])
   5 AC_CONFIG_MACRO_DIR([auto-m4])
   6 AM_INIT_AUTOMAKE([-Wall gnu 1.9 dist-bzip2 dist-zip check-news])
   7 AM_MAINTAINER_MODE
   8
   9 # Use the silent-rules feature when possible.
  10 m4_ifndef([AM_SILENT_RULES], [m4_define([AM_SILENT_RULES],[])])
  11 AM_SILENT_RULES([no])
  12
  13 if test ! -d "$srcdir/m4m"; then
  14 AC_MSG_ERROR([
  15 You are missing the m4m/ directory in your top
  16 $PACKAGE_TARNAME source directory.
  17
  18 You are probably using an ill-maintained CVS tree.
  19 Running
  20
  21     cd $srcdir
  22     cvs co m4m
  23
  24 and re-running autogen.sh might help.
  25 ])
  26 fi
  27
  28 GP_CHECK_SHELL_ENVIRONMENT
  29 GP_CONFIG_MSG([Build])
  30 GP_CONFIG_MSG([Source code location],[${srcdir}])
  31
  32 dnl ---------------------------------------------------------------------------
  33 dnl Advanced information about versioning:
  34 dnl   * "Writing shared libraries" by Mike Hearn
  35 dnl         http://plan99.net/~mike/writing-shared-libraries.html
  36 dnl   * libtool.info chapter "Versioning"
  37 dnl   * libtool.info chapter "Updating library version information"
  38 dnl ---------------------------------------------------------------------------
  39 dnl Versioning:
  40 dnl  - CURRENT (Major):  Increment if the interface has changes. AGE is always
  41 dnl                      *changed* at the same time.
  42 dnl  - AGE (Micro):      Increment if any interfaces have been added; set to 0
  43 dnl                      if any interfaces have been removed. Removal has
  44 dnl                      precedence over adding, so set to 0 if both happened.
  45 dnl                      It denotes upward compatibility.
  46 dnl  - REVISION (Minor): Increment any time the source changes; set to
  47 dnl                      0 if you incremented CURRENT.
  48 dnl
  49 dnl  To summarize. Any interface *change* increment CURRENT. If that interface
  50 dnl  change does not break upward compatibility (ie it is an addition),
  51 dnl  increment AGE, Otherwise AGE is reset to 0. If CURRENT has changed,
  52 dnl  REVISION is set to 0, otherwise REVISION is incremented.
  53 dnl ---------------------------------------------------------------------------
  54 dnl C:A:R
  55 dnl 12:0:1   0.6.13
  56 dnl 13:1:0   added EXIF_DATA_OPTION_DONT_CHANGE_MAKER_NOTE (for 0.6.14)
  57 dnl 14:2:0   added XP_ WinXP tags (for 0.6.15)
  58 dnl 14:2:1   0.6.17
  59 dnl 15:3:0   added exif_loader_get_buf (for 0.6.18)
  60 dnl 15:3:1   0.6.19
  61 LIBEXIF_CURRENT=15
  62 LIBEXIF_AGE=3
  63 LIBEXIF_REVISION=1
  64 AC_SUBST([LIBEXIF_AGE])
  65 AC_SUBST([LIBEXIF_REVISION])
  66 AC_SUBST([LIBEXIF_CURRENT])
  67 AC_SUBST([LIBEXIF_CURRENT_MIN],[`expr $LIBEXIF_CURRENT - $LIBEXIF_AGE`])
  68 LIBEXIF_VERSION_INFO="$LIBEXIF_CURRENT:$LIBEXIF_REVISION:$LIBEXIF_AGE"
  69 AC_SUBST([LIBEXIF_VERSION_INFO])
  70
  71 AC_PROG_CC
  72 AC_C_CONST
  73 AC_C_INLINE
  74 dnl FIXME: AC_LIBTOOL_WIN32_DLL
  75 AM_PROG_LIBTOOL
  76 AM_CPPFLAGS="$CPPFLAGS"
  77 GP_CONFIG_MSG([Compiler],[${CC}])
  78
  79
  80 dnl Create a stdint.h-like file containing size-specific integer definitions
  81 dnl that will always be available
  82 AX_NEED_STDINT_H([libexif/_stdint.h])
  83
  84
  85 dnl ------------------------------------------------------------------------
  86 dnl Whether we're supposed to ship binaries in the tarball
  87 dnl ------------------------------------------------------------------------
  88
  89 ship_binaries=false
  90 AC_ARG_ENABLE([ship-binaries],
  91 [AS_HELP_STRING([--enable-ship-binaries],
  92 [Whether to ship binaries in the tarball [default=no]])],[
  93         if test x$enableval = xyes; then
  94                 ship_binaries=true
  95         fi
  96 ])
  97 AM_CONDITIONAL([SHIP_BINARIES],[$ship_binaries])
  98 GP_CONFIG_MSG([Ship binaries in tarball],[$ship_binaries])
  99
 100
 101 dnl ---------------------------------------------------------------------------
 102 dnl Whether -lm is required for our math functions
 103 dnl ---------------------------------------------------------------------------
 104
 105 # we need sqrt and pow which may be in libm
 106 # We cannot use AC_CHECK_FUNC because if CFLAGS contains
 107 # -Wall -Werror here the check fails because
 108 # char *sqrt() conflicts with double sqrt(double xx)
 109
 110 # Start by assuming -lm is needed, because it's possible that the little
 111 # test program below will be optimized to in-line floating point code that
 112 # doesn't require -lm, whereas the library itself cannot be so optimized
 113 # (this actually seems to be the case on x86 with gcc 4.2). Assuming the
 114 # reverse means that -lm could be needed but wouldn't be detected below.
 115
 116 LIBS_orig="$LIBS"
 117 LIBS="$LIBS -lm"
 118 AC_MSG_CHECKING([for math functions in libm])
 119 AC_LINK_IFELSE([
 120         #include <math.h>
 121         int main() {
 122           double s = sqrt(0);
 123           double p = pow(s,s);
 124           return (int)p;
 125         }
 126 ], [AC_MSG_RESULT(yes)], [
 127         AC_MSG_RESULT(no)
 128         LIBS="$LIBS_orig"
 129         AC_MSG_CHECKING([for math functions without libm])
 130         AC_LINK_IFELSE([
 131                 #include <math.h>
 132                 int main() {
 133                   double s = sqrt(0);
 134                   double p = pow(s,s);
 135                   return (int)p;
 136                 }
 137         ], [
 138                 AC_MSG_RESULT(yes)
 139         ],[
 140                 AC_MSG_RESULT(no)
 141                 AC_MSG_ERROR([*** Could not find sqrt() & pow() functions])
 142         ])
 143 ])
 144
 145 # doc support
 146 GP_CHECK_DOC_DIR
 147 GP_CHECK_DOXYGEN
 148
 149 # Whether to enable the internal docs build.
 150 #
 151 # This takes quite some time due to the generation of lots of call
 152 # graphs, so it is disabled by default.
 153 set_enable_internal_docs=no
 154 AC_ARG_ENABLE([internal-docs], [dnl
 155 AS_HELP_STRING([--enable-internal-docs],
 156 [Build internal code docs if doxygen available])], [dnl
 157 dnl If either --enable-foo nor --disable-foo were given, execute this.
 158   if   test "x$enableval" = xno \
 159     || test "x$enableval" = xoff \
 160     || test "x$enableval" = xfalse;
 161   then
 162     set_enable_internal_docs=no
 163   elif test "x$enableval" = xyes \
 164     || test "x$enableval" = xon \
 165     || test "x$enableval" = xtrue
 166   then
 167     set_enable_internal_docs=yes
 168   fi
 169 ])
 170 AC_MSG_CHECKING([whether to create internal code docs])
 171 AC_MSG_RESULT([${set_enable_internal_docs}])
 172 AM_CONDITIONAL([ENABLE_INTERNAL_DOCS], [test "x${set_enable_internal_docs}" = "xyes"])
 173
 174
 175 # ---------------------------------------------------------------------------
 176 # i18n support
 177 # ---------------------------------------------------------------------------
 178 ALL_LINGUAS="be bs cs da de en_CA en_GB es fr it ja nl pl pt pt_BR ru sk sq sr sv tr vi zh_CN"
 179 AM_PO_SUBDIRS
 180 GP_GETTEXT_HACK([${PACKAGE}-${LIBEXIF_CURRENT_MIN}],
 181                 [Lutz Mueller and others])
 182 AM_GNU_GETTEXT_VERSION([0.14.1])
 183 AM_GNU_GETTEXT([external])
 184 AM_ICONV()
 185 GP_GETTEXT_FLAGS()
 186
 187
 188 dnl ---------------------------------------------------------------------------
 189 dnl Thread-safe functions
 190 dnl ---------------------------------------------------------------------------
 191 AC_CHECK_FUNCS(localtime_r)
 192
 193 dnl ---------------------------------------------------------------------------
 194 dnl Compiler/Linker Options and Warnings
 195 dnl ---------------------------------------------------------------------------
 196 AM_CPPFLAGS="$AM_CPPFLAGS -I\$(top_srcdir)"
 197 AM_CPPFLAGS="$AM_CPPFLAGS -I\$(top_builddir)"
 198 AM_LDFLAGS="$LDFLAGS"
 199 if test "x$GCC" = "xyes"; then
 200     AM_CFLAGS="$AM_CFLAGS -ansi -pedantic-error"
 201     AM_CXXFLAGS="$AM_CXXFLAGS -ansi -pedantic-error"
 202     AM_CPPFLAGS="$AM_CPPFLAGS -g -Wall -Wmissing-declarations -Wmissing-prototypes"
 203     AM_LDFLAGS="$AM_LDFLAGS -g -Wall"
 204 fi
 205
 206
 207
 208 AC_SUBST(AM_CPPFLAGS)
 209 AC_SUBST(AM_LDFLAGS)
 210
 211
 212 dnl ---------------------------------------------------------------------------
 213 dnl Output files
 214 dnl ---------------------------------------------------------------------------
 215 AC_CONFIG_FILES([  po/Makefile.in
 216   Makefile
 217   libexif.spec
 218   libexif/Makefile
 219   test/Makefile
 220   test/nls/Makefile
 221   m4m/Makefile
 222   doc/Makefile
 223   doc/Doxyfile
 224   doc/Doxyfile-internals
 225   libexif.pc
 226   libexif-uninstalled.pc
 227   binary/Makefile
 228   contrib/Makefile
 229   contrib/examples/Makefile
 230 ])
 231 AC_OUTPUT
 232
 233 GP_CONFIG_OUTPUT