configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign -Wall])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 LT_PREREQ([2.2])
  25 LT_INIT([disable-static])
  26
  27 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  28 USER_CFLAGS="$CFLAGS"
  29 USER_CXXFLAGS="$CXXFLAGS"
  30
  31 dnl Versions for external dependencies
  32 LIBDRM_REQUIRED=2.4.24
  33 LIBDRM_RADEON_REQUIRED=2.4.31
  34 LIBDRM_INTEL_REQUIRED=2.4.34
  35 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  36 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  37 DRI2PROTO_REQUIRED=2.6
  38 GLPROTO_REQUIRED=1.4.14
  39 LIBDRM_XORG_REQUIRED=2.4.24
  40 LIBKMS_XORG_REQUIRED=1.0.0
  41
  42 dnl Check for progs
  43 AC_PROG_CPP
  44 AC_PROG_CC
  45 AC_PROG_CXX
  46 AM_PROG_CC_C_O
  47 AM_PROG_AS
  48 AC_CHECK_PROGS([MAKE], [gmake make])
  49 AC_CHECK_PROGS([PYTHON2], [python2 python])
  50 AC_PROG_SED
  51 AC_PROG_MKDIR_P
  52 AC_PATH_PROG([MKDEP], [makedepend])
  53
  54 if test "x$MKDEP" = "x"; then
  55     AC_MSG_ERROR([makedepend is required to build Mesa])
  56 fi
  57
  58 AC_PROG_YACC
  59 AC_PATH_PROG([YACC_INST], $YACC)
  60 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  61     if test -z "$YACC_INST"; then
  62         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  63     fi
  64 fi
  65 AC_PROG_LEX
  66
  67 AC_PATH_PROG([PERL], [perl])
  68
  69 AC_CHECK_PROG(INDENT, indent, indent, cat)
  70 if test "x$INDENT" != "xcat"; then
  71     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  72 fi
  73
  74 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  75 dnl configuration in that case.
  76 AC_PROG_INSTALL
  77 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 106     AC_MSG_CHECKING([whether gcc version is sufficient])
 107     major=0
 108     minor=0
 109
 110     GCC_VERSION=`$CC -dumpversion`
 111     if test $? -eq 0; then
 112         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 113         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 114     fi
 115
 116     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 117         AC_MSG_RESULT([no])
 118         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 119     else
 120         AC_MSG_RESULT([yes])
 121     fi
 122 fi
 123
 124
 125 MKDEP_OPTIONS=-fdepend
 126 dnl Ask gcc where it's keeping its secret headers
 127 if test "x$GCC" = xyes; then
 128     for dir in include include-fixed; do
 129         GCC_INCLUDES=`$CC -print-file-name=$dir`
 130         if test "x$GCC_INCLUDES" != x && \
 131            test "$GCC_INCLUDES" != "$dir" && \
 132            test -d "$GCC_INCLUDES"; then
 133             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 134         fi
 135     done
 136 fi
 137 AC_SUBST([MKDEP_OPTIONS])
 138
 139 dnl Make sure the pkg-config macros are defined
 140 m4_ifndef([PKG_PROG_PKG_CONFIG],
 141     [m4_fatal([Could not locate the pkg-config autoconf macros.
 142   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 143   are in a different location, try setting the environment variable
 144   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 145 PKG_PROG_PKG_CONFIG()
 146
 147 dnl LIB_DIR - library basename
 148 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 149 AC_SUBST([LIB_DIR])
 150
 151 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 152 _SAVE_LDFLAGS="$LDFLAGS"
 153 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 154 AC_SUBST([EXTRA_LIB_PATH])
 155
 156 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 157 _SAVE_CPPFLAGS="$CPPFLAGS"
 158 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 159 AC_SUBST([X11_INCLUDES])
 160
 161 dnl Compiler macros
 162 DEFINES=""
 163 AC_SUBST([DEFINES])
 164 case "$host_os" in
 165 linux*|*-gnu*|gnu*)
 166     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 167     ;;
 168 solaris*)
 169     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 170     ;;
 171 cygwin*)
 172     DEFINES="$DEFINES -DPTHREADS"
 173     ;;
 174 esac
 175
 176 dnl Add flags for gcc and g++
 177 if test "x$GCC" = xyes; then
 178     CFLAGS="$CFLAGS -Wall -std=c99"
 179
 180     # Enable -Werror=implicit-function-declaration and
 181     # -Werror=missing-prototypes, if available, or otherwise, just
 182     # -Wmissing-prototypes.  This is particularly useful to avoid
 183     # generating a loadable driver module that has undefined symbols.
 184     save_CFLAGS="$CFLAGS"
 185     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 186     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 187     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 189                    AC_MSG_RESULT([yes]),
 190                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 191                     AC_MSG_RESULT([no])]);
 192
 193     # Enable -fvisibility=hidden if using a gcc that supports it
 194     save_CFLAGS="$CFLAGS"
 195     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 196     VISIBILITY_CFLAGS="-fvisibility=hidden"
 197     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 198     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 199                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 200
 201     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 202     CFLAGS=$save_CFLAGS
 203
 204     # Work around aliasing bugs - developers should comment this out
 205     CFLAGS="$CFLAGS -fno-strict-aliasing"
 206
 207     # gcc's builtin memcmp is slower than glibc's
 208     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 209     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 210 fi
 211 if test "x$GXX" = xyes; then
 212     CXXFLAGS="$CXXFLAGS -Wall"
 213
 214     # Enable -fvisibility=hidden if using a gcc that supports it
 215     save_CXXFLAGS="$CXXFLAGS"
 216     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 217     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 218     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 219     AC_LANG_PUSH([C++])
 220     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 221                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 222     AC_LANG_POP([C++])
 223
 224     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 225     CXXFLAGS=$save_CXXFLAGS
 226
 227     # Work around aliasing bugs - developers should comment this out
 228     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 229
 230     # gcc's builtin memcmp is slower than glibc's
 231     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 232     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 233 fi
 234
 235 dnl even if the compiler appears to support it, using visibility attributes isn't
 236 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 237 case "$host_os" in
 238 cygwin*)
 239     VISIBILITY_CFLAGS=""
 240     VISIBILITY_CXXFLAGS=""
 241     ;;
 242 esac
 243
 244 AC_SUBST([VISIBILITY_CFLAGS])
 245 AC_SUBST([VISIBILITY_CXXFLAGS])
 246
 247 dnl These should be unnecessary, but let the user set them if they want
 248 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 249     Default is to use CFLAGS.])
 250 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 251     compiler. Default is to use CFLAGS.])
 252 AC_SUBST([OPT_FLAGS])
 253 AC_SUBST([ARCH_FLAGS])
 254
 255 dnl
 256 dnl Hacks to enable 32 or 64 bit build
 257 dnl
 258 AC_ARG_ENABLE([32-bit],
 259     [AS_HELP_STRING([--enable-32-bit],
 260         [build 32-bit libraries @<:@default=auto@:>@])],
 261     [enable_32bit="$enableval"],
 262     [enable_32bit=auto]
 263 )
 264 if test "x$enable_32bit" = xyes; then
 265     if test "x$GCC" = xyes; then
 266         CFLAGS="$CFLAGS -m32"
 267         ARCH_FLAGS="$ARCH_FLAGS -m32"
 268         CCASFLAGS="$CCASFLAGS -m32"
 269     fi
 270     if test "x$GXX" = xyes; then
 271         CXXFLAGS="$CXXFLAGS -m32"
 272     fi
 273 fi
 274 AC_ARG_ENABLE([64-bit],
 275     [AS_HELP_STRING([--enable-64-bit],
 276         [build 64-bit libraries @<:@default=auto@:>@])],
 277     [enable_64bit="$enableval"],
 278     [enable_64bit=auto]
 279 )
 280 if test "x$enable_64bit" = xyes; then
 281     if test "x$GCC" = xyes; then
 282         CFLAGS="$CFLAGS -m64"
 283     fi
 284     if test "x$GXX" = xyes; then
 285         CXXFLAGS="$CXXFLAGS -m64"
 286     fi
 287 fi
 288
 289 dnl Can't have static and shared libraries, default to static if user
 290 dnl explicitly requested. If both disabled, set to static since shared
 291 dnl was explicitly requested.
 292 case "x$enable_static$enable_shared" in
 293 xyesyes )
 294     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 295     enable_shared=no
 296     ;;
 297 xnono )
 298     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 299     enable_static=yes
 300     ;;
 301 esac
 302
 303 dnl
 304 dnl mklib options
 305 dnl
 306 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 307 if test "$enable_static" = yes; then
 308     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 309 fi
 310 AC_SUBST([MKLIB_OPTIONS])
 311
 312 dnl
 313 dnl other compiler options
 314 dnl
 315 AC_ARG_ENABLE([debug],
 316     [AS_HELP_STRING([--enable-debug],
 317         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 318     [enable_debug="$enableval"],
 319     [enable_debug=no]
 320 )
 321 if test "x$enable_debug" = xyes; then
 322     DEFINES="$DEFINES -DDEBUG"
 323     if test "x$GCC" = xyes; then
 324         CFLAGS="$CFLAGS -g"
 325     fi
 326     if test "x$GXX" = xyes; then
 327         CXXFLAGS="$CXXFLAGS -g"
 328     fi
 329 fi
 330
 331 dnl
 332 dnl library names
 333 dnl
 334 LIB_PREFIX_GLOB='lib'
 335 LIB_VERSION_SEPARATOR='.'
 336 if test "$enable_static" = yes; then
 337     LIB_EXTENSION='a'
 338 else
 339     case "$host_os" in
 340     darwin* )
 341         LIB_EXTENSION='dylib' ;;
 342     cygwin* )
 343         dnl prefix can be 'cyg' or 'lib'
 344         LIB_PREFIX_GLOB='???'
 345         LIB_VERSION_SEPARATOR='-'
 346         LIB_EXTENSION='dll' ;;
 347     aix* )
 348         LIB_EXTENSION='a' ;;
 349     * )
 350         LIB_EXTENSION='so' ;;
 351     esac
 352 fi
 353
 354 dnl
 355 dnl Mangled Mesa support
 356 dnl
 357 AC_ARG_ENABLE([mangling],
 358   [AS_HELP_STRING([--enable-mangling],
 359     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 360   [enable_mangling="${enableval}"],
 361   [enable_mangling=no]
 362 )
 363 GL_LIB="GL"
 364 GLU_LIB="GLU"
 365 OSMESA_LIB="OSMesa"
 366 if test "x${enable_mangling}" = "xyes" ; then
 367   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 368   GL_LIB="MangledGL"
 369   GLU_LIB="MangledGLU"
 370   OSMESA_LIB="MangledOSMesa"
 371 fi
 372 AC_SUBST([GL_LIB])
 373 AC_SUBST([GLU_LIB])
 374 AC_SUBST([OSMESA_LIB])
 375 AM_CONDITIONAL(HAVE_MANGLED_GL, test $GL_LIB = MangledGL)
 376
 377 dnl
 378 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 379 dnl
 380 AC_ARG_ENABLE([texture-float],
 381     [AS_HELP_STRING([--enable-texture-float],
 382         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 383     [enable_texture_float="$enableval"],
 384     [enable_texture_float=no]
 385 )
 386 if test "x$enable_texture_float" = xyes; then
 387     AC_MSG_WARN([Floating-point textures enabled.])
 388     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 389     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 390 fi
 391
 392 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 393 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 394 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 395 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 396 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 397 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 398 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 399 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 400
 401 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 410
 411 AC_SUBST([GL_LIB_NAME])
 412 AC_SUBST([GLU_LIB_NAME])
 413 AC_SUBST([OSMESA_LIB_NAME])
 414 AC_SUBST([EGL_LIB_NAME])
 415 AC_SUBST([GLESv1_CM_LIB_NAME])
 416 AC_SUBST([GLESv2_LIB_NAME])
 417 AC_SUBST([VG_LIB_NAME])
 418 AC_SUBST([GLAPI_LIB_NAME])
 419
 420 AC_SUBST([GL_LIB_GLOB])
 421 AC_SUBST([GLU_LIB_GLOB])
 422 AC_SUBST([OSMESA_LIB_GLOB])
 423 AC_SUBST([EGL_LIB_GLOB])
 424 AC_SUBST([GLESv1_CM_LIB_GLOB])
 425 AC_SUBST([GLESv2_LIB_GLOB])
 426 AC_SUBST([VG_LIB_GLOB])
 427 AC_SUBST([GLAPI_LIB_GLOB])
 428
 429 dnl
 430 dnl Arch/platform-specific settings
 431 dnl
 432 AC_ARG_ENABLE([asm],
 433     [AS_HELP_STRING([--disable-asm],
 434         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 435     [enable_asm="$enableval"],
 436     [enable_asm=yes]
 437 )
 438 asm_arch=""
 439 ASM_FLAGS=""
 440 MESA_ASM_FILES=""
 441 GLAPI_ASM_SOURCES=""
 442 AC_MSG_CHECKING([whether to enable assembly])
 443 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 444 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 445 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 446     case "$host_cpu" in
 447     i?86 | x86_64)
 448         enable_asm=no
 449         AC_MSG_RESULT([no, cross compiling])
 450         ;;
 451     esac
 452 fi
 453 # check for supported arches
 454 if test "x$enable_asm" = xyes; then
 455     case "$host_cpu" in
 456     i?86)
 457         case "$host_os" in
 458         linux* | *freebsd* | dragonfly* | *netbsd*)
 459             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 460             ;;
 461         esac
 462         ;;
 463     x86_64)
 464         case "$host_os" in
 465         linux* | *freebsd* | dragonfly* | *netbsd*)
 466             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 467             ;;
 468         esac
 469         ;;
 470     powerpc)
 471         case "$host_os" in
 472         linux*)
 473             asm_arch=ppc
 474             ;;
 475         esac
 476         ;;
 477     sparc*)
 478         case "$host_os" in
 479         linux*)
 480             asm_arch=sparc
 481             ;;
 482         esac
 483         ;;
 484     esac
 485
 486     case "$asm_arch" in
 487     x86)
 488         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 489         MESA_ASM_FILES='$(X86_FILES)'
 490         GLAPI_ASM_SOURCES='$(X86_API)'
 491         AC_MSG_RESULT([yes, x86])
 492         ;;
 493     x86_64)
 494         ASM_FLAGS="-DUSE_X86_64_ASM"
 495         MESA_ASM_FILES='$(X86_64_FILES)'
 496         GLAPI_ASM_SOURCES='$(X86-64_API)'
 497         AC_MSG_RESULT([yes, x86_64])
 498         ;;
 499     sparc)
 500         ASM_FLAGS="-DUSE_SPARC_ASM"
 501         MESA_ASM_FILES='$(SPARC_FILES)'
 502         GLAPI_ASM_SOURCES='$(SPARC_API)'
 503         AC_MSG_RESULT([yes, sparc])
 504         ;;
 505     *)
 506         AC_MSG_RESULT([no, platform not supported])
 507         ;;
 508     esac
 509 fi
 510 AC_SUBST([ASM_FLAGS])
 511 AC_SUBST([MESA_ASM_FILES])
 512 AC_SUBST([GLAPI_ASM_SOURCES])
 513
 514 dnl PIC code macro
 515 MESA_PIC_FLAGS
 516
 517 dnl Check to see if dlopen is in default libraries (like Solaris, which
 518 dnl has it in libc), or if libdl is needed to get it.
 519 AC_CHECK_FUNC([dlopen], [],
 520     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 521 AC_SUBST([DLOPEN_LIBS])
 522
 523 dnl See if posix_memalign is available
 524 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 525
 526 dnl SELinux awareness.
 527 AC_ARG_ENABLE([selinux],
 528     [AS_HELP_STRING([--enable-selinux],
 529         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 530     [MESA_SELINUX="$enableval"],
 531     [MESA_SELINUX=no])
 532 if test "x$enable_selinux" = "xyes"; then
 533     AC_CHECK_HEADER([selinux/selinux.h],[],
 534                     [AC_MSG_ERROR([SELinux headers not found])])
 535     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 536                  [AC_MSG_ERROR([SELinux library not found])])
 537     SELINUX_LIBS="-lselinux"
 538     DEFINES="$DEFINES -DMESA_SELINUX"
 539 fi
 540
 541 dnl Options for APIs
 542 AC_ARG_ENABLE([opengl],
 543     [AS_HELP_STRING([--disable-opengl],
 544         [disable support for standard OpenGL API @<:@default=no@:>@])],
 545     [enable_opengl="$enableval"],
 546     [enable_opengl=yes])
 547 AC_ARG_ENABLE([gles1],
 548     [AS_HELP_STRING([--enable-gles1],
 549         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 550     [enable_gles1="$enableval"],
 551     [enable_gles1=no])
 552 AC_ARG_ENABLE([gles2],
 553     [AS_HELP_STRING([--enable-gles2],
 554         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 555     [enable_gles2="$enableval"],
 556     [enable_gles2=no])
 557 AC_ARG_ENABLE([openvg],
 558     [AS_HELP_STRING([--enable-openvg],
 559         [enable support for OpenVG API @<:@default=no@:>@])],
 560     [enable_openvg="$enableval"],
 561     [enable_openvg=no])
 562
 563 AC_ARG_ENABLE([dri],
 564     [AS_HELP_STRING([--enable-dri],
 565         [enable DRI modules @<:@default=auto@:>@])],
 566     [enable_dri="$enableval"],
 567     [enable_dri=auto])
 568 AC_ARG_ENABLE([glx],
 569     [AS_HELP_STRING([--enable-glx],
 570         [enable GLX library @<:@default=auto@:>@])],
 571     [enable_glx="$enableval"],
 572     [enable_glx=auto])
 573 AC_ARG_ENABLE([osmesa],
 574     [AS_HELP_STRING([--enable-osmesa],
 575         [enable OSMesa library @<:@default=auto@:>@])],
 576     [enable_osmesa="$enableval"],
 577     [enable_osmesa=auto])
 578 AC_ARG_ENABLE([egl],
 579     [AS_HELP_STRING([--disable-egl],
 580         [disable EGL library @<:@default=enabled@:>@])],
 581     [enable_egl="$enableval"],
 582     [enable_egl=yes])
 583
 584 AC_ARG_ENABLE([xorg],
 585     [AS_HELP_STRING([--enable-xorg],
 586         [enable support for X.Org DDX API @<:@default=no@:>@])],
 587     [enable_xorg="$enableval"],
 588     [enable_xorg=no])
 589 AC_ARG_ENABLE([xa],
 590     [AS_HELP_STRING([--enable-xa],
 591         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 592     [enable_xa="$enableval"],
 593     [enable_xa=no])
 594 AC_ARG_ENABLE([d3d1x],
 595     [AS_HELP_STRING([--enable-d3d1x],
 596         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 597     [enable_d3d1x="$enableval"],
 598     [enable_d3d1x=no])
 599 AC_ARG_ENABLE([gbm],
 600    [AS_HELP_STRING([--enable-gbm],
 601          [enable gbm library @<:@default=auto@:>@])],
 602    [enable_gbm="$enableval"],
 603    [enable_gbm=auto])
 604
 605 AC_ARG_ENABLE([xvmc],
 606    [AS_HELP_STRING([--enable-xvmc],
 607          [enable xvmc library @<:@default=auto@:>@])],
 608    [enable_xvmc="$enableval"],
 609    [enable_xvmc=auto])
 610 AC_ARG_ENABLE([vdpau],
 611    [AS_HELP_STRING([--enable-vdpau],
 612          [enable vdpau library @<:@default=auto@:>@])],
 613    [enable_vdpau="$enableval"],
 614    [enable_vdpau=auto])
 615 AC_ARG_ENABLE([va],
 616    [AS_HELP_STRING([--enable-va],
 617          [enable va library @<:@default=auto@:>@])],
 618    [enable_va="$enableval"],
 619    [enable_va=auto])
 620 AC_ARG_ENABLE([opencl],
 621    [AS_HELP_STRING([--enable-opencl],
 622          [enable OpenCL library @<:@default=no@:>@])],
 623    [enable_opencl="$enableval"],
 624    [enable_opencl=no])
 625 AC_ARG_ENABLE([xlib_glx],
 626     [AS_HELP_STRING([--enable-xlib-glx],
 627         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 628     [enable_xlib_glx="$enableval"],
 629     [enable_xlib_glx=auto])
 630 AC_ARG_ENABLE([gallium_egl],
 631     [AS_HELP_STRING([--enable-gallium-egl],
 632         [enable optional EGL state tracker (not required
 633          for EGL support in Gallium with OpenGL and OpenGL ES)
 634          @<:@default=disable@:>@])],
 635     [enable_gallium_egl="$enableval"],
 636     [enable_gallium_egl=no])
 637 AC_ARG_ENABLE([gallium_gbm],
 638     [AS_HELP_STRING([--enable-gallium-gbm],
 639         [enable optional gbm state tracker (not required for
 640          gbm support in Gallium)
 641          @<:@default=auto@:>@])],
 642     [enable_gallium_gbm="$enableval"],
 643     [enable_gallium_gbm=auto])
 644
 645 AC_ARG_ENABLE([r600-llvm-compiler],
 646     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 647         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 648     [enable_r600_llvm="$enableval"],
 649     [enable_r600_llvm=no])
 650
 651 AC_ARG_ENABLE([gallium_tests],
 652     [AS_HELP_STRING([--enable-gallium-tests],
 653         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 654     [enable_gallium_tests="$enableval"],
 655     [enable_gallium_tests=no])
 656
 657 # Option for Gallium drivers
 658 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 659
 660 AC_ARG_WITH([gallium-drivers],
 661     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 662         [comma delimited Gallium drivers list, e.g.
 663         "i915,nouveau,r300,r600,svga,swrast"
 664         @<:@default=r300,r600,swrast@:>@])],
 665     [with_gallium_drivers="$withval"],
 666     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 667
 668 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 669 # here so that the script doesn't choke on an unknown driver name later.
 670 case "$with_gallium_drivers" in
 671     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 672     no) with_gallium_drivers='' ;;
 673 esac
 674
 675 if test "x$enable_opengl" = xno -a \
 676         "x$enable_gles1" = xno -a \
 677         "x$enable_gles2" = xno -a \
 678         "x$enable_openvg" = xno -a \
 679         "x$enable_xorg" = xno -a \
 680         "x$enable_xa" = xno -a \
 681         "x$enable_d3d1x" = xno -a \
 682         "x$enable_xvmc" = xno -a \
 683         "x$enable_vdpau" = xno -a \
 684         "x$enable_va" = xno -a \
 685         "x$enable_opencl" = xno; then
 686     AC_MSG_ERROR([at least one API should be enabled])
 687 fi
 688
 689 API_DEFINES=""
 690 if test "x$enable_opengl" = xno; then
 691     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 692 else
 693     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 694 fi
 695 if test "x$enable_gles1" = xyes; then
 696     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 697 fi
 698 if test "x$enable_gles2" = xyes; then
 699     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 700 fi
 701 AC_SUBST([API_DEFINES])
 702
 703 AC_ARG_ENABLE([shared-glapi],
 704     [AS_HELP_STRING([--enable-shared-glapi],
 705         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 706     [enable_shared_glapi="$enableval"],
 707     [enable_shared_glapi=no])
 708
 709 SHARED_GLAPI="0"
 710 if test "x$enable_shared_glapi" = xyes; then
 711     SHARED_GLAPI="1"
 712     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 713     # the remap table)
 714     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 715     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 716 fi
 717 AC_SUBST([SHARED_GLAPI])
 718 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 719
 720 dnl
 721 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 722 dnl More later: fbdev, ...
 723 dnl
 724 default_driver="xlib"
 725
 726 case "$host_os" in
 727 linux*)
 728     case "$host_cpu" in
 729     i*86|x86_64|powerpc*|sparc*|ia64*) default_driver="dri";;
 730     esac
 731     ;;
 732 *freebsd* | dragonfly* | *netbsd*)
 733     case "$host_cpu" in
 734     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 735     esac
 736     ;;
 737 esac
 738
 739 if test "x$enable_opengl" = xno; then
 740     default_driver="no"
 741 fi
 742
 743 AC_ARG_WITH([driver],
 744     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 745     [mesa_driver="$withval"],
 746     [mesa_driver=auto])
 747 dnl Check for valid option
 748 case "x$mesa_driver" in
 749 xxlib|xdri|xosmesa|xno)
 750     if test "x$enable_dri" != xauto -o \
 751             "x$enable_glx" != xauto -o \
 752             "x$enable_osmesa" != xauto -o \
 753             "x$enable_xlib_glx" != xauto; then
 754         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 755     fi
 756     ;;
 757 xauto)
 758     mesa_driver="$default_driver"
 759     ;;
 760 *)
 761     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 762     ;;
 763 esac
 764
 765 # map $mesa_driver to APIs
 766 if test "x$enable_dri" = xauto; then
 767     case "x$mesa_driver" in
 768     xdri) enable_dri=yes ;;
 769     *)    enable_dri=no ;;
 770     esac
 771 fi
 772
 773 if test "x$enable_glx" = xauto; then
 774     case "x$mesa_driver" in
 775     xdri|xxlib) enable_glx=yes ;;
 776     *)          enable_glx=no ;;
 777     esac
 778 fi
 779
 780 if test "x$enable_osmesa" = xauto; then
 781     case "x$mesa_driver" in
 782     xxlib|xosmesa) enable_osmesa=yes ;;
 783     *)             enable_osmesa=no ;;
 784     esac
 785 fi
 786
 787 if test "x$enable_xlib_glx" = xauto; then
 788     case "x$mesa_driver" in
 789     xxlib) enable_xlib_glx=yes ;;
 790     *)     enable_xlib_glx=no ;;
 791     esac
 792 fi
 793
 794 if test "x$enable_glx" = xno; then
 795     enable_xlib_glx=no
 796 fi
 797
 798 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 799
 800 dnl
 801 dnl Driver specific build directories
 802 dnl
 803
 804 dnl this variable will be prepended to SRC_DIRS and is not exported
 805 CORE_DIRS=""
 806
 807 SRC_DIRS="gtest"
 808 GLU_DIRS="sgi"
 809 GALLIUM_DIRS="auxiliary drivers state_trackers"
 810 GALLIUM_TARGET_DIRS=""
 811 GALLIUM_WINSYS_DIRS="sw"
 812 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 813 GALLIUM_STATE_TRACKERS_DIRS=""
 814
 815 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 816 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 817 x*yes*)
 818     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 819     ;;
 820 esac
 821
 822 # build glapi if OpenGL is enabled
 823 if test "x$enable_opengl" = xyes; then
 824     CORE_DIRS="$CORE_DIRS mapi/glapi"
 825 fi
 826
 827 # build es1api if OpenGL ES 1.x is enabled
 828 if test "x$enable_gles1" = xyes; then
 829     CORE_DIRS="$CORE_DIRS mapi/es1api"
 830 fi
 831
 832 # build es2api if OpenGL ES 2.x is enabled
 833 if test "x$enable_gles2" = xyes; then
 834     CORE_DIRS="$CORE_DIRS mapi/es2api"
 835 fi
 836
 837 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 838 case "x$enable_opengl$enable_gles1$enable_gles2" in
 839 x*yes*)
 840     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 841     ;;
 842 esac
 843
 844 case "x$enable_glx$enable_xlib_glx" in
 845 xyesyes)
 846     DRIVER_DIRS="$DRIVER_DIRS x11"
 847     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 848     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 849     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 850     HAVE_WINSYS_XLIB="yes"
 851     ;;
 852 xyesno)
 853     # DRI-based GLX
 854     SRC_DIRS="$SRC_DIRS glx"
 855     ;;
 856 esac
 857
 858 if test "x$enable_dri" = xyes; then
 859     DRIVER_DIRS="$DRIVER_DIRS dri"
 860
 861     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 862     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 863     HAVE_ST_DRI="yes"
 864 fi
 865
 866 if test "x$enable_osmesa" = xyes; then
 867     # the empty space matters for osmesa... (see src/mesa/Makefile)
 868     if test -n "$DRIVER_DIRS"; then
 869         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 870     else
 871         DRIVER_DIRS="osmesa"
 872     fi
 873 fi
 874
 875 AC_SUBST([SRC_DIRS])
 876 AC_SUBST([GLU_DIRS])
 877 AC_SUBST([DRIVER_DIRS])
 878 AC_SUBST([GALLIUM_DIRS])
 879 AC_SUBST([GALLIUM_TARGET_DIRS])
 880 AC_SUBST([GALLIUM_WINSYS_DIRS])
 881 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 882 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 883 AC_SUBST([MESA_LLVM])
 884
 885 # Check for libdrm
 886 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 887                   [have_libdrm=yes], [have_libdrm=no])
 888
 889 if test "x$enable_dri" = xyes; then
 890     # DRI must be shared, I think
 891     if test "$enable_static" = yes; then
 892         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 893     fi
 894
 895     # not a hard requirement as swrast does not depend on it
 896     if test "x$have_libdrm" = xyes; then
 897         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 898     fi
 899 fi
 900
 901 dnl
 902 dnl Find out if X is available. The variable have_x is set if libX11 is
 903 dnl found to mimic AC_PATH_XTRA.
 904 dnl
 905 if test -n "$PKG_CONFIG"; then
 906     AC_MSG_CHECKING([pkg-config files for X11 are available])
 907     PKG_CHECK_EXISTS([x11],[
 908         x11_pkgconfig=yes
 909         have_x=yes
 910         ],[
 911         x11_pkgconfig=no
 912     ])
 913     AC_MSG_RESULT([$x11_pkgconfig])
 914 else
 915     x11_pkgconfig=no
 916 fi
 917 dnl Use the autoconf macro if no pkg-config files
 918 if test "$x11_pkgconfig" = yes; then
 919     PKG_CHECK_MODULES([X11], [x11])
 920 else
 921     AC_PATH_XTRA
 922     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 923     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 924     AC_SUBST([X11_CFLAGS])
 925     AC_SUBST([X11_LIBS])
 926 fi
 927
 928 dnl Try to tell the user that the --x-* options are only used when
 929 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 930 m4_divert_once([HELP_BEGIN],
 931 [These options are only used when the X libraries cannot be found by the
 932 pkg-config utility.])
 933
 934 dnl We need X for xlib and dri, so bomb now if it's not found
 935 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 936     AC_MSG_ERROR([X11 development libraries needed for GLX])
 937 fi
 938
 939 if test "x$enable_glx" = xyes; then
 940     DEFINES="$DEFINES -DUSE_XCB"
 941 fi
 942
 943 dnl Direct rendering or just indirect rendering
 944 case "$host_os" in
 945 gnu*)
 946     dnl Disable by default on GNU/Hurd
 947     driglx_direct_default="no"
 948     ;;
 949 cygwin*)
 950     dnl Disable by default on cygwin
 951     driglx_direct_default="no"
 952     ;;
 953 *)
 954     driglx_direct_default="yes"
 955     ;;
 956 esac
 957 AC_ARG_ENABLE([driglx-direct],
 958     [AS_HELP_STRING([--disable-driglx-direct],
 959         [enable direct rendering in GLX and EGL for DRI \
 960             @<:@default=auto@:>@])],
 961     [driglx_direct="$enableval"],
 962     [driglx_direct="$driglx_direct_default"])
 963
 964 dnl
 965 dnl libGL configuration per driver
 966 dnl
 967 case "x$enable_glx$enable_xlib_glx" in
 968 xyesyes)
 969     # Xlib-based GLX
 970     if test "$x11_pkgconfig" = yes; then
 971         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 972         GL_PC_REQ_PRIV="x11 xext"
 973         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 974         GL_LIB_DEPS="$XLIBGL_LIBS"
 975     else
 976         # should check these...
 977         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 978         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 979         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 980         GL_PC_CFLAGS="$X11_INCLUDES"
 981     fi
 982     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 983     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 984     ;;
 985 xyesno)
 986     # DRI-based GLX
 987     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 988     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 989     if test x"$driglx_direct" = xyes; then
 990         if test "x$have_libdrm" != xyes; then
 991             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 992         fi
 993         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 994         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 995     fi
 996
 997     # find the DRI deps for libGL
 998     if test "$x11_pkgconfig" = yes; then
 999         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
