configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  30 USER_CFLAGS="$CFLAGS"
  31 USER_CXXFLAGS="$CXXFLAGS"
  32
  33 dnl Versions for external dependencies
  34 LIBDRM_REQUIRED=2.4.24
  35 LIBDRM_RADEON_REQUIRED=2.4.31
  36 LIBDRM_INTEL_REQUIRED=2.4.37
  37 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  38 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  39 DRI2PROTO_REQUIRED=2.6
  40 GLPROTO_REQUIRED=1.4.14
  41 LIBDRM_XORG_REQUIRED=2.4.24
  42 LIBKMS_XORG_REQUIRED=1.0.0
  43
  44 dnl Check for progs
  45 AC_PROG_CPP
  46 AC_PROG_CC
  47 AC_PROG_CXX
  48 AM_PROG_CC_C_O
  49 AM_PROG_AS
  50 AC_CHECK_PROGS([MAKE], [gmake make])
  51 AC_CHECK_PROGS([PYTHON2], [python2 python])
  52 AC_PROG_SED
  53 AC_PROG_MKDIR_P
  54 AC_PATH_PROG([MKDEP], [makedepend])
  55
  56 if test "x$MKDEP" = "x"; then
  57     AC_MSG_ERROR([makedepend is required to build Mesa])
  58 fi
  59
  60 AC_PROG_YACC
  61 AC_PATH_PROG([YACC_INST], $YACC)
  62 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  63     if test -z "$YACC_INST"; then
  64         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  65     fi
  66 fi
  67 AC_PROG_LEX
  68
  69 AC_PATH_PROG([PERL], [perl])
  70
  71 AC_CHECK_PROG(INDENT, indent, indent, cat)
  72 if test "x$INDENT" != "xcat"; then
  73     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  74 fi
  75
  76 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  77 dnl configuration in that case.
  78 AC_PROG_INSTALL
  79 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  80
  81 dnl We need a POSIX shell for parts of the build. Assume we have one
  82 dnl in most cases.
  83 case "$host_os" in
  84 solaris*)
  85     # Solaris /bin/sh is too old/non-POSIX compliant
  86     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  87     SHELL="$POSIX_SHELL"
  88     ;;
  89 esac
  90
  91 dnl clang is mostly GCC-compatible, but its version is much lower,
  92 dnl so we have to check for it.
  93 AC_MSG_CHECKING([if compiling with clang])
  94
  95 AC_COMPILE_IFELSE(
  96 [AC_LANG_PROGRAM([], [[
  97 #ifndef __clang__
  98        not clang
  99 #endif
 100 ]])],
 101 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 102
 103 AC_MSG_RESULT([$acv_mesa_CLANG])
 104
 105 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 106 dnl versions are explictly not supported.
 107 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 108     AC_MSG_CHECKING([whether gcc version is sufficient])
 109     major=0
 110     minor=0
 111
 112     GCC_VERSION=`$CC -dumpversion`
 113     if test $? -eq 0; then
 114         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 115         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 116     fi
 117
 118     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 119         AC_MSG_RESULT([no])
 120         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 121     else
 122         AC_MSG_RESULT([yes])
 123     fi
 124 fi
 125
 126
 127 MKDEP_OPTIONS=-fdepend
 128 dnl Ask gcc where it's keeping its secret headers
 129 if test "x$GCC" = xyes; then
 130     for dir in include include-fixed; do
 131         GCC_INCLUDES=`$CC -print-file-name=$dir`
 132         if test "x$GCC_INCLUDES" != x && \
 133            test "$GCC_INCLUDES" != "$dir" && \
 134            test -d "$GCC_INCLUDES"; then
 135             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 136         fi
 137     done
 138 fi
 139 AC_SUBST([MKDEP_OPTIONS])
 140
 141 dnl Make sure the pkg-config macros are defined
 142 m4_ifndef([PKG_PROG_PKG_CONFIG],
 143     [m4_fatal([Could not locate the pkg-config autoconf macros.
 144   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 145   are in a different location, try setting the environment variable
 146   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 147 PKG_PROG_PKG_CONFIG()
 148
 149 dnl LIB_DIR - library basename
 150 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 151 AC_SUBST([LIB_DIR])
 152
 153 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 154 _SAVE_LDFLAGS="$LDFLAGS"
 155 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 156 AC_SUBST([EXTRA_LIB_PATH])
 157
 158 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 159 _SAVE_CPPFLAGS="$CPPFLAGS"
 160 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 161 AC_SUBST([X11_INCLUDES])
 162
 163 dnl Compiler macros
 164 DEFINES=""
 165 AC_SUBST([DEFINES])
 166 case "$host_os" in
 167 linux*|*-gnu*|gnu*)
 168     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 169     ;;
 170 solaris*)
 171     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 172     ;;
 173 cygwin*)
 174     DEFINES="$DEFINES -DPTHREADS"
 175     ;;
 176 esac
 177
 178 dnl Add flags for gcc and g++
 179 if test "x$GCC" = xyes; then
 180     CFLAGS="$CFLAGS -Wall -std=c99"
 181
 182     # Enable -Werror=implicit-function-declaration and
 183     # -Werror=missing-prototypes, if available, or otherwise, just
 184     # -Wmissing-prototypes.  This is particularly useful to avoid
 185     # generating a loadable driver module that has undefined symbols.
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 188     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 189     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 191                    AC_MSG_RESULT([yes]),
 192                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 193                     AC_MSG_RESULT([no])]);
 194
 195     # Enable -fvisibility=hidden if using a gcc that supports it
 196     save_CFLAGS="$CFLAGS"
 197     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 198     VISIBILITY_CFLAGS="-fvisibility=hidden"
 199     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 200     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 201                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 202
 203     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 204     CFLAGS=$save_CFLAGS
 205
 206     # Work around aliasing bugs - developers should comment this out
 207     CFLAGS="$CFLAGS -fno-strict-aliasing"
 208
 209     # gcc's builtin memcmp is slower than glibc's
 210     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 211     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 212 fi
 213 if test "x$GXX" = xyes; then
 214     CXXFLAGS="$CXXFLAGS -Wall"
 215
 216     # Enable -fvisibility=hidden if using a gcc that supports it
 217     save_CXXFLAGS="$CXXFLAGS"
 218     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 219     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 220     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 221     AC_LANG_PUSH([C++])
 222     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 223                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 224     AC_LANG_POP([C++])
 225
 226     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 227     CXXFLAGS=$save_CXXFLAGS
 228
 229     # Work around aliasing bugs - developers should comment this out
 230     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 231
 232     # gcc's builtin memcmp is slower than glibc's
 233     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 234     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 235 fi
 236
 237 dnl even if the compiler appears to support it, using visibility attributes isn't
 238 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 239 case "$host_os" in
 240 cygwin*)
 241     VISIBILITY_CFLAGS=""
 242     VISIBILITY_CXXFLAGS=""
 243     ;;
 244 esac
 245
 246 AC_SUBST([VISIBILITY_CFLAGS])
 247 AC_SUBST([VISIBILITY_CXXFLAGS])
 248
 249 dnl These should be unnecessary, but let the user set them if they want
 250 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 251     Default is to use CFLAGS.])
 252 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 253     compiler. Default is to use CFLAGS.])
 254 AC_SUBST([OPT_FLAGS])
 255 AC_SUBST([ARCH_FLAGS])
 256
 257 dnl
 258 dnl Hacks to enable 32 or 64 bit build
 259 dnl
 260 AC_ARG_ENABLE([32-bit],
 261     [AS_HELP_STRING([--enable-32-bit],
 262         [build 32-bit libraries @<:@default=auto@:>@])],
 263     [enable_32bit="$enableval"],
 264     [enable_32bit=auto]
 265 )
 266 if test "x$enable_32bit" = xyes; then
 267     if test "x$GCC" = xyes; then
 268         CFLAGS="$CFLAGS -m32"
 269         ARCH_FLAGS="$ARCH_FLAGS -m32"
 270         CCASFLAGS="$CCASFLAGS -m32"
 271     fi
 272     if test "x$GXX" = xyes; then
 273         CXXFLAGS="$CXXFLAGS -m32"
 274     fi
 275 fi
 276 AC_ARG_ENABLE([64-bit],
 277     [AS_HELP_STRING([--enable-64-bit],
 278         [build 64-bit libraries @<:@default=auto@:>@])],
 279     [enable_64bit="$enableval"],
 280     [enable_64bit=auto]
 281 )
 282 if test "x$enable_64bit" = xyes; then
 283     if test "x$GCC" = xyes; then
 284         CFLAGS="$CFLAGS -m64"
 285     fi
 286     if test "x$GXX" = xyes; then
 287         CXXFLAGS="$CXXFLAGS -m64"
 288     fi
 289 fi
 290
 291 dnl Can't have static and shared libraries, default to static if user
 292 dnl explicitly requested. If both disabled, set to static since shared
 293 dnl was explicitly requested.
 294 case "x$enable_static$enable_shared" in
 295 xyesyes )
 296     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 297     enable_shared=no
 298     ;;
 299 xnono )
 300     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 301     enable_static=yes
 302     ;;
 303 esac
 304
 305 dnl
 306 dnl mklib options
 307 dnl
 308 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 309 if test "$enable_static" = yes; then
 310     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 311 fi
 312 AC_SUBST([MKLIB_OPTIONS])
 313
 314 dnl
 315 dnl other compiler options
 316 dnl
 317 AC_ARG_ENABLE([debug],
 318     [AS_HELP_STRING([--enable-debug],
 319         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 320     [enable_debug="$enableval"],
 321     [enable_debug=no]
 322 )
 323 if test "x$enable_debug" = xyes; then
 324     DEFINES="$DEFINES -DDEBUG"
 325     if test "x$GCC" = xyes; then
 326         CFLAGS="$CFLAGS -g"
 327     fi
 328     if test "x$GXX" = xyes; then
 329         CXXFLAGS="$CXXFLAGS -g"
 330     fi
 331 fi
 332
 333 dnl
 334 dnl library names
 335 dnl
 336 LIB_PREFIX_GLOB='lib'
 337 LIB_VERSION_SEPARATOR='.'
 338 if test "$enable_static" = yes; then
 339     LIB_EXTENSION='a'
 340 else
 341     case "$host_os" in
 342     darwin* )
 343         LIB_EXTENSION='dylib' ;;
 344     cygwin* )
 345         dnl prefix can be 'cyg' or 'lib'
 346         LIB_PREFIX_GLOB='???'
 347         LIB_VERSION_SEPARATOR='-'
 348         LIB_EXTENSION='dll' ;;
 349     aix* )
 350         LIB_EXTENSION='a' ;;
 351     * )
 352         LIB_EXTENSION='so' ;;
 353     esac
 354 fi
 355 AC_ARG_WITH([gl-lib-name],
 356   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 357     [specify GL library name @<:@default=GL@:>@])],
 358   [GL_LIB=$withval],
 359   [GL_LIB=GL])
 360 AC_ARG_WITH([glu-lib-name],
 361   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 362     [specify GLU library name @<:@default=GLU@:>@])],
 363   [GLU_LIB=$withval],
 364   [GLU_LIB=GLU])
 365 AC_ARG_WITH([osmesa-lib-name],
 366   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 367     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 368   [OSMESA_LIB=$withval],
 369   [OSMESA_LIB=OSMesa])
 370 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 371 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 372 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 373
 374 dnl
 375 dnl Mangled Mesa support
 376 dnl
 377 AC_ARG_ENABLE([mangling],
 378   [AS_HELP_STRING([--enable-mangling],
 379     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 380   [enable_mangling="${enableval}"],
 381   [enable_mangling=no]
 382 )
 383 if test "x${enable_mangling}" = "xyes" ; then
 384   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 385   GL_LIB="Mangled${GL_LIB}"
 386   GLU_LIB="Mangled${GLU_LIB}"
 387   OSMESA_LIB="Mangled${OSMESA_LIB}"
 388 fi
 389 AC_SUBST([GL_LIB])
 390 AC_SUBST([GLU_LIB])
 391 AC_SUBST([OSMESA_LIB])
 392 AM_CONDITIONAL(HAVE_MANGLED_GL, test "x${enable_mangling}" = "xyes")
 393
 394 dnl
 395 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 396 dnl
 397 AC_ARG_ENABLE([texture-float],
 398     [AS_HELP_STRING([--enable-texture-float],
 399         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 400     [enable_texture_float="$enableval"],
 401     [enable_texture_float=no]
 402 )
 403 if test "x$enable_texture_float" = xyes; then
 404     AC_MSG_WARN([Floating-point textures enabled.])
 405     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 406     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 407 fi
 408
 409 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 410 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 411 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 412 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 413 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 414 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 415 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 416 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 417
 418 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 419 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 420 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 421 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 422 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 423 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 424 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 425 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 426 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 427
 428 AC_SUBST([GL_LIB_NAME])
 429 AC_SUBST([GLU_LIB_NAME])
 430 AC_SUBST([OSMESA_LIB_NAME])
 431 AC_SUBST([EGL_LIB_NAME])
 432 AC_SUBST([GLESv1_CM_LIB_NAME])
 433 AC_SUBST([GLESv2_LIB_NAME])
 434 AC_SUBST([VG_LIB_NAME])
 435 AC_SUBST([GLAPI_LIB_NAME])
 436
 437 AC_SUBST([GL_LIB_GLOB])
 438 AC_SUBST([GLU_LIB_GLOB])
 439 AC_SUBST([OSMESA_LIB_GLOB])
 440 AC_SUBST([EGL_LIB_GLOB])
 441 AC_SUBST([GLESv1_CM_LIB_GLOB])
 442 AC_SUBST([GLESv2_LIB_GLOB])
 443 AC_SUBST([VG_LIB_GLOB])
 444 AC_SUBST([GLAPI_LIB_GLOB])
 445
 446 dnl
 447 dnl Arch/platform-specific settings
 448 dnl
 449 AC_ARG_ENABLE([asm],
 450     [AS_HELP_STRING([--disable-asm],
 451         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 452     [enable_asm="$enableval"],
 453     [enable_asm=yes]
 454 )
 455 asm_arch=""
 456 MESA_ASM_FILES=""
 457 GLAPI_ASM_SOURCES=""
 458 AC_MSG_CHECKING([whether to enable assembly])
 459 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 460 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 461 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 462     case "$host_cpu" in
 463     i?86 | x86_64)
 464         enable_asm=no
 465         AC_MSG_RESULT([no, cross compiling])
 466         ;;
 467     esac
 468 fi
 469 # check for supported arches
 470 if test "x$enable_asm" = xyes; then
 471     case "$host_cpu" in
 472     i?86)
 473         case "$host_os" in
 474         linux* | *freebsd* | dragonfly* | *netbsd*)
 475             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 476             ;;
 477         esac
 478         ;;
 479     x86_64)
 480         case "$host_os" in
 481         linux* | *freebsd* | dragonfly* | *netbsd*)
 482             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 483             ;;
 484         esac
 485         ;;
 486     powerpc)
 487         case "$host_os" in
 488         linux*)
 489             asm_arch=ppc
 490             ;;
 491         esac
 492         ;;
 493     sparc*)
 494         case "$host_os" in
 495         linux*)
 496             asm_arch=sparc
 497             ;;
 498         esac
 499         ;;
 500     esac
 501
 502     case "$asm_arch" in
 503     x86)
 504         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 505         MESA_ASM_FILES='$(X86_FILES)'
 506         GLAPI_ASM_SOURCES='$(X86_API)'
 507         AC_MSG_RESULT([yes, x86])
 508         ;;
 509     x86_64)
 510         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 511         MESA_ASM_FILES='$(X86_64_FILES)'
 512         GLAPI_ASM_SOURCES='$(X86-64_API)'
 513         AC_MSG_RESULT([yes, x86_64])
 514         ;;
 515     sparc)
 516         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 517         MESA_ASM_FILES='$(SPARC_FILES)'
 518         GLAPI_ASM_SOURCES='$(SPARC_API)'
 519         AC_MSG_RESULT([yes, sparc])
 520         ;;
 521     *)
 522         AC_MSG_RESULT([no, platform not supported])
 523         ;;
 524     esac
 525 fi
 526 AC_SUBST([MESA_ASM_FILES])
 527 AC_SUBST([GLAPI_ASM_SOURCES])
 528
 529 dnl PIC code macro
 530 MESA_PIC_FLAGS
 531
 532 dnl Check to see if dlopen is in default libraries (like Solaris, which
 533 dnl has it in libc), or if libdl is needed to get it.
 534 AC_CHECK_FUNC([dlopen], [],
 535     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 536 AC_SUBST([DLOPEN_LIBS])
 537
 538 dnl See if posix_memalign is available
 539 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 540
 541 dnl SELinux awareness.
 542 AC_ARG_ENABLE([selinux],
 543     [AS_HELP_STRING([--enable-selinux],
 544         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 545     [MESA_SELINUX="$enableval"],
 546     [MESA_SELINUX=no])
 547 if test "x$enable_selinux" = "xyes"; then
 548     AC_CHECK_HEADER([selinux/selinux.h],[],
 549                     [AC_MSG_ERROR([SELinux headers not found])])
 550     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 551                  [AC_MSG_ERROR([SELinux library not found])])
 552     SELINUX_LIBS="-lselinux"
 553     DEFINES="$DEFINES -DMESA_SELINUX"
 554 fi
 555
 556 dnl Options for APIs
 557 AC_ARG_ENABLE([opengl],
 558     [AS_HELP_STRING([--disable-opengl],
 559         [disable support for standard OpenGL API @<:@default=no@:>@])],
 560     [enable_opengl="$enableval"],
 561     [enable_opengl=yes])
 562 AC_ARG_ENABLE([gles1],
 563     [AS_HELP_STRING([--enable-gles1],
 564         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 565     [enable_gles1="$enableval"],
 566     [enable_gles1=no])
 567 AC_ARG_ENABLE([gles2],
 568     [AS_HELP_STRING([--enable-gles2],
 569         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 570     [enable_gles2="$enableval"],
 571     [enable_gles2=no])
 572 AC_ARG_ENABLE([openvg],
 573     [AS_HELP_STRING([--enable-openvg],
 574         [enable support for OpenVG API @<:@default=no@:>@])],
 575     [enable_openvg="$enableval"],
 576     [enable_openvg=no])
 577
 578 AC_ARG_ENABLE([dri],
 579     [AS_HELP_STRING([--enable-dri],
 580         [enable DRI modules @<:@default=auto@:>@])],
 581     [enable_dri="$enableval"],
 582     [enable_dri=auto])
 583 AC_ARG_ENABLE([glx],
 584     [AS_HELP_STRING([--enable-glx],
 585         [enable GLX library @<:@default=auto@:>@])],
 586     [enable_glx="$enableval"],
 587     [enable_glx=auto])
 588 AC_ARG_ENABLE([osmesa],
 589     [AS_HELP_STRING([--enable-osmesa],
 590         [enable OSMesa library @<:@default=auto@:>@])],
 591     [enable_osmesa="$enableval"],
 592     [enable_osmesa=auto])
 593 AC_ARG_ENABLE([egl],
 594     [AS_HELP_STRING([--disable-egl],
 595         [disable EGL library @<:@default=enabled@:>@])],
 596     [enable_egl="$enableval"],
 597     [enable_egl=yes])
 598
 599 AC_ARG_ENABLE([xorg],
 600     [AS_HELP_STRING([--enable-xorg],
 601         [enable support for X.Org DDX API @<:@default=no@:>@])],
 602     [enable_xorg="$enableval"],
 603     [enable_xorg=no])
 604 AC_ARG_ENABLE([xa],
 605     [AS_HELP_STRING([--enable-xa],
 606         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 607     [enable_xa="$enableval"],
 608     [enable_xa=no])
 609 AC_ARG_ENABLE([d3d1x],
 610     [AS_HELP_STRING([--enable-d3d1x],
 611         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 612     [enable_d3d1x="$enableval"],
 613     [enable_d3d1x=no])
 614 AC_ARG_ENABLE([gbm],
 615    [AS_HELP_STRING([--enable-gbm],
 616          [enable gbm library @<:@default=auto@:>@])],
 617    [enable_gbm="$enableval"],
 618    [enable_gbm=auto])
 619
 620 AC_ARG_ENABLE([xvmc],
 621    [AS_HELP_STRING([--enable-xvmc],
 622          [enable xvmc library @<:@default=auto@:>@])],
 623    [enable_xvmc="$enableval"],
 624    [enable_xvmc=auto])
 625 AC_ARG_ENABLE([vdpau],
 626    [AS_HELP_STRING([--enable-vdpau],
 627          [enable vdpau library @<:@default=auto@:>@])],
 628    [enable_vdpau="$enableval"],
 629    [enable_vdpau=auto])
 630 AC_ARG_ENABLE([va],
 631    [AS_HELP_STRING([--enable-va],
 632          [enable va library @<:@default=auto@:>@])],
 633    [enable_va="$enableval"],
 634    [enable_va=auto])
 635 AC_ARG_ENABLE([opencl],
 636    [AS_HELP_STRING([--enable-opencl],
 637          [enable OpenCL library @<:@default=no@:>@])],
 638    [enable_opencl="$enableval"],
 639    [enable_opencl=no])
 640 AC_ARG_ENABLE([xlib_glx],
 641     [AS_HELP_STRING([--enable-xlib-glx],
 642         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 643     [enable_xlib_glx="$enableval"],
 644     [enable_xlib_glx=auto])
 645 AC_ARG_ENABLE([gallium_egl],
 646     [AS_HELP_STRING([--enable-gallium-egl],
 647         [enable optional EGL state tracker (not required
 648          for EGL support in Gallium with OpenGL and OpenGL ES)
 649          @<:@default=disable@:>@])],
 650     [enable_gallium_egl="$enableval"],
 651     [enable_gallium_egl=no])
 652 AC_ARG_ENABLE([gallium_gbm],
 653     [AS_HELP_STRING([--enable-gallium-gbm],
 654         [enable optional gbm state tracker (not required for
 655          gbm support in Gallium)
 656          @<:@default=auto@:>@])],
 657     [enable_gallium_gbm="$enableval"],
 658     [enable_gallium_gbm=auto])
 659
 660 AC_ARG_ENABLE([r600-llvm-compiler],
 661     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 662         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 663     [enable_r600_llvm="$enableval"],
 664     [enable_r600_llvm=no])
 665
 666 AC_ARG_ENABLE([gallium_tests],
 667     [AS_HELP_STRING([--enable-gallium-tests],
 668         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 669     [enable_gallium_tests="$enableval"],
 670     [enable_gallium_tests=no])
 671
 672 # Option for Gallium drivers
 673 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 674
 675 AC_ARG_WITH([gallium-drivers],
 676     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 677         [comma delimited Gallium drivers list, e.g.
 678         "i915,nouveau,r300,r600,svga,swrast"
 679         @<:@default=r300,r600,swrast@:>@])],
 680     [with_gallium_drivers="$withval"],
 681     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 682
 683 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 684 # here so that the script doesn't choke on an unknown driver name later.
 685 case "$with_gallium_drivers" in
 686     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 687     no) with_gallium_drivers='' ;;
 688 esac
 689
 690 if test "x$enable_opengl" = xno -a \
 691         "x$enable_gles1" = xno -a \
 692         "x$enable_gles2" = xno -a \
 693         "x$enable_openvg" = xno -a \
 694         "x$enable_xorg" = xno -a \
 695         "x$enable_xa" = xno -a \
 696         "x$enable_d3d1x" = xno -a \
 697         "x$enable_xvmc" = xno -a \
 698         "x$enable_vdpau" = xno -a \
 699         "x$enable_va" = xno -a \
 700         "x$enable_opencl" = xno; then
 701     AC_MSG_ERROR([at least one API should be enabled])
 702 fi
 703
 704 API_DEFINES=""
 705 if test "x$enable_opengl" = xno; then
 706     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 707 else
 708     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 709 fi
 710 if test "x$enable_gles1" = xyes; then
 711     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 712 fi
 713 if test "x$enable_gles2" = xyes; then
 714     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 715 fi
 716 AC_SUBST([API_DEFINES])
 717
 718 AC_ARG_ENABLE([shared-glapi],
 719     [AS_HELP_STRING([--enable-shared-glapi],
 720         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 721     [enable_shared_glapi="$enableval"],
 722     [enable_shared_glapi=no])
 723
 724 SHARED_GLAPI="0"
 725 if test "x$enable_shared_glapi" = xyes; then
 726     SHARED_GLAPI="1"
 727     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 728     # the remap table)
 729     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 730     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 731 fi
 732 AC_SUBST([SHARED_GLAPI])
 733 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 734
 735 dnl
 736 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 737 dnl More later: fbdev, ...
 738 dnl
 739 default_driver="xlib"
 740
 741 case "$host_os" in
 742 linux*)
 743     case "$host_cpu" in
 744     i*86|x86_64|powerpc*|sparc*|ia64*) default_driver="dri";;
 745     esac
 746     ;;
 747 *freebsd* | dragonfly* | *netbsd*)
 748     case "$host_cpu" in
 749     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 750     esac
 751     ;;
 752 esac
 753
 754 if test "x$enable_opengl" = xno; then
 755     default_driver="no"
 756 fi
 757
 758 AC_ARG_WITH([driver],
 759     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 760     [mesa_driver="$withval"],
 761     [mesa_driver=auto])
 762 dnl Check for valid option
 763 case "x$mesa_driver" in
 764 xxlib|xdri|xosmesa|xno)
 765     if test "x$enable_dri" != xauto -o \
 766             "x$enable_glx" != xauto -o \
 767             "x$enable_osmesa" != xauto -o \
 768             "x$enable_xlib_glx" != xauto; then
 769         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 770     fi
 771     ;;
 772 xauto)
 773     mesa_driver="$default_driver"
 774     ;;
 775 *)
 776     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 777     ;;
 778 esac
 779
 780 # map $mesa_driver to APIs
 781 if test "x$enable_dri" = xauto; then
 782     case "x$mesa_driver" in
 783     xdri) enable_dri=yes ;;
 784     *)    enable_dri=no ;;
 785     esac
 786 fi
 787
 788 if test "x$enable_glx" = xauto; then
 789     case "x$mesa_driver" in
 790     xdri|xxlib) enable_glx=yes ;;
 791     *)          enable_glx=no ;;
 792     esac
 793 fi
 794
 795 if test "x$enable_osmesa" = xauto; then
 796     case "x$mesa_driver" in
 797     xxlib|xosmesa) enable_osmesa=yes ;;
 798     *)             enable_osmesa=no ;;
 799     esac
 800 fi
 801
 802 if test "x$enable_xlib_glx" = xauto; then
 803     case "x$mesa_driver" in
 804     xxlib) enable_xlib_glx=yes ;;
 805     *)     enable_xlib_glx=no ;;
 806     esac
 807 fi
 808
 809 if test "x$enable_glx" = xno; then
 810     enable_xlib_glx=no
 811 fi
 812
 813 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 814
 815 dnl
 816 dnl Driver specific build directories
 817 dnl
 818
 819 dnl this variable will be prepended to SRC_DIRS and is not exported
 820 CORE_DIRS=""
 821
 822 SRC_DIRS="gtest"
 823 GLU_DIRS="sgi"
 824 GALLIUM_DIRS="auxiliary drivers state_trackers"
 825 GALLIUM_TARGET_DIRS=""
 826 GALLIUM_WINSYS_DIRS="sw"
 827 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 828 GALLIUM_STATE_TRACKERS_DIRS=""
 829
 830 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 831 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 832 x*yes*)
 833     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 834     ;;
 835 esac
 836
 837 # build glapi if OpenGL is enabled
 838 if test "x$enable_opengl" = xyes; then
 839     CORE_DIRS="$CORE_DIRS mapi/glapi"
 840 fi
 841
 842 # build es1api if OpenGL ES 1.x is enabled
 843 if test "x$enable_gles1" = xyes; then
 844     CORE_DIRS="$CORE_DIRS mapi/es1api"
 845 fi
 846
 847 # build es2api if OpenGL ES 2.x is enabled
 848 if test "x$enable_gles2" = xyes; then
 849     CORE_DIRS="$CORE_DIRS mapi/es2api"
 850 fi
 851
 852 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 853 case "x$enable_opengl$enable_gles1$enable_gles2" in
 854 x*yes*)
 855     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 856     ;;
 857 esac
 858
 859 case "x$enable_glx$enable_xlib_glx" in
 860 xyesyes)
 861     DRIVER_DIRS="$DRIVER_DIRS x11"
 862     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 863     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 864     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 865     HAVE_WINSYS_XLIB="yes"
 866     ;;
 867 xyesno)
 868     # DRI-based GLX
 869     SRC_DIRS="$SRC_DIRS glx"
 870     ;;
 871 esac
 872
 873 if test "x$enable_dri" = xyes; then
 874     DRIVER_DIRS="$DRIVER_DIRS dri"
 875
 876     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 877     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 878     HAVE_ST_DRI="yes"
 879 fi
 880
 881 if test "x$enable_osmesa" = xyes; then
 882     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 883 fi
 884
 885 AC_SUBST([SRC_DIRS])
 886 AC_SUBST([GLU_DIRS])
 887 AC_SUBST([DRIVER_DIRS])
 888 AC_SUBST([GALLIUM_DIRS])
 889 AC_SUBST([GALLIUM_TARGET_DIRS])
 890 AC_SUBST([GALLIUM_WINSYS_DIRS])
 891 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 892 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 893 AC_SUBST([MESA_LLVM])
 894
 895 # Check for libdrm
 896 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 897                   [have_libdrm=yes], [have_libdrm=no])
 898
 899 if test "x$enable_dri" = xyes; then
 900     # DRI must be shared, I think
 901     if test "$enable_static" = yes; then
 902         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 903     fi
 904
 905     # not a hard requirement as swrast does not depend on it
 906     if test "x$have_libdrm" = xyes; then
 907         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 908     fi
 909 fi
 910
 911 dnl
 912 dnl Find out if X is available. The variable have_x is set if libX11 is
 913 dnl found to mimic AC_PATH_XTRA.
 914 dnl
 915 if test -n "$PKG_CONFIG"; then
 916     AC_MSG_CHECKING([pkg-config files for X11 are available])
 917     PKG_CHECK_EXISTS([x11],[
 918         x11_pkgconfig=yes
 919         have_x=yes
 920         ],[
 921         x11_pkgconfig=no
 922     ])
 923     AC_MSG_RESULT([$x11_pkgconfig])
 924 else
 925     x11_pkgconfig=no
 926 fi
 927 dnl Use the autoconf macro if no pkg-config files
 928 if test "$x11_pkgconfig" = yes; then
 929     PKG_CHECK_MODULES([X11], [x11])
 930 else
 931     AC_PATH_XTRA
 932     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 933     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 934     AC_SUBST([X11_CFLAGS])
 935     AC_SUBST([X11_LIBS])
 936 fi
 937
 938 dnl Try to tell the user that the --x-* options are only used when
 939 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 940 m4_divert_once([HELP_BEGIN],
 941 [These options are only used when the X libraries cannot be found by the
 942 pkg-config utility.])
 943
 944 dnl We need X for xlib and dri, so bomb now if it's not found
 945 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 946     AC_MSG_ERROR([X11 development libraries needed for GLX])
 947 fi
 948
 949 if test "x$enable_glx" = xyes; then
 950     DEFINES="$DEFINES -DUSE_XCB"
 951 fi
 952
 953 dnl Direct rendering or just indirect rendering
 954 case "$host_os" in
 955 gnu*)
 956     dnl Disable by default on GNU/Hurd
 957     driglx_direct_default="no"
 958     ;;
 959 cygwin*)
 960     dnl Disable by default on cygwin
 961     driglx_direct_default="no"
 962     ;;
 963 *)
 964     driglx_direct_default="yes"
 965     ;;
 966 esac
 967 AC_ARG_ENABLE([driglx-direct],
 968     [AS_HELP_STRING([--disable-driglx-direct],
 969         [enable direct rendering in GLX and EGL for DRI \
 970             @<:@default=auto@:>@])],
 971     [driglx_direct="$enableval"],
 972     [driglx_direct="$driglx_direct_default"])
 973
 974 dnl
 975 dnl libGL configuration per driver
 976 dnl
 977 case "x$enable_glx$enable_xlib_glx" in
 978 xyesyes)
 979     # Xlib-based GLX
 980     if test "$x11_pkgconfig" = yes; then
 981         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 982         GL_PC_REQ_PRIV="x11 xext"
 983         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 984         GL_LIB_DEPS="$XLIBGL_LIBS"
 985     else
 986         # should check these...
 987         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 988         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 989         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 990         GL_PC_CFLAGS="$X11_INCLUDES"
 991     fi
 992     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 993     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 994     ;;
 995 xyesno)
 996     # DRI-based GLX
 997     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 998     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 999     if test x"$driglx_direct" = xyes; then
