configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Tell the user about autoconf.html in the --help output
   6 m4_divert_once([HELP_END], [
   7 See docs/autoconf.html for more details on the options for Mesa.])
   8
   9 AC_INIT([Mesa], [8.1.0],
  10     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  11 AC_CONFIG_AUX_DIR([bin])
  12 AC_CANONICAL_HOST
  13 AM_INIT_AUTOMAKE([foreign])
  14
  15 dnl http://people.gnome.org/~walters/docs/build-api.txt
  16 dnl We don't support srcdir != builddir.
  17 echo \#buildapi-variable-no-builddir >/dev/null
  18
  19 # Support silent build rules, requires at least automake-1.11. Disable
  20 # by either passing --disable-silent-rules to configure or passing V=1
  21 # to make
  22 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  23
  24 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  25
  26 LT_PREREQ([2.2])
  27 LT_INIT([disable-static])
  28
  29 dnl Versions for external dependencies
  30 LIBDRM_REQUIRED=2.4.24
  31 LIBDRM_RADEON_REQUIRED=2.4.38
  32 LIBDRM_INTEL_REQUIRED=2.4.37
  33 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  34 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  35 DRI2PROTO_REQUIRED=2.6
  36 GLPROTO_REQUIRED=1.4.14
  37 LIBDRM_XORG_REQUIRED=2.4.24
  38 LIBKMS_XORG_REQUIRED=1.0.0
  39
  40 dnl Check for progs
  41 AC_PROG_CPP
  42 AC_PROG_CC
  43 AC_PROG_CXX
  44 AM_PROG_CC_C_O
  45 AM_PROG_AS
  46 AC_CHECK_PROGS([MAKE], [gmake make])
  47 AC_CHECK_PROGS([PYTHON2], [python2 python])
  48 AC_PROG_SED
  49 AC_PROG_MKDIR_P
  50 AC_PATH_PROG([MKDEP], [makedepend])
  51
  52 if test "x$MKDEP" = "x"; then
  53     AC_MSG_ERROR([makedepend is required to build Mesa])
  54 fi
  55
  56 AC_PROG_YACC
  57 AC_PATH_PROG([YACC_INST], $YACC)
  58 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.c"; then
  59     if test -z "$YACC_INST"; then
  60         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  61     fi
  62 fi
  63 AC_PROG_LEX
  64
  65 AC_PATH_PROG([PERL], [perl])
  66
  67 AC_CHECK_PROG(INDENT, indent, indent, cat)
  68 if test "x$INDENT" != "xcat"; then
  69     AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -T GLubyte -T GLbyte -T Bool')
  70 fi
  71
  72 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  73 dnl configuration in that case.
  74 AC_PROG_INSTALL
  75 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  76
  77 dnl We need a POSIX shell for parts of the build. Assume we have one
  78 dnl in most cases.
  79 case "$host_os" in
  80 solaris*)
  81     # Solaris /bin/sh is too old/non-POSIX compliant
  82     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  83     SHELL="$POSIX_SHELL"
  84     ;;
  85 esac
  86
  87 dnl clang is mostly GCC-compatible, but its version is much lower,
  88 dnl so we have to check for it.
  89 AC_MSG_CHECKING([if compiling with clang])
  90
  91 AC_COMPILE_IFELSE(
  92 [AC_LANG_PROGRAM([], [[
  93 #ifndef __clang__
  94        not clang
  95 #endif
  96 ]])],
  97 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
  98
  99 AC_MSG_RESULT([$acv_mesa_CLANG])
 100
 101 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 102 dnl versions are explictly not supported.
 103 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 104     AC_MSG_CHECKING([whether gcc version is sufficient])
 105     major=0
 106     minor=0
 107
 108     GCC_VERSION=`$CC -dumpversion`
 109     if test $? -eq 0; then
 110         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 111         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 112     fi
 113
 114     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 115         AC_MSG_RESULT([no])
 116         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 117     else
 118         AC_MSG_RESULT([yes])
 119     fi
 120 fi
 121
 122
 123 MKDEP_OPTIONS=-fdepend
 124 dnl Ask gcc where it's keeping its secret headers
 125 if test "x$GCC" = xyes; then
 126     for dir in include include-fixed; do
 127         GCC_INCLUDES=`$CC -print-file-name=$dir`
 128         if test "x$GCC_INCLUDES" != x && \
 129            test "$GCC_INCLUDES" != "$dir" && \
 130            test -d "$GCC_INCLUDES"; then
 131             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 132         fi
 133     done
 134 fi
 135 AC_SUBST([MKDEP_OPTIONS])
 136
 137 dnl Make sure the pkg-config macros are defined
 138 m4_ifndef([PKG_PROG_PKG_CONFIG],
 139     [m4_fatal([Could not locate the pkg-config autoconf macros.
 140   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 141   are in a different location, try setting the environment variable
 142   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 143 PKG_PROG_PKG_CONFIG()
 144
 145 dnl LIB_DIR - library basename
 146 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 147 AC_SUBST([LIB_DIR])
 148
 149 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 150 _SAVE_LDFLAGS="$LDFLAGS"
 151 _SAVE_CPPFLAGS="$CPPFLAGS"
 152
 153 dnl Compiler macros
 154 DEFINES=""
 155 AC_SUBST([DEFINES])
 156 case "$host_os" in
 157 linux*|*-gnu*|gnu*)
 158     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 159     ;;
 160 solaris*)
 161     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 162     ;;
 163 cygwin*)
 164     DEFINES="$DEFINES -DPTHREADS"
 165     ;;
 166 esac
 167
 168 dnl Add flags for gcc and g++
 169 if test "x$GCC" = xyes; then
 170     CFLAGS="$CFLAGS -Wall -std=c99"
 171
 172     # Enable -Werror=implicit-function-declaration and
 173     # -Werror=missing-prototypes, if available, or otherwise, just
 174     # -Wmissing-prototypes.  This is particularly useful to avoid
 175     # generating a loadable driver module that has undefined symbols.
 176     save_CFLAGS="$CFLAGS"
 177     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 178     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 179     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 180     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 181                    AC_MSG_RESULT([yes]),
 182                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 183                     AC_MSG_RESULT([no])]);
 184
 185     # Enable -fvisibility=hidden if using a gcc that supports it
 186     save_CFLAGS="$CFLAGS"
 187     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 188     VISIBILITY_CFLAGS="-fvisibility=hidden"
 189     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 190     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 191                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 192
 193     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 194     CFLAGS=$save_CFLAGS
 195
 196     # Work around aliasing bugs - developers should comment this out
 197     CFLAGS="$CFLAGS -fno-strict-aliasing"
 198
 199     # gcc's builtin memcmp is slower than glibc's
 200     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 201     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 202 fi
 203 if test "x$GXX" = xyes; then
 204     CXXFLAGS="$CXXFLAGS -Wall"
 205
 206     # Enable -fvisibility=hidden if using a gcc that supports it
 207     save_CXXFLAGS="$CXXFLAGS"
 208     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 209     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 210     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 211     AC_LANG_PUSH([C++])
 212     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 213                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 214     AC_LANG_POP([C++])
 215
 216     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 217     CXXFLAGS=$save_CXXFLAGS
 218
 219     # Work around aliasing bugs - developers should comment this out
 220     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 221
 222     # gcc's builtin memcmp is slower than glibc's
 223     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 224     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 225 fi
 226
 227 dnl even if the compiler appears to support it, using visibility attributes isn't
 228 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 229 case "$host_os" in
 230 cygwin*)
 231     VISIBILITY_CFLAGS=""
 232     VISIBILITY_CXXFLAGS=""
 233     ;;
 234 esac
 235
 236 AC_SUBST([VISIBILITY_CFLAGS])
 237 AC_SUBST([VISIBILITY_CXXFLAGS])
 238
 239 dnl
 240 dnl Hacks to enable 32 or 64 bit build
 241 dnl
 242 AC_ARG_ENABLE([32-bit],
 243     [AS_HELP_STRING([--enable-32-bit],
 244         [build 32-bit libraries @<:@default=auto@:>@])],
 245     [enable_32bit="$enableval"],
 246     [enable_32bit=auto]
 247 )
 248 if test "x$enable_32bit" = xyes; then
 249     if test "x$GCC" = xyes; then
 250         CFLAGS="$CFLAGS -m32"
 251         CCASFLAGS="$CCASFLAGS -m32"
 252     fi
 253     if test "x$GXX" = xyes; then
 254         CXXFLAGS="$CXXFLAGS -m32"
 255     fi
 256 fi
 257 AC_ARG_ENABLE([64-bit],
 258     [AS_HELP_STRING([--enable-64-bit],
 259         [build 64-bit libraries @<:@default=auto@:>@])],
 260     [enable_64bit="$enableval"],
 261     [enable_64bit=auto]
 262 )
 263 if test "x$enable_64bit" = xyes; then
 264     if test "x$GCC" = xyes; then
 265         CFLAGS="$CFLAGS -m64"
 266     fi
 267     if test "x$GXX" = xyes; then
 268         CXXFLAGS="$CXXFLAGS -m64"
 269     fi
 270 fi
 271
 272 dnl Can't have static and shared libraries, default to static if user
 273 dnl explicitly requested. If both disabled, set to static since shared
 274 dnl was explicitly requested.
 275 case "x$enable_static$enable_shared" in
 276 xyesyes )
 277     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 278     enable_shared=no
 279     ;;
 280 xnono )
 281     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling static])
 282     enable_static=yes
 283     ;;
 284 esac
 285
 286 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 287
 288 dnl
 289 dnl mklib options
 290 dnl
 291 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 292 if test "$enable_static" = yes; then
 293     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 294 fi
 295 AC_SUBST([MKLIB_OPTIONS])
 296
 297 dnl
 298 dnl other compiler options
 299 dnl
 300 AC_ARG_ENABLE([debug],
 301     [AS_HELP_STRING([--enable-debug],
 302         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 303     [enable_debug="$enableval"],
 304     [enable_debug=no]
 305 )
 306 if test "x$enable_debug" = xyes; then
 307     DEFINES="$DEFINES -DDEBUG"
 308     if test "x$GCC" = xyes; then
 309         CFLAGS="$CFLAGS -g"
 310     fi
 311     if test "x$GXX" = xyes; then
 312         CXXFLAGS="$CXXFLAGS -g"
 313     fi
 314 fi
 315
 316 dnl
 317 dnl library names
 318 dnl
 319 LIB_PREFIX_GLOB='lib'
 320 LIB_VERSION_SEPARATOR='.'
 321 if test "$enable_static" = yes; then
 322     LIB_EXTENSION='a'
 323 else
 324     case "$host_os" in
 325     darwin* )
 326         LIB_EXTENSION='dylib' ;;
 327     cygwin* )
 328         dnl prefix can be 'cyg' or 'lib'
 329         LIB_PREFIX_GLOB='???'
 330         LIB_VERSION_SEPARATOR='-'
 331         LIB_EXTENSION='dll' ;;
 332     aix* )
 333         LIB_EXTENSION='a' ;;
 334     * )
 335         LIB_EXTENSION='so' ;;
 336     esac
 337 fi
 338 AC_ARG_WITH([gl-lib-name],
 339   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 340     [specify GL library name @<:@default=GL@:>@])],
 341   [GL_LIB=$withval],
 342   [GL_LIB=GL])
 343 AC_ARG_WITH([glu-lib-name],
 344   [AS_HELP_STRING([--with-glu-lib-name@<:@=NAME@:>@],
 345     [specify GLU library name @<:@default=GLU@:>@])],
 346   [GLU_LIB=$withval],
 347   [GLU_LIB=GLU])
 348 AC_ARG_WITH([osmesa-lib-name],
 349   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 350     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 351   [OSMESA_LIB=$withval],
 352   [OSMESA_LIB=OSMesa])
 353 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB=GL])
 354 AS_IF([test "x$GLU_LIB" = xyes], [GLU_LIB=GLU])
 355 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 356
 357 dnl
 358 dnl Mangled Mesa support
 359 dnl
 360 AC_ARG_ENABLE([mangling],
 361   [AS_HELP_STRING([--enable-mangling],
 362     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 363   [enable_mangling="${enableval}"],
 364   [enable_mangling=no]
 365 )
 366 if test "x${enable_mangling}" = "xyes" ; then
 367   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 368   GL_LIB="Mangled${GL_LIB}"
 369   GLU_LIB="Mangled${GLU_LIB}"
 370   OSMESA_LIB="Mangled${OSMESA_LIB}"
 371 fi
 372 AC_SUBST([GL_LIB])
 373 AC_SUBST([GLU_LIB])
 374 AC_SUBST([OSMESA_LIB])
 375
 376 dnl
 377 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 378 dnl
 379 AC_ARG_ENABLE([texture-float],
 380     [AS_HELP_STRING([--enable-texture-float],
 381         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 382     [enable_texture_float="$enableval"],
 383     [enable_texture_float=no]
 384 )
 385 if test "x$enable_texture_float" = xyes; then
 386     AC_MSG_WARN([Floating-point textures enabled.])
 387     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 388     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 389 fi
 390
 391 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 392 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 393 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 394 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 395 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 396 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 397 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 398 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 399
 400 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408
 409 AC_SUBST([GL_LIB_NAME])
 410 AC_SUBST([GLU_LIB_NAME])
 411 AC_SUBST([OSMESA_LIB_NAME])
 412 AC_SUBST([EGL_LIB_NAME])
 413 AC_SUBST([GLESv1_CM_LIB_NAME])
 414 AC_SUBST([GLESv2_LIB_NAME])
 415 AC_SUBST([VG_LIB_NAME])
 416 AC_SUBST([GLAPI_LIB_NAME])
 417
 418 AC_SUBST([GL_LIB_GLOB])
 419 AC_SUBST([GLU_LIB_GLOB])
 420 AC_SUBST([EGL_LIB_GLOB])
 421 AC_SUBST([GLESv1_CM_LIB_GLOB])
 422 AC_SUBST([GLESv2_LIB_GLOB])
 423 AC_SUBST([VG_LIB_GLOB])
 424 AC_SUBST([GLAPI_LIB_GLOB])
 425
 426 dnl
 427 dnl Arch/platform-specific settings
 428 dnl
 429 AC_ARG_ENABLE([asm],
 430     [AS_HELP_STRING([--disable-asm],
 431         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 432     [enable_asm="$enableval"],
 433     [enable_asm=yes]
 434 )
 435 asm_arch=""
 436 MESA_ASM_FILES=""
 437 AC_MSG_CHECKING([whether to enable assembly])
 438 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 439 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 440 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 441     case "$host_cpu" in
 442     i?86 | x86_64)
 443         enable_asm=no
 444         AC_MSG_RESULT([no, cross compiling])
 445         ;;
 446     esac
 447 fi
 448 # check for supported arches
 449 if test "x$enable_asm" = xyes; then
 450     case "$host_cpu" in
 451     i?86)
 452         case "$host_os" in
 453         linux* | *freebsd* | dragonfly* | *netbsd*)
 454             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 455             ;;
 456         esac
 457         ;;
 458     x86_64)
 459         case "$host_os" in
 460         linux* | *freebsd* | dragonfly* | *netbsd*)
 461             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 462             ;;
 463         esac
 464         ;;
 465     sparc*)
 466         case "$host_os" in
 467         linux*)
 468             asm_arch=sparc
 469             ;;
 470         esac
 471         ;;
 472     esac
 473
 474     case "$asm_arch" in
 475     x86)
 476         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 477         MESA_ASM_FILES='$(X86_FILES)'
 478         AC_MSG_RESULT([yes, x86])
 479         ;;
 480     x86_64)
 481         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 482         MESA_ASM_FILES='$(X86_64_FILES)'
 483         AC_MSG_RESULT([yes, x86_64])
 484         ;;
 485     sparc)
 486         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 487         MESA_ASM_FILES='$(SPARC_FILES)'
 488         AC_MSG_RESULT([yes, sparc])
 489         ;;
 490     *)
 491         AC_MSG_RESULT([no, platform not supported])
 492         ;;
 493     esac
 494 fi
 495 AC_SUBST([MESA_ASM_FILES])
 496
 497 dnl PIC code macro
 498 MESA_PIC_FLAGS
 499
 500 dnl Check to see if dlopen is in default libraries (like Solaris, which
 501 dnl has it in libc), or if libdl is needed to get it.
 502 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 503     [AC_CHECK_LIB([dl], [dlopen],
 504        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 505 AC_SUBST([DLOPEN_LIBS])
 506
 507 dnl See if posix_memalign is available
 508 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 509
 510 dnl SELinux awareness.
 511 AC_ARG_ENABLE([selinux],
 512     [AS_HELP_STRING([--enable-selinux],
 513         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 514     [MESA_SELINUX="$enableval"],
 515     [MESA_SELINUX=no])
 516 if test "x$enable_selinux" = "xyes"; then
 517     AC_CHECK_HEADER([selinux/selinux.h],[],
 518                     [AC_MSG_ERROR([SELinux headers not found])])
 519     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 520                  [AC_MSG_ERROR([SELinux library not found])])
 521     SELINUX_LIBS="-lselinux"
 522     DEFINES="$DEFINES -DMESA_SELINUX"
 523 fi
 524
 525 dnl Options for APIs
 526 AC_ARG_ENABLE([opengl],
 527     [AS_HELP_STRING([--disable-opengl],
 528         [disable support for standard OpenGL API @<:@default=no@:>@])],
 529     [enable_opengl="$enableval"],
 530     [enable_opengl=yes])
 531 AC_ARG_ENABLE([gles1],
 532     [AS_HELP_STRING([--enable-gles1],
 533         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 534     [enable_gles1="$enableval"],
 535     [enable_gles1=no])
 536 AC_ARG_ENABLE([gles2],
 537     [AS_HELP_STRING([--enable-gles2],
 538         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 539     [enable_gles2="$enableval"],
 540     [enable_gles2=no])
 541 AC_ARG_ENABLE([openvg],
 542     [AS_HELP_STRING([--enable-openvg],
 543         [enable support for OpenVG API @<:@default=no@:>@])],
 544     [enable_openvg="$enableval"],
 545     [enable_openvg=no])
 546
 547 AC_ARG_ENABLE([dri],
 548     [AS_HELP_STRING([--enable-dri],
 549         [enable DRI modules @<:@default=enabled@:>@])],
 550     [enable_dri="$enableval"],
 551     [enable_dri=yes])
 552 AC_ARG_ENABLE([glx],
 553     [AS_HELP_STRING([--enable-glx],
 554         [enable GLX library @<:@default=enabled@:>@])],
 555     [enable_glx="$enableval"],
 556     [enable_glx=yes])
 557 AC_ARG_ENABLE([osmesa],
 558     [AS_HELP_STRING([--enable-osmesa],
 559         [enable OSMesa library @<:@default=disabled@:>@])],
 560     [enable_osmesa="$enableval"],
 561     [enable_osmesa=no])
 562 AC_ARG_ENABLE([egl],
 563     [AS_HELP_STRING([--disable-egl],
 564         [disable EGL library @<:@default=enabled@:>@])],
 565     [enable_egl="$enableval"],
 566     [enable_egl=yes])
 567
 568 AC_ARG_ENABLE([xorg],
 569     [AS_HELP_STRING([--enable-xorg],
 570         [enable support for X.Org DDX API @<:@default=no@:>@])],
 571     [enable_xorg="$enableval"],
 572     [enable_xorg=no])
 573 AC_ARG_ENABLE([xa],
 574     [AS_HELP_STRING([--enable-xa],
 575         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 576     [enable_xa="$enableval"],
 577     [enable_xa=no])
 578 AC_ARG_ENABLE([d3d1x],
 579     [AS_HELP_STRING([--enable-d3d1x],
 580         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 581     [enable_d3d1x="$enableval"],
 582     [enable_d3d1x=no])
 583 AC_ARG_ENABLE([gbm],
 584    [AS_HELP_STRING([--enable-gbm],
 585          [enable gbm library @<:@default=auto@:>@])],
 586    [enable_gbm="$enableval"],
 587    [enable_gbm=auto])
 588
 589 AC_ARG_ENABLE([xvmc],
 590    [AS_HELP_STRING([--enable-xvmc],
 591          [enable xvmc library @<:@default=auto@:>@])],
 592    [enable_xvmc="$enableval"],
 593    [enable_xvmc=auto])
 594 AC_ARG_ENABLE([vdpau],
 595    [AS_HELP_STRING([--enable-vdpau],
 596          [enable vdpau library @<:@default=auto@:>@])],
 597    [enable_vdpau="$enableval"],
 598    [enable_vdpau=auto])
 599 AC_ARG_ENABLE([va],
 600    [AS_HELP_STRING([--enable-va],
 601          [enable va library @<:@default=auto@:>@])],
 602    [enable_va="$enableval"],
 603    [enable_va=auto])
 604 AC_ARG_ENABLE([opencl],
 605    [AS_HELP_STRING([--enable-opencl],
 606          [enable OpenCL library @<:@default=no@:>@])],
 607    [enable_opencl="$enableval"],
 608    [enable_opencl=no])
 609 AC_ARG_ENABLE([xlib_glx],
 610     [AS_HELP_STRING([--enable-xlib-glx],
 611         [make GLX library Xlib-based instead of DRI-based @<:@default=disabled@:>@])],
 612     [enable_xlib_glx="$enableval"],
 613     [enable_xlib_glx=no])
 614 AC_ARG_ENABLE([gallium_egl],
 615     [AS_HELP_STRING([--enable-gallium-egl],
 616         [enable optional EGL state tracker (not required
 617          for EGL support in Gallium with OpenGL and OpenGL ES)
 618          @<:@default=disable@:>@])],
 619     [enable_gallium_egl="$enableval"],
 620     [enable_gallium_egl=no])
 621 AC_ARG_ENABLE([gallium_gbm],
 622     [AS_HELP_STRING([--enable-gallium-gbm],
 623         [enable optional gbm state tracker (not required for
 624          gbm support in Gallium)
 625          @<:@default=auto@:>@])],
 626     [enable_gallium_gbm="$enableval"],
 627     [enable_gallium_gbm=auto])
 628
 629 AC_ARG_ENABLE([r600-llvm-compiler],
 630     [AS_HELP_STRING([--enable-r600-llvm-compiler],
 631         [Enable experimental LLVM backend for graphics shaders @<:@default=disable@:>@])],
 632     [enable_r600_llvm="$enableval"],
 633     [enable_r600_llvm=no])
 634
 635 AC_ARG_ENABLE([gallium_tests],
 636     [AS_HELP_STRING([--enable-gallium-tests],
 637         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 638     [enable_gallium_tests="$enableval"],
 639     [enable_gallium_tests=no])
 640
 641 # Option for Gallium drivers
 642 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 643
 644 AC_ARG_WITH([gallium-drivers],
 645     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 646         [comma delimited Gallium drivers list, e.g.
 647         "i915,nouveau,r300,r600,svga,swrast"
 648         @<:@default=r300,r600,swrast@:>@])],
 649     [with_gallium_drivers="$withval"],
 650     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 651
 652 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 653 # here so that the script doesn't choke on an unknown driver name later.
 654 case "$with_gallium_drivers" in
 655     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 656     no) with_gallium_drivers='' ;;
 657 esac
 658
 659 if test "x$enable_opengl" = xno -a \
 660         "x$enable_gles1" = xno -a \
 661         "x$enable_gles2" = xno -a \
 662         "x$enable_openvg" = xno -a \
 663         "x$enable_xorg" = xno -a \
 664         "x$enable_xa" = xno -a \
 665         "x$enable_d3d1x" = xno -a \
 666         "x$enable_xvmc" = xno -a \
 667         "x$enable_vdpau" = xno -a \
 668         "x$enable_va" = xno -a \
 669         "x$enable_opencl" = xno; then
 670     AC_MSG_ERROR([at least one API should be enabled])
 671 fi
 672
 673 API_DEFINES=""
 674 if test "x$enable_opengl" = xno; then
 675     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 676 else
 677     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 678 fi
 679 if test "x$enable_gles1" = xyes; then
 680     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 681 fi
 682 if test "x$enable_gles2" = xyes; then
 683     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 684 fi
 685 AC_SUBST([API_DEFINES])
 686
 687 if test "x$enable_glx" = xno; then
 688     AC_MSG_WARN([GLX disabled, disabling Xlib-GLX])
 689     enable_xlib_glx=no
 690 fi
 691
 692 if test "x$enable_dri$enable_xlib_glx" = xyesyes; then
 693     AC_MSG_ERROR([DRI and Xlib-GLX cannot be built together])
 694 fi
 695
 696 # Disable GLX if DRI and Xlib-GLX are not enabled
 697 if test "x$enable_glx" = xyes -a \
 698         "x$enable_dri" = xno -a \
 699         "x$enable_xlib_glx" = xno; then
 700     AC_MSG_WARN([Neither DRI nor Xlib-GLX enabled, disabling GLX])
 701     enable_glx=no
 702 fi
 703
 704 AM_CONDITIONAL(HAVE_DRI, test "x$enable_dri" = xyes)
 705 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_xlib_glx" = xyes -o \
 706                                   "x$enable_osmesa" = xyes)
 707
 708 AC_ARG_ENABLE([shared-glapi],
 709     [AS_HELP_STRING([--enable-shared-glapi],
 710         [Enable shared glapi for OpenGL @<:@default=yes@:>@])],
 711     [enable_shared_glapi="$enableval"],
 712     [enable_shared_glapi="$enable_dri"])
 713
 714 # Shared GLAPI is only useful for DRI
 715 if test "x$enable_dri" = xno; then
 716     AC_MSG_NOTICE([Shared GLAPI is only useful for DRI, disabling])
 717     enable_shared_glapi=no
 718 fi
 719
 720 # TODO: Get rid of SHARED_GLAPI variable
 721 SHARED_GLAPI="0"
 722 if test "x$enable_shared_glapi" = xyes; then
 723     SHARED_GLAPI="1"
 724     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 725     # the remap table)
 726     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 727     CORE_DIRS="mapi/shared-glapi"
 728 fi
 729 AC_SUBST([SHARED_GLAPI])
 730 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
 731
 732 dnl
 733 dnl Driver specific build directories
 734 dnl
 735 SRC_DIRS="gtest"
 736 GALLIUM_DIRS="auxiliary drivers state_trackers"
 737 GALLIUM_TARGET_DIRS=""
 738 GALLIUM_WINSYS_DIRS="sw"
 739 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 740 GALLIUM_STATE_TRACKERS_DIRS=""
 741
 742 # build glapi if OpenGL is enabled
 743 if test "x$enable_opengl" = xyes; then
 744     CORE_DIRS="$CORE_DIRS mapi/glapi"
 745 fi
 746
 747 # build es1api if OpenGL ES 1.x is enabled
 748 if test "x$enable_gles1" = xyes; then
 749     CORE_DIRS="$CORE_DIRS mapi/es1api"
 750 fi
 751
 752 # build es2api if OpenGL ES 2.x is enabled
 753 if test "x$enable_gles2" = xyes; then
 754     CORE_DIRS="$CORE_DIRS mapi/es2api"
 755 fi
 756
 757 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 758 case "x$enable_opengl$enable_gles1$enable_gles2" in
 759 x*yes*)
 760     CORE_DIRS="mapi/glapi/gen $CORE_DIRS glsl mesa"
 761     ;;
 762 esac
 763
 764 case "x$enable_glx$enable_xlib_glx" in
 765 xyesyes)
 766     DRIVER_DIRS="$DRIVER_DIRS x11"
 767     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 768     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 769     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 770     HAVE_WINSYS_XLIB="yes"
 771     ;;
 772 xyesno)
 773     # DRI-based GLX
 774     SRC_DIRS="$SRC_DIRS glx"
 775     ;;
 776 esac
 777
 778 if test "x$enable_dri" = xyes; then
 779     DRIVER_DIRS="$DRIVER_DIRS dri"
 780
 781     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 782     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 783     HAVE_ST_DRI="yes"
 784 fi
 785
 786 if test "x$enable_osmesa" = xyes; then
 787     DRIVER_DIRS="$DRIVER_DIRS osmesa"
 788 fi
 789
 790 AC_SUBST([SRC_DIRS])
 791 AC_SUBST([DRIVER_DIRS])
 792 AC_SUBST([GALLIUM_DIRS])
 793 AC_SUBST([GALLIUM_TARGET_DIRS])
 794 AC_SUBST([GALLIUM_WINSYS_DIRS])
 795 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 796 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 797 AC_SUBST([MESA_LLVM])
 798
 799 # Check for libdrm
 800 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 801                   [have_libdrm=yes], [have_libdrm=no])
 802
 803 if test "x$enable_dri" = xyes; then
 804     # DRI must be shared, I think
 805     if test "$enable_static" = yes; then
 806         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
 807     fi
 808
 809     # not a hard requirement as swrast does not depend on it
 810     if test "x$have_libdrm" = xyes; then
 811         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 812     fi
 813 fi
 814
 815 dnl Find out if X is available.
 816 PKG_CHECK_MODULES([X11], [x11])
 817
 818 dnl Try to tell the user that the --x-* options are only used when
 819 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 820 m4_divert_once([HELP_BEGIN],
 821 [These options are only used when the X libraries cannot be found by the
 822 pkg-config utility.])
 823
 824 dnl We need X for xlib and dri, so bomb now if it's not found
 825 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 826     AC_MSG_ERROR([X11 development libraries needed for GLX])
 827 fi
 828
 829 if test "x$enable_glx" = xyes; then
 830     DEFINES="$DEFINES -DUSE_XCB"
 831 fi
 832
 833 dnl Direct rendering or just indirect rendering
 834 case "$host_os" in
 835 gnu*)
 836     dnl Disable by default on GNU/Hurd
 837     driglx_direct_default="no"
 838     ;;
 839 cygwin*)
 840     dnl Disable by default on cygwin
 841     driglx_direct_default="no"
 842     ;;
 843 *)
 844     driglx_direct_default="yes"
 845     ;;
 846 esac
 847 AC_ARG_ENABLE([driglx-direct],
 848     [AS_HELP_STRING([--disable-driglx-direct],
 849         [enable direct rendering in GLX and EGL for DRI \
 850             @<:@default=auto@:>@])],
 851     [driglx_direct="$enableval"],
 852     [driglx_direct="$driglx_direct_default"])
 853
 854 dnl
 855 dnl libGL configuration per driver
 856 dnl
 857 case "x$enable_glx$enable_xlib_glx" in
 858 xyesyes)
 859     # Xlib-based GLX
 860     PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 861     GL_PC_REQ_PRIV="x11 xext"
 862     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 863     GL_LIB_DEPS="$XLIBGL_LIBS"
 864     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 865     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 866     ;;
 867 xyesno)
 868     # DRI-based GLX
 869     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 870     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 871     if test x"$driglx_direct" = xyes; then
 872         if test "x$have_libdrm" != xyes; then
 873             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 874         fi
 875         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 876         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 877     fi
 878
 879     # find the DRI deps for libGL
 880     dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx >= 1.8.1"
 881
 882     # add xf86vidmode if available
 883     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 884     if test "$HAVE_XF86VIDMODE" = yes ; then
 885         dri_modules="$dri_modules xxf86vm"
 886     fi
 887
 888     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 889     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 890     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 891     GL_LIB_DEPS="$DRIGL_LIBS"
 892
 893     # need DRM libs, -lpthread, etc.
 894     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 895     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 896     ;;
 897 esac
 898
 899 # This is outside the case (above) so that it is invoked even for non-GLX
 900 # builds.
 901 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
 902
 903 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 904 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 905 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 906 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 907
 908 AC_SUBST([GL_LIB_DEPS])
 909 AC_SUBST([GL_PC_REQ_PRIV])
 910 AC_SUBST([GL_PC_LIB_PRIV])
 911 AC_SUBST([GL_PC_CFLAGS])
 912 AC_SUBST([DRI_PC_REQ_PRIV])
 913 AC_SUBST([GLESv1_CM_LIB_DEPS])
 914 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 915 AC_SUBST([GLESv2_LIB_DEPS])
 916 AC_SUBST([GLESv2_PC_LIB_PRIV])
 917
 918 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
 919 AC_SUBST([GLAPI_LIB_DEPS])
 920
 921
 922 DRI_LIB_DEPS="\$(top_builddir)/src/mesa/libdricore/libdricore${VERSION}.la"
 923 GALLIUM_DRI_LIB_DEPS="\$(TOP)/\$(LIB_DIR)/libdricore${VERSION}.so"
 924
 925 AC_SUBST([HAVE_XF86VIDMODE])
 926
 927 dnl
 928 dnl More GLX setup
 929 dnl
 930 case "x$enable_glx$enable_xlib_glx" in
 931 xyesyes)
 932     DEFINES="$DEFINES -DUSE_XSHM"
 933     ;;
 934 xyesno)
 935     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 936     if test "x$driglx_direct" = xyes; then
 937         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 938     fi
 939     ;;
 940 esac
 941
 942 dnl
 943 dnl TLS detection
 944 dnl
 945
 946 AC_ARG_ENABLE([glx-tls],
 947     [AS_HELP_STRING([--enable-glx-tls],
 948         [enable TLS support in GLX @<:@default=disabled@:>@])],
 949     [GLX_USE_TLS="$enableval"],
 950     [GLX_USE_TLS=no])
 951 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
 952
 953 AS_IF([test "x$GLX_USE_TLS" = xyes],
 954       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
 955
 956 dnl
 957 dnl More DRI setup
 958 dnl
 959 dnl Directory for DRI drivers
 960 AC_ARG_WITH([dri-driverdir],
 961     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 962         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 963     [DRI_DRIVER_INSTALL_DIR="$withval"],
 964     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 965 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 966 dnl Extra search path for DRI drivers
 967 AC_ARG_WITH([dri-searchpath],
 968     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 969         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 970     [DRI_DRIVER_SEARCH_DIR="$withval"],
 971     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 972 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 973 dnl Which drivers to build - default is chosen by platform
 974 AC_ARG_WITH([dri-drivers],
 975     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 976         [comma delimited DRI drivers list, e.g.
 977         "swrast,i965,radeon" @<:@default=auto@:>@])],
 978     [with_dri_drivers="$withval"],
 979     [with_dri_drivers=yes])
 980 if test "x$with_dri_drivers" = x; then
 981     with_dri_drivers=no
 982 fi
 983
 984 dnl If $with_dri_drivers is yes, directories will be added through
 985 dnl platform checks
 986 DRI_DIRS=""
 987 case "$with_dri_drivers" in
 988 no) ;;
 989 yes)
 990     # classic DRI drivers require FEATURE_GL to build
 991     if test "x$enable_opengl" = xyes; then
 992         DRI_DIRS="yes"
 993     fi
 994     ;;
 995 *)
 996     # verify the requested driver directories exist
 997     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 998     for driver in $dri_drivers; do
 999         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1000             AC_MSG_ERROR([DRI driver directory '$driver' does not exist])