1000
1001         # add xf86vidmode if available
1002         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1003         if test "$HAVE_XF86VIDMODE" = yes ; then
1004             dri_modules="$dri_modules xxf86vm"
1005         fi
1006
1007         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1008         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1009         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1010         GL_LIB_DEPS="$DRIGL_LIBS"
1011     else
1012         # should check these...
1013         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
1014         if test "x$HAVE_XF86VIDMODE" == xyes; then
1015            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1016         else
1017            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1018         fi
1019         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1020         GL_PC_CFLAGS="$X11_INCLUDES"
1021
1022         # XCB can only be used from pkg-config
1023         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
1024         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1025         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1026         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1027     fi
1028
1029     # Check to see if the xcb-glx library is new enough to support
1030     # GLX_ARB_create_context.  This bit of hackery is necessary until XCB 1.8
1031     # is released.
1032     save_CPPFLAGS="$CPPFLAGS"
1033     save_LDFLAGS="$LDFLAGS"
1034     CPPFLAGS="$CPPFLAGS $X11_INCLUDES"
1035     LDFLAGS="$LDFLAGS $GL_LIB_DEPS"
1036     AC_CHECK_LIB(xcb-glx, xcb_glx_create_context_attribs_arb_checked,
1037         [HAVE_XCB_GLX_CREATE_CONTEXT=yes],
1038         [HAVE_XCB_GLX_CREATE_CONTEXT=no])
1039     CPPFLAGS="$save_CPPFLAGS"
1040     LDFLAGS="$save_LDFLAGS"
1041
1042     if test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes; then
1043         X11_INCLUDES="$X11_INCLUDES -DHAVE_XCB_GLX_CREATE_CONTEXT"
1044     fi
1045
1046     # need DRM libs, -lpthread, etc.
1047     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1048     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1049     ;;
1050 esac
1051
1052 # This is outside the case (above) so that it is invoked even for non-GLX
1053 # builds.
1054 AM_CONDITIONAL(HAVE_XCB_GLX_CREATE_CONTEXT,
1055     test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes)
1056 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1057
1058 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1059 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1060 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1061 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1062
1063 AC_SUBST([GL_LIB_DEPS])
1064 AC_SUBST([GL_PC_REQ_PRIV])
1065 AC_SUBST([GL_PC_LIB_PRIV])
1066 AC_SUBST([GL_PC_CFLAGS])
1067 AC_SUBST([DRI_PC_REQ_PRIV])
1068 AC_SUBST([GLESv1_CM_LIB_DEPS])
1069 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1070 AC_SUBST([GLESv2_LIB_DEPS])
1071 AC_SUBST([GLESv2_PC_LIB_PRIV])
1072
1073 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1074 AC_SUBST([GLAPI_LIB_DEPS])
1075
1076
1077 dnl Setup default DRI CFLAGS
1078 DRI_CFLAGS='$(CFLAGS)'
1079 DRI_CXXFLAGS='$(CXXFLAGS)'
1080 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1081 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
1082
1083 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1084     DRICORE_LIBS='$(TOP)/$(LIB_DIR)/libdricore.so'
1085     DRICORE_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR)'
1086     DRI_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -ldricore'
1087     DRI_CFLAGS='$(CFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1088     DRI_CXXFLAGS='$(CXXFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1089     MESA_MODULES='$(DRICORE_LIBS)'
1090     HAVE_DRICORE=yes
1091 fi
1092 AM_CONDITIONAL(HAVE_DRICORE, test x$HAVE_DRICORE = xyes)
1093 AC_SUBST([DRICORE_LIBS])
1094 AC_SUBST([DRICORE_LIB_DEPS])
1095 AC_SUBST([DRI_CXXFLAGS])
1096 AC_SUBST([DRI_CFLAGS])
1097 AC_SUBST([MESA_MODULES])
1098
1099 AC_SUBST([HAVE_XF86VIDMODE])
1100
1101 dnl
1102 dnl More GLX setup
1103 dnl
1104 case "x$enable_glx$enable_xlib_glx" in
1105 xyesyes)
1106     DEFINES="$DEFINES -DUSE_XSHM"
1107     ;;
1108 xyesno)
1109     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1110     if test "x$driglx_direct" = xyes; then
1111         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1112     fi
1113     ;;
1114 esac
1115
1116 dnl
1117 dnl TLS detection
1118 dnl
1119
1120 AC_ARG_ENABLE([glx-tls],
1121     [AS_HELP_STRING([--enable-glx-tls],
1122         [enable TLS support in GLX @<:@default=disabled@:>@])],
1123     [GLX_USE_TLS="$enableval"],
1124     [GLX_USE_TLS=no])
1125 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1126
1127 AS_IF([test "x$GLX_USE_TLS" = xyes],
1128       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1129
1130 dnl
1131 dnl More DRI setup
1132 dnl
1133 dnl Directory for DRI drivers
1134 AC_ARG_WITH([dri-driverdir],
1135     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1136         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1137     [DRI_DRIVER_INSTALL_DIR="$withval"],
1138     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1139 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1140 dnl Extra search path for DRI drivers
1141 AC_ARG_WITH([dri-searchpath],
1142     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1143         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1144     [DRI_DRIVER_SEARCH_DIR="$withval"],
1145     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1146 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1147 dnl Which drivers to build - default is chosen by platform
1148 AC_ARG_WITH([dri-drivers],
1149     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1150         [comma delimited DRI drivers list, e.g.
1151         "swrast,i965,radeon" @<:@default=auto@:>@])],
1152     [with_dri_drivers="$withval"],
1153     [with_dri_drivers=yes])
1154 if test "x$with_dri_drivers" = x; then
1155     with_dri_drivers=no
1156 fi
1157
1158 dnl If $with_dri_drivers is yes, directories will be added through
1159 dnl platform checks
1160 DRI_DIRS=""
1161 case "$with_dri_drivers" in
1162 no) ;;
1163 yes)
1164     # classic DRI drivers require FEATURE_GL to build
1165     if test "x$enable_opengl" = xyes; then
1166         DRI_DIRS="yes"
1167     fi
1168     ;;
1169 *)
1170     # verify the requested driver directories exist
1171     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1172     for driver in $dri_drivers; do
1173         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1174             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1175     done
1176     DRI_DIRS="$dri_drivers"
1177     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1178         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1179     fi
1180     ;;
1181 esac
1182
1183 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1184 if test "x$enable_dri" = xyes; then
1185     # Platform specific settings and drivers to build
1186     case "$host_os" in
1187     linux*)
1188         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1189         DEFINES="$DEFINES -DHAVE_ALIAS"
1190
1191         case "$host_cpu" in
1192         x86_64)
1193             if test "x$DRI_DIRS" = "xyes"; then
1194                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1195             fi
1196             ;;
1197         powerpc*)
1198             # Build only the drivers for cards that exist on PowerPC.
1199             if test "x$DRI_DIRS" = "xyes"; then
1200                 DRI_DIRS="r200 radeon swrast"
1201             fi
1202             ;;
1203         sparc*)
1204             # Build only the drivers for cards that exist on sparc
1205             if test "x$DRI_DIRS" = "xyes"; then
1206                 DRI_DIRS="r200 radeon swrast"
1207             fi
1208             ;;
1209         esac
1210         ;;
1211     freebsd* | dragonfly* | *netbsd*)
1212         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1213         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1214
1215         if test "x$DRI_DIRS" = "xyes"; then
1216             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1217         fi
1218         ;;
1219     gnu*)
1220         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1221         DEFINES="$DEFINES -DHAVE_ALIAS"
1222         ;;
1223     solaris*)
1224         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1225         ;;
1226     cygwin*)
1227         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1228         if test "x$DRI_DIRS" = "xyes"; then
1229             DRI_DIRS="swrast"
1230         fi
1231         ;;
1232     esac
1233
1234     # default drivers
1235     if test "x$DRI_DIRS" = "xyes"; then
1236         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1237     fi
1238
1239     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1240
1241     # Check for expat
1242     if test "x$enable_dri" = xyes; then
1243         EXPAT_INCLUDES=""
1244         EXPAT_LIB=-lexpat
1245         AC_ARG_WITH([expat],
1246             [AS_HELP_STRING([--with-expat=DIR],
1247                 [expat install directory])],[
1248             EXPAT_INCLUDES="-I$withval/include"
1249             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1250             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1251             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1252             ])
1253         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1254         save_LIBS="$LIBS"
1255         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1256             [AC_MSG_ERROR([Expat required for DRI.])])
1257         LIBS="$save_LIBS"
1258     fi
1259
1260     # if we are building any dri driver other than swrast ...
1261     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1262         # ... libdrm is required
1263         if test "x$have_libdrm" != xyes; then
1264             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1265         fi
1266         # ... and build dricommon
1267         HAVE_COMMON_DRI=yes
1268     fi
1269
1270     # put all the necessary libs together
1271     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1272 fi
1273 AC_SUBST([DRI_DIRS])
1274 AC_SUBST([EXPAT_INCLUDES])
1275 AC_SUBST([DRI_LIB_DEPS])
1276
1277 case $DRI_DIRS in
1278 *i915*|*i965*)
1279     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1280
1281     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1282         case $d in
1283         i915)
1284             HAVE_I915_DRI=yes;
1285             ;;
1286         i965)
1287             HAVE_I965_DRI=yes;
1288             ;;
1289         esac
1290     done
1291
1292     ;;
1293 esac
1294
1295 case $DRI_DIRS in
1296 *nouveau*)
1297     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1298     HAVE_NOUVEAU_DRI=yes;
1299     ;;
1300 esac
1301
1302 case $DRI_DIRS in
1303 *radeon*|*r200*)
1304     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1305
1306     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1307         case $d in
1308         radeon)
1309             HAVE_RADEON_DRI=yes;
1310             ;;
1311         r200)
1312             HAVE_R200_DRI=yes;
1313             ;;
1314         esac
1315     done
1316
1317     ;;
1318 esac
1319
1320 case $DRI_DIRS in
1321 *swrast*)
1322     HAVE_SWRAST_DRI=yes;
1323     ;;
1324 esac
1325
1326 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1327 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1328 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1329 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1330 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1331 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1332 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1333
1334 dnl
1335 dnl OSMesa configuration
1336 dnl
1337
1338 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1339 AC_ARG_WITH([osmesa-bits],
1340     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1341         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1342     [osmesa_bits="$withval"],
1343     [osmesa_bits=8])
1344 if test "x$osmesa_bits" != x8; then
1345     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1346         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1347         osmesa_bits=8
1348     fi
1349 fi
1350 case "x$osmesa_bits" in
1351 x8)
1352     OSMESA_LIB="${OSMESA_LIB}"
1353     ;;
1354 x16|x32)
1355     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1356     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1357     ;;
1358 *)
1359     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1360     ;;
1361 esac
1362
1363 if test "x$enable_osmesa" = xyes; then
1364     # only link libraries with osmesa if shared
1365     if test "$enable_static" = no; then
1366         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1367     else
1368         OSMESA_LIB_DEPS=""
1369     fi
1370     OSMESA_MESA_DEPS=""
1371     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1372 fi
1373 AC_SUBST([OSMESA_LIB_DEPS])
1374 AC_SUBST([OSMESA_MESA_DEPS])
1375 AC_SUBST([OSMESA_PC_REQ])
1376 AC_SUBST([OSMESA_PC_LIB_PRIV])
1377
1378 dnl
1379 dnl gbm configuration
1380 dnl
1381 if test "x$enable_gbm" = xauto; then
1382     case "$with_egl_platforms" in
1383         *drm*)
1384             enable_gbm=yes ;;
1385          *)
1386             enable_gbm=no ;;
1387     esac
1388 fi
1389 if test "x$enable_gbm" = xyes; then
1390     SRC_DIRS="$SRC_DIRS gbm"
1391
1392     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1393                       AC_MSG_ERROR([gbm needs udev]))
1394
1395     if test "x$enable_dri" = xyes; then
1396         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1397         if test "$SHARED_GLAPI" -eq 0; then
1398             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1399         fi
1400     fi
1401 fi
1402 GBM_PC_REQ_PRIV="libudev"
1403 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1404 AC_SUBST([GBM_PC_REQ_PRIV])
1405 AC_SUBST([GBM_PC_LIB_PRIV])
1406
1407 dnl
1408 dnl EGL configuration
1409 dnl
1410 EGL_CLIENT_APIS=""
1411
1412 if test "x$enable_egl" = xyes; then
1413     SRC_DIRS="$SRC_DIRS egl"
1414     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1415
1416     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1417
1418     if test "$enable_static" != yes; then
1419         # build egl_glx when libGL is built
1420         if test "x$enable_glx" = xyes; then
1421             HAVE_EGL_DRIVER_GLX=1
1422         fi
1423
1424         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1425                           [have_libudev=yes],[have_libudev=no])
1426         if test "$have_libudev" = yes; then
1427             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1428         fi
1429
1430         if test "x$enable_dri" = xyes; then
1431             HAVE_EGL_DRIVER_DRI2=1
1432         fi
1433
1434     fi
1435 fi
1436 AC_SUBST([EGL_LIB_DEPS])
1437
1438 dnl
1439 dnl EGL Gallium configuration
1440 dnl
1441 if test "x$enable_gallium_egl" = xyes; then
1442     if test "x$with_gallium_drivers" = x; then
1443         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1444     fi
1445     if test "x$enable_egl" = xno; then
1446         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1447     fi
1448     if test "x$have_libdrm" != xyes; then
1449         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1450     fi
1451
1452     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1453     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1454     HAVE_ST_EGL="yes"
1455 fi
1456
1457 dnl
1458 dnl gbm Gallium configuration
1459 dnl
1460 if test "x$enable_gallium_gbm" = xauto; then
1461     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1462         yesyesyes*drm*)
1463             enable_gallium_gbm=yes ;;
1464          *)
1465             enable_gallium_gbm=no ;;
1466     esac
1467 fi
1468 if test "x$enable_gallium_gbm" = xyes; then
1469     if test "x$with_gallium_drivers" = x; then
1470         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1471     fi
1472     if test "x$enable_gbm" = xno; then
1473         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1474     fi
1475     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1476     if test "x$enable_dri" = xno; then
1477         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1478     fi
1479
1480     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1481     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1482     HAVE_ST_GBM="yes"
1483     enable_gallium_loader=yes
1484 fi
1485
1486 dnl
1487 dnl X.Org DDX configuration
1488 dnl
1489 if test "x$enable_xorg" = xyes; then
1490     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1491     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1492     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1493     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1494         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1495         HAVE_XEXTPROTO_71="no")
1496     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1497     HAVE_ST_XORG=yes
1498 fi
1499
1500 dnl
1501 dnl XA configuration
1502 dnl
1503 if test "x$enable_xa" = xyes; then
1504 AC_PROG_AWK
1505 AC_PROG_GREP
1506 AC_CHECK_PROG(NM, nm, "nm")
1507 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1508 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1509 enable_xa=no
1510 fi
1511 fi
1512 if test "x$enable_xa" = xyes; then
1513     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1514     HAVE_ST_XA=yes
1515     AC_SUBST(AWK)
1516     AC_SUBST(GREP)
1517     AC_SUBST(NM)
1518 fi
1519
1520 dnl
1521 dnl OpenVG configuration
1522 dnl
1523 VG_LIB_DEPS=""
1524
1525 if test "x$enable_openvg" = xyes; then
1526     if test "x$enable_egl" = xno; then
1527         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1528     fi
1529     if test "x$with_gallium_drivers" = x; then
1530         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1531     fi
1532     if test "x$enable_gallium_egl" = xno; then
1533         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1534     fi
1535
1536     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1537     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1538     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1539     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1540     HAVE_ST_VEGA=yes
1541 fi
1542
1543 dnl
1544 dnl D3D1X configuration
1545 dnl
1546
1547 if test "x$enable_d3d1x" = xyes; then
1548     if test "x$with_gallium_drivers" = x; then
1549         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1550     fi
1551
1552     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1553     HAVE_ST_D3D1X=yes
1554 fi
1555
1556 dnl
1557 dnl Gallium G3DVL configuration
1558 dnl
1559 AC_ARG_ENABLE([gallium-g3dvl],
1560     [AS_HELP_STRING([--enable-gallium-g3dvl],
1561         [build gallium g3dvl @<:@default=disabled@:>@])],
1562     [enable_gallium_g3dvl="$enableval"],
1563     [enable_gallium_g3dvl=no])
1564 if test "x$enable_gallium_g3dvl" = xyes; then
1565     if test "x$with_gallium_drivers" = x; then
1566         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1567     fi
1568
1569     if test "x$enable_xvmc" = xauto; then
1570         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1571     fi
1572
1573     if test "x$enable_vdpau" = xauto; then
1574         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1575     fi
1576
1577     if test "x$enable_va" = xauto; then
1578         #don't enable vaapi state tracker even if package exists
1579         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1580         enable_va=no
1581     fi
1582 fi
1583
1584 if test "x$enable_xvmc" = xyes; then
1585     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1586     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1587     HAVE_ST_XVMC="yes"
1588 fi
1589
1590 if test "x$enable_vdpau" = xyes; then
1591     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1592     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1593     HAVE_ST_VDPAU="yes"
1594 fi
1595
1596 if test "x$enable_va" = xyes; then
1597     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1598     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1599     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1600     HAVE_ST_VA="yes"
1601 fi
1602
1603 dnl
1604 dnl OpenCL configuration
1605 dnl
1606
1607 AC_ARG_WITH([libclc-path],
1608    [AS_HELP_STRING([--with-libclc-path],
1609          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1610    [LIBCLC_PATH="$withval"],
1611    [LIBCLC_PATH=""])
1612
1613 AC_SUBST([LIBCLC_PATH])
1614
1615 if test "x$enable_opencl" = xyes; then
1616     if test "x$with_gallium_drivers" = x; then
1617         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1618     fi
1619
1620     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1621         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1622     fi
1623
1624     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1625     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1626     enable_gallium_loader=yes
1627 fi
1628
1629 dnl
1630 dnl GLU configuration
1631 dnl
1632 AC_ARG_ENABLE([glu],
1633     [AS_HELP_STRING([--disable-glu],
1634         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1635     [enable_glu="$enableval"],
1636     [enable_glu=yes])
1637
1638 if test "x$enable_glu" = xyes; then
1639     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1640         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1641         enable_glu=no
1642     fi
1643 fi
1644
1645 if test "x$enable_glu" = xyes; then
1646     SRC_DIRS="$SRC_DIRS glu"
1647
1648     if test "x$enable_glx" = xno; then
1649         # Link libGLU to libOSMesa instead of libGL
1650         GLU_LIB_DEPS=""
1651         GLU_PC_REQ="osmesa"
1652         if test "$enable_static" = no; then
1653             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1654         else
1655             GLU_MESA_DEPS=""
1656         fi
1657     else
1658         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1659         GLU_PC_REQ="gl"
1660         GLU_PC_LIB_PRIV="-lm"
1661         if test "$enable_static" = no; then
1662             GLU_LIB_DEPS="-lm"
1663             GLU_MESA_DEPS='-l$(GL_LIB)'
1664         else
1665             GLU_LIB_DEPS=""
1666             GLU_MESA_DEPS=""
1667         fi
1668     fi
1669 fi
1670 if test "$enable_static" = no; then
1671     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1672 fi
1673 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1674 AC_SUBST([GLU_LIB_DEPS])
1675 AC_SUBST([GLU_MESA_DEPS])
1676 AC_SUBST([GLU_PC_REQ])
1677 AC_SUBST([GLU_PC_REQ_PRIV])
1678 AC_SUBST([GLU_PC_LIB_PRIV])
1679 AC_SUBST([GLU_PC_CFLAGS])
1680
1681 AC_SUBST([PROGRAM_DIRS])
1682
1683 dnl
1684 dnl Gallium configuration
1685 dnl
1686 if test "x$with_gallium_drivers" != x; then
1687     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1688 fi
1689
1690 AC_SUBST([LLVM_BINDIR])
1691 AC_SUBST([LLVM_CFLAGS])
1692 AC_SUBST([LLVM_CPPFLAGS])
1693 AC_SUBST([LLVM_CXXFLAGS])
1694 AC_SUBST([LLVM_LIBDIR])
1695 AC_SUBST([LLVM_LIBS])
1696 AC_SUBST([LLVM_LDFLAGS])
1697 AC_SUBST([LLVM_INCLUDEDIR])
1698 AC_SUBST([LLVM_VERSION])
1699
1700 case "x$enable_opengl$enable_gles1$enable_gles2" in
1701 x*yes*)
1702     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1703     ;;
1704 esac
1705
1706 AC_SUBST([VG_LIB_DEPS])
1707 AC_SUBST([EGL_CLIENT_APIS])
1708
1709 dnl
1710 dnl EGL Platforms configuration
1711 dnl
1712 AC_ARG_WITH([egl-platforms],
1713     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1714         [comma delimited native platforms libEGL supports, e.g.
1715         "x11,drm" @<:@default=auto@:>@])],
1716     [with_egl_platforms="$withval"],
1717     [if test "x$enable_egl" = xyes; then
1718         with_egl_platforms="x11"
1719     else
1720         with_egl_platforms=""
1721     fi])
1722
1723 EGL_PLATFORMS=""
1724
1725 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1726     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1727 fi
1728
1729 # Do per-EGL platform setups and checks
1730 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1731 for plat in $egl_platforms; do
1732         case "$plat" in
1733         fbdev|null)
1734                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1735                 ;;
1736
1737         wayland)
1738                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1739                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1740                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1741
1742                 m4_ifdef([WAYLAND_SCANNER_RULES],
1743                          [WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/egl/wayland/wayland-drm/protocol'])])
1744                 ;;
1745
1746         x11)
1747                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1748                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1749                 save_LIBS="$LIBS"
1750                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1751                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1752                 LIBS="$save_LIBS"
1753                 ;;
1754
1755         drm)
1756                 test "x$enable_gbm" = "xno" &&
1757                         AC_MSG_ERROR([EGL platform drm needs gbm])
1758                 ;;
1759
1760         android|gdi)
1761                 ;;
1762
1763         *)
1764                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1765                 ;;
1766         esac
1767
1768         case "$plat$have_libudev" in
1769                 waylandno|drmno)
1770                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1771         esac
1772 done
1773
1774 # libEGL wants to default to the first platform specified in
1775 # ./configure.  parse that here.
1776 if test "x$egl_platforms" != "x"; then
1777     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1778     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1779 else
1780     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1781 fi
1782
1783 EGL_PLATFORMS="$egl_platforms"
1784
1785 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1786 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1787 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1788 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1789 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1790
1791 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1792 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1793
1794 AC_SUBST([EGL_NATIVE_PLATFORM])
1795 AC_SUBST([EGL_PLATFORMS])
1796 AC_SUBST([EGL_CFLAGS])
1797
1798 AC_ARG_WITH([egl-driver-dir],
1799     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1800                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1801     [EGL_DRIVER_INSTALL_DIR="$withval"],
1802     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1803 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1804
1805 AC_ARG_WITH([xorg-driver-dir],
1806     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1807                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1808     [XORG_DRIVER_INSTALL_DIR="$withval"],
1809     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1810 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1811
1812 AC_ARG_WITH([max-width],
1813     [AS_HELP_STRING([--with-max-width=N],
1814                     [Maximum framebuffer width (4096)])],
1815     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1816      AS_IF([test "${withval}" -gt "4096"],
1817            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1818 )
1819 AC_ARG_WITH([max-height],
1820     [AS_HELP_STRING([--with-max-height=N],
1821                     [Maximum framebuffer height (4096)])],
1822     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1823      AS_IF([test "${withval}" -gt "4096"],
1824            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1825 )
1826
1827 dnl
1828 dnl Gallium LLVM
1829 dnl
1830 AC_ARG_ENABLE([gallium-llvm],
1831     [AS_HELP_STRING([--enable-gallium-llvm],
1832         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1833     [enable_gallium_llvm="$enableval"],
1834     [enable_gallium_llvm=auto])
1835
1836 AC_ARG_WITH([llvm-shared-libs],
1837     [AS_HELP_STRING([--with-llvm-shared-libs],
1838         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1839     [with_llvm_shared_libs=yes],
1840     [with_llvm_shared_libs=no])
1841
1842 if test "x$with_gallium_drivers" = x; then
1843     enable_gallium_llvm=no
1844 fi
1845 if test "x$enable_gallium_llvm" = xauto; then
1846     case "$host_cpu" in
1847     i*86|x86_64) enable_gallium_llvm=yes;;
1848     esac
1849 fi
1850 if test "x$enable_gallium_llvm" = xyes; then
1851     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1852
1853     if test "x$LLVM_CONFIG" != xno; then
1854         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1855         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1856         if test "x$with_llvm_shared_libs" = xyes; then
1857             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1858             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1859         else
1860             LLVM_LIBS="`$LLVM_CONFIG --libs engine bitwriter`"
1861             if test "x$enable_opencl" = xyes; then
1862                 LLVM_LIBS="${LLVM_LIBS} `llvm-config --libs ipo linker instrumentation`"
1863             fi
1864         fi
1865         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1866         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1867         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1868         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1869         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1870         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1871         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1872         MESA_LLVM=1
1873     else
1874         MESA_LLVM=0
1875     fi
1876 else
1877     MESA_LLVM=0
1878 fi
1879
1880 dnl Directory for XVMC libs
1881 AC_ARG_WITH([xvmc-libdir],
1882     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1883         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1884     [XVMC_LIB_INSTALL_DIR="$withval"],
1885     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1886 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1887
1888 dnl
1889 dnl Gallium Tests
1890 dnl
1891 if test "x$enable_gallium_tests" = xyes; then
1892     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1893     enable_gallium_loader=yes
1894 fi
1895
1896 dnl Directory for VDPAU libs
1897 AC_ARG_WITH([vdpau-libdir],
1898     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1899         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1900     [VDPAU_LIB_INSTALL_DIR="$withval"],
1901     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1902 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1903
1904 dnl Directory for VA libs
1905 AC_ARG_WITH([va-libdir],
1906     [AS_HELP_STRING([--with-va-libdir=DIR],
1907         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1908     [VA_LIB_INSTALL_DIR="$withval"],
1909     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1910 AC_SUBST([VA_LIB_INSTALL_DIR])
1911
1912 dnl Directory for OpenCL libs
1913 AC_ARG_WITH([opencl-libdir],
1914     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1915         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1916     [OPENCL_LIB_INSTALL_DIR="$withval"],
1917     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1918 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1919
1920 dnl
1921 dnl Gallium helper functions
1922 dnl
1923 gallium_check_st() {
1924     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1925          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1926          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1927          if test "x$have_libdrm" != xyes; then
1928             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1929          fi
1930          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1931     fi
1932     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1933          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1934     fi
1935     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1936          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1937     fi
1938     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1939          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1940     fi
1941     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1942          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1943     fi
1944     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1945          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1946     fi
1947     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1948          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1949     fi
1950 }
1951
1952 gallium_require_llvm() {
1953     if test "x$MESA_LLVM" = x0; then
1954         case "$host_cpu" in
1955         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1956         esac
1957     fi
1958 }
1959
1960 gallium_require_drm_loader() {
1961     if test "x$enable_gallium_loader" = xyes; then
1962         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1963                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1964         if test "x$have_libdrm" != xyes; then
1965             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1966         fi
1967         enable_gallium_drm_loader=yes
1968     fi
1969 }
1970
1971 dnl Gallium drivers
1972 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1973 if test "x$with_gallium_drivers" != x; then
1974     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1975     for driver in $gallium_drivers; do
1976         case "x$driver" in
1977         xsvga)
1978             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1979             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1980             ;;
1981         xi915)
1982             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1983             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1984             if test "x$MESA_LLVM" = x1; then
1985                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1986             fi
1987             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1988             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1989             ;;
1990         xr300)
1991             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1992             gallium_require_llvm "Gallium R300"
1993             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1994             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1995             ;;
1996         xr600)
1997             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1998             gallium_require_drm_loader
1999             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
2000             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
2001                 if test "x$LLVM_VERSION" != "x3.1"; then
2002                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
2003                 fi
2004                 NEED_RADEON_GALLIUM=yes;
2005             fi
2006             if test "x$enable_r600_llvm" = xyes; then
2007                 USE_R600_LLVM_COMPILER=yes;
2008             fi
2009             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
2010                 LLVM_LIBS="${LLVM_LIBS} `llvm-config --libs bitreader asmparser`"
2011             fi
2012             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
2013             ;;
2014         xradeonsi)
2015             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2016             gallium_require_drm_loader
2017             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
2018             if test "x$LLVM_VERSION" != "x3.1"; then
2019                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
2020             fi
2021             NEED_RADEON_GALLIUM=yes;
2022             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi"
2023             ;;
2024         xnouveau)
2025             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2026             gallium_require_drm_loader
2027             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
2028             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
2029             ;;
2030         xswrast)
2031             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
2032             if test "x$MESA_LLVM" = x1; then
2033                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2034             fi
2035
2036             if test "x$HAVE_ST_DRI" = xyes; then
2037                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2038             fi
2039             if test "x$HAVE_ST_VDPAU" = xyes; then
2040                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
2041             fi
2042             if test "x$HAVE_ST_XVMC" = xyes; then
2043                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
2044             fi
2045             if test "x$HAVE_ST_VA" = xyes; then
2046                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
2047             fi
2048             if test "x$HAVE_ST_VDPAU" = xyes ||
2049                test "x$HAVE_ST_XVMC" = xyes ||
2050                test "x$HAVE_ST_VA" = xyes; then
2051                if test "x$HAVE_WINSYS_XLIB" != xyes; then
2052                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
2053                fi
2054             fi
2055             ;;
2056         *)
2057             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2058             ;;
2059         esac
2060     done
2061 fi
2062
2063 if test "x$enable_gallium_loader" = xyes; then
2064     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2065     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
2066     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
2067     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
2068
2069     if test "x$HAVE_WINSYS_XLIB" = xyes; then
2070         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2071         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
2072     fi
2073
2074     if test "x$enable_gallium_drm_loader" = xyes; then
2075         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2076     fi
2077
2078     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2079     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2080 fi
2081
2082 dnl Tell Automake which drivers to build
2083 for driver in $GALLIUM_DRIVERS_DIRS; do
2084     case "x$driver" in
2085         xgalahad)
2086             HAVE_GALAHAD_GALLIUM=yes;
2087             ;;
2088         xidentity)
2089             HAVE_IDENTITY_GALLIUM=yes;
2090             ;;
2091         xnoop)
2092             HAVE_NOOP_GALLIUM=yes;
2093             ;;
2094         *)
2095             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2096             ;;
2097     esac
2098 done
2099
2100 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2101 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2102 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2103 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2104 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2105 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2106 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2107 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2108 AC_SUBST([GALLIUM_MAKE_DIRS])
2109
2110 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
2111 AM_CONDITIONAL(HAVE_DRI_DRIVER, echo "$DRIVER_DIRS" | grep 'dri' >/dev/null 2>&1)
2112 AM_CONDITIONAL(HAVE_OSMESA_DRIVER, echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1)
2113
2114 AM_CONDITIONAL(HAVE_X86_ASM, echo "$ASM_FLAGS" | grep 'X86_ASM' >/dev/null 2>&1)
2115 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$ASM_FLAGS" | grep 'X86_64_ASM' >/dev/null 2>&1)
2116 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$ASM_FLAGS" | grep 'SPARC_ASM' >/dev/null 2>&1)
2117
2118 dnl prepend CORE_DIRS to SRC_DIRS
2119 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2120
2121 dnl Restore LDFLAGS and CPPFLAGS
2122 LDFLAGS="$_SAVE_LDFLAGS"
2123 CPPFLAGS="$_SAVE_CPPFLAGS"
2124
2125 dnl Add user CFLAGS and CXXFLAGS
2126 CFLAGS="$CFLAGS $USER_CFLAGS"
2127 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2128
2129 dnl Substitute the config
2130 AC_CONFIG_FILES([configs/autoconf
2131                 Makefile
2132                 src/Makefile
2133                 src/gallium/auxiliary/pipe-loader/Makefile
2134                 src/gallium/state_trackers/clover/Makefile
2135                 src/gallium/drivers/Makefile
2136                 src/gallium/drivers/r300/Makefile
2137                 src/gallium/drivers/r600/Makefile
2138                 src/gallium/targets/opencl/Makefile
2139                 src/gbm/Makefile
2140                 src/gbm/main/gbm.pc
2141                 src/egl/drivers/Makefile
2142                 src/egl/drivers/dri2/Makefile
2143                 src/egl/drivers/glx/Makefile
2144                 src/egl/main/Makefile
2145                 src/egl/main/egl.pc
2146                 src/egl/wayland/Makefile
2147                 src/egl/wayland/wayland-egl/Makefile
2148                 src/egl/wayland/wayland-egl/wayland-egl.pc
2149                 src/egl/wayland/wayland-drm/Makefile
2150                 src/glsl/tests/Makefile
2151                 src/glx/Makefile
2152                 src/mapi/shared-glapi/Makefile
2153                 src/gtest/Makefile
2154                 src/mesa/libdricore/Makefile
2155                 src/mesa/drivers/dri/dri.pc
2156                 src/mesa/drivers/dri/Makefile
2157                 src/mesa/drivers/dri/common/Makefile
2158                 src/mesa/drivers/dri/i915/Makefile
2159                 src/mesa/drivers/dri/i965/Makefile
2160                 src/mesa/drivers/dri/nouveau/Makefile
2161                 src/mesa/drivers/dri/r200/Makefile
2162                 src/mesa/drivers/dri/radeon/Makefile
2163                 src/mesa/drivers/dri/swrast/Makefile
2164                 tests/Makefile
2165                 tests/glx/Makefile])
2166
2167 dnl Replace the configs/current symlink
2168 AC_CONFIG_COMMANDS([configs],[
2169 if test -f configs/current || test -L configs/current; then
2170     rm -f configs/current
2171 fi
2172 ln -s autoconf configs/current
2173 ])
2174
2175 dnl Sort the dirs alphabetically
2176 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2177 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2178 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2179 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2180 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2181
2182 AC_OUTPUT
2183
2184 dnl
2185 dnl Output some configuration info for the user
2186 dnl
2187 echo ""
2188 echo "        prefix:          $prefix"
2189 echo "        exec_prefix:     $exec_prefix"
2190 echo "        libdir:          $libdir"
2191 echo "        includedir:      $includedir"
2192
2193 dnl API info
2194 echo ""
2195 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2196 echo "        OpenVG:          $enable_openvg"
2197
2198 dnl Driver info
2199 echo ""
2200 if test "x$enable_osmesa" != xno; then
2201         echo "        OSMesa:          lib$OSMESA_LIB"
2202 else
2203         echo "        OSMesa:          no"
2204 fi
2205
2206 if test "x$enable_dri" != xno; then
2207         # cleanup the drivers var
2208         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2209         if test "x$DRI_DIRS" = x; then
2210             echo "        DRI drivers:     no"
2211         else
2212             echo "        DRI drivers:     $dri_dirs"
2213         fi
2214         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2215 fi
2216
2217 case "x$enable_glx$enable_xlib_glx" in
2218 xyesyes)
2219     echo "        GLX:             Xlib-based"
2220     ;;
2221 xyesno)
2222     echo "        GLX:             DRI-based"
2223     ;;
2224 *)
2225     echo "        GLX:             $enable_glx"
2226     ;;
2227 esac
2228
2229 echo ""
2230 echo "        GLU:             $enable_glu"
2231
2232 dnl EGL
2233 echo ""
2234 echo "        EGL:             $enable_egl"
2235 if test "$enable_egl" = yes; then
2236     echo "        EGL platforms:   $EGL_PLATFORMS"
2237
2238     egl_drivers=""
2239     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2240         egl_drivers="$egl_drivers builtin:egl_glx"
2241     fi
2242     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2243         egl_drivers="$egl_drivers builtin:egl_dri2"
2244     fi
2245
2246     if test "x$HAVE_ST_EGL" = xyes; then
2247         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2248         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2249     else
2250         echo "        EGL drivers:    $egl_drivers"
2251     fi
2252 fi
2253
2254 echo ""
2255 if test "x$MESA_LLVM" = x1; then
2256     echo "        llvm:            yes"
2257     echo "        llvm-config:     $LLVM_CONFIG"
2258     echo "        llvm-version:    $LLVM_VERSION"
2259 else
2260     echo "        llvm:            no"
2261 fi
2262
2263 echo ""
2264 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2265     echo "        Gallium:         yes"
2266     echo "        Gallium dirs:    $GALLIUM_DIRS"
2267     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2268     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2269     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2270     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2271 else
2272     echo "        Gallium:         no"
2273 fi
2274
2275
2276 dnl Libraries
2277 echo ""
2278 echo "        Shared libs:     $enable_shared"
2279 echo "        Static libs:     $enable_static"
2280
2281 dnl Compiler options
2282 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2283 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2284     $SED 's/^ *//;s/  */ /;s/ *$//'`
2285 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2286     $SED 's/^ *//;s/  */ /;s/ *$//'`
2287 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2288 echo ""
2289 echo "        CFLAGS:          $cflags"
2290 echo "        CXXFLAGS:        $cxxflags"
2291 echo "        Macros:          $defines"
2292 echo ""
2293 echo "        PYTHON2:         $PYTHON2"
2294
2295 echo ""
2296 echo "        Run '${MAKE-make}' to build Mesa"
2297 echo ""