configure.ac

   1 # -*- autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1991-2012 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Written by Jim Meyering.
  20
  21 AC_PREREQ([2.64])
  22
  23 # Make inter-release version strings look like, e.g., v6.9-219-g58ddd, which
  24 # indicates that it is built from the 219th delta (in _some_ repository)
  25 # following the v6.9 tag, and that 58ddd is a prefix of the commit SHA1.
  26 AC_INIT([GNU coreutils],
  27         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  28         [bug-coreutils@gnu.org])
  29
  30 AC_CONFIG_SRCDIR([src/ls.c])
  31
  32 AC_CONFIG_AUX_DIR([build-aux])
  33 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  34
  35 AM_INIT_AUTOMAKE([1.11.2 no-dist-gzip dist-xz color-tests parallel-tests
  36                   subdir-objects])
  37 AM_SILENT_RULES([yes]) # make --enable-silent-rules the default.
  38
  39 dnl POSIXCHECK is worthwhile for maintainers, but adds several seconds
  40 dnl (more than 10% execution time) to ./configure, with no benefit for
  41 dnl most users.  Using it to look for bugs requires:
  42 dnl   GNULIB_POSIXCHECK=1 autoreconf -f
  43 dnl   ./configure
  44 dnl   make
  45 dnl   make -C src clean
  46 dnl   make CFLAGS=-DGNULIB_POSIXCHECK=1
  47 dnl FIXME: Once we figure out how to avoid false positives, we should
  48 dnl have 'make my-distcheck' in dist-check.mk exercise this.
  49 m4_syscmd([test "${GNULIB_POSIXCHECK+set}" = set])
  50 m4_if(m4_sysval, [0], [], [dnl
  51 gl_ASSERT_NO_GNULIB_POSIXCHECK])
  52
  53 AC_PROG_CC_STDC
  54 AM_PROG_CC_C_O
  55 AC_PROG_CPP
  56 AC_PROG_GCC_TRADITIONAL
  57 AC_PROG_RANLIB
  58 AC_PROG_LN_S
  59 gl_EARLY
  60 gl_INIT
  61 coreutils_MACROS
  62
  63 # The test suite needs to know if we have a working perl.
  64 # FIXME: this is suboptimal.  Ideally, we would be able to call gl_PERL
  65 # with an ACTION-IF-NOT-FOUND argument ...
  66 cu_have_perl=yes
  67 case $PERL in *"/missing ") cu_have_perl=no;; esac
  68 AM_CONDITIONAL([HAVE_PERL], [test $cu_have_perl = yes])
  69
  70 AC_ARG_ENABLE([gcc-warnings],
  71   [AS_HELP_STRING([--enable-gcc-warnings],
  72                   [turn on lots of GCC warnings (for developers)])],
  73   [case $enableval in
  74      yes|no) ;;
  75      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
  76    esac
  77    gl_gcc_warnings=$enableval],
  78   [gl_gcc_warnings=no]
  79 )
  80
  81 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
  82 # ------------------------------------------------
  83 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
  84 # Otherwise, run RUN-IF-NOT-FOUND.
  85 AC_DEFUN([gl_GCC_VERSION_IFELSE],
  86   [AC_PREPROC_IFELSE(
  87     [AC_LANG_PROGRAM(
  88       [[
  89 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
  90 /* ok */
  91 #else
  92 # error "your version of gcc is older than $1.$2"
  93 #endif
  94       ]]),
  95     ], [$3], [$4])
  96   ]
  97 )
  98
  99 if test "$gl_gcc_warnings" = yes; then
 100   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 101   AC_SUBST([WERROR_CFLAGS])
 102
 103   nw=
 104   # This, $nw, is the list of warnings we disable.
 105   nw="$nw -Wdeclaration-after-statement" # too useful to forbid
 106   nw="$nw -Waggregate-return"       # anachronistic
 107   nw="$nw -Wlong-long"              # C90 is anachronistic (lib/gethrxtime.h)
 108   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 109   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 110   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 111   nw="$nw -Wcast-qual"              # Too many warnings for now
 112   nw="$nw -Wconversion"             # Too many warnings for now
 113   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 114   nw="$nw -Wsign-conversion"        # Too many warnings for now
 115   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 116   nw="$nw -Wunreachable-code"       # Too many warnings for now
 117   nw="$nw -Wpadded"                 # Our structs are not padded
 118   nw="$nw -Wredundant-decls"        # openat.h declares e.g., mkdirat
 119   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 120   nw="$nw -Wformat-nonliteral"      # who.c and pinky.c strftime uses
 121   nw="$nw -Wvla"                    # warnings in gettext.h
 122   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 123   nw="$nw -Wswitch-enum"            # Too many warnings for now
 124   nw="$nw -Wswitch-default"         # Too many warnings for now
 125   nw="$nw -Wstack-protector"        # not worth working around
 126   # things I might fix soon:
 127   nw="$nw -Wfloat-equal"            # sort.c, seq.c
 128   nw="$nw -Wmissing-format-attribute" # copy.c
 129   nw="$nw -Wunsafe-loop-optimizations" # a few src/*.c
 130   nw="$nw -Winline"                 # system.h's readdir_ignoring_dot_and_dotdot
 131   nw="$nw -Wsuggest-attribute=format" # warns about copy.c and factor.c
 132
 133   # Using -Wstrict-overflow is a pain, but the alternative is worse.
 134   # For an example, see the code that provoked this report:
 135   # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=33498
 136   # Code like that still infloops with gcc-4.6.0 and -O2.  Scary indeed.
 137
 138   gl_MANYWARN_ALL_GCC([ws])
 139   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 140   for w in $ws; do
 141     gl_WARN_ADD([$w])
 142   done
 143   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 144   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 145   gl_WARN_ADD([-Wsuggest-attribute=const])
 146   gl_WARN_ADD([-Wsuggest-attribute=noreturn])
 147   gl_WARN_ADD([-Wno-format-nonliteral])
 148
 149   # Enable this warning only with gcc-4.7 and newer.  With 4.6.2 20111027,
 150   # it suggests test.c's advance function may be pure, even though it
 151   # increments a global variable.  Oops.
 152   # Normally we'd write code to test for the precise failure, but that
 153   # requires a relatively large input to make gcc exhibit the failure.
 154   gl_GCC_VERSION_IFELSE([4], [7], [gl_WARN_ADD([-Wsuggest-attribute=pure])])
 155
 156   # In spite of excluding -Wlogical-op above, it is enabled, as of
 157   # gcc 4.5.0 20090517, and it provokes warnings in cat.c, dd.c, truncate.c
 158   gl_WARN_ADD([-Wno-logical-op])
 159
 160   gl_WARN_ADD([-fdiagnostics-show-option])
 161   gl_WARN_ADD([-funit-at-a-time])
 162
 163   AC_SUBST([WARN_CFLAGS])
 164
 165   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 166   AH_VERBATIM([FORTIFY_SOURCE],
 167   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 168       without upsetting glibc 2.15+. */
 169    #if defined __OPTIMIZE__ && __OPTIMIZE__
 170    # define _FORTIFY_SOURCE 2
 171    #endif
 172   ])
 173   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 174
 175   # We use a slightly smaller set of warning options for lib/.
 176   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 177   nw=
 178   nw="$nw -Wstrict-overflow"
 179   nw="$nw -Wuninitialized"
 180   nw="$nw -Wunused-macros"
 181   nw="$nw -Wmissing-prototypes"
 182   nw="$nw -Wold-style-definition"
 183   # FIXME: it may be easy to remove this, since it affects only one file:
 184   # the snprintf call at ftoastr.c:132.
 185   nw="$nw -Wdouble-promotion"
 186   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 187   AC_SUBST([GNULIB_WARN_CFLAGS])
 188
 189   # For gnulib-tests, the set is slightly smaller still.
 190   nw=
 191   nw="$nw -Wstrict-prototypes"
 192   # It's not worth being this picky about test programs.
 193   nw="$nw -Wsuggest-attribute=const"
 194   nw="$nw -Wsuggest-attribute=pure"
 195   gl_MANYWARN_COMPLEMENT([GNULIB_TEST_WARN_CFLAGS],
 196                          [$GNULIB_WARN_CFLAGS], [$nw])
 197   AC_SUBST([GNULIB_TEST_WARN_CFLAGS])
 198 fi
 199
 200 AC_FUNC_FORK
 201
 202 optional_bin_progs=
 203 AC_CHECK_FUNCS([chroot],
 204         gl_ADD_PROG([optional_bin_progs], [chroot]))
 205 AC_CHECK_FUNCS([gethostid],
 206         gl_ADD_PROG([optional_bin_progs], [hostid]))
 207
 208 gl_WINSIZE_IN_PTEM
 209
 210 AC_MSG_CHECKING([whether localtime caches TZ])
 211 AC_CACHE_VAL([utils_cv_localtime_cache],
 212 [if test x$ac_cv_func_tzset = xyes; then
 213 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
 214 #if STDC_HEADERS
 215 # include <stdlib.h>
 216 #endif
 217 extern char **environ;
 218 void unset_TZ (void)
 219 {
 220   char **from, **to;
 221   for (to = from = environ; (*to = *from); from++)
 222     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
 223       to++;
 224 }
 225 int main()
 226 {
 227   time_t now = time ((time_t *) 0);
 228   int hour_GMT0, hour_unset;
 229   if (putenv ("TZ=GMT0") != 0)
 230     return 1;
 231   hour_GMT0 = localtime (&now)->tm_hour;
 232   unset_TZ ();
 233   hour_unset = localtime (&now)->tm_hour;
 234   if (putenv ("TZ=PST8") != 0)
 235     return 1;
 236   if (localtime (&now)->tm_hour == hour_GMT0)
 237     return 1;
 238   unset_TZ ();
 239   if (localtime (&now)->tm_hour != hour_unset)
 240     return 1;
 241   return 0;
 242 }]])],
 243 [utils_cv_localtime_cache=no],
 244 [utils_cv_localtime_cache=yes],
 245 [# If we have tzset, assume the worst when cross-compiling.
 246 utils_cv_localtime_cache=yes])
 247 else
 248         # If we lack tzset, report that localtime does not cache TZ,
 249         # since we can't invalidate the cache if we don't have tzset.
 250         utils_cv_localtime_cache=no
 251 fi])dnl
 252 AC_MSG_RESULT([$utils_cv_localtime_cache])
 253 if test $utils_cv_localtime_cache = yes; then
 254   AC_DEFINE([LOCALTIME_CACHE], [1], [FIXME])
 255 fi
 256
 257 # SCO-ODT-3.0 is reported to need -los to link programs using initgroups
 258 AC_CHECK_FUNCS([initgroups])
 259 if test $ac_cv_func_initgroups = no; then
 260   AC_CHECK_LIB([os], [initgroups])
 261 fi
 262
 263 AC_CHECK_FUNCS([syslog])
 264 if test $ac_cv_func_syslog = no; then
 265   # syslog is not in the default libraries.  See if it's in some other.
 266   for lib in bsd socket inet; do
 267     AC_CHECK_LIB([$lib], [syslog], [AC_DEFINE([HAVE_SYSLOG], [1], [FIXME])
 268       LIBS="$LIBS -l$lib"; break])
 269   done
 270 fi
 271
 272 AC_CACHE_CHECK([for 3-argument setpriority function],
 273   [utils_cv_func_setpriority],
 274   [AC_LINK_IFELSE(
 275     [AC_LANG_PROGRAM(
 276        [[#include <sys/time.h>
 277          #include <sys/resource.h>
 278        ]],
 279        [[setpriority (0, 0, 0);]])],
 280     [utils_cv_func_setpriority=yes],
 281     [utils_cv_func_setpriority=no])])
 282 if test $utils_cv_func_setpriority = no; then
 283   AC_CHECK_FUNCS([nice])
 284 fi
 285 case $utils_cv_func_setpriority,$ac_cv_func_nice in
 286 *yes*)
 287   gl_ADD_PROG([optional_bin_progs], [nice])
 288 esac
 289
 290 AC_DEFUN([coreutils_DUMMY_1],
 291 [
 292   AC_REQUIRE([gl_READUTMP])
 293   if test $ac_cv_header_utmp_h = yes || test $ac_cv_header_utmpx_h = yes; then
 294     gl_ADD_PROG([optional_bin_progs], [who])
 295     gl_ADD_PROG([optional_bin_progs], [users])
 296     gl_ADD_PROG([optional_bin_progs], [pinky])
 297   fi
 298 ])
 299 coreutils_DUMMY_1
 300
 301 AC_MSG_CHECKING([ut_host in struct utmp])
 302 AC_CACHE_VAL([su_cv_func_ut_host_in_utmp],
 303 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 304 #include <utmp.h>]], [[struct utmp ut; return !sizeof ut.ut_host;]])],
 305   [su_cv_func_ut_host_in_utmp=yes],
 306   [su_cv_func_ut_host_in_utmp=no])])
 307 AC_MSG_RESULT([$su_cv_func_ut_host_in_utmp])
 308 if test $su_cv_func_ut_host_in_utmp = yes; then
 309   have_ut_host=1
 310   AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 311 fi
 312
 313 if test -z "$have_ut_host"; then
 314   AC_MSG_CHECKING([ut_host in struct utmpx])
 315   AC_CACHE_VAL([su_cv_func_ut_host_in_utmpx],
 316   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 317 #include <utmpx.h>]], [[struct utmpx ut; return !sizeof ut.ut_host;]])],
 318     [su_cv_func_ut_host_in_utmpx=yes],
 319     [su_cv_func_ut_host_in_utmpx=no])])
 320   AC_MSG_RESULT([$su_cv_func_ut_host_in_utmpx])
 321   if test $su_cv_func_ut_host_in_utmpx = yes; then
 322     AC_DEFINE([HAVE_UTMPX_H], [1], [FIXME])
 323     AC_DEFINE([HAVE_UT_HOST], [1], [FIXME])
 324   fi
 325 fi
 326
 327 GNULIB_BOOT_TIME([gl_ADD_PROG([optional_bin_progs], [uptime])])
 328
 329 AC_SYS_POSIX_TERMIOS()
 330 gl_HEADER_TIOCGWINSZ_NEEDS_SYS_IOCTL
 331
 332 if test $ac_cv_sys_posix_termios = yes; then
 333   gl_ADD_PROG([optional_bin_progs], [stty])
 334
 335   AC_MSG_CHECKING([whether termios.h needs _XOPEN_SOURCE])
 336   AC_CACHE_VAL([su_cv_sys_termios_needs_xopen_source],
 337   [AC_EGREP_CPP([yes], [#include <termios.h>
 338 #ifdef IUCLC
 339 yes
 340 #endif], su_cv_sys_termios_needs_xopen_source=no,
 341    AC_EGREP_CPP([yes], [#define _XOPEN_SOURCE
 342 #include <termios.h>
 343 #ifdef IUCLC
 344 yes
 345 #endif], su_cv_sys_termios_needs_xopen_source=yes,
 346    su_cv_sys_termios_needs_xopen_source=no))])
 347   AC_MSG_RESULT([$su_cv_sys_termios_needs_xopen_source])
 348   test $su_cv_sys_termios_needs_xopen_source = yes &&
 349     AC_DEFINE([TERMIOS_NEEDS_XOPEN_SOURCE], [1], [FIXME])
 350
 351   AC_MSG_CHECKING([c_line in struct termios])
 352   AC_CACHE_VAL([su_cv_sys_c_line_in_termios],
 353   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#if TERMIOS_NEEDS_XOPEN_SOURCE
 354 #define _XOPEN_SOURCE
 355 #endif
 356 #include <sys/types.h>
 357 #include <termios.h>]], [[struct termios t; return !sizeof t.c_line;]])],
 358     [su_cv_sys_c_line_in_termios=yes],
 359     [su_cv_sys_c_line_in_termios=no])])
 360   AC_MSG_RESULT([$su_cv_sys_c_line_in_termios])
 361   test $su_cv_sys_c_line_in_termios = yes \
 362     && AC_DEFINE([HAVE_C_LINE], [1], [FIXME])
 363 fi
 364
 365 # FIXME: note that this macro appears above, too.
 366 # I'm leaving it here for now.  This whole thing needs to be modernized...
 367 gl_WINSIZE_IN_PTEM
 368
 369 gl_HEADER_TIOCGWINSZ_IN_TERMIOS_H
 370
 371 if test $gl_cv_sys_tiocgwinsz_needs_termios_h = no && \
 372    test $gl_cv_sys_tiocgwinsz_needs_sys_ioctl_h = no; then
 373   AC_MSG_CHECKING([TIOCGWINSZ in sys/pty.h])
 374   AC_CACHE_VAL([su_cv_sys_tiocgwinsz_in_sys_pty_h],
 375   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 376 #ifdef WINSIZE_IN_PTEM
 377 # include <sys/stream.h>
 378 # include <sys/ptem.h>
 379 #endif
 380 #include <sys/ioctl.h>
 381 #include <sys/tty.h>
 382 #include <sys/pty.h>]], [[int x = TIOCGWINSZ;]])],
 383     [su_cv_sys_tiocgwinsz_in_sys_pty_h=yes],
 384     [su_cv_sys_tiocgwinsz_in_sys_pty_h=no])])
 385   AC_MSG_RESULT([$su_cv_sys_tiocgwinsz_in_sys_pty_h])
 386
 387   test $su_cv_sys_tiocgwinsz_in_sys_pty_h = yes \
 388       && AC_DEFINE([GWINSZ_IN_SYS_PTY], [1],
 389                    [Define if your system defines TIOCGWINSZ in sys/pty.h.])
 390 fi
 391
 392 # For src/kill.c.
 393 AC_CHECK_DECLS([strsignal, sys_siglist, _sys_siglist, __sys_siglist], , ,
 394   [AC_INCLUDES_DEFAULT
 395 #include <signal.h>])
 396
 397 cu_GMP
 398
 399 # Build df only if there's a point to it.
 400 if test $gl_cv_list_mounted_fs = yes && test $gl_cv_fs_space = yes; then
 401   gl_ADD_PROG([optional_bin_progs], [df])
 402 fi
 403
 404 # Limit stdbuf to ELF systems with GCC
 405 AC_MSG_CHECKING([whether this is an ELF system])
 406 AC_EGREP_CPP([yes], [#if __ELF__
 407 yes
 408 #endif], [elf_sys=yes], [elf_sys=no])
 409 AC_MSG_RESULT([$elf_sys])
 410 if test "$elf_sys" = "yes" && \
 411    test "$GCC" = "yes"; then
 412   gl_ADD_PROG([optional_bin_progs], [stdbuf])
 413 fi
 414
 415 ############################################################################
 416
 417 dnl Autogenerated by the 'gen-lists-of-programs.sh' auxiliary script.
 418 dnl Issue proper calls to the macros gl_INCLUDE_EXCLUDE_PROG and
 419 dnl gl_ADD_PROG (updating $optional_bin_progs), and generate the list
 420 dnl of coreutils programs to be built only upon explicit user request,
 421 dnl saving that list in the $no_install_progs_default shell variable.
 422 m4_include([m4/cu-progs.m4])
 423
 424 # Now that we know which programs will actually be built, determine
 425 # which optional helper progs should be compiled.
 426 case " $optional_bin_progs " in
 427   *' stdbuf '*) pkglibexec_PROGRAMS='src/libstdbuf.so';;
 428   *) pkglibexec_PROGRAMS='';;
 429 esac
 430
 431 man1_MANS=`
 432   for p in $optional_bin_progs; do
 433     # Change "ginstall.1" to "install.1".
 434     test $p = ginstall && p=install
 435     # Ignore the "[" program, since writing a portable make rule to
 436     # generate its manpage is not practical.
 437     dnl Use the autoconf-provided quadrigraph to represent "[",
 438     dnl otherwise we will incur in dreadful quoting issues.
 439     test x$p = x'@<:@' && continue
 440     echo "man/$p.1"
 441   done`
 442
 443 # Not installed by "make install", but must be built when creating
 444 # a distribution tarball.
 445 EXTRA_MANS=`for p in $no_install_progs_default; do echo man/$p.1; done`
 446
 447 # The programs built and installed by "make && make install".
 448 # Since this is AC_SUBST'd, Automake won't be able to perform rewrite
 449 # with $(EXEEXT) appending on it, so we have to do it ourselves -- in
 450 # this case, only for $(bin_PROGRAMS).
 451 bin_PROGRAMS=`
 452   for p in $optional_bin_progs; do echo src/"$p"'$(EXEEXT)'; done`
 453
 454 # Normalize whitespace.
 455 man1_MANS=`echo $man1_MANS`
 456 EXTRA_MANS=`echo $EXTRA_MANS`
 457 bin_PROGRAMS=`echo $bin_PROGRAMS`
 458 pkglibexec_PROGS=`echo $pkglibexec_PROGRAMS`
 459
 460 AC_SUBST([bin_PROGRAMS])        AM_SUBST_NOTMAKE([bin_PROGRAMS])
 461 AC_SUBST([pkglibexec_PROGRAMS]) AM_SUBST_NOTMAKE([pkglibexec_PROGRAMS])
 462 AC_SUBST([man1_MANS])           AM_SUBST_NOTMAKE([man1_MANS])
 463 AC_SUBST([EXTRA_MANS])          AM_SUBST_NOTMAKE([EXTRA_MANS])
 464
 465 AC_SUBST([built_programs], [$optional_bin_progs])
 466
 467 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 468
 469 ############################################################################
 470
 471 # As long as "grep 'PRI[diouxX]' po/*.pot" reports matches in
 472 # translatable strings, we must use need-formatstring-macros here.
 473 AM_GNU_GETTEXT([external], [need-formatstring-macros])
 474 AM_GNU_GETTEXT_VERSION([0.18.1])
 475
 476 # For a test of uniq: it uses the $LOCALE_FR envvar.
 477 gt_LOCALE_FR
 478
 479 AC_CONFIG_FILES(
 480   Makefile
 481   lib/Makefile
 482   po/Makefile.in
 483   tests/Makefile
 484   gnulib-tests/Makefile
 485   )
 486 AC_OUTPUT