configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [35])
  34 m4_define([glib_micro_version], [1])
  35 m4_define([glib_interface_age], [0])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     glib_native_win32=no
 156     glib_pid_type=int
 157     ;;
 158 esac
 159 case $host in
 160   *-*-linux*)
 161     glib_os_linux=yes
 162     ;;
 163 esac
 164
 165 AC_MSG_RESULT([$glib_native_win32])
 166
 167 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 168
 169 glib_have_carbon=no
 170 AC_MSG_CHECKING([for Mac OS X Carbon support])
 171 AC_TRY_CPP([
 172 #include <Carbon/Carbon.h>
 173 #include <CoreServices/CoreServices.h>
 174 ], glib_have_carbon=yes)
 175
 176 AC_MSG_RESULT([$glib_have_carbon])
 177
 178 glib_have_cocoa=no
 179 AC_MSG_CHECKING([for Mac OS X Cocoa support])
 180 AC_TRY_CPP([
 181 #include <Cocoa/Cocoa.h>
 182 #ifdef GNUSTEP_BASE_VERSION
 183 #error "Detected GNUstep, not Cocoa"
 184 #endif
 185 ], glib_have_cocoa=yes)
 186
 187 AC_MSG_RESULT([$glib_have_cocoa])
 188
 189 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 190 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 191 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 192 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 193 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 194 AM_CONDITIONAL(OS_COCOA, [test "$glib_have_cocoa" = "yes"])
 195
 196 AS_IF([test "$glib_native_win32" = "yes"], [
 197   AC_CHECK_TOOL(WINDRES, windres, no)
 198   if test "$WINDRES" = no; then
 199     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 200   fi
 201   AC_CHECK_TOOL(NM, nm, no)
 202   if test "$NM" = no; then
 203     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 204   fi
 205   AC_CHECK_TOOL(RANLIB, ranlib, :)
 206   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 207 ])
 208 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 209
 210 if test "$glib_native_win32" != yes; then
 211     # libtool option to control which symbols are exported
 212     # right now, symbols starting with _ are not exported
 213     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 214 else
 215     # We currently use .def files on Windows
 216     LIBTOOL_EXPORT_OPTIONS=
 217 fi
 218 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 219
 220 AS_IF([test "x$glib_have_carbon" = "xyes"], [
 221   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 222   LDFLAGS="$LDFLAGS -Wl,-framework,Carbon"
 223 ])
 224
 225 if test "x$glib_have_cocoa" = "xyes"; then
 226   AC_DEFINE(HAVE_COCOA, 1, [define to 1 if Cocoa is available])
 227   LDFLAGS="$LDFLAGS -Wl,-framework,Foundation"
 228 fi
 229
 230 gl_GLIBC21
 231 AS_IF([test "x$GLIBC21" = "xyes"], [
 232   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 233 ])
 234
 235 dnl declare --enable-* args and collect ac_help strings
 236 AC_ARG_ENABLE(debug,
 237               AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 238                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 239               enable_debug=glib_debug_default)
 240
 241 AC_ARG_ENABLE(gc_friendly,
 242               [AS_HELP_STRING([--enable-gc-friendly],
 243                               [turn on garbage collector friendliness [default=no]])],,
 244               [enable_gc_friendly=no])
 245 AC_ARG_ENABLE(mem_pools,
 246               [AS_HELP_STRING([--disable-mem-pools],
 247                               [disable all glib memory pools])],,
 248               [disable_mem_pools=no])
 249 AC_ARG_ENABLE(rebuilds,
 250               [AS_HELP_STRING([--disable-rebuilds],
 251                               [disable all source autogeneration rules])],,
 252               [enable_rebuilds=yes])
 253 AC_ARG_ENABLE(modular_tests,
 254               AS_HELP_STRING([--disable-modular-tests],
 255                              [Disable build of test programs (default: no)]),,
 256               [enable_modular_tests=yes])
 257 AM_CONDITIONAL(BUILD_MODULAR_TESTS, test x$enable_modular_tests = xyes)
 258
 259 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 260 AS_IF([test "x$enable_gc_friendly" = "xyes"], [
 261   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 262   AC_MSG_RESULT([yes])
 263 ], [ AC_MSG_RESULT([no]) ])
 264
 265 AC_MSG_CHECKING([whether to disable memory pools])
 266 AS_IF([test "x$disable_mem_pools" = "xno"], [
 267   AC_MSG_RESULT([no])
 268 ], [
 269   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 270   AC_MSG_RESULT([yes])
 271 ])
 272
 273 dnl location to install runtime libraries, e.g. ../../lib to install
 274 dnl to /lib if libdir is /usr/lib
 275 AC_ARG_WITH(runtime-libdir,
 276            [AS_HELP_STRING([--with-runtime-libdir=RELPATH],
 277                            [install runtime libraries relative to libdir])],
 278            [],
 279            [with_runtime_libdir=""])
 280 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 281 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 282 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 283 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 284 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 285
 286 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 287 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 288 AC_LANG_SAVE
 289 AC_LANG_CPLUSPLUS
 290 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 291 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 292 AC_LANG_RESTORE
 293
 294 AM_PROG_CC_STDC
 295 AM_PROG_CC_C_O
 296 AC_PROG_INSTALL
 297
 298 AC_SYS_LARGEFILE
 299
 300 PKG_PROG_PKG_CONFIG(0.16)
 301
 302 if test "x$enable_debug" = "xyes"; then
 303   if test x$cflags_set != xset ; then
 304       case " $CFLAGS " in
 305       *[[\ \    ]]-g[[\ \       ]]*) ;;
 306       *) CFLAGS="$CFLAGS -g" ;;
 307       esac
 308   fi
 309   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 310 else
 311   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 312
 313   if test "x$enable_debug" = "xno"; then
 314     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 315   fi
 316 fi
 317
 318 # Ensure MSVC-compatible struct packing convention is used when
 319 # compiling for Win32 with gcc.
 320 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 321 # gcc2 uses "-fnative-struct".
 322 if test x"$glib_native_win32" = xyes; then
 323   if test x"$GCC" = xyes; then
 324     msnative_struct=''
 325     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 326     if test -z "$ac_cv_prog_CC"; then
 327       our_gcc="$CC"
 328     else
 329       our_gcc="$ac_cv_prog_CC"
 330     fi
 331     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 332       2.)
 333         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 334           msnative_struct='-fnative-struct'
 335         fi
 336         ;;
 337       *)
 338         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 339           msnative_struct='-mms-bitfields'
 340         fi
 341         ;;
 342     esac
 343     if test x"$msnative_struct" = x ; then
 344       AC_MSG_RESULT([no way])
 345       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 346     else
 347       CFLAGS="$CFLAGS $msnative_struct"
 348       AC_MSG_RESULT([${msnative_struct}])
 349     fi
 350   fi
 351 fi
 352 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 353 AC_SUBST(GLIB_EXTRA_CFLAGS)
 354
 355 AC_EXEEXT
 356
 357 # define a MAINT-like variable REBUILD which is set if Perl
 358 # and awk are found, so autogenerated sources can be rebuilt
 359 AC_PROG_AWK
 360 AC_CHECK_PROGS(PERL, [perl5 perl])
 361 # We would like indent, but don't require it.
 362 AC_CHECK_PROG(INDENT, indent, indent)
 363 REBUILD=\#
 364 if test "x$enable_rebuilds" = "xyes" && \
 365      test -n "$PERL" && \
 366      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 367      test -n "$AWK" ; then
 368   REBUILD=
 369 fi
 370 AC_SUBST(REBUILD)
 371
 372 # Need full path to Perl for glib-mkenums
 373 #
 374 if test "x$PERL" != x ; then
 375   AC_PATH_PROG(PERL_PATH, [$PERL])
 376 fi
 377 if test "x$PERL_PATH" = x ; then
 378   PERL_PATH="/usr/bin/env perl"
 379 fi
 380 AC_SUBST(PERL_PATH)
 381
 382 # Need suitable python path for greport
 383 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 384
 385
 386 dnl ***********************
 387 dnl *** Tests for iconv ***
 388 dnl ***********************
 389 dnl
 390 dnl We do this before the gettext checks, to avoid distortion
 391
 392 dnl On Windows we use a native implementation
 393
 394 AS_IF([ test x"$glib_native_win32" = xyes], [
 395   with_libiconv=native
 396 ], [
 397   AC_ARG_WITH(libiconv,
 398               [AS_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 399                               [use the libiconv library])],,
 400               [with_libiconv=maybe])
 401
 402   found_iconv=no
 403   case $with_libiconv in
 404     maybe)
 405       # Check in the C library first
 406       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 407       # Check if we have GNU libiconv
 408       if test $found_iconv = "no"; then
 409         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 410       fi
 411       # Check if we have a iconv in -liconv, possibly from vendor
 412       if test $found_iconv = "no"; then
 413         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 414       fi
 415       ;;
 416     no)
 417       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 418       ;;
 419     gnu|yes)
 420       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 421       ;;
 422     native)
 423       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 424       ;;
 425   esac
 426
 427   if test "x$found_iconv" = "xno" ; then
 428      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 429   fi
 430 ])
 431
 432 AC_ARG_ENABLE(iconv-cache,
 433               [AS_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 434                               [cache iconv descriptors [default=auto]])],,
 435               [enable_iconv_cache=auto])
 436
 437 AC_MSG_CHECKING([whether to cache iconv descriptors])
 438 case $enable_iconv_cache in
 439   auto)
 440     if test $ac_cv_gnu_library_2_1 = yes; then
 441       enable_iconv_cache=no
 442     else
 443       enable_iconv_cache=yes
 444     fi
 445   ;;
 446   yes|no)
 447   ;;
 448   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 449   ;;
 450 esac
 451
 452 if test $enable_iconv_cache = yes; then
 453    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 454 fi
 455
 456 AC_MSG_RESULT($enable_iconv_cache)
 457
 458
 459 dnl
 460 dnl zlib support
 461 dnl
 462 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 463 AS_IF([test "x$found_zlib" = "xno"], [
 464   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 465   if test "x$found_zlib" = "xno" ; then
 466     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 467   fi
 468   ZLIB_LIBS='-lz'
 469   AC_SUBST(ZLIB_LIBS)
 470 ])
 471
 472 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 473 AC_SUBST(LIBFFI_CFLAGS)
 474 AC_SUBST(LIBFFI_LIBS)
 475
 476 dnl
 477 dnl gettext support
 478 dnl
 479
 480 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 481 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 482 GLIB_GNU_GETTEXT
 483
 484 if test "$gt_cv_have_gettext" != "yes" ; then
 485   AC_MSG_ERROR([
 486 *** You must have either have gettext support in your C library, or use the
 487 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 488 ])
 489 fi
 490
 491 LIBS="$INTLLIBS $LIBS"
 492
 493 GETTEXT_PACKAGE=glib20
 494 AC_SUBST(GETTEXT_PACKAGE)
 495 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 496   [Define the gettext package to be used])
 497
 498 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 499
 500 dnl
 501 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 502 dnl
 503
 504 AS_IF([test x"$glib_native_win32" != xyes], [
 505   if test x$with_libiconv != xno ; then
 506     case " $INTLLIBS " in
 507     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 508     *) ICONV_LIBS="-liconv" ;;
 509     esac
 510   fi
 511 ])
 512 AC_SUBST(ICONV_LIBS)
 513
 514 case $with_libiconv in
 515   gnu)
 516     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 517     ;;
 518   native)
 519     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 520     ;;
 521 esac
 522
 523 dnl Initialize libtool
 524 LT_PREREQ([2.2])
 525 LT_INIT([disable-static win32-dll])
 526 dnl when using libtool 2.x create libtool early, because it's used in configure
 527 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 528
 529
 530 AS_IF([test "$glib_native_win32" = "yes"], [
 531   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 532     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 533   fi
 534   if test x$enable_static = xyes; then
 535     glib_win32_static_compilation=yes
 536     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 537 #define GOBJECT_STATIC_COMPILATION 1"
 538     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 539   fi
 540 ])
 541 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 542
 543 dnl
 544 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 545 dnl
 546 AS_IF([test $cross_compiling != yes], [
 547     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 548     glib_save_LIBS=$LIBS
 549     LIBS="$LIBS -lm"
 550     AC_TRY_RUN([#include <math.h>
 551                  int main (void) { return (log(1) != log(1.)); }],
 552          AC_MSG_RESULT(none needed),
 553          glib_save_CFLAGS=$CFLAGS
 554          CFLAGS="$CFLAGS -std1"
 555          AC_TRY_RUN([#include <math.h>
 556                      int main (void) { return (log(1) != log(1.)); }],
 557              AC_MSG_RESULT(-std1),
 558              AC_MSG_RESULT()
 559              CFLAGS=$glib_save_CFLAGS
 560              AC_MSG_WARN(
 561                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 562          )
 563     )
 564     LIBS=$glib_save_LIBS
 565 ])
 566
 567 dnl NeXTStep cc seems to need this
 568 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 569 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 570   AC_MSG_RESULT(none needed),
 571   glib_save_CFLAGS=$CFLAGS
 572   CFLAGS="$CFLAGS -posix"
 573   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 574     AC_MSG_RESULT(-posix),
 575     AC_MSG_RESULT()
 576     CFLAGS=$glib_save_CFLAGS
 577     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 578
 579 # Checks for library functions.
 580 AC_FUNC_VPRINTF
 581 AC_FUNC_ALLOCA
 582 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2 issetugid)
 583 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 584
 585 AC_CACHE_CHECK([for __libc_enable_secure], glib_cv_have_libc_enable_secure,
 586   [AC_TRY_LINK([#include <unistd.h>
 587     extern int __libc_enable_secure;],
 588     [return __libc_enable_secure;],
 589    glib_cv_have_libc_enable_secure=yes,
 590    glib_cv_have_libc_enable_secure=no)])
 591 AS_IF([test x$glib_cv_have_libc_enable_secure = xyes], [
 592    AC_DEFINE(HAVE_LIBC_ENABLE_SECURE, 1,
 593      [Define if you have the __libc_enable_secure variable (GNU libc, eglibc)])
 594 ])
 595
 596 AC_CHECK_SIZEOF(char)
 597 AC_CHECK_SIZEOF(short)
 598 AC_CHECK_SIZEOF(long)
 599 AC_CHECK_SIZEOF(int)
 600 AC_CHECK_SIZEOF(void *)
 601 AC_CHECK_SIZEOF(long long)
 602 AC_CHECK_SIZEOF(__int64)
 603
 604 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 605   [AC_TRY_LINK([#include <signal.h>
 606      #include <sys/types.h>
 607      sig_atomic_t val = 42;],
 608     [return val == 42 ? 0 : 1],
 609    ac_cv_type_sig_atomic_t=yes,
 610    ac_cv_type_sig_atomic_t=no)])
 611 if test x$ac_cv_type_sig_atomic_t = xyes; then
 612    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 613      [Define if you have the 'sig_atomic_t' type.])
 614 fi
 615
 616 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 617   :
 618 else
 619   AC_MSG_ERROR([
 620 *** GLib requires a 64 bit type. You might want to consider
 621 *** using the GNU C compiler.
 622 ])
 623 fi
 624
 625 AS_IF([test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8], [
 626         # long long is a 64 bit integer.
 627         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 628         AC_CACHE_VAL(glib_cv_long_long_format,[
 629                 for format in ll q I64; do
 630                   AC_TRY_RUN([#include <stdio.h>
 631                         int main()
 632                         {
 633                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 634                           char buffer[1000];
 635                           sprintf (buffer, "%${format}u", a);
 636                           sscanf (buffer, "%${format}u", &b);
 637                           exit (b!=a);
 638                         }
 639                         ],
 640                         [glib_cv_long_long_format=${format}
 641                         break],
 642                         [],[:])
 643                 done])
 644         AS_IF([ test -n "$glib_cv_long_long_format"], [
 645           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 646           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 647           if test x"$glib_cv_long_long_format" = xI64; then
 648             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 649           fi
 650         ], [AC_MSG_RESULT(none)])
 651 ],[ test x$ac_cv_sizeof___int64 = x8], [
 652         # __int64 is a 64 bit integer.
 653         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 654         # We know this is MSVCRT.DLL, and what the formats are
 655         glib_cv_long_long_format=I64
 656         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 657         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 658         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 659 ])
 660
 661 AC_C_CONST
 662
 663 dnl ok, here we try to check whether the systems prototypes for
 664 dnl malloc and friends actually match the prototypes provided
 665 dnl by gmem.h (keep in sync). i currently only know how to check
 666 dnl this reliably with gcc (-Werror), improvements for other
 667 dnl compilers are apprechiated.
 668 SANE_MALLOC_PROTOS=no
 669 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 670 glib_save_CFLAGS=$CFLAGS
 671 AS_IF([test "x$GCC" = "xyes"], [
 672   CFLAGS="$CFLAGS -Werror"
 673   AC_TRY_COMPILE([#include <stdlib.h>], [
 674     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 675     void* (*my_malloc_p)  (size_t)         = malloc;
 676     void  (*my_free_p)    (void*)          = free;
 677     void* (*my_realloc_p) (void*, size_t)  = realloc;
 678     my_calloc_p = 0;
 679     my_malloc_p = 0;
 680     my_free_p = 0;
 681     my_realloc_p = 0;
 682   ],
 683     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 684       [Define if you have correct malloc prototypes])
 685     SANE_MALLOC_PROTOS=yes)
 686 ])
 687 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 688 CFLAGS=$glib_save_CFLAGS
 689
 690 dnl
 691 dnl check in which direction the stack grows
 692 dnl
 693 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 694         AC_TRY_RUN([
 695         volatile int *a = 0, *b = 0;
 696         void foo (void);
 697         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 698         void foo (void) { volatile int x = 5; b = &x; }
 699         ],
 700         glib_cv_stack_grows=no
 701         ,
 702         glib_cv_stack_grows=yes
 703         ,)
 704 ])
 705
 706 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 707 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 708 dnl actually supported.
 709 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 710         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 711         __inline int foo () { return 0; }
 712         int main () { return foo (); }
 713         ]])],
 714         glib_cv_has__inline=yes
 715         ,
 716         glib_cv_has__inline=no
 717         ,)
 718 ])
 719 case x$glib_cv_has__inline in
 720 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 721 esac
 722 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 723         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 724         __inline__ int foo () { return 0; }
 725         int main () { return foo (); }
 726         ]])],
 727         glib_cv_has__inline__=yes
 728         ,
 729         glib_cv_has__inline__=no
 730         ,)
 731 ])
 732 case x$glib_cv_has__inline__ in
 733 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 734 esac
 735 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 736         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 737         #undef inline
 738         inline int foo () { return 0; }
 739         int main () { return foo (); }
 740         ]])],
 741         glib_cv_hasinline=yes
 742         ,
 743         glib_cv_hasinline=no
 744         ,)
 745 ])
 746 case x$glib_cv_hasinline in
 747 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 748 esac
 749
 750 # if we can use inline functions in headers
 751 AC_MSG_CHECKING(if inline functions in headers work)
 752 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 753 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 754 #  undef inline
 755 #  define inline __inline__
 756 #elif !defined (G_HAVE_INLINE)
 757 #  undef inline
 758 #  if defined (G_HAVE___INLINE__)
 759 #    define inline __inline__
 760 #  elif defined (G_HAVE___INLINE)
 761 #    define inline __inline
 762 #  endif
 763 #endif
 764
 765 int glib_test_func2 (int);
 766
 767 static inline int
 768 glib_test_func1 (void) {
 769   return glib_test_func2 (1);
 770 }
 771
 772 int
 773 main (void) {
 774   int i = 1;
 775 }]])],[g_can_inline=yes],[g_can_inline=no])
 776 AC_MSG_RESULT($g_can_inline)
 777
 778 dnl *** check for working do while(0) macros ***
 779 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 780         AC_TRY_COMPILE([],[
 781         #define STMT_START do
 782         #define STMT_END while(0)
 783         #define STMT_TEST STMT_START { i = 0; } STMT_END
 784         int main(void) { int i = 1; STMT_TEST; return i; }],
 785         [g_cv_support_dowhile_macros=yes],
 786         [g_cv_support_dowhile_macros=no],
 787         [g_cv_support_dowhile_macros=yes])
 788 ])
 789 if test x$g_cv_support_dowhile_macros = xyes; then
 790   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 791 fi
 792
 793 # check for flavours of varargs macros
 794 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 795 AC_TRY_COMPILE([],[
 796 int a(int p1, int p2, int p3);
 797 #define call_a(...) a(1,__VA_ARGS__)
 798 call_a(2,3);
 799 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 800 AC_MSG_RESULT($g_have_iso_c_varargs)
 801
 802 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 803 AS_IF([test "$CXX" = ""], [
 804 dnl No C++ compiler
 805   g_have_iso_cxx_varargs=no
 806 else
 807   AC_LANG_CPLUSPLUS
 808   AC_TRY_COMPILE([],[
 809 int a(int p1, int p2, int p3);
 810 #define call_a(...) a(1,__VA_ARGS__)
 811 call_a(2,3);
 812 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 813   AC_LANG_C
 814 ])
 815 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 816
 817 AC_MSG_CHECKING(for GNUC varargs macros)
 818 AC_TRY_COMPILE([],[
 819 int a(int p1, int p2, int p3);
 820 #define call_a(params...) a(1,params)
 821 call_a(2,3);
 822 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 823 AC_MSG_RESULT($g_have_gnuc_varargs)
 824
 825 # check for GNUC visibility support
 826 AC_MSG_CHECKING(for GNUC visibility attribute)
 827 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 828 void
 829 __attribute__ ((visibility ("hidden")))
 830      f_hidden (void)
 831 {
 832 }
 833 void
 834 __attribute__ ((visibility ("internal")))
 835      f_internal (void)
 836 {
 837 }
 838 void
 839 __attribute__ ((visibility ("protected")))
 840      f_protected (void)
 841 {
 842 }
 843 void
 844 __attribute__ ((visibility ("default")))
 845      f_default (void)
 846 {
 847 }
 848 int main (int argc, char **argv)
 849 {
 850         f_hidden();
 851         f_internal();
 852         f_protected();
 853         f_default();
 854         return 0;
 855 }
 856 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 857 AC_MSG_RESULT($g_have_gnuc_visibility)
 858 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 859
 860 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 861 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 862 #else
 863 # include "error: this is not Sun Studio."
 864 #endif
 865 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 866 AC_MSG_RESULT($g_have_sunstudio_visibility)
 867 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 868
 869 # check for bytesex stuff
 870 AC_C_BIGENDIAN
 871 if test x$ac_cv_c_bigendian = xuniversal ; then
 872 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 873 #else
 874 #error Not a big endian.
 875 #endif],
 876     ac_cv_c_bigendian=yes
 877     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 878 #else
 879 #error Not a little endian.
 880 #endif],
 881     ac_cv_c_bigendian=no
 882     ,AC_MSG_WARN([Could not determine endianness.])))
 883 fi
 884
 885
 886 # check for header files
 887 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 888 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 889 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 890 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h sys/filio.h])
 891 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 892 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 893 AC_CHECK_HEADERS([linux/magic.h])
 894 AC_CHECK_HEADERS([sys/prctl.h])
 895
 896 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 897 [#if HAVE_SYS_PARAM_H
 898  #include <sys/param.h>
 899  #endif
 900 ])
 901
 902 AC_CHECK_HEADERS([xlocale.h])
 903
 904 # check for structure fields
 905 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 906 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 907 #include <sys/stat.h>
 908 #include <unistd.h>
 909 #ifdef HAVE_SYS_STATFS_H
 910 #include <sys/statfs.h>
 911 #endif
 912 #ifdef HAVE_SYS_PARAM_H
 913 #include <sys/param.h>
 914 #endif
 915 #ifdef HAVE_SYS_MOUNT_H
 916 #include <sys/mount.h>
 917 #endif])
 918 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 919 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 920 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 921 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 922
 923 AC_STRUCT_DIRENT_D_TYPE
 924
 925 # Checks for libcharset
 926 AM_LANGINFO_CODESET
 927 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 928 AC_CHECK_FUNCS(setlocale)
 929
 930 # check additional type sizes
 931 AC_CHECK_SIZEOF(size_t)
 932
 933 dnl Try to figure out whether gsize, gssize should be long or int
 934 AC_MSG_CHECKING([for the appropriate definition for size_t])
 935
 936 case $ac_cv_sizeof_size_t in
 937   $ac_cv_sizeof_short)
 938       glib_size_type=short
 939       ;;
 940   $ac_cv_sizeof_int)
 941       glib_size_type=int
 942       ;;
 943   $ac_cv_sizeof_long)
 944       glib_size_type=long
 945       ;;
 946   $ac_cv_sizeof_long_long)
 947       glib_size_type='long long'
 948       ;;
 949   $ac_cv_sizeof__int64)
 950       glib_size_type='__int64'
 951       ;;
 952   *)  AC_MSG_ERROR([No type matching size_t in size])
 953       ;;
 954 esac
 955
 956 dnl If int/long are the same size, we see which one produces
 957 dnl warnings when used in the location as size_t. (This matters
 958 dnl on AIX with xlc)
 959 dnl
 960 AS_IF([test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 961        test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long], [
 962   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 963 #if defined(_AIX) && !defined(__GNUC__)
 964 #pragma options langlvl=stdc89
 965 #endif
 966 #include <stddef.h>
 967 int main ()
 968 {
 969   size_t s = 1;
 970   unsigned int *size_int = &s;
 971   return (int)*size_int;
 972 }
 973     ]])],glib_size_type=int,
 974       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 975 #if defined(_AIX) && !defined(__GNUC__)
 976 #pragma options langlvl=stdc89
 977 #endif
 978 #include <stddef.h>
 979 int main ()
 980 {
 981    size_t s = 1;
 982    unsigned long *size_long = &s;
 983    return (int)*size_long;
 984 }
 985         ]])],glib_size_type=long)])
 986 ])
 987
 988 AC_MSG_RESULT(unsigned $glib_size_type)
 989
 990 # Check for some functions
 991 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 992 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid getresuid)
 993 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 994 # Check for high-resolution sleep functions
 995 AC_CHECK_FUNCS(splice)
 996 AC_CHECK_FUNCS(prlimit)
 997
 998 # To avoid finding a compatibility unusable statfs, which typically
 999 # successfully compiles, but warns to use the newer statvfs interface:
