configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_PATH_PROG([MKDEP], [makedepend])
  34 AC_PATH_PROG([SED], [sed])
  35
  36 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  37 dnl configuration in that case.
  38 AC_PROG_INSTALL
  39 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  40
  41 dnl We need a POSIX shell for parts of the build. Assume we have one
  42 dnl in most cases.
  43 case "$host_os" in
  44 solaris*)
  45     # Solaris /bin/sh is too old/non-POSIX compliant
  46     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  47     SHELL="$POSIX_SHELL"
  48     ;;
  49 esac
  50
  51 dnl clang is mostly GCC-compatible, but its version is much lower,
  52 dnl so we have to check for it.
  53 AC_MSG_CHECKING([if compiling with clang])
  54
  55 AC_COMPILE_IFELSE(
  56 [AC_LANG_PROGRAM([], [[
  57 #ifndef __clang__
  58        not clang
  59 #endif
  60 ]])],
  61 [CLANG=yes], [CLANG=no])
  62
  63 AC_MSG_RESULT([$CLANG])
  64
  65 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  66 dnl versions are explictly not supported.
  67 if test "x$GCC" = xyes -a "x$CLANG" = xno; then
  68     AC_MSG_CHECKING([whether gcc version is sufficient])
  69     major=0
  70     minor=0
  71
  72     GCC_VERSION=`$CC -dumpversion`
  73     if test $? -eq 0; then
  74         major=`echo $GCC_VERSION | cut -d. -f1`
  75         minor=`echo $GCC_VERSION | cut -d. -f1`
  76     fi
  77
  78     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  79         AC_MSG_RESULT([no])
  80         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  81     else
  82         AC_MSG_RESULT([yes])
  83     fi
  84 fi
  85
  86
  87 MKDEP_OPTIONS=-fdepend
  88 dnl Ask gcc where it's keeping its secret headers
  89 if test "x$GCC" = xyes; then
  90     for dir in include include-fixed; do
  91         GCC_INCLUDES=`$CC -print-file-name=$dir`
  92         if test "x$GCC_INCLUDES" != x && \
  93            test "$GCC_INCLUDES" != "$dir" && \
  94            test -d "$GCC_INCLUDES"; then
  95             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
  96         fi
  97     done
  98 fi
  99 AC_SUBST([MKDEP_OPTIONS])
 100
 101 dnl Make sure the pkg-config macros are defined
 102 m4_ifndef([PKG_PROG_PKG_CONFIG],
 103     [m4_fatal([Could not locate the pkg-config autoconf macros.
 104   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 105   are in a different location, try setting the environment variable
 106   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 107 PKG_PROG_PKG_CONFIG()
 108
 109 dnl LIB_DIR - library basename
 110 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 111 AC_SUBST([LIB_DIR])
 112
 113 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 114 _SAVE_LDFLAGS="$LDFLAGS"
 115 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 116 AC_SUBST([EXTRA_LIB_PATH])
 117
 118 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 119 _SAVE_CPPFLAGS="$CPPFLAGS"
 120 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 121 AC_SUBST([X11_INCLUDES])
 122
 123 dnl Compiler macros
 124 DEFINES=""
 125 AC_SUBST([DEFINES])
 126 case "$host_os" in
 127 linux*|*-gnu*|gnu*)
 128     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 129     ;;
 130 solaris*)
 131     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 132     ;;
 133 cygwin*)
 134     DEFINES="$DEFINES -DPTHREADS"
 135     ;;
 136 esac
 137
 138 dnl Add flags for gcc and g++
 139 if test "x$GCC" = xyes; then
 140     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99"
 141     if test "x$CLANG" = "xno"; then
 142        CFLAGS="$CFLAGS -ffast-math"
 143     fi
 144
 145     # Enable -fvisibility=hidden if using a gcc that supports it
 146     save_CFLAGS="$CFLAGS"
 147     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 148     CFLAGS="$CFLAGS -fvisibility=hidden"
 149     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 150                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 151
 152     # Work around aliasing bugs - developers should comment this out
 153     CFLAGS="$CFLAGS -fno-strict-aliasing"
 154 fi
 155 if test "x$GXX" = xyes; then
 156     CXXFLAGS="$CXXFLAGS -Wall"
 157
 158     # Enable -fvisibility=hidden if using a gcc that supports it
 159     save_CXXFLAGS="$CXXFLAGS"
 160     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 161     CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
 162     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 163                    [CXXFLAGS="$save_CXXFLAGS" ; AC_MSG_RESULT([no])]);
 164
 165     # Work around aliasing bugs - developers should comment this out
 166     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 167 fi
 168
 169 dnl These should be unnecessary, but let the user set them if they want
 170 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 171     Default is to use CFLAGS.])
 172 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 173     compiler. Default is to use CFLAGS.])
 174 AC_SUBST([OPT_FLAGS])
 175 AC_SUBST([ARCH_FLAGS])
 176
 177 dnl
 178 dnl Hacks to enable 32 or 64 bit build
 179 dnl
 180 AC_ARG_ENABLE([32-bit],
 181     [AS_HELP_STRING([--enable-32-bit],
 182         [build 32-bit libraries @<:@default=auto@:>@])],
 183     [enable_32bit="$enableval"],
 184     [enable_32bit=auto]
 185 )
 186 if test "x$enable_32bit" = xyes; then
 187     if test "x$GCC" = xyes; then
 188         CFLAGS="$CFLAGS -m32"
 189         ARCH_FLAGS="$ARCH_FLAGS -m32"
 190     fi
 191     if test "x$GXX" = xyes; then
 192         CXXFLAGS="$CXXFLAGS -m32"
 193     fi
 194 fi
 195 AC_ARG_ENABLE([64-bit],
 196     [AS_HELP_STRING([--enable-64-bit],
 197         [build 64-bit libraries @<:@default=auto@:>@])],
 198     [enable_64bit="$enableval"],
 199     [enable_64bit=auto]
 200 )
 201 if test "x$enable_64bit" = xyes; then
 202     if test "x$GCC" = xyes; then
 203         CFLAGS="$CFLAGS -m64"
 204     fi
 205     if test "x$GXX" = xyes; then
 206         CXXFLAGS="$CXXFLAGS -m64"
 207     fi
 208 fi
 209
 210 dnl
 211 dnl shared/static libraries, mimic libtool options
 212 dnl
 213 AC_ARG_ENABLE([static],
 214     [AS_HELP_STRING([--enable-static],
 215         [build static libraries @<:@default=disabled@:>@])],
 216     [enable_static="$enableval"],
 217     [enable_static=no]
 218 )
 219 case "x$enable_static" in
 220 xyes|xno ) ;;
 221 x ) enable_static=no ;;
 222 * )
 223     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 224     ;;
 225 esac
 226 AC_ARG_ENABLE([shared],
 227     [AS_HELP_STRING([--disable-shared],
 228         [build shared libraries @<:@default=enabled@:>@])],
 229     [enable_shared="$enableval"],
 230     [enable_shared=yes]
 231 )
 232 case "x$enable_shared" in
 233 xyes|xno ) ;;
 234 x ) enable_shared=yes ;;
 235 * )
 236     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 237     ;;
 238 esac
 239
 240 dnl Can't have static and shared libraries, default to static if user
 241 dnl explicitly requested. If both disabled, set to static since shared
 242 dnl was explicitly requirested.
 243 case "x$enable_static$enable_shared" in
 244 xyesyes )
 245     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 246     enable_shared=no
 247     ;;
 248 xnono )
 249     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 250     enable_static=yes
 251     ;;
 252 esac
 253
 254 dnl
 255 dnl mklib options
 256 dnl
 257 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 258 if test "$enable_static" = yes; then
 259     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 260 fi
 261 AC_SUBST([MKLIB_OPTIONS])
 262
 263 dnl
 264 dnl other compiler options
 265 dnl
 266 AC_ARG_ENABLE([debug],
 267     [AS_HELP_STRING([--enable-debug],
 268         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 269     [enable_debug="$enableval"],
 270     [enable_debug=no]
 271 )
 272 if test "x$enable_debug" = xyes; then
 273     DEFINES="$DEFINES -DDEBUG"
 274     if test "x$GCC" = xyes; then
 275         CFLAGS="$CFLAGS -g"
 276     fi
 277     if test "x$GXX" = xyes; then
 278         CXXFLAGS="$CXXFLAGS -g"
 279     fi
 280 fi
 281
 282 dnl
 283 dnl library names
 284 dnl
 285 LIB_PREFIX_GLOB='lib'
 286 LIB_VERSION_SEPARATOR='.'
 287 if test "$enable_static" = yes; then
 288     LIB_EXTENSION='a'
 289 else
 290     case "$host_os" in
 291     darwin* )
 292         LIB_EXTENSION='dylib' ;;
 293     cygwin* )
 294         dnl prefix can be 'cyg' or 'lib'
 295         LIB_PREFIX_GLOB='???'
 296         LIB_VERSION_SEPARATOR='-'
 297         LIB_EXTENSION='dll' ;;
 298     aix* )
 299         LIB_EXTENSION='a' ;;
 300     * )
 301         LIB_EXTENSION='so' ;;
 302     esac
 303 fi
 304
 305 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 306 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 307 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 308 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 309 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 310 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 311 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 312 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 313 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 314
 315 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 316 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 317 GLUT_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLUT_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 318 GLW_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLW_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 319 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 320 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 321 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 322 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 323 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 324 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 325
 326 AC_SUBST([GL_LIB_NAME])
 327 AC_SUBST([GLU_LIB_NAME])
 328 AC_SUBST([GLUT_LIB_NAME])
 329 AC_SUBST([GLW_LIB_NAME])
 330 AC_SUBST([OSMESA_LIB_NAME])
 331 AC_SUBST([EGL_LIB_NAME])
 332 AC_SUBST([GLESv1_CM_LIB_NAME])
 333 AC_SUBST([GLESv2_LIB_NAME])
 334 AC_SUBST([VG_LIB_NAME])
 335
 336 AC_SUBST([GL_LIB_GLOB])
 337 AC_SUBST([GLU_LIB_GLOB])
 338 AC_SUBST([GLUT_LIB_GLOB])
 339 AC_SUBST([GLW_LIB_GLOB])
 340 AC_SUBST([OSMESA_LIB_GLOB])
 341 AC_SUBST([EGL_LIB_GLOB])
 342 AC_SUBST([GLESv1_CM_LIB_GLOB])
 343 AC_SUBST([GLESv2_LIB_GLOB])
 344 AC_SUBST([VG_LIB_GLOB])
 345
 346 dnl
 347 dnl Arch/platform-specific settings
 348 dnl
 349 AC_ARG_ENABLE([asm],
 350     [AS_HELP_STRING([--disable-asm],
 351         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 352     [enable_asm="$enableval"],
 353     [enable_asm=yes]
 354 )
 355 asm_arch=""
 356 ASM_FLAGS=""
 357 MESA_ASM_SOURCES=""
 358 GLAPI_ASM_SOURCES=""
 359 AC_MSG_CHECKING([whether to enable assembly])
 360 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 361 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 362 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 363     case "$host_cpu" in
 364     i?86 | x86_64)
 365         enable_asm=no
 366         AC_MSG_RESULT([no, cross compiling])
 367         ;;
 368     esac
 369 fi
 370 # check for supported arches
 371 if test "x$enable_asm" = xyes; then
 372     case "$host_cpu" in
 373     i?86)
 374         case "$host_os" in
 375         linux* | *freebsd* | dragonfly*)
 376             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 377             ;;
 378         esac
 379         ;;
 380     x86_64)
 381         case "$host_os" in
 382         linux* | *freebsd* | dragonfly*)
 383             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 384             ;;
 385         esac
 386         ;;
 387     powerpc)
 388         case "$host_os" in
 389         linux*)
 390             asm_arch=ppc
 391             ;;
 392         esac
 393         ;;
 394     sparc*)
 395         case "$host_os" in
 396         linux*)
 397             asm_arch=sparc
 398             ;;
 399         esac
 400         ;;
 401     esac
 402
 403     case "$asm_arch" in
 404     x86)
 405         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 406         MESA_ASM_SOURCES='$(X86_SOURCES)'
 407         GLAPI_ASM_SOURCES='$(X86_API)'
 408         AC_MSG_RESULT([yes, x86])
 409         ;;
 410     x86_64)
 411         ASM_FLAGS="-DUSE_X86_64_ASM"
 412         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 413         GLAPI_ASM_SOURCES='$(X86-64_API)'
 414         AC_MSG_RESULT([yes, x86_64])
 415         ;;
 416     ppc)
 417         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 418         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 419         AC_MSG_RESULT([yes, ppc])
 420         ;;
 421     sparc)
 422         ASM_FLAGS="-DUSE_SPARC_ASM"
 423         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 424         GLAPI_ASM_SOURCES='$(SPARC_API)'
 425         AC_MSG_RESULT([yes, sparc])
 426         ;;
 427     *)
 428         AC_MSG_RESULT([no, platform not supported])
 429         ;;
 430     esac
 431 fi
 432 AC_SUBST([ASM_FLAGS])
 433 AC_SUBST([MESA_ASM_SOURCES])
 434 AC_SUBST([GLAPI_ASM_SOURCES])
 435
 436 dnl PIC code macro
 437 MESA_PIC_FLAGS
 438
 439 dnl Check to see if dlopen is in default libraries (like Solaris, which
 440 dnl has it in libc), or if libdl is needed to get it.
 441 AC_CHECK_FUNC([dlopen], [],
 442     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 443 AC_SUBST([DLOPEN_LIBS])
 444
 445 dnl See if posix_memalign is available
 446 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 447
 448 dnl SELinux awareness.
 449 AC_ARG_ENABLE([selinux],
 450     [AS_HELP_STRING([--enable-selinux],
 451         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 452     [MESA_SELINUX="$enableval"],
 453     [MESA_SELINUX=no])
 454 if test "x$enable_selinux" = "xyes"; then
 455     AC_CHECK_HEADER([selinux/selinux.h],[],
 456                     [AC_MSG_ERROR([SELinux headers not found])])
 457     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 458                  [AC_MSG_ERROR([SELinux library not found])])
 459     SELINUX_LIBS="-lselinux"
 460     DEFINES="$DEFINES -DMESA_SELINUX"
 461 fi
 462
 463 dnl
 464 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 465 dnl More later: fbdev, ...
 466 dnl
 467 default_driver="xlib"
 468
 469 case "$host_os" in
 470 linux*)
 471     case "$host_cpu" in
 472     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 473     esac
 474     ;;
 475 *freebsd* | dragonfly*)
 476     case "$host_cpu" in
 477     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 478     esac
 479     ;;
 480 esac
 481
 482 AC_ARG_WITH([driver],
 483     [AS_HELP_STRING([--with-driver=DRIVER],
 484         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 485     [mesa_driver="$withval"],
 486     [mesa_driver="$default_driver"])
 487 dnl Check for valid option
 488 case "x$mesa_driver" in
 489 xxlib|xdri|xosmesa)
 490     ;;
 491 *)
 492     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 493     ;;
 494 esac
 495
 496 PKG_CHECK_MODULES([TALLOC], [talloc])
 497 AC_SUBST([TALLOC_LIBS])
 498 AC_SUBST([TALLOC_CFLAGS])
 499
 500 dnl
 501 dnl Driver specific build directories
 502 dnl
 503
 504 dnl this variable will be prepended to SRC_DIRS and is not exported
 505 CORE_DIRS="mapi/glapi glsl mesa"
 506
 507 SRC_DIRS=""
 508 GLU_DIRS="sgi"
 509 GALLIUM_DIRS="auxiliary drivers state_trackers"
 510 GALLIUM_TARGET_DIRS=""
 511 GALLIUM_WINSYS_DIRS="sw"
 512 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug identity"
 513 GALLIUM_STATE_TRACKERS_DIRS=""
 514
 515 case "$mesa_driver" in
 516 xlib)
 517     DRIVER_DIRS="x11"
 518     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 519     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 520     ;;
 521 dri)
 522     SRC_DIRS="$SRC_DIRS glx"
 523     DRIVER_DIRS="dri"
 524     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 525     ;;
 526 osmesa)
 527     DRIVER_DIRS="osmesa"
 528     ;;
 529 esac
 530 AC_SUBST([SRC_DIRS])
 531 AC_SUBST([GLU_DIRS])
 532 AC_SUBST([DRIVER_DIRS])
 533 AC_SUBST([GALLIUM_DIRS])
 534 AC_SUBST([GALLIUM_TARGET_DIRS])
 535 AC_SUBST([GALLIUM_WINSYS_DIRS])
 536 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 537 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 538 AC_SUBST([MESA_LLVM])
 539
 540 dnl
 541 dnl Find out if X is available. The variable have_x is set if libX11 is
 542 dnl found to mimic AC_PATH_XTRA.
 543 dnl
 544 if test -n "$PKG_CONFIG"; then
 545     AC_MSG_CHECKING([pkg-config files for X11 are available])
 546     PKG_CHECK_EXISTS([x11],[
 547         x11_pkgconfig=yes
 548         have_x=yes
 549         ],[
 550         x11_pkgconfig=no
 551     ])
 552     AC_MSG_RESULT([$x11_pkgconfig])
 553 else
 554     x11_pkgconfig=no
 555 fi
 556 dnl Use the autoconf macro if no pkg-config files
 557 if test "$x11_pkgconfig" = yes; then
 558     PKG_CHECK_MODULES([X11], [x11])
 559 else
 560     AC_PATH_XTRA
 561     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 562     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 563     AC_SUBST([X11_CFLAGS])
 564     AC_SUBST([X11_LIBS])
 565 fi
 566
 567 dnl Try to tell the user that the --x-* options are only used when
 568 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 569 m4_divert_once([HELP_BEGIN],
 570 [These options are only used when the X libraries cannot be found by the
 571 pkg-config utility.])
 572
 573 dnl We need X for xlib and dri, so bomb now if it's not found
 574 case "$mesa_driver" in
 575 xlib|dri)
 576     if test "$no_x" = yes; then
 577         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 578     fi
 579     ;;
 580 esac
 581
 582 dnl XCB - this is only used for GLX right now
 583 AC_ARG_ENABLE([xcb],
 584     [AS_HELP_STRING([--enable-xcb],
 585         [use XCB for GLX @<:@default=disabled@:>@])],
 586     [enable_xcb="$enableval"],
 587     [enable_xcb=no])
 588 if test "x$enable_xcb" = xyes; then
 589     DEFINES="$DEFINES -DUSE_XCB"
 590 else
 591     enable_xcb=no
 592 fi
 593
 594 dnl
 595 dnl libGL configuration per driver
 596 dnl
 597 case "$mesa_driver" in
 598 xlib)
 599     if test "$x11_pkgconfig" = yes; then
 600         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 601         GL_PC_REQ_PRIV="x11 xext"
 602         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 603         GL_LIB_DEPS="$XLIBGL_LIBS"
 604     else
 605         # should check these...
 606         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 607         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 608         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 609         GL_PC_CFLAGS="$X11_INCLUDES"
 610     fi
 611     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 612     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 613
 614     # if static, move the external libraries to the programs
 615     # and empty the libraries for libGL
 616     if test "$enable_static" = yes; then
 617         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 618         GL_LIB_DEPS=""
 619     fi
 620     ;;
 621 dri)
 622     # DRI must be shared, I think
 623     if test "$enable_static" = yes; then
 624         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 625     fi
 626
 627     # Check for libdrm
 628     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 629     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 630     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 631     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 632     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 633
 634     # find the DRI deps for libGL
 635     if test "$x11_pkgconfig" = yes; then
 636         dri_modules="x11 xext xdamage xfixes"
 637
 638         # add xf86vidmode if available
 639         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 640         if test "$HAVE_XF86VIDMODE" = yes ; then
 641             dri_modules="$dri_modules xxf86vm"
 642         fi
 643
 644         # add xcb modules if necessary
 645         if test "$enable_xcb" = yes; then
 646             dri_modules="$dri_modules x11-xcb xcb-glx"
 647         fi
 648
 649         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 650         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 651         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 652         GL_LIB_DEPS="$DRIGL_LIBS"
 653     else
 654         # should check these...
 655         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 656         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 657         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 658         GL_PC_CFLAGS="$X11_INCLUDES"
 659
 660         # XCB can only be used from pkg-config
 661         if test "$enable_xcb" = yes; then
 662             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 663             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 664             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 665             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 666         fi
 667     fi
 668
 669     # need DRM libs, -lpthread, etc.
 670     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 671     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 672     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 673     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 674     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 675     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 676     ;;
 677 osmesa)
 678     # No libGL for osmesa
 679     GL_LIB_DEPS=""
 680     ;;
 681 esac
 682 AC_SUBST([GL_LIB_DEPS])
 683 AC_SUBST([GL_PC_REQ_PRIV])
 684 AC_SUBST([GL_PC_LIB_PRIV])
 685 AC_SUBST([GL_PC_CFLAGS])
 686 AC_SUBST([DRI_PC_REQ_PRIV])
 687 AC_SUBST([GLESv1_CM_LIB_DEPS])
 688 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 689 AC_SUBST([GLESv2_LIB_DEPS])
 690 AC_SUBST([GLESv2_PC_LIB_PRIV])
 691
 692
 693 AC_SUBST([HAVE_XF86VIDMODE])
 694
 695 dnl
 696 dnl More X11 setup
 697 dnl
 698 if test "$mesa_driver" = xlib; then
 699     DEFINES="$DEFINES -DUSE_XSHM"
 700 fi
 701
 702 dnl
 703 dnl More DRI setup
 704 dnl
 705 AC_ARG_ENABLE([glx-tls],
 706     [AS_HELP_STRING([--enable-glx-tls],
 707         [enable TLS support in GLX @<:@default=disabled@:>@])],
 708     [GLX_USE_TLS="$enableval"],
 709     [GLX_USE_TLS=no])
 710 dnl Directory for DRI drivers
 711 AC_ARG_WITH([dri-driverdir],
 712     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 713         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 714     [DRI_DRIVER_INSTALL_DIR="$withval"],
 715     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 716 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 717 dnl Extra search path for DRI drivers
 718 AC_ARG_WITH([dri-searchpath],
 719     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 720         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 721     [DRI_DRIVER_SEARCH_DIR="$withval"],
 722     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 723 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 724 dnl Direct rendering or just indirect rendering
 725 AC_ARG_ENABLE([driglx-direct],
 726     [AS_HELP_STRING([--disable-driglx-direct],
 727         [enable direct rendering in GLX and EGL for DRI @<:@default=enabled@:>@])],
 728     [driglx_direct="$enableval"],
 729     [driglx_direct="yes"])
 730 dnl Which drivers to build - default is chosen by platform
 731 AC_ARG_WITH([dri-drivers],
 732     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 733         [comma delimited DRI drivers list, e.g.
 734         "swrast,i965,radeon" @<:@default=auto@:>@])],
 735     [with_dri_drivers="$withval"],
 736     [with_dri_drivers=yes])
 737 if test "x$with_dri_drivers" = x; then
 738     with_dri_drivers=no
 739 fi
 740
 741 dnl Determine which APIs to support
 742 AC_ARG_ENABLE([opengl],
 743     [AS_HELP_STRING([--disable-opengl],
 744         [disable support for standard OpenGL API @<:@default=no@:>@])],
 745     [enable_opengl="$enableval"],
 746     [enable_opengl=yes])
 747 AC_ARG_ENABLE([gles1],
 748     [AS_HELP_STRING([--enable-gles1],
 749         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 750     [enable_gles1="$enableval"],
 751     [enable_gles1=no])
 752 AC_ARG_ENABLE([gles2],
 753     [AS_HELP_STRING([--enable-gles2],
 754         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 755     [enable_gles2="$enableval"],
 756     [enable_gles2=no])
 757 AC_ARG_ENABLE([gles-overlay],
 758     [AS_HELP_STRING([--enable-gles-overlay],
 759         [build separate OpenGL ES only libraries @<:@default=no@:>@])],
 760     [enable_gles_overlay="$enableval"],
 761     [enable_gles_overlay=no])
 762
 763 API_DEFINES=""
 764 GLES_OVERLAY=0
 765 if test "x$enable_opengl" = xno; then
 766     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 767 else
 768     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 769 fi
 770 if test "x$enable_gles1" = xyes; then
 771     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 772 fi
 773 if test "x$enable_gles2" = xyes; then
 774     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 775 fi
 776 if test "x$enable_gles_overlay" = xyes -o \
 777     "x$enable_gles1" = xyes -o "x$enable_gles2" = xyes; then
 778     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
 779     if test "x$enable_gles_overlay" = xyes; then
 780         GLES_OVERLAY=1
 781     fi
 782 fi
 783 AC_SUBST([API_DEFINES])
 784 AC_SUBST([GLES_OVERLAY])
 785
 786 dnl If $with_dri_drivers is yes, directories will be added through
 787 dnl platform checks
 788 DRI_DIRS=""
 789 case "$with_dri_drivers" in
 790 no) ;;
 791 yes)
 792     DRI_DIRS="yes"
 793     ;;
 794 *)
 795     # verify the requested driver directories exist
 796     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 797     for driver in $dri_drivers; do
 798         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 799             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 800     done
 801     DRI_DIRS="$dri_drivers"
 802     ;;
 803 esac
 804
 805 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 806 if test "$mesa_driver" = dri; then
 807     # Use TLS in GLX?
 808     if test "x$GLX_USE_TLS" = xyes; then
 809         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 810     fi
 811
 812     # Platform specific settings and drivers to build
 813     case "$host_os" in
 814     linux*)
 815         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 816         if test "x$driglx_direct" = xyes; then
 817             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 818         fi
 819         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 820
 821         case "$host_cpu" in
 822         x86_64)
 823             # sis is missing because they have not be converted to use
 824             # the new interface.  i810 are missing because there is no
 825             # x86-64 system where they could *ever* be used.
 826             if test "x$DRI_DIRS" = "xyes"; then
 827                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 828                     savage tdfx unichrome swrast"
 829             fi
 830             ;;
 831         powerpc*)
 832             # Build only the drivers for cards that exist on PowerPC.
 833             # At some point MGA will be added, but not yet.
 834             if test "x$DRI_DIRS" = "xyes"; then
 835                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 836             fi
 837             ;;
 838         sparc*)
 839             # Build only the drivers for cards that exist on sparc`
 840             if test "x$DRI_DIRS" = "xyes"; then
 841                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 842             fi
 843             ;;
 844         esac
 845         ;;
 846     freebsd* | dragonfly*)
 847         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 848         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 849         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 850         if test "x$driglx_direct" = xyes; then
 851             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 852         fi
 853         if test "x$GXX" = xyes; then
 854             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 855         fi
 856
 857         if test "x$DRI_DIRS" = "xyes"; then
 858             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 859                 unichrome savage sis swrast"
 860         fi
 861         ;;
 862     gnu*)
 863         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 864         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 865         ;;
 866     solaris*)
 867         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 868         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 869         if test "x$driglx_direct" = xyes; then
 870             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 871         fi
 872         ;;
 873     esac
 874
 875     # default drivers
 876     if test "x$DRI_DIRS" = "xyes"; then
 877         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 878             savage sis tdfx unichrome swrast"
 879     fi
 880
 881     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 882
 883     # Check for expat
 884     EXPAT_INCLUDES=""
 885     EXPAT_LIB=-lexpat
 886     AC_ARG_WITH([expat],
 887         [AS_HELP_STRING([--with-expat=DIR],
 888             [expat install directory])],[
 889         EXPAT_INCLUDES="-I$withval/include"
 890         CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 891         LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 892         EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 893         ])
 894     AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 895     AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 896         [AC_MSG_ERROR([Expat required for DRI.])])
 897
 898     # put all the necessary libs together
 899     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS $TALLOC_LIBS"
 900 fi
 901 AC_SUBST([DRI_DIRS])
 902 AC_SUBST([EXPAT_INCLUDES])
 903 AC_SUBST([DRI_LIB_DEPS])
 904
 905 case $DRI_DIRS in
 906 *i915*|*i965*)
 907     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.21])
 908     ;;
 909 esac
 910
 911 case $DRI_DIRS in
 912 *radeon*|*r200*|*r300*|*r600*)
 913     PKG_CHECK_MODULES([LIBDRM_RADEON],
 914                       [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 915                       HAVE_LIBDRM_RADEON=yes,
 916                       HAVE_LIBDRM_RADEON=no)
 917
 918     if test "$HAVE_LIBDRM_RADEON" = yes; then
 919         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 920         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 921     fi
 922     ;;
 923 esac
 924 AC_SUBST([RADEON_CFLAGS])
 925 AC_SUBST([RADEON_LDFLAGS])
 926
 927
 928 dnl
 929 dnl OSMesa configuration
 930 dnl
 931 if test "$mesa_driver" = xlib; then
 932     default_gl_osmesa=yes
 933 else
 934     default_gl_osmesa=no
 935 fi
 936 AC_ARG_ENABLE([gl-osmesa],
 937     [AS_HELP_STRING([--enable-gl-osmesa],
 938         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
 939     [gl_osmesa="$enableval"],
 940     [gl_osmesa="$default_gl_osmesa"])
 941 if test "x$gl_osmesa" = xyes; then
 942     if test "$mesa_driver" = osmesa; then
 943         AC_MSG_ERROR([libGL is not available for OSMesa driver])
 944     else
 945         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 946     fi
 947 fi
 948
 949 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
 950 AC_ARG_WITH([osmesa-bits],
 951     [AS_HELP_STRING([--with-osmesa-bits=BITS],
 952         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
 953     [osmesa_bits="$withval"],
 954     [osmesa_bits=8])
 955 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
 956     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
 957     osmesa_bits=8
 958 fi
 959 case "x$osmesa_bits" in
 960 x8)
 961     OSMESA_LIB=OSMesa
 962     ;;
 963 x16|x32)
 964     OSMESA_LIB="OSMesa$osmesa_bits"
 965     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
 966     ;;
 967 *)
 968     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
 969     ;;
 970 esac
 971 AC_SUBST([OSMESA_LIB])
 972
 973 case "$DRIVER_DIRS" in
 974 *osmesa*)
 975     # only link libraries with osmesa if shared
 976     if test "$enable_static" = no; then
 977         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
 978     else
 979         OSMESA_LIB_DEPS=""
 980     fi
 981     OSMESA_MESA_DEPS=""
 982     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
 983     ;;
 984 esac
 985 AC_SUBST([OSMESA_LIB_DEPS])
 986 AC_SUBST([OSMESA_MESA_DEPS])
 987 AC_SUBST([OSMESA_PC_REQ])
 988 AC_SUBST([OSMESA_PC_LIB_PRIV])
 989
 990 dnl
 991 dnl EGL configuration
 992 dnl
 993 AC_ARG_ENABLE([egl],
 994     [AS_HELP_STRING([--disable-egl],
 995         [disable EGL library @<:@default=enabled@:>@])],
 996     [enable_egl="$enableval"],
 997     [enable_egl=yes])
 998 if test "x$enable_egl" = xyes; then
 999     SRC_DIRS="$SRC_DIRS egl"
1000     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1001     EGL_DRIVERS_DIRS=""
1002     if test "$enable_static" != yes; then
1003         # build egl_glx when libGL is built
1004         if test "$mesa_driver" != osmesa; then
1005             EGL_DRIVERS_DIRS="glx"
1006         fi
1007
1008         if test "$mesa_driver" = dri; then
1009             # build egl_dri2 when xcb-dri2 is available
1010             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1011                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1012             PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1013                           [have_libudev=yes],[have_libudev=no])
1014
1015             if test "$have_xcb_dri2" = yes; then
1016                 EGL_DRIVER_DRI2=dri2
1017                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1018                 if test "$have_libudev" = yes; then
1019                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1020                 fi
1021             fi
1022         fi
1023
1024         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1025     fi
1026 fi
1027 AC_SUBST([EGL_LIB_DEPS])
1028 AC_SUBST([EGL_DRIVERS_DIRS])
1029
1030 dnl
1031 dnl GLU configuration
1032 dnl
1033 AC_ARG_ENABLE([glu],
1034     [AS_HELP_STRING([--disable-glu],
1035         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1036     [enable_glu="$enableval"],
1037     [enable_glu=yes])
1038 if test "x$enable_glu" = xyes; then
1039     SRC_DIRS="$SRC_DIRS glu"
1040
1041     case "$mesa_driver" in
1042     osmesa)
1043         # Link libGLU to libOSMesa instead of libGL
1044         GLU_LIB_DEPS=""
1045         GLU_PC_REQ="osmesa"
1046         if test "$enable_static" = no; then
1047             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1048         else
1049             GLU_MESA_DEPS=""
1050         fi
1051         ;;
1052     *)
1053         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1054         GLU_PC_REQ="gl"
1055         GLU_PC_LIB_PRIV="-lm"
1056         if test "$enable_static" = no; then
1057             GLU_LIB_DEPS="-lm"
1058             GLU_MESA_DEPS='-l$(GL_LIB)'
1059         else
1060             GLU_LIB_DEPS=""
1061             GLU_MESA_DEPS=""
1062             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1063         fi
1064         ;;
1065     esac
1066 fi
1067 if test "$enable_static" = no; then
1068     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1069 fi
1070 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1071 AC_SUBST([GLU_LIB_DEPS])
1072 AC_SUBST([GLU_MESA_DEPS])
1073 AC_SUBST([GLU_PC_REQ])
1074 AC_SUBST([GLU_PC_REQ_PRIV])
1075 AC_SUBST([GLU_PC_LIB_PRIV])
1076 AC_SUBST([GLU_PC_CFLAGS])
1077
1078 dnl
1079 dnl GLw configuration
1080 dnl
1081 AC_ARG_ENABLE([glw],
1082     [AS_HELP_STRING([--disable-glw],
1083         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1084     [enable_glw="$enableval"],
1085     [enable_glw=yes])
1086 dnl Don't build GLw on osmesa
1087 if test "x$enable_glw" = xyes && test "$mesa_driver" = osmesa; then
1088     AC_MSG_WARN([Disabling GLw since the driver is OSMesa])
1089     enable_glw=no
1090 fi
1091 AC_ARG_ENABLE([motif],
1092     [AS_HELP_STRING([--enable-motif],
1093         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1094     [enable_motif="$enableval"],
1095     [enable_motif=no])
1096
1097 if test "x$enable_glw" = xyes; then
1098     SRC_DIRS="$SRC_DIRS glw"
1099     if test "$x11_pkgconfig" = yes; then
1100         PKG_CHECK_MODULES([GLW],[x11 xt])
1101         GLW_PC_REQ_PRIV="x11 xt"
1102         GLW_LIB_DEPS="$GLW_LIBS"
1103     else
1104         # should check these...
1105         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1106         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1107         GLW_PC_CFLAGS="$X11_INCLUDES"
1108     fi
1109
1110     GLW_SOURCES="GLwDrawA.c"
1111     MOTIF_CFLAGS=
1112     if test "x$enable_motif" = xyes; then
1113         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1114         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1115         if test "x$MOTIF_CONFIG" != xno; then
1116             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1117             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1118         else
1119             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1120                 [AC_MSG_ERROR([Can't locate Motif headers])])
1121             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1122                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1123         fi
1124         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1125         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1126         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1127         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1128     fi
1129
1130     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1131     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1132     if test "$enable_static" = no; then
1133         GLW_MESA_DEPS='-l$(GL_LIB)'
1134         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1135     else
1136         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1137         GLW_LIB_DEPS=""
1138         GLW_MESA_DEPS=""
1139     fi
1140 fi
1141 AC_SUBST([GLW_LIB_DEPS])
1142 AC_SUBST([GLW_MESA_DEPS])
1143 AC_SUBST([GLW_SOURCES])
1144 AC_SUBST([MOTIF_CFLAGS])
1145 AC_SUBST([GLW_PC_REQ_PRIV])
1146 AC_SUBST([GLW_PC_LIB_PRIV])
1147 AC_SUBST([GLW_PC_CFLAGS])
1148
1149 dnl
1150 dnl GLUT configuration
1151 dnl
1152 if test -f "$srcdir/include/GL/glut.h"; then
1153     default_glut=yes
1154 else
1155     default_glut=no
1156 fi
1157 AC_ARG_ENABLE([glut],
1158     [AS_HELP_STRING([--disable-glut],
1159         [enable GLUT library @<:@default=enabled if source available@:>@])],
1160     [enable_glut="$enableval"],
1161     [enable_glut="$default_glut"])
1162
1163 dnl Can't build glut if GLU not available
1164 if test "x$enable_glu$enable_glut" = xnoyes; then
1165     AC_MSG_WARN([Disabling glut since GLU is disabled])
1166     enable_glut=no
1167 fi
1168 dnl Don't build glut on osmesa
1169 if test "x$enable_glut" = xyes && test "$mesa_driver" = osmesa; then
1170     AC_MSG_WARN([Disabling glut since the driver is OSMesa])
1171     enable_glut=no
1172 fi
1173
1174 if test "x$enable_glut" = xyes; then
1175     SRC_DIRS="$SRC_DIRS glut/glx"
1176     if test "$x11_pkgconfig" = yes; then
1177         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1178         GLUT_PC_REQ_PRIV="x11 xmu xi"
1179         GLUT_LIB_DEPS="$GLUT_LIBS"
1180     else
1181         # should check these...
1182         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1183         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1184         GLUT_PC_CFLAGS="$X11_INCLUDES"
1185     fi
1186     if test "x$GCC" = xyes; then
1187         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1188     fi
1189     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1190     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1191
1192     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1193     if test "$enable_static" = no; then
1194         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1195     else
1196         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1197         GLUT_LIB_DEPS=""
1198         GLUT_MESA_DEPS=""
1199     fi
1200 fi
1201 AC_SUBST([GLUT_LIB_DEPS])
1202 AC_SUBST([GLUT_MESA_DEPS])
1203 AC_SUBST([GLUT_CFLAGS])
1204 AC_SUBST([GLUT_PC_REQ_PRIV])
1205 AC_SUBST([GLUT_PC_LIB_PRIV])
1206 AC_SUBST([GLUT_PC_CFLAGS])
1207
1208 dnl
1209 dnl Program library dependencies
1210 dnl    Only libm is added here if necessary as the libraries should
1211 dnl    be pulled in by the linker
1212 dnl
1213 if test "x$APP_LIB_DEPS" = x; then
1214     case "$host_os" in
1215     solaris*)
1216         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1217         ;;
1218     cygwin*)
1219         APP_LIB_DEPS="-lX11"
1220         ;;
1221     *)
1222         APP_LIB_DEPS="-lm"
1223         ;;
1224     esac
1225 fi
1226 AC_SUBST([APP_LIB_DEPS])
1227 AC_SUBST([PROGRAM_DIRS])
1228
1229 dnl
1230 dnl Gallium configuration
1231 dnl
1232 AC_ARG_ENABLE([gallium],
1233     [AS_HELP_STRING([--disable-gallium],
1234         [build gallium @<:@default=enabled@:>@])],
1235     [enable_gallium="$enableval"],
1236     [enable_gallium=yes])
1237 if test "x$enable_gallium" = xyes; then
1238     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1239     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1240                 [HAS_UDIS86="no"])
1241     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1242 fi
1243
1244 AC_SUBST([LLVM_CFLAGS])
1245 AC_SUBST([LLVM_LIBS])
1246 AC_SUBST([LLVM_LDFLAGS])
1247 AC_SUBST([LLVM_VERSION])
1248
1249 VG_LIB_DEPS=""
1250 EGL_CLIENT_APIS='$(GL_LIB)'
1251 if test "x$enable_gles_overlay" = xyes; then
1252     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1253 fi
1254
1255 dnl
1256 dnl Gallium state trackers configuration
1257 dnl
1258 AC_ARG_WITH([state-trackers],
1259     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1260         [comma delimited state_trackers list, e.g.
1261         "egl,glx" @<:@default=auto@:>@])],
1262     [with_state_trackers="$withval"],
1263     [with_state_trackers=yes])
1264
1265 case "$with_state_trackers" in
1266 no)
1267     GALLIUM_STATE_TRACKERS_DIRS=""
1268     ;;
1269 yes)
1270     # look at what else is built
1271     case "$mesa_driver" in
1272     xlib)
1273         GALLIUM_STATE_TRACKERS_DIRS=glx
1274         ;;
1275     dri)
1276         GALLIUM_STATE_TRACKERS_DIRS="dri"
1277         HAVE_ST_DRI="yes"
1278         if test "x$enable_egl" = xyes; then
1279             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1280             HAVE_ST_EGL="yes"
1281         fi
1282         # Have only tested st/xorg on 1.6.0 servers
1283         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1284             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1285             HAVE_ST_XORG="no")
1286         ;;
1287     esac
1288     ;;
1289 *)
1290     # verify the requested state tracker exist
1291     state_trackers=""
1292     _state_trackers=`IFS=', '; echo $with_state_trackers`
1293     for tracker in $_state_trackers; do
1294         case "$tracker" in
1295         dri)
1296             if test "x$mesa_driver" != xdri; then
1297                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1298             fi
1299             HAVE_ST_DRI="yes"
1300             ;;
1301         egl)
1302             if test "x$enable_egl" != xyes; then
1303                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1304             fi
1305             HAVE_ST_EGL="yes"
1306             ;;
1307         xorg)
1308             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1309             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1310             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1311             HAVE_ST_XORG="yes"
1312             ;;
1313         es)
1314             AC_MSG_WARN([state tracker 'es' has been replaced by --enable-gles-overlay])
1315
1316             if test "x$enable_gles_overlay" != xyes; then
1317                 if test "x$enable_gles1" != xyes -a "x$enable_gles2" != xyes; then
1318                     CORE_DIRS="mapi/es1api mapi/es2api $CORE_DIRS"
1319                 fi
1320                 GLES_OVERLAY=1
1321                 EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1322             fi
1323             tracker=""
1324             ;;
1325         vega)
1326             CORE_DIRS="$CORE_DIRS mapi/vgapi"
1327             VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1328             EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1329             ;;
1330         esac
1331
1332         if test -n "$tracker"; then
1333             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1334                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1335             if test -n "$state_trackers"; then
1336                 state_trackers="$state_trackers $tracker"
1337             else
1338                 state_trackers="$tracker"
1339             fi
1340         fi
1341     done
1342     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1343     ;;
1344 esac
1345
1346 AC_SUBST([VG_LIB_DEPS])
1347 AC_SUBST([EGL_CLIENT_APIS])
1348
1349 if test "x$HAVE_ST_EGL" = xyes; then
1350         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1351         # define GLX_DIRECT_RENDERING even when the driver is not dri
1352         if test "x$mesa_driver" != xdri -a "x$driglx_direct" = xyes; then
1353             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1354         fi
1355 fi
1356
1357 if test "x$HAVE_ST_XORG" = xyes; then
1358     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1359         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1360         HAVE_XEXTPROTO_71="no")
1361 fi
1362
1363 AC_ARG_WITH([egl-platforms],
1364     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1365         [comma delimited native platforms libEGL supports, e.g.
1366         "x11,drm" @<:@default=auto@:>@])],
1367     [with_egl_platforms="$withval"],
1368     [with_egl_platforms=yes])
1369 AC_ARG_WITH([egl-displays],
1370     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1371         [DEPRECATED.  Use --with-egl-platforms instead])],
1372     [with_egl_platforms="$withval"])
1373
1374 EGL_PLATFORMS=""
1375 case "$with_egl_platforms" in
1376 yes)
1377     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1378         EGL_PLATFORMS="x11"
1379         if test "$mesa_driver" = dri; then
1380             EGL_PLATFORMS="$EGL_PLATFORMS drm"
1381         fi
1382     fi
1383     ;;
1384 *)
1385     if test "x$enable_egl" != xyes; then
1386         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1387     fi
1388     # verify the requested driver directories exist
1389     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1390     for plat in $egl_platforms; do
1391         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1392             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1393         if test "$plat" = "fbdev"; then
1394                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1395         fi
1396     done
1397     EGL_PLATFORMS="$egl_platforms"
1398     ;;
1399 esac
1400 AC_SUBST([EGL_PLATFORMS])
1401
1402 AC_ARG_WITH([egl-driver-dir],
1403     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1404                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1405     [EGL_DRIVER_INSTALL_DIR="$withval"],
1406     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1407 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1408
1409 AC_ARG_WITH([xorg-driver-dir],
1410     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1411                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1412     [XORG_DRIVER_INSTALL_DIR="$withval"],
1413     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1414 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1415
1416 AC_ARG_WITH([max-width],
1417     [AS_HELP_STRING([--with-max-width=N],
1418                     [Maximum framebuffer width (4096)])],
1419     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1420      AS_IF([test "${withval}" -gt "4096"],
1421            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1422 )
1423 AC_ARG_WITH([max-height],
1424     [AS_HELP_STRING([--with-max-height=N],
1425                     [Maximum framebuffer height (4096)])],
1426     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1427      AS_IF([test "${withval}" -gt "4096"],
1428            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1429 )
1430
1431 dnl
1432 dnl Gallium LLVM
1433 dnl
1434 AC_ARG_ENABLE([gallium-llvm],
1435     [AS_HELP_STRING([--enable-gallium-llvm],
1436         [build gallium LLVM support @<:@default=disabled@:>@])],
1437     [enable_gallium_llvm="$enableval"],
1438     [enable_gallium_llvm=auto])
1439 if test "x$enable_gallium_llvm" = xyes; then
1440     if test "x$LLVM_CONFIG" != xno; then
1441         LLVM_VERSION=`$LLVM_CONFIG --version`
1442         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1443         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1444
1445         if test "x$HAS_UDIS86" != xno; then
1446             LLVM_LIBS="$LLVM_LIBS -ludis86"
1447             DEFINES="$DEFINES -DHAVE_UDIS86"
1448         fi
1449         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1450         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1451         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1452         MESA_LLVM=1
1453     else
1454         MESA_LLVM=0
1455     fi
1456 else
1457     MESA_LLVM=0
1458 fi
1459
1460 dnl
1461 dnl Gallium helper functions
1462 dnl
1463 gallium_check_st() {
1464     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1465          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1466     fi
1467     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1468          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1469     fi
1470     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1471          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1472     fi
1473 }
1474
1475
1476 dnl
1477 dnl Gallium SVGA configuration
1478 dnl
1479 AC_ARG_ENABLE([gallium-svga],
1480     [AS_HELP_STRING([--enable-gallium-svga],
1481         [build gallium SVGA @<:@default=disabled@:>@])],
1482     [enable_gallium_svga="$enableval"],
1483     [enable_gallium_svga=auto])
1484 if test "x$enable_gallium_svga" = xyes; then
1485     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1486     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1487 elif test "x$enable_gallium_svga" = xauto; then
1488     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1489 fi
1490
1491 dnl
1492 dnl Gallium i915 configuration
1493 dnl
1494 AC_ARG_ENABLE([gallium-i915],
1495     [AS_HELP_STRING([--enable-gallium-i915],
1496         [build gallium i915 @<:@default=disabled@:>@])],
1497     [enable_gallium_i915="$enableval"],
1498     [enable_gallium_i915=auto])
1499 if test "x$enable_gallium_i915" = xyes; then
1500     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1501     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1502     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1503 elif test "x$enable_gallium_i915" = xauto; then
1504     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1505     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1506 fi
1507
1508 dnl
1509 dnl Gallium i965 configuration
1510 dnl
1511 AC_ARG_ENABLE([gallium-i965],
1512     [AS_HELP_STRING([--enable-gallium-i965],
1513         [build gallium i965 @<:@default=disabled@:>@])],
1514     [enable_gallium_i965="$enableval"],
1515     [enable_gallium_i965=auto])
1516 if test "x$enable_gallium_i965" = xyes; then
1517     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1518     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1519 elif test "x$enable_gallium_i965" = xauto; then
1520     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1521 fi
1522
1523 dnl
1524 dnl Gallium Radeon configuration
1525 dnl
1526 AC_ARG_ENABLE([gallium-radeon],
1527     [AS_HELP_STRING([--enable-gallium-radeon],
1528         [build gallium radeon @<:@default=disabled@:>@])],
1529     [enable_gallium_radeon="$enableval"],
1530     [enable_gallium_radeon=auto])
1531 if test "x$enable_gallium_radeon" = xyes; then
1532     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1533     gallium_check_st "radeon/drm" "dri-r300" "xorg-radeon"
1534 elif test "x$enable_gallium_radeon" = xauto; then
1535     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1536 fi
1537
1538 dnl
1539 dnl Gallium Radeon r600g configuration
1540 dnl
1541 AC_ARG_ENABLE([gallium-r600],
1542     [AS_HELP_STRING([--enable-gallium-r600],
1543         [build gallium radeon @<:@default=disabled@:>@])],
1544     [enable_gallium_r600="$enableval"],
1545     [enable_gallium_r600=auto])
1546 if test "x$enable_gallium_r600" = xyes; then
1547     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1548     gallium_check_st "r600/drm" "dri-r600"
1549 fi
1550
1551 dnl
1552 dnl Gallium Nouveau configuration
1553 dnl
1554 AC_ARG_ENABLE([gallium-nouveau],
1555     [AS_HELP_STRING([--enable-gallium-nouveau],
1556         [build gallium nouveau @<:@default=disabled@:>@])],
1557     [enable_gallium_nouveau="$enableval"],
1558     [enable_gallium_nouveau=no])
1559 if test "x$enable_gallium_nouveau" = xyes; then
1560     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1561     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau"
1562 fi
1563
1564 dnl
1565 dnl Gallium swrast configuration
1566 dnl
1567 AC_ARG_ENABLE([gallium-swrast],
1568     [AS_HELP_STRING([--enable-gallium-swrast],
1569         [build gallium swrast @<:@default=auto@:>@])],
1570     [enable_gallium_swrast="$enableval"],
1571     [enable_gallium_swrast=auto])
1572 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1573     if test "x$HAVE_ST_DRI" = xyes; then
1574         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1575     fi
1576 fi
1577
1578 dnl prepend CORE_DIRS to SRC_DIRS
1579 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1580
1581 dnl Restore LDFLAGS and CPPFLAGS
1582 LDFLAGS="$_SAVE_LDFLAGS"
1583 CPPFLAGS="$_SAVE_CPPFLAGS"
1584
1585 dnl Substitute the config
1586 AC_CONFIG_FILES([configs/autoconf])
1587
1588 dnl Replace the configs/current symlink
1589 AC_CONFIG_COMMANDS([configs],[
1590 if test -f configs/current || test -L configs/current; then
1591     rm -f configs/current
1592 fi
1593 ln -s autoconf configs/current
1594 ])
1595
1596 AC_OUTPUT
1597
1598 dnl
1599 dnl Output some configuration info for the user
1600 dnl
1601 echo ""
1602 echo "        prefix:          $prefix"
1603 echo "        exec_prefix:     $exec_prefix"
1604 echo "        libdir:          $libdir"
1605 echo "        includedir:      $includedir"
1606
1607 dnl Driver info
1608 echo ""
1609 echo "        Driver:          $mesa_driver"
1610 if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1611     echo "        OSMesa:          lib$OSMESA_LIB"
1612 else
1613     echo "        OSMesa:          no"
1614 fi
1615 if test "$mesa_driver" = dri; then
1616     # cleanup the drivers var
1617     dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1618 if test "x$DRI_DIRS" = x; then
1619     echo "        DRI drivers:     no"
1620 else
1621     echo "        DRI drivers:     $dri_dirs"
1622 fi
1623     echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1624 fi
1625 echo "        Use XCB:         $enable_xcb"
1626
1627 echo ""
1628 if test "x$MESA_LLVM" = x1; then
1629     echo "        llvm:            yes"
1630     echo "        llvm-config:     $LLVM_CONFIG"
1631     echo "        llvm-version:    $LLVM_VERSION"
1632 else
1633     echo "        llvm:            no"
1634 fi
1635
1636 echo ""
1637 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1638     echo "        Gallium:         yes"
1639     echo "        Gallium dirs:    $GALLIUM_DIRS"
1640     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1641     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1642     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1643     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1644     if test "x$HAVE_ST_EGL" = xyes; then
1645         echo "        EGL client APIs: $EGL_CLIENT_APIS"
1646     fi
1647 else
1648     echo "        Gallium:         no"
1649 fi
1650
1651 dnl Libraries
1652 echo ""
1653 echo "        Shared libs:     $enable_shared"
1654 echo "        Static libs:     $enable_static"
1655 if test "$enable_egl" = yes; then
1656     echo "        EGL:             $EGL_DRIVERS_DIRS"
1657     echo "        EGL platforms:   $EGL_PLATFORMS"
1658 else
1659     echo "        EGL:             no"
1660 fi
1661 echo "        GLU:             $enable_glu"
1662 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1663 echo "        glut:            $enable_glut"
1664
1665 dnl Compiler options
1666 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1667 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1668     $SED 's/^ *//;s/  */ /;s/ *$//'`
1669 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1670     $SED 's/^ *//;s/  */ /;s/ *$//'`
1671 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1672 echo ""
1673 echo "        CFLAGS:          $cflags"
1674 echo "        CXXFLAGS:        $cxxflags"
1675 echo "        Macros:          $defines"
1676
1677 echo ""
1678 echo "        Run '${MAKE-make}' to build Mesa"
1679 echo ""