provide a common PATH_SEPARATOR check method which is required by
[platform/upstream/c-ares.git] / configure.ac
1 AC_PREREQ(2.57)
2
3 dnl Version not hardcoded here. Fetched later from ares_version.h
4 AC_INIT([c-ares], [-],
5   [c-ares mailing list => http://cool.haxx.se/mailman/listinfo/c-ares])
6
7 CARES_OVERRIDE_AUTOCONF
8
9 AC_CONFIG_SRCDIR([ares_ipv6.h])
10 AM_CONFIG_HEADER([config.h])
11 AM_MAINTAINER_MODE
12
13 CARES_CHECK_OPTION_DEBUG
14 CARES_CHECK_OPTION_OPTIMIZE
15 CARES_CHECK_OPTION_WARNINGS
16
17 CARES_CHECK_PATH_SEPARATOR
18
19 dnl SED is mandatory for configure process and libtool.
20 dnl Set it now, allowing it to be changed later.
21 AC_PATH_PROG([SED], [sed], [not_found],
22   [$PATH:/usr/bin:/usr/local/bin])
23 if test -z "$SED" || test "$SED" = "not_found"; then
24   AC_MSG_ERROR([sed not found in PATH. Cannot continue without sed.])
25 fi
26 AC_SUBST([SED])
27
28 dnl GREP is mandatory for configure process and libtool.
29 dnl Set it now, allowing it to be changed later.
30 AC_PATH_PROG([GREP], [grep], [not_found],
31   [$PATH:/usr/bin:/usr/local/bin])
32 if test -z "$GREP" || test "$GREP" = "not_found"; then
33   AC_MSG_ERROR([grep not found in PATH. Cannot continue without grep.])
34 fi
35 AC_SUBST([GREP])
36
37 dnl EGREP is mandatory for configure process and libtool.
38 dnl Set it now, allowing it to be changed later.
39 if echo a | ($GREP -E '(a|b)') >/dev/null 2>&1; then
40   AC_MSG_CHECKING([for egrep])
41   EGREP="$GREP -E"
42   AC_MSG_RESULT([$EGREP])
43 else
44   AC_PATH_PROG([EGREP], [egrep], [not_found],
45     [$PATH:/usr/bin:/usr/local/bin])
46 fi
47 if test -z "$EGREP" || test "$EGREP" = "not_found"; then
48   AC_MSG_ERROR([egrep not found in PATH. Cannot continue without egrep.])
49 fi
50 AC_SUBST([EGREP])
51
52 dnl AR is mandatory for configure process and libtool.
53 dnl This is target dependant, so check it as a tool.
54 AC_PATH_TOOL([AR], [ar], [not_found],
55   [$PATH:/usr/bin:/usr/local/bin])
56 if test -z "$AR" || test "$AR" = "not_found"; then
57   AC_MSG_ERROR([ar not found in PATH. Cannot continue without ar.])
58 fi
59 AC_SUBST([AR])
60
61 dnl Fetch c-ares version from ares_version.h
62 VERSION=`$SED -ne 's/^#define ARES_VERSION_STR "\(.*\)"/\1/p' ${srcdir}/ares_version.h`
63 AM_INIT_AUTOMAKE([c-ares], [$VERSION])
64 AC_MSG_CHECKING([c-ares version])
65 AC_MSG_RESULT([$VERSION])
66
67 dnl
68 dnl Detect the canonical host and target build environment
69 dnl
70
71 AC_CANONICAL_HOST
72 dnl Get system canonical name
73 AC_DEFINE_UNQUOTED(OS, "${host}", [cpu-machine-OS])
74
75 CARES_CHECK_PROG_CC
76 AM_PROG_CC_C_O
77 AC_PROG_INSTALL
78
79 dnl This defines _ALL_SOURCE for AIX
80 CARES_CHECK_AIX_ALL_SOURCE
81
82 dnl Our configure and build reentrant settings
83 CARES_CONFIGURE_REENTRANT
84
85 dnl check for how to do large files
86 AC_SYS_LARGEFILE
87
88 case $host_os in
89   solaris*)
90     AC_DEFINE(ETC_INET, 1, [if a /etc/inet dir is being used])
91     ;;
92 esac
93
94 dnl support building of Windows DLLs
95 AC_LIBTOOL_WIN32_DLL
96
97 CARES_PROCESS_DEBUG_BUILD_OPTS
98
99 AM_CONDITIONAL(DEBUGBUILD, test x$want_debug = xyes)
100 AM_CONDITIONAL(CURLDEBUG, test x$want_debug = xyes)
101
102 dnl force libtool to build static libraries with PIC on AMD64-Linux & FreeBSD
103 AC_MSG_CHECKING([if arch-OS host is AMD64-Linux/FreeBSD (to build static libraries with PIC)])
104 case $host in
105   x86_64*linux*|amd64*freebsd*|ia64*freebsd*)
106     AC_MSG_RESULT([yes])
107     with_pic=yes
108     ;;
109   *)
110     AC_MSG_RESULT([no])
111     ;;
112 esac
113
114 dnl libtool setup
115 AC_PROG_LIBTOOL
116
117 AC_MSG_CHECKING([if we need -no-undefined])
118 case $host in
119   *-*-cygwin* | *-*-mingw* | *-*-pw32* | *-*-cegcc*)
120     need_no_undefined=yes
121     ;;
122   *)
123     need_no_undefined=no
124     ;;
125 esac
126 AC_MSG_RESULT($need_no_undefined)
127 AM_CONDITIONAL(NO_UNDEFINED, test x$need_no_undefined = xyes)
128
129 dnl **********************************************************************
130 dnl platform/compiler/architecture specific checks/flags
131 dnl **********************************************************************
132
133 CARES_CHECK_COMPILER
134 CARES_SET_COMPILER_BASIC_OPTS
135 CARES_SET_COMPILER_DEBUG_OPTS
136 CARES_SET_COMPILER_OPTIMIZE_OPTS
137 CARES_SET_COMPILER_WARNING_OPTS
138
139 case $host in
140   #
141   x86_64*linux*|amd64*freebsd*|ia64*freebsd*)
142     #
143     if test "$compiler_id" = "INTEL_UNIX_C"; then
144       #
145       if test "$compiler_num" -ge "900" &&
146         test "$compiler_num" -lt "1000"; then
147         dnl icc 9.X specific
148         CFLAGS="$CFLAGS -i-dynamic"
149       fi
150       #
151       if test "$compiler_num" -ge "1000"; then
152         dnl icc 10.X or later
153         CFLAGS="$CFLAGS -shared-intel"
154       fi
155       #
156     fi
157     ;;
158   #
159 esac
160
161 CURL_CHECK_COMPILER_HALT_ON_ERROR
162 CURL_CHECK_COMPILER_ARRAY_SIZE_NEGATIVE
163
164 dnl **********************************************************************
165 dnl Compilation based checks should not be done before this point.
166 dnl **********************************************************************
167
168 dnl **********************************************************************
169 dnl Make sure that our checks for headers windows.h winsock.h winsock2.h 
170 dnl and ws2tcpip.h take precedence over any other further checks which 
171 dnl could be done later using AC_CHECK_HEADER or AC_CHECK_HEADERS for
172 dnl this specific header files. And do them before its results are used.
173 dnl **********************************************************************
174
175 CURL_CHECK_HEADER_WINDOWS
176 CURL_CHECK_NATIVE_WINDOWS
177 case X-"$ac_cv_native_windows" in
178   X-yes)
179     CURL_CHECK_HEADER_WINSOCK
180     CURL_CHECK_HEADER_WINSOCK2
181     CURL_CHECK_HEADER_WS2TCPIP
182     ;;
183   *)
184     ac_cv_header_winsock_h="no"
185     ac_cv_header_winsock2_h="no"
186     ac_cv_header_ws2tcpip_h="no"
187     ;;
188 esac
189
190 dnl **********************************************************************
191 dnl Checks for libraries.
192 dnl **********************************************************************
193
194 dnl gethostbyname without lib or in the nsl lib?
195 AC_CHECK_FUNC(gethostbyname,
196               [HAVE_GETHOSTBYNAME="1"
197               ],
198               [ AC_CHECK_LIB(nsl, gethostbyname,
199                              [HAVE_GETHOSTBYNAME="1"
200                              LIBS="$LIBS -lnsl"
201                              ])
202               ])
203
204 if test "$HAVE_GETHOSTBYNAME" != "1"
205 then
206   dnl gethostbyname in the socket lib?
207   AC_CHECK_LIB(socket, gethostbyname,
208                [HAVE_GETHOSTBYNAME="1"
209                LIBS="$LIBS -lsocket"
210                ])
211 fi
212
213 dnl At least one system has been identified to require BOTH nsl and socket
214 dnl libs at the same time to link properly.
215 if test "$HAVE_GETHOSTBYNAME" != "1"
216 then
217   AC_MSG_CHECKING([for gethostbyname with both nsl and socket libs])
218   my_ac_save_LIBS=$LIBS
219   LIBS="-lnsl -lsocket $LIBS"
220   AC_LINK_IFELSE([
221     AC_LANG_PROGRAM([[
222     ]],[[
223       gethostbyname();
224     ]])
225   ],[
226     AC_MSG_RESULT([yes])
227     HAVE_GETHOSTBYNAME="1"
228   ],[
229     AC_MSG_RESULT([no])
230     LIBS=$my_ac_save_LIBS
231   ])
232 fi
233
234 if test "$HAVE_GETHOSTBYNAME" != "1"
235 then
236   dnl This is for winsock systems
237   if test "$ac_cv_header_windows_h" = "yes"; then
238     if test "$ac_cv_header_winsock_h" = "yes"; then
239       case $host in
240         *-*-mingw32ce*)
241           winsock_LIB="-lwinsock"
242           ;;
243         *)
244           winsock_LIB="-lwsock32"
245           ;;
246       esac
247     fi
248     if test "$ac_cv_header_winsock2_h" = "yes"; then
249       winsock_LIB="-lws2_32"
250     fi
251     if test ! -z "$winsock_LIB"; then
252       my_ac_save_LIBS=$LIBS
253       LIBS="$winsock_LIB $LIBS"
254       AC_MSG_CHECKING([for gethostbyname in $winsock_LIB])
255       AC_LINK_IFELSE([
256         AC_LANG_PROGRAM([[
257 #ifdef HAVE_WINDOWS_H
258 #ifndef WIN32_LEAN_AND_MEAN
259 #define WIN32_LEAN_AND_MEAN
260 #endif
261 #include <windows.h>
262 #ifdef HAVE_WINSOCK2_H
263 #include <winsock2.h>
264 #else
265 #ifdef HAVE_WINSOCK_H
266 #include <winsock.h>
267 #endif
268 #endif
269 #endif
270         ]],[[
271           gethostbyname("www.dummysite.com");
272         ]])
273       ],[
274         AC_MSG_RESULT([yes])
275         HAVE_GETHOSTBYNAME="1"
276       ],[
277         AC_MSG_RESULT([no])
278         winsock_LIB=""
279         LIBS=$my_ac_save_LIBS
280       ])
281     fi
282   fi
283 fi
284
285 if test "$HAVE_GETHOSTBYNAME" != "1"
286 then
287   dnl This is for Minix 3.1
288   AC_MSG_CHECKING([for gethostbyname for Minix 3])
289   AC_LINK_IFELSE([
290     AC_LANG_PROGRAM([[
291 /* Older Minix versions may need <net/gen/netdb.h> here instead */
292 #include <netdb.h>
293     ]],[[
294       gethostbyname("www.dummysite.com");
295     ]])
296   ],[
297     AC_MSG_RESULT([yes])
298     HAVE_GETHOSTBYNAME="1"
299   ],[
300     AC_MSG_RESULT([no])
301   ])
302 fi
303
304 if test "$HAVE_GETHOSTBYNAME" != "1"
305 then
306   dnl This is for eCos with a stubbed DNS implementation
307   AC_MSG_CHECKING([for gethostbyname for eCos])
308   AC_LINK_IFELSE([
309     AC_LANG_PROGRAM([[
310 #include <stdio.h>
311 #include <netdb.h>
312     ]],[[
313       gethostbyname("www.dummysite.com");
314     ]])
315   ],[
316     AC_MSG_RESULT([yes])
317     HAVE_GETHOSTBYNAME="1"
318   ],[
319     AC_MSG_RESULT([no])
320   ])
321 fi
322
323 if test "$HAVE_GETHOSTBYNAME" != "1"
324 then
325   dnl gethostbyname in the net lib - for BeOS
326   AC_CHECK_LIB(net, gethostbyname,
327                [HAVE_GETHOSTBYNAME="1"
328                LIBS="$LIBS -lnet"
329                ])
330 fi
331
332
333 if test "$HAVE_GETHOSTBYNAME" != "1"; then
334   AC_MSG_ERROR([couldn't find libraries for gethostbyname()])
335 fi
336
337 dnl resolve lib?
338 AC_CHECK_FUNC(strcasecmp, , [ AC_CHECK_LIB(resolve, strcasecmp) ])
339
340 if test "$ac_cv_lib_resolve_strcasecmp" = "$ac_cv_func_strcasecmp"; then
341   AC_CHECK_LIB(resolve, strcasecmp,
342               [LIBS="-lresolve $LIBS"],
343                ,
344                -lnsl)
345 fi
346 ac_cv_func_strcasecmp="no"
347
348 dnl socket lib?
349 AC_CHECK_FUNC(connect, , [ AC_CHECK_LIB(socket, connect) ])
350
351 dnl **********************************************************************
352 dnl In case that function clock_gettime with monotonic timer is available,
353 dnl check for additional required libraries.
354 dnl **********************************************************************
355 CURL_CHECK_LIBS_CLOCK_GETTIME_MONOTONIC
356
357 AC_MSG_CHECKING([whether to use libgcc])
358 AC_ARG_ENABLE(libgcc,
359 AC_HELP_STRING([--enable-libgcc],[use libgcc when linking]),
360 [ case "$enableval" in
361   yes)
362         LIBS="$LIBS -lgcc"
363        AC_MSG_RESULT(yes)
364        ;;
365   *)   AC_MSG_RESULT(no)
366        ;;
367   esac ],
368        AC_MSG_RESULT(no)
369 )
370
371
372 dnl Default is to try the thread-safe versions of a few functions
373 OPT_THREAD=on
374
375 dnl detect AIX 4.3 or later
376 AC_MSG_CHECKING([AIX 4.3 or later])
377 AC_PREPROC_IFELSE([
378 #if defined(_AIX) && defined(_AIX43)
379 printf("just fine");
380 #else
381 #error "this is not AIX 4.3 or later"
382 #endif
383 ],
384  [ AC_MSG_RESULT([yes])
385    RECENTAIX=yes
386    OPT_THREAD=off ],
387  [ AC_MSG_RESULT([no]) ]
388 )
389
390 AC_ARG_ENABLE(thread,dnl
391 AC_HELP_STRING([--disable-thread],[don't look for thread-safe functions])
392 AC_HELP_STRING([--enable-thread],[look for thread-safe functions]),
393 [ case "$enableval" in
394   no)
395     OPT_THREAD=off
396     AC_MSG_WARN(c-ares will not get built using thread-safe functions)
397     ;;
398   *)
399     ;;
400   esac
401 ]
402 )
403
404 if test X"$OPT_THREAD" = Xoff
405 then
406   AC_DEFINE(DISABLED_THREADSAFE, 1,
407     [Set to explicitly specify we don't want to use thread-safe functions])
408 fi
409
410 dnl for recent AIX versions, we skip all the thread-safe checks above since
411 dnl they claim a thread-safe libc using the standard API. But there are
412 dnl some functions still not thread-safe. Check for these!
413
414 dnl Let's hope this split URL remains working:
415 dnl http://publibn.boulder.ibm.com/doc_link/en_US/a_doc_lib/aixprggd/ \
416 dnl genprogc/thread_quick_ref.htm
417
418 if test "x$RECENTAIX" = "xyes"; then
419
420   AC_DEFINE(_THREAD_SAFE, 1, [define this if you need it to compile thread-safe code])
421
422 fi
423
424
425 dnl **********************************************************************
426 dnl Back to "normal" configuring
427 dnl **********************************************************************
428
429 dnl Checks for header files.
430 AC_HEADER_STDC
431
432 CURL_CHECK_HEADER_MALLOC
433
434 dnl check for a few basic system headers we need
435 AC_CHECK_HEADERS(
436        sys/types.h \
437        sys/time.h \
438        sys/select.h \
439        sys/socket.h \
440        sys/ioctl.h \
441        sys/param.h \
442        sys/uio.h \
443        netdb.h \
444        netinet/in.h \
445        netinet/tcp.h \
446        net/if.h \
447        errno.h \
448        strings.h \
449        stdbool.h \
450        time.h \
451        arpa/nameser.h \
452        arpa/nameser_compat.h \
453        arpa/inet.h,
454 dnl to do if not found
455 [],
456 dnl to do if found
457 [],
458 dnl default includes
459 [
460 #ifdef HAVE_SYS_TYPES_H
461 #include <sys/types.h>
462 #endif
463 #ifdef HAVE_SYS_TIME_H
464 #include <sys/time.h>
465 #endif
466 dnl We do this default-include simply to make sure that the nameser_compat.h
467 dnl header *REALLY* can be include after the new nameser.h. It seems AIX 5.1
468 dnl (and others?) is not designed to allow this.
469 #ifdef HAVE_ARPA_NAMESER_H
470 #include <arpa/nameser.h>
471 #endif
472
473 dnl *Sigh* these are needed in order for net/if.h to get properly detected.
474 #ifdef HAVE_SYS_SOCKET_H
475 #include <sys/socket.h>
476 #endif
477 #ifdef HAVE_NETINET_IN_H
478 #include <netinet/in.h>
479 #endif
480 ]
481 )
482
483 dnl Checks for typedefs, structures, and compiler characteristics.
484 AC_C_CONST
485 AC_TYPE_SIZE_T
486 AC_HEADER_TIME
487 CURL_CHECK_STRUCT_TIMEVAL
488
489 AC_CHECK_SIZEOF(size_t)
490 AC_CHECK_SIZEOF(long)
491 AC_CHECK_SIZEOF(time_t)
492
493 AC_CHECK_TYPE(long long,
494    [AC_DEFINE(HAVE_LONGLONG, 1,
495      [Define to 1 if the compiler supports the 'long long' data type.])]
496    longlong="yes"  
497 )
498
499 if test "xyes" = "x$longlong"; then
500   AC_MSG_CHECKING([if numberLL works])
501   AC_COMPILE_IFELSE([long long val = 1000LL;],
502    [AC_DEFINE(HAVE_LL, 1, [if your compiler supports LL])]
503    AC_MSG_RESULT(yes),
504    AC_MSG_RESULT(no)
505   )
506 fi
507
508
509 # check for ssize_t
510 AC_CHECK_TYPE(ssize_t, ,
511    AC_DEFINE(ssize_t, int, [the signed version of size_t]))
512
513 # check for bool type
514 AC_CHECK_TYPE([bool],[
515   AC_DEFINE(HAVE_BOOL_T, 1,
516     [Define to 1 if bool is an available type.])
517 ], ,[
518 #ifdef HAVE_SYS_TYPES_H
519 #include <sys/types.h>
520 #endif
521 #ifdef HAVE_STDBOOL_H
522 #include <stdbool.h>
523 #endif
524 ])
525
526 # Check for socklen_t or equivalent
527 CURL_CHECK_TYPE_SOCKLEN_T
528
529 TYPE_IN_ADDR_T
530
531 TYPE_SOCKADDR_STORAGE
532
533 TYPE_SIG_ATOMIC_T
534
535 AC_TYPE_SIGNAL
536
537 CURL_CHECK_FUNC_RECV
538 CURL_CHECK_FUNC_RECVFROM
539 CURL_CHECK_FUNC_SEND
540 CURL_CHECK_MSG_NOSIGNAL
541
542 CARES_CHECK_FUNC_FCNTL
543 CARES_CHECK_FUNC_FREEADDRINFO
544 CARES_CHECK_FUNC_GETADDRINFO
545 CARES_CHECK_FUNC_GETHOSTBYADDR
546 CARES_CHECK_FUNC_GETHOSTBYNAME
547 CARES_CHECK_FUNC_GETHOSTNAME
548 CARES_CHECK_FUNC_GETSERVBYPORT_R
549 CARES_CHECK_FUNC_INET_NTOP
550 CARES_CHECK_FUNC_INET_PTON
551 CARES_CHECK_FUNC_IOCTL
552 CARES_CHECK_FUNC_IOCTLSOCKET
553 CARES_CHECK_FUNC_IOCTLSOCKET_CAMEL
554 CARES_CHECK_FUNC_SETSOCKOPT
555 CARES_CHECK_FUNC_STRCASECMP
556 CARES_CHECK_FUNC_STRCMPI
557 CARES_CHECK_FUNC_STRDUP
558 CARES_CHECK_FUNC_STRICMP
559 CARES_CHECK_FUNC_STRNCASECMP
560 CARES_CHECK_FUNC_STRNCMPI
561 CARES_CHECK_FUNC_STRNICMP
562 CARES_CHECK_FUNC_WRITEV
563
564
565 dnl check for AF_INET6
566 CARES_CHECK_CONSTANT(
567   [
568 #undef inline
569 #ifdef HAVE_WINDOWS_H
570 #ifndef WIN32_LEAN_AND_MEAN
571 #define WIN32_LEAN_AND_MEAN
572 #endif
573 #include <windows.h>
574 #ifdef HAVE_WINSOCK2_H
575 #include <winsock2.h>
576 #endif
577 #else
578 #ifdef HAVE_SYS_TYPES_H
579 #include <sys/types.h>
580 #endif
581 #ifdef HAVE_SYS_SOCKET_H
582 #include <sys/socket.h>
583 #endif
584 #endif
585   ], [PF_INET6], 
586      AC_DEFINE_UNQUOTED(HAVE_PF_INET6,1,[Define to 1 if you have PF_INET6.])
587 )
588
589 dnl check for PF_INET6
590 CARES_CHECK_CONSTANT(
591   [
592 #undef inline
593 #ifdef HAVE_WINDOWS_H
594 #ifndef WIN32_LEAN_AND_MEAN
595 #define WIN32_LEAN_AND_MEAN
596 #endif
597 #include <windows.h>
598 #ifdef HAVE_WINSOCK2_H
599 #include <winsock2.h>
600 #endif
601 #else
602 #ifdef HAVE_SYS_TYPES_H
603 #include <sys/types.h>
604 #endif
605 #ifdef HAVE_SYS_SOCKET_H
606 #include <sys/socket.h>
607 #endif
608 #endif
609   ], [AF_INET6], 
610      AC_DEFINE_UNQUOTED(HAVE_AF_INET6,1,[Define to 1 if you have AF_INET6.])
611 )
612
613
614 dnl check for the in6_addr structure
615 CARES_CHECK_STRUCT(
616   [
617 #undef inline
618 #ifdef HAVE_WINDOWS_H
619 #ifndef WIN32_LEAN_AND_MEAN
620 #define WIN32_LEAN_AND_MEAN
621 #endif
622 #include <windows.h>
623 #ifdef HAVE_WINSOCK2_H
624 #include <winsock2.h>
625 #ifdef HAVE_WS2TCPIP_H
626 #include <ws2tcpip.h>
627 #endif
628 #endif
629 #else
630 #ifdef HAVE_SYS_TYPES_H
631 #include <sys/types.h>
632 #endif
633 #ifdef HAVE_NETINET_IN_H
634 #include <netinet/in.h>
635 #endif
636 #endif
637   ], [in6_addr], 
638      AC_DEFINE_UNQUOTED(HAVE_STRUCT_IN6_ADDR,1,[Define to 1 if you have struct in6_addr.])
639 )
640
641 dnl check for the sockaddr_in6 structure
642 CARES_CHECK_STRUCT(
643   [
644 #undef inline
645 #ifdef HAVE_WINDOWS_H
646 #ifndef WIN32_LEAN_AND_MEAN
647 #define WIN32_LEAN_AND_MEAN
648 #endif
649 #include <windows.h>
650 #ifdef HAVE_WINSOCK2_H
651 #include <winsock2.h>
652 #ifdef HAVE_WS2TCPIP_H
653 #include <ws2tcpip.h>
654 #endif
655 #endif
656 #else
657 #ifdef HAVE_SYS_TYPES_H
658 #include <sys/types.h>
659 #endif
660 #ifdef HAVE_NETINET_IN_H
661 #include <netinet/in.h>
662 #endif
663 #endif
664   ], [sockaddr_in6], 
665      AC_DEFINE_UNQUOTED(HAVE_STRUCT_SOCKADDR_IN6,1,
666        [Define to 1 if you have struct sockaddr_in6.]) ac_have_sockaddr_in6=yes
667 )
668
669 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_scope_id,
670     AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_IN6_SIN6_SCOPE_ID,1,
671       [Define to 1 if your struct sockaddr_in6 has sin6_scope_id.])
672    , ,
673   [
674 #undef inline
675 #ifdef HAVE_WINDOWS_H
676 #ifndef WIN32_LEAN_AND_MEAN
677 #define WIN32_LEAN_AND_MEAN
678 #endif
679 #include <windows.h>
680 #ifdef HAVE_WINSOCK2_H
681 #include <winsock2.h>
682 #ifdef HAVE_WS2TCPIP_H
683 #include <ws2tcpip.h>
684 #endif
685 #endif
686 #else
687 #ifdef HAVE_SYS_TYPES_H
688 #include <sys/types.h>
689 #endif
690 #ifdef HAVE_NETINET_IN_H
691 #include <netinet/in.h>
692 #endif
693 #endif
694   ])
695
696 dnl check for the addrinfo structure
697 AC_CHECK_MEMBER(struct addrinfo.ai_flags,
698      AC_DEFINE_UNQUOTED(HAVE_STRUCT_ADDRINFO,1,
699        [Define to 1 if you have struct addrinfo.]),,
700   [
701 #undef inline
702 #ifdef HAVE_WINDOWS_H
703 #ifndef WIN32_LEAN_AND_MEAN
704 #define WIN32_LEAN_AND_MEAN
705 #endif
706 #include <windows.h>
707 #ifdef HAVE_WINSOCK2_H
708 #include <winsock2.h>
709 #ifdef HAVE_WS2TCPIP_H
710 #include <ws2tcpip.h>
711 #endif
712 #endif
713 #else
714 #ifdef HAVE_SYS_TYPES_H
715 #include <sys/types.h>
716 #endif
717 #ifdef HAVE_NETINET_IN_H
718 #include <netinet/in.h>
719 #endif
720 #ifdef HAVE_SYS_SOCKET_H
721 #include <sys/socket.h>
722 #endif
723 #ifdef HAVE_NETDB_H
724 #include <netdb.h>
725 #endif
726 #endif
727   ]
728 )
729
730
731 AC_CHECK_FUNCS([bitncmp \
732   gettimeofday \
733   if_indextoname
734 ],[
735 ],[
736   func="$ac_func"
737   AC_MSG_CHECKING([deeper for $func])
738   AC_LINK_IFELSE([
739     AC_LANG_PROGRAM([[
740     ]],[[
741       $func ();
742     ]])
743   ],[
744     AC_MSG_RESULT([yes])
745     eval "ac_cv_func_$func=yes"
746     AC_DEFINE_UNQUOTED([AS_TR_CPP([HAVE_$func])], [1],
747       [Define to 1 if you have the $func function.])
748   ],[
749     AC_MSG_RESULT([but still no])
750   ])
751 ])
752
753
754 dnl Check for inet_net_pton
755 AC_CHECK_FUNCS(inet_net_pton)
756 dnl Again, some systems have it, but not IPv6
757 if test "$ac_cv_func_inet_net_pton" = "yes" ; then
758 AC_MSG_CHECKING(if inet_net_pton supports IPv6)
759 AC_TRY_RUN(
760   [
761 #ifdef HAVE_SYS_TYPES_H
762 #include <sys/types.h>
763 #endif
764 #ifdef HAVE_SYS_SOCKET_H
765 #include <sys/socket.h>
766 #endif
767 #ifdef HAVE_NETINET_IN_H
768 #include <netinet/in.h>
769 #endif
770 int main()
771   {
772     struct in6_addr addr6;
773     if (inet_net_pton(AF_INET6, "::1", &addr6, sizeof(addr6)) < 1)
774       exit(1);
775     else
776       exit(0);
777   }
778   ], [
779        AC_MSG_RESULT(yes)
780        AC_DEFINE_UNQUOTED(HAVE_INET_NET_PTON_IPV6,1,[Define to 1 if inet_net_pton supports IPv6.])
781      ], AC_MSG_RESULT(no),AC_MSG_RESULT(no))
782 fi
783
784
785 AC_CHECK_SIZEOF(struct in6_addr, ,
786 [
787 #undef inline
788 #ifdef HAVE_WINDOWS_H
789 #ifndef WIN32_LEAN_AND_MEAN
790 #define WIN32_LEAN_AND_MEAN
791 #endif
792 #include <windows.h>
793 #ifdef HAVE_WINSOCK2_H
794 #include <winsock2.h>
795 #ifdef HAVE_WS2TCPIP_H
796 #include <ws2tcpip.h>
797 #endif
798 #endif
799 #else
800 #ifdef HAVE_SYS_TYPES_H
801 #include <sys/types.h>
802 #endif
803 #ifdef HAVE_SYS_SOCKET_H
804 #include <sys/socket.h>
805 #endif
806 #ifdef HAVE_NETINET_IN_H
807 #include <netinet/in.h>
808 #endif
809 #endif
810 ]
811 )
812
813 AC_CHECK_SIZEOF(struct in_addr, ,
814 [
815 #undef inline
816 #ifdef HAVE_WINDOWS_H
817 #ifndef WIN32_LEAN_AND_MEAN
818 #define WIN32_LEAN_AND_MEAN
819 #endif
820 #include <windows.h>
821 #ifdef HAVE_WINSOCK2_H
822 #include <winsock2.h>
823 #ifdef HAVE_WS2TCPIP_H
824 #include <ws2tcpip.h>
825 #endif
826 #endif
827 #else
828 #ifdef HAVE_SYS_TYPES_H
829 #include <sys/types.h>
830 #endif
831 #ifdef HAVE_SYS_SOCKET_H
832 #include <sys/socket.h>
833 #endif
834 #ifdef HAVE_NETINET_IN_H
835 #include <netinet/in.h>
836 #endif
837 #endif
838 ]
839 )
840
841
842 dnl Check if the getnameinfo function is available
843 dnl and get the types of five of its arguments.
844 CURL_CHECK_FUNC_GETNAMEINFO
845
846
847 AC_C_BIGENDIAN(
848     [AC_DEFINE(ARES_BIG_ENDIAN, 1,
849       [define this if ares is built for a big endian system])],
850     ,
851     [AC_MSG_WARN([couldn't figure out endianess, assuming little endian!])]
852 )
853
854 dnl Check for user-specified random device
855 AC_ARG_WITH(random,
856 AC_HELP_STRING([--with-random=FILE],
857                [read randomness from FILE (default=/dev/urandom)]),
858     [ RANDOM_FILE="$withval" ],
859     [
860         dnl Check for random device.  If we're cross compiling, we can't
861         dnl check, and it's better to assume it doesn't exist than it is
862         dnl to fail on AC_CHECK_FILE or later.
863         if test "$cross_compiling" = "no"; then
864           AC_CHECK_FILE("/dev/urandom", [ RANDOM_FILE="/dev/urandom"] )
865         else
866           AC_MSG_WARN([cannot check for /dev/urandom while cross compiling; assuming none])
867         fi
868         
869     ]
870 )
871 if test -n "$RANDOM_FILE" && test X"$RANDOM_FILE" != Xno ; then
872         AC_SUBST(RANDOM_FILE)
873         AC_DEFINE_UNQUOTED(RANDOM_FILE, "$RANDOM_FILE",
874         [a suitable file/device to read random data from])
875 fi
876
877 CARES_CHECK_OPTION_NONBLOCKING
878 CARES_CHECK_NONBLOCKING_SOCKET
879
880 CARES_PRIVATE_LIBS="$LIBS"
881 AC_SUBST(CARES_PRIVATE_LIBS)
882
883 dnl squeeze whitespace out of some variables
884
885 squeeze CFLAGS
886 squeeze CPPFLAGS
887 squeeze DEFS
888 squeeze LDFLAGS
889 squeeze LIBS
890
891 squeeze CARES_PRIVATE_LIBS
892
893 AC_CONFIG_FILES([Makefile libcares.pc])
894 AC_OUTPUT