1000 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1001 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1002
1003 AC_MSG_CHECKING([whether to use statfs or statvfs])
1004 # Some systems have both statfs and statvfs, pick the most "native" for these
1005 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1006    [
1007    # on solaris and irix, statfs doesn't even have the f_bavail field
1008    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1009       [ac_cv_func_statfs=no],
1010    # else, at least on linux, statfs is the actual syscall
1011       [ac_cv_func_statvfs=no])
1012    ])
1013
1014 AS_IF([test x$ac_cv_func_statfs = xyes],
1015       [
1016          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1017          AC_MSG_RESULT([statfs])
1018       ],
1019       [test x$ac_cv_func_statvfs = xyes],
1020       [
1021          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1022          AC_MSG_RESULT([statvfs])
1023       ],
1024       [  AC_MSG_RESULT([neither])])
1025
1026 AC_CHECK_HEADERS(crt_externs.h)
1027 AC_CHECK_FUNCS(_NSGetEnviron)
1028
1029 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1030
1031 AC_FUNC_VSNPRINTF_C99
1032 AC_FUNC_PRINTF_UNIX98
1033
1034 # Internet address families
1035 if test $glib_native_win32 = yes; then
1036   glib_inet_includes=["
1037 #include <winsock2.h>
1038   "]
1039 else
1040   glib_inet_includes=["
1041 #include <sys/types.h>
1042 #include <sys/socket.h>
1043   "]
1044 fi
1045
1046 glib_failed=false
1047 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1048 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1049 # winsock defines this even though it doesn't support it
1050 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1051 if $glib_failed ; then
1052   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1053 fi
1054
1055 glib_failed=false
1056 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1057 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1058 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1059 if $glib_failed ; then
1060   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1061 fi
1062
1063 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1064 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1065
1066 AS_IF([test $glib_native_win32 = no], [
1067   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1068   NETWORK_LIBS=""
1069   AC_MSG_CHECKING([for res_query])
1070   AC_TRY_LINK([#include <sys/types.h>
1071                #include <netinet/in.h>
1072                #include <arpa/nameser.h>
1073                #include <resolv.h>
1074               ],[
1075                res_query("test", 0, 0, (void *)0, 0);
1076               ],[AC_MSG_RESULT([yes])],
1077               [save_libs="$LIBS"
1078                LIBS="-lresolv $LIBS"
1079                AC_TRY_LINK([#include <sys/types.h>
1080                             #include <netinet/in.h>
1081                             #include <arpa/nameser.h>
1082                             #include <resolv.h>
1083                            ],[
1084                             res_query("test", 0, 0, (void *)0, 0);
1085                            ],[AC_MSG_RESULT([in -lresolv])
1086                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1087                            [LIBS="-lbind $save_libs"
1088                             AC_TRY_LINK([#include <resolv.h>],
1089                                         [res_query("test", 0, 0, (void *)0, 0);],
1090                                         [AC_MSG_RESULT([in -lbind])
1091                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1092                                         [AC_MSG_ERROR(not found)])])
1093                LIBS="$save_libs"])
1094   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1095                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1096                                         [AC_MSG_ERROR(Could not find socket())]))
1097 ])
1098 AC_SUBST(NETWORK_LIBS)
1099
1100 AC_CHECK_HEADER([linux/netlink.h],
1101                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1102                 [#include <sys/socket.h>])
1103 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1104
1105 AC_CHECK_TYPE([struct ip_mreqn], [
1106               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1107               [#include <netinet/in.h>])
1108
1109 case $host in
1110   *-*-solaris* )
1111      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1112      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1113      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1114      ;;
1115 esac
1116
1117 dnl
1118 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1119 dnl
1120 AS_IF([test "$ac_cv_func_statfs" = yes], [
1121   AC_MSG_CHECKING([number of arguments to statfs()])
1122   AC_TRY_COMPILE([#include <unistd.h>
1123   #ifdef HAVE_SYS_PARAM_H
1124   #include <sys/param.h>
1125   #endif
1126   #ifdef HAVE_SYS_VFS_H
1127   #include <sys/vfs.h>
1128   #endif
1129   #ifdef HAVE_SYS_MOUNT_H
1130   #include <sys/mount.h>
1131   #endif
1132   #ifdef HAVE_SYS_STATFS_H
1133   #include <sys/statfs.h>
1134   #endif], [struct statfs st;
1135   statfs(NULL, &st);],[
1136     AC_MSG_RESULT([2])
1137     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1138     AC_TRY_COMPILE([#include <unistd.h>
1139   #ifdef HAVE_SYS_PARAM_H
1140   #include <sys/param.h>
1141   #endif
1142   #ifdef HAVE_SYS_VFS_H
1143   #include <sys/vfs.h>
1144   #endif
1145   #ifdef HAVE_SYS_MOUNT_H
1146   #include <sys/mount.h>
1147   #endif
1148   #ifdef HAVE_SYS_STATFS_H
1149   #include <sys/statfs.h>
1150   #endif], [struct statfs st;
1151   statfs(NULL, &st, sizeof (st), 0);],[
1152       AC_MSG_RESULT([4])
1153       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1154       AC_MSG_RESULT(unknown)
1155       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1156 ])
1157
1158 #
1159 # Check whether to use an included printf
1160 #
1161
1162 AC_ARG_ENABLE(included-printf,
1163               [AS_HELP_STRING([--enable-included-printf],
1164                               [use included printf [default=auto]])],
1165               enable_included_printf="$enableval")
1166
1167 need_included_printf=no
1168 if test "x$enable_included_printf" = "xyes" ; then
1169   need_included_printf=yes
1170 fi
1171 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1172   need_included_printf=yes
1173 fi
1174 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1175   need_included_printf=yes
1176 fi
1177 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1178    test -z "$glib_cv_long_long_format" ; then
1179   need_included_printf=yes
1180 fi
1181
1182 if test "x$enable_included_printf" = "xno" &&
1183    test "x$need_included_printf" = "xyes" ; then
1184   AC_MSG_ERROR([
1185 *** Your C library's printf doesn't appear to have the features that
1186 *** GLib needs, but you specified --enable-included-printf=no.])
1187 fi
1188
1189 enable_included_printf=$need_included_printf
1190
1191 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1192 AS_IF([test "$enable_included_printf" != "yes"], [
1193   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1194 ], [
1195   if test -z "$glib_cv_long_long_format" ; then
1196     glib_cv_long_long_format="ll"
1197   fi
1198   AC_DEFINE(HAVE_VASPRINTF,1)
1199 ])
1200
1201 # Checks needed for gnulib vasnprintf
1202 bh_C_SIGNED
1203 jm_AC_TYPE_LONG_LONG
1204 gt_TYPE_LONGDOUBLE
1205 gt_TYPE_WCHAR_T
1206 gt_TYPE_WINT_T
1207 AC_TYPE_SIZE_T
1208 AC_CHECK_TYPES(ptrdiff_t)
1209 jm_AC_TYPE_INTMAX_T
1210 AC_CHECK_FUNCS([snprintf wcslen])
1211 AC_FUNC_SNPRINTF_C99
1212
1213 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1214 # The check is borrowed from the PERL Configure script.
1215 AS_IF([test "$ac_cv_func_memmove" != "yes"],
1216   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1217     glib_cv_working_bcopy,[AC_TRY_RUN([
1218       int main() {
1219         char buf[128], abc[128], *b;
1220         int len, off, align;
1221         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1222         for (align = 7; align >= 0; align--) {
1223           for (len = 36; len; len--) {
1224             b = buf+align; bcopy(abc, b, len);
1225             for (off = 1; off <= len; off++) {
1226               bcopy(b, b+off, len); bcopy(b+off, b, len);
1227                 if (bcmp(b, abc, len)) return(1);
1228             }
1229           }
1230         }
1231         return(0);
1232       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1233
1234   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1235   if test "$glib_cv_working_bcopy" = "yes"; then
1236     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1237   fi
1238 ])
1239
1240 # Check if <sys/select.h> needs to be included for fd_set
1241 AC_MSG_CHECKING([for fd_set])
1242 AC_TRY_COMPILE([#include <sys/types.h>],
1243         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1244 AS_IF([test "$gtk_ok" = "yes"], [
1245     AC_MSG_RESULT([yes, found in sys/types.h])
1246 ], [
1247     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1248     if test "$gtk_ok" = "yes"; then
1249         # *** FIXME: give it a different name
1250         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1251         AC_MSG_RESULT([yes, found in sys/select.h])
1252     else
1253         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1254         AC_MSG_RESULT(no)
1255     fi
1256 ])
1257
1258 dnl *** check for sane realloc() ***
1259 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1260         AC_TRY_RUN([#include <stdlib.h>
1261         int main() {
1262           return realloc (0, sizeof (int)) == 0;
1263         }],
1264         [glib_cv_sane_realloc=yes],
1265         [glib_cv_sane_realloc=no],
1266         [glib_cv_sane_realloc=yes])
1267 ])
1268 AS_IF([test x$glib_cv_sane_realloc = xyes], [
1269   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1270 ])
1271
1272 dnl Check for nl_langinfo and CODESET
1273 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1274         AC_TRY_COMPILE([#include <langinfo.h>],
1275                 [char *codeset = nl_langinfo (CODESET);],
1276                 [glib_cv_langinfo_codeset=yes],
1277                 [glib_cv_langinfo_codeset=no])])
1278 if test x$glib_cv_langinfo_codeset = xyes; then
1279   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1280 fi
1281
1282 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1283 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1284         AC_TRY_COMPILE([#include <langinfo.h>],
1285                 [char *str;
1286                  str = nl_langinfo (PM_STR);
1287                  str = nl_langinfo (D_T_FMT);
1288                  str = nl_langinfo (D_FMT);
1289                  str = nl_langinfo (T_FMT);
1290                  str = nl_langinfo (T_FMT_AMPM);
1291                  str = nl_langinfo (MON_1);
1292                  str = nl_langinfo (ABMON_12);
1293                  str = nl_langinfo (DAY_1);
1294                  str = nl_langinfo (ABDAY_7);],
1295                 [glib_cv_langinfo_time=yes],
1296                 [glib_cv_langinfo_time=no])])
1297 if test x$glib_cv_langinfo_time = xyes; then
1298   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1299 fi
1300
1301 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1302 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1303         AC_TRY_COMPILE([#include <langinfo.h>],
1304                 [char *str;
1305                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1306                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1307                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1308                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1309                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1310                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1311                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1312                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1313                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1314                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1315                 [glib_cv_langinfo_outdigit=yes],
1316                 [glib_cv_langinfo_outdigit=no])])
1317 if test x$glib_cv_langinfo_outdigit = xyes; then
1318   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1319 fi
1320
1321 dnl ****************************************
1322 dnl *** posix_memalign                   ***
1323 dnl ****************************************
1324 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1325 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1326     glib_cv_compliant_posix_memalign=0
1327     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1328         AC_TRY_RUN([
1329                 #define _XOPEN_SOURCE 600
1330                 #include <stdlib.h> /* posix_memalign() should be defined here */
1331                 /* some systems break if #include <malloc.h> used */
1332                 static void test_memalign (size_t boundary, size_t size) {
1333                     void *mem = 0;
1334                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1335                         exit (1);
1336                     else
1337                       free (mem);
1338                 }
1339                 int main() {
1340                     test_memalign (  128,   128 - 2 * sizeof (void*));
1341                     test_memalign (  256,   256 - 2 * sizeof (void*));
1342                     test_memalign (  512,   512 - 2 * sizeof (void*));
1343                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1344                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1345                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1346                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1347                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1348                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1349                     exit (0); /* success */
1350                 }
1351                 ],
1352             [glib_cv_compliant_posix_memalign=1], [], [:])
1353       :
1354     fi
1355     ])
1356 AS_IF([test "$glib_cv_compliant_posix_memalign" = "1"], [
1357     AC_MSG_RESULT(yes)
1358     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1359 ], [
1360     AC_MSG_RESULT(no)
1361 ])
1362
1363
1364 dnl ****************************************
1365 dnl *** strlcpy/strlcat                  ***
1366 dnl ****************************************
1367 # Check for strlcpy
1368 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1369 AC_TRY_RUN([#include <stdlib.h>
1370 #include <string.h>
1371 int main() {
1372   char p[10];
1373   (void) strlcpy (p, "hi", 10);
1374   if (strlcat (p, "bye", 0) != 3)
1375     return 1;
1376   return 0;
1377 }], glib_cv_have_strlcpy=yes,
1378     glib_cv_have_strlcpy=no,
1379     glib_cv_have_strlcpy=no)])
1380 if test "$glib_cv_have_strlcpy" = "yes"; then
1381     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1382 fi
1383
1384
1385 dnl **********************
1386 dnl *** va_copy checks ***
1387 dnl **********************
1388 dnl we currently check for all three va_copy possibilities, so we get
1389 dnl all results in config.log for bug reports.
1390 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1391         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1392 #include <stdlib.h>
1393         void f (int i, ...) {
1394         va_list args1, args2;
1395         va_start (args1, i);
1396         va_copy (args2, args1);
1397         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1398           exit (1);
1399         va_end (args1); va_end (args2);
1400         }
1401         int main() {
1402           f (0, 42);
1403           return 0;
1404         }]])],
1405         [glib_cv_va_copy=yes],
1406         [glib_cv_va_copy=no])
1407 ])
1408 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1409         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1410 #include <stdlib.h>
1411         void f (int i, ...) {
1412         va_list args1, args2;
1413         va_start (args1, i);
1414         __va_copy (args2, args1);
1415         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1416           exit (1);
1417         va_end (args1); va_end (args2);
1418         }
1419         int main() {
1420           f (0, 42);
1421           return 0;
1422         }]])],
1423         [glib_cv___va_copy=yes],
1424         [glib_cv___va_copy=no])
1425 ])
1426
1427 if test "x$glib_cv_va_copy" = "xyes"; then
1428   g_va_copy_func=va_copy
1429 else if test "x$glib_cv___va_copy" = "xyes"; then
1430   g_va_copy_func=__va_copy
1431 fi
1432 fi
1433
1434 if test -n "$g_va_copy_func"; then
1435   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1436 fi
1437
1438 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1439         AC_TRY_RUN([#include <stdarg.h>
1440 #include <stdlib.h>
1441         void f (int i, ...) {
1442         va_list args1, args2;
1443         va_start (args1, i);
1444         args2 = args1;
1445         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1446           exit (1);
1447         va_end (args1); va_end (args2);
1448         }
1449         int main() {
1450           f (0, 42);
1451           return 0;
1452         }],
1453         [glib_cv_va_val_copy=yes],
1454         [glib_cv_va_val_copy=no],
1455         [glib_cv_va_val_copy=yes])
1456 ])
1457
1458 AS_IF([ test "x$glib_cv_va_val_copy" = "xno"], [
1459   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1460 ])
1461
1462 dnl ***********************
1463 dnl *** g_module checks ***
1464 dnl ***********************
1465 G_MODULE_LIBS=
1466 G_MODULE_LIBS_EXTRA=
1467 G_MODULE_PLUGIN_LIBS=
1468 if test x"$glib_native_win32" = xyes; then
1469   dnl No use for this on Win32
1470   G_MODULE_LDFLAGS=
1471 else
1472   export SED
1473   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1474 fi
1475 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1476 G_MODULE_NEED_USCORE=0
1477 G_MODULE_BROKEN_RTLD_GLOBAL=0
1478 G_MODULE_HAVE_DLERROR=0
1479 dnl *** force native WIN32 shared lib loader
1480 if test -z "$G_MODULE_IMPL"; then
1481   case "$host" in
1482   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1483   esac
1484 fi
1485 dnl *** force native AIX library loader
1486 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1487 if test -z "$G_MODULE_IMPL"; then
1488   case "$host" in
1489   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1490   esac
1491 fi
1492 dnl *** dlopen() and dlsym() in system libraries
1493 AS_IF([ test -z "$G_MODULE_IMPL"], [
1494         AC_CHECK_FUNC(dlopen,
1495                       [AC_CHECK_FUNC(dlsym,
1496                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1497                       [])
1498 ])
1499 dnl *** load_image (BeOS)
1500 AS_IF([test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"], [
1501   AC_CHECK_LIB(root, load_image,
1502       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1503       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1504       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1505       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1506       [])
1507 ])
1508 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1509 AS_IF([ test -z "$G_MODULE_IMPL" ], [
1510         AC_CHECK_FUNC(NSLinkModule,
1511                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1512                        G_MODULE_NEED_USCORE=1],
1513                       [])
1514 ])
1515 dnl *** dlopen() and dlsym() in libdl
1516 AS_IF([ test -z "$G_MODULE_IMPL"], [
1517         AC_CHECK_LIB(dl, dlopen,
1518                      [AC_CHECK_LIB(dl, dlsym,
1519                                    [G_MODULE_LIBS=-ldl
1520                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1521                      [])
1522 ])
1523 dnl *** shl_load() in libdld (HP-UX)
1524 AS_IF([ test -z "$G_MODULE_IMPL"], [
1525         AC_CHECK_LIB(dld, shl_load,
1526                 [G_MODULE_LIBS=-ldld
1527                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1528                 [])
1529 ])
1530 dnl *** additional checks for G_MODULE_IMPL_DL
1531 AS_IF([ test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL" ], [
1532         LIBS_orig="$LIBS"
1533         LDFLAGS_orig="$LDFLAGS"
1534         LIBS="$G_MODULE_LIBS $LIBS"
1535         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1536 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1537         echo "void glib_plugin_test(void) { }" > plugin.c
1538         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1539                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1540         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1541                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1542                 -shrext ".o" -avoid-version plugin.lo \
1543                 -rpath /dont/care >/dev/null 2>&1
1544         eval `./libtool --config | grep ^objdir`
1545         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1546                 glib_cv_rtldglobal_broken,[
1547                 AC_TRY_RUN([
1548 #include <dlfcn.h>
1549 #ifndef RTLD_GLOBAL
1550 #  define RTLD_GLOBAL 0
1551 #endif
1552 #ifndef RTLD_LAZY
1553 #  define RTLD_LAZY 0
1554 #endif
1555 int glib_plugin_test;
1556 int main () {
1557     void *handle, *global, *local;
1558     global = &glib_plugin_test;
1559     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1560     if (!handle) return 0;
1561     local = dlsym (handle, "glib_plugin_test");
1562     return global == local;
1563 }                       ],
1564                         [glib_cv_rtldglobal_broken=no],
1565                         [glib_cv_rtldglobal_broken=yes],
1566                         [glib_cv_rtldglobal_broken=no])
1567                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1568                 rmdir ${objdir} 2>/dev/null
1569         ])
1570         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1571                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1572         else
1573                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1574         fi
1575 dnl *** check whether we need preceeding underscores
1576         AC_CACHE_CHECK([for preceeding underscore in symbols],
1577                 glib_cv_uscore,[
1578                 AC_TRY_RUN([#include <dlfcn.h>
1579                 int glib_underscore_test (void) { return 42; }
1580                 int main() {
1581                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1582                   handle = dlopen ((void*)0, 0);
1583                   if (handle) {
1584                     f1 = dlsym (handle, "glib_underscore_test");
1585                     f2 = dlsym (handle, "_glib_underscore_test");
1586                   } return (!f2 || f1);
1587                 }],
1588                         [glib_cv_uscore=yes],
1589                         [glib_cv_uscore=no],
1590                         [])
1591                 rm -f plugin.c plugin.$ac_objext plugin.lo
1592         ])
1593         GLIB_ASSERT_SET(glib_cv_uscore)
1594         if test "x$glib_cv_uscore" = "xyes"; then
1595                 G_MODULE_NEED_USCORE=1
1596         else
1597                 G_MODULE_NEED_USCORE=0
1598         fi
1599
1600         LDFLAGS="$LDFLAGS_orig"
1601 dnl *** check for having dlerror()
1602         AC_CHECK_FUNC(dlerror,
1603                 [G_MODULE_HAVE_DLERROR=1],
1604                 [G_MODULE_HAVE_DLERROR=0])
1605         LIBS="$LIBS_orig"
1606 ])
1607 dnl *** done, have we got an implementation?
1608 if test -z "$G_MODULE_IMPL"; then
1609         G_MODULE_IMPL=0
1610         G_MODULE_SUPPORTED=false
1611 else
1612         G_MODULE_SUPPORTED=true
1613 fi
1614
1615 AC_MSG_CHECKING(for the suffix of module shared libraries)
1616 export SED
1617 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1618 eval $shrext_cmds
1619 module=yes eval std_shrext=$shrext_cmds
1620 # chop the initial dot
1621 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1622 AC_MSG_RESULT(.$glib_gmodule_suffix)
1623 # any reason it may fail?
1624 if test "x$glib_gmodule_suffix" = x; then
1625         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1626 fi
1627
1628 AC_SUBST(G_MODULE_SUPPORTED)
1629 AC_SUBST(G_MODULE_IMPL)
1630 AC_SUBST(G_MODULE_LIBS)
1631 AC_SUBST(G_MODULE_LIBS_EXTRA)
1632 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1633 AC_SUBST(G_MODULE_LDFLAGS)
1634 AC_SUBST(G_MODULE_HAVE_DLERROR)
1635 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1636 AC_SUBST(G_MODULE_NEED_USCORE)
1637 AC_SUBST(GLIB_DEBUG_FLAGS)
1638
1639 dnl **********************
1640 dnl *** g_spawn checks ***
1641 dnl **********************
1642
1643 AC_MSG_CHECKING(for gspawn implementation)
1644 case "$host" in
1645   *-*-mingw*)
1646     GSPAWN=gspawn-win32.lo
1647     ;;
1648   *)
1649     GSPAWN=gspawn.lo
1650     ;;
1651 esac
1652 AC_MSG_RESULT($GSPAWN)
1653 AC_SUBST(GSPAWN)
1654
1655 dnl *************************
1656 dnl *** GIOChannel checks ***
1657 dnl *************************
1658
1659 AC_MSG_CHECKING(for GIOChannel implementation)
1660 case "$host" in
1661   *-*-mingw*)
1662     GIO=giowin32.lo
1663     ;;
1664   *)
1665     GIO=giounix.lo
1666     ;;
1667 esac
1668 AC_MSG_RESULT($GIO)
1669 AC_SUBST(GIO)
1670
1671 dnl *********************************
1672 dnl *** Directory for GIO modules ***
1673 dnl *********************************
1674
1675 AC_ARG_WITH(gio-module-dir,
1676            [AS_HELP_STRING([--with-gio-module-dir=DIR],
1677                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1678            [],
1679            [with_gio_module_dir='${libdir}/gio/modules'])
1680 GIO_MODULE_DIR=$with_gio_module_dir
1681 AC_SUBST(GIO_MODULE_DIR)
1682
1683 dnl **********************************
1684 dnl *** Check for libselinux (GIO) ***
1685 dnl **********************************
1686 AC_ARG_ENABLE(selinux,
1687               AS_HELP_STRING([--disable-selinux],
1688                              [build without selinux support]))
1689 msg_selinux=no
1690 SELINUX_LIBS=
1691 AS_IF([ test "x$enable_selinux" != "xno"], [
1692
1693  AC_CHECK_LIB(selinux, is_selinux_enabled,
1694    [AC_CHECK_HEADERS(selinux/selinux.h,
1695      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1696        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1697         SELINUX_LIBS="-lselinux"
1698         msg_selinux=yes])
1699      ])
1700    ])
1701 ])
1702 AC_SUBST(SELINUX_LIBS)
1703
1704 dnl *****************************
1705 dnl ** Check for inotify (GIO) **
1706 dnl *****************************
1707 inotify_support=no
1708 AC_CHECK_HEADERS([sys/inotify.h],
1709 [
1710         inotify_support=yes
1711         AC_CHECK_FUNCS(inotify_init1)
1712 ])
1713
1714 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1715
1716 dnl *********************************
1717 dnl ** Check for Solaris FEN (GIO) **
1718 dnl *********************************
1719 fen_support=no
1720 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1721 #include <port.h>
1722 #ifndef PORT_SOURCE_FILE
1723 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1724 #endif
1725 int main() { return 0; } ]])],
1726 [
1727         fen_support=yes
1728 ],)
1729
1730 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1731
1732 dnl ****************************
1733 dnl *** Checks for FAM (GIO) ***
1734 dnl ****************************
1735
1736 should_disable_fam=no
1737
1738 AC_ARG_ENABLE(fam,
1739               AS_HELP_STRING([--disable-fam],
1740                              [don't use fam for file system monitoring]),
1741                          [
1742                                 if test "x$enable_fam" = "xno"; then
1743                                         should_disable_fam=yes
1744                                 fi
1745                          ]
1746                          )
1747 fam_support=no
1748 FAM_LIBS=
1749 if test "x$should_disable_fam" = "xno"; then
1750 AC_CHECK_LIB(fam, FAMOpen,
1751   [AC_CHECK_HEADERS(fam.h,
1752     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1753      AC_CHECK_LIB(fam, FAMNoExists,
1754                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1755      FAM_LIBS="-lfam"]
1756      fam_support=yes,
1757     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1758   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1759 AC_SUBST(FAM_LIBS)
1760 fi
1761 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1762
1763
1764 dnl *****************************
1765 dnl *** Check for xattr (GIO) ***
1766 dnl *****************************
1767 AC_ARG_ENABLE(xattr,
1768               AS_HELP_STRING([--disable-xattr], [build without xattr support]))
1769 msg_xattr=no
1770 XATTR_LIBS=
1771 AS_IF([ test "x$enable_xattr" != "xno"], [
1772
1773 dnl either glibc or libattr can provide xattr support
1774
1775 dnl for both of them, we check for getxattr being in
1776 dnl the library and a valid xattr header.
1777
1778 dnl try glibc
1779  AC_CHECK_LIB(c, getxattr,
1780    [AC_CHECK_HEADERS(sys/xattr.h,
1781      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1782       msg_xattr=yes])
1783    ])
1784
1785   AS_IF([ test "x$msg_xattr" != "xyes"], [
1786 dnl   failure. try libattr
1787    AC_CHECK_LIB(attr, getxattr,
1788       [AC_CHECK_HEADERS(attr/xattr.h,
1789        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1790         XATTR_LIBS="-lattr"
1791         msg_xattr=yes])
1792       ])
1793   ])
1794
1795   AS_IF([ test "x$msg_xattr" = "xyes"], [
1796     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1797     AC_TRY_COMPILE([
1798       #include <stdio.h>
1799       #ifdef HAVE_SYS_TYPES_H
1800       #include <sys/types.h>
1801       #endif
1802       #ifdef HAVE_SYS_XATTR_H
1803       #include <sys/xattr.h>
1804       #elif HAVE_ATTR_XATTR_H
1805       #include <attr/xattr.h>
1806       #endif
1807     ],
1808     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1809     [
1810       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1811       AC_MSG_RESULT([yes])
1812     ],
1813     [AC_MSG_RESULT([no])]
1814     )
1815   ])
1816 ])
1817 AC_SUBST(XATTR_LIBS)
1818
1819 dnl ************************
1820 dnl *** check for libelf ***
1821 dnl ************************
1822 AC_ARG_ENABLE(libelf,
1823               AS_HELP_STRING([--disable-libelf], [build without libelf support]))
1824 AS_IF([ test "x$enable_libelf" != "xno"],[
1825 PKG_CHECK_MODULES([LIBELF], [libelf >= 0.8.12], [have_libelf=yes], [have_libelf=maybe])
1826 AS_IF([ test $have_libelf = maybe ], [
1827   glib_save_LIBS=$LIBS
1828   AC_CHECK_LIB([elf], [elf_begin], [:], [have_libelf=no])
1829   AC_CHECK_LIB([elf], [elf_getshdrstrndx], [:], [have_libelf=no])
1830   AC_CHECK_LIB([elf], [elf_getshdrnum], [:], [have_libelf=no])
1831   AC_CHECK_HEADER([libelf.h], [:], [have_libelf=no])
1832   LIBS=$glib_save_LIBS
1833
1834   if test $have_libelf != no; then
1835     LIBELF_LIBS=-lelf
1836     have_libelf=yes
1837   fi
1838 ])
1839 ])
1840
1841 if test x$have_libelf = xyes; then
1842   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1843 fi
1844
1845 dnl ****************************************
1846 dnl *** platform dependent source checks ***
1847 dnl ****************************************
1848
1849 AC_MSG_CHECKING(for platform-dependent source)
1850 case "$host" in
1851   *-*-cygwin*|*-*-mingw*)
1852     PLATFORMDEP=gwin32.lo
1853     ;;
1854   *)
1855     PLATFORMDEP=
1856     ;;
1857 esac
1858 AC_MSG_RESULT($PLATFORMDEP)
1859 AC_SUBST(PLATFORMDEP)
1860
1861 AC_MSG_CHECKING([whether to compile timeloop])
1862 case "$host" in
1863   *-*-cygwin*|*-*-mingw*|*-*-minix)
1864     enable_timeloop=no
1865     ;;
1866   *)
1867     enable_timeloop=yes
1868     ;;
1869 esac
1870 AC_MSG_RESULT($enable_timeloop)
1871 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1872
1873 AC_MSG_CHECKING([if building for some Win32 platform])
1874 case "$host" in
1875   *-*-mingw*|*-*-cygwin*)
1876     platform_win32=yes
1877     ;;
1878   *)
1879     platform_win32=no
1880     ;;
1881 esac
1882 AC_MSG_RESULT($platform_win32)
1883 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1884
1885 dnl ***********************
1886 dnl *** g_thread checks ***
1887 dnl ***********************
1888
1889 AC_ARG_WITH(threads,
1890            [AS_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1891                            [specify a thread implementation to use])],
1892            [],
1893            [with_threads=yes])
1894
1895 dnl error and warning message
1896 dnl *************************
1897
1898 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1899
1900 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1901                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1902                 compilation now, but then your programs might not work.
1903                 Please provide information on how it is done on your system."
1904
1905 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1906                  "
1907
1908 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1909                   provide information on your thread implementation."
1910
1911 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1912                 functions will not be MT-safe during their first call because
1913                 there is no working 'getpwuid_r' on your system."
1914
1915 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1916                 because there is no 'localtime_r' on your system."
1917
1918 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1919                 linking threaded applications. As GLib cannot do that
1920                 automatically, you will get an linkg error everytime you are
1921                 not using the right compiler. In that case you have to relink
1922                 with the right compiler. Ususally just '_r' is appended
1923                 to the compiler name."
1924
1925 dnl determination of thread implementation
1926 dnl ***************************************
1927
1928 AC_MSG_CHECKING(for thread implementation)
1929
1930 have_threads=no
1931 AS_IF([ test "x$with_threads" = xyes || test "x$with_threads" = xposix], [
1932         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1933         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1934         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1935         glib_save_CPPFLAGS="$CPPFLAGS"
1936         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1937         AS_IF([ test "x$have_threads" = xno], [
1938                 AC_TRY_COMPILE([#include <pthread.h>],
1939                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1940                         have_threads=posix)
1941         ])
1942         # Tru64Unix requires -pthread to find pthread.h. See #103020
1943         CPPFLAGS="$CPPFLAGS -pthread"
1944         if test "x$have_threads" = xno; then
1945         AC_TRY_COMPILE([#include <pthread.h>],
1946                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1947                        have_threads=posix)
1948         fi
1949         CPPFLAGS="$glib_save_CPPFLAGS"
1950 ])
1951 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1952         case $host in
1953                 *-*-mingw*)
1954                 have_threads=win32
1955                 ;;
1956         esac
1957 fi
1958
1959 if test "x$have_threads" = xno; then
1960         AC_MSG_RESULT(none available)
1961         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1962 else
1963         AC_MSG_RESULT($have_threads)
1964 fi
1965
1966
1967 dnl determination of G_THREAD_CFLAGS
1968 dnl ********************************
1969
1970 G_THREAD_LIBS=
1971 G_THREAD_LIBS_EXTRA=
1972 G_THREAD_CFLAGS=
1973
1974 dnl
1975 dnl Test program for basic POSIX threads functionality
1976 dnl
1977 m4_define([glib_thread_test],[
1978 #include <pthread.h>
1979 int check_me = 0;
1980 void* func(void* data) {check_me = 42; return &check_me;}
1981 int main()
1982  { pthread_t t;
1983    void *ret;
1984    pthread_create (&t, $1, func, 0);
1985    pthread_join (t, &ret);
1986    return (check_me != 42 || ret != &check_me);
1987 }])
1988
1989 AS_IF([ test x"$have_threads" = xposix], [
1990   # First we test for posix, whether -pthread or -pthreads do the trick as
1991   # both CPPFLAG and LIBS.
1992   # One of them does for most gcc versions and some other platforms/compilers
1993   # too and could be considered as the canonical way to go.
1994   case $host in
1995     *-*-cygwin*|*-*-darwin*)
1996        # skip cygwin and darwin -pthread or -pthreads test
1997        ;;
1998     *-solaris*)
1999       # These compiler/linker flags work with both Sun Studio and gcc
2000       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2001       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2002       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2003       G_THREAD_LIBS="-lpthread -lthread"
2004       ;;
2005     *)
2006       for flag in pthread pthreads mt; do
2007         glib_save_CFLAGS="$CFLAGS"
2008         CFLAGS="$CFLAGS -$flag"
2009         AC_TRY_RUN(glib_thread_test(0),
2010                    glib_flag_works=yes,
2011                    glib_flag_works=no,
2012                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2013                                    glib_flag_works=yes,
2014                                    glib_flag_works=no)])
2015         CFLAGS="$glib_save_CFLAGS"
2016         if test $glib_flag_works = yes ; then
2017            G_THREAD_CFLAGS=-$flag
2018         G_THREAD_LIBS=-$flag
2019         break;
2020         fi
2021       done
2022        ;;
2023   esac
2024 ])
2025
2026 AS_IF([ test x"$G_THREAD_CFLAGS" = x], [
2027
2028   # The canonical -pthread[s] does not work. Try something different.
2029
2030   case $host in
2031         *-aix*)
2032                 if test x"$GCC" = xyes; then
2033                         # GCC 3.0 and above needs -pthread.
2034                         # Should be coverd by the case above.
2035                         # GCC 2.x and below needs -mthreads
2036                         G_THREAD_CFLAGS="-mthreads"
2037                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2038                 else
2039                         # We are probably using the aix compiler. Normaly a
2040                         # program would have to be compiled with the _r variant
2041                         # of the corresponding compiler, but we as GLib cannot
2042                         # do that: but the good news is that for compiling the
2043                         # only difference is the added -D_THREAD_SAFE compile
2044                         # option. This is according to the "C for AIX User's
2045                         # Guide".
2046                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2047                 fi
2048                 ;;
2049         *-dg-dgux*)  # DG/UX
2050                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2051                 ;;
2052         *-sysv5uw7*) # UnixWare 7
2053                 # We are not using gcc with -pthread. Catched above.
2054                 G_THREAD_CFLAGS="-Kthread"
2055                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2056                 ;;
2057         *-mingw*)
2058                 # No flag needed when using MSVCRT.DLL
2059                 G_THREAD_CFLAGS=""
2060                 ;;
2061         *)
2062                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2063                 ;;
2064   esac
2065 ])
2066
2067 # if we are not finding the localtime_r function, then we probably are
2068 # not using the proper multithread flag
2069
2070 glib_save_CPPFLAGS="$CPPFLAGS"
2071 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2072
2073 # First we test, whether localtime_r is declared in time.h
2074 # directly. Then we test whether a macro localtime_r exists, in
2075 # which case localtime_r in the test program is replaced and thus
2076 # if we still find localtime_r in the output, it is not defined as
2077 # a macro.
2078
2079 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2080   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2081                                                            localtime_r(a,b)],
2082                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2083
2084 CPPFLAGS="$glib_save_CPPFLAGS"
2085
2086 AC_MSG_CHECKING(thread related cflags)
2087 AC_MSG_RESULT($G_THREAD_CFLAGS)
2088 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2089
2090 dnl determination of G_THREAD_LIBS
2091 dnl ******************************
2092
2093 AS_IF([test x$have_threads = xposix], [
2094           glib_save_CPPFLAGS="$CPPFLAGS"
2095           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2096           AS_IF([ test x"$G_THREAD_LIBS" = x ], [
2097             case $host in
2098               *-aix*)
2099                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2100                 # probably using the aix compiler.
2101                 AC_MSG_WARN($AIX_COMPILE_INFO)
2102                 ;;
2103               *)
2104                 G_THREAD_LIBS=error
2105                 glib_save_LIBS="$LIBS"
2106                 for thread_lib in "" pthread pthread32 pthreads thread; do
2107                         if test x"$thread_lib" = x; then
2108                                 add_thread_lib=""
2109                                 IN=""
2110                         else
2111                                 add_thread_lib="-l$thread_lib"
2112                                 IN=" in -l$thread_lib"
2113                         fi
2114                         if test x"$have_threads" = xposix; then
2115                                 defattr=0
2116                         else
2117                                 defattr=pthread_attr_default
2118                         fi
2119
2120                         LIBS="$add_thread_lib $glib_save_LIBS"
2121
2122                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2123                         AC_TRY_RUN(glib_thread_test($defattr),
2124                                    glib_result=yes,
2125                                    glib_result=no,
2126                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2127                                                    glib_result=yes,
2128                                                    glib_result=no)])
2129                         AC_MSG_RESULT($glib_result)
2130
2131                         if test "$glib_result" = "yes" ; then
2132                           G_THREAD_LIBS="$add_thread_lib"
2133                           break
2134                         fi
2135                 done
2136                 if test "x$G_THREAD_LIBS" = xerror; then
2137                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2138                 fi
2139                 LIBS="$glib_save_LIBS"
2140                 ;;
2141             esac
2142           ])
2143
2144           g_threads_impl="POSIX"
2145           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2146           CPPFLAGS="$glib_save_CPPFLAGS"
2147 ], [test x$have_threads = xwin32], [
2148            g_threads_impl="WIN32"
2149 ], [
2150            g_threads_impl="NONE"
2151            G_THREAD_LIBS=error
2152 ])
2153
2154 if test "x$G_THREAD_LIBS" = xerror; then
2155         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2156 fi
2157
2158 case $host in
2159   *-*-beos*)
2160     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2161     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2162     ;;
2163   *)
2164     ;;
2165 esac
2166
2167 AC_MSG_CHECKING(thread related libraries)
2168 AC_MSG_RESULT($G_THREAD_LIBS)
2169
2170 dnl check for mt safe function variants and some posix functions
2171 dnl ************************************************************
2172
2173 glib_save_LIBS="$LIBS"
2174 # we are not doing the following for now, as this might require glib
2175 # to always be linked with the thread libs on some platforms.
2176 # LIBS="$LIBS $G_THREAD_LIBS"
2177 AC_CHECK_FUNCS(localtime_r gmtime_r)
2178 AS_IF([ test "$ac_cv_header_pwd_h" = "yes"], [
2179         AC_CACHE_CHECK([for posix getpwuid_r],
2180                 ac_cv_func_posix_getpwuid_r,
2181                 [AC_TRY_RUN([
2182 #include <errno.h>
2183 #include <pwd.h>
2184 int main () {
2185     char buffer[10000];
2186     struct passwd pwd, *pwptr = &pwd;
2187     int error;
2188     errno = 0;
2189     error = getpwuid_r (0, &pwd, buffer,
2190                         sizeof (buffer), &pwptr);
2191    return (error < 0 && errno == ENOSYS)
2192            || error == ENOSYS;
2193 }                               ],
2194                         [ac_cv_func_posix_getpwuid_r=yes],
2195                         [ac_cv_func_posix_getpwuid_r=no])])
2196         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2197         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2198                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2199                         [Have POSIX function getpwuid_r])
2200         else
2201                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2202                         ac_cv_func_nonposix_getpwuid_r,
2203                         [AC_TRY_LINK([#include <pwd.h>],
2204                                 [char buffer[10000];
2205                                 struct passwd pwd;
2206                                 getpwuid_r (0, &pwd, buffer,
2207                                                 sizeof (buffer));],
2208                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2209                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2210                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2211                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2212                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2213                                 [Have non-POSIX function getpwuid_r])
2214                 fi
2215         fi
2216 ])
2217 AS_IF([ test "$ac_cv_header_grp_h" = "yes"], [
2218         AC_CACHE_CHECK([for posix getgrgid_r],
2219                 ac_cv_func_posix_getgrgid_r,
2220                 [AC_TRY_RUN([
2221 #include <errno.h>
2222 #include <grp.h>
2223 int main () {
2224     char buffer[10000];
2225     struct group grp, *grpptr = &grp;
2226     int error;
2227     errno = 0;
2228     error = getgrgid_r (0, &grp, buffer,
2229                         sizeof (buffer), &grpptr);
2230    return (error < 0 && errno == ENOSYS)
2231            || error == ENOSYS;
2232 }                              ],
2233                        [ac_cv_func_posix_getgrgid_r=yes],
2234                        [ac_cv_func_posix_getgrgid_r=no])])
2235         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2236         AS_IF([ test "$ac_cv_func_posix_getgrgid_r" = yes ], [
2237                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2238                         [Have POSIX function getgrgid_r])
2239         ], [
2240                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2241                         ac_cv_func_nonposix_getgrgid_r,
2242                         [AC_TRY_LINK([#include <grp.h>],
2243                                 [char buffer[10000];
2244                                 struct group grp;
2245                                 getgrgid_r (0, &grp, buffer,
2246                                 sizeof (buffer));],
2247                         [ac_cv_func_nonposix_getgrgid_r=yes],
2248                         [ac_cv_func_nonposix_getgrgid_r=no])])
2249                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2250                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2251                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2252                                 [Have non-POSIX function getgrgid_r])
2253                 fi
2254         ])
2255 ])
2256 LIBS="$G_THREAD_LIBS $LIBS"
2257 AS_IF([ test x"$have_threads" = xposix], [
2258         glib_save_CPPFLAGS="$CPPFLAGS"
2259         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2260         # This is not AC_CHECK_FUNC to also work with function
2261         # name mangling in header files.
2262         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2263         AC_LINK_IFELSE(
2264             [AC_LANG_PROGRAM(
2265                 [#include <pthread.h>],
2266                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2267             [AC_MSG_RESULT(yes)
2268              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2269                 [Have function pthread_attr_setstacksize])],
2270             [AC_MSG_RESULT(no)])
2271         AC_MSG_CHECKING(for pthread_condattr_setclock)
2272         AC_LINK_IFELSE(
2273             [AC_LANG_PROGRAM(
2274                 [#include <pthread.h>],
2275                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2276             [AC_MSG_RESULT(yes)
2277              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2278                 [Have function pthread_condattr_setclock])],
2279             [AC_MSG_RESULT(no)])
2280         CPPFLAGS="$glib_save_CPPFLAGS"
2281 ])
2282
2283 LIBS="$glib_save_LIBS"
2284
2285 # now spit out all the warnings.
2286 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2287    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2288         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2289 fi
2290 if test "$ac_cv_func_localtime_r" != "yes"; then
2291         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2292 fi
2293
2294 #
2295 # Hack to deal with:
2296 #
2297 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2298 #     building shared libraries with linux.
2299 #  b) FreeBSD doesn't do this either.
2300 #
2301 case $host in
2302   *-*-freebsd*|*-*-linux*)
2303     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2304     ;;
2305   *-*-openbsd*)
2306     LDFLAGS="$LDFLAGS -pthread"
2307     ;;
2308   *)
2309     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2310     ;;
2311 esac
2312
2313 AC_SUBST(G_THREAD_CFLAGS)
2314 AC_SUBST(G_THREAD_LIBS)
2315 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2316 AC_SUBST(G_THREAD_LIBS_EXTRA)
2317
2318 AC_CHECK_FUNCS(clock_gettime, [], [
2319   AC_CHECK_LIB(rt, clock_gettime, [
2320     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2321     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2322     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2323   ])
2324 ])
2325
2326
2327 dnl ************************
2328 dnl *** g_atomic_* tests ***
2329 dnl ************************
2330
2331 dnl We need to decide at configure time if GLib will use real atomic
2332 dnl operations ("lock free") or emulated ones with a mutex.  This is
2333 dnl because we must put this information in glibconfig.h so we know if
2334 dnl it is safe or not to inline using compiler intrinsics directly from
2335 dnl the header.
2336 dnl
2337 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2338 dnl user is interested in knowing if they can use the atomic ops across
2339 dnl processes.
2340 dnl
2341 dnl We can currently support the atomic ops natively when building GLib
2342 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2343 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2344 dnl we are using GCC.
2345 dnl
2346 dnl Note that the atomic ops are only available with GCC on x86 when
2347 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2348 dnl not available but would be available given the right flags, we want
2349 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2350 dnl that then to silently fall back on emulated atomic ops just because
2351 dnl the user had the wrong build environment.
2352
2353 dnl We may add other compilers here in the future...
2354
2355 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2356   AC_TRY_COMPILE([],
2357                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2358                  [glib_cv_g_atomic_lock_free=yes],
2359                  [glib_cv_g_atomic_lock_free=no])])
2360
2361 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2362   SAVE_CFLAGS="${CFLAGS}"
2363   CFLAGS="-march=i486"
2364   AC_TRY_COMPILE([],
2365                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2366                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2367                  [])
2368   CFLAGS="${SAVE_CFLAGS}"
2369 fi
2370
2371 dnl We need a more robust approach here...
2372 case $host_cpu in
2373   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2374     glib_memory_barrier_needed=no
2375     ;;
2376   sparc*|alpha*|powerpc*|ia64)
2377     glib_memory_barrier_needed=yes
2378     ;;
2379   *)
2380     glib_memory_barrier_needed=yes
2381     ;;
2382 esac
2383
2384 dnl ************************
2385 dnl ** Check for futex(2) **
2386 dnl ************************
2387 AC_CACHE_CHECK(for futex(2) system call,
2388     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2389 #include <linux/futex.h>
2390 #include <sys/syscall.h>
2391 #include <unistd.h>
2392 ],[
2393 int
2394 main (void)
2395 {
2396   /* it is not like this actually runs or anything... */
2397   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2398   return 0;
2399 }
2400 ])],glib_cv_futex=yes,glib_cv_futex=no))
2401 if test x"$glib_cv_futex" = xyes; then
2402   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2403 fi
2404
2405 AC_CACHE_CHECK(for eventfd(2) system call,
2406     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2407 #include <sys/eventfd.h>
2408 #include <unistd.h>
2409 ],[
2410 int
2411 main (void)
2412 {
2413   eventfd (0, EFD_CLOEXEC);
2414   return 0;
2415 }
2416 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2417 if test x"$glib_cv_eventfd" = x"yes"; then
2418   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2419 fi
2420 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2421
2422 dnl ****************************************
2423 dnl *** GLib POLL* compatibility defines ***
2424 dnl ****************************************
2425
2426 glib_poll_includes=["
2427 #include <sys/types.h>
2428 #include <sys/poll.h>
2429 "]
2430
2431 AS_IF([ test $ac_cv_header_sys_types_h = yes &&
2432    test $ac_cv_header_sys_poll_h = yes ], [
2433   glib_failed=false
2434   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2435   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2436   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2437   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2438   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2439   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2440   if $glib_failed ; then
2441     AC_MSG_ERROR([Could not determine values for POLL* constants])
2442   fi
2443 ], [
2444   glib_cv_value_POLLIN=1
2445   glib_cv_value_POLLOUT=4
2446   glib_cv_value_POLLPRI=2
2447   glib_cv_value_POLLERR=8
2448   glib_cv_value_POLLHUP=16
2449   glib_cv_value_POLLNVAL=32
2450 ])
2451
2452 AC_MSG_CHECKING([for broken poll])
2453 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2454         #include <stdlib.h>
2455         #include <fcntl.h>
2456         #include <poll.h>
2457         #ifdef HAVE_SYS_POLL_H
2458         #include <sys/poll.h>
2459         #endif
2460         int main(void) {
2461           struct pollfd fds[1];
2462           int fd;
2463           fd = open("/dev/null", 1);
2464           fds[0].fd = fd;
2465           fds[0].events = POLLIN;
2466           fds[0].revents = 0;
2467           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2468                 exit(1);  /* Does not work for devices -- fail */
2469           }
2470           exit(0);
2471         }]])],
2472   [broken_poll=no],
2473   [broken_poll=yes
2474    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2475   [broken_poll="no (cross compiling)"])
2476 AC_MSG_RESULT($broken_poll)
2477
2478 dnl *********************
2479 dnl *** GRegex checks ***
2480 dnl *********************
2481
2482 PCRE_REQUIRED_VERSION=8.13
2483
2484 # Check if we should use the internal or the system-supplied pcre
2485 AC_ARG_WITH(pcre,
2486             [AS_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2487                             [whether to use system PCRE [default=internal]])])
2488
2489 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2490
2491 AS_IF([ test "x$with_pcre" = xsystem], [
2492   PKG_CHECK_MODULES(PCRE,
2493                     libpcre >= $PCRE_REQUIRED_VERSION)
2494   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2495                   glib_save_CFLAGS="$CFLAGS"
2496                   glib_save_LIBS="$LIBS"
2497                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2498                   AC_TRY_RUN([#include <pcre.h>
2499                               int main () {
2500                                 int support;
2501                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2502                                 if (!support)
2503                                   return 1;
2504                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2505                                 if (!support)
2506                                   return 1;
2507                                 return 0;
2508                               }],
2509                   glib_cv_pcre_has_unicode=yes,
2510                   glib_cv_pcre_has_unicode=no,
2511                   glib_cv_pcre_has_unicode=yes)
2512                   CFLAGS="$glib_save_CFLAGS"
2513                   LIBS="$glib_save_LIBS"
2514       ])
2515   if test "$glib_cv_pcre_has_unicode" = "no"; then
2516     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2517   fi
2518   AC_SUBST(PCRE_CFLAGS)
2519   AC_SUBST(PCRE_LIBS)
2520   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2521   PCRE_REQUIRES=libpcre
2522   AC_SUBST(PCRE_REQUIRES)
2523 ], [
2524   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2525   AS_IF([ test x"$GCC" = xyes], [
2526     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2527     save_CFLAGS="$CFLAGS"
2528     CFLAGS="$CFLAGS -Wno-pointer-sign"
2529     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2530                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2531     CFLAGS="$save_CFLAGS"
2532   ])
2533 ])
2534 AC_SUBST(PCRE_WARN_CFLAGS)
2535
2536 dnl **********************
2537 dnl *** Win32 API libs ***
2538 dnl **********************
2539
2540 case $host in
2541   *-*-cygwin*)
2542         G_LIBS_EXTRA="-luser32 -lkernel32"
2543     ;;
2544   *-*-mingw*)
2545         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2546     ;;
2547   *)
2548         G_LIBS_EXTRA=""
2549     ;;
2550 esac
2551 AC_SUBST(G_LIBS_EXTRA)
2552
2553 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2554 dnl since we need it for g_iconv()
2555
2556 AC_MSG_CHECKING([for EILSEQ])
2557 AC_TRY_COMPILE([
2558 #include <errno.h>
2559 ],
2560 [
2561 int error = EILSEQ;
2562 ], have_eilseq=yes, have_eilseq=no);
2563 AC_MSG_RESULT($have_eilseq)
2564
2565 dnl ******************************************************************
2566 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2567 dnl *** glib-compile-schemas in PATH                               ***
2568 dnl ******************************************************************
2569
2570 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2571
2572 AS_IF([ test $cross_compiling = yes && test x$enable_modular_tests = xyes], [
2573   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2574   if test x$GLIB_GENMARSHAL = xno; then
2575     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2576   fi
2577
2578   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2579   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2580     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2581   fi
2582
2583   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2584   if test x$GLIB_COMPILE_RESOURCES = xno; then
2585     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2586   fi
2587 ])
2588
2589 dnl **************************
2590 dnl *** Checks for gtk-doc ***
2591 dnl **************************
2592 # gtkdocize greps for ^GTK_DOC_CHECK and parses it, so you need to have
2593 # it on it's own line.
2594 m4_ifdef([GTK_DOC_CHECK], [
2595 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2596 ],[
2597 AM_CONDITIONAL([ENABLE_GTK_DOC],[false])
2598 ])
2599
2600 AC_ARG_ENABLE(man,
2601               [AS_HELP_STRING([--enable-man],
2602                               [generate man pages [default=auto]])],,
2603               enable_man=maybe)
2604
2605 AS_IF([test "$enable_man" != no], [
2606   AC_PATH_PROG([XSLTPROC], [xsltproc])
2607   AS_IF([test -z "$XSLTPROC"], [
2608     AS_IF([test "$enable_man" = yes], [
2609       AC_MSG_ERROR([xsltproc is required for --enable-man])
2610     ])
2611     enable_man=no
2612   ])
2613 ])
2614
2615 AS_IF([ test "$enable_man" != no ], [
2616   dnl check for DocBook DTD in the local catalog
2617   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2618      [DocBook XML DTD V4.1.2], [have_docbook_dtd=yes], [have_docbook_dtd=no])
2619   AS_IF([test "$have_docbook_dtd" != yes], [
2620     AS_IF([test "$enable_man" = yes ], [
2621       AC_MSG_ERROR([DocBook DTD is required for --enable-man])
2622     ])
2623     enable_man=no
2624   ])
2625 ])
2626
2627 AS_IF([test "$enable_man" != no], [
2628   dnl check for DocBook XSL stylesheets in the local catalog
2629   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2630      [DocBook XSL Stylesheets], [have_docbook_style=yes],[have_docbook_style=no])
2631   AS_IF([ test "$have_docbook_dtd" != yes ], [
2632     AS_IF([ test "$enable_man" = yes ], [
2633       AC_MSG_ERROR([DocBook XSL Stylesheets are required for --enable-man])
2634     ])
2635     enable_man=no
2636   ])
2637 ])
2638
2639 AM_CONDITIONAL(ENABLE_MAN, test "$enable_man" != no)
2640
2641 AC_MSG_CHECKING([whether to generate man pages])
2642 AS_IF([ test "$enable_man" != no ], [
2643   AC_MSG_RESULT([yes])
2644 ], [
2645   AC_MSG_RESULT([no])
2646 ])
2647
2648 dnl
2649 dnl Tracing
2650 dnl
2651
2652 AC_ARG_ENABLE([dtrace],
2653              [AS_HELP_STRING([--enable-dtrace],
2654                               [include tracing support for dtrace])])
2655 have_dtrace=no
2656 AC_MSG_CHECKING([whether to include dtrace tracing support])
2657 AS_IF([ test "x$enable_dtrace" != xno], [
2658   if test x$glib_have_carbon = xyes; then
2659     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2660   else
2661     AC_MSG_RESULT([yes])
2662     AC_CHECK_PROGS(DTRACE, dtrace)
2663     if test -z "$DTRACE"; then
2664       if test "x$enable_dtrace" = xyes; then
2665         AC_MSG_ERROR([dtrace not found])
2666       fi
2667     else
2668       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2669                       [if test "x$enable_dtrace" = xyes; then
2670                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2671                        fi])
2672     fi
2673   fi
2674 ], [
2675   AC_MSG_RESULT([no])
2676 ])
2677 if test "x$have_dtrace" = xyes; then
2678   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2679 fi
2680 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2681
2682 AC_MSG_CHECKING([whether to include systemtap tracing support])
2683 AC_ARG_ENABLE([systemtap],
2684              [AS_HELP_STRING([--enable-systemtap],
2685                               [include tracing support for systemtap])])
2686 have_systemtap=no
2687 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2688   have_systemtap=yes
2689 fi
2690 AC_MSG_RESULT(${have_systemtap})
2691
2692 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2693
2694 AC_ARG_WITH([tapset-install-dir],
2695             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2696                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2697             [if test "x${withval}" = x; then
2698                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2699              else
2700                ABS_TAPSET_DIR="${withval}"
2701               fi],
2702             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2703 AC_SUBST(ABS_TAPSET_DIR)
2704
2705 dnl ************************************
2706 dnl *** Enable lcov coverage reports ***
2707 dnl ************************************
2708
2709 AC_ARG_ENABLE(gcov,
2710   AS_HELP_STRING([--enable-gcov],
2711                  [enable coverage testing with gcov]),
2712   [use_gcov=$enableval], [use_gcov=no])
2713
2714 AS_IF([ test "x$use_gcov" = "xyes"], [
2715   dnl we need gcc:
2716   if test "$GCC" != "yes"; then
2717     AC_MSG_ERROR([GCC is required for --enable-gcov])
2718   fi
2719
2720   dnl Check if ccache is being used
2721   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2722   case `$SHTOOL path $CC` in
2723     *ccache*[)] gcc_ccache=yes;;
2724     *[)] gcc_ccache=no;;
2725   esac
2726
2727   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2728     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2729   fi
2730
2731   ltp_version_list="1.6 1.7 1.8 1.9"
2732   AC_CHECK_PROG(LTP, lcov, lcov)
2733   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2734
2735   AS_IF([ test "$LTP" ], [
2736     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2737       glib_cv_ltp_version=invalid
2738       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2739       for ltp_check_version in $ltp_version_list; do
2740         if test "$ltp_version" = "$ltp_check_version"; then
2741           glib_cv_ltp_version="$ltp_check_version (ok)"
2742         fi
2743       done
2744     ])
2745   ], [
2746     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2747     AC_MSG_ERROR([$ltp_msg])
2748   ])
2749
2750   case $glib_cv_ltp_version in
2751     ""|invalid[)]
2752       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2753       AC_MSG_ERROR([$ltp_msg])
2754       LTP="exit 0;"
2755       ;;
2756   esac
2757
2758   if test -z "$LTP_GENHTML"; then
2759     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2760   fi
2761
2762   dnl Remove all optimization flags from CFLAGS
2763   changequote({,})
2764   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2765   changequote([,])
2766
2767   dnl Add the special gcc flags
2768   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2769   LDFLAGS="$LDFLAGS -lgcov"
2770 ])
2771
2772 dnl ******************************
2773 dnl *** output the whole stuff ***
2774 dnl ******************************
2775
2776 dnl this section will only be run if config.status is invoked with no
2777 dnl arguments, or with "glib/glibconfig.h" as an argument.
2778 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2779 [
2780         outfile=glib/glibconfig.h-tmp
2781         cat > $outfile <<\_______EOF
2782 /* glibconfig.h
2783  *
2784  * This is a generated file.  Please modify 'configure.ac'
2785  */
2786
2787 #ifndef __GLIBCONFIG_H__
2788 #define __GLIBCONFIG_H__
2789
2790 #include <glib/gmacros.h>
2791
2792 _______EOF
2793
2794         if test x$glib_limits_h = xyes; then
2795           echo '#include <limits.h>' >> $outfile
2796         fi
2797         if test x$glib_float_h = xyes; then
2798           echo '#include <float.h>' >> $outfile
2799         fi
2800         if test x$glib_values_h = xyes; then
2801           echo '#include <values.h>' >> $outfile
2802         fi
2803         if test "$glib_header_alloca_h" = "yes"; then
2804           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2805         fi
2806         if test x$glib_sys_poll_h = xyes; then
2807           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2808         fi
2809         if test x$glib_included_printf != xyes; then
2810           echo "
2811 /* Specifies that GLib's g_print*() functions wrap the
2812  * system printf functions.  This is useful to know, for example,
2813  * when using glibc's register_printf_function().
2814  */" >> $outfile
2815           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2816         fi
2817
2818         cat >> $outfile <<_______EOF
2819
2820 G_BEGIN_DECLS
2821
2822 #define G_MINFLOAT      $glib_mf
2823 #define G_MAXFLOAT      $glib_Mf
2824 #define G_MINDOUBLE     $glib_md
2825 #define G_MAXDOUBLE     $glib_Md
2826 #define G_MINSHORT      $glib_ms
2827 #define G_MAXSHORT      $glib_Ms
2828 #define G_MAXUSHORT     $glib_Mus
2829 #define G_MININT        $glib_mi
2830 #define G_MAXINT        $glib_Mi
2831 #define G_MAXUINT       $glib_Mui
2832 #define G_MINLONG       $glib_ml
2833 #define G_MAXLONG       $glib_Ml
2834 #define G_MAXULONG      $glib_Mul
2835
2836 _______EOF
2837
2838
2839         ### this should always be true in a modern C/C++ compiler
2840         cat >>$outfile <<_______EOF
2841 typedef signed char gint8;
2842 typedef unsigned char guint8;
2843 _______EOF
2844
2845
2846         if test -n "$gint16"; then
2847           cat >>$outfile <<_______EOF
2848 typedef signed $gint16 gint16;
2849 typedef unsigned $gint16 guint16;
2850 #define G_GINT16_MODIFIER $gint16_modifier
2851 #define G_GINT16_FORMAT $gint16_format
2852 #define G_GUINT16_FORMAT $guint16_format
2853 _______EOF
2854         fi
2855
2856
2857         if test -n "$gint32"; then
2858           cat >>$outfile <<_______EOF
2859 typedef signed $gint32 gint32;
2860 typedef unsigned $gint32 guint32;
2861 #define G_GINT32_MODIFIER $gint32_modifier
2862 #define G_GINT32_FORMAT $gint32_format
2863 #define G_GUINT32_FORMAT $guint32_format
2864 _______EOF
2865         fi
2866
2867         cat >>$outfile <<_______EOF
2868 #define G_HAVE_GINT64 1          /* deprecated, always true */
2869
2870 ${glib_extension}typedef signed $gint64 gint64;
2871 ${glib_extension}typedef unsigned $gint64 guint64;
2872
2873 #define G_GINT64_CONSTANT(val)  $gint64_constant
2874 #define G_GUINT64_CONSTANT(val) $guint64_constant
2875 _______EOF
2876
2877         if test x$gint64_format != x ; then
2878           cat >>$outfile <<_______EOF
2879 #define G_GINT64_MODIFIER $gint64_modifier
2880 #define G_GINT64_FORMAT $gint64_format
2881 #define G_GUINT64_FORMAT $guint64_format
2882 _______EOF
2883         else
2884           cat >>$outfile <<_______EOF
2885 #undef G_GINT64_MODIFIER
2886 #undef G_GINT64_FORMAT
2887 #undef G_GUINT64_FORMAT
2888 _______EOF
2889         fi
2890
2891         cat >>$outfile <<_______EOF
2892
2893 #define GLIB_SIZEOF_VOID_P $glib_void_p
2894 #define GLIB_SIZEOF_LONG   $glib_long
2895 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2896
2897 _______EOF
2898
2899         cat >>$outfile <<_______EOF
2900 typedef signed $glib_size_type_define gssize;
2901 typedef unsigned $glib_size_type_define gsize;
2902 #define G_GSIZE_MODIFIER $gsize_modifier
2903 #define G_GSSIZE_FORMAT $gssize_format
2904 #define G_GSIZE_FORMAT $gsize_format
2905
2906 #define G_MAXSIZE       G_MAXU$glib_msize_type
2907 #define G_MINSSIZE      G_MIN$glib_msize_type
2908 #define G_MAXSSIZE      G_MAX$glib_msize_type
2909
2910 typedef gint64 goffset;
2911 #define G_MINOFFSET     G_MININT64
2912 #define G_MAXOFFSET     G_MAXINT64
2913
2914 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2915 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2916 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2917
2918 _______EOF
2919
2920         if test -z "$glib_unknown_void_p"; then
2921           cat >>$outfile <<_______EOF
2922
2923 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2924 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2925
2926 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2927 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2928
2929 typedef signed $glib_intptr_type_define gintptr;
2930 typedef unsigned $glib_intptr_type_define guintptr;
2931
2932 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2933 #define G_GINTPTR_FORMAT        $gintptr_format
2934 #define G_GUINTPTR_FORMAT       $guintptr_format
2935 _______EOF
2936         else
2937           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2938         fi
2939
2940
2941
2942         cat >>$outfile <<_______EOF
2943 $glib_atexit
2944 $glib_memmove
2945 $glib_defines
2946 $glib_os
2947 $glib_static_compilation
2948
2949 $glib_vacopy
2950
2951 #ifdef  __cplusplus
2952 #define G_HAVE_INLINE   1
2953 #else   /* !__cplusplus */
2954 $glib_inline
2955 #endif  /* !__cplusplus */
2956
2957 #ifdef  __cplusplus
2958 #define G_CAN_INLINE    1
2959 _______EOF
2960
2961         if test x$g_can_inline = xyes ; then
2962                 cat >>$outfile <<_______EOF
2963 #else   /* !__cplusplus */
2964 #define G_CAN_INLINE    1
2965 _______EOF
2966         fi
2967
2968         cat >>$outfile <<_______EOF
2969 #endif
2970
2971 _______EOF
2972
2973         if test x$g_have_iso_c_varargs = xyes ; then
2974                 cat >>$outfile <<_______EOF
2975 #ifndef __cplusplus
2976 # define G_HAVE_ISO_VARARGS 1
2977 #endif
2978 _______EOF
2979         fi
2980         if test x$g_have_iso_cxx_varargs = xyes ; then
2981                 cat >>$outfile <<_______EOF
2982 #ifdef __cplusplus
2983 # define G_HAVE_ISO_VARARGS 1
2984 #endif
2985 _______EOF
2986         fi
2987         if test x$g_have_gnuc_varargs = xyes ; then
2988                 cat >>$outfile <<_______EOF
2989
2990 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2991  * is passed ISO vararg support is turned off, and there is no work
2992  * around to turn it on, so we unconditionally turn it off.
2993  */
2994 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2995 #  undef G_HAVE_ISO_VARARGS
2996 #endif
2997
2998 #define G_HAVE_GNUC_VARARGS 1
2999 _______EOF
3000         fi
3001
3002         case x$g_stack_grows in
3003         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3004         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3005         esac
3006
3007
3008         echo >>$outfile
3009         if test x$g_have_eilseq = xno; then
3010                 cat >>$outfile <<_______EOF
3011 #ifndef EILSEQ
3012 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3013  * The correspondence between this and the corresponding definition
3014  * in libiconv is essential.
3015  */
3016 #  define EILSEQ ENOENT
3017 #endif
3018 _______EOF
3019
3020         fi
3021
3022         if test x$g_have_gnuc_visibility = xyes; then
3023                 cat >>$outfile <<_______EOF
3024 #define G_HAVE_GNUC_VISIBILITY 1
3025 _______EOF
3026         fi
3027                 cat >>$outfile <<_______EOF
3028 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3029 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3030 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3031 #define G_GNUC_INTERNAL __hidden
3032 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3033 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3034 #else
3035 #define G_GNUC_INTERNAL
3036 #endif
3037 _______EOF
3038
3039         echo >>$outfile
3040         cat >>$outfile <<_______EOF
3041 #define G_THREADS_ENABLED
3042 #define G_THREADS_IMPL_$g_threads_impl_def
3043 _______EOF
3044
3045         if test x"$g_memory_barrier_needed" != xno; then
3046           echo >>$outfile
3047           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3048         fi
3049         if test x"$g_atomic_lock_free" = xyes; then
3050           echo >>$outfile
3051           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
3052         fi
3053         echo >>$outfile
3054         g_bit_sizes="16 32 64"
3055         for bits in $g_bit_sizes; do
3056           cat >>$outfile <<_______EOF
3057 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3058 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3059 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3060 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3061 _______EOF
3062         done
3063
3064         cat >>$outfile <<_______EOF
3065 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3066 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3067 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3068 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3069 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3070 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3071 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3072 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3073 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3074 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3075 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3076 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3077 #define G_BYTE_ORDER $g_byte_order
3078
3079 #define GLIB_SYSDEF_POLLIN =$g_pollin
3080 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3081 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3082 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3083 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3084 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3085
3086 #define G_MODULE_SUFFIX "$g_module_suffix"
3087
3088 typedef $g_pid_type GPid;
3089
3090 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3091 #define GLIB_SYSDEF_AF_INET $g_af_inet
3092 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3093
3094 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3095 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3096 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3097
3098 G_END_DECLS
3099
3100 #endif /* __GLIBCONFIG_H__ */
3101 _______EOF
3102
3103
3104         if cmp -s $outfile glib/glibconfig.h; then
3105           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3106           rm -f $outfile
3107         else
3108           mv $outfile glib/glibconfig.h
3109         fi
3110 ],[
3111
3112 # Note that if two cases are the same, case goes with the first one.
3113 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3114 # on variable expansion in case labels.  Look at the generated config.status
3115 # for a hint.
3116
3117 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3118   glib_header_alloca_h="$ac_cv_working_alloca_h"
3119 else
3120   glib_header_alloca_h="$ac_cv_header_alloca_h"
3121 fi
3122
3123 case xyes in
3124 x$ac_cv_header_float_h)
3125   glib_float_h=yes
3126   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3127   glib_md=DBL_MIN glib_Md=DBL_MAX
3128   ;;
3129 x$ac_cv_header_values_h)
3130   glib_values_h=yes
3131   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3132   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3133   ;;
3134 esac
3135
3136 case xyes in
3137 x$ac_cv_header_limits_h)
3138   glib_limits_h=yes
3139   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3140   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3141   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3142   ;;
3143 x$ac_cv_header_values_h)
3144   glib_values_h=yes
3145   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3146   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3147   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3148   ;;
3149 esac
3150
3151 if test x$ac_cv_header_sys_poll_h = xyes ; then
3152   glib_sys_poll_h=yes
3153 fi
3154
3155 if test x$enable_included_printf = xyes ; then
3156   glib_included_printf=yes
3157 fi
3158
3159 case 2 in
3160 $ac_cv_sizeof_short)
3161   gint16=short
3162   gint16_modifier='"h"'
3163   gint16_format='"hi"'
3164   guint16_format='"hu"'
3165   ;;
3166 $ac_cv_sizeof_int)
3167   gint16=int
3168   gint16_modifier='""'
3169   gint16_format='"i"'
3170   guint16_format='"u"'
3171   ;;
3172 esac
3173 case 4 in
3174 $ac_cv_sizeof_short)
3175   gint32=short
3176   gint32_modifier='"h"'
3177   gint32_format='"hi"'
3178   guint32_format='"hu"'
3179   ;;
3180 $ac_cv_sizeof_int)
3181   gint32=int
3182   gint32_modifier='""'
3183   gint32_format='"i"'
3184   guint32_format='"u"'
3185   ;;
3186 $ac_cv_sizeof_long)
3187   gint32=long
3188   gint32_modifier='"l"'
3189   gint32_format='"li"'
3190   guint32_format='"lu"'
3191   ;;
3192 esac
3193 case 8 in
3194 $ac_cv_sizeof_int)
3195   gint64=int
3196   gint64_modifier='""'
3197   gint64_format='"i"'
3198   guint64_format='"u"'
3199   glib_extension=
3200   gint64_constant='(val)'
3201   guint64_constant='(val)'
3202   ;;
3203 $ac_cv_sizeof_long)
3204   gint64=long
3205   gint64_modifier='"l"'
3206   gint64_format='"li"'
3207   guint64_format='"lu"'
3208   glib_extension=
3209   gint64_constant='(val##L)'
3210   guint64_constant='(val##UL)'
3211   ;;
3212 $ac_cv_sizeof_long_long)
3213   gint64='long long'
3214   if test -n "$glib_cv_long_long_format"; then
3215     gint64_modifier='"'$glib_cv_long_long_format'"'
3216     gint64_format='"'$glib_cv_long_long_format'i"'
3217     guint64_format='"'$glib_cv_long_long_format'u"'
3218   fi
3219   glib_extension='G_GNUC_EXTENSION '
3220   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3221   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3222   ;;
3223 $ac_cv_sizeof___int64)
3224   gint64='__int64'
3225   if test -n "$glib_cv_long_long_format"; then
3226     gint64_modifier='"'$glib_cv_long_long_format'"'
3227     gint64_format='"'$glib_cv_long_long_format'i"'
3228     guint64_format='"'$glib_cv_long_long_format'u"'
3229   fi
3230   glib_extension=
3231   gint64_constant='(val##i64)'
3232   guint64_constant='(val##ui64)'
3233   ;;
3234 esac
3235 glib_size_t=$ac_cv_sizeof_size_t
3236 glib_size_type_define="$glib_size_type"
3237 glib_void_p=$ac_cv_sizeof_void_p
3238 glib_long=$ac_cv_sizeof_long
3239
3240 case "$glib_size_type" in
3241 short)
3242   gsize_modifier='"h"'
3243   gsize_format='"hu"'
3244   gssize_format='"hi"'
3245   glib_msize_type='SHRT'
3246   ;;
3247 int)
3248   gsize_modifier='""'
3249   gsize_format='"u"'
3250   gssize_format='"i"'
3251   glib_msize_type='INT'
3252   ;;
3253 long)
3254   gsize_modifier='"l"'
3255   gsize_format='"lu"'
3256   gssize_format='"li"'
3257   glib_msize_type='LONG'
3258   ;;
3259 "long long"|__int64)
3260   gsize_modifier='"I64"'
3261   gsize_format='"I64u"'
3262   gssize_format='"I64i"'
3263   glib_msize_type='INT64'
3264   ;;
3265 esac
3266
3267 gintbits=`expr $ac_cv_sizeof_int \* 8`
3268 glongbits=`expr $ac_cv_sizeof_long \* 8`
3269 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3270
3271 case $ac_cv_sizeof_void_p in
3272 $ac_cv_sizeof_int)
3273   glib_intptr_type_define=int
3274   gintptr_modifier='""'
3275   gintptr_format='"i"'
3276   guintptr_format='"u"'
3277   glib_gpi_cast='(gint)'
3278   glib_gpui_cast='(guint)'
3279   ;;
3280 $ac_cv_sizeof_long)
3281   glib_intptr_type_define=long
3282   gintptr_modifier='"l"'
3283   gintptr_format='"li"'
3284   guintptr_format='"lu"'
3285   glib_gpi_cast='(glong)'
3286   glib_gpui_cast='(gulong)'
3287   ;;
3288 $ac_cv_sizeof_long_long)
3289   glib_intptr_type_define='long long'
3290   gintptr_modifier='"I64"'
3291   gintptr_format='"I64i"'
3292   guintptr_format='"I64u"'
3293   glib_gpi_cast='(gint64)'
3294   glib_gpui_cast='(guint64)'
3295   ;;
3296 $ac_cv_sizeof___int64)
3297   glib_intptr_type_define=__int64
3298   gintptr_modifier='"I64"'
3299   gintptr_format='"I64i"'
3300   guintptr_format='"I64u"'
3301   glib_gpi_cast='(gint64)'
3302   glib_gpui_cast='(guint64)'
3303   ;;
3304 *)
3305   glib_unknown_void_p=yes
3306   ;;
3307 esac
3308
3309
3310 case xyes in
3311 x$ac_cv_func_atexit)
3312   glib_atexit="
3313 #ifdef NeXT /* @#%@! NeXTStep */
3314 # define g_ATEXIT(proc) (!atexit (proc))
3315 #else
3316 # define g_ATEXIT(proc) (atexit (proc))
3317 #endif"
3318   ;;
3319 x$ac_cv_func_on_exit)
3320   glib_atexit="
3321 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3322   ;;
3323 esac
3324
3325 case xyes in
3326 x$ac_cv_func_memmove)
3327   glib_memmove='
3328 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3329   ;;
3330 x$glib_cv_working_bcopy)
3331   glib_memmove="
3332 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3333 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3334   ;;
3335 *)
3336   glib_memmove="
3337 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3338  * so we have to roll our own copy routine. */
3339 void g_memmove (void* dest, const void * src, unsigned long len);"
3340   ;;
3341 esac
3342
3343 glib_defines="
3344 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3345 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3346 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3347 "
3348
3349 case xyes in
3350 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3351 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3352 *)                      glib_vacopy=''
3353 esac
3354
3355 if test x$glib_cv_va_val_copy = xno; then
3356   glib_vacopy="\$glib_vacopy
3357 #define G_VA_COPY_AS_ARRAY 1"
3358 fi
3359
3360 if test x$glib_cv_hasinline = xyes; then
3361     glib_inline='#define G_HAVE_INLINE 1'
3362 fi
3363 if test x$glib_cv_has__inline = xyes; then
3364     glib_inline="\$glib_inline
3365 #define G_HAVE___INLINE 1"
3366 fi
3367 if test x$glib_cv_has__inline__ = xyes; then
3368     glib_inline="\$glib_inline
3369 #define G_HAVE___INLINE__ 1"
3370 fi
3371
3372 g_have_gnuc_varargs=$g_have_gnuc_varargs
3373 g_have_iso_c_varargs=$g_have_iso_c_varargs
3374 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3375
3376 g_can_inline=$g_can_inline
3377 g_have_gnuc_visibility=$g_have_gnuc_visibility
3378 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3379
3380 if test x$ac_cv_c_bigendian = xyes; then
3381   g_byte_order=G_BIG_ENDIAN
3382   g_bs_native=BE
3383   g_bs_alien=LE
3384 else
3385   g_byte_order=G_LITTLE_ENDIAN
3386   g_bs_native=LE
3387   g_bs_alien=BE
3388 fi
3389
3390 g_pollin=$glib_cv_value_POLLIN
3391 g_pollout=$glib_cv_value_POLLOUT
3392 g_pollpri=$glib_cv_value_POLLPRI
3393 g_pollhup=$glib_cv_value_POLLHUP
3394 g_pollerr=$glib_cv_value_POLLERR
3395 g_pollnval=$glib_cv_value_POLLNVAL
3396
3397 # If a family is not found on the system, define that family to
3398 # a negative value, picking a different one for each undefined
3399 # family (-1 for AF_UNIX, -2 for the next one, -3 ...)
3400 # This is needed because glib-mkenums doesn't handle optional
3401 # values in enums, and thus we have to have all existing values
3402 # defined in the enum.
3403 if test "x$glib_cv_value_AF_UNIX" != "x"; then
3404   g_af_unix=$glib_cv_value_AF_UNIX
3405 else
3406   g_af_unix=-1
3407 fi
3408 g_af_inet=$glib_cv_value_AF_INET
3409 g_af_inet6=$glib_cv_value_AF_INET6
3410
3411 g_msg_peek=$glib_cv_value_MSG_PEEK
3412 g_msg_oob=$glib_cv_value_MSG_OOB
3413 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3414
3415 g_stack_grows=$glib_cv_stack_grows
3416
3417 g_have_eilseq=$have_eilseq
3418
3419 g_threads_impl_def=$g_threads_impl
3420
3421 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3422 g_memory_barrier_needed="$glib_memory_barrier_needed"
3423 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3424
3425 g_module_suffix="$glib_gmodule_suffix"
3426
3427 g_pid_type="$glib_pid_type"
3428 case $host in
3429   *-*-beos*)
3430     glib_os="#define G_OS_BEOS"
3431     ;;
3432   *-*-cygwin*)
3433     glib_os="#define G_OS_UNIX
3434 #define G_PLATFORM_WIN32
3435 #define G_WITH_CYGWIN"
3436     ;;
3437   *-*-mingw*)
3438     glib_os="#define G_OS_WIN32
3439 #define G_PLATFORM_WIN32"
3440     ;;
3441   *)
3442     glib_os="#define G_OS_UNIX"
3443     ;;
3444 esac
3445 glib_static_compilation=""
3446 if test x$glib_win32_static_compilation = xyes; then
3447   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3448 #define GOBJECT_STATIC_COMPILATION 1"
3449 fi
3450 ])
3451
3452 # Redo enough to get guint32 and guint64 for the alignment checks below
3453 case 4 in
3454 $ac_cv_sizeof_short)
3455   gint32=short
3456   ;;
3457 $ac_cv_sizeof_int)
3458   gint32=int
3459   ;;
3460 $ac_cv_sizeof_long)
3461   gint32=long
3462   ;;
3463 esac
3464 case 8 in
3465 $ac_cv_sizeof_int)
3466   gint64=int
3467   ;;
3468 $ac_cv_sizeof_long)
3469   gint64=long
3470   ;;
3471 $ac_cv_sizeof_long_long)
3472   gint64='long long'
3473   ;;
3474 $ac_cv_sizeof___int64)
3475   gint64='__int64'
3476   ;;
3477 esac
3478
3479 AC_CHECK_TYPE([guint32],,,[typedef unsigned $gint32 guint32;])
3480 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3481 typedef unsigned $gint32 guint32;])
3482 AC_CHECK_TYPE([guint64],,,[typedef unsigned $gint64 guint64;])
3483 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3484 typedef unsigned $gint64 guint64;])
3485 AC_CHECK_TYPE([unsigned long])
3486 AC_CHECK_ALIGNOF([unsigned long])
3487
3488 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3489 #
3490 # 1.2.14 required for dbus_message_set_serial
3491 AS_IF([ test x$enable_modular_tests = xyes], [
3492    PKG_CHECK_MODULES(DBUS1,
3493                      dbus-1 >= 1.2.14,
3494                      [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3495                      have_dbus1=no)
3496    AC_SUBST(DBUS1_CFLAGS)
3497    AC_SUBST(DBUS1_LIBS)
3498 ])
3499 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3500
3501 AC_CHECK_PROGS([DBUS_DAEMON], [dbus-daemon])
3502 AM_CONDITIONAL([HAVE_DBUS_DAEMON], [test x$DBUS_DAEMON = xdbus-daemon ])
3503
3504 dnl
3505 dnl Check for -Bsymbolic-functions linker flag used to avoid
3506 dnl intra-library PLT jumps, if available.
3507 dnl
3508
3509 AC_ARG_ENABLE(Bsymbolic,
3510               [AS_HELP_STRING([--disable-Bsymbolic],
3511                               [avoid linking with -Bsymbolic])],,
3512               [SAVED_LDFLAGS="${LDFLAGS}"
3513                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3514                LDFLAGS=-Wl,-Bsymbolic-functions
3515                AC_TRY_LINK([], [int main (void) { return 0; }],
3516                            AC_MSG_RESULT(yes)
3517                            enable_Bsymbolic=yes,
3518                            AC_MSG_RESULT(no)
3519                            enable_Bsymbolic=no)
3520                LDFLAGS="${SAVED_LDFLAGS}"])
3521
3522 if test "x${enable_Bsymbolic}" = "xyes"; then
3523   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3524 fi
3525
3526 AC_SUBST(GLIB_LINK_FLAGS)
3527
3528 dnl Compiler flags; macro originates from systemd
3529 dnl See https://bugzilla.gnome.org/show_bug.cgi?id=608953
3530 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
3531    -Wall -Wstrict-prototypes -Werror=declaration-after-statement \
3532    -Werror=missing-prototypes -Werror=implicit-function-declaration \
3533    -Werror=pointer-arith -Werror=init-self -Werror=format-security \
3534    -Werror=format=2 -Werror=missing-include-dirs])
3535 CFLAGS="$CFLAGS $with_cflags"
3536
3537 #
3538 # Define variables corresponding to the correct include paths to use for
3539 # in-tree building.
3540 #
3541
3542 # for config.h:
3543 config_h_INCLUDES='-I$(top_builddir)'
3544 AC_SUBST(config_h_INCLUDES)
3545
3546 # glib:
3547 #   config.h
3548 #   $(top_builddir)/glib: for glibconfig.h
3549 #   $(top_srcdir)/glib:   for glib.h
3550 #   $(top_srcdir):        for everything
3551 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3552 AC_SUBST(glib_INCLUDES)
3553
3554 # gthread:
3555 #   same as glib
3556 gthread_INCLUDES='$(glib_INCLUDES)'
3557 AC_SUBST(gthread_INCLUDES)
3558
3559 # gobject:
3560 #   same as gthread
3561 gobject_INCLUDES='$(gthread_INCLUDES)'
3562 AC_SUBST(gobject_INCLUDES)
3563
3564 # gmodule:
3565 #   glib includes
3566 #   $(top_srcdir)/gmodule: for gmodule.h
3567 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3568 AC_SUBST(gmodule_INCLUDES)
3569
3570 # gio:
3571 #   same as gmodule
3572 gio_INCLUDES='$(gmodule_INCLUDES)'
3573 AC_SUBST(gio_INCLUDES)
3574
3575
3576 AC_CONFIG_FILES([
3577 glib-2.0.pc
3578 gmodule-2.0.pc
3579 gmodule-export-2.0.pc
3580 gmodule-no-export-2.0.pc
3581 gthread-2.0.pc
3582 gobject-2.0.pc
3583 gio-2.0.pc
3584 gio-unix-2.0.pc
3585 gio-windows-2.0.pc
3586 glib-zip
3587 glib-gettextize
3588 Makefile
3589 build/Makefile
3590 build/win32/Makefile
3591 build/win32/dirent/Makefile
3592 build/win32/vs9/Makefile
3593 build/win32/vs10/Makefile
3594 glib/Makefile
3595 glib/glib.stp
3596 glib/libcharset/Makefile
3597 glib/gnulib/Makefile
3598 glib/pcre/Makefile
3599 glib/update-pcre/Makefile
3600 glib/tests/Makefile
3601 gmodule/Makefile
3602 gmodule/gmoduleconf.h
3603 gobject/Makefile
3604 gobject/gobject.stp
3605 gobject/glib-mkenums
3606 gobject/tests/Makefile
3607 gthread/Makefile
3608 gio/Makefile
3609 gio/gdbus-2.0/codegen/Makefile
3610 gio/gdbus-2.0/codegen/config.py
3611 gio/xdgmime/Makefile
3612 gio/inotify/Makefile
3613 gio/fen/Makefile
3614 gio/fam/Makefile
3615 gio/win32/Makefile
3616 gio/tests/Makefile
3617 gio/tests/gdbus-object-manager-example/Makefile
3618 po/Makefile.in
3619 docs/Makefile
3620 docs/reference/Makefile
3621 docs/reference/glib/Makefile
3622 docs/reference/glib/version.xml
3623 docs/reference/gobject/Makefile
3624 docs/reference/gobject/version.xml
3625 docs/reference/gio/Makefile
3626 docs/reference/gio/gdbus-object-manager-example/Makefile
3627 docs/reference/gio/version.xml
3628 tests/Makefile
3629 tests/gobject/Makefile
3630 tests/refcount/Makefile
3631 m4macros/Makefile
3632 ])
3633
3634 AC_CONFIG_COMMANDS([chmod-scripts],
3635 [chmod 0755 glib-zip
3636 chmod 0755 glib-gettextize
3637 chmod 0755 gobject/glib-mkenums])
3638
3639 # we want to invoke this macro solely so that the config.status script
3640 # and automake generated makefiles know about these generated files.
3641 # They are only needed to distcheck the package
3642 if false; then
3643   AC_CONFIG_FILES([
3644     INSTALL
3645     README
3646     config.h.win32
3647     glib/glibconfig.h.win32
3648     glib/makefile.msc
3649     glib/glib.rc
3650     gmodule/makefile.msc
3651     gmodule/gmodule.rc
3652     gobject/makefile.msc
3653     gobject/gobject.rc
3654     gthread/makefile.msc
3655     gthread/gthread.rc
3656     gio/gio.rc
3657     tests/makefile.msc
3658   ])
3659 fi
3660
3661 AC_OUTPUT