configure.ac

   1 dnl -*- mode: m4 -*-
   2 AC_PREREQ([2.63])
   3
   4 m4_define([dbus_major_version], [1])
   5 m4_define([dbus_minor_version], [11])
   6 m4_define([dbus_micro_version], [10])
   7 m4_define([dbus_version],
   8           [dbus_major_version.dbus_minor_version.dbus_micro_version])
   9 AC_INIT([dbus],[dbus_version],[https://bugs.freedesktop.org/enter_bug.cgi?product=dbus],[dbus])
  10
  11 AC_CONFIG_AUX_DIR([build-aux])
  12
  13 m4_pattern_forbid([^AX_],
  14   [Unexpanded AX_ macro found. Please install GNU autoconf-archive])
  15
  16 AC_CANONICAL_HOST
  17
  18 AC_CONFIG_HEADERS([config.h])
  19 AC_CONFIG_MACRO_DIR([m4])
  20
  21 AM_INIT_AUTOMAKE([1.13 tar-ustar -Wno-portability subdir-objects])
  22
  23 GETTEXT_PACKAGE=dbus-1
  24 AC_SUBST(GETTEXT_PACKAGE)
  25 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[The name of the gettext domain])
  26
  27 # By default, rebuild autotools files on demand; only use ./missing if the
  28 # user says --disable-maintainer-mode (some distributions like to do this)
  29 AM_MAINTAINER_MODE([enable])
  30
  31 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  32
  33 AC_DEFINE_UNQUOTED(DBUS_DAEMON_NAME,"dbus-daemon",[Name of executable])
  34
  35 # libtool versioning - this applies to libdbus
  36 #
  37 # See http://sources.redhat.com/autobook/autobook/autobook_91.html#SEC91 for details
  38 #
  39
  40 ## increment if the interface has additions, changes, removals.
  41 LT_CURRENT=19
  42
  43 ## increment any time the source changes; set to
  44 ##  0 if you increment CURRENT
  45 LT_REVISION=4
  46
  47 ## increment if any interfaces have been added; set to 0
  48 ## if any interfaces have been changed or removed. removal has
  49 ## precedence over adding, so set to 0 if both happened.
  50 LT_AGE=16
  51
  52 AC_SUBST(LT_CURRENT)
  53 AC_SUBST(LT_REVISION)
  54 AC_SUBST(LT_AGE)
  55 SOVERSION=`expr ${LT_CURRENT} - ${LT_AGE}`
  56 AC_SUBST([SOVERSION])
  57
  58 DBUS_MAJOR_VERSION=dbus_major_version
  59 DBUS_MINOR_VERSION=dbus_minor_version
  60 DBUS_MICRO_VERSION=dbus_micro_version
  61 DBUS_VERSION=dbus_major_version.dbus_minor_version.dbus_micro_version
  62
  63 AC_SUBST(DBUS_MAJOR_VERSION)
  64 AC_SUBST(DBUS_MINOR_VERSION)
  65 AC_SUBST(DBUS_MICRO_VERSION)
  66 AC_SUBST(DBUS_VERSION)
  67
  68 dnl
  69 dnl Build configuration
  70 dnl
  71
  72 dnl This must come first: other options use this to set their defaults. Don't
  73 dnl enable developer mode on production builds.
  74 AC_ARG_ENABLE([developer],
  75   [AS_HELP_STRING([--enable-developer],
  76     [set defaults to be appropriate for a D-Bus developer instead of a distribution/end-user])],
  77   [enable_developer=$enableval],
  78   [enable_developer=no])
  79
  80 dnl 'disable_developer' is the negation of 'enable_developer'. If
  81 dnl 'enable-developer' is set to 'no' (the default), the value of
  82 dnl 'disable_developer' is set to 'yes', and vice versa. It's used
  83 dnl for macros that require the opposite of 'enable_developer', such
  84 dnl as several AX_ macros.
  85 dnl See https://bugs.freedesktop.org/show_bug.cgi?id=97357
  86 AS_IF([test "x$enable_developer" = "xyes"],[
  87     disable_developer=no
  88   ],[
  89     disable_developer=yes
  90   ])
  91
  92 # The debugging check must run before the compiler tests. Other command-line
  93 # options also use it to set their defaults. We disable debugging by default,
  94 # except for developer builds.
  95 AX_CHECK_ENABLE_DEBUG([$enable_developer])
  96
  97 AC_PROG_CC
  98 AM_PROG_CC_C_O
  99 AC_PROG_CXX
 100 AC_USE_SYSTEM_EXTENSIONS
 101 AC_SYS_LARGEFILE
 102 AC_ISC_POSIX
 103 AC_HEADER_STDC
 104 AC_C_INLINE
 105 AM_PROG_LIBTOOL
 106 AC_PROG_MKDIR_P
 107 PKG_PROG_PKG_CONFIG
 108
 109 # TAP test driver support
 110 AC_PROG_AWK
 111 AC_REQUIRE_AUX_FILE([tap-driver.sh])
 112
 113 # This must come before we set up compiler warnings because it assumes
 114 # non-use of -Werror=missing-prototypes
 115 gl_VISIBILITY
 116 AM_CONDITIONAL([HAVE_VISIBILITY], [test "x$HAVE_VISIBILITY" = x1])
 117
 118 # Initialize libtool
 119 LT_INIT([win32-dll])
 120 LT_LANG([Windows Resource])
 121
 122 # Set some internal variables depending on the platform for later use.
 123 dbus_win=no
 124 dbus_cygwin=no
 125 dbus_unix=no
 126 case "${host}" in
 127     *-mingw32ce*)
 128         dbus_win=yes
 129         dbus_wince=yes
 130         ;;
 131     *-mingw32*)
 132         dbus_win=yes
 133         ;;
 134     *-cygwin*)
 135         dbus_cygwin=yes
 136         dbus_unix=yes
 137         ;;
 138     *)
 139         dbus_unix=yes
 140        ;;
 141 esac
 142
 143 # Special defines for certain platforms
 144 if test "$dbus_win" = yes; then
 145     AC_DEFINE(DBUS_WIN,1,[Defined if we run on a W32 API based system])
 146     # Yes, on Windows it really does work like this.
 147     # http://support.microsoft.com/kb/111855
 148     AC_DEFINE(FD_SETSIZE,8192,[The maximum number of connections that can be handled at once])
 149     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 150     AC_SUBST(BUILD_TIMESTAMP)
 151     # Assume DBUS_VERSION is always three numbers
 152     BUILD_FILEVERSION=`echo "$DBUS_VERSION" | sed -e 's/\./,/g'`,0
 153     AC_SUBST(BUILD_FILEVERSION)
 154     AC_CHECK_TOOL(WINDRES, windres, no)
 155     if test "$WINDRES" = no; then
 156       AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 157     fi
 158     if test "$dbus_wince" = yes; then
 159       AC_DEFINE(DBUS_WINCE,1,[Defined if we run on a W32 CE API based system])
 160       AC_DEFINE(_WIN32_WCE, 0x0502, [Defined to get newer W32 CE APIs])
 161     fi
 162 else
 163     AC_DEFINE(DBUS_UNIX,1,[Defined if we run on a Unix-based system])
 164 fi
 165 if test "$dbus_cygwin" = yes; then
 166     AC_DEFINE(DBUS_CYGWIN,1,[Defined if we run on a cygwin API based system])
 167 fi
 168
 169 # For best security, assume that all non-Windows platforms can do
 170 # credentials-passing.
 171 AS_IF([test "$dbus_win" = yes],
 172     [DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL="<!--<auth>EXTERNAL</auth>-->"],
 173     [DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL="<auth>EXTERNAL</auth>"])
 174 AC_SUBST([DBUS_SESSION_CONF_MAYBE_AUTH_EXTERNAL])
 175
 176 AM_CONDITIONAL(DBUS_WIN, test "$dbus_win" = yes)
 177 AM_CONDITIONAL(DBUS_WINCE, test "$dbus_wince" = yes)
 178 AM_CONDITIONAL(DBUS_UNIX, test "$dbus_unix" = yes)
 179 AM_CONDITIONAL(DBUS_CYGWIN, test "$dbus_cygwin" = yes)
 180
 181 DBUS_STATIC_BUILD_CPPFLAGS=
 182 if test "x$enable_shared" = xno; then
 183     # On Windows, linking against the static library requires special effort
 184     # to turn off DLL import/export processing. We normally link some things
 185     # against the dynamic library, but if we're not building that, we'll
 186     # have to link everything statically.
 187     DBUS_STATIC_BUILD_CPPFLAGS=-DDBUS_STATIC_BUILD
 188 fi
 189 AC_SUBST([DBUS_STATIC_BUILD_CPPFLAGS])
 190
 191 AC_ARG_ENABLE(ansi, AS_HELP_STRING([--enable-ansi],[enable -ansi -pedantic gcc flags]),enable_ansi=$enableval,enable_ansi=no)
 192 AC_ARG_ENABLE(verbose-mode, AS_HELP_STRING([--enable-verbose-mode],[support verbose debug mode]),enable_verbose_mode=$enableval,enable_verbose_mode=$enable_developer)
 193 AC_ARG_ENABLE(asserts, AS_HELP_STRING([--enable-asserts],[include assertion checks]),enable_asserts=$enableval,enable_asserts=$enable_developer)
 194 AC_ARG_ENABLE(checks, AS_HELP_STRING([--enable-checks],[include sanity checks on public API]),enable_checks=$enableval,enable_checks=yes)
 195 AC_ARG_ENABLE(xml-docs, AS_HELP_STRING([--enable-xml-docs],[build XML documentation (requires xmlto)]),enable_xml_docs=$enableval,enable_xml_docs=auto)
 196 AC_ARG_ENABLE(doxygen-docs, AS_HELP_STRING([--enable-doxygen-docs],[build DOXYGEN documentation (requires Doxygen)]),enable_doxygen_docs=$enableval,enable_doxygen_docs=auto)
 197 AC_ARG_ENABLE([ducktype-docs],
 198               AS_HELP_STRING([--enable-ducktype-docs],
 199                              [build Ducktype documentation (requires Ducktype)]),
 200               [enable_ducktype_docs=$enableval], [enable_ducktype_docs=auto])
 201 AC_ARG_ENABLE(abstract-sockets, AS_HELP_STRING([--enable-abstract-sockets],[use abstract socket namespace (linux only)]),enable_abstract_sockets=$enableval,enable_abstract_sockets=auto)
 202 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--enable-selinux],[build with SELinux support]),enable_selinux=$enableval,enable_selinux=auto)
 203 AC_ARG_ENABLE([apparmor],
 204   [AS_HELP_STRING([--enable-apparmor], [build with AppArmor support])],
 205   [enable_apparmor=$enableval],
 206   [enable_apparmor=auto])
 207 AC_ARG_ENABLE(libaudit,AS_HELP_STRING([--enable-libaudit],[build audit daemon support for SELinux]),enable_libaudit=$enableval,enable_libaudit=auto)
 208 AC_ARG_ENABLE(inotify, AS_HELP_STRING([--enable-inotify],[build with inotify support (linux only)]),enable_inotify=$enableval,enable_inotify=auto)
 209 AC_ARG_ENABLE(kqueue, AS_HELP_STRING([--enable-kqueue],[build with kqueue support]),enable_kqueue=$enableval,enable_kqueue=auto)
 210 AC_ARG_ENABLE(console-owner-file, AS_HELP_STRING([--enable-console-owner-file],[enable console owner file]),enable_console_owner_file=$enableval,enable_console_owner_file=auto)
 211 AC_ARG_ENABLE(launchd, AS_HELP_STRING([--enable-launchd],[build with launchd auto-launch support]),enable_launchd=$enableval,enable_launchd=auto)
 212 AC_ARG_ENABLE(systemd, AS_HELP_STRING([--enable-systemd],[build with systemd at_console support]),enable_systemd=$enableval,enable_systemd=auto)
 213
 214 AC_ARG_WITH(init-scripts, AS_HELP_STRING([--with-init-scripts=[redhat]],[Style of init scripts to install]))
 215 AC_ARG_WITH(session-socket-dir, AS_HELP_STRING([--with-session-socket-dir=[dirname]],[Where to put sockets for the per-login-session message bus]))
 216 AC_ARG_WITH(test-socket-dir, AS_HELP_STRING([--with-test-socket-dir=[dirname]],[Where to put sockets for make check]))
 217 AC_ARG_WITH(system-pid-file, AS_HELP_STRING([--with-system-pid-file=[pidfile]],[PID file for systemwide daemon]))
 218 AC_ARG_WITH(system-socket, AS_HELP_STRING([--with-system-socket=[filename]],[UNIX domain socket for systemwide daemon]))
 219 AC_ARG_WITH(console-auth-dir, AS_HELP_STRING([--with-console-auth-dir=[dirname]],[directory to check for console ownerhip]))
 220 AC_ARG_WITH(console-owner-file, AS_HELP_STRING([--with-console-owner-file=[filename]],[file whose owner determines current console owner]))
 221 AC_ARG_WITH(launchd-agent-dir, AS_HELP_STRING([--with-launchd-agent-dir=[dirname]],[directory to put the launchd agent (default: /Library/LaunchAgents)]))
 222 AC_ARG_WITH(dbus_user, AS_HELP_STRING([--with-dbus-user=<user>],[User for running the DBUS daemon (messagebus)]))
 223 AC_ARG_WITH([test_user],
 224   [AS_HELP_STRING([--with-test-user=<user>],
 225     [Unprivileged user for regression tests, other than root and the dbus_user (default: nobody)])])
 226 AC_ARG_WITH(dbus_daemondir, AS_HELP_STRING([--with-dbus-daemondir=[dirname]],[Directory for installing the DBUS daemon]))
 227
 228 AC_ARG_ENABLE([embedded-tests],
 229   AS_HELP_STRING([--enable-embedded-tests],
 230     [enable unit test code in the library and binaries]),
 231   [], [enable_embedded_tests=$enable_developer])
 232 AC_ARG_ENABLE([modular-tests],
 233   AS_HELP_STRING([--enable-modular-tests],
 234     [enable modular regression tests (requires GLib)]),
 235   [], [enable_modular_tests=auto])
 236 # --enable-tests overrides both --enable-embedded-tests and
 237 # --enable-modular-tests
 238 AC_ARG_ENABLE([tests],
 239   AS_HELP_STRING([--enable-tests],
 240     [enable/disable all tests, overriding embedded-tests/modular-tests]),
 241   [
 242   if test "x$enableval" = xyes; then
 243     AC_MSG_NOTICE([Full test coverage was requested with --enable-tests=yes])
 244     AC_MSG_NOTICE([This has many dependencies (GLib, Python etc.)])
 245   fi
 246   enable_embedded_tests=$enableval
 247   enable_modular_tests=$enableval
 248   ],
 249   [])
 250
 251 # DBUS_ENABLE_EMBEDDED_TESTS controls unit tests built in to .c files
 252 # and also some stuff in the test/ subdir.
 253 AM_CONDITIONAL([DBUS_ENABLE_EMBEDDED_TESTS],
 254   [test "x$enable_embedded_tests" = xyes])
 255 if test "x$enable_embedded_tests" = xyes; then
 256     AC_DEFINE([DBUS_ENABLE_EMBEDDED_TESTS], [1],
 257       [Define to build test code into the library and binaries])
 258 fi
 259
 260 # DBUS_ENABLE_MODULAR_TESTS controls tests that work based on public API.
 261 # These use GTest, from GLib, because life's too short. They're enabled by
 262 # default (unless you don't have GLib), because they don't bloat the library
 263 # or binaries.
 264
 265 AC_DEFINE([GLIB_VERSION_MIN_REQUIRED], [GLIB_VERSION_2_36], [Ignore post-2.36 deprecations])
 266 AC_DEFINE([GLIB_VERSION_MAX_ALLOWED], [GLIB_VERSION_2_38], [Prevent post-2.38 APIs])
 267
 268 with_glib=yes
 269
 270 AS_IF([test "x$enable_modular_tests" != xno],
 271   [
 272   PKG_CHECK_MODULES([GLIB], [glib-2.0 >= 2.36, gio-2.0 >= 2.36],
 273     [
 274       AS_IF([test "x$dbus_unix" = xyes],
 275         [PKG_CHECK_MODULES([GIO_UNIX], [gio-unix-2.0],
 276            [AC_DEFINE([HAVE_GIO_UNIX], [1], [Define if you have gio-unix-2.0])], [])])
 277     ],
 278     [if test "x$enable_modular_tests" = xyes; then
 279       AC_MSG_NOTICE([Full test coverage (--enable-modular-tests=yes or --enable-tests=yes) requires GLib])
 280       AC_MSG_ERROR([$GLIB_ERRORS])
 281     else # assumed to be "auto"
 282       with_glib=no
 283     fi])
 284   ],
 285   [with_glib=no])
 286
 287 if test "x$enable_modular_tests" != xno; then
 288   AC_DEFINE([DBUS_ENABLE_MODULAR_TESTS], [1],
 289     [Define to build independent test binaries])
 290 fi
 291 AM_CONDITIONAL([DBUS_ENABLE_MODULAR_TESTS],
 292   [test "x$enable_modular_tests" != xno])
 293
 294 if test "x$with_glib" != xno; then
 295   AC_DEFINE([DBUS_WITH_GLIB], [1],
 296     [Define if GLib, GObject, GIO are available])
 297 fi
 298 AM_CONDITIONAL([DBUS_WITH_GLIB], [test "x$with_glib" != xno])
 299
 300 AC_ARG_ENABLE([installed-tests],
 301   AS_HELP_STRING([--enable-installed-tests],
 302     [enable unit test code in the library and binaries]),
 303   [], [enable_installed_tests=no])
 304 AM_CONDITIONAL([DBUS_ENABLE_INSTALLED_TESTS],
 305   [test "x$enable_installed_tests" = xyes])
 306
 307 if test "x$enable_tests" = xyes; then
 308   # full test coverage is required, Python is a hard dependency
 309   AC_MSG_NOTICE([Full test coverage (--enable-tests=yes) requires Python, dbus-python, pygi])
 310   AM_PATH_PYTHON([2.6])
 311   AC_MSG_CHECKING([for Python modules for full test coverage])
 312   if "$PYTHON" -c "import dbus, gi.repository.GObject, dbus.mainloop.glib"; then
 313     AC_MSG_RESULT([yes])
 314   else
 315     AC_MSG_RESULT([no])
 316     AC_MSG_ERROR([cannot import dbus, gi.repository.GObject, dbus.mainloop.glib Python modules])
 317   fi
 318 else
 319   # --enable-tests not given: do not abort if Python is missing
 320   AM_PATH_PYTHON([2.6], [], [:])
 321 fi
 322
 323 if test x$enable_verbose_mode = xyes; then
 324     AC_DEFINE(DBUS_ENABLE_VERBOSE_MODE,1,[Support a verbose mode])
 325 fi
 326
 327 dnl Intentional:
 328 dnl - $DISABLE_WARNINGS disables unused-label warnings if not
 329 dnl   checking or not asserting (tested further below)
 330 dnl - missing field initializers being 0 is a C feature, not a bug
 331 dnl - unused-parameter is to make writing callbacks less annoying
 332 DISABLE_WARNINGS="$DISABLE_WARNINGS
 333                   -Wno-missing-field-initializers
 334                   -Wno-unused-parameter"
 335
 336 if test x$enable_asserts = xno; then
 337     AC_DEFINE(DBUS_DISABLE_ASSERT,1,[Disable assertion checking])
 338     DISABLE_WARNINGS="$DISABLE_WARNINGS -Wno-unused-label"
 339     R_DYNAMIC_LDFLAG=""
 340     if test x$enable_embedded_tests = xyes; then
 341         DISABLE_WARNINGS="$DISABLE_WARNINGS
 342                           -Wno-unused-but-set-variable
 343                           -Wno-unused-variable
 344                           -Wno-unused-function"
 345     fi
 346 else
 347     # -rdynamic is needed for glibc's backtrace_symbols to work.
 348     # No clue how much overhead this adds, but it's useful
 349     # to do this on any assertion failure,
 350     # so for now it's enabled anytime asserts are (currently not
 351     # in production builds).
 352
 353     # To get -rdynamic you pass -export-dynamic to libtool.
 354     AC_DEFINE(DBUS_BUILT_R_DYNAMIC,1,[whether -export-dynamic was passed to libtool])
 355     R_DYNAMIC_LDFLAG=-export-dynamic
 356 fi
 357 AC_SUBST(R_DYNAMIC_LDFLAG)
 358
 359 if test x$enable_checks = xno; then
 360     AC_DEFINE(DBUS_DISABLE_CHECKS,1,[Disable public API sanity checking])
 361     AC_DEFINE(G_DISABLE_CHECKS,1,[Disable GLib public API sanity checking])
 362     DISABLE_WARNINGS="$DISABLE_WARNINGS -Wno-unused-label"
 363 fi
 364
 365 AH_BOTTOM([
 366 /* explicitly define these macros to get less confusing conditions */
 367 #ifndef DBUS_DISABLE_ASSERT
 368 #  define DBUS_ENABLE_ASSERT 1
 369 #endif
 370 #ifndef DBUS_DISABLE_CHECKS
 371 #  define DBUS_ENABLE_CHECKS 1
 372 #endif])
 373
 374 # Test for code-coverage tools if --enable-code-coverage
 375 AX_CODE_COVERAGE
 376
 377 AS_IF([test x$enable_code_coverage = xyes],[
 378     AC_DEFINE_UNQUOTED(
 379       [DBUS_GCOV_ENABLED], [1],
 380       [Defined if gcov is enabled to force a rebuild due to config.h changing])
 381   ])
 382
 383 #### Integer sizes
 384
 385 AC_CHECK_SIZEOF(char)
 386 AC_CHECK_SIZEOF(short)
 387 AC_CHECK_SIZEOF(long)
 388 AC_CHECK_SIZEOF(int)
 389 AC_CHECK_SIZEOF(void *)
 390 AC_CHECK_SIZEOF(long long)
 391 AC_CHECK_SIZEOF(__int64)
 392
 393 ### See what our 64 bit type is called
 394 AC_MSG_CHECKING([64-bit integer type])
 395
 396 case 8 in
 397 $ac_cv_sizeof_int)
 398   dbusint64=int
 399   dbusint64_constant='(val)'
 400   dbusuint64_constant='(val)'
 401   ;;
 402 $ac_cv_sizeof_long)
 403   dbusint64=long
 404   dbusint64_constant='(val##L)'
 405   dbusuint64_constant='(val##UL)'
 406   ;;
 407 $ac_cv_sizeof_long_long)
 408   dbusint64='long long'
 409   dbusint64_constant='(val##LL)'
 410   dbusuint64_constant='(val##ULL)'
 411   ;;
 412 $ac_cv_sizeof___int64)
 413   dbusint64=__int64
 414   dbusint64_constant='(val##i64)'
 415   dbusuint64_constant='(val##ui64)'
 416   ;;
 417 esac
 418
 419 AS_IF(
 420   [test -z "$dbusint64"],
 421   [AC_MSG_RESULT([not found])
 422   AC_MSG_ERROR([Could not find a 64-bit integer type.
 423
 424 Please report a bug here with details of your platform and compiler:
 425
 426     http://bugs.freedesktop.org/enter_bug.cgi?product=DBus&component=core])
 427   ],
 428   dnl else
 429   [
 430         DBUS_INT64_TYPE="$dbusint64"
 431         DBUS_INT64_CONSTANT="$dbusint64_constant"
 432         DBUS_UINT64_CONSTANT="$dbusuint64_constant"
 433         AC_MSG_RESULT($DBUS_INT64_TYPE)
 434   ])
 435
 436 AC_SUBST(DBUS_INT64_TYPE)
 437 AC_SUBST(DBUS_INT64_CONSTANT)
 438 AC_SUBST(DBUS_UINT64_CONSTANT)
 439
 440 ### see what 32-bit int is called
 441 AC_MSG_CHECKING([32-bit integer type])
 442
 443 case 4 in
 444 $ac_cv_sizeof_short)
 445   dbusint32=short
 446   ;;
 447 $ac_cv_sizeof_int)
 448   dbusint32=int
 449   ;;
 450 $ac_cv_sizeof_long)
 451   dbusint32=long
 452   ;;
 453 esac
 454
 455 if test -z "$dbusint32" ; then
 456         DBUS_INT32_TYPE="no_int32_type_detected"
 457         AC_MSG_ERROR([No 32-bit integer type found])
 458 else
 459         DBUS_INT32_TYPE="$dbusint32"
 460         AC_MSG_RESULT($DBUS_INT32_TYPE)
 461 fi
 462
 463 AC_SUBST(DBUS_INT32_TYPE)
 464
 465 ### see what 16-bit int is called
 466 AC_MSG_CHECKING([16-bit integer type])
 467
 468 case 2 in
 469 $ac_cv_sizeof_short)
 470   dbusint16=short
 471   ;;
 472 $ac_cv_sizeof_int)
 473   dbusint16=int
 474   ;;
 475 esac
 476
 477 if test -z "$dbusint16" ; then
 478         DBUS_INT16_TYPE="no_int16_type_detected"
 479         AC_MSG_ERROR([No 16-bit integer type found])
 480 else
 481         DBUS_INT16_TYPE="$dbusint16"
 482         AC_MSG_RESULT($DBUS_INT16_TYPE)
 483 fi
 484
 485 AC_SUBST(DBUS_INT16_TYPE)
 486
 487 ## byte order
 488 case $host_os in
 489         darwin*)
 490                 # check at compile-time, so that it is possible to build universal
 491                 # (with multiple architectures at once on the compile line)
 492                 AH_VERBATIM([WORDS_BIGENDIAN_DARWIN], [
 493                         /* Use the compiler-provided endianness defines to allow universal compiling. */
 494                         #if defined(__BIG_ENDIAN__)
 495                         #define WORDS_BIGENDIAN 1
 496                         #endif
 497                 ])
 498                 ;;
 499         *)
 500                 AC_C_BIGENDIAN
 501                 ;;
 502 esac
 503
 504 # As a GNU extension, glibc declares environ in unistd.h, which is one of
 505 # the AC_INCLUDES_DEFAULT.
 506 AC_CHECK_DECLS([environ])
 507
 508 dnl **********************************
 509 dnl *** va_copy checks (from GLib) ***
 510 dnl **********************************
 511 dnl we currently check for all three va_copy possibilities, so we get
 512 dnl all results in config.log for bug reports.
 513 AC_CACHE_CHECK([for an implementation of va_copy()],dbus_cv_va_copy,[
 514         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 515 #include <stdlib.h>
 516         static void f (int i, ...) {
 517         va_list args1, args2;
 518         va_start (args1, i);
 519         va_copy (args2, args1);
 520         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 521           exit (1);
 522         va_end (args1); va_end (args2);
 523         }
 524         int main() {
 525           f (0, 42);
 526           return 0;
 527         }])],
 528         [dbus_cv_va_copy=yes],
 529         [dbus_cv_va_copy=no])
 530 ])
 531 AC_CACHE_CHECK([for an implementation of __va_copy()],dbus_cv___va_copy,[
 532         AC_LINK_IFELSE([AC_LANG_SOURCE([#include <stdarg.h>
 533 #include <stdlib.h>
 534         static void f (int i, ...) {
 535         va_list args1, args2;
 536         va_start (args1, i);
 537         __va_copy (args2, args1);
 538         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 539           exit (1);
 540         va_end (args1); va_end (args2);
 541         }
 542         int main() {
 543           f (0, 42);
 544           return 0;
 545         }])],
 546         [dbus_cv___va_copy=yes],
 547         [dbus_cv___va_copy=no])
 548 ])
 549
 550 if test "x$dbus_cv_va_copy" = "xyes"; then
 551   dbus_va_copy_func=va_copy
 552 else if test "x$dbus_cv___va_copy" = "xyes"; then
 553   dbus_va_copy_func=__va_copy
 554 fi
 555 fi
 556
 557 if test -n "$dbus_va_copy_func"; then
 558   AC_DEFINE_UNQUOTED(DBUS_VA_COPY,$dbus_va_copy_func,[A 'va_copy' style function])
 559 fi
 560
 561 AC_LANG_PUSH(C)
 562 AC_CACHE_CHECK([whether va_lists can be copied by value],
 563         dbus_cv_va_val_copy,
 564         [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 565 [[
 566         #include <stdarg.h>
 567         #include <stdlib.h>
 568 ]],
 569 [[
 570         static void f (int i, ...) {
 571         va_list args1, args2;
 572         va_start (args1, i);
 573         args2 = args1;
 574         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
 575           exit (1);
 576         va_end (args1); va_end (args2);
 577         }
 578         int main() {
 579           f (0, 42);
 580           return 0;
 581         }
 582 ]])],
 583         [dbus_cv_va_val_copy=yes],
 584         [dbus_cv_va_val_copy=no],
 585         [dbus_cv_va_val_copy=yes])
 586 ])
 587 AC_LANG_POP(C)
 588
 589 if test "x$dbus_cv_va_val_copy" = "xno"; then
 590   AC_DEFINE(DBUS_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
 591 fi
 592
 593
 594 #### Atomic integers
 595
 596 AC_CACHE_CHECK([whether $CC knows __sync_sub_and_fetch()],
 597   dbus_cv_sync_sub_and_fetch,
 598   [AC_LINK_IFELSE([
 599      AC_LANG_PROGRAM([[]], [[int a = 4; int b = __sync_sub_and_fetch(&a, 4); exit(b); ]])],
 600      [dbus_cv_sync_sub_and_fetch=yes],
 601      [dbus_cv_sync_sub_and_fetch=no])
 602   ])
 603
 604 if test "x$dbus_cv_sync_sub_and_fetch" = "xyes" ; then
 605    have_sync=1
 606 else
 607    have_sync=0
 608 fi
 609
 610 AC_DEFINE_UNQUOTED([DBUS_USE_SYNC], [$have_sync], [Use the gcc __sync extension])
 611
 612 #### Various functions
 613 AC_SEARCH_LIBS(socket,[socket network])
 614 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 615
 616 AC_CHECK_FUNCS([vsnprintf vasprintf nanosleep usleep setenv clearenv unsetenv socketpair getgrouplist fpathconf setrlimit poll setlocale localeconv strtoll strtoull issetugid getresuid setresuid getrlimit])
 617
 618 AC_CHECK_HEADERS([syslog.h])
 619 if test "x$ac_cv_header_syslog_h" = "xyes"; then
 620   AC_CHECK_DECLS([LOG_PERROR], [], [], [[#include <syslog.h>]])
 621 fi
 622
 623 # For test-segfault.c
 624 AC_CHECK_HEADERS_ONCE([sys/prctl.h])
 625 AC_CHECK_FUNCS_ONCE([prctl raise])
 626
 627 #### Check for broken poll; taken from Glib's configure
 628
 629 AC_MSG_CHECKING([for broken poll])
 630 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 631     #include <stdlib.h>
 632     #include <fcntl.h>
 633     #include <poll.h>
 634     #ifdef HAVE_SYS_POLL_H
 635     #include <sys/poll.h>
 636     #endif
 637     int main(void) {
 638       struct pollfd fds[1];
 639       int fd;
 640       fd = open("/dev/null", 1);
 641       fds[0].fd = fd;
 642       fds[0].events = POLLIN;
 643       fds[0].revents = 0;
 644       if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
 645             exit(1);  /* Does not work for devices -- fail */
 646       }
 647       exit(0);
 648     }]])],
 649   [broken_poll=no],
 650   [broken_poll=yes
 651    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
 652   [broken_poll="no (cross compiling)"])
 653 AC_MSG_RESULT($broken_poll)
 654
 655 AC_MSG_CHECKING(for dirfd)
 656 AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 657 #include <sys/types.h>
 658 #include <dirent.h>
 659 ]], [[
 660 DIR *dirp;
 661 dirp = opendir(".");
 662 dirfd(dirp);
 663 closedir(dirp);
 664 ]])],
 665 [dbus_have_dirfd=yes],
 666 [dbus_have_dirfd=no])
 667 AC_MSG_RESULT($dbus_have_dirfd)
 668 if test "$dbus_have_dirfd" = yes; then
 669         AC_DEFINE(HAVE_DIRFD,1,[Have dirfd function])
 670 else
 671         AC_MSG_CHECKING(for DIR *dirp->dd_fd)
 672         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 673 #include <sys/types.h>
 674 #include <dirent.h>
 675         ]], [[
 676 DIR *dirp;
 677 int fd;
 678 dirp = opendir(".");
 679 fd = dirp->dd_fd;
 680 closedir(dirp);
 681         ]])],
 682         [dbus_have_ddfd=yes],
 683         [dbus_have_ddfd=no])
 684         AC_MSG_RESULT($dbus_have_ddfd)
 685         if test "$dbus_have_ddfd" = yes; then
 686                 AC_DEFINE(HAVE_DDFD,1,[Have the ddfd member of DIR])
 687         fi
 688 fi
 689
 690 AC_CHECK_HEADERS(sys/resource.h)
 691
 692 AC_CHECK_HEADERS(dirent.h)
 693
 694 AC_CHECK_HEADERS([execinfo.h],
 695         [AC_SEARCH_LIBS([backtrace], [execinfo],
 696                 [AC_DEFINE([HAVE_BACKTRACE], [1],
 697                         [Define to 1 if you have backtrace().])])])
 698
 699 AC_CHECK_HEADERS(errno.h)
 700
 701 AC_CHECK_HEADERS(signal.h)
 702
 703 AC_CHECK_HEADERS(locale.h)
 704
 705 AC_CHECK_HEADERS(byteswap.h)
 706
 707 AC_CHECK_HEADERS(unistd.h)
 708
 709 AC_CHECK_HEADERS([stdint.h])
 710
 711 AC_CHECK_HEADERS(ws2tcpip.h)
 712
 713 AC_CHECK_HEADERS(alloca.h)
 714
 715 # Add -D_POSIX_PTHREAD_SEMANTICS if on Solaris
 716 #
 717 case $host_os in
 718     solaris*)
 719        CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS" ;;
 720 esac
 721
 722 # checking for a posix version of getpwnam_r
 723 # if we are cross compiling and can not run the test
 724 # assume getpwnam_r is the posix version
 725 # it is up to the person cross compiling to change
 726 # this behavior if desired
 727 AC_LANG_PUSH(C)
 728 AC_CACHE_CHECK([for posix getpwnam_r],
 729                 ac_cv_func_posix_getpwnam_r,
 730                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 731 [[
 732 #include <errno.h>
 733 #include <pwd.h>
 734 ]],
 735 [[
 736     char buffer[10000];
 737     struct passwd pwd, *pwptr = &pwd;
 738     int error;
 739     errno = 0;
 740     error = getpwnam_r ("", &pwd, buffer,
 741                         sizeof (buffer), &pwptr);
 742    return (error < 0 && errno == ENOSYS)
 743            || error == ENOSYS;
 744 ]])],
 745         [ac_cv_func_posix_getpwnam_r=yes],
 746         [ac_cv_func_posix_getpwnam_r=no],
 747         [ac_cv_func_posix_getpwnam_r=yes]
 748 )])
 749 AC_LANG_POP(C)
 750
 751 if test "$ac_cv_func_posix_getpwnam_r" = yes; then
 752         AC_DEFINE(HAVE_POSIX_GETPWNAM_R,1,
 753                 [Have POSIX function getpwnam_r])
 754 else
 755         AC_CACHE_CHECK([for nonposix getpwnam_r],
 756                 ac_cv_func_nonposix_getpwnam_r,
 757                 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pwd.h>]], [[char buffer[10000];
 758                         struct passwd pwd;
 759                         getpwnam_r ("", &pwd, buffer,
 760                                         sizeof (buffer));]])],
 761                         [ac_cv_func_nonposix_getpwnam_r=yes],
 762                         [ac_cv_func_nonposix_getpwnam_r=no])])
 763                 if test "$ac_cv_func_nonposix_getpwnam_r" = yes; then
 764                 AC_DEFINE(HAVE_NONPOSIX_GETPWNAM_R,1,
 765                         [Have non-POSIX function getpwnam_r])
 766         fi
 767 fi
 768
 769 dnl check for socklen_t
 770 AC_MSG_CHECKING(whether socklen_t is defined)
 771 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 772 #include <sys/types.h>
 773 #include <sys/socket.h>
 774 #include <netdb.h>
 775 ]], [[
 776 socklen_t foo;
 777 foo = 1;
 778 ]])],
 779 [dbus_have_socklen_t=yes],
 780 [dbus_have_socklen_t=no])
 781 AC_MSG_RESULT($dbus_have_socklen_t)
 782
 783 if test "x$dbus_have_socklen_t" = "xyes"; then
 784     AC_DEFINE(HAVE_SOCKLEN_T,1,[Have socklen_t type])
 785 fi
 786
 787 dnl check for writev header and writev function so we're
 788 dnl good to go if HAVE_WRITEV gets defined.
 789 AC_CHECK_HEADERS(sys/uio.h, [AC_CHECK_FUNCS(writev)])
 790
 791 dnl needed on darwin for NAME_MAX
 792 AC_CHECK_HEADERS(sys/syslimits.h)
 793
 794 dnl Make it easy to check if we have MSG_NOSIGNAL without actually having to include sys/socket.h
 795 AC_CHECK_DECLS([MSG_NOSIGNAL], [], [], [[ #include <sys/types.h>
 796 #include <sys/socket.h> ]])
 797
 798 dnl check for flavours of varargs macros (test from GLib)
 799 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 800 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 801 int a(int p1, int p2, int p3);
 802 #define call_a(...) a(1,__VA_ARGS__)
 803 call_a(2,3);
 804 ]])],
 805 [dbus_have_iso_c_varargs=yes],
 806 [dbus_have_iso_c_varargs=no])
 807 AC_MSG_RESULT($dbus_have_iso_c_varargs)
 808
 809 AC_MSG_CHECKING(for GNUC varargs macros)
 810 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[
 811 int a(int p1, int p2, int p3);
 812 #define call_a(params...) a(1,params)
 813 call_a(2,3);
 814 ]])],
 815 [dbus_have_gnuc_varargs=yes],
 816 [dbus_have_gnuc_varargs=no])
 817 AC_MSG_RESULT($dbus_have_gnuc_varargs)
 818
 819 dnl Output varargs tests
 820 if test x$dbus_have_iso_c_varargs = xyes; then
 821     AC_DEFINE(HAVE_ISO_VARARGS,1,[Have ISO C99 varargs macros])
 822 fi
 823 if test x$dbus_have_gnuc_varargs = xyes; then
 824     AC_DEFINE(HAVE_GNUC_VARARGS,1,[Have GNU-style varargs macros])
 825 fi
 826
 827 dnl Check for various credentials.
 828 AC_MSG_CHECKING(for struct cmsgcred)
 829 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 830 #include <sys/types.h>
 831 #include <sys/socket.h>
 832 ]], [[
 833 struct cmsgcred cred;
 834
 835 cred.cmcred_pid = 0;
 836 ]])],
 837 [dbus_have_struct_cmsgcred=yes],
 838 [dbus_have_struct_cmsgcred=no])
 839 AC_MSG_RESULT($dbus_have_struct_cmsgcred)
 840
 841 if test x$dbus_have_struct_cmsgcred = xyes; then
 842     AC_DEFINE(HAVE_CMSGCRED,1,[Have cmsgcred structure])
 843 fi
 844
 845 AC_CHECK_MEMBER([struct unpcbid.unp_pid],
 846                 [AC_DEFINE([HAVE_UNPCBID], 1, [Have unpcbid structure])],
 847                 [],
 848                 [[#include <sys/un.h>]])
 849
 850 AC_CHECK_FUNCS(getpeerucred getpeereid)
 851
 852 AC_CHECK_FUNCS(pipe2 accept4)
 853
 854 #### Abstract sockets
 855
 856 if test x$enable_abstract_sockets = xauto; then
 857 AC_LANG_PUSH(C)
 858 warn_on_xcompile=no
 859 AC_CACHE_CHECK([abstract socket namespace],
 860                 ac_cv_have_abstract_sockets,
 861                 [AC_RUN_IFELSE([AC_LANG_PROGRAM(
 862 [[
 863 #include <sys/types.h>
 864 #include <stdlib.h>
 865 #include <string.h>
 866 #include <stdio.h>
 867 #include <sys/socket.h>
 868 #include <sys/un.h>
 869 #include <errno.h>
 870 ]],
 871 [[
 872   size_t slen;
 873   int listen_fd;
 874   struct sockaddr_un addr;
 875
 876   listen_fd = socket (PF_UNIX, SOCK_STREAM, 0);
 877
 878   if (listen_fd < 0)
 879     {
 880       fprintf (stderr, "socket() failed: %s\n", strerror (errno));
 881       exit (1);
 882     }
 883
 884   memset (&addr, '\0', sizeof (addr));
 885   addr.sun_family = AF_UNIX;
 886   strcpy (addr.sun_path, "X/tmp/dbus-fake-socket-path-used-in-configure-test");
 887   /* SUN_LEN uses strlen() so need to calculate it before adding \0 at the
 888    * beginning.
 889    */
 890   slen = SUN_LEN(&addr);
 891   addr.sun_path[0] = '\0'; /* this is what makes it abstract */
 892
 893   if (bind (listen_fd, (struct sockaddr*) &addr, slen) < 0)
 894     {
 895        fprintf (stderr, "Abstract socket namespace bind() failed: %s\n",
 896                 strerror (errno));
 897        exit (1);
 898     }
 899   else
 900     exit (0);
 901 ]])],
 902               [ac_cv_have_abstract_sockets=yes],
 903               [ac_cv_have_abstract_sockets=no],
 904               [
 905                 ac_cv_have_abstract_sockets=no
 906                 warn_on_xcompile=yes
 907               ]
 908 )])
 909 if test x$warn_on_xcompile = xyes ; then
 910   AC_MSG_WARN([Cannot check for abstract sockets when cross-compiling, please use --enable-abstract-sockets])
 911 fi
 912 AC_LANG_POP(C)
 913 fi
 914
 915 if test x$enable_abstract_sockets = xyes; then
 916     if test x$ac_cv_have_abstract_sockets = xno; then
 917         AC_MSG_ERROR([Abstract sockets explicitly required, and support not detected.])
 918     fi
 919 fi
 920
 921 if test x$enable_abstract_sockets = xno; then
 922    ac_cv_have_abstract_sockets=no;
 923 fi
 924
 925 if test x$ac_cv_have_abstract_sockets = xyes ; then
 926    DBUS_PATH_OR_ABSTRACT=abstract
 927    AC_DEFINE(HAVE_ABSTRACT_SOCKETS,1,[Have abstract socket namespace])
 928 else
 929    DBUS_PATH_OR_ABSTRACT=path
 930 fi
 931
 932 # this is used in addresses to prefer abstract, e.g.
 933 # unix:path=/foo or unix:abstract=/foo
 934 AC_SUBST(DBUS_PATH_OR_ABSTRACT)
 935
 936 #### Sort out XML library
 937
 938 AC_CHECK_LIB(expat, XML_ParserCreate_MM,
 939              [ AC_CHECK_HEADERS(expat.h, [],
 940                                 [AC_MSG_ERROR([Could not find expat.h, check config.log for failed attempts])]) ],
 941              [ AC_MSG_ERROR([Explicitly requested expat but expat not found]) ])
 942
 943 XML_LIBS=-lexpat
 944 XML_CFLAGS=
 945 AC_SUBST([XML_CFLAGS])
 946 AC_SUBST([XML_LIBS])
 947
 948 # Thread lib detection
 949 AC_ARG_VAR([THREAD_LIBS])
 950 save_libs="$LIBS"
 951 LIBS="$LIBS $THREAD_LIBS"
 952
 953 is_missing_pthread_function="is required when compiling D-Bus on Unix platforms, but is not in your libc or libpthread. Please open a bug on https://bugs.freedesktop.org/enter_bug.cgi?product=dbus with details of your platform."
 954
 955 # Don't do these automatic checks if the user set THREAD_LIBS on the
 956 # configure command-line. If they did, we assume they're right.
 957 #
 958 # We also don't do these checks on Windows, because you don't need magical
 959 # linker flags to have threading support there.
 960 AS_IF([test "x$dbus_unix" = xyes && test "x$THREAD_LIBS" = x],
 961   [
 962     # Mandatory pthread functions. In principle, some of these could be made
 963     # optional if there are platforms that don't have them.
 964     #
 965     # Currently, we only look in -lpthread.
 966     # In principle we might need to look in -lpthreads, -lthreads, ...
 967     # as well - please file a bug if your platform needs this.
 968     AC_SEARCH_LIBS([pthread_cond_timedwait],
 969         [pthread],
 970         [THREAD_LIBS="$LIBS"],
 971         [AC_MSG_ERROR([pthread_cond_timedwait $is_missing_pthread_function])],
 972         [])
 973     AC_SEARCH_LIBS([pthread_mutexattr_init],
 974         [pthread],
 975         [THREAD_LIBS="$LIBS"],
 976         [AC_MSG_ERROR([pthread_mutexattr_init $is_missing_pthread_function])],
 977         [])
 978     AC_SEARCH_LIBS([pthread_mutexattr_settype],
 979         [pthread],
 980         [THREAD_LIBS="$LIBS"],
 981         [AC_MSG_ERROR([pthread_mutexattr_settype $is_missing_pthread_function])],
 982         [])
 983
 984     # Optional, for monotonic clocks. Because it's optional, this check
 985     # is non-fatal if we don't find it.
 986     AC_SEARCH_LIBS([pthread_condattr_setclock],
 987         [pthread],
 988         [THREAD_LIBS="$LIBS"])
 989
 990     AS_IF([test "x$ac_cv_search_pthread_condattr_setclock" != xno],
 991       [
 992         AC_SEARCH_LIBS([clock_getres], [rt], [THREAD_LIBS="$LIBS"])
 993         AC_MSG_CHECKING([for CLOCK_MONOTONIC])
 994         AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 995 [[#include <time.h>
 996 #include <pthread.h>
 997 ]], [[
 998 struct timespec monotonic_timer;
 999 pthread_condattr_t attr;
1000 pthread_condattr_init (&attr);
1001 pthread_condattr_setclock (&attr, CLOCK_MONOTONIC);
1002 clock_getres (CLOCK_MONOTONIC,&monotonic_timer);
1003 ]])],
1004             [have_clock_monotonic=true],
1005             [have_clock_monotonic=false])
1006         AS_IF([test x$have_clock_monotonic = xtrue],
1007           [
1008             AC_MSG_RESULT([found])
1009             AC_DEFINE(HAVE_MONOTONIC_CLOCK, 1, [Define if we have CLOCK_MONOTONIC])
1010           ],
1011           [AC_MSG_RESULT([not found])])
1012       ]) dnl have pthread_condattr_setclock
1013   ]) dnl on Unix
1014
1015 LIBS="$save_libs"
1016
1017 AC_SUBST([THREAD_LIBS])
1018
1019 # SELinux detection
1020 if test x$enable_selinux = xno ; then
1021     have_selinux=no;
1022 else
1023     # See if we have SELinux library
1024     AC_CHECK_LIB(selinux, is_selinux_enabled,
1025                  have_selinux=yes, have_selinux=no)
1026
1027     # see if we have the SELinux header with the new D-Bus stuff in it
1028     if test x$have_selinux = xyes ; then
1029         AC_MSG_CHECKING([for DBUS Flask permissions in selinux/av_permissions.h])
1030         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <selinux/av_permissions.h>]],
1031                           [[#ifdef DBUS__ACQUIRE_SVC return 0;
1032                             #else
1033                             #error DBUS__ACQUIRE_SVC not defined
1034                             #endif]])],
1035                           [have_selinux=yes],
1036                           [have_selinux=no])
1037         AC_MSG_RESULT($have_selinux)
1038     fi
1039
1040     if test x$enable_selinux = xauto ; then
1041         if test x$have_selinux = xno ; then
1042                 AC_MSG_WARN([Sufficiently new SELinux library not found])
1043         fi
1044     else
1045         if test x$have_selinux = xno ; then
1046                 AC_MSG_ERROR([SElinux explicitly required, and SELinux library not found])
1047         fi
1048     fi
1049 fi
1050
1051 AM_CONDITIONAL(HAVE_SELINUX, test x$have_selinux = xyes)
1052
1053 if test x$have_selinux = xyes ; then
1054     # the selinux code creates threads
1055     # which requires libpthread even on linux
1056     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,
1057                                                 [SELINUX_THREAD_LIBS="-lpthread"])])
1058
1059     SELINUX_LIBS="-lselinux $SELINUX_THREAD_LIBS"
1060     AC_DEFINE(HAVE_SELINUX,1,[SELinux support])
1061 else
1062     SELINUX_LIBS=
1063 fi
1064
1065 # AppArmor detection
1066 AS_IF([test x$enable_apparmor = xno],
1067   [have_apparmor=no],
1068   [
1069   PKG_CHECK_MODULES([APPARMOR], [libapparmor >= 2.8.95],
1070                     [have_apparmor=yes], [have_apparmor=no])
1071   PKG_CHECK_MODULES([APPARMOR_2_10], [libapparmor >= 2.10],
1072                     [have_apparmor_2_10=yes], [have_apparmor_2_10=no])
1073
1074   AS_IF([test x$enable_apparmor = xauto && test x$have_apparmor = xno],
1075         [AC_MSG_WARN([Sufficiently new AppArmor library not found])])
1076   AS_IF([test x$enable_apparmor != xauto && test x$have_apparmor = xno],
1077         [AC_MSG_ERROR([AppArmor explicitly required, and AppArmor library not found])])
1078   ])
1079
1080 AS_IF([test x$have_apparmor = xyes],
1081       [AC_DEFINE([HAVE_APPARMOR], [1], [AppArmor Support])])
1082 AS_IF([test x$have_apparmor_2_10 = xyes],
1083       [AC_DEFINE([HAVE_APPARMOR_2_10], [1],
1084                  [Define if libapparmor is version 2.10 or later])])
1085
1086 # inotify checks
1087 if test x$enable_inotify = xno ; then
1088     have_inotify=no;
1089 else
1090     AC_CHECK_HEADERS(sys/inotify.h, have_inotify=yes, have_inotify=no)
1091 fi
1092
1093 dnl check if inotify backend is enabled
1094 if test x$have_inotify = xyes; then
1095    AC_DEFINE(DBUS_BUS_ENABLE_INOTIFY,1,[Use inotify])
1096    AC_CHECK_FUNCS(inotify_init1)
1097 fi
1098
1099 AM_CONDITIONAL(DBUS_BUS_ENABLE_INOTIFY, test x$have_inotify = xyes)
1100
1101 # For simplicity, we require the userland API for epoll_create1 at
1102 # compile-time (glibc 2.9), but we'll run on kernels that turn out
1103 # not to have it at runtime.
1104 AC_ARG_ENABLE([epoll],
1105               [AS_HELP_STRING([--enable-epoll],[use epoll(4) on Linux])],
1106               [enable_epoll=$enableval], [enable_epoll=auto])
1107 if test x$enable_epoll = xno; then
1108     have_linux_epoll=no
1109 else
1110     AC_MSG_CHECKING([for Linux epoll(4)])
1111     AC_LINK_IFELSE([AC_LANG_PROGRAM(
1112         [
1113         #ifndef __linux__
1114         #error This is not Linux
1115         #endif
1116         #include <sys/epoll.h>
1117         ],
1118         [epoll_create1 (EPOLL_CLOEXEC);])],
1119         [have_linux_epoll=yes],
1120         [have_linux_epoll=no])
1121     AC_MSG_RESULT([$have_linux_epoll])
1122 fi
1123 if test x$enable_epoll,$have_linux_epoll = xyes,no; then
1124     AC_MSG_ERROR([epoll support explicitly enabled but not available])
1125 fi
1126 if test x$have_linux_epoll = xyes; then
1127   AC_DEFINE([DBUS_HAVE_LINUX_EPOLL], 1, [Define to use epoll(4) on Linux])
1128 fi
1129 AM_CONDITIONAL([HAVE_LINUX_EPOLL], [test x$have_linux_epoll = xyes])
1130
1131 # kqueue checks
1132 if test x$enable_kqueue = xno ; then
1133     have_kqueue=no
1134 else
1135     have_kqueue=yes
1136     AC_CHECK_HEADER(sys/event.h, , have_kqueue=no)
1137     AC_CHECK_FUNC(kqueue, , have_kqueue=no)
1138
1139     if test x$enable_kqueue = xyes -a x$have_kqueue = xno; then
1140         AC_MSG_ERROR(kqueue support explicitly enabled but not available)
1141     fi
1142 fi
1143
1144 dnl check if kqueue backend is enabled
1145 if test x$have_kqueue = xyes; then
1146    AC_DEFINE(DBUS_BUS_ENABLE_KQUEUE,1,[Use kqueue])
1147 fi
1148
1149 AM_CONDITIONAL(DBUS_BUS_ENABLE_KQUEUE, test x$have_kqueue = xyes)
1150
1151 # launchd checks
1152 if test x$enable_launchd = xno ; then
1153     have_launchd=no
1154 else
1155     have_launchd=yes
1156     AC_CHECK_HEADER([launch.h], , have_launchd=no)
1157     AC_PATH_PROG([LAUNCHCTL], [launchctl])
1158     if test "x$LAUNCHCTL" = "x"; then
1159         have_launchd=no
1160     fi
1161
1162     if test x$enable_launchd = xyes && test x$have_launchd = xno ; then
1163         AC_MSG_ERROR([launchd support explicitly enabled but not available])
1164     fi
1165 fi
1166
1167 dnl check if launchd is enabled
1168 if test x$have_launchd = xyes; then
1169     AC_DEFINE(DBUS_ENABLE_LAUNCHD,1,[Use launchd autolaunch])
1170 fi
1171
1172 AM_CONDITIONAL(DBUS_ENABLE_LAUNCHD, test x$have_launchd = xyes)
1173
1174 #### Directory to place launchd agent file
1175 if test "x$with_launchd_agent_dir" = "x"; then
1176    LAUNCHD_AGENT_DIR="/Library/LaunchAgents"
1177 else
1178    LAUNCHD_AGENT_DIR="$with_launchd_agent_dir"
1179 fi
1180
1181 AC_SUBST(LAUNCHD_AGENT_DIR)
1182
1183 dnl console owner file
1184 if test x$enable_console_owner_file = xno ; then
1185     have_console_owner_file=no;
1186 else
1187     case $host_os in
1188     solaris*)
1189         have_console_owner_file=yes;
1190         AC_DEFINE(HAVE_CONSOLE_OWNER_FILE,1,[Have console owner file])
1191         ;;
1192     *)
1193         have_console_owner_file=no;;
1194     esac
1195 fi
1196
1197 AM_CONDITIONAL(HAVE_CONSOLE_OWNER_FILE, test x$have_console_owner_file = xyes)
1198
1199 dnl systemd detection
1200 if test x$enable_systemd = xno ; then
1201     have_systemd=no;
1202 else
1203     PKG_CHECK_MODULES([SYSTEMD],
1204         [libsystemd >= 209],
1205         [have_systemd=yes],
1206         [PKG_CHECK_MODULES([SYSTEMD],
1207             [libsystemd-login >= 32, libsystemd-daemon >= 32, libsystemd-journal >= 32],
1208             [have_systemd=yes],
1209             [have_systemd=no])])
1210 fi
1211
1212 if test x$have_systemd = xyes; then
1213     AC_DEFINE(HAVE_SYSTEMD,1,[Have systemd])
1214 fi
1215
1216 if test x$enable_systemd = xyes -a x$have_systemd != xyes ; then
1217     AC_MSG_ERROR([Explicitly requested systemd support, but systemd not found])
1218 fi
1219
1220 # If not found in $PATH, we might still have systemd and systemctl at runtime
1221 # (perhaps dbus is being compiled in a minimal chroot with no systemd).
1222 # Assume the upstream-recommended location. Distributors with split /usr
1223 # can override this with ./configure SYSTEMCTL=/bin/systemctl
1224 AC_PATH_PROG([SYSTEMCTL], [systemctl], [/usr/bin/systemctl])
1225
1226 # libaudit detection
1227 if test x$enable_libaudit = xno ; then
1228     have_libaudit=no;
1229 else
1230     # See if we have audit daemon & capabilities library
1231     AC_CHECK_LIB(audit, audit_log_user_avc_message,
1232                  have_libaudit=yes, have_libaudit=no)
1233     if test x$have_libaudit = xyes ; then
1234         AC_CHECK_LIB(cap-ng, capng_clear,
1235                  have_libaudit=yes, have_libaudit=no)
1236     fi
1237 fi
1238
1239 AM_CONDITIONAL(HAVE_LIBAUDIT, test x$have_libaudit = xyes)
1240
1241 if test x$have_libaudit = xyes ; then
1242     SELINUX_LIBS="$SELINUX_LIBS -laudit -lcap-ng"
1243     AC_DEFINE(HAVE_LIBAUDIT,1,[audit daemon SELinux support])
1244 fi
1245
1246 AC_SUBST([SELINUX_LIBS])
1247
1248 # Check for ADT API (Solaris Basic Security Mode auditing)
1249 AC_MSG_CHECKING(for ADT API)
1250 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1251 #include <bsm/adt.h>
1252 adt_user_context = ADT_USER;
1253 ]], [[]])], [ check_adt_audit=yes ], [ check_adt_audit=no ])
1254
1255 if test ${check_adt_audit} = yes
1256 then
1257    AC_DEFINE([HAVE_ADT], [], [Adt audit API])
1258    ADT_LIBS="-lbsm"
1259    LIBS="-lbsm $LIBS"
1260    AC_MSG_RESULT(yes)
1261 else
1262    AC_MSG_RESULT(no)
1263 fi
1264 AC_SUBST([ADT_LIBS])
1265
1266 # Check for SCM_RIGHTS
1267 AC_MSG_CHECKING([for SCM_RIGHTS])
1268 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1269 #include <sys/types.h>
1270 #include <sys/socket.h>
1271 #include <sys/un.h>
1272 static int x = SCM_RIGHTS;
1273 ]], [[]])],
1274 [ AC_MSG_RESULT([supported])
1275   AC_DEFINE([HAVE_UNIX_FD_PASSING], [1], [Supports sending UNIX file descriptors]) ],
1276 [ AC_MSG_RESULT([not supported]) ])
1277
1278 NETWORK_libs=
1279 if test x$dbus_win = xyes ; then
1280   if test x$dbus_wince = xyes ; then
1281     NETWORK_libs="-lws2"
1282   else
1283     NETWORK_libs="-lws2_32 -liphlpapi -ldbghelp"
1284   fi
1285 fi
1286
1287 AC_SUBST([NETWORK_libs])
1288
1289 AC_ARG_WITH([valgrind],
1290   [AS_HELP_STRING([--with-valgrind],
1291      [Add instrumentation to help valgrind to understand our allocator])],
1292   [],
1293   [with_valgrind=no])
1294
1295 AS_IF([test "x$with_valgrind" = xauto],
1296   [PKG_CHECK_EXISTS([valgrind >= 3.6],
1297     [with_valgrind=yes], [with_valgrind=no])])
1298
1299 if test x$with_valgrind != xno; then
1300   PKG_CHECK_MODULES([VALGRIND], [valgrind >= 3.6])
1301   AC_DEFINE([WITH_VALGRIND], [1], [Define to add Valgrind instrumentation])
1302 fi
1303
1304 #### Set up final flags
1305 LIBDBUS_LIBS="$THREAD_LIBS $NETWORK_libs $SYSTEMD_LIBS"
1306 AC_SUBST([LIBDBUS_LIBS])
1307
1308 ### X11 detection
1309 DBUS_X_LIBS=
1310 DBUS_X_CFLAGS=
1311
1312 AC_ARG_ENABLE([x11-autolaunch],
1313   AS_HELP_STRING([--enable-x11-autolaunch], [build with X11 auto-launch support]),
1314   [], [enable_x11_autolaunch=auto])
1315
1316 if test "x$dbus_win" = xyes; then
1317     if test "x$enable_x11_autolaunch" = xyes; then
1318         AC_MSG_ERROR([X11 auto-launch is not supported on Windows])
1319     fi
1320
1321     enable_x11_autolaunch=no
1322     have_x11=no
1323 else
1324     AC_PATH_XTRA
1325
1326     if test "x$no_x" = xyes; then
1327         have_x11=no
1328     else
1329         have_x11=yes
1330         DBUS_X_LIBS="$X_LIBS $X_PRE_LIBS -lX11 $X_EXTRA_LIBS"
1331         DBUS_X_CFLAGS="$X_CFLAGS"
1332     fi
1333 fi
1334
1335 if test "x$enable_x11_autolaunch,$have_x11" = xyes,no; then
1336     AC_MSG_ERROR([X11 auto-launch requires X headers/libraries])
1337 else
1338     # move from "auto" to "yes" or "no" if necessary
1339     if test "x$enable_x11_autolaunch" != xno; then
1340         enable_x11_autolaunch="$have_x11"
1341     fi
1342 fi
1343
1344 if test "x$have_x11" = xyes ; then
1345    AC_DEFINE([DBUS_BUILD_X11], [1], [Define to build X11 functionality])
1346 fi
1347
1348 if test "x$enable_x11_autolaunch" = xyes ; then
1349    AC_DEFINE([DBUS_ENABLE_X11_AUTOLAUNCH], [1], [Define to enable X11 auto-launch])
1350 fi
1351 AM_CONDITIONAL([DBUS_ENABLE_X11_AUTOLAUNCH],
1352   [test "x$enable_x11_autolaunch" = xyes])
1353
1354 AC_SUBST([DBUS_X_CFLAGS])
1355 AC_SUBST([DBUS_X_LIBS])
1356
1357 # We're treating -fno-common like a warning: it makes the linker more
1358 # strict, because on some systems the linker is *always* this strict
1359 TEST_CFLAGS="$TEST_CFLAGS -fno-common"
1360
1361 AS_IF([test "x$enable_ansi" = "xyes"],[
1362     TEST_CFLAGS="$TEST_CFLAGS -ansi -pedantic"
1363     AC_DEFINE([_POSIX_C_SOURCE],[199309L],[Define to enable POSIX features])
1364     AC_DEFINE([_BSD_SOURCE],[1],[Define to enable BSD features])
1365   ])
1366
1367 dnl TODO: The compiler flags below disable warnings that the
1368 dnl       compiler emits while building dbus. Fix the source
1369 dnl       code and remove these flags.
1370 DISABLE_WARNINGS="$DISABLE_WARNINGS
1371                   -Wno-switch-default
1372                   -Wno-switch-enum
1373                   "
1374
1375 dnl We are only calling this for its side-effect of setting up
1376 dnl --enable-compile-warnings; the WARN_CFLAGS, etc. are ignored,
1377 dnl to work around https://github.com/peti/autoconf-archive/pull/96
1378 AX_COMPILER_FLAGS([], [], [$disable_developer])
1379
1380 dnl Work around https://github.com/peti/autoconf-archive/pull/96 by using
1381 dnl a non-default variable name here (in particular there is no way to tell
1382 dnl AX_COMPILER_FLAGS to not use WARN_CXXFLAGS)
1383 AX_COMPILER_FLAGS_CFLAGS([EXTRA_CFLAGS],
1384                          [$disable_developer],
1385                          [$TEST_CFLAGS],
1386                          [-Wchar-subscripts \
1387                           -Wfloat-equal \
1388                           -Wpointer-sign \
1389                           $DISABLE_WARNINGS])
1390 dnl cc1plus: warning: command line option ‘-Wpointer-sign’ is valid for
1391 dnl C/ObjC but not for C++
1392 AX_COMPILER_FLAGS_CXXFLAGS([EXTRA_CXXFLAGS],
1393                            [$disable_developer],
1394                            [],
1395                            [-Wchar-subscripts \
1396                             -Wfloat-equal \
1397                             $DISABLE_WARNINGS])
1398 AX_COMPILER_FLAGS_LDFLAGS([EXTRA_LDFLAGS],
1399                           [$disable_developer])
1400
1401 dnl TODO: In principle we should put EXTRA_CFLAGS in each Makefile.am like
1402 dnl telepathy-glib does, since CFLAGS is meant to be reserved for the user...
1403 dnl but prepending to CFLAGS (so the user can override it with later CFLAGS)
1404 dnl is the next best thing.
1405 CFLAGS="$EXTRA_CFLAGS $CFLAGS"
1406 CXXFLAGS="$EXTRA_CXXFLAGS $CXXFLAGS"
1407 LDFLAGS="$EXTRA_LDFLAGS $LDFLAGS"
1408
1409 case $host_os in
1410     solaris*)
1411         # Solaris' C library apparently needs these runes to be threadsafe...
1412         CFLAGS="$CFLAGS -D_POSIX_PTHREAD_SEMANTICS -D_REENTRANT"
1413         # ... this opt-in to get sockaddr_in6 and sockaddr_storage...
1414         CFLAGS="$CFLAGS -D__EXTENSIONS__"
1415         # ... and this opt-in to get file descriptor passing support
1416         CFLAGS="$CFLAGS -D_XOPEN_SOURCE=500"
1417         ;;
1418 esac
1419
1420 ### Detect if ld supports --version-script
1421
1422 gl_LD_VERSION_SCRIPT
1423 AM_CONDITIONAL([HAVE_LD_VERSION_SCRIPT],
1424                [test "x$have_ld_version_script" = xyes])
1425 ### Doxygen Documentation
1426
1427 AC_PATH_PROG(DOXYGEN, doxygen, no)
1428
1429 AC_MSG_CHECKING([whether to build Doxygen documentation])
1430
1431 if test x$DOXYGEN = xno ; then
1432     have_doxygen=no
1433 else
1434     have_doxygen=yes
1435 fi
1436
1437 if test x$enable_doxygen_docs = xauto ; then
1438     if test x$have_doxygen = xno ; then
1439         enable_doxygen_docs=no
1440     else
1441         enable_doxygen_docs=yes
1442     fi
1443 fi
1444
1445 if test x$enable_doxygen_docs = xyes; then
1446     if test x$have_doxygen = xno; then
1447         AC_MSG_ERROR([Building Doxygen docs explicitly required, but Doxygen not found])
1448     fi
1449 fi
1450
1451 AM_CONDITIONAL(DBUS_DOXYGEN_DOCS_ENABLED, test x$enable_doxygen_docs = xyes)
1452 AC_MSG_RESULT($enable_doxygen_docs)
1453
1454 AC_CHECK_PROGS([XSLTPROC], [xsltproc])
1455 AM_CONDITIONAL([DBUS_HAVE_XSLTPROC], [test "x$XSLTPROC" != "x"])
1456
1457 ### Ducktype/Yelp documentation
1458
1459 AC_PATH_PROG([DUCKTYPE],[ducktype],[no])
1460 AC_PATH_PROG([YELP_BUILD],[yelp-build],[no])
1461
1462 AC_MSG_CHECKING([whether to build Ducktype documentation])
1463
1464 AS_IF([test "$DUCKTYPE" = "no"],[have_ducktype=no],[have_ducktype=yes])
1465 AS_IF([test "$YELP_BUILD" = "no"],[have_yelp_build=no],[have_yelp_build=yes])
1466
1467 AS_IF([test "$enable_ducktype_docs" = "auto"],[
1468     AS_IF([test "$have_ducktype" = "no" || test "$have_yelp_build" = "no"],[
1469         enable_ducktype_docs=no
1470     ],[
1471         enable_ducktype_docs=yes
1472     ])
1473 ])
1474
1475 AS_IF([test "$enable_ducktype_docs" = "yes"],[
1476     AS_IF([test "$have_ducktype" = "no"],[
1477         AC_MSG_ERROR([Building Ducktype docs explicitly required, but ducktype not found])
1478     ])
1479     AS_IF([test "$have_yelp_build" = "no"],[
1480         AC_MSG_ERROR([Building Ducktype docs explicitly required, but yelp-build not found])
1481     ])
1482 ])
1483
1484 AM_CONDITIONAL([DBUS_DUCKTYPE_DOCS_ENABLED],[test "$enable_ducktype_docs" = "yes"])
1485 AC_MSG_RESULT([$enable_ducktype_docs])
1486
1487 ### XML Documentation
1488
1489 AC_PATH_PROG(XMLTO, xmlto, no)
1490
1491 AC_MSG_CHECKING([whether to build XML documentation])
1492
1493 if test x$XMLTO = xno ; then
1494     have_xmlto=no
1495 else
1496     have_xmlto=yes
1497 fi
1498
1499 if test x$enable_xml_docs = xauto ; then
1500     if test x$have_xmlto = xno ; then
1501         enable_xml_docs=no
1502     else
1503         enable_xml_docs=yes
1504     fi
1505 fi
1506
1507 if test x$enable_xml_docs = xyes; then
1508     if test x$have_xmlto = xno; then
1509         AC_MSG_ERROR([Building XML docs explicitly required, but xmlto not found])
1510     fi
1511 fi
1512
1513 AM_CONDITIONAL(DBUS_XML_DOCS_ENABLED, test x$enable_xml_docs = xyes)
1514 AC_MSG_RESULT($enable_xml_docs)
1515
1516 AM_CONDITIONAL(DBUS_CAN_UPLOAD_DOCS,
1517     [test x$enable_doxygen_docs = xyes && test x$enable_xml_docs = xyes &&
1518      test x$enable_ducktype_docs = xyes])
1519
1520 #### Have to go $localstatedir->$prefix/var->/usr/local/var
1521
1522 #### find the actual value for $prefix that we'll end up with
1523 ##   (I know this is broken and should be done in the Makefile, but
1524 ##    that's a major pain and almost nobody actually seems to care)
1525 AS_AC_EXPAND(EXPANDED_PREFIX, "$prefix")
1526 AS_AC_EXPAND(EXPANDED_LOCALSTATEDIR, "$localstatedir")
1527 AS_AC_EXPAND(EXPANDED_SYSCONFDIR, "$sysconfdir")
1528 AS_AC_EXPAND(EXPANDED_BINDIR, "$bindir")
1529 AS_AC_EXPAND(EXPANDED_LIBDIR, "$libdir")
1530 AS_AC_EXPAND(EXPANDED_LIBEXECDIR, "$libexecdir")
1531 AS_AC_EXPAND(EXPANDED_DATADIR, "$datadir")
1532
1533 #### Check our operating system
1534 operating_system=unknown
1535 if test -f /etc/redhat-release || test -f $EXPANDED_SYSCONFDIR/redhat-release ; then
1536    operating_system=redhat
1537 fi
1538
1539 if test -f /etc/slackware-version || test -f $EXPANDED_SYSCONFDIR/slackware-version ; then
1540    operating_system=slackware
1541 fi
1542
1543 if test -f /usr/bin/cygwin1.dll || test -f $EXPANDED_BINDIR/cygwin1.dll ; then
1544    operating_system=cygwin
1545 fi
1546
1547 #### Sort out init scripts
1548
1549 if test x$with_init_scripts = x; then
1550     case x$operating_system in
1551         xredhat)        with_init_scripts=redhat ;;
1552         xslackware)     with_init_scripts=slackware ;;
1553         xcygwin)        with_init_scripts=cygwin ;;
1554         *)                      with_init_scripts=none ;;
1555     esac
1556 fi
1557
1558 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_RED_HAT, test x$with_init_scripts = xredhat)
1559 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_SLACKWARE, test x$with_init_scripts = xslackware)
1560 AM_CONDITIONAL(DBUS_INIT_SCRIPTS_CYGWIN, test x$with_init_scripts = xcygwin)
1561
1562 ##### systemd unit files
1563 AC_ARG_WITH([systemdsystemunitdir],
1564 AS_HELP_STRING([--with-systemdsystemunitdir=DIR], [Directory for systemd service files]),
1565     [],
1566     [
1567     PKG_CHECK_EXISTS([systemd],
1568       [with_systemdsystemunitdir=$($PKG_CONFIG --variable=systemdsystemunitdir systemd)],
1569       [with_systemdsystemunitdir=no])
1570     ])
1571 if test "x$with_systemdsystemunitdir" != xno; then
1572    AC_SUBST([systemdsystemunitdir], [$with_systemdsystemunitdir])
1573 fi
1574 AM_CONDITIONAL(HAVE_SYSTEMD, [test "x$have_systemd" != "xno" -a -n "$with_systemdsystemunitdir" -a "x$with_systemdsystemunitdir" != xno ])
1575
1576 AC_ARG_WITH([systemduserunitdir],
1577 AS_HELP_STRING([--with-systemduserunitdir=DIR], [Directory for systemd user service files]),
1578     [],
1579     [
1580     PKG_CHECK_EXISTS([systemd],
1581       [with_systemduserunitdir=$($PKG_CONFIG --variable=systemduserunitdir systemd)],
1582       [with_systemduserunitdir='${libdir}/systemd/user'])
1583     ])
1584 AC_SUBST([systemduserunitdir], [$with_systemduserunitdir])
1585
1586 ##### Set up location for system bus socket
1587 if ! test -z "$with_system_socket"; then
1588    DBUS_SYSTEM_SOCKET=$with_system_socket
1589 else
1590    DBUS_SYSTEM_SOCKET=${EXPANDED_LOCALSTATEDIR}/run/dbus/system_bus_socket
1591 fi
1592
1593 AC_SUBST(DBUS_SYSTEM_SOCKET)
1594 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_SOCKET,"$DBUS_SYSTEM_SOCKET",[The name of the socket the system bus listens on by default])
1595
1596 ## System bus only listens on local domain sockets, and never
1597 ## on an abstract socket (so only root can create the socket).
1598 ##
1599 ## This won't work on Windows. It's not meant to - the system bus is
1600 ## meaningless on Windows anyway.
1601 ##
1602 ## This has to be suitable for hard-coding in client libraries as well as
1603 ## in the dbus-daemon's configuration, so it has to be valid to listen on
1604 ## and also to connect to. If this ever changes, it'll need to be split into
1605 ## two variables, one for the listening address and one for the connecting
1606 ## address.
1607 DBUS_SYSTEM_BUS_DEFAULT_ADDRESS="unix:path=$DBUS_SYSTEM_SOCKET"
1608 AC_SUBST(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS)
1609 AC_DEFINE_UNQUOTED(DBUS_SYSTEM_BUS_DEFAULT_ADDRESS, "$DBUS_SYSTEM_BUS_DEFAULT_ADDRESS",[The default D-Bus address of the system bus])
1610
1611 #### Set up the pid file
1612 if ! test -z "$with_system_pid_file"; then
1613    DBUS_SYSTEM_PID_FILE=$with_system_pid_file
1614 elif test x$with_init_scripts = xredhat ; then
1615    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/messagebus.pid
1616 else
1617    DBUS_SYSTEM_PID_FILE=${EXPANDED_LOCALSTATEDIR}/run/dbus/pid
1618 fi
1619
1620 AC_SUBST(DBUS_SYSTEM_PID_FILE)
1621
1622 #### Directory to check for console ownership
1623 if ! test -z "$with_console_auth_dir"; then
1624    DBUS_CONSOLE_AUTH_DIR=$with_console_auth_dir
1625 else
1626    DBUS_CONSOLE_AUTH_DIR=/var/run/console/
1627 fi
1628
1629 AC_SUBST(DBUS_CONSOLE_AUTH_DIR)
1630 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_AUTH_DIR, "$DBUS_CONSOLE_AUTH_DIR", [Directory to check for console ownerhip])
1631
1632 #### File to check for console ownership
1633 if test x$have_console_owner_file = xyes; then
1634    if ! test -z "$with_console_owner_file"; then
1635       DBUS_CONSOLE_OWNER_FILE=$with_console_owner_file
1636    else
1637       DBUS_CONSOLE_OWNER_FILE=/dev/console
1638    fi
1639 else
1640   DBUS_CONSOLE_OWNER_FILE=
1641 fi
1642
1643 AC_SUBST(DBUS_CONSOLE_OWNER_FILE)
1644 AC_DEFINE_UNQUOTED(DBUS_CONSOLE_OWNER_FILE, "$DBUS_CONSOLE_OWNER_FILE", [File to check for console ownerhip])
1645
1646 #### User to start the system bus as
1647 if test -z "$with_dbus_user" ; then
1648     DBUS_USER=messagebus
1649 else
1650     DBUS_USER=$with_dbus_user
1651 fi
1652 AC_SUBST(DBUS_USER)
1653 AC_DEFINE_UNQUOTED(DBUS_USER,"$DBUS_USER", [User for running the system BUS daemon])
1654
1655 #### User for regression tests
1656 AS_IF([test -z "$with_test_user"], [with_test_user=nobody])
1657 DBUS_TEST_USER="$with_test_user"
1658 AC_SUBST([DBUS_TEST_USER])
1659 AC_DEFINE_UNQUOTED([DBUS_TEST_USER], ["$DBUS_TEST_USER"],
1660   [Unprivileged user used in some regression tests])
1661
1662 #### Prefix to install into
1663 DBUS_PREFIX=$EXPANDED_PREFIX
1664 AC_SUBST(DBUS_PREFIX)
1665 AC_DEFINE_UNQUOTED(DBUS_PREFIX,"$DBUS_PREFIX", [Prefix for installing DBUS])
1666
1667 #### Direcotry to install data files into
1668 DBUS_DATADIR=$EXPANDED_DATADIR
1669 AC_SUBST(DBUS_DATADIR)
1670 AC_DEFINE_UNQUOTED(DBUS_DATADIR,"$DBUS_DATADIR", [Directory for installing DBUS data files])
1671
1672 #### Directory to install dbus-daemon
1673 if test -z "$with_dbus_daemondir" ; then
1674     DBUS_DAEMONDIR=$EXPANDED_BINDIR
1675     dbus_daemondir='$bindir'
1676 else
1677     DBUS_DAEMONDIR=$with_dbus_daemondir
1678     dbus_daemondir=$with_dbus_daemondir
1679 fi
1680 AC_SUBST(DBUS_DAEMONDIR)
1681 AC_SUBST(dbus_daemondir)
1682 AC_DEFINE_UNQUOTED(DBUS_DAEMONDIR,"$DBUS_DAEMONDIR", [Directory for installing the DBUS daemon])
1683
1684 #### Directory to install the other binaries
1685 DBUS_BINDIR="$EXPANDED_BINDIR"
1686 AC_SUBST(DBUS_BINDIR)
1687 AC_DEFINE_UNQUOTED(DBUS_BINDIR,"$DBUS_BINDIR", [Directory for installing the binaries])
1688
1689 #### Directory to install the libexec binaries
1690 DBUS_LIBEXECDIR="$EXPANDED_LIBEXECDIR"
1691 AC_SUBST(DBUS_LIBEXECDIR)
1692 AC_DEFINE_UNQUOTED(DBUS_LIBEXECDIR,"$DBUS_LIBEXECDIR", [Directory for installing the libexec binaries])
1693
1694 #### Directory to source sysconfdir configuration from
1695
1696 # On Windows this is relative to where we put the bus setup, in
1697 # ${datadir}/dbus-1. For simplicity, we only do this if
1698 # ${sysconfdir} = ${prefix}/etc and ${datadir} = ${prefix}/share.
1699 #
1700 # On Unix, or on Windows with weird install layouts, it's the absolute path.
1701 AS_IF([test "${dbus_win}" = yes && \
1702        test "$EXPANDED_SYSCONFDIR" = "$EXPANDED_PREFIX/etc" && \
1703        test "$EXPANDED_DATADIR" = "$EXPANDED_PREFIX/share"],
1704       [SYSCONFDIR_FROM_PKGDATADIR="../../etc"
1705        DATADIR_FROM_PKGSYSCONFDIR="../../share"],
1706       [SYSCONFDIR_FROM_PKGDATADIR="$EXPANDED_SYSCONFDIR"
1707        DATADIR_FROM_PKGSYSCONFDIR="$EXPANDED_DATADIR"])
1708 AC_SUBST([SYSCONFDIR_FROM_PKGDATADIR])
1709 AC_SUBST([DATADIR_FROM_PKGSYSCONFDIR])
1710
1711 #### Tell tests where to find certain stuff in builddir
1712
1713 DBUS_PWD=`pwd`
1714 # Useful in a cross-compilation environment, where the tests are run on the host system.
1715 AC_ARG_WITH(dbus-test-dir, AS_HELP_STRING([--with-dbus-test-dir=[dirname]],[path where the tests tools are available]),
1716                            DBUS_PWD=$withval)
1717
1718 DBUS_TEST_EXEC="$DBUS_PWD/test"
1719 DBUS_TEST_DATA="$DBUS_PWD/test/data"
1720
1721 AC_SUBST([DBUS_TEST_DATA])
1722 AC_SUBST([DBUS_TEST_EXEC])
1723
1724 AC_DEFINE_UNQUOTED([DBUS_TEST_EXEC], ["$DBUS_TEST_EXEC"],
1725                    [Full path to the daemon in the builddir])
1726 AC_DEFINE_UNQUOTED([DBUS_EXEEXT], ["$EXEEXT"],
1727                    [Extension for executables, typically empty or .exe])
1728
1729 ## Export the non-setuid external helper
1730 TEST_LAUNCH_HELPER_BINARY="$DBUS_PWD/bus/dbus-daemon-launch-helper-test$EXEEXT"
1731 AC_SUBST(TEST_LAUNCH_HELPER_BINARY)
1732 AC_DEFINE_UNQUOTED(DBUS_TEST_LAUNCH_HELPER_BINARY, "$TEST_LAUNCH_HELPER_BINARY",
1733                    [Full path to the launch helper test program in the builddir])
1734
1735 #### Find socket directories
1736 if ! test -z "$TMPDIR" ; then
1737    DEFAULT_SOCKET_DIR=$TMPDIR
1738 elif ! test -z "$TEMP" ; then
1739    DEFAULT_SOCKET_DIR=$TEMP
1740 elif ! test -z "$TMP" ; then
1741    DEFAULT_SOCKET_DIR=$TMP
1742 else
1743    DEFAULT_SOCKET_DIR=/tmp
1744 fi
1745
1746 DEFAULT_SOCKET_DIR=`echo $DEFAULT_SOCKET_DIR | sed 's/+/%2B/g'`
1747
1748 if ! test -z "$with_test_socket_dir" ; then
1749    TEST_SOCKET_DIR="$with_test_socket_dir"
1750 else
1751    TEST_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1752 fi
1753 AC_SUBST(TEST_SOCKET_DIR)
1754 AC_DEFINE_UNQUOTED(DBUS_TEST_SOCKET_DIR, "$TEST_SOCKET_DIR", [Where to put test sockets])
1755
1756 if test "x$dbus_unix" = xyes; then
1757   TEST_LISTEN="unix:tmpdir=$TEST_SOCKET_DIR"
1758 else
1759   TEST_LISTEN="tcp:host=localhost"
1760 fi
1761 AC_SUBST([TEST_LISTEN])
1762 AC_DEFINE_UNQUOTED([TEST_LISTEN], ["$TEST_LISTEN"],
1763   [Listening address for regression tests])
1764
1765 if ! test -z "$with_session_socket_dir" ; then
1766    DBUS_SESSION_SOCKET_DIR="$with_session_socket_dir"
1767 else
1768    DBUS_SESSION_SOCKET_DIR=$DEFAULT_SOCKET_DIR
1769 fi
1770 AC_DEFINE_UNQUOTED(DBUS_SESSION_SOCKET_DIR, "$DBUS_SESSION_SOCKET_DIR", [Where per-session bus puts its sockets])
1771 AC_SUBST(DBUS_SESSION_SOCKET_DIR)
1772
1773 # This must be a listening address. It doesn't necessarily need to be an
1774 # address you can connect to - it can be something vague like
1775 # "nonce-tcp:".
1776 #
1777 # The default varies by platform.
1778 AC_ARG_WITH([dbus_session_bus_listen_address],
1779             AS_HELP_STRING([--with-dbus-session-bus-listen-address=[ADDRESS]],
1780                            [default address for a session bus to listen on (see configure.ac)]),
1781             [with_dbus_session_bus_listen_address=$withval],
1782             [with_dbus_session_bus_listen_address=])
1783
1784 if test "x$with_dbus_session_bus_listen_address" != "x"; then
1785         # the user specified something, trust them
1786         DBUS_SESSION_BUS_LISTEN_ADDRESS="$with_dbus_session_bus_listen_address"
1787 elif test x$dbus_win = xyes; then
1788         # On Windows, you can (and should) listen on autolaunch addresses,
1789         # because autolaunching is different.
1790         # See https://bugs.freedesktop.org/show_bug.cgi?id=38201
1791         DBUS_SESSION_BUS_LISTEN_ADDRESS="autolaunch:"
1792 elif test x$have_launchd = xyes; then
1793         # Mac OS X default is to use launchd
1794         DBUS_SESSION_BUS_LISTEN_ADDRESS="launchd:env=DBUS_LAUNCHD_SESSION_BUS_SOCKET"
1795 else
1796         # The default on all other Unix platforms (notably Linux)
1797         # is to create a randomly named socket in /tmp or similar
1798         DBUS_SESSION_BUS_LISTEN_ADDRESS="unix:tmpdir=$DBUS_SESSION_SOCKET_DIR"
1799 fi
1800 AC_SUBST([DBUS_SESSION_BUS_LISTEN_ADDRESS])
1801
1802 # This must be an address you can connect to. It doesn't necessarily
1803 # need to be an address you can listen on - it can be "autolaunch:",
1804 # even on Unix.
1805 #
1806 # The default varies by platform.
1807 AC_ARG_WITH([dbus_session_bus_connect_address],
1808             AS_HELP_STRING([--with-dbus-session-bus-connect-address=[ADDRESS]],
1809                            [fallback address for a session bus client to connect to (see configure.ac)]),
1810             [with_dbus_session_bus_connect_address=$withval],
1811             [with_dbus_session_bus_connect_address=])
1812
1813 if test "x$with_dbus_session_bus_connect_address" != "x"; then
1814         # the user specified something, trust them
1815         DBUS_SESSION_BUS_CONNECT_ADDRESS="$with_dbus_session_bus_connect_address"
1816 elif test x$dbus_win = xyes; then
1817         # Windows autolaunching is a bit different; leaving it in its own
1818         # branch of the conditional because the default might conceivably
1819         # change (see #38201)
1820         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1821 else
1822         # The default on all other Unix platforms (notably Linux)
1823         # is to use auto-launching - this works a bit differently on Mac OS X
1824         # but comes out basically the same in the end
1825         DBUS_SESSION_BUS_CONNECT_ADDRESS="autolaunch:"
1826 fi
1827 AC_SUBST([DBUS_SESSION_BUS_CONNECT_ADDRESS])
1828 AC_DEFINE_UNQUOTED([DBUS_SESSION_BUS_CONNECT_ADDRESS],
1829   ["$DBUS_SESSION_BUS_CONNECT_ADDRESS"],
1830   [Fallback address for session bus clients])
1831
1832 # darwin needs this to initialize the environment
1833 AC_CHECK_HEADERS(crt_externs.h)
1834 AC_CHECK_FUNC(_NSGetEnviron, [AC_DEFINE(HAVE_NSGETENVIRON, 1, [Define if your system needs _NSGetEnviron to set up the environment])])
1835 AH_VERBATIM(_DARWIN_ENVIRON,
1836 [
1837 #if defined(HAVE_NSGETENVIRON) && defined(HAVE_CRT_EXTERNS_H)
1838 # include <sys/time.h>
1839 # include <crt_externs.h>
1840 # define environ (*_NSGetEnviron())
1841 #endif
1842 ])
1843
1844 AC_ARG_ENABLE([stats],
1845   [AS_HELP_STRING([--disable-stats],
1846     [disable bus daemon usage statistics])],
1847   [], [enable_stats=yes])
1848 if test "x$enable_stats" = xyes; then
1849   AC_DEFINE([DBUS_ENABLE_STATS], [1],
1850     [Define to enable bus daemon usage statistics])
1851 fi
1852
1853 AC_ARG_ENABLE([user-session],
1854   [AS_HELP_STRING([--enable-user-session],
1855     [enable user-session semantics for session bus under systemd])],
1856   [], [enable_user_session=no])
1857 AM_CONDITIONAL([DBUS_ENABLE_USER_SESSION],
1858   [test "x$enable_user_session" = xyes])
1859
1860 AC_CONFIG_FILES([
1861 Doxyfile
1862 dbus/Version
1863 dbus/versioninfo.rc
1864 dbus/dbus-arch-deps.h
1865 bus/system.conf
1866 bus/session.conf
1867 bus/legacy-config/system.conf
1868 bus/legacy-config/session.conf
1869 bus/example-system-enable-stats.conf
1870 bus/example-session-disable-stats.conf
1871 bus/messagebus
1872 bus/messagebus-config
1873 bus/org.freedesktop.dbus-session.plist
1874 bus/rc.messagebus
1875 bus/dbus.service
1876 bus/dbus.socket
1877 bus/systemd-user/dbus.service
1878 bus/systemd-user/dbus.socket
1879 bus/sysusers.d/dbus.conf
1880 Makefile
1881 dbus/Makefile
1882 bus/Makefile
1883 tools/Makefile
1884 test/Makefile
1885 test/name-test/Makefile
1886 doc/Makefile
1887 doc/dbus-cleanup-sockets.1.xml
1888 doc/dbus-daemon.1.xml
1889 doc/dbus-launch.1.xml
1890 doc/dbus-monitor.1.xml
1891 doc/dbus-run-session.1.xml
1892 doc/dbus-send.1.xml
1893 doc/dbus-test-tool.1.xml
1894 doc/dbus-update-activation-environment.1.xml
1895 doc/dbus-uuidgen.1.xml
1896 dbus-1.pc
1897 dbus-1-uninstalled.pc
1898 ])
1899 AC_OUTPUT
1900
1901 dnl ==========================================================================
1902 echo "
1903                     D-Bus $VERSION
1904                   ==============
1905
1906         prefix:                   ${EXPANDED_PREFIX}
1907         exec_prefix:              ${exec_prefix}
1908         libdir:                   ${EXPANDED_LIBDIR}
1909         libexecdir:               ${EXPANDED_LIBEXECDIR}
1910         bindir:                   ${EXPANDED_BINDIR}
1911         sysconfdir:               ${EXPANDED_SYSCONFDIR}
1912         localstatedir:            ${EXPANDED_LOCALSTATEDIR}
1913         datadir:                  ${EXPANDED_DATADIR}
1914         source code location:     ${srcdir}
1915         compiler:                 ${CC}
1916         cflags:                   ${CFLAGS}
1917         cppflags:                 ${CPPFLAGS}
1918         cxxflags:                 ${CXXFLAGS}
1919         ldflags:                  ${LDFLAGS}
1920         64-bit int:               ${DBUS_INT64_TYPE}
1921         32-bit int:               ${DBUS_INT32_TYPE}
1922         16-bit int:               ${DBUS_INT16_TYPE}
1923         Doxygen:                  ${DOXYGEN:-not found}
1924         xmlto:                    ${XMLTO:-not found}
1925         ducktype:                 ${DUCKTYPE:-not found}
1926         yelp-build:               ${YELP_BUILD:-not found}"
1927
1928 echo "
1929         Rebuilding generated files: ${USE_MAINTAINER_MODE}
1930         gcc coverage profiling:   ${enable_code_coverage}
1931         Building embedded tests:  ${enable_embedded_tests}
1932         Building modular tests:   ${enable_modular_tests}
1933             - with GLib:          ${with_glib}
1934         Installing tests:         ${enable_installed_tests}
1935         Building verbose mode:    ${enable_verbose_mode}
1936         Building assertions:      ${enable_asserts}
1937         Building checks:          ${enable_checks}
1938         Building bus stats API:   ${enable_stats}
1939         Building SELinux support: ${have_selinux}
1940         Building AppArmor support: ${have_apparmor}
1941         Building inotify support: ${have_inotify}
1942         Building kqueue support:  ${have_kqueue}
1943         Building systemd support: ${have_systemd}
1944         Building X11 code:        ${have_x11}
1945         Building Doxygen docs:    ${enable_doxygen_docs}
1946         Building Ducktype docs:   ${enable_ducktype_docs}
1947         Building XML docs:        ${enable_xml_docs}
1948         Building launchd support: ${have_launchd}
1949         Init scripts style:       ${with_init_scripts}
1950         Abstract socket names:    ${ac_cv_have_abstract_sockets}
1951         System bus socket:        ${DBUS_SYSTEM_SOCKET}
1952         System bus address:       ${DBUS_SYSTEM_BUS_DEFAULT_ADDRESS}
1953         System bus PID file:      ${DBUS_SYSTEM_PID_FILE}
1954         Session bus listens on:   ${DBUS_SESSION_BUS_LISTEN_ADDRESS}
1955         Session clients connect to: ${DBUS_SESSION_BUS_CONNECT_ADDRESS}
1956         Console auth dir:         ${DBUS_CONSOLE_AUTH_DIR}
1957         Console owner file:       ${have_console_owner_file}
1958         Console owner file path:  ${DBUS_CONSOLE_OWNER_FILE}
1959         System bus user:          ${DBUS_USER}
1960         Session bus services dir: ${EXPANDED_DATADIR}/dbus-1/services
1961         'make check' socket dir:  ${TEST_SOCKET_DIR}
1962 "
1963 if test x$have_launchd = xyes; then
1964         echo "        launchd agent dir:        ${LAUNCHD_AGENT_DIR}"
1965 fi
1966 echo
1967
1968 if test x$enable_embedded_tests = xyes; then
1969         echo "NOTE: building with unit tests increases the size of the installed library and renders it insecure."
1970 fi
1971 if test x$enable_embedded_tests = xyes -a x$enable_asserts = xno; then
1972         echo "NOTE: building with embedded tests but without assertions means tests may not properly report failures (this configuration is only useful when doing something like profiling the tests)"
1973 fi
1974 AS_IF([test x$enable_code_coverage = xyes],[
1975     AC_MSG_WARN([Building with coverage profiling is definitely for developers only.])
1976   ])
1977 if test x$enable_verbose_mode = xyes; then
1978         echo "NOTE: building with verbose mode increases library size, may slightly increase security risk, and decreases performance."
1979 fi
1980 if test x$enable_asserts = xyes; then
1981         echo "NOTE: building with assertions increases library size and decreases performance."
1982 fi
1983 if test x$enable_checks = xno; then
1984         echo "NOTE: building without checks for arguments passed to public API makes it harder to debug apps using D-Bus, but will slightly decrease D-Bus library size and _very_ slightly improve performance."
1985 fi