configure.ac

   1 AC_PREREQ(2.52)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, cvs and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for cvs/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.11.1,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 dnl initialize automake
  13 AM_INIT_AUTOMAKE
  14
  15 dnl define PACKAGE_VERSION_* variables
  16 AS_VERSION
  17
  18 dnl check if this is a release version
  19 AS_NANO(GST_CVS="no", GST_CVS="yes")
  20
  21 dnl can autoconf find the source ?
  22 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  23
  24 dnl define the output header for config
  25 AM_CONFIG_HEADER([config.h])
  26
  27 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  28 AM_MAINTAINER_MODE
  29
  30 dnl sets host_* variables
  31 AC_CANONICAL_HOST
  32
  33 dnl our libraries and install dirs use major.minor as a version
  34 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  35 dnl we override it here if we need to for the release candidate of new series
  36 GST_MAJORMINOR=0.10
  37 AC_SUBST(GST_MAJORMINOR)
  38
  39 dnl CURRENT, REVISION, AGE
  40 dnl - library source changed -> increment REVISION
  41 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  42 dnl - interfaces added -> increment AGE
  43 dnl - interfaces removed -> AGE = 0
  44 dnl sets GST_LT_LDFLAGS
  45 AS_LIBTOOL(GST, 8, 0, 8)
  46
  47 dnl FIXME: this macro doesn't actually work;
  48 dnl the generated libtool script has no support for the listed tags.
  49 dnl So this needs to be fixed first if we want to use this
  50 dnl AS_LIBTOOL_TAGS
  51
  52 AM_PROG_LIBTOOL
  53
  54 dnl *** required versions of GStreamer stuff ***
  55 GST_REQ=0.10.11.1
  56
  57 dnl *** autotools stuff ****
  58
  59 dnl allow for different autotools
  60 AS_AUTOTOOLS_ALTERNATE
  61
  62 dnl Add parameters for aclocal
  63 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  64
  65 dnl set up gettext
  66 dnl the version check needs to stay here because autopoint greps for it
  67 AM_GNU_GETTEXT_VERSION([0.11.5])
  68 AM_GNU_GETTEXT([external])
  69 GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  70
  71 dnl *** check for arguments to configure ***
  72
  73 GST_ARG_DEBUG
  74 GST_ARG_PROFILING
  75 GST_ARG_VALGRIND
  76 GST_ARG_GCOV
  77
  78 GST_ARG_EXAMPLES
  79
  80 GST_ARG_WITH_PKG_CONFIG_PATH
  81 GST_ARG_WITH_PACKAGE_NAME
  82 GST_ARG_WITH_PACKAGE_ORIGIN
  83
  84 dnl let distro override plugin install helper path
  85 AC_ARG_WITH(install-plugins-helper,
  86   AC_HELP_STRING([--with-install-plugins-helper],
  87     [specify path of helper script to call to install plugins]),
  88   [
  89     case "${withval}" in
  90       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  91       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
  92       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
  93     esac
  94   ],
  95   [
  96     dnl Default value
  97     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
  98   ]
  99 )
 100 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 101 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 102     [plugin install helper script])
 103 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 104
 105
 106 dnl these are all the gst plug-ins, compilable without additional libs
 107 GST_PLUGINS_ALL="\
 108         adder \
 109         audioconvert \
 110         audiorate \
 111         audioresample \
 112         audiotestsrc \
 113         ffmpegcolorspace \
 114         gdp \
 115         playback \
 116         typefind \
 117         videotestsrc \
 118         videorate \
 119         videoscale \
 120         volume \
 121         "
 122 AC_SUBST(GST_PLUGINS_ALL)
 123
 124 GST_PLUGINS_SELECTED=""
 125
 126 AC_ARG_WITH(plugins,
 127     AC_HELP_STRING([--with-plugins],
 128       [comma-separated list of plug-ins to compile]),
 129     [for i in `echo $withval | tr , ' '`; do
 130         if echo $GST_PLUGINS_ALL | grep $i > /dev/null
 131         then
 132             GST_PLUGINS_SELECTED="$GST_PLUGINS_SELECTED $i"
 133         else
 134             echo "plug-in $i not recognized, ignoring..."
 135         fi
 136     done],
 137     [GST_PLUGINS_SELECTED=$GST_PLUGINS_ALL])
 138
 139 AC_SUBST(GST_PLUGINS_SELECTED)
 140
 141 dnl ext plug-ins; plug-ins that have external dependencies
 142 GST_CHECK_FEATURE(EXTERNAL, [enable building of plug-ins with external deps],,
 143   [HAVE_EXTERNAL=yes], enabled,
 144   [
 145     AC_MSG_NOTICE(building external plug-ins)
 146     BUILD_EXTERNAL="yes"
 147   ],[
 148     AC_MSG_NOTICE(all plug-ins with external dependencies will not be built)
 149     BUILD_EXTERNAL="no"
 150   ])
 151 AM_CONDITIONAL(BUILD_EXTERNAL, test "x$BUILD_EXTERNAL" = "xyes")
 152
 153 dnl *** checks for platform ***
 154
 155 dnl * hardware/architecture *
 156
 157 dnl common/m4/gst-arch.m4
 158 dnl check CPU type
 159 GST_ARCH
 160
 161 dnl *** checks for programs ***
 162
 163 dnl find a compiler
 164 AC_PROG_CC
 165
 166 dnl determine c++ compiler
 167 AC_PROG_CXX
 168 dnl determine if c++ is available on this system
 169 AC_CHECK_PROG(HAVE_CXX, $CXX, yes, no)
 170
 171 dnl determine c++ preprocessor
 172 dnl FIXME: do we need this ?
 173 AC_PROG_CXXCPP
 174
 175 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 176 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 177
 178 dnl check for documentation tools
 179 GTK_DOC_CHECK([1.3])
 180 AS_PATH_PYTHON([2.1])
 181 GST_PLUGIN_DOCS([1.3],[2.1])
 182
 183 dnl *** checks for libraries ***
 184
 185 dnl For interactive UNIX (a Sun thing)
 186 dnl FIXME: this adds -lcposix to LIBS, but I doubt we use LIBS
 187 AC_ISC_POSIX
 188
 189 dnl libm, for sin() etc.
 190 AC_CHECK_LIBM
 191 AC_SUBST(LIBM)
 192
 193 dnl *** checks for header files ***
 194
 195 dnl check if we have ANSI C header files
 196 AC_HEADER_STDC
 197
 198 dnl used in gst/ffmpegcolorspace/mem.c
 199 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 200 AC_CHECK_HEADERS([malloc.h])
 201
 202 dnl used in gst/subparse/gstsubparse.c
 203 AC_CHECK_HEADERS([regex.h], HAVE_REGEX_H="yes", HAVE_REGEX_H="no")
 204 AM_CONDITIONAL(HAVE_REGEX_H, test "x$HAVE_REGEX_H" = "xyes")
 205
 206 dnl used in gst/tcp
 207 AC_CHECK_HEADERS([sys/socket.h],
 208   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 209 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 210
 211 dnl used in gst-libs/gst/utils and associated unit test
 212 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 213
 214 dnl ffmpegcolorspace includes _stdint.h
 215 dnl also, Windows does not have long long
 216 AX_CREATE_STDINT_H
 217
 218 dnl *** checks for functions ***
 219 AC_CHECK_FUNCS([localtime_r])
 220
 221 dnl *** checks for types/defines ***
 222
 223 dnl Check for FIONREAD ioctl declaration
 224 dnl used in gst/tcp
 225 GST_CHECK_FIONREAD
 226
 227 dnl *** checks for structures ***
 228
 229 dnl *** checks for compiler characteristics ***
 230
 231 dnl make sure we can use "inline" from C code
 232 AC_C_INLINE
 233
 234 dnl *** checks for library functions ***
 235
 236 dnl Check for fast float to int casting as defined in C99
 237 dnl used in gst-libs/gst/floatcast/floatcast.h
 238 AC_C99_FUNC_LRINT
 239 AC_C99_FUNC_LRINTF
 240
 241 dnl Check for a way to display the function name in debug output
 242 GST_CHECK_FUNCTION
 243
 244 dnl *** checks for dependency libraries ***
 245
 246 dnl GLib is required
 247 GST_GLIB_CHECK([2.6])
 248
 249 dnl liboil is required
 250 PKG_CHECK_MODULES(LIBOIL, liboil-0.3 >= 0.3.8, HAVE_LIBOIL=yes, HAVE_LIBOIL=no)
 251 if test "x$HAVE_LIBOIL" != "xyes"
 252 then
 253   AC_ERROR([liboil-0.3.8 or later is required])
 254 fi
 255
 256 dnl checks for gstreamer
 257 dnl uninstalled is selected preferentially -- see pkg-config(1)
 258 GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ])
 259 GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ])
 260 GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ])
 261 GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ])
 262 GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 263
 264 dnl FIXME: get rid of this by making sure gstreamer-check brings it in
 265 dnl check for "check", unit testing library/header
 266 AM_PATH_CHECK(0.9.2, HAVE_CHECK=yes, HAVE_CHECK=no)
 267 AM_CONDITIONAL(HAVE_CHECK, test "x$HAVE_CHECK" = "xyes")
 268
 269 dnl Check for documentation xrefs
 270 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 271 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 272 AC_SUBST(GLIB_PREFIX)
 273 AC_SUBST(GST_PREFIX)
 274
 275 dnl GTK is optional and used in examples
 276 HAVE_GTK=NO
 277 PKG_CHECK_MODULES(GTK2, gtk+-2.0 >= 2.2.0, HAVE_GTK_22=yes, HAVE_GTK_22=no)
 278 if test "x$HAVE_GTK_22" = "xyes"; then
 279   HAVE_GTK=yes
 280   GTK_VERSION=`$PKG_CONFIG --variable=gtk_binary_version gtk+-2.0`
 281   AC_SUBST(GTK_VERSION)
 282   GTK_PREFIX=`$PKG_CONFIG --variable=prefix gdk-pixbuf-2.0`
 283   AC_SUBST(GTK_BASE_DIR)
 284 else
 285   PKG_CHECK_MODULES(GTK2, gtk+-2.0, HAVE_GTK_20=yes, HAVE_GTK_20=no)
 286 fi
 287 if test "x$HAVE_GTK_20" = "xyes"; then
 288   HAVE_GTK=yes
 289 fi
 290 GTK_CFLAGS=$GTK2_CFLAGS
 291 GTK_LIBS=$GTK2_LIBS
 292 AC_SUBST(GTK_LIBS)
 293 AC_SUBST(GTK_CFLAGS)
 294 AC_SUBST(HAVE_GTK)
 295 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 296
 297 dnl *** set variables based on configure arguments ***
 298
 299 dnl set license and copyright notice
 300 GST_LICENSE="LGPL"
 301 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 302 AC_SUBST(GST_LICENSE)
 303
 304 dnl set location of plugin directory
 305 GST_SET_PLUGINDIR
 306
 307 dnl define an ERROR_CFLAGS Makefile variable
 308 GST_SET_ERROR_CFLAGS($GST_CVS)
 309
 310 dnl define correct level for debugging messages
 311 GST_SET_LEVEL_DEFAULT($GST_CVS)
 312
 313 dnl used in examples
 314 GST_DEFAULT_ELEMENTS
 315
 316 dnl *** sys plug-ins ***
 317
 318 echo
 319 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 320 echo
 321
 322 dnl *** X11 ***
 323 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 324 GST_CHECK_FEATURE(X, [X libraries and plugins],
 325                   [ximagesink], [
 326   AC_PATH_XTRA
 327   ac_cflags_save="$CFLAGS"
 328   ac_cppflags_save="$CPPFLAGS"
 329   CFLAGS="$CFLAGS $X_CFLAGS"
 330   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 331
 332   dnl now try to find the HEADER
 333   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 334
 335   if test "x$HAVE_X" = "xno"
 336   then
 337     AC_MSG_NOTICE([cannot find X11 development files])
 338   else
 339     dnl this is much more than we want
 340     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 341     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 342     dnl it does not add the libs; therefore we add them here
 343     X_LIBS="$X_LIBS -lX11"
 344     AC_SUBST(X_CFLAGS)
 345     AC_SUBST(X_LIBS)
 346   fi
 347   AC_SUBST(HAVE_X)
 348   CFLAGS="$ac_cflags_save"
 349   CPPFLAGS="$ac_cppflags_save"
 350 ])
 351
 352 dnl Check for Xv extension
 353 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 354 GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 355                   [xvimagesink], [
 356   GST_CHECK_XV
 357 ])
 358
 359 dnl check for X Shm
 360 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 361 GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 362   if test x$HAVE_X = xyes; then
 363     AC_CHECK_LIB(Xext, XShmAttach,
 364                  HAVE_XSHM="yes", HAVE_XSHM="no",
 365                  $X_LIBS)
 366     if test "x$HAVE_XSHM" = "xyes"; then
 367       XSHM_LIBS="-lXext"
 368     else
 369       dnl On AIX, it is in XextSam instead, but we still need -lXext
 370       AC_CHECK_LIB(XextSam, XShmAttach,
 371                    HAVE_XSHM="yes", HAVE_XSHM="no",
 372                    $X_LIBS)
 373       if test "x$HAVE_XSHM" = "xyes"; then
 374         XSHM_LIBS="-lXext -lXextSam"
 375       fi
 376     fi
 377   fi
 378 ], , [
 379   AC_SUBST(HAVE_XSHM)
 380   AC_SUBST(XSHM_LIBS)
 381 ])
 382
 383 dnl v4l/v4l2 checks have been moved down because they require X
 384
 385 dnl *** Video 4 Linux ***
 386 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 387 dnl renamed to GST_V4L in accordance with V4L2 below
 388 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 389 GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 390   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 391 #include <sys/types.h>
 392 #define _LINUX_TIME_H
 393 #define __user
 394 #include <linux/videodev.h>
 395   ])
 396
 397   dnl we can build v4l without Xv, but then we won't have XOverlay support
 398   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 399   then
 400     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 401     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 402   fi
 403 ])
 404
 405 dnl *** ext plug-ins ***
 406 dnl keep this list sorted alphabetically !
 407
 408 if test "x$BUILD_EXTERNAL" = "xyes"; then
 409
 410 echo
 411 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 412 echo
 413
 414 dnl *** alsa ***
 415 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 416 GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 417   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 418     HAVE_ALSA="yes"
 419     AC_SUBST(ALSA_CFLAGS)
 420     AC_SUBST(ALSA_LIBS)
 421   ], [
 422     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 423   ])
 424 ])
 425
 426 dnl *** CDParanoia ***
 427 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 428 GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 429   GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 430                       cdda_open, -lm,
 431                       cdda_interface.h,
 432                       CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 433                       HEADER_DIR="no"
 434                       FOUND_CDPARANOIA="yes")
 435   if test "x$FOUND_CDPARANOIA" != "xyes";
 436   then
 437     GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 438                         cdda_open, -lm,
 439                         cdda/cdda_interface.h,
 440                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 441                         HEADER_DIR="yes"
 442                         FOUND_CDPARANOIA="yes")
 443   fi
 444   if test "x$HEADER_DIR" = "xyes";
 445   then
 446     AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 447                        defined if cdda headers are in a cdda/ directory)
 448   fi
 449   AC_SUBST(CDPARANOIA_LIBS)
 450 ])
 451 dnl FIXME : add second check somehow if that is necessary
 452 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 453 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 454
 455 dnl *** GNOME VFS ***
 456 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 457 GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 458   GST_PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0)
 459 ])
 460
 461 dnl *** libvisual ***
 462 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 463 GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 464   GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 465   if test $HAVE_LIBVISUAL = no
 466   then
 467     GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 468   fi
 469 ])
 470
 471 dnl *** ogg ***
 472 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 473 GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 474   GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 475   if test $HAVE_OGG = no
 476   then
 477     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 478     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 479   fi
 480 ])
 481
 482 dnl *** pango ***
 483 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 484 GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 485   GST_PKG_CHECK_MODULES(PANGO, pango pangoft2)
 486 ])
 487
 488 dnl *** theora ***
 489 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 490 GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 491   GST_PKG_CHECK_MODULES(THEORA, theora)
 492   if test $HAVE_THEORA = no
 493   then
 494     GST_CHECK_LIBHEADER(THEORA, theora, theora_version_string, "-logg", theora/theora.h, THEORA_LIBS="-ltheora -logg")
 495     AC_SUBST(THEORA_LIBS)
 496   fi
 497 ])
 498
 499 dnl *** vorbis ***
 500 dnl AM_PATH_VORBIS only takes two options
 501 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 502 GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 503   GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 504   if test $HAVE_VORBIS = no
 505   then
 506     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 507     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 508   fi
 509 ])
 510
 511 if test "x$HAVE_VORBIS" = "xyes"; then
 512   ac_cflags_save="$CFLAGS"
 513   dnl FIXME: does this work on non-gcc? -- Company
 514   dnl FIXME: no, it doesn't.  Why is this here in the first place ? -- thomasvs
 515   CFLAGS="-Wall -Werror"
 516   AC_COMPILE_IFELSE(
 517     AC_LANG_PROGRAM([
 518 #include <vorbis/codec.h>
 519                      ],[
 520 vorbis_dsp_state *v;
 521
 522 vorbis_synthesis_restart (v);
 523                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 524   if test "x$HAVE_VSR" = "xyes"; then
 525     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 526                        [defined if vorbis_synthesis_restart is present])
 527   fi
 528   CFLAGS="$ac_cflags_save"
 529 fi
 530
 531 else
 532
 533 dnl not building plugins with external dependencies,
 534 dnl but we still need to set the conditionals
 535 AM_CONDITIONAL(USE_ALSA, false)
 536 AM_CONDITIONAL(USE_CDPARANOIA, false)
 537 AM_CONDITIONAL(USE_GNOME_VFS, false)
 538 AM_CONDITIONAL(USE_LIBVISUAL, false)
 539 AM_CONDITIONAL(USE_OGG, false)
 540 AM_CONDITIONAL(USE_PANGO, false)
 541 AM_CONDITIONAL(USE_THEORA, false)
 542 AM_CONDITIONAL(USE_VORBIS, false)
 543
 544 fi dnl of EXT plugins
 545
 546 dnl seeking needs freetype, so check for it here
 547 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 548   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 549 ])
 550 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 551 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 552 AC_SUBST(FT2_CFLAGS)
 553 AC_SUBST(FT2_LIBS)
 554
 555 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 556
 557 dnl Overview:
 558 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 559 dnl GST_*:              flags shared by built objects to link against GStreamer
 560 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 561 dnl                          (compare to other modules) or for i18n
 562 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 563 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 564 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 565 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 566
 567 dnl GST_OPTION_CFLAGS
 568 if test "x$USE_DEBUG" = xyes; then
 569    PROFILE_CFLAGS="-g"
 570 fi
 571 AC_SUBST(PROFILE_CFLAGS)
 572
 573 DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 574 AC_SUBST(DEPRECATED_CFLAGS)
 575
 576 dnl every flag in GST_OPTION_CFLAGS can be overridden at make time
 577 GST_OPTION_CFLAGS="\$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 578 AC_SUBST(GST_OPTION_CFLAGS)
 579
 580 dnl our libraries need to be versioned correctly
 581 AC_SUBST(GST_LT_LDFLAGS)
 582
 583 dnl GST_PLUGINS_BASE_CFLAGS
 584 dnl prefer internal headers to already installed ones
 585 dnl also add builddir include for enumtypes and marshal
 586 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 587 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 588
 589 dnl FIXME: do we want to rename to GST_ALL_* ?
 590 dnl add GST_OPTION_CFLAGS, but overridable
 591 GST_CFLAGS="$GST_CFLAGS \$(GST_OPTION_CFLAGS)"
 592 AC_SUBST(GST_CFLAGS)
 593 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 594 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 595 AC_SUBST(GST_LIBS)
 596
 597 dnl LDFLAGS really should only contain flags, not libs - they get added before
 598 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 599 GST_ALL_LDFLAGS="-no-undefined"
 600 AC_SUBST(GST_ALL_LDFLAGS)
 601
 602 dnl GST_LIB_LDFLAGS
 603 dnl linker flags shared by all libraries
 604 dnl LDFLAGS modifier defining exported symbols from built libraries
 605 GST_LIB_LDFLAGS="-export-symbols-regex [_]*\(gst_\|Gst\|GST_\).*"
 606 AC_SUBST(GST_LIB_LDFLAGS)
 607
 608 dnl this really should only contain flags, not libs - they get added before
 609 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 610 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc\$\$' $GST_ALL_LDFLAGS"
 611 AC_SUBST(GST_PLUGIN_LDFLAGS)
 612
 613 dnl *** output files ***
 614
 615 AC_CONFIG_FILES(
 616 Makefile
 617 gst-plugins-base.spec
 618 gst/Makefile
 619 gst/adder/Makefile
 620 gst/audioconvert/Makefile
 621 gst/audiorate/Makefile
 622 gst/audioresample/Makefile
 623 gst/audiotestsrc/Makefile
 624 gst/ffmpegcolorspace/Makefile
 625 gst/gdp/Makefile
 626 gst/playback/Makefile
 627 gst/subparse/Makefile
 628 gst/tcp/Makefile
 629 gst/typefind/Makefile
 630 gst/videotestsrc/Makefile
 631 gst/videorate/Makefile
 632 gst/videoscale/Makefile
 633 gst/volume/Makefile
 634 sys/Makefile
 635 sys/ximage/Makefile
 636 sys/xvimage/Makefile
 637 sys/v4l/Makefile
 638 ext/Makefile
 639 ext/alsa/Makefile
 640 ext/cdparanoia/Makefile
 641 ext/gnomevfs/Makefile
 642 ext/libvisual/Makefile
 643 ext/ogg/Makefile
 644 ext/pango/Makefile
 645 ext/theora/Makefile
 646 ext/vorbis/Makefile
 647 gst-libs/Makefile
 648 gst-libs/gst/Makefile
 649 gst-libs/gst/audio/Makefile
 650 gst-libs/gst/cdda/Makefile
 651 gst-libs/gst/floatcast/Makefile
 652 gst-libs/gst/interfaces/Makefile
 653 gst-libs/gst/netbuffer/Makefile
 654 gst-libs/gst/riff/Makefile
 655 gst-libs/gst/rtp/Makefile
 656 gst-libs/gst/tag/Makefile
 657 gst-libs/gst/utils/Makefile
 658 gst-libs/gst/video/Makefile
 659 tools/Makefile
 660 win32/common/config.h
 661 pkgconfig/Makefile
 662 pkgconfig/gstreamer-plugins-base.pc
 663 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 664 tests/Makefile
 665 tests/check/Makefile
 666 tests/examples/Makefile
 667 tests/examples/seek/Makefile
 668 tests/examples/volume/Makefile
 669 tests/icles/Makefile
 670 docs/Makefile
 671 docs/design/Makefile
 672 docs/libs/Makefile
 673 docs/plugins/Makefile
 674 docs/version.entities
 675 po/Makefile.in
 676 common/Makefile
 677 common/m4/Makefile
 678 m4/Makefile
 679 )
 680 AC_OUTPUT
 681
 682 GST_OUTPUT_PLUGINS