configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003,
   4 # 2004, 2006, 2007, 2008, 2009, 2010, 2011, 2012 Free Software
   5 # Foundation, Inc.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.68])
  21 AC_INIT([GNU Automake], [1.11a], [bug-automake@gnu.org])
  22
  23 AC_CONFIG_SRCDIR([automake.in])
  24 AC_CONFIG_AUX_DIR([lib])
  25
  26 AM_SILENT_RULES([yes])
  27
  28 AC_CANONICAL_HOST
  29 AC_CANONICAL_BUILD
  30
  31 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  32 # way we can run Autoconf tests from configure (or from the test
  33 # suite) without being bothered by `missing'.  Likewise for autom4te,
  34 # autoreconf, autoheader, and autoupdate.
  35 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  36 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  37 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  38 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  39 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  40
  41 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  42 dnl testsuite, so also use `no-dependencies' and `no-define' among
  43 dnl the automake options to avoid bloating and potential problems.
  44 AM_INIT_AUTOMAKE([1.10a dist-xz filename-length-max=99 color-tests
  45                   parallel-tests silent-rules no-define no-dependencies])
  46
  47 # The API version is the base version.  We must guarantee
  48 # compatibility for all releases with the same API version.
  49 # Our current rule is that:
  50 # * All releases, including the prereleases, in an X.Y series
  51 #   are compatible.  So 1.5.1c is compatible with 1.5.
  52 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  53 #   aren't the same.
  54 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  55 AC_SUBST([APIVERSION])
  56
  57 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  58 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  59 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  60 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  61 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  62
  63 # $AUTOMAKE and $ACLOCAL are always run after a `cd $top_srcdir',
  64 # hence `.' is really what we want for perllibdir, libdir, and acdir.
  65 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  66 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  67
  68 AC_PATH_PROG([PERL], [perl])
  69 if test -z "$PERL"; then
  70    AC_MSG_ERROR([perl not found])
  71 fi
  72 # Save details about the selected perl interpreter in config.log.
  73 AM_RUN_LOG([$PERL --version])
  74 $PERL -e 'require 5.006;' || {
  75    AC_MSG_ERROR(
  76 [perl 5.6 or better is required; perl 5.8.2 or better
  77 is recommended.  If you have several perl versions
  78 installed, select the one Automake should use using
  79   ./configure PERL=/path/to/perl])
  80 }
  81
  82 # We require ithreads support, and version 5.7.2 for CLONE.
  83 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  84 [if $PERL -e '
  85     require 5.007_002;
  86     use Config;
  87     if ($Config{useithreads})
  88       {
  89         require threads;
  90         import threads;
  91         require Thread::Queue;
  92         import Thread::Queue;
  93         exit 0;
  94       }
  95     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  96 then
  97   am_cv_prog_PERL_ithreads=yes
  98 else
  99   am_cv_prog_PERL_ithreads=no
 100 fi])
 101 if test $am_cv_prog_PERL_ithreads = yes; then
 102   PERL_THREADS=1;
 103 else
 104   PERL_THREADS=0;
 105 fi
 106 AC_SUBST([PERL_THREADS])
 107
 108 # The test suite will skip some tests if tex is absent.
 109 AC_CHECK_PROG([TEX], [tex], [tex])
 110 # Save details about the selected TeX program in config.log.
 111 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 112 # for input from the terminal.
 113 AM_RUN_LOG([$TEX --version </dev/null])
 114
 115 # Generate man pages.
 116 AM_MISSING_PROG([HELP2MAN], [help2man])
 117
 118 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 119 # deletion of any files created (such as those added to
 120 # autom4te.cache).  We used to perform only the last of the three
 121 # following tests, but some users were unable to figure out that their
 122 # installation was broken since --version appeared to work.
 123
 124 required_autoconf_version=2.62
 125 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 126 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 127 then
 128   am_cv_autoconf_installed=yes
 129 else
 130   am_cv_autoconf_installed=no
 131 fi])
 132 if test "$am_cv_autoconf_installed" = no; then
 133   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 134     Please make sure it is installed and in your PATH.])
 135 fi
 136
 137 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 138 [mkdir conftest
 139 echo 'AC''_INIT' > conftest/conftest.ac
 140 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 141 then
 142   am_cv_autoconf_works=yes
 143 else
 144   am_cv_autoconf_works=no
 145 fi
 146 rm -rf conftest])
 147 if test "$am_cv_autoconf_works" = no; then
 148   AC_MSG_ERROR([The installed version of autoconf does not work.
 149     Please check config.log for error messages before this one.])
 150 fi
 151
 152 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 153 [mkdir conftest
 154 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 155 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 156 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 157 then
 158   am_cv_autoconf_version=yes
 159 else
 160   am_cv_autoconf_version=no
 161 fi
 162 rm -rf conftest])
 163 if test "$am_cv_autoconf_version" = no; then
 164   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 165 fi
 166
 167 # Test for ln.  We need use it to install the versioned binaries.
 168 AC_MSG_CHECKING([whether ln works])
 169 AC_CACHE_VAL([am_cv_prog_ln], [
 170 rm -f conftest conftest.file
 171 : >conftest.file
 172 if ln conftest.file conftest 2>/dev/null; then
 173   am_cv_prog_ln=ln
 174 else
 175   am_cv_prog_ln='cp -p'
 176 fi
 177 rm -f conftest conftest.file])
 178 AC_SUBST([LN], [$am_cv_prog_ln])
 179 result=no
 180 test "x$am_cv_prog_ln" = xln && result=yes
 181 AC_MSG_RESULT([$result])
 182
 183 # The amount we should wait after modifying files depends on the platform.
 184 # On Windows '95, '98 and ME, files modifications have 2-seconds
 185 # granularity and can be up to 3 seconds in the future w.r.t. the
 186 # system clock.  When it is important to ensure one file is older
 187 # than another we wait at least 5 seconds between creations.
 188 case $build in
 189   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 190   *)               MODIFICATION_DELAY=2;;
 191 esac
 192 AC_SUBST([MODIFICATION_DELAY])
 193
 194 # Test for things needed by the test suite.
 195 AC_PROG_EGREP
 196 AC_PROG_FGREP
 197
 198 AC_CACHE_CHECK([whether $SHELL has working 'set -e' with exit trap],
 199 [am_cv_sh_errexit_works],
 200 [if $SHELL -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 201 then
 202   am_cv_sh_errexit_works=yes
 203 else
 204   am_cv_sh_errexit_works=no
 205 fi
 206 ])
 207 if test $am_cv_sh_errexit_works = no; then
 208   AC_MSG_WARN([`${MAKE-make} check' will leave leftover directories tests/*.dir])
 209   AC_MSG_WARN([you can clean them up manually using `${MAKE-make} clean' or])
 210   AC_MSG_WARN([`cd tests && ${MAKE-make} clean-local-check'])
 211   dnl restore font-lock: `
 212 fi
 213 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 214
 215
 216 ###########################################################################
 217
 218 # Look for C, C++ and fortran compilers to be used in the testsuite.
 219
 220 dnl We don't want to abort our configuration script if no C compiler is
 221 dnl available, as such a compiler is only required to run part of the
 222 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 223 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 224 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 225
 226 dnl We want the body of this macro to expand as a single shell statement,
 227 dnl thus we wrap it into { ... } brackets.
 228 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 229   AC_MSG_WARN([$1])
 230   am__failed=yes
 231   break
 232 } ])
 233
 234 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 235   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 236   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 237   am__failed=no
 238   while :; do
 239      $1
 240      break
 241   done
 242   AS_IF([test $am__failed = yes], [$2])
 243   # We have to clear these cache variables, so that future checks on
 244   # compilers for different languages won't be confused.
 245   unset ac_cv_objext ac_cv_exeext
 246   # We also need to meddle with the autoconf internals to ensure that
 247   # checks to find object and executable extensions will be run anew.
 248   # FIXME: In the long run, the better thing to do would be to fix
 249   # FIXME: autoconf instead ...
 250   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 251   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 252   m4_popdef([AC_MSG_FAILURE])
 253   m4_popdef([AC_MSG_ERROR])
 254 ])
 255
 256 # Prefer generic compilers to GNU ones when possible.  This will ensure
 257 # more testsuite coverage "in the wild".
 258 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 259 # deliberate; for more discussion an rationale, see:
 260 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 261
 262 # C compiler.
 263 _AM_COMPILER_CAN_FAIL([AC_PROG_CC([cc gcc])], [CC=false])
 264 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 265
 266 # The list of C++ compilers here has been copied, pasted and edited
 267 # from `lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 268 # Keep it in sync, or better again, find out a way to avoid this code
 269 # duplication.
 270 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 271   [aCC CC FCC KCC RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 272   [CXX=false])
 273 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 274
 275 # The lists of Fortran compilers here has been copied, pasted and edited
 276 # from file `lib/autoconf/fortran.m4' in the Autoconf distribution.
 277 # Keep it in sync, or better again, find out a way to avoid this code
 278 # duplication.
 279
 280 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 281   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 282   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 283   [FC=false])
 284 # FIXME this won't work as expected until we can assume autoconf 2.69 :-(
 285 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 286
 287 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 288   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 289   [F77=false])
 290 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 291
 292 # Some tests will need the GNU compilers.  Searching for them here would
 293 # be overkill, since our testsuite already handles their search and setup
 294 # pretty well.  However, in case the compilers detected above at configure
 295 # time are not the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS,
 296 # FCFLAGS and FFLAGS detected for them with the GNU compilers too, since
 297 # it's likely they won't be compatible.  So we allow the user to define
 298 # variants of this variables for the GNU compilers separately.
 299
 300 test $am_CC_is_GNU = yes && GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 301 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 302
 303 test $am_CXX_is_GNU = yes && GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 304 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 305
 306 test $am_F77_is_GNU = yes && GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 307 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 308
 309 test $am_FC_is_GNU = yes && GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 310 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 311
 312 # If we have been able to find at least a working compiler above, we
 313 # know what the object and executable extensions for this platform are.
 314 OBJEXT=${ac_cv_objext-UNKNOWN}
 315 EXEEXT=${ac_cv_exeext-UNKNOWN}
 316 AC_SUBST([OBJEXT])
 317 AC_SUBST([EXEEXT])
 318
 319 ###########################################################################
 320
 321 AC_CONFIG_FILES([
 322   Makefile
 323   contrib/Makefile
 324   doc/Makefile
 325   lib/Automake/Makefile
 326   lib/Makefile
 327   lib/am/Makefile
 328   m4/Makefile
 329   tests/Makefile
 330 ])
 331 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 332 AC_CONFIG_LINKS([tests/defs:tests/defs])
 333 AC_CONFIG_FILES([tests/aclocal-${APIVERSION}:tests/aclocal.in],
 334                 [chmod +x tests/aclocal-${APIVERSION}],
 335                 [APIVERSION=$APIVERSION])
 336 AC_CONFIG_FILES([tests/automake-${APIVERSION}:tests/automake.in],
 337                 [chmod +x tests/automake-${APIVERSION}])
 338
 339 AC_OUTPUT
 340
 341 # Inform the user if this version of automake is a beta release or
 342 # a development snapshot.
 343 # According to HACKING, the version of a development snapshot should
 344 # end with an "odd" letter (a, c, ...), the version of a test release
 345 # should end wit an "even" letter (b, d, ...).
 346
 347 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 348 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 349
 350 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 351   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 352   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 353   { print \"development snapshot\"; }"]`
 354
 355 test "$am_release_type" = stable || cat <<EOF
 356
 357 WARNING: You are about to use a $am_release_type of automake.
 358 WARNING: It might easily suffer from new bugs or regressions.
 359 WARNING: You are strongly advised not to use it in production code.
 360
 361 Please report bugs, problems and feedback to <bug-automake@gnu.org>.
 362 EOF
 363
 364 AS_EXIT([0])