configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change (which shall not occur!)
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [0])
  30 m4_define([va_api_minor_version], [33])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version - 32)])
  45 m4_define([libva_micro_version], [0])
  46 m4_define([libva_pre_version],   [1])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 # libdrm minimun version requirement
  78 m4_define([libdrm_version], [2.4])
  79
  80 AC_PREREQ(2.57)
  81 AC_INIT([libva], [libva_version], [waldo.bastian@intel.com], libva)
  82 AC_CONFIG_SRCDIR([Makefile.am])
  83 AM_INIT_AUTOMAKE([dist-bzip2])
  84
  85 AM_CONFIG_HEADER([config.h])
  86 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  87
  88 VA_API_MAJOR_VERSION=va_api_major_version
  89 VA_API_MINOR_VERSION=va_api_minor_version
  90 VA_API_MICRO_VERSION=va_api_micro_version
  91 VA_API_VERSION=va_api_version
  92 AC_SUBST(VA_API_MAJOR_VERSION)
  93 AC_SUBST(VA_API_MINOR_VERSION)
  94 AC_SUBST(VA_API_MICRO_VERSION)
  95 AC_SUBST(VA_API_VERSION)
  96
  97 LIBVA_MAJOR_VERSION=libva_major_version
  98 LIBVA_MINOR_VERSION=libva_minor_version
  99 LIBVA_MICRO_VERSION=libva_micro_version
 100 LIBVA_VERSION=libva_version
 101 AC_SUBST(LIBVA_MAJOR_VERSION)
 102 AC_SUBST(LIBVA_MINOR_VERSION)
 103 AC_SUBST(LIBVA_MICRO_VERSION)
 104 AC_SUBST(LIBVA_VERSION)
 105
 106 LIBVA_LT_CURRENT=libva_lt_current
 107 LIBVA_LT_REV=libva_lt_revision
 108 LIBVA_LT_AGE=libva_lt_age
 109 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 110 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 111 AC_SUBST(LIBVA_LT_VERSION)
 112 AC_SUBST(LIBVA_LT_LDFLAGS)
 113
 114 AC_ARG_ENABLE(docs,
 115     [AC_HELP_STRING([--enable-docs],
 116                     [build Doxygen documentation @<:@default=no@:>@])],
 117     [], [enable_docs="no"])
 118
 119 AC_ARG_ENABLE(glx,
 120     [AC_HELP_STRING([--enable-glx],
 121                     [build with GLX support @<:@default=yes@:>@])],
 122     [], [enable_glx="yes"])
 123
 124 AC_ARG_ENABLE(egl,
 125     [AC_HELP_STRING([--enable-egl],
 126                     [build with EGL support @<:@default=yes@:>@])],
 127     [], [enable_egl="yes"])
 128
 129 AC_ARG_ENABLE(dummy-driver,
 130     [AC_HELP_STRING([--enable-dummy-driver],
 131                     [build dummy video driver @<:@default=yes@:>@])],
 132     [], [enable_dummy_driver="yes"])
 133 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
 134
 135 AC_ARG_ENABLE(dummy-backend,
 136     [AC_HELP_STRING([--enable-dummy-backend],
 137                     [build dummy libva backend])],
 138     [], [enable_dummy_backend="no"])
 139
 140 AC_ARG_WITH(drivers-path,
 141     [AC_HELP_STRING([--with-drivers-path=[[path]]],
 142                     [drivers path])],
 143     [], [with_drivers_path="$libdir/dri"])
 144
 145 LIBVA_DRIVERS_PATH="$with_drivers_path"
 146 AC_SUBST(LIBVA_DRIVERS_PATH)
 147
 148 AC_DISABLE_STATIC
 149 AC_PROG_LIBTOOL
 150 AC_PROG_CC
 151 AC_PROG_CXX
 152 AM_PROG_CC_C_O
 153
 154 AC_HEADER_STDC
 155 AC_SYS_LARGEFILE
 156
 157 PKG_CHECK_MODULES([X11], [x11])
 158 PKG_CHECK_MODULES([XEXT],[xext])
 159 PKG_CHECK_MODULES([XFIXES], [xfixes])
 160
 161 # Check for Doxygen
 162 if test "$enable_docs" = "yes"; then
 163     AC_CHECK_TOOL([DOXYGEN], [doxygen], [enable_docs="no"])
 164 fi
 165 AM_CONDITIONAL(ENABLE_DOCS, test "$enable_docs" = "yes")
 166
 167 # Check for recent enough DRM
 168 LIBDRM_VERSION=libdrm_version
 169 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
 170 AC_SUBST(LIBDRM_VERSION)
 171
 172 if test x$enable_dummy_backend = xyes; then
 173     PKG_CHECK_MODULES([UDEV], [libudev], [libudev=yes], [libudev=no])
 174 fi
 175 if test x$libudev = xno; then
 176    enable_dummy_backend=no
 177 fi
 178 AM_CONDITIONAL(BUILD_DUMMY_BACKEND, test x$enable_dummy_backend = xyes)
 179
 180 # Check for GLX
 181 USE_GLX="no"
 182 GL_DEPS_CFLAGS=""
 183 GL_DEPS_LIBS=""
 184 if test "$enable_glx" = "yes"; then
 185     saved_CFLAGS="$CFLAGS"
 186     saved_LIBS="$LIBS"
 187     PKG_CHECK_MODULES([GL_DEPS], [gl], [], [GL_DEPS_LIBS="-lX11 -lGL"])
 188     CFLAGS="$CFLAGS $GL_DEPS_CFLAGS"
 189     LIBS="$LIBS $GL_DEPS_LIBS"
 190     AC_CHECK_HEADERS([GL/gl.h])
 191     AC_CHECK_HEADERS([GL/glx.h])
 192     AC_CHECK_LIB(GL, glXCreateContext, [USE_GLX="yes"])
 193     CFLAGS="$saved_CFLAGS"
 194     LIBS="$saved_LIBS"
 195 fi
 196 AC_SUBST(GL_DEPS_CFLAGS)
 197 AC_SUBST(GL_DEPS_LIBS)
 198 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 199
 200 # Check for EGL
 201 USE_EGL="no"
 202 EGL_DEPS_CFLAGS=""
 203 EGL_DEPS_LIBS=""
 204 if test "$enable_egl" = "yes"; then
 205     saved_CFLAGS="$CFLAGS"
 206     saved_LIBS="$LIBS"
 207     PKG_CHECK_MODULES([EGL_DEPS], [egl], [], [EGL_DEPS_LIBS="-lEGL"])
 208     CFLAGS="$CFLAGS $EGL_DEPS_CFLAGS"
 209     LIBS="$LIBS $EGL_DEPS_LIBS"
 210     AC_CHECK_HEADERS([EGL/egl.h], [USE_EGL="yes"], [USE_EGL="no"])
 211
 212     if test "x$USE_EGL" = "xyes"; then
 213         AC_CHECK_LIB(EGL, eglGetDisplay, [USE_EGL="yes"], [USE_EGL="no"])
 214     fi
 215
 216     CFLAGS="$saved_CFLAGS"
 217     LIBS="$saved_LIBS"
 218
 219     libglesv1_cm="no"
 220     PKG_CHECK_MODULES([GLESv1_CM], [glesv1_cm], [libglesv1_cm="yes"], [libglesv1_cm="no"])
 221 fi
 222 AC_SUBST(EGL_DEPS_CFLAGS)
 223 AC_SUBST(EGL_DEPS_LIBS)
 224 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 225 AM_CONDITIONAL(BUILD_EGL_TEST, [test "x$USE_EGL" = "xyes" && test "x$libglesv1_cm" = "xyes"])
 226
 227 # We only need the headers, we don't link against the DRM libraries
 228 LIBVA_CFLAGS="$DRM_CFLAGS"
 229 AC_SUBST(LIBVA_CFLAGS)
 230 AC_SUBST(LIBVA_LIBS)
 231
 232 pkgconfigdir=${libdir}/pkgconfig
 233 AC_SUBST(pkgconfigdir)
 234
 235 LIBVA_DISPLAY=x11
 236 libvacorelib=libva.la
 237 libvabackendlib=libva-$LIBVA_DISPLAY.la
 238 AC_SUBST([libvacorelib])
 239 AC_SUBST([libvabackendlib])
 240
 241 AC_OUTPUT([
 242     Makefile
 243     debian.upstream/Makefile
 244     doc/Makefile
 245     dummy_drv_video/Makefile
 246     pkgconfig/Makefile
 247     pkgconfig/libva-egl.pc
 248     pkgconfig/libva-glx.pc
 249     pkgconfig/libva-tpi.pc
 250     pkgconfig/libva-x11.pc
 251     pkgconfig/libva.pc
 252     test/Makefile
 253     test/basic/Makefile
 254     test/common/Makefile
 255     test/decode/Makefile
 256     test/encode/Makefile
 257     test/putsurface/Makefile
 258     test/vainfo/Makefile
 259     test/v4l_h264/Makefile
 260     test/v4l_h264/encode/Makefile
 261     test/v4l_h264/decode/Makefile
 262     va/Makefile
 263     va/dummy/Makefile
 264     va/egl/Makefile
 265     va/glx/Makefile
 266     va/va_version.h
 267     va/x11/Makefile
 268 ])
 269
 270 # Print a small summary
 271 AS_IF([test x$USE_GLX = xyes], [BACKENDS="glx $BACKENDS"])
 272 AS_IF([test x$USE_EGL = xyes], [BACKENDS="egl $BACKENDS"])
 273
 274 echo
 275 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 276 echo
 277 echo Installation prefix .............. : $prefix
 278 echo Default driver path .............. : $LIBVA_DRIVERS_PATH
 279 echo Extra window systems ............. : $BACKENDS
 280 echo Build dummy driver ............... : $enable_dummy_driver
 281 echo Build documentation .............. : $enable_docs
 282 echo