configure.ac

   1 dnl  Copyright 2005 Red Hat, Inc.
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Red Hat not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Red Hat makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  RED HAT DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL RED HAT BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 AC_PREREQ([2.57])
  24
  25 #   Pixman versioning scheme
  26 #
  27 #   - The version in git has an odd MICRO version number
  28 #
  29 #   - Released versions both development and stable have an even MICRO
  30 #     version number
  31 #
  32 #   - Released development versions have an odd MINOR number
  33 #
  34 #   - Released stable versions have an event MINOR number
  35 #
  36 #   - Versions that break ABI must have a new MAJOR number
  37 #
  38 #   - If you break the ABI, then at least this must be done:
  39 #
  40 #        - increment MAJOR
  41 #
  42 #        - In the first development release where you break ABI, find
  43 #          all instances of "pixman-n" and change them to pixman-(n+1)
  44 #
  45 #          This needs to be done at least in
  46 #                    configure.ac
  47 #                    all Makefile.am's
  48 #                    pixman-n.pc.in
  49 #
  50 #      This ensures that binary incompatible versions can be installed
  51 #      in parallel.  See http://www106.pair.com/rhp/parallel.html for
  52 #      more information
  53 #
  54
  55 m4_define([pixman_major], 0)
  56 m4_define([pixman_minor], 11)
  57 m4_define([pixman_micro], 8)
  58
  59 m4_define([pixman_version],[pixman_major.pixman_minor.pixman_micro])
  60
  61 AC_INIT(pixman, pixman_version, "sandmann@daimi.au.dk", pixman)
  62 AM_INIT_AUTOMAKE([dist-bzip2])
  63
  64 AM_CONFIG_HEADER(config.h)
  65
  66 AC_PROG_CC
  67 AC_PROG_LIBTOOL
  68 AC_CHECK_FUNCS([getisax])
  69 AC_C_BIGENDIAN
  70
  71 #
  72 # We ignore pixman_major in the version here because the major version should
  73 # always be encoded in the actual library name. Ie., the soname is:
  74 #
  75 #      pixman-$(pixman_major).0.minor.micro
  76 #
  77 m4_define([lt_current], [pixman_minor])
  78 m4_define([lt_revision], [pixman_micro])
  79 m4_define([lt_age], [pixman_minor])
  80
  81 LT_VERSION_INFO="lt_current:lt_revision:lt_age"
  82
  83 PIXMAN_VERSION_MAJOR=pixman_major()
  84 AC_SUBST(PIXMAN_VERSION_MAJOR)
  85 PIXMAN_VERSION_MINOR=pixman_minor()
  86 AC_SUBST(PIXMAN_VERSION_MINOR)
  87 PIXMAN_VERSION_MICRO=pixman_micro()
  88 AC_SUBST(PIXMAN_VERSION_MICRO)
  89
  90 AC_SUBST(LT_VERSION_INFO)
  91
  92 # Check for dependencies
  93 #PKG_CHECK_MODULES(DEP, x11)
  94
  95 changequote(,)dnl
  96 if test "x$GCC" = "xyes"; then
  97   case " $CFLAGS " in
  98   *[\ \ ]-Wall[\ \      ]*) ;;
  99   *) CFLAGS="$CFLAGS -Wall" ;;
 100   esac fi changequote([,])dnl
 101
 102 AC_PATH_PROG(PERL, perl, no)
 103 if test "x$PERL" = xno; then
 104     AC_MSG_ERROR([Perl is required to build pixman.])
 105 fi
 106 AC_SUBST(PERL)
 107
 108 dnl =========================================================================
 109 dnl -fvisibility stuff
 110
 111 have_gcc4=no
 112 AC_MSG_CHECKING(for -fvisibility)
 113 AC_COMPILE_IFELSE([
 114 #if defined(__GNUC__) && (__GNUC__ >= 4)
 115 #else
 116 #error Need GCC 4.0 for visibility
 117 #endif
 118 int main () { return 0; }
 119 ], have_gcc4=yes)
 120
 121 if test "x$have_gcc4" = "xyes"; then
 122    CFLAGS="$CFLAGS -fvisibility=hidden"
 123 fi
 124 AC_MSG_RESULT($have_gcc4)
 125
 126 dnl ===========================================================================
 127 dnl Check for MMX
 128
 129 MMX_CFLAGS="-mmmx -Winline"
 130
 131 if test "x$GCC" = "xyes"; then
 132     MMX_CFLAGS="$MMX_CFLAGS --param inline-unit-growth=10000 --param large-function-growth=10000"
 133 fi
 134
 135 have_mmx_intrinsics=no
 136 AC_MSG_CHECKING(whether to use MMX intrinsics)
 137 xserver_save_CFLAGS=$CFLAGS
 138 CFLAGS="$CFLAGS $MMX_CFLAGS"
 139 AC_COMPILE_IFELSE([
 140 #if defined(__GNUC__) && (__GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 4))
 141 #error "Need GCC >= 3.4 for MMX intrinsics"
 142 #endif
 143 #include <mmintrin.h>
 144 int main () {
 145     __m64 v = _mm_cvtsi32_si64 (1);
 146     return _mm_cvtsi64_si32 (v);
 147 }], have_mmx_intrinsics=yes)
 148 CFLAGS=$xserver_save_CFLAGS
 149
 150 AC_ARG_ENABLE(mmx,
 151    [AC_HELP_STRING([--disable-mmx],
 152                    [disable MMX fast paths])],
 153    [enable_mmx=$enableval], [enable_mmx=auto])
 154
 155 if test $enable_mmx = no ; then
 156    have_mmx_intrinsics=disabled
 157 fi
 158
 159 if test $have_mmx_intrinsics = yes ; then
 160    AC_DEFINE(USE_MMX, 1, [use MMX compiler intrinsics])
 161 else
 162    MMX_CFLAGS=
 163 fi
 164
 165 AC_MSG_RESULT($have_mmx_intrinsics)
 166 if test $enable_mmx = yes && test $have_mmx_intrinsics = no ; then
 167    AC_MSG_ERROR([MMX intrinsics not detected])
 168 fi
 169
 170 AM_CONDITIONAL(USE_MMX, test $have_mmx_intrinsics = yes)
 171
 172 dnl =======================================================
 173
 174 dnl GCC 4.2 when compiling with -msse will generate SSE instructions
 175 dnl on its own.  This means anything compiled with -mss can only be
 176 dnl run after a runtime check for SSE.  Unfortunately, since we still
 177 dnl need to support MMX-but-not-SSE (such as the OLPC), this means we
 178 dnl can only use SSE when compiling for x86-64 (where SSE is always
 179 dnl supported).
 180
 181 have_sse_intrinsics=no
 182 AC_MSG_CHECKING(whether to use SSE intrinsics)
 183 xserver_save_CFLAGS=$CFLAGS
 184 CFLAGS="$CFLAGS -msse $MMX_CFLAGS"
 185
 186 AC_COMPILE_IFELSE([
 187 #if defined(__GNUC__) && (__GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 4))
 188 #error "Need GCC >= 3.4 for SSE intrinsics"
 189 #endif
 190 #if !defined(__amd64__) && !defined(__x86_64__)
 191 #error "Need x86-64 for SSE"
 192 #endif
 193 #include <mmintrin.h>
 194 #include <xmmintrin.h>
 195 int main () {
 196     __m64 v = _mm_cvtsi32_si64 (1);
 197     v = _mm_shuffle_pi16 (v, _MM_SHUFFLE(3, 3, 3, 3));
 198     return _mm_cvtsi64_si32 (v);
 199 }], have_sse_intrinsics=yes)
 200 CFLAGS=$xserver_save_CFLAGS
 201 AC_MSG_RESULT($have_sse_intrinsics)
 202
 203 if test $have_sse_intrinsics = yes ; then
 204    AC_DEFINE(USE_SSE, 1, [use SSE compiler intrinsics])
 205    MMX_CFLAGS="-msse $MMX_CFLAGS"
 206 fi
 207
 208 AM_CONDITIONAL(USE_SSE, test $have_sse_intrinsics = yes)
 209
 210
 211 dnl ===========================================================================
 212 dnl Check for SSE2
 213
 214 SSE_CFLAGS="-mmmx -msse2 -Winline"
 215
 216 if test "x$GCC" = "xyes"; then
 217     SSE_CFLAGS="$SSE_CFLAGS --param inline-unit-growth=10000 --param large-function-growth=10000 --param  max-inline-insns-single=6000"
 218 fi
 219
 220 have_sse2_intrinsics=no
 221 AC_MSG_CHECKING(whether to use SSE2 intrinsics)
 222 xserver_save_CFLAGS=$CFLAGS
 223 CFLAGS="$CFLAGS -msse2 $SSE_CFLAGS"
 224
 225 AC_COMPILE_IFELSE([
 226 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 2))
 227 #error "Need GCC >= 4.2 for SSE2 intrinsics"
 228 #endif
 229 #include <mmintrin.h>
 230 #include <xmmintrin.h>
 231 #include <emmintrin.h>
 232 int main () {
 233     __m128i a, b, c;
 234         c = _mm_xor_si128 (a, b);
 235     return 0;
 236 }], have_sse2_intrinsics=yes)
 237 CFLAGS=$xserver_save_CFLAGS
 238
 239 AC_ARG_ENABLE(sse2,
 240    [AC_HELP_STRING([--disable-sse2],
 241                    [disable SSE2 fast paths])],
 242    [enable_sse2=$enableval], [enable_sse2=auto])
 243
 244 if test $enable_sse2 = no ; then
 245    have_sse2_intrinsics=disabled
 246 fi
 247
 248 if test $have_sse2_intrinsics = yes ; then
 249    AC_DEFINE(USE_SSE2, 1, [use SSE2 compiler intrinsics])
 250 fi
 251
 252 AC_MSG_RESULT($have_sse2_intrinsics)
 253 if test $enable_sse2 = yes && test $have_sse_intrinsics = no ; then
 254    AC_MSG_ERROR([SSE2 intrinsics not detected])
 255 fi
 256
 257 AM_CONDITIONAL(USE_SSE2, test $have_sse2_intrinsics = yes)
 258
 259 dnl ========================================================
 260 AC_SUBST(MMX_CFLAGS)
 261 AC_SUBST(SSE_CFLAGS)
 262
 263 dnl Check for VMX/Altivec
 264 if test -n "`$CC -v 2>&1 | grep version | grep Apple`"; then
 265     VMX_CFLAGS="-faltivec"
 266 else
 267     VMX_CFLAGS="-maltivec -mabi=altivec"
 268 fi
 269
 270 have_vmx_intrinsics=no
 271 AC_MSG_CHECKING(whether to use VMX/Altivec intrinsics)
 272 xserver_save_CFLAGS=$CFLAGS
 273 CFLAGS="$CFLAGS $VMX_CFLAGS"
 274 AC_COMPILE_IFELSE([
 275 #if defined(__GNUC__) && (__GNUC__ < 3 || (__GNUC__ == 3 && __GNUC_MINOR__ < 4))
 276 #error "Need GCC >= 3.4 for sane altivec support"
 277 #endif
 278 #include <altivec.h>
 279 int main () {
 280     vector unsigned int v = vec_splat_u32 (1);
 281     v = vec_sub (v, v);
 282     return 0;
 283 }], have_vmx_intrinsics=yes)
 284 CFLAGS=$xserver_save_CFLAGS
 285
 286 AC_ARG_ENABLE(vmx,
 287    [AC_HELP_STRING([--disable-vmx],
 288                    [disable VMX fast paths])],
 289    [enable_vmx=$enableval], [enable_vmx=auto])
 290
 291 if test $enable_vmx = no ; then
 292    have_vmx_intrinsics=disabled
 293 fi
 294
 295 if test $have_vmx_intrinsics = yes ; then
 296    AC_DEFINE(USE_VMX, 1, [use VMX compiler intrinsics])
 297 else
 298    VMX_CFLAGS=
 299 fi
 300
 301 AC_MSG_RESULT($have_vmx_intrinsics)
 302 if test $enable_vmx = yes && test $have_vmx_intrinsics = no ; then
 303    AC_MSG_ERROR([VMX intrinsics not detected])
 304 fi
 305
 306 AC_SUBST(VMX_CFLAGS)
 307
 308 AM_CONDITIONAL(USE_VMX, test $have_vmx_intrinsics = yes)
 309
 310 AC_ARG_ENABLE(gtk,
 311    [AC_HELP_STRING([--enable-gtk],
 312                    [enable tests using GTK+ [default=auto]])],
 313    [enable_gtk=$enableval], [enable_gtk=auto])
 314
 315 PKG_PROG_PKG_CONFIG
 316 if test $enable_gtk = auto ; then
 317    PKG_CHECK_EXISTS([gtk+-2.0], [enable_gtk=yes], [enable_gtk=no])
 318 fi
 319 if test $enable_gtk = yes ; then
 320    PKG_CHECK_MODULES(GTK, [gtk+-2.0])
 321 fi
 322
 323 AM_CONDITIONAL(HAVE_GTK, [test "x$enable_gtk" = xyes])
 324
 325 AC_SUBST(GTK_CFLAGS)
 326 AC_SUBST(GTK_LIBS)
 327 AC_SUBST(DEP_CFLAGS)
 328 AC_SUBST(DEP_LIBS)
 329
 330 AC_OUTPUT([pixman-1.pc
 331            pixman-1-uninstalled.pc
 332            Makefile
 333            pixman/Makefile
 334            pixman/pixman-version.h
 335            test/Makefile])