1000         if test "x$have_libdrm" != xyes; then
1001             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
1002         fi
1003         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1004         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
1005     fi
1006
1007     # find the DRI deps for libGL
1008     if test "$x11_pkgconfig" = yes; then
1009         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
1010
1011         # add xf86vidmode if available
1012         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1013         if test "$HAVE_XF86VIDMODE" = yes ; then
1014             dri_modules="$dri_modules xxf86vm"
1015         fi
1016
1017         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1018         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1019         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1020         GL_LIB_DEPS="$DRIGL_LIBS"
1021     else
1022         # should check these...
1023         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
1024         if test "x$HAVE_XF86VIDMODE" == xyes; then
1025            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1026         else
1027            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1028         fi
1029         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1030         GL_PC_CFLAGS="$X11_INCLUDES"
1031
1032         # XCB can only be used from pkg-config
1033         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx >= 1.8.1])
1034         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1035         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1036         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1037     fi
1038
1039     # need DRM libs, -lpthread, etc.
1040     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1041     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1042     ;;
1043 esac
1044
1045 # This is outside the case (above) so that it is invoked even for non-GLX
1046 # builds.
1047 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1048
1049 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1050 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1051 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1052 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1053
1054 AC_SUBST([GL_LIB_DEPS])
1055 AC_SUBST([GL_PC_REQ_PRIV])
1056 AC_SUBST([GL_PC_LIB_PRIV])
1057 AC_SUBST([GL_PC_CFLAGS])
1058 AC_SUBST([DRI_PC_REQ_PRIV])
1059 AC_SUBST([GLESv1_CM_LIB_DEPS])
1060 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1061 AC_SUBST([GLESv2_LIB_DEPS])
1062 AC_SUBST([GLESv2_PC_LIB_PRIV])
1063
1064 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1065 AC_SUBST([GLAPI_LIB_DEPS])
1066
1067
1068 dnl Setup default DRI CFLAGS
1069 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1070 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
1071
1072 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1073     DRI_LIB_DEPS="-L\$(TOP)/\$(LIB_DIR) -ldricore$VERSION"
1074     MESA_MODULES="\$(TOP)/\$(LIB_DIR)/libdricore$VERSION.so"
1075     HAVE_DRICORE=yes
1076 fi
1077 AM_CONDITIONAL(HAVE_DRICORE, test x$HAVE_DRICORE = xyes)
1078 AC_SUBST([MESA_MODULES])
1079
1080 AC_SUBST([HAVE_XF86VIDMODE])
1081
1082 dnl
1083 dnl More GLX setup
1084 dnl
1085 case "x$enable_glx$enable_xlib_glx" in
1086 xyesyes)
1087     DEFINES="$DEFINES -DUSE_XSHM"
1088     ;;
1089 xyesno)
1090     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1091     if test "x$driglx_direct" = xyes; then
1092         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1093     fi
1094     ;;
1095 esac
1096
1097 dnl
1098 dnl TLS detection
1099 dnl
1100
1101 AC_ARG_ENABLE([glx-tls],
1102     [AS_HELP_STRING([--enable-glx-tls],
1103         [enable TLS support in GLX @<:@default=disabled@:>@])],
1104     [GLX_USE_TLS="$enableval"],
1105     [GLX_USE_TLS=no])
1106 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1107
1108 AS_IF([test "x$GLX_USE_TLS" = xyes],
1109       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1110
1111 dnl
1112 dnl More DRI setup
1113 dnl
1114 dnl Directory for DRI drivers
1115 AC_ARG_WITH([dri-driverdir],
1116     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1117         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1118     [DRI_DRIVER_INSTALL_DIR="$withval"],
1119     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1120 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1121 dnl Extra search path for DRI drivers
1122 AC_ARG_WITH([dri-searchpath],
1123     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1124         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1125     [DRI_DRIVER_SEARCH_DIR="$withval"],
1126     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1127 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1128 dnl Which drivers to build - default is chosen by platform
1129 AC_ARG_WITH([dri-drivers],
1130     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1131         [comma delimited DRI drivers list, e.g.
1132         "swrast,i965,radeon" @<:@default=auto@:>@])],
1133     [with_dri_drivers="$withval"],
1134     [with_dri_drivers=yes])
1135 if test "x$with_dri_drivers" = x; then
1136     with_dri_drivers=no
1137 fi
1138
1139 dnl If $with_dri_drivers is yes, directories will be added through
1140 dnl platform checks
1141 DRI_DIRS=""
1142 case "$with_dri_drivers" in
1143 no) ;;
1144 yes)
1145     # classic DRI drivers require FEATURE_GL to build
1146     if test "x$enable_opengl" = xyes; then
1147         DRI_DIRS="yes"
1148     fi
1149     ;;
1150 *)
1151     # verify the requested driver directories exist
1152     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1153     for driver in $dri_drivers; do
1154         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1155             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1156     done
1157     DRI_DIRS="$dri_drivers"
1158     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1159         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1160     fi
1161     ;;
1162 esac
1163
1164 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1165 if test "x$enable_dri" = xyes; then
1166     # Platform specific settings and drivers to build
1167     case "$host_os" in
1168     linux*)
1169         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1170         DEFINES="$DEFINES -DHAVE_ALIAS"
1171
1172         case "$host_cpu" in
1173         x86_64)
1174             if test "x$DRI_DIRS" = "xyes"; then
1175                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1176             fi
1177             ;;
1178         powerpc*)
1179             # Build only the drivers for cards that exist on PowerPC.
1180             if test "x$DRI_DIRS" = "xyes"; then
1181                 DRI_DIRS="r200 radeon swrast"
1182             fi
1183             ;;
1184         sparc*)
1185             # Build only the drivers for cards that exist on sparc
1186             if test "x$DRI_DIRS" = "xyes"; then
1187                 DRI_DIRS="r200 radeon swrast"
1188             fi
1189             ;;
1190         esac
1191         ;;
1192     freebsd* | dragonfly* | *netbsd*)
1193         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1194         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1195
1196         if test "x$DRI_DIRS" = "xyes"; then
1197             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1198         fi
1199         ;;
1200     gnu*)
1201         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1202         DEFINES="$DEFINES -DHAVE_ALIAS"
1203         ;;
1204     solaris*)
1205         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1206         ;;
1207     cygwin*)
1208         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1209         if test "x$DRI_DIRS" = "xyes"; then
1210             DRI_DIRS="swrast"
1211         fi
1212         ;;
1213     esac
1214
1215     # default drivers
1216     if test "x$DRI_DIRS" = "xyes"; then
1217         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1218     fi
1219
1220     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1221
1222     # Check for expat
1223     if test "x$enable_dri" = xyes; then
1224         EXPAT_INCLUDES=""
1225         EXPAT_LIB=-lexpat
1226         AC_ARG_WITH([expat],
1227             [AS_HELP_STRING([--with-expat=DIR],
1228                 [expat install directory])],[
1229             EXPAT_INCLUDES="-I$withval/include"
1230             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1231             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1232             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1233             ])
1234         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1235         save_LIBS="$LIBS"
1236         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1237             [AC_MSG_ERROR([Expat required for DRI.])])
1238         LIBS="$save_LIBS"
1239     fi
1240
1241     # if we are building any dri driver other than swrast ...
1242     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1243         # ... libdrm is required
1244         if test "x$have_libdrm" != xyes; then
1245             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1246         fi
1247         # ... and build dricommon
1248         HAVE_COMMON_DRI=yes
1249     fi
1250
1251     # put all the necessary libs together
1252     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1253 fi
1254 AC_SUBST([DRI_DIRS])
1255 AC_SUBST([EXPAT_INCLUDES])
1256 AC_SUBST([DRI_LIB_DEPS])
1257
1258 case $DRI_DIRS in
1259 *i915*|*i965*)
1260     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1261
1262     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1263         case $d in
1264         i915)
1265             HAVE_I915_DRI=yes;
1266             ;;
1267         i965)
1268             HAVE_I965_DRI=yes;
1269             ;;
1270         esac
1271     done
1272
1273     ;;
1274 esac
1275
1276 case $DRI_DIRS in
1277 *nouveau*)
1278     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1279     HAVE_NOUVEAU_DRI=yes;
1280     ;;
1281 esac
1282
1283 case $DRI_DIRS in
1284 *radeon*|*r200*)
1285     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1286
1287     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1288         case $d in
1289         radeon)
1290             HAVE_RADEON_DRI=yes;
1291             ;;
1292         r200)
1293             HAVE_R200_DRI=yes;
1294             ;;
1295         esac
1296     done
1297
1298     ;;
1299 esac
1300
1301 case $DRI_DIRS in
1302 *swrast*)
1303     HAVE_SWRAST_DRI=yes;
1304     ;;
1305 esac
1306
1307 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1308 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1309 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1310 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1311 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1312 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1313 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1314
1315 dnl
1316 dnl OSMesa configuration
1317 dnl
1318
1319 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1320 AC_ARG_WITH([osmesa-bits],
1321     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1322         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1323     [osmesa_bits="$withval"],
1324     [osmesa_bits=8])
1325 if test "x$osmesa_bits" != x8; then
1326     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1327         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1328         osmesa_bits=8
1329     fi
1330 fi
1331 case "x$osmesa_bits" in
1332 x8)
1333     OSMESA_LIB="${OSMESA_LIB}"
1334     ;;
1335 x16|x32)
1336     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1337     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1338     ;;
1339 *)
1340     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1341     ;;
1342 esac
1343
1344 if test "x$enable_osmesa" = xyes; then
1345     # only link libraries with osmesa if shared
1346     if test "$enable_static" = no; then
1347         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1348     else
1349         OSMESA_LIB_DEPS=""
1350     fi
1351     OSMESA_MESA_DEPS=""
1352     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1353 fi
1354
1355 OSMESA_VERSION=`echo "$VERSION" | $SED 's/\./:/g'`
1356
1357 AC_SUBST([OSMESA_LIB_DEPS])
1358 AC_SUBST([OSMESA_MESA_DEPS])
1359 AC_SUBST([OSMESA_PC_REQ])
1360 AC_SUBST([OSMESA_PC_LIB_PRIV])
1361 AC_SUBST([OSMESA_VERSION])
1362
1363 dnl
1364 dnl gbm configuration
1365 dnl
1366 if test "x$enable_gbm" = xauto; then
1367     case "$with_egl_platforms" in
1368         *drm*)
1369             enable_gbm=yes ;;
1370          *)
1371             enable_gbm=no ;;
1372     esac
1373 fi
1374 if test "x$enable_gbm" = xyes; then
1375     SRC_DIRS="$SRC_DIRS gbm"
1376
1377     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1378                       AC_MSG_ERROR([gbm needs udev]))
1379
1380     if test "x$enable_dri" = xyes; then
1381         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1382         if test "$SHARED_GLAPI" -eq 0; then
1383             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1384         fi
1385     fi
1386 fi
1387 GBM_PC_REQ_PRIV="libudev"
1388 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1389 AC_SUBST([GBM_PC_REQ_PRIV])
1390 AC_SUBST([GBM_PC_LIB_PRIV])
1391
1392 dnl
1393 dnl EGL configuration
1394 dnl
1395 EGL_CLIENT_APIS=""
1396
1397 if test "x$enable_egl" = xyes; then
1398     SRC_DIRS="$SRC_DIRS egl"
1399     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1400
1401     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1402
1403     if test "$enable_static" != yes; then
1404         # build egl_glx when libGL is built
1405         if test "x$enable_glx" = xyes; then
1406             HAVE_EGL_DRIVER_GLX=1
1407         fi
1408
1409         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1410                           [have_libudev=yes],[have_libudev=no])
1411         if test "$have_libudev" = yes; then
1412             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1413         fi
1414
1415         if test "x$enable_dri" = xyes; then
1416             HAVE_EGL_DRIVER_DRI2=1
1417         fi
1418
1419     fi
1420 fi
1421 AC_SUBST([EGL_LIB_DEPS])
1422
1423 dnl
1424 dnl EGL Gallium configuration
1425 dnl
1426 if test "x$enable_gallium_egl" = xyes; then
1427     if test "x$with_gallium_drivers" = x; then
1428         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1429     fi
1430     if test "x$enable_egl" = xno; then
1431         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1432     fi
1433     if test "x$have_libdrm" != xyes; then
1434         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1435     fi
1436
1437     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1438     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1439     HAVE_ST_EGL="yes"
1440 fi
1441
1442 dnl
1443 dnl gbm Gallium configuration
1444 dnl
1445 if test "x$enable_gallium_gbm" = xauto; then
1446     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1447         yesyesyes*drm*)
1448             enable_gallium_gbm=yes ;;
1449          *)
1450             enable_gallium_gbm=no ;;
1451     esac
1452 fi
1453 if test "x$enable_gallium_gbm" = xyes; then
1454     if test "x$with_gallium_drivers" = x; then
1455         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1456     fi
1457     if test "x$enable_gbm" = xno; then
1458         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1459     fi
1460     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1461     if test "x$enable_dri" = xno; then
1462         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1463     fi
1464
1465     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1466     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1467     HAVE_ST_GBM="yes"
1468     enable_gallium_loader=yes
1469 fi
1470
1471 dnl
1472 dnl X.Org DDX configuration
1473 dnl
1474 if test "x$enable_xorg" = xyes; then
1475     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1476     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1477     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1478     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1479         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1480         HAVE_XEXTPROTO_71="no")
1481     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1482     HAVE_ST_XORG=yes
1483 fi
1484
1485 dnl
1486 dnl XA configuration
1487 dnl
1488 if test "x$enable_xa" = xyes; then
1489 AC_PROG_AWK
1490 AC_PROG_GREP
1491 AC_CHECK_PROG(NM, nm, "nm")
1492 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1493 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1494 enable_xa=no
1495 fi
1496 fi
1497 if test "x$enable_xa" = xyes; then
1498     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1499     HAVE_ST_XA=yes
1500     AC_SUBST(AWK)
1501     AC_SUBST(GREP)
1502     AC_SUBST(NM)
1503 fi
1504
1505 dnl
1506 dnl OpenVG configuration
1507 dnl
1508 VG_LIB_DEPS=""
1509
1510 if test "x$enable_openvg" = xyes; then
1511     if test "x$enable_egl" = xno; then
1512         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1513     fi
1514     if test "x$with_gallium_drivers" = x; then
1515         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1516     fi
1517     if test "x$enable_gallium_egl" = xno; then
1518         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1519     fi
1520
1521     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1522     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1523     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1524     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1525     HAVE_ST_VEGA=yes
1526 fi
1527
1528 dnl
1529 dnl D3D1X configuration
1530 dnl
1531
1532 if test "x$enable_d3d1x" = xyes; then
1533     if test "x$with_gallium_drivers" = x; then
1534         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1535     fi
1536
1537     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1538     HAVE_ST_D3D1X=yes
1539 fi
1540
1541 dnl
1542 dnl Gallium G3DVL configuration
1543 dnl
1544 AC_ARG_ENABLE([gallium-g3dvl],
1545     [AS_HELP_STRING([--enable-gallium-g3dvl],
1546         [build gallium g3dvl @<:@default=disabled@:>@])],
1547     [enable_gallium_g3dvl="$enableval"],
1548     [enable_gallium_g3dvl=no])
1549 if test "x$enable_gallium_g3dvl" = xyes; then
1550     if test "x$with_gallium_drivers" = x; then
1551         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1552     fi
1553
1554     if test "x$enable_xvmc" = xauto; then
1555         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1556     fi
1557
1558     if test "x$enable_vdpau" = xauto; then
1559         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1560     fi
1561
1562     if test "x$enable_va" = xauto; then
1563         #don't enable vaapi state tracker even if package exists
1564         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1565         enable_va=no
1566     fi
1567 fi
1568
1569 if test "x$enable_xvmc" = xyes; then
1570     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1571     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1572     HAVE_ST_XVMC="yes"
1573 fi
1574
1575 if test "x$enable_vdpau" = xyes; then
1576     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1577     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1578     HAVE_ST_VDPAU="yes"
1579 fi
1580
1581 if test "x$enable_va" = xyes; then
1582     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1583     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1584     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1585     HAVE_ST_VA="yes"
1586 fi
1587
1588 dnl
1589 dnl OpenCL configuration
1590 dnl
1591
1592 AC_ARG_WITH([libclc-path],
1593    [AS_HELP_STRING([--with-libclc-path],
1594          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1595    [LIBCLC_PATH="$withval"],
1596    [LIBCLC_PATH=""])
1597
1598 AC_ARG_WITH([clang-libdir],
1599    [AS_HELP_STRING([--with-clang-libdir],
1600          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1601    [CLANG_LIBDIR="$withval"],
1602    [CLANG_LIBDIR=""])
1603
1604 AC_SUBST([LIBCLC_PATH])
1605
1606 if test "x$enable_opencl" = xyes; then
1607     if test "x$with_gallium_drivers" = x; then
1608         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1609     fi
1610
1611     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1612         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1613     fi
1614
1615     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1616     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1617     enable_gallium_loader=yes
1618 fi
1619
1620 dnl
1621 dnl GLU configuration
1622 dnl
1623 AC_ARG_ENABLE([glu],
1624     [AS_HELP_STRING([--disable-glu],
1625         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1626     [enable_glu="$enableval"],
1627     [enable_glu=yes])
1628
1629 if test "x$enable_glu" = xyes; then
1630     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1631         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1632         enable_glu=no
1633     fi
1634 fi
1635
1636 if test "x$enable_glu" = xyes; then
1637     SRC_DIRS="$SRC_DIRS glu"
1638
1639     if test "x$enable_glx" = xno; then
1640         # Link libGLU to libOSMesa instead of libGL
1641         GLU_LIB_DEPS=""
1642         GLU_PC_REQ="osmesa"
1643         if test "$enable_static" = no; then
1644             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1645         else
1646             GLU_MESA_DEPS=""
1647         fi
1648     else
1649         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1650         GLU_PC_REQ="gl"
1651         GLU_PC_LIB_PRIV="-lm"
1652         if test "$enable_static" = no; then
1653             GLU_LIB_DEPS="-lm"
1654             GLU_MESA_DEPS='-l$(GL_LIB)'
1655         else
1656             GLU_LIB_DEPS=""
1657             GLU_MESA_DEPS=""
1658         fi
1659     fi
1660 fi
1661 if test "$enable_static" = no; then
1662     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1663 fi
1664 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1665 AC_SUBST([GLU_LIB_DEPS])
1666 AC_SUBST([GLU_MESA_DEPS])
1667 AC_SUBST([GLU_PC_REQ])
1668 AC_SUBST([GLU_PC_REQ_PRIV])
1669 AC_SUBST([GLU_PC_LIB_PRIV])
1670 AC_SUBST([GLU_PC_CFLAGS])
1671
1672 AC_SUBST([PROGRAM_DIRS])
1673
1674 dnl
1675 dnl Gallium configuration
1676 dnl
1677 if test "x$with_gallium_drivers" != x; then
1678     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1679 fi
1680
1681 AC_SUBST([LLVM_BINDIR])
1682 AC_SUBST([LLVM_CFLAGS])
1683 AC_SUBST([LLVM_CPPFLAGS])
1684 AC_SUBST([LLVM_CXXFLAGS])
1685 AC_SUBST([LLVM_LIBDIR])
1686 AC_SUBST([LLVM_LIBS])
1687 AC_SUBST([LLVM_LDFLAGS])
1688 AC_SUBST([LLVM_INCLUDEDIR])
1689 AC_SUBST([LLVM_VERSION])
1690 AC_SUBST([CLANG_RESOURCE_DIR])
1691
1692 case "x$enable_opengl$enable_gles1$enable_gles2" in
1693 x*yes*)
1694     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1695     ;;
1696 esac
1697
1698 AC_SUBST([VG_LIB_DEPS])
1699 AC_SUBST([EGL_CLIENT_APIS])
1700
1701 dnl
1702 dnl EGL Platforms configuration
1703 dnl
1704 AC_ARG_WITH([egl-platforms],
1705     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1706         [comma delimited native platforms libEGL supports, e.g.
1707         "x11,drm" @<:@default=auto@:>@])],
1708     [with_egl_platforms="$withval"],
1709     [if test "x$enable_egl" = xyes; then
1710         with_egl_platforms="x11"
1711     else
1712         with_egl_platforms=""
1713     fi])
1714
1715 EGL_PLATFORMS=""
1716
1717 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1718     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1719 fi
1720
1721 # Do per-EGL platform setups and checks
1722 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1723 for plat in $egl_platforms; do
1724         case "$plat" in
1725         fbdev|null)
1726                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1727                 ;;
1728
1729         wayland)
1730                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1731                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1732                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1733
1734                 m4_ifdef([WAYLAND_SCANNER_RULES],
1735                          [WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/egl/wayland/wayland-drm/protocol'])])
1736                 ;;
1737
1738         x11)
1739                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1740                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1741                 save_LIBS="$LIBS"
1742                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1743                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1744                 LIBS="$save_LIBS"
1745                 ;;
1746
1747         drm)
1748                 test "x$enable_gbm" = "xno" &&
1749                         AC_MSG_ERROR([EGL platform drm needs gbm])
1750                 ;;
1751
1752         android|gdi)
1753                 ;;
1754
1755         *)
1756                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1757                 ;;
1758         esac
1759
1760         case "$plat$have_libudev" in
1761                 waylandno|drmno)
1762                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1763         esac
1764 done
1765
1766 # libEGL wants to default to the first platform specified in
1767 # ./configure.  parse that here.
1768 if test "x$egl_platforms" != "x"; then
1769     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1770     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1771 else
1772     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1773 fi
1774
1775 EGL_PLATFORMS="$egl_platforms"
1776
1777 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1778 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1779 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1780 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1781 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1782
1783 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1784 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1785
1786 AC_SUBST([EGL_NATIVE_PLATFORM])
1787 AC_SUBST([EGL_PLATFORMS])
1788 AC_SUBST([EGL_CFLAGS])
1789
1790 AC_ARG_WITH([egl-driver-dir],
1791     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1792                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1793     [EGL_DRIVER_INSTALL_DIR="$withval"],
1794     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1795 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1796
1797 AC_ARG_WITH([xorg-driver-dir],
1798     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1799                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1800     [XORG_DRIVER_INSTALL_DIR="$withval"],
1801     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1802 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1803
1804 AC_ARG_WITH([max-width],
1805     [AS_HELP_STRING([--with-max-width=N],
1806                     [Maximum framebuffer width (4096)])],
1807     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1808      AS_IF([test "${withval}" -gt "4096"],
1809            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1810 )
1811 AC_ARG_WITH([max-height],
1812     [AS_HELP_STRING([--with-max-height=N],
1813                     [Maximum framebuffer height (4096)])],
1814     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1815      AS_IF([test "${withval}" -gt "4096"],
1816            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1817 )
1818
1819 dnl
1820 dnl Gallium LLVM
1821 dnl
1822 AC_ARG_ENABLE([gallium-llvm],
1823     [AS_HELP_STRING([--enable-gallium-llvm],
1824         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1825     [enable_gallium_llvm="$enableval"],
1826     [enable_gallium_llvm=auto])
1827
1828 AC_ARG_WITH([llvm-shared-libs],
1829     [AS_HELP_STRING([--with-llvm-shared-libs],
1830         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1831     [with_llvm_shared_libs=yes],
1832     [with_llvm_shared_libs=no])
1833
1834 if test "x$with_gallium_drivers" = x; then
1835     enable_gallium_llvm=no
1836 fi
1837 if test "x$enable_gallium_llvm" = xauto; then
1838     case "$host_cpu" in
1839     i*86|x86_64) enable_gallium_llvm=yes;;
1840     esac
1841 fi
1842 if test "x$enable_gallium_llvm" = xyes; then
1843     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1844
1845     if test "x$LLVM_CONFIG" != xno; then
1846         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1847         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1848         if test "x$with_llvm_shared_libs" = xyes; then
1849             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1850             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1851         else
1852             LLVM_LIBS="`$LLVM_CONFIG --libs engine bitwriter`"
1853             if test "x$enable_opencl" = xyes; then
1854                 LLVM_LIBS="${LLVM_LIBS} `llvm-config --libs ipo linker instrumentation`"
1855             fi
1856         fi
1857         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1858         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1859         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1860         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1861         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1862         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1863         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1864         MESA_LLVM=1
1865
1866         dnl Check for Clang interanl headers
1867         if test "x$enable_opencl" = xyes; then
1868             if test "x$CLANG_LIBDIR" = x; then
1869                 CLANG_LIBDIR=${LLVM_LIBDIR}
1870             fi
1871             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1872             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1873                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1874         fi
1875     else
1876         MESA_LLVM=0
1877     fi
1878 else
1879     MESA_LLVM=0
1880 fi
1881
1882 dnl Directory for XVMC libs
1883 AC_ARG_WITH([xvmc-libdir],
1884     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1885         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1886     [XVMC_LIB_INSTALL_DIR="$withval"],
1887     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1888 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1889
1890 dnl
1891 dnl Gallium Tests
1892 dnl
1893 if test "x$enable_gallium_tests" = xyes; then
1894     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1895     enable_gallium_loader=yes
1896 fi
1897
1898 dnl Directory for VDPAU libs
1899 AC_ARG_WITH([vdpau-libdir],
1900     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1901         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1902     [VDPAU_LIB_INSTALL_DIR="$withval"],
1903     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1904 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1905
1906 dnl Directory for VA libs
1907 AC_ARG_WITH([va-libdir],
1908     [AS_HELP_STRING([--with-va-libdir=DIR],
1909         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1910     [VA_LIB_INSTALL_DIR="$withval"],
1911     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1912 AC_SUBST([VA_LIB_INSTALL_DIR])
1913
1914 dnl Directory for OpenCL libs
1915 AC_ARG_WITH([opencl-libdir],
1916     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1917         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1918     [OPENCL_LIB_INSTALL_DIR="$withval"],
1919     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1920 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1921
1922 dnl
1923 dnl Gallium helper functions
1924 dnl
1925 gallium_check_st() {
1926     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1927          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1928          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1929          if test "x$have_libdrm" != xyes; then
1930             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1931          fi
1932          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1933     fi
1934     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1935          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1936     fi
1937     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1938          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1939     fi
1940     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1941          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1942     fi
1943     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1944          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1945     fi
1946     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1947          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1948     fi
1949     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1950          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1951     fi
1952 }
1953
1954 gallium_require_llvm() {
1955     if test "x$MESA_LLVM" = x0; then
1956         case "$host_cpu" in
1957         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1958         esac
1959     fi
1960 }
1961
1962 gallium_require_drm_loader() {
1963     if test "x$enable_gallium_loader" = xyes; then
1964         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1965                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1966         if test "x$have_libdrm" != xyes; then
1967             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1968         fi
1969         enable_gallium_drm_loader=yes
1970     fi
1971 }
1972
1973 dnl Gallium drivers
1974 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1975 if test "x$with_gallium_drivers" != x; then
1976     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1977     for driver in $gallium_drivers; do
1978         case "x$driver" in
1979         xsvga)
1980             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1981             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1982             ;;
1983         xi915)
1984             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1985             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1986             if test "x$MESA_LLVM" = x1; then
1987                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1988             fi
1989             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1990             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1991             ;;
1992         xr300)
1993             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1994             gallium_require_llvm "Gallium R300"
1995             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1996             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1997             ;;
1998         xr600)
1999             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2000             gallium_require_drm_loader
2001             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
2002             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2003                 if test "x$LLVM_VERSION" != "x3.1"; then
2004                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
2005                 fi
2006                 NEED_RADEON_GALLIUM=yes;
2007             fi
2008             if test "x$enable_r600_llvm" = xyes; then
2009                 USE_R600_LLVM_COMPILER=yes;
2010             fi
2011             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
2012                 LLVM_LIBS="${LLVM_LIBS} `llvm-config --libs bitreader asmparser`"
2013             fi
2014             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
2015             ;;
2016         xradeonsi)
2017             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2018             gallium_require_drm_loader
2019             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
2020             if test "x$LLVM_VERSION" != "x3.1"; then
2021                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
2022             fi
2023             NEED_RADEON_GALLIUM=yes;
2024             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi"
2025             ;;
2026         xnouveau)
2027             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2028             gallium_require_drm_loader
2029             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
2030             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
2031             ;;
2032         xswrast)
2033             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
2034             if test "x$MESA_LLVM" = x1; then
2035                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2036             fi
2037
2038             if test "x$HAVE_ST_DRI" = xyes; then
2039                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2040             fi
2041             if test "x$HAVE_ST_VDPAU" = xyes; then
2042                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
2043             fi
2044             if test "x$HAVE_ST_XVMC" = xyes; then
2045                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
2046             fi
2047             if test "x$HAVE_ST_VA" = xyes; then
2048                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
2049             fi
2050             if test "x$HAVE_ST_VDPAU" = xyes ||
2051                test "x$HAVE_ST_XVMC" = xyes ||
2052                test "x$HAVE_ST_VA" = xyes; then
2053                if test "x$HAVE_WINSYS_XLIB" != xyes; then
2054                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
2055                fi
2056             fi
2057             ;;
2058         *)
2059             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2060             ;;
2061         esac
2062     done
2063 fi
2064
2065 if test "x$enable_gallium_loader" = xyes; then
2066     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2067     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
2068     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
2069     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
2070
2071     if test "x$HAVE_WINSYS_XLIB" = xyes; then
2072         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2073         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
2074     fi
2075
2076     if test "x$enable_gallium_drm_loader" = xyes; then
2077         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2078     fi
2079
2080     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2081     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2082 fi
2083
2084 dnl Tell Automake which drivers to build
2085 for driver in $GALLIUM_DRIVERS_DIRS; do
2086     case "x$driver" in
2087         xgalahad)
2088             HAVE_GALAHAD_GALLIUM=yes;
2089             ;;
2090         xidentity)
2091             HAVE_IDENTITY_GALLIUM=yes;
2092             ;;
2093         xnoop)
2094             HAVE_NOOP_GALLIUM=yes;
2095             ;;
2096         *)
2097             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2098             ;;
2099     esac
2100 done
2101
2102 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2103 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2104 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2105 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2106 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2107 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2108 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2109 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2110 AC_SUBST([GALLIUM_MAKE_DIRS])
2111
2112 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2113 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
2114 AM_CONDITIONAL(HAVE_OSMESA_DRIVER, echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1)
2115
2116 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
2117 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
2118 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
2119
2120 dnl prepend CORE_DIRS to SRC_DIRS
2121 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2122
2123 dnl Restore LDFLAGS and CPPFLAGS
2124 LDFLAGS="$_SAVE_LDFLAGS"
2125 CPPFLAGS="$_SAVE_CPPFLAGS"
2126
2127 dnl Add user CFLAGS and CXXFLAGS
2128 CFLAGS="$CFLAGS $USER_CFLAGS"
2129 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2130
2131 dnl Substitute the config
2132 AC_CONFIG_FILES([configs/current
2133                 Makefile
2134                 src/Makefile
2135                 src/gallium/Makefile
2136                 src/gallium/auxiliary/pipe-loader/Makefile
2137                 src/gallium/state_trackers/clover/Makefile
2138                 src/gallium/drivers/Makefile
2139                 src/gallium/drivers/r300/Makefile
2140                 src/gallium/drivers/r600/Makefile
2141                 src/gallium/targets/opencl/Makefile
2142                 src/gbm/Makefile
2143                 src/gbm/main/gbm.pc
2144                 src/egl/drivers/Makefile
2145                 src/egl/drivers/dri2/Makefile
2146                 src/egl/drivers/glx/Makefile
2147                 src/egl/Makefile
2148                 src/egl/main/Makefile
2149                 src/egl/main/egl.pc
2150                 src/egl/wayland/Makefile
2151                 src/egl/wayland/wayland-egl/Makefile
2152                 src/egl/wayland/wayland-egl/wayland-egl.pc
2153                 src/egl/wayland/wayland-drm/Makefile
2154                 src/glsl/tests/Makefile
2155                 src/glx/Makefile
2156                 src/glx/tests/Makefile
2157                 src/mapi/glapi/gen/Makefile
2158                 src/mapi/shared-glapi/Makefile
2159                 src/mapi/glapi/tests/Makefile
2160                 src/gtest/Makefile
2161                 src/mesa/Makefile
2162                 src/mesa/libdricore/Makefile
2163                 src/mesa/main/tests/Makefile
2164                 src/mesa/x86/Makefile
2165                 src/mesa/x86-64/Makefile
2166                 src/mesa/drivers/Makefile
2167                 src/mesa/drivers/dri/dri.pc
2168                 src/mesa/drivers/dri/Makefile
2169                 src/mesa/drivers/dri/common/Makefile
2170                 src/mesa/drivers/dri/i915/Makefile
2171                 src/mesa/drivers/dri/i965/Makefile
2172                 src/mesa/drivers/dri/nouveau/Makefile
2173                 src/mesa/drivers/dri/r200/Makefile
2174                 src/mesa/drivers/dri/radeon/Makefile
2175                 src/mesa/drivers/dri/swrast/Makefile
2176                 src/mesa/drivers/osmesa/Makefile
2177                 src/mesa/drivers/x11/Makefile
2178                 src/mesa/gl.pc
2179                 src/mesa/osmesa.pc])
2180
2181 dnl Sort the dirs alphabetically
2182 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2183 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2184 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2185 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2186 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2187
2188 AC_OUTPUT
2189
2190 dnl
2191 dnl Output some configuration info for the user
2192 dnl
2193 echo ""
2194 echo "        prefix:          $prefix"
2195 echo "        exec_prefix:     $exec_prefix"
2196 echo "        libdir:          $libdir"
2197 echo "        includedir:      $includedir"
2198
2199 dnl API info
2200 echo ""
2201 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2202 echo "        OpenVG:          $enable_openvg"
2203
2204 dnl Driver info
2205 echo ""
2206 if test "x$enable_osmesa" != xno; then
2207         echo "        OSMesa:          lib$OSMESA_LIB"
2208 else
2209         echo "        OSMesa:          no"
2210 fi
2211
2212 if test "x$enable_dri" != xno; then
2213         # cleanup the drivers var
2214         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2215         if test "x$DRI_DIRS" = x; then
2216             echo "        DRI drivers:     no"
2217         else
2218             echo "        DRI drivers:     $dri_dirs"
2219         fi
2220         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2221 fi
2222
2223 case "x$enable_glx$enable_xlib_glx" in
2224 xyesyes)
2225     echo "        GLX:             Xlib-based"
2226     ;;
2227 xyesno)
2228     echo "        GLX:             DRI-based"
2229     ;;
2230 *)
2231     echo "        GLX:             $enable_glx"
2232     ;;
2233 esac
2234
2235 echo ""
2236 echo "        GLU:             $enable_glu"
2237
2238 dnl EGL
2239 echo ""
2240 echo "        EGL:             $enable_egl"
2241 if test "$enable_egl" = yes; then
2242     echo "        EGL platforms:   $EGL_PLATFORMS"
2243
2244     egl_drivers=""
2245     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2246         egl_drivers="$egl_drivers builtin:egl_glx"
2247     fi
2248     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2249         egl_drivers="$egl_drivers builtin:egl_dri2"
2250     fi
2251
2252     if test "x$HAVE_ST_EGL" = xyes; then
2253         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2254         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2255     else
2256         echo "        EGL drivers:    $egl_drivers"
2257     fi
2258 fi
2259
2260 echo ""
2261 if test "x$MESA_LLVM" = x1; then
2262     echo "        llvm:            yes"
2263     echo "        llvm-config:     $LLVM_CONFIG"
2264     echo "        llvm-version:    $LLVM_VERSION"
2265 else
2266     echo "        llvm:            no"
2267 fi
2268
2269 echo ""
2270 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2271     echo "        Gallium:         yes"
2272     echo "        Gallium dirs:    $GALLIUM_DIRS"
2273     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2274     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2275     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2276     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2277 else
2278     echo "        Gallium:         no"
2279 fi
2280
2281
2282 dnl Libraries
2283 echo ""
2284 echo "        Shared libs:     $enable_shared"
2285 echo "        Static libs:     $enable_static"
2286
2287 dnl Compiler options
2288 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2289 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2290     $SED 's/^ *//;s/  */ /;s/ *$//'`
2291 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2292     $SED 's/^ *//;s/  */ /;s/ *$//'`
2293 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2294 echo ""
2295 echo "        CFLAGS:          $cflags"
2296 echo "        CXXFLAGS:        $cxxflags"
2297 echo "        Macros:          $defines"
2298 echo ""
2299 echo "        PYTHON2:         $PYTHON2"
2300
2301 echo ""
2302 echo "        Run '${MAKE-make}' to build Mesa"
2303 echo ""