configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change (which shall not occur!)
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [0])
  30 m4_define([va_api_minor_version], [33])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version - 32)])
  45 m4_define([libva_micro_version], [0])
  46 m4_define([libva_pre_version],   [1])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 # libdrm minimun version requirement
  78 m4_define([libdrm_version], [2.4])
  79
  80 AC_PREREQ(2.57)
  81 AC_INIT([libva], [libva_version], [waldo.bastian@intel.com], libva)
  82 AC_CONFIG_SRCDIR([Makefile.am])
  83 AC_CONFIG_MACRO_DIR([m4])
  84 AM_INIT_AUTOMAKE([dist-bzip2])
  85
  86 AM_CONFIG_HEADER([config.h])
  87 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  88
  89 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  90 AC_SUBST(TODAY)
  91
  92 VA_API_MAJOR_VERSION=va_api_major_version
  93 VA_API_MINOR_VERSION=va_api_minor_version
  94 VA_API_MICRO_VERSION=va_api_micro_version
  95 VA_API_VERSION=va_api_version
  96 AC_SUBST(VA_API_MAJOR_VERSION)
  97 AC_SUBST(VA_API_MINOR_VERSION)
  98 AC_SUBST(VA_API_MICRO_VERSION)
  99 AC_SUBST(VA_API_VERSION)
 100
 101 LIBVA_MAJOR_VERSION=libva_major_version
 102 LIBVA_MINOR_VERSION=libva_minor_version
 103 LIBVA_MICRO_VERSION=libva_micro_version
 104 LIBVA_VERSION=libva_version
 105 AC_SUBST(LIBVA_MAJOR_VERSION)
 106 AC_SUBST(LIBVA_MINOR_VERSION)
 107 AC_SUBST(LIBVA_MICRO_VERSION)
 108 AC_SUBST(LIBVA_VERSION)
 109
 110 LIBVA_LT_CURRENT=libva_lt_current
 111 LIBVA_LT_REV=libva_lt_revision
 112 LIBVA_LT_AGE=libva_lt_age
 113 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 114 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 115 AC_SUBST(LIBVA_LT_VERSION)
 116 AC_SUBST(LIBVA_LT_LDFLAGS)
 117
 118 AC_ARG_ENABLE(docs,
 119     [AC_HELP_STRING([--enable-docs],
 120                     [build Doxygen documentation @<:@default=no@:>@])],
 121     [], [enable_docs="no"])
 122
 123 AC_ARG_ENABLE(drm,
 124     [AC_HELP_STRING([--enable-drm],
 125                     [build with VA/DRM API support @<:@default=yes@:>@])],
 126     [], [enable_drm="yes"])
 127
 128 AC_ARG_ENABLE(x11,
 129     [AC_HELP_STRING([--enable-x11],
 130                     [build with VA/X11 API support @<:@default=yes@:>@])],
 131     [], [enable_x11="yes"])
 132
 133 AC_ARG_ENABLE(glx,
 134     [AC_HELP_STRING([--enable-glx],
 135                     [build with VA/GLX API support @<:@default=yes@:>@])],
 136     [], [enable_glx="yes"])
 137
 138 AC_ARG_ENABLE(egl,
 139     [AC_HELP_STRING([--enable-egl],
 140                     [build with VA/EGL API support @<:@default=yes@:>@])],
 141     [], [enable_egl="yes"])
 142
 143 AC_ARG_ENABLE([wayland],
 144     [AC_HELP_STRING([--enable-wayland],
 145                     [build with VA/Wayland API support @<:@default=yes@:>@])],
 146     [], [enable_wayland="yes"])
 147
 148 AC_ARG_ENABLE(dummy-driver,
 149     [AC_HELP_STRING([--enable-dummy-driver],
 150                     [build dummy video driver @<:@default=yes@:>@])],
 151     [], [enable_dummy_driver="yes"])
 152 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
 153
 154 AC_ARG_WITH(drivers-path,
 155     [AC_HELP_STRING([--with-drivers-path=[[path]]],
 156                     [drivers path])],
 157     [], [with_drivers_path="$libdir/dri"])
 158
 159 LIBVA_DRIVERS_PATH="$with_drivers_path"
 160 AC_SUBST(LIBVA_DRIVERS_PATH)
 161
 162 AC_DISABLE_STATIC
 163 AC_PROG_LIBTOOL
 164 AC_PROG_CC
 165 AC_PROG_CXX
 166 AM_PROG_CC_C_O
 167 PKG_PROG_PKG_CONFIG
 168
 169 AC_HEADER_STDC
 170 AC_SYS_LARGEFILE
 171
 172 # Check for Doxygen
 173 if test "$enable_docs" = "yes"; then
 174     AC_CHECK_TOOL([DOXYGEN], [doxygen], [enable_docs="no"])
 175 fi
 176 AM_CONDITIONAL(ENABLE_DOCS, test "$enable_docs" = "yes")
 177
 178 # Check for __attribute__((visibility()))
 179 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
 180     ac_cv_have_gnuc_visibility_attribute,
 181     [cat > conftest.c <<EOF
 182 int foo __attribute__ ((visibility ("hidden"))) = 1;
 183 int bar __attribute__ ((visibility ("protected"))) = 1;
 184 EOF
 185     ac_cv_have_gnuc_visibility_attribute="no"
 186     if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
 187         if grep '\.hidden.*foo' conftest.s >/dev/null; then
 188             if grep '\.protected.*bar' conftest.s >/dev/null; then
 189                 ac_cv_have_gnuc_visibility_attribute="yes"
 190             fi
 191         fi
 192     fi
 193     rm -f conftest.[cs]
 194 ])
 195 if test "$ac_cv_have_gnuc_visibility_attribute" = "yes"; then
 196     AC_DEFINE([HAVE_GNUC_VISIBILITY_ATTRIBUTE], [1],
 197               [Defined to 1 if GCC visibility attribute is supported])
 198 fi
 199
 200 # Check for DRM (mandatory)
 201 LIBDRM_VERSION=libdrm_version
 202 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
 203 AC_SUBST(LIBDRM_VERSION)
 204
 205 USE_DRM="no"
 206 if test "$enable_drm" = "yes"; then
 207     USE_DRM="yes"
 208     AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is built])
 209 fi
 210 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 211
 212 # Check for X11
 213 USE_X11="no"
 214 if test "$enable_x11" = "yes"; then
 215     USE_X11="yes"
 216     PKG_CHECK_MODULES([X11],    [x11],    [:], [USE_X11="no"])
 217     PKG_CHECK_MODULES([XEXT],   [xext],   [:], [USE_X11="no"])
 218     PKG_CHECK_MODULES([XFIXES], [xfixes], [:], [USE_X11="no"])
 219     if test "$USE_X11" = "yes"; then
 220         AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is built])
 221     fi
 222 fi
 223 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 224
 225 # Check for GLX
 226 USE_GLX="no"
 227 if test "$USE_X11:$enable_glx" = "yes:yes"; then
 228     PKG_CHECK_MODULES([GLX], [gl x11], [USE_GLX="yes"], [:])
 229     saved_CPPFLAGS="$CPPFLAGS"
 230     saved_LIBS="$LIBS"
 231     CPPFLAGS="$CPPFLAGS $GLX_CFLAGS"
 232     LIBS="$LIBS $GLX_LIBS"
 233     AC_CHECK_HEADERS([GL/gl.h GL/glx.h], [:], [USE_GLX="no"])
 234     AC_CHECK_LIB([GL], [glXCreateContext], [:] [USE_GLX="no"])
 235     CPPFLAGS="$saved_CPPFLAGS"
 236     LIBS="$saved_LIBS"
 237     if test "$USE_GLX" = "yes"; then
 238         AC_DEFINE([HAVE_VA_GLX], [1], [Defined to 1 if VA/GLX API is built])
 239     fi
 240 fi
 241 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 242
 243 # Check for EGL
 244 USE_EGL="no"
 245 if test "$enable_egl" = "yes"; then
 246     PKG_CHECK_MODULES([EGL], [egl], [USE_EGL="yes"], [:])
 247     saved_CPPFLAGS="$CPPFLAGS"
 248     saved_LIBS="$LIBS"
 249     CPPFLAGS="$CPPFLAGS $EGL_CFLAGS"
 250     LIBS="$LIBS $EGL_LIBS"
 251     AC_CHECK_HEADERS([EGL/egl.h], [:], [USE_EGL="no"])
 252     AC_CHECK_LIB([EGL], [eglGetDisplay], [:], [USE_EGL="no"])
 253     CPPFLAGS="$saved_CPPFLAGS"
 254     LIBS="$saved_LIBS"
 255     if test "$USE_EGL" = "yes"; then
 256         AC_DEFINE([HAVE_VA_EGL], [1], [Defined to 1 if VA/EGL API is built])
 257     fi
 258 fi
 259 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 260
 261 # Check for Wayland
 262 USE_WAYLAND="no"
 263 if test "$enable_wayland" = "yes"; then
 264     PKG_CHECK_MODULES([WAYLAND], [wayland-client], [USE_WAYLAND="yes"], [:])
 265     if test "$USE_WAYLAND" = "yes"; then
 266         AC_DEFINE([HAVE_VA_WAYLAND], [1],
 267                   [Defined to 1 if VA/Wayland API is built])
 268     fi
 269 fi
 270 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 271
 272 m4_ifdef([WAYLAND_SCANNER_RULES],
 273     [WAYLAND_SCANNER_RULES(['$(top_srcdir)/va/wayland/protocol'])],
 274     [wayland_scanner_rules=""; AC_SUBST(wayland_scanner_rules)])
 275
 276 pkgconfigdir=${libdir}/pkgconfig
 277 AC_SUBST(pkgconfigdir)
 278
 279 # Check for builds without backend
 280 if test "$USE_DRM:$USE_X11:$USE_WAYLAND" = "no:no:no"; then
 281     AC_MSG_ERROR([Please select at least one backend (DRM, X11, Wayland)])
 282 fi
 283
 284 AC_OUTPUT([
 285     Makefile
 286     debian.upstream/Makefile
 287     debian.upstream/changelog
 288     debian.upstream/control
 289     debian.upstream/libva$LIBVA_MAJOR_VERSION.install:\
 290 debian.upstream/libva.install.in
 291     doc/Makefile
 292     dummy_drv_video/Makefile
 293     pkgconfig/Makefile
 294     pkgconfig/libva-drm.pc
 295     pkgconfig/libva-egl.pc
 296     pkgconfig/libva-glx.pc
 297     pkgconfig/libva-tpi.pc
 298     pkgconfig/libva-wayland.pc
 299     pkgconfig/libva-x11.pc
 300     pkgconfig/libva.pc
 301     test/Makefile
 302     test/basic/Makefile
 303     test/common/Makefile
 304     test/decode/Makefile
 305     test/encode/Makefile
 306     test/putsurface/Makefile
 307     test/vainfo/Makefile
 308     test/v4l_h264/Makefile
 309     test/v4l_h264/encode/Makefile
 310     test/v4l_h264/decode/Makefile
 311     va/Makefile
 312     va/drm/Makefile
 313     va/egl/Makefile
 314     va/glx/Makefile
 315     va/va_version.h
 316     va/wayland/Makefile
 317     va/wayland/protocol/Makefile
 318     va/x11/Makefile
 319 ])
 320
 321 # Print a small summary
 322 BACKENDS=""
 323 AS_IF([test x$USE_DRM = xyes], [BACKENDS="$BACKENDS drm"])
 324 AS_IF([test x$USE_X11 = xyes], [BACKENDS="$BACKENDS x11"])
 325 AS_IF([test x$USE_GLX = xyes], [BACKENDS="$BACKENDS glx"])
 326 AS_IF([test x$USE_EGL = xyes], [BACKENDS="$BACKENDS egl"])
 327 AS_IF([test x$USE_WAYLAND = xyes], [BACKENDS="$BACKENDS wayland"])
 328
 329 echo
 330 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 331 echo
 332 echo Installation prefix .............. : $prefix
 333 echo Default driver path .............. : $LIBVA_DRIVERS_PATH
 334 echo Extra window systems ............. : $BACKENDS
 335 echo Build dummy driver ............... : $enable_dummy_driver
 336 echo Build documentation .............. : $enable_docs
 337 echo