configure.ac

   1 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   2 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
   3 m4_define([v_maj], [1])
   4 m4_define([v_min], [0])
   5 m4_define([v_mic], [0])
   6 m4_define([v_rev], m4_esyscmd([(svnversion "${SVN_REPO_PATH:-.}" | grep -v export || echo 0) | awk -F : '{printf("%s\n", $1);}' | tr -d ' :MSP\n']))
   7 m4_if(v_rev, [0], [m4_define([v_rev], m4_esyscmd([git log 2> /dev/null | (grep -m1 git-svn-id || echo 0) | sed -e 's/.*@\([0-9]*\).*/\1/' | tr -d '\n']))])
   8 ##--   When released, remove the dnl on the below line
   9 m4_undefine([v_rev])
  10 ##--   When doing snapshots - change soname. remove dnl on below line
  11 dnl m4_define([relname], [ver-pre-svn-07])
  12 dnl m4_define([v_rel], [-release relname])
  13 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  14 m4_ifdef([v_rev], [m4_define([v_ver], [v_maj.v_min.v_mic.v_rev])], [m4_define([v_ver], [v_maj.v_min.v_mic])])
  15 m4_define([lt_rev], m4_eval(v_maj + v_min))
  16 m4_define([lt_cur], v_mic)
  17 m4_define([lt_age], v_min)
  18 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  19 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  20
  21 AC_INIT([eina], [v_ver.beta], [enlightenment-devel@lists.sourceforge.net])
  22 AC_PREREQ([2.59])
  23 AC_CONFIG_SRCDIR([configure.ac])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AC_CANONICAL_BUILD
  26 AC_CANONICAL_HOST
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE([1.6 dist-bzip2])
  30 AM_CONFIG_HEADER([config.h])
  31 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  32
  33 AC_LIBTOOL_WIN32_DLL
  34 define([AC_LIBTOOL_LANG_CXX_CONFIG], [:])dnl
  35 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])dnl
  36 AC_PROG_LIBTOOL
  37
  38 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  39 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  40 m4_ifdef([v_rev], , [m4_define([v_rev], [0])])
  41 m4_ifdef([v_rel], , [m4_define([v_rel], [])])
  42 AC_DEFINE_UNQUOTED(VMAJ, [v_maj], [Major version])
  43 AC_DEFINE_UNQUOTED(VMIN, [v_min], [Minor version])
  44 AC_DEFINE_UNQUOTED(VMIC, [v_mic], [Micro version])
  45 AC_DEFINE_UNQUOTED(VREV, [v_rev], [Revison])
  46 version_info="lt_rev:lt_cur:lt_age"
  47 release_info="v_rel"
  48 AC_SUBST(version_info)
  49 AC_SUBST(release_info)
  50 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  51 ##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##--##
  52 VMAJ=v_maj
  53 AC_SUBST(VMAJ)
  54
  55 ### Needed information
  56
  57 requirement_eina=""
  58
  59 case "$host_os" in
  60    mingw32ce*)
  61       MODULE_ARCH="$host_os-$host_cpu"
  62       ;;
  63    *)
  64       MODULE_ARCH="$host_os-$host_cpu-v_maj.v_min.v_mic"
  65       ;;
  66 esac
  67 AC_SUBST(MODULE_ARCH)
  68 AC_DEFINE_UNQUOTED(MODULE_ARCH, "${MODULE_ARCH}", "Module architecture")
  69
  70 case "$host_os" in
  71    mingw*)
  72       MODULE_EXT=".dll"
  73       ;;
  74    *)
  75       MODULE_EXT=".so"
  76       ;;
  77 esac
  78
  79 AC_DEFINE_UNQUOTED(SHARED_LIB_SUFFIX, "${MODULE_EXT}", [Suffix for shared objects])
  80
  81 EFL_CHECK_CPU_MMX([have_mmx="yes"], [have_mmx="no"])
  82 EFL_CHECK_CPU_SSE([have_sse="yes"], [have_sse="no"])
  83 EFL_CHECK_CPU_SSE2([have_sse2="yes"], [have_sse2="no"])
  84 EFL_CHECK_CPU_ALTIVEC([have_altivec="yes"], [have_altivec="no"])
  85
  86 EFL_CHECK_THREADS(
  87    [
  88     if test "x${_efl_have_posix_threads}" = "xyes" ; then
  89        have_threads="POSIX"
  90     else
  91        if test "x${_efl_have_win32_threads}" = "xyes" ; then
  92           have_threads="Win32"
  93        else
  94           have_threads="no"
  95        fi
  96     fi
  97    ],
  98    [have_threads="no"])
  99 EFL_CHECK_SPINLOCK([have_posix_threads_spinlock="yes"], [have_posix_threads_spinlock="no"])
 100
 101 ### Additional options to configure
 102
 103 # Magic debug
 104 AC_ARG_ENABLE([magic-debug],
 105    [AC_HELP_STRING([--disable-magic-debug], [disable magic debug of eina structure @<:@default=enabled@:>@])],
 106    [
 107     if test "x${enableval}" = "xyes" ; then
 108        have_magic_debug="yes"
 109     else
 110        have_magic_debug="no"
 111     fi
 112    ],
 113    [have_magic_debug="yes"])
 114
 115 AC_MSG_CHECKING([whether magic debug is enable])
 116 AC_MSG_RESULT([${have_magic_debug}])
 117
 118 if test "x${have_magic_debug}" = "xyes" ; then
 119    EINA_CONFIGURE_MAGIC_DEBUG="#define EINA_MAGIC_DEBUG"
 120 fi
 121 AC_SUBST(EINA_CONFIGURE_MAGIC_DEBUG)
 122
 123 # Safety checks (avoid crashes on wrong api usage)
 124 AC_ARG_ENABLE(safety-checks,
 125    [AC_HELP_STRING([--disable-safety-checks], [disable safety checks for NULL pointers and like. @<:@default=enabled@:>@])],
 126    [
 127     if test "x${enableval}" = "xyes" ; then
 128        have_safety_checks="yes"
 129     else
 130        have_safety_checks="no"
 131     fi
 132    ],
 133    [have_safety_checks="yes"])
 134
 135 AC_MSG_CHECKING(whether to do safety checking on api parameters)
 136 AC_MSG_RESULT($have_safety_checks)
 137
 138 AM_CONDITIONAL(SAFETY_CHECKS, test "x$have_safety_checks" = "xyes")
 139 if test "x$have_safety_checks" = "xyes"; then
 140   AC_DEFINE(EINA_SAFETY_CHECKS, 1, [disable safety checks for NULL pointers and like.])
 141   EINA_CONFIGURE_SAFETY_CHECKS="#define EINA_SAFETY_CHECKS"
 142 fi
 143 AC_SUBST(EINA_CONFIGURE_SAFETY_CHECKS)
 144
 145 with_max_log_level="<unset>"
 146 AC_ARG_WITH(internal-maximum-log-level,
 147    [AC_HELP_STRING([--with-internal-maximum-log-level=NUMBER],
 148                    [limit eina internal log level to the given number, any call to EINA_LOG() with values greater than this will be compiled out, ignoring runtime settings, but saving function calls.])],
 149    [
 150     if test "x${withval}" != "xno"; then
 151        if echo "${withval}" | grep '^[[0-9]]\+$' >/dev/null 2>/dev/null; then
 152           AC_MSG_NOTICE([ignoring any EINA_LOG() with level greater than ${withval}])
 153           AC_DEFINE_UNQUOTED(EINA_LOG_LEVEL_MAXIMUM, ${withval}, [if set, logging is limited to this amount.])
 154           with_max_log_level="${withval}"
 155        else
 156           AC_MSG_ERROR([--with-internal-maximum-log-level takes a decimal number, got "${withval}" instead.])
 157        fi
 158     fi
 159     ], [:])
 160
 161 AC_ARG_ENABLE([amalgamation],
 162    [AC_HELP_STRING([--enable-amalgamation], [enable generation of one single file with all source code in it, helps compiler optimizations.])],
 163    [if test "x${enableval}" = "xyes"; then
 164        do_amalgamation="yes"
 165     else
 166        do_amalgamation="no"
 167     fi
 168    ],
 169    [do_amalgamation="no"]
 170 )
 171 AM_CONDITIONAL(EINA_AMALGAMATION, test "x${do_amalgamation}" = "xyes")
 172
 173 # Choose best memory pool
 174 AC_ARG_ENABLE([default-mempool],
 175    [AC_HELP_STRING([--enable-default-mempool], [Default memory allocator could be faster for some computer. @<:@default=disabled@:>@])],
 176    [
 177     if test "x${enableval}" = "xyes"; then
 178        have_default_mempool="yes"
 179     else
 180        have_default_mempool="no"
 181     fi
 182    ],
 183    [have_default_mempool="no"]
 184 )
 185 AC_MSG_CHECKING([whether to use default mempool allocator])
 186 AC_MSG_RESULT([${have_default_mempool}])
 187
 188 if test "x${have_default_mempool}" = "xyes" ; then
 189    EINA_CONFIGURE_DEFAULT_MEMPOOL="#define EINA_DEFAULT_MEMPOOL"
 190 fi
 191 AC_SUBST(EINA_CONFIGURE_DEFAULT_MEMPOOL)
 192
 193 # Report stringshare usage
 194 AC_ARG_ENABLE([stringshare-usage],
 195    [AC_HELP_STRING([--enable-stringshare-usage], [Report stringshare usage on stringshare shutdown. @<:@default=disabled@:>@])],
 196    [
 197     if test "x${enableval}" = "xyes"; then
 198        have_stringshare_usage="yes"
 199     else
 200        have_stringshare_usage="no"
 201     fi
 202    ],
 203    [have_stringshare_usage="no"]
 204 )
 205 AC_MSG_CHECKING([whether to report stringshare usage])
 206 AC_MSG_RESULT([${have_stringshare_usage}])
 207
 208 if test "x${have_stringshare_usage}" = "xyes"; then
 209    AC_DEFINE(EINA_STRINGSHARE_USAGE, 1, [Report Eina stringshare usage pattern])
 210 fi
 211
 212 # Check if we want to benchmark on real data
 213 enable_benchmark_e17="no"
 214 AC_ARG_ENABLE([e17],
 215    [AC_HELP_STRING([--enable-e17], [enable heavy benchmark @<:@default=no@:>@])],
 216    [
 217     if test "x${enableval}" = "xyes" ; then
 218        enable_benchmark_e17="yes"
 219     else
 220        enable_benchmark_e17="no"
 221     fi
 222    ],
 223    [enable_benchmark_e17="no"])
 224
 225 AC_MSG_CHECKING([whether e17 real data benchmark are built])
 226 AC_MSG_RESULT([${enable_benchmark_e17}])
 227
 228 AM_CONDITIONAL(EINA_ENABLE_BENCHMARK_E17, test "x${enable_benchmark_e17}" = "xyes")
 229
 230
 231 ### Checks for programs
 232 AC_PROG_CC
 233
 234 # pkg-config
 235 PKG_PROG_PKG_CONFIG
 236
 237 # Check whether pkg-config supports Requires.private
 238 if $PKG_CONFIG --atleast-pkgconfig-version 0.22; then
 239    pkgconfig_requires_private="Requires.private"
 240 else
 241    pkgconfig_requires_private="Requires"
 242 fi
 243 AC_SUBST(pkgconfig_requires_private)
 244
 245 # doxygen program for documentation building
 246
 247 EFL_CHECK_DOXYGEN([build_doc="yes"], [build_doc="no"])
 248
 249
 250 ### Checks for libraries
 251
 252 # Evil library for compilation on Windows CE
 253
 254 EFL_EINA_BUILD=""
 255 case "$host_os" in
 256    mingw*)
 257       PKG_CHECK_MODULES([EVIL], [evil])
 258       AC_DEFINE(HAVE_EVIL, 1, [Set to 1 if evil package is installed])
 259       requirement_eina="evil"
 260       EFL_EINA_BUILD="-DEFL_EINA_BUILD"
 261    ;;
 262 esac
 263 AC_SUBST(EFL_EINA_BUILD)
 264
 265 # Check ememoa memory pool library
 266
 267 AC_ARG_ENABLE([ememoa],
 268    [AC_HELP_STRING([--enable-ememoa], [build ememoa memory pool module @<:@default=yes@:>@])],
 269    [
 270     if test "x${enableval}" = "xyes" ; then
 271        enable_ememoa="yes"
 272     else
 273        enable_ememoa="no"
 274     fi
 275    ],
 276    [enable_ememoa="yes"]
 277 )
 278 AC_MSG_CHECKING([whether to use ememoa for memory pool])
 279 AC_MSG_RESULT([$enable_ememoa])
 280
 281 if test "x${enable_ememoa}" = "xyes" ; then
 282    PKG_CHECK_MODULES([EMEMOA],
 283       [ememoa >= 0.0.26 ],
 284       [enable_ememoa="yes"],
 285       [enable_ememoa="no"]
 286    )
 287 fi
 288
 289
 290 ### Checks for header files
 291 AC_HEADER_ASSERT
 292 AC_HEADER_DIRENT
 293 AC_HEADER_TIME
 294
 295
 296 ### Checks for types
 297 AC_CHECK_HEADER([inttypes.h],
 298                 [EINA_CONFIGURE_HAVE_INTTYPES_H="#define EINA_HAVE_INTTYPES_H"])
 299 AC_SUBST(EINA_CONFIGURE_HAVE_INTTYPES_H)
 300
 301 AC_CHECK_HEADER([stdint.h],
 302                 [EINA_CONFIGURE_HAVE_STDINT_H="#define EINA_HAVE_STDINT_H"])
 303 AC_SUBST(EINA_CONFIGURE_HAVE_STDINT_H)
 304
 305 AC_CHECK_SIZEOF(wchar_t)
 306 EINA_SIZEOF_WCHAR_T=$ac_cv_sizeof_wchar_t
 307 AC_SUBST(EINA_SIZEOF_WCHAR_T)
 308
 309 ### Checks for structures
 310
 311
 312 ### Checks for compiler characteristics
 313 AC_C_CONST
 314 AC_C_BIGENDIAN
 315 AC_C_INLINE
 316 AC_C___ATTRIBUTE__
 317 AC_PROG_CC_STDC
 318
 319 EINA_CPPFLAGS=""
 320 EINA_CFLAGS=""
 321 case "$host_os" in
 322    mingw32ce*)
 323       EINA_CPPFLAGS="-D_WIN32_WCE=0x0420"
 324       EINA_CFLAGS="${EVIL_CFLAGS}"
 325       ;;
 326    mingw*)
 327       EINA_CPPFLAGS="-D_WIN32_WINNT=0x0501"
 328       EINA_CFLAGS="${EVIL_CFLAGS}"
 329       ;;
 330 esac
 331
 332 m4_ifdef([v_mic],
 333    [
 334     EFL_COMPILER_FLAG([-Wall])
 335     EFL_COMPILER_FLAG([-W])
 336    ])
 337
 338 EFL_COMPILER_FLAG([-Wshadow])
 339
 340 AC_SUBST(EINA_CPPFLAGS)
 341 AC_SUBST(EINA_CFLAGS)
 342
 343
 344 ### Checks for linker characteristics
 345 EINA_LIBS=
 346 lt_enable_auto_import=""
 347 case "${host_os}" in
 348    mingw*)
 349       EINA_LIBS="-ldl ${EVIL_LIBS} -lm"
 350       lt_enable_auto_import="-Wl,--enable-auto-import"
 351    ;;
 352    dragonfly*|openbsd*)
 353       EINA_LIBS="-lm"
 354    ;;
 355    freebsd*|netbsd*)
 356       EINA_LIBS="-lrt -lm"
 357    ;;
 358    darwin*)
 359       EINA_LIBS="-lm"
 360    ;;
 361    cygwin*)
 362       EINA_LIBS="-ldl -lm"
 363    ;;
 364    *)
 365       EINA_LIBS="-ldl -lrt -lm"
 366    ;;
 367 esac
 368 AC_SUBST(EINA_LIBS)
 369 AC_SUBST(lt_enable_auto_import)
 370
 371 EFL_LINKER_FLAG([-fno-strict-aliasing])
 372
 373
 374 ### Checks for library functions
 375 AC_FUNC_ALLOCA
 376 AC_CHECK_FUNCS(strlcpy)
 377
 378 #dlopen and dladdr
 379 dlopen_libs=""
 380 case "$host_os" in
 381    mingw*)
 382 # managed by evil
 383       AC_DEFINE(HAVE_DLADDR)
 384       ;;
 385    *)
 386       AC_CHECK_FUNCS([dlopen], [res="yes"], [res="no"])
 387       if test "x${res}" = "xyes" ; then
 388          AC_CHECK_FUNCS([dladdr], [AC_DEFINE(HAVE_DLADDR)])
 389       else
 390          AC_CHECK_LIB([dl], [dlopen], [res="yes"], [res="no"])
 391          if test "x${res}" = "xyes" ; then
 392             AC_CHECK_LIB([dl], [dladdr], [AC_DEFINE(HAVE_DLADDR)])
 393             dlopen_libs="-ldl"
 394          else
 395             AC_MSG_ERROR([Cannot find dlopen])
 396          fi
 397       fi
 398       ;;
 399 esac
 400 AC_SUBST(dlopen_libs)
 401
 402 EFL_CHECK_FNMATCH([], [AC_MSG_ERROR([Cannot find fnmatch()])])
 403
 404 # iconv library
 405 have_iconv="no"
 406 AC_ARG_WITH([iconv-link],
 407    AC_HELP_STRING([--with-iconv-link=ICONV_LINK], [explicitly specify an iconv link option]),
 408    [
 409     LIBS="$withval $LIBS"
 410     have_iconv="yes"
 411    ])
 412
 413 AC_MSG_CHECKING(for explicit iconv link options)
 414 if test "x${iconv_libs}" = "x" ; then
 415    AC_MSG_RESULT([no explicit iconv link option])
 416 else
 417    AC_MSG_RESULT([$iconv_libs])
 418 fi
 419
 420 if test "x${have_iconv}" = "xno" ; then
 421    AC_CHECK_HEADERS([iconv.h], [have_iconv="yes"])
 422
 423    if test "x${have_iconv}" = "xyes" ; then
 424       AC_MSG_CHECKING([whether iconv() is in libc])
 425
 426       AC_LINK_IFELSE(
 427          [AC_LANG_PROGRAM(
 428              [[
 429 #include <stdlib.h>
 430 #include <iconv.h>
 431              ]],
 432              [[
 433 iconv_t ic;
 434 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 435              ]])],
 436          [have_iconv="yes"],
 437          [have_iconv="no"])
 438
 439       AC_MSG_RESULT([${have_iconv}])
 440    fi
 441
 442    if test "x${have_iconv}" = "xno" ; then
 443       AC_MSG_CHECKING([whether iconv() is in libiconv.a])
 444
 445       LIBS_save="${LIBS}"
 446       LIBS="-liconv $LIBS"
 447       AC_LINK_IFELSE(
 448          [AC_LANG_PROGRAM(
 449              [[
 450 #include <stdlib.h>
 451 #include <iconv.h>
 452              ]],
 453              [[
 454 iconv_t ic;
 455 size_t count;
 456 count = iconv(ic, NULL, NULL, NULL, NULL);
 457              ]])],
 458          [have_iconv="yes"],
 459          [
 460           have_iconv="no"
 461           LIBS=${LIBS_save}
 462          ])
 463
 464       AC_MSG_RESULT([${have_iconv}])
 465    fi
 466
 467    if test "x${have_iconv}" = "xno" ; then
 468       AC_MSG_CHECKING([whether iconv() is in libiconv_plug.a])
 469
 470       LIBS_save="${LIBS}"
 471       LIBS="-liconv_plug $LIBS"
 472       AC_LINK_IFELSE(
 473          [AC_LANG_PROGRAM(
 474              [[
 475 #include <stdlib.h>
 476 #include <iconv.h>
 477              ]],
 478              [[
 479 iconv_t ic;
 480 size_t count = iconv(ic, NULL, NULL, NULL, NULL);
 481              ]])],
 482          [have_iconv="yes"],
 483          [
 484           have_iconv="no"
 485           LIBS=${LIBS_save}
 486          ])
 487
 488       AC_MSG_RESULT([${have_iconv}])
 489    fi
 490 fi
 491
 492 if test "x${have_iconv}" = "xyes" ; then
 493    AC_DEFINE([HAVE_ICONV], [1], [Set to 1 if iconv library is installed])
 494 fi
 495
 496
 497 ### Modules
 498
 499 if test "x${have_default_mempool}" = "xyes" ; then
 500    enable_chained_pool="no"
 501    enable_pass_through="static"
 502 else
 503    enable_chained_pool="static"
 504    enable_pass_through="no"
 505 fi
 506
 507 enable_one_big="static"
 508
 509 EINA_CHECK_MODULE([chained-pool],   [${enable_chained_pool}], [chained pool])
 510 EINA_CHECK_MODULE([ememoa-fixed],   [${enable_ememoa}],       [ememoa fixed])
 511 EINA_CHECK_MODULE([ememoa-unknown], [${enable_ememoa}],       [ememoa unknown])
 512 EINA_CHECK_MODULE([fixed-bitmap],   [no],                     [fixed bitmap])
 513 EINA_CHECK_MODULE([pass-through],   [${enable_pass_through}], [pass through])
 514 EINA_CHECK_MODULE([buddy],          [no],                     [buddy])
 515 EINA_CHECK_MODULE([one-big],        [${enable_one_big}],      [one big])
 516
 517 ### Make the debug preprocessor configurable
 518
 519 ### Unit tests, coverage and benchmarking
 520
 521 EFL_CHECK_TESTS([enable_tests="yes"], [enable_tests="no"])
 522
 523 EFL_CHECK_COVERAGE([${enable_tests}], [enable_coverage="yes"], [enable_coverage="no"])
 524 EINA_CFLAGS="${EINA_CFLAGS} ${EFL_COVERAGE_CFLAGS}"
 525 EINA_LIBS="${EINA_LIBS} ${EFL_COVERAGE_LIBS}"
 526 if test "x$enable_coverage" = "xyes" ; then
 527    EINA_CFLAGS="${EINA_CFLAGS} ${EFL_DEBUG_CFLAGS}"
 528 fi
 529
 530 EFL_CHECK_BENCHMARK([enable_benchmark="yes"], [enable_benchmark="no"])
 531 EINA_BENCH_MODULE([glib], [${enable_benchmark}], [glib-2.0], [enable_benchmark_glib="yes"], [enable_benchmark_glib="no"])
 532
 533 AC_SUBST(requirement_eina)
 534
 535 ### Create the .pc.in file according to the major version
 536 #cat > ${srcdir}/eina-${VMAJ}.pc.in << EOF
 537 #prefix=@prefix@
 538 #exec_prefix=@exec_prefix@
 539 #libdir=@libdir@
 540 #includedir=@includedir@
 541 #
 542 #Name: Eina
 543 #Description: A Library that implements fast data types and miscellaneous tools
 544 #Requires:
 545 #Version: @VERSION@
 546 #Libs: -L${libdir} -leina
 547 #Libs.private: -ldl
 548 #Cflags: -I${includedir}/eina-@VMAJ@ -I${includedir}/eina-@VMAJ@/eina
 549 #EOF
 550
 551 AC_CONFIG_FILES([
 552 Makefile
 553 eina.pc
 554 eina.spec
 555 doc/Makefile
 556 src/Makefile
 557 src/include/Makefile
 558 src/include/eina_config.h
 559 src/lib/Makefile
 560 src/modules/Makefile
 561 src/modules/mp/Makefile
 562 src/modules/mp/chained_pool/Makefile
 563 src/modules/mp/ememoa_fixed/Makefile
 564 src/modules/mp/ememoa_unknown/Makefile
 565 src/modules/mp/pass_through/Makefile
 566 src/modules/mp/fixed_bitmap/Makefile
 567 src/modules/mp/buddy/Makefile
 568 src/modules/mp/one_big/Makefile
 569 src/tests/Makefile
 570 ])
 571
 572 AC_OUTPUT
 573
 574 #####################################################################
 575 ## Info
 576
 577 echo
 578 echo
 579 echo
 580 echo "------------------------------------------------------------------------"
 581 echo "$PACKAGE $VERSION"
 582 echo "------------------------------------------------------------------------"
 583 echo
 584 echo
 585 echo "Configuration Options Summary:"
 586 echo
 587 echo "  Magic debug..........: ${have_magic_debug}"
 588 echo "  Safety checks........: ${have_safety_checks}"
 589 echo "  Maximum log level....: ${with_max_log_level}"
 590 echo "  Report string usage..: ${have_stringshare_usage}"
 591 echo "  Default mempool......: ${have_default_mempool}"
 592 echo "  Thread Support.......: ${have_threads}"
 593 if test "${have_threads}" = "POSIX" ; then
 594 echo "    spinlock...........: ${have_posix_threads_spinlock}"
 595 fi
 596 echo "  Amalgamation.........: ${do_amalgamation}"
 597 echo "  Iconv support........: ${have_iconv}"
 598 echo
 599 echo "  Documentation........: ${build_doc}"
 600 echo "  Tests................: ${enable_tests}"
 601 echo "  Coverage.............: ${enable_coverage}"
 602 echo "  Benchmark............: ${enable_benchmark}"
 603 if test "x${enable_benchmark}" = "xyes" ; then
 604 echo "    Glib...............: ${enable_benchmark_glib}"
 605 echo "    E17 real data......: ${enable_benchmark_e17}"
 606 fi
 607 echo
 608 echo "  CPU Specific Extensions:"
 609 echo "    MMX................: ${have_mmx}"
 610 echo "    SSE................: ${have_sse}"
 611 echo "    SSE2...............: ${have_sse2}"
 612 echo "    ALTIVEC............: ${have_altivec}"
 613 echo
 614 echo "  Memory pools:"
 615 echo "    Chained pool.......: ${enable_chained_pool}"
 616 echo "    Ememoa fixed.......: ${enable_ememoa_fixed}"
 617 echo "    Ememoa unknown.....: ${enable_ememoa_unknown}"
 618 echo "    Fixed bitmap.......: ${enable_fixed_bitmap}"
 619 echo "    Pass through.......: ${enable_pass_through}"
 620 echo "    Buddy..............: ${enable_buddy}"
 621 echo "    One big............: ${enable_one_big}"
 622 echo
 623 echo "Compilation............: make (or gmake)"
 624 echo "  CPPFLAGS.............: $CPPFLAGS"
 625 echo "  CFLAGS...............: $CFLAGS"
 626 echo "  LDFLAGS..............: $LDFLAGS"
 627 echo
 628 echo "Installation...........: make install (as root if needed, with 'su' or 'sudo')"
 629 echo "  prefix...............: $prefix"
 630 echo
 631 EFL_FORM_VOLTRON