configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 AC_PREREQ([2.57])
  24 AC_INIT([libxkbcommon], [0.1.0],
  25     [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg])
  26 AM_INIT_AUTOMAKE([dist-bzip2 foreign])
  27 AM_SILENT_RULES([yes])
  28 AC_CONFIG_HEADERS([src/config.h])
  29 AC_CONFIG_MACRO_DIR([m4])
  30
  31 AC_PROG_LIBTOOL
  32 AC_PROG_CC
  33 AC_PROG_YACC
  34 AC_PROG_LEX
  35
  36 m4_ifndef([PKG_PROG_PKG_CONFIG],
  37     [m4_fatal([Could not locate the pkg-config autoconf macros.
  38     These are usually located in /usr/share/aclocal/pkg.m4. If your
  39     macros are in a different location, try setting the environment
  40     variable ACLOCAL="aclocal -I/other/macro/dir" before running
  41     autoreconf/autogen.sh.])])
  42 PKG_PROG_PKG_CONFIG
  43
  44 # Require xorg-macros version 1.2.0 or newer for XORG_CHANGELOG macro
  45 m4_ifndef([XORG_MACROS_VERSION],
  46     [m4_fatal([must install xorg-macros before running autoconf/autogen.sh])])
  47 XORG_MACROS_VERSION([1.2.0])
  48
  49 dnl Build native compiler needed for makekeys
  50 AC_ARG_VAR([CC_FOR_BUILD], [Build native C compiler program])
  51 if test "x$CC_FOR_BUILD" = x; then
  52     if test "$cross_compiling" != no; then
  53         AC_PATH_PROGS([CC_FOR_BUILD], [gcc cc], [cc])
  54     else
  55         CC_FOR_BUILD="$CC"
  56     fi
  57 fi
  58
  59 AC_CHECK_FUNCS([strcasecmp])
  60 XORG_CHECK_MALLOC_ZERO
  61 XORG_CWARNFLAGS
  62
  63 if  test "x$GCC" = xyes ; then
  64   CFLAGS="$CFLAGS -fvisibility=hidden"
  65 fi
  66
  67 PKG_CHECK_MODULES([X11], [xproto kbproto >= 1.0.5])
  68
  69 dnl Ensure we have keysym headers
  70 AC_MSG_CHECKING([for X11 includedir])
  71 x11includedir="`$PKG_CONFIG --variable=includedir xproto`/X11"
  72 AC_MSG_RESULT([$x11includedir])
  73
  74 AC_MSG_CHECKING([for keysymdef.h])
  75 KEYSYMDEF_H="$x11includedir/keysymdef.h"
  76 test -f "$KEYSYMDEF_H" || AC_MSG_ERROR([can't locate keysymdef.h in $x11includedir])
  77 AC_MSG_RESULT([$KEYSYMDEF_H])
  78 AC_SUBST([KEYSYMDEF_H])
  79
  80 AC_MSG_CHECKING([for XF86keysym.h])
  81 XF86KEYSYM_H="$x11includedir/XF86keysym.h"
  82 test -f "$XF86KEYSYM_H" || AC_MSG_ERROR([can't locate XF86keysym.h in $x11includedir])
  83 AC_MSG_RESULT([$XF86KEYSYM_H])
  84 AC_SUBST([XF86KEYSYM_H])
  85
  86 AC_SUBST([KS_HEADERS], ['$(KEYSYMDEF_H) $(XF86KEYSYM_H)'])
  87
  88 AC_ARG_WITH([xkb_config_root],
  89     [AC_HELP_STRING([--with-xkb-config-root=<paths>],
  90         [Set default XKB config root (default: ${datadir}/X11/xkb)])],
  91     [XKBCONFIGROOT="$withval"],
  92     [XKBCONFIGROOT='${datadir}/X11/xkb'])
  93 AC_SUBST([XKBCONFIGROOT])
  94
  95 XORG_RELEASE_VERSION
  96 XORG_CHANGELOG
  97
  98 AC_OUTPUT([
  99 Makefile
 100 xkbcommon.pc
 101 include/Makefile
 102 src/Makefile
 103 src/makekeys/Makefile
 104 src/xkbcomp/Makefile
 105 test/Makefile
 106 ])