1001     done
1002     DRI_DIRS="$dri_drivers"
1003     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1004         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1005     fi
1006     ;;
1007 esac
1008
1009 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1010 if test "x$enable_dri" = xyes; then
1011     # Platform specific settings and drivers to build
1012     case "$host_os" in
1013     linux*)
1014         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1015         DEFINES="$DEFINES -DHAVE_ALIAS"
1016
1017         case "$host_cpu" in
1018         x86_64)
1019             if test "x$DRI_DIRS" = "xyes"; then
1020                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1021             fi
1022             ;;
1023         powerpc*)
1024             # Build only the drivers for cards that exist on PowerPC.
1025             if test "x$DRI_DIRS" = "xyes"; then
1026                 DRI_DIRS="r200 radeon swrast"
1027             fi
1028             ;;
1029         sparc*)
1030             # Build only the drivers for cards that exist on sparc
1031             if test "x$DRI_DIRS" = "xyes"; then
1032                 DRI_DIRS="r200 radeon swrast"
1033             fi
1034             ;;
1035         esac
1036         ;;
1037     freebsd* | dragonfly* | *netbsd*)
1038         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1039         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1040
1041         if test "x$DRI_DIRS" = "xyes"; then
1042             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1043         fi
1044         ;;
1045     gnu*)
1046         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1047         DEFINES="$DEFINES -DHAVE_ALIAS"
1048         ;;
1049     solaris*)
1050         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1051         ;;
1052     cygwin*)
1053         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1054         if test "x$DRI_DIRS" = "xyes"; then
1055             DRI_DIRS="swrast"
1056         fi
1057         ;;
1058     esac
1059
1060     # default drivers
1061     if test "x$DRI_DIRS" = "xyes"; then
1062         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1063     fi
1064
1065     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1066
1067     # Check for expat
1068     if test "x$enable_dri" = xyes; then
1069         EXPAT_INCLUDES=""
1070         EXPAT_LIB=-lexpat
1071         AC_ARG_WITH([expat],
1072             [AS_HELP_STRING([--with-expat=DIR],
1073                 [expat install directory])],[
1074             EXPAT_INCLUDES="-I$withval/include"
1075             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1076             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1077             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1078             ])
1079         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1080         save_LIBS="$LIBS"
1081         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1082             [AC_MSG_ERROR([Expat required for DRI.])])
1083         LIBS="$save_LIBS"
1084     fi
1085
1086     # if we are building any dri driver other than swrast ...
1087     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1088         # ... libdrm is required
1089         if test "x$have_libdrm" != xyes; then
1090             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1091         fi
1092         # ... and build dricommon
1093         HAVE_COMMON_DRI=yes
1094     fi
1095
1096     # put all the necessary libs together
1097     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1098     GALLIUM_DRI_LIB_DEPS="$GALLIUM_DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1099 fi
1100 AC_SUBST([DRI_DIRS])
1101 AC_SUBST([EXPAT_INCLUDES])
1102 AC_SUBST([DRI_LIB_DEPS])
1103 AC_SUBST([GALLIUM_DRI_LIB_DEPS])
1104
1105 case $DRI_DIRS in
1106 *i915*|*i965*)
1107     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1108
1109     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1110         case $d in
1111         i915)
1112             HAVE_I915_DRI=yes;
1113             ;;
1114         i965)
1115             HAVE_I965_DRI=yes;
1116             ;;
1117         esac
1118     done
1119
1120     ;;
1121 esac
1122
1123 case $DRI_DIRS in
1124 *nouveau*)
1125     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1126     HAVE_NOUVEAU_DRI=yes;
1127     ;;
1128 esac
1129
1130 case $DRI_DIRS in
1131 *radeon*|*r200*)
1132     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1133
1134     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1135         case $d in
1136         radeon)
1137             HAVE_RADEON_DRI=yes;
1138             ;;
1139         r200)
1140             HAVE_R200_DRI=yes;
1141             ;;
1142         esac
1143     done
1144
1145     ;;
1146 esac
1147
1148 case $DRI_DIRS in
1149 *swrast*)
1150     HAVE_SWRAST_DRI=yes;
1151     ;;
1152 esac
1153
1154 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1155 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1156 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1157 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1158 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1159 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1160 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1161
1162 dnl
1163 dnl OSMesa configuration
1164 dnl
1165
1166 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1167 AC_ARG_WITH([osmesa-bits],
1168     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1169         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1170     [osmesa_bits="$withval"],
1171     [osmesa_bits=8])
1172 if test "x$osmesa_bits" != x8; then
1173     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1174         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1175         osmesa_bits=8
1176     fi
1177 fi
1178 case "x$osmesa_bits" in
1179 x8)
1180     OSMESA_LIB="${OSMESA_LIB}"
1181     ;;
1182 x16|x32)
1183     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1184     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1185     ;;
1186 *)
1187     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1188     ;;
1189 esac
1190
1191 if test "x$enable_osmesa" = xyes; then
1192     # only link libraries with osmesa if shared
1193     if test "$enable_static" = no; then
1194         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1195     else
1196         OSMESA_LIB_DEPS=""
1197     fi
1198     OSMESA_MESA_DEPS=""
1199     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1200 fi
1201
1202 AC_SUBST([OSMESA_LIB_DEPS])
1203 AC_SUBST([OSMESA_MESA_DEPS])
1204 AC_SUBST([OSMESA_PC_REQ])
1205 AC_SUBST([OSMESA_PC_LIB_PRIV])
1206
1207 dnl
1208 dnl gbm configuration
1209 dnl
1210 if test "x$enable_gbm" = xauto; then
1211     case "$with_egl_platforms" in
1212         *drm*)
1213             enable_gbm=yes ;;
1214          *)
1215             enable_gbm=no ;;
1216     esac
1217 fi
1218 if test "x$enable_gbm" = xyes; then
1219     SRC_DIRS="$SRC_DIRS gbm"
1220
1221     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1222                       AC_MSG_ERROR([gbm needs udev]))
1223
1224     if test "x$enable_dri" = xyes; then
1225         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1226         if test "x$enable_shared_glapi" = xno; then
1227             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1228         fi
1229     fi
1230 fi
1231 GBM_PC_REQ_PRIV="libudev"
1232 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1233 AC_SUBST([GBM_PC_REQ_PRIV])
1234 AC_SUBST([GBM_PC_LIB_PRIV])
1235
1236 dnl
1237 dnl EGL configuration
1238 dnl
1239 EGL_CLIENT_APIS=""
1240
1241 if test "x$enable_egl" = xyes; then
1242     SRC_DIRS="$SRC_DIRS egl"
1243     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1244
1245     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1246
1247     if test "$enable_static" != yes; then
1248         # build egl_glx when libGL is built
1249         if test "x$enable_glx" = xyes; then
1250             HAVE_EGL_DRIVER_GLX=1
1251         fi
1252
1253         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1254                           [have_libudev=yes],[have_libudev=no])
1255         if test "$have_libudev" = yes; then
1256             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1257         fi
1258
1259         if test "x$enable_dri" = xyes; then
1260             HAVE_EGL_DRIVER_DRI2=1
1261         fi
1262
1263     fi
1264 fi
1265 AC_SUBST([EGL_LIB_DEPS])
1266
1267 dnl
1268 dnl EGL Gallium configuration
1269 dnl
1270 if test "x$enable_gallium_egl" = xyes; then
1271     if test "x$with_gallium_drivers" = x; then
1272         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1273     fi
1274     if test "x$enable_egl" = xno; then
1275         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1276     fi
1277     if test "x$have_libdrm" != xyes; then
1278         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1279     fi
1280
1281     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1282     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1283     HAVE_ST_EGL="yes"
1284 fi
1285
1286 dnl
1287 dnl gbm Gallium configuration
1288 dnl
1289 if test "x$enable_gallium_gbm" = xauto; then
1290     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1291         yesyesyes*drm*)
1292             enable_gallium_gbm=yes ;;
1293          *)
1294             enable_gallium_gbm=no ;;
1295     esac
1296 fi
1297 if test "x$enable_gallium_gbm" = xyes; then
1298     if test "x$with_gallium_drivers" = x; then
1299         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1300     fi
1301     if test "x$enable_gbm" = xno; then
1302         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1303     fi
1304     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1305     if test "x$enable_dri" = xno; then
1306         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1307     fi
1308
1309     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1310     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1311     HAVE_ST_GBM="yes"
1312     enable_gallium_loader=yes
1313 fi
1314
1315 dnl
1316 dnl X.Org DDX configuration
1317 dnl
1318 if test "x$enable_xorg" = xyes; then
1319     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1320     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1321     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1322     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1323         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1324         HAVE_XEXTPROTO_71="no")
1325     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1326     HAVE_ST_XORG=yes
1327 fi
1328
1329 dnl
1330 dnl XA configuration
1331 dnl
1332 if test "x$enable_xa" = xyes; then
1333 AC_PROG_AWK
1334 AC_PROG_GREP
1335 AC_CHECK_PROG(NM, nm, "nm")
1336 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1337 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1338 enable_xa=no
1339 fi
1340 fi
1341 if test "x$enable_xa" = xyes; then
1342     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1343     HAVE_ST_XA=yes
1344     AC_SUBST(AWK)
1345     AC_SUBST(GREP)
1346     AC_SUBST(NM)
1347 fi
1348
1349 dnl
1350 dnl OpenVG configuration
1351 dnl
1352 VG_LIB_DEPS=""
1353
1354 if test "x$enable_openvg" = xyes; then
1355     if test "x$enable_egl" = xno; then
1356         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1357     fi
1358     if test "x$with_gallium_drivers" = x; then
1359         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1360     fi
1361     if test "x$enable_gallium_egl" = xno; then
1362         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1363     fi
1364
1365     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1366     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1367     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1368     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1369     HAVE_ST_VEGA=yes
1370     VG_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1371     AC_SUBST([VG_PC_LIB_PRIV])
1372 fi
1373
1374 dnl
1375 dnl D3D1X configuration
1376 dnl
1377
1378 if test "x$enable_d3d1x" = xyes; then
1379     if test "x$with_gallium_drivers" = x; then
1380         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1381     fi
1382
1383     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1384     HAVE_ST_D3D1X=yes
1385 fi
1386
1387 dnl
1388 dnl Gallium G3DVL configuration
1389 dnl
1390 AC_ARG_ENABLE([gallium-g3dvl],
1391     [AS_HELP_STRING([--enable-gallium-g3dvl],
1392         [build gallium g3dvl @<:@default=disabled@:>@])],
1393     [enable_gallium_g3dvl="$enableval"],
1394     [enable_gallium_g3dvl=no])
1395 if test "x$enable_gallium_g3dvl" = xyes; then
1396     if test "x$with_gallium_drivers" = x; then
1397         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1398     fi
1399
1400     if test "x$enable_xvmc" = xauto; then
1401         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1402     fi
1403
1404     if test "x$enable_vdpau" = xauto; then
1405         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1406     fi
1407
1408     if test "x$enable_va" = xauto; then
1409         #don't enable vaapi state tracker even if package exists
1410         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1411         enable_va=no
1412     fi
1413 fi
1414
1415 if test "x$enable_xvmc" = xyes; then
1416     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1417     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1418     HAVE_ST_XVMC="yes"
1419 fi
1420
1421 if test "x$enable_vdpau" = xyes; then
1422     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1423     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1424     HAVE_ST_VDPAU="yes"
1425 fi
1426
1427 if test "x$enable_va" = xyes; then
1428     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1429     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1430     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1431     HAVE_ST_VA="yes"
1432 fi
1433
1434 dnl
1435 dnl OpenCL configuration
1436 dnl
1437
1438 AC_ARG_WITH([libclc-path],
1439    [AS_HELP_STRING([--with-libclc-path],
1440          [Path to libclc builtins library.  Example: --with-libclc-path=\$HOME/libclc/])],
1441    [LIBCLC_PATH="$withval"],
1442    [LIBCLC_PATH=""])
1443
1444 AC_ARG_WITH([clang-libdir],
1445    [AS_HELP_STRING([--with-clang-libdir],
1446          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1447    [CLANG_LIBDIR="$withval"],
1448    [CLANG_LIBDIR=""])
1449
1450 AC_SUBST([LIBCLC_PATH])
1451
1452 if test "x$enable_opencl" = xyes; then
1453     if test "x$with_gallium_drivers" = x; then
1454         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1455     fi
1456
1457     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1458         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1459     fi
1460
1461     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1462     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1463     enable_gallium_loader=yes
1464 fi
1465
1466 dnl
1467 dnl GLU configuration
1468 dnl
1469 AC_ARG_ENABLE([glu],
1470     [AS_HELP_STRING([--disable-glu],
1471         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1472     [enable_glu="$enableval"],
1473     [enable_glu=yes])
1474
1475 if test "x$enable_glu" = xyes; then
1476     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1477         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1478         enable_glu=no
1479     fi
1480 fi
1481
1482 if test "x$enable_glu" = xyes; then
1483     SRC_DIRS="$SRC_DIRS glu"
1484
1485     if test "x$enable_glx" = xno; then
1486         # Link libGLU to libOSMesa instead of libGL
1487         GLU_LIB_DEPS=""
1488         GLU_PC_REQ="osmesa"
1489         if test "$enable_static" = no; then
1490             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1491         else
1492             GLU_MESA_DEPS=""
1493         fi
1494     else
1495         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1496         GLU_PC_REQ="gl"
1497         GLU_PC_LIB_PRIV="-lm"
1498         if test "$enable_static" = no; then
1499             GLU_LIB_DEPS="-lm"
1500             GLU_MESA_DEPS='-l$(GL_LIB)'
1501         else
1502             GLU_LIB_DEPS=""
1503             GLU_MESA_DEPS=""
1504         fi
1505     fi
1506 fi
1507 if test "$enable_static" = no; then
1508     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1509 fi
1510 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1511 AC_SUBST([GLU_LIB_DEPS])
1512 AC_SUBST([GLU_MESA_DEPS])
1513 AC_SUBST([GLU_PC_REQ])
1514 AC_SUBST([GLU_PC_REQ_PRIV])
1515 AC_SUBST([GLU_PC_LIB_PRIV])
1516 AC_SUBST([GLU_PC_CFLAGS])
1517
1518 AC_SUBST([PROGRAM_DIRS])
1519
1520 dnl
1521 dnl Gallium configuration
1522 dnl
1523 if test "x$with_gallium_drivers" != x; then
1524     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1525 fi
1526 AM_CONDITIONAL(HAVE_GALLIUM, test "x$with_gallium_drivers" != x)
1527
1528 AC_SUBST([LLVM_BINDIR])
1529 AC_SUBST([LLVM_CFLAGS])
1530 AC_SUBST([LLVM_CPPFLAGS])
1531 AC_SUBST([LLVM_CXXFLAGS])
1532 AC_SUBST([LLVM_LIBDIR])
1533 AC_SUBST([LLVM_LIBS])
1534 AC_SUBST([LLVM_LDFLAGS])
1535 AC_SUBST([LLVM_INCLUDEDIR])
1536 AC_SUBST([LLVM_VERSION])
1537 AC_SUBST([CLANG_RESOURCE_DIR])
1538
1539 case "x$enable_opengl$enable_gles1$enable_gles2" in
1540 x*yes*)
1541     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1542     ;;
1543 esac
1544
1545 AC_SUBST([VG_LIB_DEPS])
1546 AC_SUBST([EGL_CLIENT_APIS])
1547
1548 dnl
1549 dnl EGL Platforms configuration
1550 dnl
1551 AC_ARG_WITH([egl-platforms],
1552     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1553         [comma delimited native platforms libEGL supports, e.g.
1554         "x11,drm" @<:@default=auto@:>@])],
1555     [with_egl_platforms="$withval"],
1556     [if test "x$enable_egl" = xyes; then
1557         with_egl_platforms="x11"
1558     else
1559         with_egl_platforms=""
1560     fi])
1561
1562 EGL_PLATFORMS=""
1563
1564 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1565     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1566 fi
1567
1568 # Do per-EGL platform setups and checks
1569 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1570 for plat in $egl_platforms; do
1571         case "$plat" in
1572         fbdev|null)
1573                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/$plat"
1574                 ;;
1575
1576         wayland)
1577                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1578                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1579                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1580
1581                 WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
1582                 AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
1583                              [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
1584                 ;;
1585
1586         x11)
1587                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes])
1588                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1589                 save_LIBS="$LIBS"
1590                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1591                              [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1592                 LIBS="$save_LIBS"
1593                 ;;
1594
1595         drm)
1596                 test "x$enable_gbm" = "xno" &&
1597                         AC_MSG_ERROR([EGL platform drm needs gbm])
1598                 ;;
1599
1600         android|gdi)
1601                 ;;
1602
1603         *)
1604                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
1605                 ;;
1606         esac
1607
1608         case "$plat$have_libudev" in
1609                 waylandno|drmno)
1610                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1611         esac
1612 done
1613
1614 # libEGL wants to default to the first platform specified in
1615 # ./configure.  parse that here.
1616 if test "x$egl_platforms" != "x"; then
1617     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1618     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1619 else
1620     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1621 fi
1622
1623 EGL_PLATFORMS="$egl_platforms"
1624
1625 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1626 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1627 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1628 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1629 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1630
1631 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1632 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1633
1634 AC_SUBST([EGL_NATIVE_PLATFORM])
1635 AC_SUBST([EGL_PLATFORMS])
1636 AC_SUBST([EGL_CFLAGS])
1637
1638 AC_ARG_WITH([egl-driver-dir],
1639     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1640                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1641     [EGL_DRIVER_INSTALL_DIR="$withval"],
1642     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1643 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1644
1645 AC_ARG_WITH([xorg-driver-dir],
1646     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1647                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1648     [XORG_DRIVER_INSTALL_DIR="$withval"],
1649     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1650 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1651
1652 AC_ARG_WITH([max-width],
1653     [AS_HELP_STRING([--with-max-width=N],
1654                     [Maximum framebuffer width (4096)])],
1655     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1656      AS_IF([test "${withval}" -gt "4096"],
1657            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1658 )
1659 AC_ARG_WITH([max-height],
1660     [AS_HELP_STRING([--with-max-height=N],
1661                     [Maximum framebuffer height (4096)])],
1662     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1663      AS_IF([test "${withval}" -gt "4096"],
1664            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1665 )
1666
1667 dnl
1668 dnl Gallium LLVM
1669 dnl
1670 AC_ARG_ENABLE([gallium-llvm],
1671     [AS_HELP_STRING([--enable-gallium-llvm],
1672         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1673     [enable_gallium_llvm="$enableval"],
1674     [enable_gallium_llvm=auto])
1675
1676 AC_ARG_WITH([llvm-shared-libs],
1677     [AS_HELP_STRING([--with-llvm-shared-libs],
1678         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1679     [with_llvm_shared_libs=yes],
1680     [with_llvm_shared_libs=no])
1681
1682 AC_ARG_WITH([llvm-prefix],
1683     [AS_HELP_STRING([--with-llvm-prefix],
1684         [Prefix for LLVM installations in non-standard locations])],
1685     [llvm_prefix="$withval"],
1686     [llvm_prefix=""])
1687
1688
1689 if test "x$with_gallium_drivers" = x; then
1690     enable_gallium_llvm=no
1691 fi
1692 if test "x$enable_gallium_llvm" = xauto; then
1693     case "$host_cpu" in
1694     i*86|x86_64) enable_gallium_llvm=yes;;
1695     esac
1696 fi
1697 if test "x$enable_gallium_llvm" = xyes; then
1698     if test "x$llvm_prefix" != x; then
1699         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
1700     else
1701         AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1702     fi
1703
1704     if test "x$LLVM_CONFIG" != xno; then
1705         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1706         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g' -e 's/-Wcovered-switch-default//g'`
1707         if test "x$with_llvm_shared_libs" = xyes; then
1708             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1709             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1710         else
1711             LLVM_COMPONENTS="engine bitwriter"
1712             if $LLVM_CONFIG --components | grep -q '\<mcjit\>'; then
1713                 LLVM_COMPONENTS="${LLVM_COMPONENTS} mcjit"
1714             fi
1715             if test "x$enable_opencl" = xyes; then
1716                 LLVM_COMPONENTS="${LLVM_COMPONENTS} ipo linker instrumentation"
1717             fi
1718             LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
1719         fi
1720         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1721         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1722         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1723         LLVM_CPPFLAGS=`$LLVM_CONFIG --cppflags`
1724         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1725         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
1726         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1727         MESA_LLVM=1
1728
1729         dnl Check for Clang interanl headers
1730         if test "x$enable_opencl" = xyes; then
1731             if test "x$CLANG_LIBDIR" = x; then
1732                 CLANG_LIBDIR=${LLVM_LIBDIR}
1733             fi
1734             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
1735             AC_CHECK_FILE("$CLANG_RESOURCE_DIR/include/stddef.h",,
1736                 AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.]))
1737         fi
1738     else
1739         MESA_LLVM=0
1740     fi
1741 else
1742     MESA_LLVM=0
1743 fi
1744
1745 dnl Directory for XVMC libs
1746 AC_ARG_WITH([xvmc-libdir],
1747     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1748         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1749     [XVMC_LIB_INSTALL_DIR="$withval"],
1750     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1751 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1752
1753 dnl
1754 dnl Gallium Tests
1755 dnl
1756 if test "x$enable_gallium_tests" = xyes; then
1757     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1758     enable_gallium_loader=yes
1759 fi
1760
1761 dnl Directory for VDPAU libs
1762 AC_ARG_WITH([vdpau-libdir],
1763     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1764         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1765     [VDPAU_LIB_INSTALL_DIR="$withval"],
1766     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1767 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1768
1769 dnl Directory for VA libs
1770 AC_ARG_WITH([va-libdir],
1771     [AS_HELP_STRING([--with-va-libdir=DIR],
1772         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1773     [VA_LIB_INSTALL_DIR="$withval"],
1774     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1775 AC_SUBST([VA_LIB_INSTALL_DIR])
1776
1777 dnl Directory for OpenCL libs
1778 AC_ARG_WITH([opencl-libdir],
1779     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1780         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1781     [OPENCL_LIB_INSTALL_DIR="$withval"],
1782     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1783 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1784
1785 dnl
1786 dnl Gallium helper functions
1787 dnl
1788 gallium_check_st() {
1789     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1790          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1791          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1792          if test "x$have_libdrm" != xyes; then
1793             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1794          fi
1795          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1796     fi
1797     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1798          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1799     fi
1800     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1801          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1802     fi
1803     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1804          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1805     fi
1806     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1807          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1808     fi
1809     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1810          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1811     fi
1812     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1813          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1814     fi
1815 }
1816
1817 gallium_require_llvm() {
1818     if test "x$MESA_LLVM" = x0; then
1819         case "$host_cpu" in
1820         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1821         esac
1822     fi
1823 }
1824
1825 gallium_require_drm_loader() {
1826     if test "x$enable_gallium_loader" = xyes; then
1827         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1828                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1829         if test "x$have_libdrm" != xyes; then
1830             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1831         fi
1832         enable_gallium_drm_loader=yes
1833     fi
1834 }
1835
1836 dnl Gallium drivers
1837 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1838 if test "x$with_gallium_drivers" != x; then
1839     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1840     for driver in $gallium_drivers; do
1841         case "x$driver" in
1842         xsvga)
1843             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1844             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1845             ;;
1846         xi915)
1847             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1848             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1849             if test "x$MESA_LLVM" = x1; then
1850                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1851             fi
1852             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1853             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1854             ;;
1855         xr300)
1856             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1857             gallium_require_llvm "Gallium R300"
1858             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1859             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1860             ;;
1861         xr600)
1862             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1863             gallium_require_drm_loader
1864             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1865             if test "x$enable_r600_llvm" = xyes -o "x$enable_opencl" = xyes; then
1866                 if test "x$LLVM_VERSION" != "x3.1"; then
1867                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1868                 fi
1869                 NEED_RADEON_GALLIUM=yes;
1870             fi
1871             if test "x$enable_r600_llvm" = xyes; then
1872                 USE_R600_LLVM_COMPILER=yes;
1873             fi
1874             if test "x$enable_opencl" = xyes -a "x$with_llvm_shared_libs" = xno; then
1875                 LLVM_LIBS="${LLVM_LIBS} `$LLVM_CONFIG --libs bitreader asmparser`"
1876             fi
1877             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1878             ;;
1879         xradeonsi)
1880             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1881             gallium_require_drm_loader
1882             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1883             if test "x$LLVM_VERSION" != "x3.1"; then
1884                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1885             fi
1886             NEED_RADEON_GALLIUM=yes;
1887             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi" "" "" "vdpau-radeonsi" ""
1888             ;;
1889         xnouveau)
1890             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1891             gallium_require_drm_loader
1892             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1893             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1894             ;;
1895         xswrast)
1896             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
1897             if test "x$MESA_LLVM" = x1; then
1898                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1899             fi
1900
1901             if test "x$HAVE_ST_DRI" = xyes; then
1902                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1903             fi
1904             if test "x$HAVE_ST_VDPAU" = xyes; then
1905                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
1906             fi
1907             if test "x$HAVE_ST_XVMC" = xyes; then
1908                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
1909             fi
1910             if test "x$HAVE_ST_VA" = xyes; then
1911                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
1912             fi
1913             if test "x$HAVE_ST_VDPAU" = xyes ||
1914                test "x$HAVE_ST_XVMC" = xyes ||
1915                test "x$HAVE_ST_VA" = xyes; then
1916                if test "x$HAVE_WINSYS_XLIB" != xyes; then
1917                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
1918                fi
1919             fi
1920             ;;
1921         *)
1922             AC_MSG_ERROR([Unknown Gallium driver: $driver])
1923             ;;
1924         esac
1925     done
1926 fi
1927
1928 if test "x$enable_gallium_loader" = xyes; then
1929     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1930     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
1931     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
1932     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
1933
1934     if test "x$HAVE_WINSYS_XLIB" = xyes; then
1935         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
1936         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
1937     fi
1938
1939     if test "x$enable_gallium_drm_loader" = xyes; then
1940         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
1941         PKG_CHECK_MODULES([GALLIUM_PIPE_LOADER_XCB], [xcb xcb-dri2],
1942                           pipe_loader_have_xcb=yes, pipe_loader_have_xcb=no)
1943         if test "x$pipe_loader_have_xcb" = xyes; then
1944             GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DPIPE_LOADER_HAVE_XCB"
1945             GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS $GALLIUM_PIPE_LOADER_XCB_LIBS $LIBDRM_LIBS"
1946         fi
1947     fi
1948
1949     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
1950     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
1951 fi
1952
1953 dnl Tell Automake which drivers to build
1954 for driver in $GALLIUM_DRIVERS_DIRS; do
1955     case "x$driver" in
1956         xgalahad)
1957             HAVE_GALAHAD_GALLIUM=yes;
1958             ;;
1959         xidentity)
1960             HAVE_IDENTITY_GALLIUM=yes;
1961             ;;
1962         xnoop)
1963             HAVE_NOOP_GALLIUM=yes;
1964             ;;
1965         *)
1966             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
1967             ;;
1968     esac
1969 done
1970
1971 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
1972 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
1973 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
1974 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
1975 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
1976 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
1977 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
1978 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
1979 AC_SUBST([GALLIUM_MAKE_DIRS])
1980
1981 AM_CONDITIONAL(HAVE_X11_DRIVER, echo "$DRIVER_DIRS" | grep 'x11' >/dev/null 2>&1)
1982
1983 AM_CONDITIONAL(HAVE_X86_ASM, echo "$DEFINES" | grep 'X86_ASM' >/dev/null 2>&1)
1984 AM_CONDITIONAL(HAVE_X86_64_ASM, echo "$DEFINES" | grep 'X86_64_ASM' >/dev/null 2>&1)
1985 AM_CONDITIONAL(HAVE_SPARC_ASM, echo "$DEFINES" | grep 'SPARC_ASM' >/dev/null 2>&1)
1986
1987 # To pass as an argument to libtool's -version-number flag
1988 VERSION_NUMBER=`echo "$VERSION" | $SED 's/\./:/g'`
1989 AC_SUBST([VERSION_NUMBER])
1990
1991 dnl prepend CORE_DIRS to SRC_DIRS
1992 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1993
1994 dnl Restore LDFLAGS and CPPFLAGS
1995 LDFLAGS="$_SAVE_LDFLAGS"
1996 CPPFLAGS="$_SAVE_CPPFLAGS"
1997
1998 dnl Add user CFLAGS and CXXFLAGS
1999 CFLAGS="$CFLAGS $USER_CFLAGS"
2000 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2001
2002 dnl Substitute the config
2003 AC_CONFIG_FILES([configs/current
2004                 Makefile
2005                 src/egl/Makefile
2006                 src/egl/drivers/Makefile
2007                 src/egl/drivers/dri2/Makefile
2008                 src/egl/drivers/glx/Makefile
2009                 src/egl/main/Makefile
2010                 src/egl/main/egl.pc
2011                 src/egl/wayland/Makefile
2012                 src/egl/wayland/wayland-drm/Makefile
2013                 src/egl/wayland/wayland-egl/Makefile
2014                 src/egl/wayland/wayland-egl/wayland-egl.pc
2015                 src/gallium/Makefile
2016                 src/gallium/auxiliary/pipe-loader/Makefile
2017                 src/gallium/drivers/Makefile
2018                 src/gallium/drivers/r300/Makefile
2019                 src/gallium/drivers/r600/Makefile
2020                 src/gallium/state_trackers/clover/Makefile
2021                 src/gallium/targets/opencl/Makefile
2022                 src/gbm/Makefile
2023                 src/gbm/main/gbm.pc
2024                 src/glsl/Makefile
2025                 src/glsl/glcpp/Makefile
2026                 src/glsl/tests/Makefile
2027                 src/glx/Makefile
2028                 src/glx/tests/Makefile
2029                 src/gtest/Makefile
2030                 src/Makefile
2031                 src/mapi/es1api/Makefile
2032                 src/mapi/es1api/glesv1_cm.pc
2033                 src/mapi/es2api/Makefile
2034                 src/mapi/es2api/glesv2.pc
2035                 src/mapi/glapi/Makefile
2036                 src/mapi/glapi/gen/Makefile
2037                 src/mapi/glapi/tests/Makefile
2038                 src/mapi/shared-glapi/Makefile
2039                 src/mapi/shared-glapi/tests/Makefile
2040                 src/mapi/vgapi/Makefile
2041                 src/mapi/vgapi/vg.pc
2042                 src/mesa/Makefile
2043                 src/mesa/gl.pc
2044                 src/mesa/drivers/Makefile
2045                 src/mesa/drivers/dri/dri.pc
2046                 src/mesa/drivers/dri/common/Makefile
2047                 src/mesa/drivers/dri/i915/Makefile
2048                 src/mesa/drivers/dri/i965/Makefile
2049                 src/mesa/drivers/dri/Makefile
2050                 src/mesa/drivers/dri/nouveau/Makefile
2051                 src/mesa/drivers/dri/r200/Makefile
2052                 src/mesa/drivers/dri/radeon/Makefile
2053                 src/mesa/drivers/dri/swrast/Makefile
2054                 src/mesa/drivers/osmesa/Makefile
2055                 src/mesa/drivers/osmesa/osmesa.pc
2056                 src/mesa/drivers/x11/Makefile
2057                 src/mesa/libdricore/Makefile
2058                 src/mesa/main/tests/Makefile
2059                 src/mesa/x86-64/Makefile
2060                 src/mesa/x86/Makefile])
2061
2062 dnl Sort the dirs alphabetically
2063 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2064 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2065 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2066 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2067 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2068
2069 AC_OUTPUT
2070
2071 dnl
2072 dnl Output some configuration info for the user
2073 dnl
2074 echo ""
2075 echo "        prefix:          $prefix"
2076 echo "        exec_prefix:     $exec_prefix"
2077 echo "        libdir:          $libdir"
2078 echo "        includedir:      $includedir"
2079
2080 dnl API info
2081 echo ""
2082 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2083 echo "        OpenVG:          $enable_openvg"
2084
2085 dnl Driver info
2086 echo ""
2087 if test "x$enable_osmesa" != xno; then
2088         echo "        OSMesa:          lib$OSMESA_LIB"
2089 else
2090         echo "        OSMesa:          no"
2091 fi
2092
2093 if test "x$enable_dri" != xno; then
2094         # cleanup the drivers var
2095         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2096         if test "x$DRI_DIRS" = x; then
2097             echo "        DRI drivers:     no"
2098         else
2099             echo "        DRI drivers:     $dri_dirs"
2100         fi
2101         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2102 fi
2103
2104 case "x$enable_glx$enable_xlib_glx" in
2105 xyesyes)
2106     echo "        GLX:             Xlib-based"
2107     ;;
2108 xyesno)
2109     echo "        GLX:             DRI-based"
2110     ;;
2111 *)
2112     echo "        GLX:             $enable_glx"
2113     ;;
2114 esac
2115
2116 echo ""
2117 echo "        GLU:             $enable_glu"
2118
2119 dnl EGL
2120 echo ""
2121 echo "        EGL:             $enable_egl"
2122 if test "$enable_egl" = yes; then
2123     echo "        EGL platforms:   $EGL_PLATFORMS"
2124
2125     egl_drivers=""
2126     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2127         egl_drivers="$egl_drivers builtin:egl_glx"
2128     fi
2129     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2130         egl_drivers="$egl_drivers builtin:egl_dri2"
2131     fi
2132
2133     if test "x$HAVE_ST_EGL" = xyes; then
2134         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2135         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2136     else
2137         echo "        EGL drivers:    $egl_drivers"
2138     fi
2139 fi
2140
2141 echo ""
2142 if test "x$MESA_LLVM" = x1; then
2143     echo "        llvm:            yes"
2144     echo "        llvm-config:     $LLVM_CONFIG"
2145     echo "        llvm-version:    $LLVM_VERSION"
2146 else
2147     echo "        llvm:            no"
2148 fi
2149
2150 echo ""
2151 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2152     echo "        Gallium:         yes"
2153     echo "        Gallium dirs:    $GALLIUM_DIRS"
2154     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2155     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2156     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2157     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2158 else
2159     echo "        Gallium:         no"
2160 fi
2161
2162
2163 dnl Libraries
2164 echo ""
2165 echo "        Shared libs:     $enable_shared"
2166 echo "        Static libs:     $enable_static"
2167 echo "        Shared-glapi:    $enable_shared_glapi"
2168
2169 dnl Compiler options
2170 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2171 cflags=`echo $CFLAGS $PIC_FLAGS | \
2172     $SED 's/^ *//;s/  */ /;s/ *$//'`
2173 cxxflags=`echo $CXXFLAGS $PIC_FLAGS | \
2174     $SED 's/^ *//;s/  */ /;s/ *$//'`
2175 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2176 echo ""
2177 echo "        CFLAGS:          $cflags"
2178 echo "        CXXFLAGS:        $cxxflags"
2179 echo "        Macros:          $defines"
2180 echo ""
2181 echo "        PYTHON2:         $PYTHON2"
2182
2183 echo ""
2184 echo "        Run '${MAKE-make}' to build Mesa"
2185 echo ""