configure.ac

   1 AC_INIT([btrfs-progs],
   2         m4_esyscmd([./version.sh --configure]),
   3         [linux-btrfs@vger.kernel.org],,
   4         [http://btrfs.wiki.kernel.org])
   5
   6 dnl library version
   7 LIBBTRFS_MAJOR=0
   8 LIBBTRFS_MINOR=1
   9 LIBBTRFS_PATCHLEVEL=1
  10
  11 AC_PREREQ([2.60])
  12
  13 AC_CONFIG_AUX_DIR([config])
  14 dnl AC_USE_SYSTEM_EXTENSIONS must be called before any macros that run
  15 dnl the compiler (like AC_PROG_LIBTOOL) to avoid autoconf errors.
  16 AC_USE_SYSTEM_EXTENSIONS
  17
  18 AC_CONFIG_SRCDIR([btrfs.c])
  19 AC_PREFIX_DEFAULT([/usr])
  20
  21 AC_PROG_CC
  22 AC_CANONICAL_HOST
  23 AC_C_CONST
  24 AC_C_VOLATILE
  25 AC_C_BIGENDIAN
  26
  27 AC_SYS_LARGEFILE
  28
  29 AC_PROG_INSTALL
  30 AC_PROG_LN_S
  31 AC_PATH_PROG([AR], [ar])
  32
  33 AC_CHECK_FUNCS([openat], [],
  34         [AC_MSG_ERROR([cannot find openat() function])])
  35
  36 m4_ifndef([PKG_PROG_PKG_CONFIG],
  37   [m4_fatal([Could not locate the pkg-config autoconf
  38     macros. These are usually located in /usr/share/aclocal/pkg.m4.
  39     If your macros are in a different location, try setting the
  40     environment variable AL_OPTS="-I/other/macro/dir" before running
  41     ./autogen.sh or autoreconf again.])])
  42 PKG_PROG_PKG_CONFIG
  43
  44
  45 dnl
  46 dnl Calls pkg-config --static
  47 dnl
  48 AC_DEFUN([PKG_STATIC], [
  49   if AC_RUN_LOG([pkg-config --exists --print-errors "$2"]); then
  50     $1=`pkg-config --libs --static "$2"`
  51     AC_SUBST([$1])
  52   else
  53     AC_MSG_ERROR([pkg-config description of $2, needed for static build, is not available])
  54   fi
  55 ])
  56
  57 dnl Define <NAME>_LIBS= and <NAME>_CFLAGS= by pkg-config
  58 dnl
  59 dnl The default PKG_CHECK_MODULES() action-if-not-found is end the
  60 dnl execution with error. The static libs are optional.
  61
  62 PKG_CHECK_MODULES(BLKID, [blkid])
  63 PKG_STATIC(BLKID_LIBS_STATIC, [blkid])
  64
  65 PKG_CHECK_MODULES(UUID, [uuid])
  66 PKG_STATIC(UUID_LIBS_STATIC, [uuid])
  67
  68 PKG_CHECK_MODULES(ZLIB, [zlib])
  69 PKG_STATIC(ZLIB_LIBS_STATIC, [zlib])
  70
  71 dnl lzo library does not provide pkg-config, let use classic way
  72 AC_CHECK_LIB([lzo2], [lzo_version], [
  73         LZO2_LIBS="-llzo2"
  74         LZO2_CFLAGS=""
  75         LZO2_LIBS_STATIC="-llzo2"],[
  76         AC_MSG_ERROR([cannot find lzo2 library])
  77 ])
  78 AC_SUBST([LZO2_LIBS])
  79 AC_SUBST([LZO2_LIBS_STATIC])
  80 AC_SUBST([LZO2_CFLAGS])
  81
  82
  83 dnl library stuff
  84 AC_SUBST([LIBBTRFS_MAJOR])
  85 AC_SUBST([LIBBTRFS_MINOR])
  86 AC_SUBST([LIBBTRFS_PATCHLEVEL])
  87
  88 AC_CONFIG_HEADERS([config.h])
  89
  90 AC_CONFIG_FILES([
  91 Makefile
  92 version.h
  93 ])
  94
  95 AC_OUTPUT
  96
  97 AC_MSG_RESULT([
  98         ${PACKAGE_NAME} ${PACKAGE_VERSION}
  99
 100         prefix:            ${prefix}
 101         exec prefix:       ${exec_prefix}
 102
 103         bindir:            ${bindir}
 104         libdir:            ${libdir}
 105         includedir:        ${includedir}
 106
 107         compiler:          ${CC}
 108         cflags:            ${CFLAGS}
 109         ldflags:           ${LDFLAGS}
 110
 111         Type 'make' to compile.
 112 ])
 113