configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.60])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19 AM_INIT_AUTOMAKE([foreign -Wall])
  20
  21 dnl http://people.gnome.org/~walters/docs/build-api.txt
  22 dnl We don't support srcdir != builddir.
  23 echo \#buildapi-variable-no-builddir >/dev/null
  24
  25 # Support silent build rules, requires at least automake-1.11. Disable
  26 # by either passing --disable-silent-rules to configure or passing V=1
  27 # to make
  28 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  29
  30 LT_PREREQ([2.2])
  31 LT_INIT([disable-static])
  32
  33 dnl Save user CFLAGS and CXXFLAGS so one can override the default ones
  34 USER_CFLAGS="$CFLAGS"
  35 USER_CXXFLAGS="$CXXFLAGS"
  36
  37 dnl Versions for external dependencies
  38 LIBDRM_REQUIRED=2.4.24
  39 LIBDRM_RADEON_REQUIRED=2.4.31
  40 LIBDRM_INTEL_REQUIRED=2.4.32
  41 LIBDRM_NVVIEUX_REQUIRED=2.4.33
  42 LIBDRM_NOUVEAU_REQUIRED=2.4.33
  43 DRI2PROTO_REQUIRED=2.6
  44 GLPROTO_REQUIRED=1.4.14
  45 LIBDRM_XORG_REQUIRED=2.4.24
  46 LIBKMS_XORG_REQUIRED=1.0.0
  47
  48 dnl Check for progs
  49 AC_PROG_CPP
  50 AC_PROG_CC
  51 AC_PROG_CXX
  52 AM_PROG_CC_C_O
  53 AC_CHECK_PROGS([MAKE], [gmake make])
  54 AC_CHECK_PROGS([PYTHON2], [python2 python])
  55 AC_PROG_SED
  56 AC_PROG_MKDIR_P
  57 AC_PATH_PROG([MKDEP], [makedepend])
  58
  59 if test "x$MKDEP" = "x"; then
  60     AC_MSG_ERROR([makedepend is required to build Mesa])
  61 fi
  62
  63 AC_PROG_YACC
  64 AC_PATH_PROG([YACC_INST], $YACC)
  65 if test ! -f "$srcdir/src/glsl/glcpp/glcpp-parse.y"; then
  66     if test -z "$YACC_INST"; then
  67         AC_MSG_ERROR([yacc not found - unable to compile glcpp-parse.y])
  68     fi
  69 fi
  70 AC_PROG_LEX
  71
  72 AC_PATH_PROG([PERL], [perl])
  73
  74 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  75 dnl configuration in that case.
  76 AC_PROG_INSTALL
  77 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  78
  79 dnl We need a POSIX shell for parts of the build. Assume we have one
  80 dnl in most cases.
  81 case "$host_os" in
  82 solaris*)
  83     # Solaris /bin/sh is too old/non-POSIX compliant
  84     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  85     SHELL="$POSIX_SHELL"
  86     ;;
  87 esac
  88
  89 dnl clang is mostly GCC-compatible, but its version is much lower,
  90 dnl so we have to check for it.
  91 AC_MSG_CHECKING([if compiling with clang])
  92
  93 AC_COMPILE_IFELSE(
  94 [AC_LANG_PROGRAM([], [[
  95 #ifndef __clang__
  96        not clang
  97 #endif
  98 ]])],
  99 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 100
 101 AC_MSG_RESULT([$acv_mesa_CLANG])
 102
 103 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
 104 dnl versions are explictly not supported.
 105 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 106     AC_MSG_CHECKING([whether gcc version is sufficient])
 107     major=0
 108     minor=0
 109
 110     GCC_VERSION=`$CC -dumpversion`
 111     if test $? -eq 0; then
 112         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 113         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 114     fi
 115
 116     if test $GCC_VERSION_MAJOR -lt 3 -o $GCC_VERSION_MAJOR -eq 3 -a $GCC_VERSION_MINOR -lt 3 ; then
 117         AC_MSG_RESULT([no])
 118         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
 119     else
 120         AC_MSG_RESULT([yes])
 121     fi
 122 fi
 123
 124
 125 MKDEP_OPTIONS=-fdepend
 126 dnl Ask gcc where it's keeping its secret headers
 127 if test "x$GCC" = xyes; then
 128     for dir in include include-fixed; do
 129         GCC_INCLUDES=`$CC -print-file-name=$dir`
 130         if test "x$GCC_INCLUDES" != x && \
 131            test "$GCC_INCLUDES" != "$dir" && \
 132            test -d "$GCC_INCLUDES"; then
 133             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 134         fi
 135     done
 136 fi
 137 AC_SUBST([MKDEP_OPTIONS])
 138
 139 dnl Make sure the pkg-config macros are defined
 140 m4_ifndef([PKG_PROG_PKG_CONFIG],
 141     [m4_fatal([Could not locate the pkg-config autoconf macros.
 142   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 143   are in a different location, try setting the environment variable
 144   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 145 PKG_PROG_PKG_CONFIG()
 146
 147 dnl LIB_DIR - library basename
 148 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 149 AC_SUBST([LIB_DIR])
 150
 151 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 152 _SAVE_LDFLAGS="$LDFLAGS"
 153 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 154 AC_SUBST([EXTRA_LIB_PATH])
 155
 156 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 157 _SAVE_CPPFLAGS="$CPPFLAGS"
 158 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 159 AC_SUBST([X11_INCLUDES])
 160
 161 dnl Compiler macros
 162 DEFINES=""
 163 AC_SUBST([DEFINES])
 164 case "$host_os" in
 165 linux*|*-gnu*|gnu*)
 166     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 167     ;;
 168 solaris*)
 169     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 170     ;;
 171 cygwin*)
 172     DEFINES="$DEFINES -DPTHREADS"
 173     ;;
 174 esac
 175
 176 dnl Add flags for gcc and g++
 177 if test "x$GCC" = xyes; then
 178     CFLAGS="$CFLAGS -Wall -std=c99"
 179
 180     # Enable -Werror=implicit-function-declaration and
 181     # -Werror=missing-prototypes, if available, or otherwise, just
 182     # -Wmissing-prototypes.  This is particularly useful to avoid
 183     # generating a loadable driver module that has undefined symbols.
 184     save_CFLAGS="$CFLAGS"
 185     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 186     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 187     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 188     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 189                    AC_MSG_RESULT([yes]),
 190                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 191                     AC_MSG_RESULT([no])]);
 192
 193     # Enable -fvisibility=hidden if using a gcc that supports it
 194     save_CFLAGS="$CFLAGS"
 195     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 196     VISIBILITY_CFLAGS="-fvisibility=hidden"
 197     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 198     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 199                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 200
 201     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 202     CFLAGS=$save_CFLAGS
 203
 204     # Work around aliasing bugs - developers should comment this out
 205     CFLAGS="$CFLAGS -fno-strict-aliasing"
 206
 207     # gcc's builtin memcmp is slower than glibc's
 208     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 209     CFLAGS="$CFLAGS -fno-builtin-memcmp"
 210 fi
 211 if test "x$GXX" = xyes; then
 212     CXXFLAGS="$CXXFLAGS -Wall"
 213
 214     # Enable -fvisibility=hidden if using a gcc that supports it
 215     save_CXXFLAGS="$CXXFLAGS"
 216     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 217     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 218     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 219     AC_LANG_PUSH([C++])
 220     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 221                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 222     AC_LANG_POP([C++])
 223
 224     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 225     CXXFLAGS=$save_CXXFLAGS
 226
 227     # Work around aliasing bugs - developers should comment this out
 228     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 229
 230     # gcc's builtin memcmp is slower than glibc's
 231     # http://gcc.gnu.org/bugzilla/show_bug.cgi?id=43052
 232     CXXFLAGS="$CXXFLAGS -fno-builtin-memcmp"
 233 fi
 234
 235 dnl even if the compiler appears to support it, using visibility attributes isn't
 236 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 237 case "$host_os" in
 238 cygwin*)
 239     VISIBILITY_CFLAGS=""
 240     VISIBILITY_CXXFLAGS=""
 241     ;;
 242 esac
 243
 244 AC_SUBST([VISIBILITY_CFLAGS])
 245 AC_SUBST([VISIBILITY_CXXFLAGS])
 246
 247 dnl These should be unnecessary, but let the user set them if they want
 248 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 249     Default is to use CFLAGS.])
 250 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 251     compiler. Default is to use CFLAGS.])
 252 AC_SUBST([OPT_FLAGS])
 253 AC_SUBST([ARCH_FLAGS])
 254
 255 dnl
 256 dnl Hacks to enable 32 or 64 bit build
 257 dnl
 258 AC_ARG_ENABLE([32-bit],
 259     [AS_HELP_STRING([--enable-32-bit],
 260         [build 32-bit libraries @<:@default=auto@:>@])],
 261     [enable_32bit="$enableval"],
 262     [enable_32bit=auto]
 263 )
 264 if test "x$enable_32bit" = xyes; then
 265     if test "x$GCC" = xyes; then
 266         CFLAGS="$CFLAGS -m32"
 267         ARCH_FLAGS="$ARCH_FLAGS -m32"
 268     fi
 269     if test "x$GXX" = xyes; then
 270         CXXFLAGS="$CXXFLAGS -m32"
 271     fi
 272 fi
 273 AC_ARG_ENABLE([64-bit],
 274     [AS_HELP_STRING([--enable-64-bit],
 275         [build 64-bit libraries @<:@default=auto@:>@])],
 276     [enable_64bit="$enableval"],
 277     [enable_64bit=auto]
 278 )
 279 if test "x$enable_64bit" = xyes; then
 280     if test "x$GCC" = xyes; then
 281         CFLAGS="$CFLAGS -m64"
 282     fi
 283     if test "x$GXX" = xyes; then
 284         CXXFLAGS="$CXXFLAGS -m64"
 285     fi
 286 fi
 287
 288 dnl Can't have static and shared libraries, default to static if user
 289 dnl explicitly requested. If both disabled, set to static since shared
 290 dnl was explicitly requested.
 291 case "x$enable_static$enable_shared" in
 292 xyesyes )
 293     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 294     enable_shared=no
 295     ;;
 296 xnono )
 297     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 298     enable_static=yes
 299     ;;
 300 esac
 301
 302 dnl
 303 dnl mklib options
 304 dnl
 305 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 306 if test "$enable_static" = yes; then
 307     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 308 fi
 309 AC_SUBST([MKLIB_OPTIONS])
 310
 311 dnl
 312 dnl other compiler options
 313 dnl
 314 AC_ARG_ENABLE([debug],
 315     [AS_HELP_STRING([--enable-debug],
 316         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 317     [enable_debug="$enableval"],
 318     [enable_debug=no]
 319 )
 320 if test "x$enable_debug" = xyes; then
 321     DEFINES="$DEFINES -DDEBUG"
 322     if test "x$GCC" = xyes; then
 323         CFLAGS="$CFLAGS -g"
 324     fi
 325     if test "x$GXX" = xyes; then
 326         CXXFLAGS="$CXXFLAGS -g"
 327     fi
 328 fi
 329
 330 dnl
 331 dnl library names
 332 dnl
 333 LIB_PREFIX_GLOB='lib'
 334 LIB_VERSION_SEPARATOR='.'
 335 if test "$enable_static" = yes; then
 336     LIB_EXTENSION='a'
 337 else
 338     case "$host_os" in
 339     darwin* )
 340         LIB_EXTENSION='dylib' ;;
 341     cygwin* )
 342         dnl prefix can be 'cyg' or 'lib'
 343         LIB_PREFIX_GLOB='???'
 344         LIB_VERSION_SEPARATOR='-'
 345         LIB_EXTENSION='dll' ;;
 346     aix* )
 347         LIB_EXTENSION='a' ;;
 348     * )
 349         LIB_EXTENSION='so' ;;
 350     esac
 351 fi
 352
 353 dnl
 354 dnl Mangled Mesa support
 355 dnl
 356 AC_ARG_ENABLE([mangling],
 357   [AS_HELP_STRING([--enable-mangling],
 358     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 359   [enable_mangling="${enableval}"],
 360   [enable_mangling=no]
 361 )
 362 GL_LIB="GL"
 363 GLU_LIB="GLU"
 364 OSMESA_LIB="OSMesa"
 365 if test "x${enable_mangling}" = "xyes" ; then
 366   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 367   GL_LIB="MangledGL"
 368   GLU_LIB="MangledGLU"
 369   OSMESA_LIB="MangledOSMesa"
 370 fi
 371 AC_SUBST([GL_LIB])
 372 AC_SUBST([GLU_LIB])
 373 AC_SUBST([OSMESA_LIB])
 374 AM_CONDITIONAL(HAVE_MANGLED_GL, test $GL_LIB = MangledGL)
 375
 376 dnl
 377 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 378 dnl
 379 AC_ARG_ENABLE([texture-float],
 380     [AS_HELP_STRING([--enable-texture-float],
 381         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 382     [enable_texture_float="$enableval"],
 383     [enable_texture_float=no]
 384 )
 385 if test "x$enable_texture_float" = xyes; then
 386     AC_MSG_WARN([Floating-point textures enabled.])
 387     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 388     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 389 fi
 390
 391 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 392 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 393 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 394 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 395 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 396 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 397 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 398 GLAPI_LIB_NAME='lib$(GLAPI_LIB).'${LIB_EXTENSION}
 399
 400 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 401 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 402 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 403 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 404 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 405 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 406 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 407 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 408 GLAPI_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLAPI_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 409
 410 AC_SUBST([GL_LIB_NAME])
 411 AC_SUBST([GLU_LIB_NAME])
 412 AC_SUBST([OSMESA_LIB_NAME])
 413 AC_SUBST([EGL_LIB_NAME])
 414 AC_SUBST([GLESv1_CM_LIB_NAME])
 415 AC_SUBST([GLESv2_LIB_NAME])
 416 AC_SUBST([VG_LIB_NAME])
 417 AC_SUBST([GLAPI_LIB_NAME])
 418
 419 AC_SUBST([GL_LIB_GLOB])
 420 AC_SUBST([GLU_LIB_GLOB])
 421 AC_SUBST([OSMESA_LIB_GLOB])
 422 AC_SUBST([EGL_LIB_GLOB])
 423 AC_SUBST([GLESv1_CM_LIB_GLOB])
 424 AC_SUBST([GLESv2_LIB_GLOB])
 425 AC_SUBST([VG_LIB_GLOB])
 426 AC_SUBST([GLAPI_LIB_GLOB])
 427
 428 dnl
 429 dnl Arch/platform-specific settings
 430 dnl
 431 AC_ARG_ENABLE([asm],
 432     [AS_HELP_STRING([--disable-asm],
 433         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 434     [enable_asm="$enableval"],
 435     [enable_asm=yes]
 436 )
 437 asm_arch=""
 438 ASM_FLAGS=""
 439 MESA_ASM_SOURCES=""
 440 GLAPI_ASM_SOURCES=""
 441 AC_MSG_CHECKING([whether to enable assembly])
 442 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 443 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 444 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 445     case "$host_cpu" in
 446     i?86 | x86_64)
 447         enable_asm=no
 448         AC_MSG_RESULT([no, cross compiling])
 449         ;;
 450     esac
 451 fi
 452 # check for supported arches
 453 if test "x$enable_asm" = xyes; then
 454     case "$host_cpu" in
 455     i?86)
 456         case "$host_os" in
 457         linux* | *freebsd* | dragonfly* | *netbsd*)
 458             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 459             ;;
 460         esac
 461         ;;
 462     x86_64)
 463         case "$host_os" in
 464         linux* | *freebsd* | dragonfly* | *netbsd*)
 465             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 466             ;;
 467         esac
 468         ;;
 469     powerpc)
 470         case "$host_os" in
 471         linux*)
 472             asm_arch=ppc
 473             ;;
 474         esac
 475         ;;
 476     sparc*)
 477         case "$host_os" in
 478         linux*)
 479             asm_arch=sparc
 480             ;;
 481         esac
 482         ;;
 483     esac
 484
 485     case "$asm_arch" in
 486     x86)
 487         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 488         MESA_ASM_SOURCES='$(X86_SOURCES)'
 489         GLAPI_ASM_SOURCES='$(X86_API)'
 490         AC_MSG_RESULT([yes, x86])
 491         ;;
 492     x86_64)
 493         ASM_FLAGS="-DUSE_X86_64_ASM"
 494         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 495         GLAPI_ASM_SOURCES='$(X86-64_API)'
 496         AC_MSG_RESULT([yes, x86_64])
 497         ;;
 498     sparc)
 499         ASM_FLAGS="-DUSE_SPARC_ASM"
 500         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 501         GLAPI_ASM_SOURCES='$(SPARC_API)'
 502         AC_MSG_RESULT([yes, sparc])
 503         ;;
 504     *)
 505         AC_MSG_RESULT([no, platform not supported])
 506         ;;
 507     esac
 508 fi
 509 AC_SUBST([ASM_FLAGS])
 510 AC_SUBST([MESA_ASM_SOURCES])
 511 AC_SUBST([GLAPI_ASM_SOURCES])
 512
 513 dnl PIC code macro
 514 MESA_PIC_FLAGS
 515
 516 dnl Check to see if dlopen is in default libraries (like Solaris, which
 517 dnl has it in libc), or if libdl is needed to get it.
 518 AC_CHECK_FUNC([dlopen], [],
 519     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 520 AC_SUBST([DLOPEN_LIBS])
 521
 522 dnl See if posix_memalign is available
 523 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 524
 525 dnl SELinux awareness.
 526 AC_ARG_ENABLE([selinux],
 527     [AS_HELP_STRING([--enable-selinux],
 528         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 529     [MESA_SELINUX="$enableval"],
 530     [MESA_SELINUX=no])
 531 if test "x$enable_selinux" = "xyes"; then
 532     AC_CHECK_HEADER([selinux/selinux.h],[],
 533                     [AC_MSG_ERROR([SELinux headers not found])])
 534     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 535                  [AC_MSG_ERROR([SELinux library not found])])
 536     SELINUX_LIBS="-lselinux"
 537     DEFINES="$DEFINES -DMESA_SELINUX"
 538 fi
 539
 540 dnl Options for APIs
 541 AC_ARG_ENABLE([opengl],
 542     [AS_HELP_STRING([--disable-opengl],
 543         [disable support for standard OpenGL API @<:@default=no@:>@])],
 544     [enable_opengl="$enableval"],
 545     [enable_opengl=yes])
 546 AC_ARG_ENABLE([gles1],
 547     [AS_HELP_STRING([--enable-gles1],
 548         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 549     [enable_gles1="$enableval"],
 550     [enable_gles1=no])
 551 AC_ARG_ENABLE([gles2],
 552     [AS_HELP_STRING([--enable-gles2],
 553         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 554     [enable_gles2="$enableval"],
 555     [enable_gles2=no])
 556 AC_ARG_ENABLE([openvg],
 557     [AS_HELP_STRING([--enable-openvg],
 558         [enable support for OpenVG API @<:@default=no@:>@])],
 559     [enable_openvg="$enableval"],
 560     [enable_openvg=no])
 561
 562 AC_ARG_ENABLE([dri],
 563     [AS_HELP_STRING([--enable-dri],
 564         [enable DRI modules @<:@default=auto@:>@])],
 565     [enable_dri="$enableval"],
 566     [enable_dri=auto])
 567 AC_ARG_ENABLE([glx],
 568     [AS_HELP_STRING([--enable-glx],
 569         [enable GLX library @<:@default=auto@:>@])],
 570     [enable_glx="$enableval"],
 571     [enable_glx=auto])
 572 AC_ARG_ENABLE([osmesa],
 573     [AS_HELP_STRING([--enable-osmesa],
 574         [enable OSMesa library @<:@default=auto@:>@])],
 575     [enable_osmesa="$enableval"],
 576     [enable_osmesa=auto])
 577 AC_ARG_ENABLE([egl],
 578     [AS_HELP_STRING([--disable-egl],
 579         [disable EGL library @<:@default=enabled@:>@])],
 580     [enable_egl="$enableval"],
 581     [enable_egl=yes])
 582
 583 AC_ARG_ENABLE([xorg],
 584     [AS_HELP_STRING([--enable-xorg],
 585         [enable support for X.Org DDX API @<:@default=no@:>@])],
 586     [enable_xorg="$enableval"],
 587     [enable_xorg=no])
 588 AC_ARG_ENABLE([xa],
 589     [AS_HELP_STRING([--enable-xa],
 590         [enable build of the XA X Acceleration API @<:@default=no@:>@])],
 591     [enable_xa="$enableval"],
 592     [enable_xa=no])
 593 AC_ARG_ENABLE([d3d1x],
 594     [AS_HELP_STRING([--enable-d3d1x],
 595         [enable support for Direct3D 10 & 11 low-level API @<:@default=no@:>@])],
 596     [enable_d3d1x="$enableval"],
 597     [enable_d3d1x=no])
 598 AC_ARG_ENABLE([gbm],
 599    [AS_HELP_STRING([--enable-gbm],
 600          [enable gbm library @<:@default=auto@:>@])],
 601    [enable_gbm="$enableval"],
 602    [enable_gbm=auto])
 603
 604 AC_ARG_ENABLE([xvmc],
 605    [AS_HELP_STRING([--enable-xvmc],
 606          [enable xvmc library @<:@default=auto@:>@])],
 607    [enable_xvmc="$enableval"],
 608    [enable_xvmc=auto])
 609 AC_ARG_ENABLE([vdpau],
 610    [AS_HELP_STRING([--enable-vdpau],
 611          [enable vdpau library @<:@default=auto@:>@])],
 612    [enable_vdpau="$enableval"],
 613    [enable_vdpau=auto])
 614 AC_ARG_ENABLE([va],
 615    [AS_HELP_STRING([--enable-va],
 616          [enable va library @<:@default=auto@:>@])],
 617    [enable_va="$enableval"],
 618    [enable_va=auto])
 619 AC_ARG_ENABLE([opencl],
 620    [AS_HELP_STRING([--enable-opencl],
 621          [enable OpenCL library @<:@default=no@:>@])],
 622    [enable_opencl="$enableval"],
 623    [enable_opencl=no])
 624 AC_ARG_ENABLE([xlib_glx],
 625     [AS_HELP_STRING([--enable-xlib-glx],
 626         [make GLX library Xlib-based instead of DRI-based @<:@default=disable@:>@])],
 627     [enable_xlib_glx="$enableval"],
 628     [enable_xlib_glx=auto])
 629 AC_ARG_ENABLE([gallium_egl],
 630     [AS_HELP_STRING([--enable-gallium-egl],
 631         [enable optional EGL state tracker (not required
 632          for EGL support in Gallium with OpenGL and OpenGL ES)
 633          @<:@default=disable@:>@])],
 634     [enable_gallium_egl="$enableval"],
 635     [enable_gallium_egl=no])
 636 AC_ARG_ENABLE([gallium_gbm],
 637     [AS_HELP_STRING([--enable-gallium-gbm],
 638         [enable optional gbm state tracker (not required for
 639          gbm support in Gallium)
 640          @<:@default=auto@:>@])],
 641     [enable_gallium_gbm="$enableval"],
 642     [enable_gallium_gbm=auto])
 643
 644 AC_ARG_ENABLE([r600-llvm-compiler],
 645     [AS_HELP_STRING([--enable-r600-llvm-compilerl],
 646         [Enable experimental LLVM backend for graphics shaders @<:default=disable@:>@])],
 647     [enable_r600_llvm="$enableval"],
 648     [enable_r600_llvm=no])
 649
 650 AC_ARG_ENABLE([gallium_tests],
 651     [AS_HELP_STRING([--enable-gallium-tests],
 652         [Enable optional Gallium tests) @<:@default=disable@:>@])],
 653     [enable_gallium_tests="$enableval"],
 654     [enable_gallium_tests=no])
 655
 656 # Option for Gallium drivers
 657 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
 658
 659 AC_ARG_WITH([gallium-drivers],
 660     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
 661         [comma delimited Gallium drivers list, e.g.
 662         "i915,nouveau,r300,r600,svga,swrast"
 663         @<:@default=r300,r600,swrast@:>@])],
 664     [with_gallium_drivers="$withval"],
 665     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
 666
 667 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
 668 # here so that the script doesn't choke on an unknown driver name later.
 669 case "$with_gallium_drivers" in
 670     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
 671     no) with_gallium_drivers='' ;;
 672 esac
 673
 674 if test "x$enable_opengl" = xno -a \
 675         "x$enable_gles1" = xno -a \
 676         "x$enable_gles2" = xno -a \
 677         "x$enable_openvg" = xno -a \
 678         "x$enable_xorg" = xno -a \
 679         "x$enable_xa" = xno -a \
 680         "x$enable_d3d1x" = xno -a \
 681         "x$enable_xvmc" = xno -a \
 682         "x$enable_vdpau" = xno -a \
 683         "x$enable_va" = xno -a \
 684         "x$enable_opencl" = xno; then
 685     AC_MSG_ERROR([at least one API should be enabled])
 686 fi
 687
 688 API_DEFINES=""
 689 if test "x$enable_opengl" = xno; then
 690     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 691 else
 692     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 693 fi
 694 if test "x$enable_gles1" = xyes; then
 695     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 696 fi
 697 if test "x$enable_gles2" = xyes; then
 698     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 699 fi
 700 AC_SUBST([API_DEFINES])
 701
 702 AC_ARG_ENABLE([shared-glapi],
 703     [AS_HELP_STRING([--enable-shared-glapi],
 704         [EXPERIMENTAL.  Enable shared glapi for OpenGL @<:@default=no@:>@])],
 705     [enable_shared_glapi="$enableval"],
 706     [enable_shared_glapi=no])
 707
 708 SHARED_GLAPI="0"
 709 if test "x$enable_shared_glapi" = xyes; then
 710     SHARED_GLAPI="1"
 711     # libGL will use libglapi for function lookups (IN_DRI_DRIVER means to use
 712     # the remap table)
 713     DEFINES="$DEFINES -DIN_DRI_DRIVER"
 714     SRC_DIRS="$SRC_DIRS mapi/shared-glapi"
 715 fi
 716 AC_SUBST([SHARED_GLAPI])
 717 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test $SHARED_GLAPI = 1)
 718
 719 dnl
 720 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 721 dnl More later: fbdev, ...
 722 dnl
 723 default_driver="xlib"
 724
 725 case "$host_os" in
 726 linux*)
 727     case "$host_cpu" in
 728     i*86|x86_64|powerpc*|sparc*|ia64*) default_driver="dri";;
 729     esac
 730     ;;
 731 *freebsd* | dragonfly* | *netbsd*)
 732     case "$host_cpu" in
 733     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 734     esac
 735     ;;
 736 esac
 737
 738 if test "x$enable_opengl" = xno; then
 739     default_driver="no"
 740 fi
 741
 742 AC_ARG_WITH([driver],
 743     [AS_HELP_STRING([--with-driver=DRIVER], [DEPRECATED])],
 744     [mesa_driver="$withval"],
 745     [mesa_driver=auto])
 746 dnl Check for valid option
 747 case "x$mesa_driver" in
 748 xxlib|xdri|xosmesa|xno)
 749     if test "x$enable_dri" != xauto -o \
 750             "x$enable_glx" != xauto -o \
 751             "x$enable_osmesa" != xauto -o \
 752             "x$enable_xlib_glx" != xauto; then
 753         AC_MSG_ERROR([--with-driver=$mesa_driver is deprecated])
 754     fi
 755     ;;
 756 xauto)
 757     mesa_driver="$default_driver"
 758     ;;
 759 *)
 760     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 761     ;;
 762 esac
 763
 764 # map $mesa_driver to APIs
 765 if test "x$enable_dri" = xauto; then
 766     case "x$mesa_driver" in
 767     xdri) enable_dri=yes ;;
 768     *)    enable_dri=no ;;
 769     esac
 770 fi
 771
 772 if test "x$enable_glx" = xauto; then
 773     case "x$mesa_driver" in
 774     xdri|xxlib) enable_glx=yes ;;
 775     *)          enable_glx=no ;;
 776     esac
 777 fi
 778
 779 if test "x$enable_osmesa" = xauto; then
 780     case "x$mesa_driver" in
 781     xxlib|xosmesa) enable_osmesa=yes ;;
 782     *)             enable_osmesa=no ;;
 783     esac
 784 fi
 785
 786 if test "x$enable_xlib_glx" = xauto; then
 787     case "x$mesa_driver" in
 788     xxlib) enable_xlib_glx=yes ;;
 789     *)     enable_xlib_glx=no ;;
 790     esac
 791 fi
 792
 793 if test "x$enable_glx" = xno; then
 794     enable_xlib_glx=no
 795 fi
 796
 797 AM_CONDITIONAL(HAVE_DRI, test x"$enable_dri" = xyes)
 798
 799 dnl
 800 dnl Driver specific build directories
 801 dnl
 802
 803 dnl this variable will be prepended to SRC_DIRS and is not exported
 804 CORE_DIRS=""
 805
 806 SRC_DIRS="gtest"
 807 GLU_DIRS="sgi"
 808 GALLIUM_DIRS="auxiliary drivers state_trackers"
 809 GALLIUM_TARGET_DIRS=""
 810 GALLIUM_WINSYS_DIRS="sw"
 811 GALLIUM_DRIVERS_DIRS="galahad trace rbug noop identity"
 812 GALLIUM_STATE_TRACKERS_DIRS=""
 813
 814 # build shared-glapi if enabled for OpenGL or if OpenGL ES is enabled
 815 case "x$enable_shared_glapi$enable_gles1$enable_gles2" in
 816 x*yes*)
 817     CORE_DIRS="$CORE_DIRS mapi/shared-glapi"
 818     ;;
 819 esac
 820
 821 # build glapi if OpenGL is enabled
 822 if test "x$enable_opengl" = xyes; then
 823     CORE_DIRS="$CORE_DIRS mapi/glapi"
 824 fi
 825
 826 # build es1api if OpenGL ES 1.x is enabled
 827 if test "x$enable_gles1" = xyes; then
 828     CORE_DIRS="$CORE_DIRS mapi/es1api"
 829 fi
 830
 831 # build es2api if OpenGL ES 2.x is enabled
 832 if test "x$enable_gles2" = xyes; then
 833     CORE_DIRS="$CORE_DIRS mapi/es2api"
 834 fi
 835
 836 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 837 case "x$enable_opengl$enable_gles1$enable_gles2" in
 838 x*yes*)
 839     CORE_DIRS="$CORE_DIRS glsl mesa"
 840     ;;
 841 esac
 842
 843 case "x$enable_glx$enable_xlib_glx" in
 844 xyesyes)
 845     DRIVER_DIRS="$DRIVER_DIRS x11"
 846     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 847     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 848     GALLIUM_STATE_TRACKERS_DIRS="glx $GALLIUM_STATE_TRACKERS_DIRS"
 849     HAVE_WINSYS_XLIB="yes"
 850     ;;
 851 xyesno)
 852     # DRI-based GLX
 853     SRC_DIRS="$SRC_DIRS glx"
 854     ;;
 855 esac
 856
 857 if test "x$enable_dri" = xyes; then
 858     DRIVER_DIRS="$DRIVER_DIRS dri"
 859
 860     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/dri"
 861     GALLIUM_STATE_TRACKERS_DIRS="dri $GALLIUM_STATE_TRACKERS_DIRS"
 862     HAVE_ST_DRI="yes"
 863 fi
 864
 865 if test "x$enable_osmesa" = xyes; then
 866     # the empty space matters for osmesa... (see src/mesa/Makefile)
 867     if test -n "$DRIVER_DIRS"; then
 868         DRIVER_DIRS="$DRIVER_DIRS osmesa"
 869     else
 870         DRIVER_DIRS="osmesa"
 871     fi
 872 fi
 873
 874 AC_SUBST([SRC_DIRS])
 875 AC_SUBST([GLU_DIRS])
 876 AC_SUBST([DRIVER_DIRS])
 877 AC_SUBST([GALLIUM_DIRS])
 878 AC_SUBST([GALLIUM_TARGET_DIRS])
 879 AC_SUBST([GALLIUM_WINSYS_DIRS])
 880 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 881 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 882 AC_SUBST([MESA_LLVM])
 883
 884 # Check for libdrm
 885 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
 886                   [have_libdrm=yes], [have_libdrm=no])
 887
 888 if test "x$enable_dri" = xyes; then
 889     # DRI must be shared, I think
 890     if test "$enable_static" = yes; then
 891         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 892     fi
 893
 894     # not a hard requirement as swrast does not depend on it
 895     if test "x$have_libdrm" = xyes; then
 896         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 897     fi
 898 fi
 899
 900 dnl
 901 dnl Find out if X is available. The variable have_x is set if libX11 is
 902 dnl found to mimic AC_PATH_XTRA.
 903 dnl
 904 if test -n "$PKG_CONFIG"; then
 905     AC_MSG_CHECKING([pkg-config files for X11 are available])
 906     PKG_CHECK_EXISTS([x11],[
 907         x11_pkgconfig=yes
 908         have_x=yes
 909         ],[
 910         x11_pkgconfig=no
 911     ])
 912     AC_MSG_RESULT([$x11_pkgconfig])
 913 else
 914     x11_pkgconfig=no
 915 fi
 916 dnl Use the autoconf macro if no pkg-config files
 917 if test "$x11_pkgconfig" = yes; then
 918     PKG_CHECK_MODULES([X11], [x11])
 919 else
 920     AC_PATH_XTRA
 921     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 922     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 923     AC_SUBST([X11_CFLAGS])
 924     AC_SUBST([X11_LIBS])
 925 fi
 926
 927 dnl Try to tell the user that the --x-* options are only used when
 928 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 929 m4_divert_once([HELP_BEGIN],
 930 [These options are only used when the X libraries cannot be found by the
 931 pkg-config utility.])
 932
 933 dnl We need X for xlib and dri, so bomb now if it's not found
 934 if test "x$enable_glx" = xyes -a "x$no_x" = xyes; then
 935     AC_MSG_ERROR([X11 development libraries needed for GLX])
 936 fi
 937
 938 if test "x$enable_glx" = xyes; then
 939     DEFINES="$DEFINES -DUSE_XCB"
 940 fi
 941
 942 dnl Direct rendering or just indirect rendering
 943 case "$host_os" in
 944 gnu*)
 945     dnl Disable by default on GNU/Hurd
 946     driglx_direct_default="no"
 947     ;;
 948 cygwin*)
 949     dnl Disable by default on cygwin
 950     driglx_direct_default="no"
 951     ;;
 952 *)
 953     driglx_direct_default="yes"
 954     ;;
 955 esac
 956 AC_ARG_ENABLE([driglx-direct],
 957     [AS_HELP_STRING([--disable-driglx-direct],
 958         [enable direct rendering in GLX and EGL for DRI \
 959             @<:@default=auto@:>@])],
 960     [driglx_direct="$enableval"],
 961     [driglx_direct="$driglx_direct_default"])
 962
 963 dnl
 964 dnl libGL configuration per driver
 965 dnl
 966 case "x$enable_glx$enable_xlib_glx" in
 967 xyesyes)
 968     # Xlib-based GLX
 969     if test "$x11_pkgconfig" = yes; then
 970         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 971         GL_PC_REQ_PRIV="x11 xext"
 972         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 973         GL_LIB_DEPS="$XLIBGL_LIBS"
 974     else
 975         # should check these...
 976         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 977         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 978         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 979         GL_PC_CFLAGS="$X11_INCLUDES"
 980     fi
 981     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $DLOPEN_LIBS"
 982     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread"
 983     ;;
 984 xyesno)
 985     # DRI-based GLX
 986     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 987     GL_PC_REQ_PRIV="glproto >= $GLPROTO_REQUIRED"
 988     if test x"$driglx_direct" = xyes; then
 989         if test "x$have_libdrm" != xyes; then
 990             AC_MSG_ERROR([Direct rendering requires libdrm >= $LIBDRM_REQUIRED])
 991         fi
 992         PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 993         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED"
 994     fi
 995
 996     # find the DRI deps for libGL
 997     if test "$x11_pkgconfig" = yes; then
 998         dri_modules="x11 xext xdamage xfixes x11-xcb xcb-glx"
 999
1000         # add xf86vidmode if available
1001         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1002         if test "$HAVE_XF86VIDMODE" = yes ; then
1003             dri_modules="$dri_modules xxf86vm"
1004         fi
1005
1006         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1007         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1008         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1009         GL_LIB_DEPS="$DRIGL_LIBS"
1010     else
1011         # should check these...
1012         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
1013         if test "x$HAVE_XF86VIDMODE" == xyes; then
1014            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
1015         else
1016            GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXdamage -lXfixes"
1017         fi
1018         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
1019         GL_PC_CFLAGS="$X11_INCLUDES"
1020
1021         # XCB can only be used from pkg-config
1022         PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
1023         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
1024         X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
1025         GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
1026     fi
1027
1028     # Check to see if the xcb-glx library is new enough to support
1029     # GLX_ARB_create_context.  This bit of hackery is necessary until XCB 1.8
1030     # is released.
1031     save_CPPFLAGS="$CPPFLAGS"
1032     save_LDFLAGS="$LDFLAGS"
1033     CPPFLAGS="$CPPFLAGS $X11_INCLUDES"
1034     LDFLAGS="$LDFLAGS $GL_LIB_DEPS"
1035     AC_CHECK_LIB(xcb-glx, xcb_glx_create_context_attribs_arb_checked,
1036         [HAVE_XCB_GLX_CREATE_CONTEXT=yes],
1037         [HAVE_XCB_GLX_CREATE_CONTEXT=no])
1038     CPPFLAGS="$save_CPPFLAGS"
1039     LDFLAGS="$save_LDFLAGS"
1040
1041     if test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes; then
1042         X11_INCLUDES="$X11_INCLUDES -DHAVE_XCB_GLX_CREATE_CONTEXT"
1043     fi
1044
1045     # need DRM libs, -lpthread, etc.
1046     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1047     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1048     ;;
1049 esac
1050
1051 # This is outside the case (above) so that it is invoked even for non-GLX
1052 # builds.
1053 AM_CONDITIONAL(HAVE_XCB_GLX_CREATE_CONTEXT,
1054     test x$HAVE_XCB_GLX_CREATE_CONTEXT = xyes)
1055 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1056
1057 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1058 GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1059 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
1060 GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
1061
1062 AC_SUBST([GL_LIB_DEPS])
1063 AC_SUBST([GL_PC_REQ_PRIV])
1064 AC_SUBST([GL_PC_LIB_PRIV])
1065 AC_SUBST([GL_PC_CFLAGS])
1066 AC_SUBST([DRI_PC_REQ_PRIV])
1067 AC_SUBST([GLESv1_CM_LIB_DEPS])
1068 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1069 AC_SUBST([GLESv2_LIB_DEPS])
1070 AC_SUBST([GLESv2_PC_LIB_PRIV])
1071
1072 GLAPI_LIB_DEPS="-lpthread $SELINUX_LIBS"
1073 AC_SUBST([GLAPI_LIB_DEPS])
1074
1075
1076 dnl Setup default DRI CFLAGS
1077 DRI_CFLAGS='$(CFLAGS)'
1078 DRI_CXXFLAGS='$(CXXFLAGS)'
1079 DRI_LIB_DEPS='$(TOP)/src/mesa/libmesa.a'
1080 MESA_MODULES='$(TOP)/src/mesa/libmesa.a'
1081
1082 if test "x$enable_dri" = xyes && test "x$driglx_direct" = xyes ; then
1083     DRICORE_GLSL_LIBS='$(TOP)/$(LIB_DIR)/libglsl.so'
1084     DRICORE_LIBS='$(TOP)/$(LIB_DIR)/libdricore.so'
1085     DRICORE_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -lglsl'
1086     DRI_LIB_DEPS='-L$(TOP)/$(LIB_DIR) -Wl,-R$(DRI_DRIVER_INSTALL_DIR) -ldricore -lglsl'
1087     DRI_CFLAGS='$(CFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1088     DRI_CXXFLAGS='$(CXXFLAGS_NOVISIBILITY) -DUSE_DRICORE'
1089     MESA_MODULES='$(DRICORE_LIBS) $(DRICORE_GLSL_LIBS)'
1090 fi
1091 AC_SUBST([DRICORE_LIBS])
1092 AC_SUBST([DRICORE_GLSL_LIBS])
1093 AC_SUBST([DRICORE_LIB_DEPS])
1094 AC_SUBST([DRI_CXXFLAGS])
1095 AC_SUBST([DRI_CFLAGS])
1096 AC_SUBST([MESA_MODULES])
1097
1098 AC_SUBST([HAVE_XF86VIDMODE])
1099
1100 dnl
1101 dnl More GLX setup
1102 dnl
1103 case "x$enable_glx$enable_xlib_glx" in
1104 xyesyes)
1105     DEFINES="$DEFINES -DUSE_XSHM"
1106     ;;
1107 xyesno)
1108     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1109     if test "x$driglx_direct" = xyes; then
1110         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1111     fi
1112     ;;
1113 esac
1114
1115 dnl
1116 dnl TLS detection
1117 dnl
1118
1119 AC_ARG_ENABLE([glx-tls],
1120     [AS_HELP_STRING([--enable-glx-tls],
1121         [enable TLS support in GLX @<:@default=disabled@:>@])],
1122     [GLX_USE_TLS="$enableval"],
1123     [GLX_USE_TLS=no])
1124 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1125
1126 AS_IF([test "x$GLX_USE_TLS" = xyes],
1127       [DEFINES="${DEFINES} -DGLX_USE_TLS -DPTHREADS"])
1128
1129 dnl
1130 dnl More DRI setup
1131 dnl
1132 dnl Directory for DRI drivers
1133 AC_ARG_WITH([dri-driverdir],
1134     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1135         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1136     [DRI_DRIVER_INSTALL_DIR="$withval"],
1137     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1138 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1139 dnl Extra search path for DRI drivers
1140 AC_ARG_WITH([dri-searchpath],
1141     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1142         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1143     [DRI_DRIVER_SEARCH_DIR="$withval"],
1144     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1145 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1146 dnl Which drivers to build - default is chosen by platform
1147 AC_ARG_WITH([dri-drivers],
1148     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1149         [comma delimited DRI drivers list, e.g.
1150         "swrast,i965,radeon" @<:@default=auto@:>@])],
1151     [with_dri_drivers="$withval"],
1152     [with_dri_drivers=yes])
1153 if test "x$with_dri_drivers" = x; then
1154     with_dri_drivers=no
1155 fi
1156
1157 dnl If $with_dri_drivers is yes, directories will be added through
1158 dnl platform checks
1159 DRI_DIRS=""
1160 case "$with_dri_drivers" in
1161 no) ;;
1162 yes)
1163     # classic DRI drivers require FEATURE_GL to build
1164     if test "x$enable_opengl" = xyes; then
1165         DRI_DIRS="yes"
1166     fi
1167     ;;
1168 *)
1169     # verify the requested driver directories exist
1170     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1171     for driver in $dri_drivers; do
1172         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
1173             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
1174     done
1175     DRI_DIRS="$dri_drivers"
1176     if test -n "$DRI_DIRS" -a "x$enable_opengl" != xyes; then
1177         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1178     fi
1179     ;;
1180 esac
1181
1182 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
1183 if test "x$enable_dri" = xyes; then
1184     # Platform specific settings and drivers to build
1185     case "$host_os" in
1186     linux*)
1187         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1188         DEFINES="$DEFINES -DHAVE_ALIAS"
1189
1190         case "$host_cpu" in
1191         x86_64)
1192             if test "x$DRI_DIRS" = "xyes"; then
1193                 DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1194             fi
1195             ;;
1196         powerpc*)
1197             # Build only the drivers for cards that exist on PowerPC.
1198             if test "x$DRI_DIRS" = "xyes"; then
1199                 DRI_DIRS="r200 radeon swrast"
1200             fi
1201             ;;
1202         sparc*)
1203             # Build only the drivers for cards that exist on sparc
1204             if test "x$DRI_DIRS" = "xyes"; then
1205                 DRI_DIRS="r200 radeon swrast"
1206             fi
1207             ;;
1208         esac
1209         ;;
1210     freebsd* | dragonfly* | *netbsd*)
1211         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
1212         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
1213
1214         if test "x$DRI_DIRS" = "xyes"; then
1215             DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1216         fi
1217         ;;
1218     gnu*)
1219         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1220         DEFINES="$DEFINES -DHAVE_ALIAS"
1221         ;;
1222     solaris*)
1223         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1224         ;;
1225     cygwin*)
1226         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
1227         if test "x$DRI_DIRS" = "xyes"; then
1228             DRI_DIRS="swrast"
1229         fi
1230         ;;
1231     esac
1232
1233     # default drivers
1234     if test "x$DRI_DIRS" = "xyes"; then
1235         DRI_DIRS="i915 i965 nouveau r200 radeon swrast"
1236     fi
1237
1238     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
1239
1240     # Check for expat
1241     if test "x$enable_dri" = xyes; then
1242         EXPAT_INCLUDES=""
1243         EXPAT_LIB=-lexpat
1244         AC_ARG_WITH([expat],
1245             [AS_HELP_STRING([--with-expat=DIR],
1246                 [expat install directory])],[
1247             EXPAT_INCLUDES="-I$withval/include"
1248             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
1249             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
1250             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
1251             ])
1252         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
1253         save_LIBS="$LIBS"
1254         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1255             [AC_MSG_ERROR([Expat required for DRI.])])
1256         LIBS="$save_LIBS"
1257     fi
1258
1259     # if we are building any dri driver other than swrast ...
1260     if test -n "$DRI_DIRS" -a x"$DRI_DIRS" != xswrast; then
1261         # ... libdrm is required
1262         if test "x$have_libdrm" != xyes; then
1263             AC_MSG_ERROR([DRI drivers requires libdrm >= $LIBDRM_REQUIRED])
1264         fi
1265         # ... and build dricommon
1266         HAVE_COMMON_DRI=yes
1267     fi
1268
1269     # put all the necessary libs together
1270     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS"
1271 fi
1272 AC_SUBST([DRI_DIRS])
1273 AC_SUBST([EXPAT_INCLUDES])
1274 AC_SUBST([DRI_LIB_DEPS])
1275
1276 case $DRI_DIRS in
1277 *i915*|*i965*)
1278     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1279
1280     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1281         case $d in
1282         i915)
1283             HAVE_I915_DRI=yes;
1284             ;;
1285         i965)
1286             HAVE_I965_DRI=yes;
1287             ;;
1288         esac
1289     done
1290
1291     ;;
1292 esac
1293
1294 case $DRI_DIRS in
1295 *nouveau*)
1296     PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1297     HAVE_NOUVEAU_DRI=yes;
1298     ;;
1299 esac
1300
1301 case $DRI_DIRS in
1302 *radeon*|*r200*)
1303     PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1304
1305     for d in $(echo $DRI_DIRS | sed 's/,/ /g'); do
1306         case $d in
1307         radeon)
1308             HAVE_RADEON_DRI=yes;
1309             ;;
1310         r200)
1311             HAVE_R200_DRI=yes;
1312             ;;
1313         esac
1314     done
1315
1316     ;;
1317 esac
1318
1319 case $DRI_DIRS in
1320 *swrast*)
1321     HAVE_SWRAST_DRI=yes;
1322     ;;
1323 esac
1324
1325 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
1326 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
1327 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
1328 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
1329 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
1330 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
1331 AM_CONDITIONAL(HAVE_COMMON_DRI, test x$HAVE_COMMON_DRI = xyes)
1332
1333 dnl
1334 dnl OSMesa configuration
1335 dnl
1336
1337 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1338 AC_ARG_WITH([osmesa-bits],
1339     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1340         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1341     [osmesa_bits="$withval"],
1342     [osmesa_bits=8])
1343 if test "x$osmesa_bits" != x8; then
1344     if test "x$enable_dri" = xyes -o "x$enable_glx" = xyes; then
1345         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1346         osmesa_bits=8
1347     fi
1348 fi
1349 case "x$osmesa_bits" in
1350 x8)
1351     OSMESA_LIB="${OSMESA_LIB}"
1352     ;;
1353 x16|x32)
1354     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1355     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1356     ;;
1357 *)
1358     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1359     ;;
1360 esac
1361
1362 if test "x$enable_osmesa" = xyes; then
1363     # only link libraries with osmesa if shared
1364     if test "$enable_static" = no; then
1365         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1366     else
1367         OSMESA_LIB_DEPS=""
1368     fi
1369     OSMESA_MESA_DEPS=""
1370     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS"
1371 fi
1372 AC_SUBST([OSMESA_LIB_DEPS])
1373 AC_SUBST([OSMESA_MESA_DEPS])
1374 AC_SUBST([OSMESA_PC_REQ])
1375 AC_SUBST([OSMESA_PC_LIB_PRIV])
1376
1377 dnl
1378 dnl gbm configuration
1379 dnl
1380 if test "x$enable_gbm" = xauto; then
1381     case "$with_egl_platforms" in
1382         *drm*)
1383             enable_gbm=yes ;;
1384          *)
1385             enable_gbm=no ;;
1386     esac
1387 fi
1388 if test "x$enable_gbm" = xyes; then
1389     SRC_DIRS="$SRC_DIRS gbm"
1390
1391     PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1392                       AC_MSG_ERROR([gbm needs udev]))
1393
1394     if test "x$enable_dri" = xyes; then
1395         GBM_BACKEND_DIRS="$GBM_BACKEND_DIRS dri"
1396         if test "$SHARED_GLAPI" -eq 0; then
1397             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1398         fi
1399     fi
1400 fi
1401 GBM_PC_REQ_PRIV="libudev"
1402 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1403 AC_SUBST([GBM_PC_REQ_PRIV])
1404 AC_SUBST([GBM_PC_LIB_PRIV])
1405
1406 dnl
1407 dnl EGL configuration
1408 dnl
1409 EGL_CLIENT_APIS=""
1410
1411 if test "x$enable_egl" = xyes; then
1412     SRC_DIRS="$SRC_DIRS egl"
1413     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS -lpthread"
1414
1415     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1416
1417     if test "$enable_static" != yes; then
1418         # build egl_glx when libGL is built
1419         if test "x$enable_glx" = xyes; then
1420             HAVE_EGL_DRIVER_GLX=1
1421         fi
1422
1423         PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1424                           [have_libudev=yes],[have_libudev=no])
1425         if test "$have_libudev" = yes; then
1426             DEFINES="$DEFINES -DHAVE_LIBUDEV"
1427         fi
1428         if test "x$enable_dri" = xyes; then
1429             # build egl_dri2 when xcb-dri2 is available
1430             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1431                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1432             if test "$have_xcb_dri2" = yes; then
1433                 HAVE_EGL_DRIVER_DRI2=1
1434                 # workaround a bug in xcb-dri2 generated by xcb-proto 1.6
1435                 save_LIBS="$LIBS"
1436                 AC_CHECK_LIB(xcb-dri2, xcb_dri2_connect_alignment_pad, [],
1437                           [DEFINES="$DEFINES -DXCB_DRI2_CONNECT_DEVICE_NAME_BROKEN"])
1438                 LIBS="$save_LIBS"
1439             fi
1440         fi
1441
1442     fi
1443 fi
1444 AC_SUBST([EGL_LIB_DEPS])
1445
1446 dnl
1447 dnl EGL Gallium configuration
1448 dnl
1449 if test "x$enable_gallium_egl" = xyes; then
1450     if test "x$with_gallium_drivers" = x; then
1451         AC_MSG_ERROR([cannot enable egl_gallium without Gallium])
1452     fi
1453     if test "x$enable_egl" = xno; then
1454         AC_MSG_ERROR([cannot enable egl_gallium without EGL])
1455     fi
1456     if test "x$have_libdrm" != xyes; then
1457         AC_MSG_ERROR([egl_gallium requires libdrm >= $LIBDRM_REQUIRED])
1458     fi
1459
1460     GALLIUM_STATE_TRACKERS_DIRS="egl $GALLIUM_STATE_TRACKERS_DIRS"
1461     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl-static"
1462     HAVE_ST_EGL="yes"
1463 fi
1464
1465 dnl
1466 dnl gbm Gallium configuration
1467 dnl
1468 if test "x$enable_gallium_gbm" = xauto; then
1469     case "$enable_gbm$HAVE_ST_EGL$enable_dri$with_egl_platforms" in
1470         yesyesyes*drm*)
1471             enable_gallium_gbm=yes ;;
1472          *)
1473             enable_gallium_gbm=no ;;
1474     esac
1475 fi
1476 if test "x$enable_gallium_gbm" = xyes; then
1477     if test "x$with_gallium_drivers" = x; then
1478         AC_MSG_ERROR([cannot enable gbm_gallium without Gallium])
1479     fi
1480     if test "x$enable_gbm" = xno; then
1481         AC_MSG_ERROR([cannot enable gbm_gallium without gbm])
1482     fi
1483     # gbm_gallium abuses DRI_LIB_DEPS to link.  Make sure it is set.
1484     if test "x$enable_dri" = xno; then
1485         AC_MSG_ERROR([gbm_gallium requires --enable-dri to build])
1486     fi
1487
1488     GALLIUM_STATE_TRACKERS_DIRS="gbm $GALLIUM_STATE_TRACKERS_DIRS"
1489     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS gbm"
1490     HAVE_ST_GBM="yes"
1491     enable_gallium_loader=yes
1492 fi
1493
1494 dnl
1495 dnl X.Org DDX configuration
1496 dnl
1497 if test "x$enable_xorg" = xyes; then
1498     PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1499     PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1500     PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1501     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1502         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1503         HAVE_XEXTPROTO_71="no")
1504     GALLIUM_STATE_TRACKERS_DIRS="xorg $GALLIUM_STATE_TRACKERS_DIRS"
1505     HAVE_ST_XORG=yes
1506 fi
1507
1508 dnl
1509 dnl XA configuration
1510 dnl
1511 if test "x$enable_xa" = xyes; then
1512 AC_PROG_AWK
1513 AC_PROG_GREP
1514 AC_CHECK_PROG(NM, nm, "nm")
1515 if test "x$AWK" = x || test "x$GREP" = x || test "x$NM" = x; then
1516 AC_MSG_WARN([Missing one of nm, grep or awk. Disabling xa.])
1517 enable_xa=no
1518 fi
1519 fi
1520 if test "x$enable_xa" = xyes; then
1521     GALLIUM_STATE_TRACKERS_DIRS="xa $GALLIUM_STATE_TRACKERS_DIRS"
1522     HAVE_ST_XA=yes
1523     AC_SUBST(AWK)
1524     AC_SUBST(GREP)
1525     AC_SUBST(NM)
1526 fi
1527
1528 dnl
1529 dnl OpenVG configuration
1530 dnl
1531 VG_LIB_DEPS=""
1532
1533 if test "x$enable_openvg" = xyes; then
1534     if test "x$enable_egl" = xno; then
1535         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1536     fi
1537     if test "x$with_gallium_drivers" = x; then
1538         AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1539     fi
1540     if test "x$enable_gallium_egl" = xno; then
1541         AC_MSG_ERROR([cannot enable OpenVG without egl_gallium])
1542     fi
1543
1544     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1545     VG_LIB_DEPS="$VG_LIB_DEPS $SELINUX_LIBS -lpthread"
1546     CORE_DIRS="$CORE_DIRS mapi/vgapi"
1547     GALLIUM_STATE_TRACKERS_DIRS="vega $GALLIUM_STATE_TRACKERS_DIRS"
1548     HAVE_ST_VEGA=yes
1549 fi
1550
1551 dnl
1552 dnl D3D1X configuration
1553 dnl
1554
1555 if test "x$enable_d3d1x" = xyes; then
1556     if test "x$with_gallium_drivers" = x; then
1557         AC_MSG_ERROR([cannot enable D3D1X without Gallium])
1558     fi
1559
1560     GALLIUM_STATE_TRACKERS_DIRS="d3d1x $GALLIUM_STATE_TRACKERS_DIRS"
1561     HAVE_ST_D3D1X=yes
1562 fi
1563
1564 dnl
1565 dnl Gallium G3DVL configuration
1566 dnl
1567 AC_ARG_ENABLE([gallium-g3dvl],
1568     [AS_HELP_STRING([--enable-gallium-g3dvl],
1569         [build gallium g3dvl @<:@default=disabled@:>@])],
1570     [enable_gallium_g3dvl="$enableval"],
1571     [enable_gallium_g3dvl=no])
1572 if test "x$enable_gallium_g3dvl" = xyes; then
1573     if test "x$with_gallium_drivers" = x; then
1574         AC_MSG_ERROR([cannot enable G3DVL without Gallium])
1575     fi
1576
1577     if test "x$enable_xvmc" = xauto; then
1578         PKG_CHECK_EXISTS([xvmc], [enable_xvmc=yes], [enable_xvmc=no])
1579     fi
1580
1581     if test "x$enable_vdpau" = xauto; then
1582         PKG_CHECK_EXISTS([vdpau], [enable_vdpau=yes], [enable_vdpau=no])
1583     fi
1584
1585     if test "x$enable_va" = xauto; then
1586         #don't enable vaapi state tracker even if package exists
1587         #PKG_CHECK_EXISTS([libva], [enable_vdpau=yes], [enable_vdpau=no])
1588         enable_va=no
1589     fi
1590 fi
1591
1592 if test "x$enable_xvmc" = xyes; then
1593     PKG_CHECK_MODULES([XVMC], [xvmc >= 1.0.6 x11-xcb xcb-dri2 >= 1.8])
1594     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xvmc"
1595     HAVE_ST_XVMC="yes"
1596 fi
1597
1598 if test "x$enable_vdpau" = xyes; then
1599     PKG_CHECK_MODULES([VDPAU], [vdpau >= 0.4.1 x11-xcb xcb-dri2 >= 1.8])
1600     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vdpau"
1601     HAVE_ST_VDPAU="yes"
1602 fi
1603
1604 if test "x$enable_va" = xyes; then
1605     PKG_CHECK_MODULES([LIBVA], [libva = 0.31.1 x11-xcb xcb-dri2 >= 1.8])
1606     AC_MSG_WARN([vaapi state tracker currently unmaintained])
1607     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS va"
1608     HAVE_ST_VA="yes"
1609 fi
1610
1611 dnl
1612 dnl OpenCL configuration
1613 dnl
1614
1615 if test "x$enable_opencl" = xyes; then
1616     if test "x$with_gallium_drivers" = x; then
1617         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1618     fi
1619
1620     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1621         AC_MSG_ERROR([gcc >= 4.6 is required to build clover])
1622     fi
1623
1624     GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS clover"
1625     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS opencl"
1626     enable_gallium_loader=yes
1627 fi
1628
1629 dnl
1630 dnl GLU configuration
1631 dnl
1632 AC_ARG_ENABLE([glu],
1633     [AS_HELP_STRING([--disable-glu],
1634         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1635     [enable_glu="$enableval"],
1636     [enable_glu=yes])
1637
1638 if test "x$enable_glu" = xyes; then
1639     if test "x$enable_glx" = xno -a "x$enable_osmesa" = xno; then
1640         AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1641         enable_glu=no
1642     fi
1643 fi
1644
1645 if test "x$enable_glu" = xyes; then
1646     SRC_DIRS="$SRC_DIRS glu"
1647
1648     if test "x$enable_glx" = xno; then
1649         # Link libGLU to libOSMesa instead of libGL
1650         GLU_LIB_DEPS=""
1651         GLU_PC_REQ="osmesa"
1652         if test "$enable_static" = no; then
1653             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1654         else
1655             GLU_MESA_DEPS=""
1656         fi
1657     else
1658         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1659         GLU_PC_REQ="gl"
1660         GLU_PC_LIB_PRIV="-lm"
1661         if test "$enable_static" = no; then
1662             GLU_LIB_DEPS="-lm"
1663             GLU_MESA_DEPS='-l$(GL_LIB)'
1664         else
1665             GLU_LIB_DEPS=""
1666             GLU_MESA_DEPS=""
1667         fi
1668     fi
1669 fi
1670 if test "$enable_static" = no; then
1671     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1672 fi
1673 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1674 AC_SUBST([GLU_LIB_DEPS])
1675 AC_SUBST([GLU_MESA_DEPS])
1676 AC_SUBST([GLU_PC_REQ])
1677 AC_SUBST([GLU_PC_REQ_PRIV])
1678 AC_SUBST([GLU_PC_LIB_PRIV])
1679 AC_SUBST([GLU_PC_CFLAGS])
1680
1681 AC_SUBST([PROGRAM_DIRS])
1682
1683 dnl
1684 dnl Gallium configuration
1685 dnl
1686 if test "x$with_gallium_drivers" != x; then
1687     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1688 fi
1689
1690 AC_SUBST([LLVM_BINDIR])
1691 AC_SUBST([LLVM_CFLAGS])
1692 AC_SUBST([LLVM_CXXFLAGS])
1693 AC_SUBST([LLVM_LIBS])
1694 AC_SUBST([LLVM_LDFLAGS])
1695 AC_SUBST([LLVM_INCLUDEDIR])
1696 AC_SUBST([LLVM_VERSION])
1697
1698 case "x$enable_opengl$enable_gles1$enable_gles2" in
1699 x*yes*)
1700     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1701     ;;
1702 esac
1703
1704 AC_SUBST([VG_LIB_DEPS])
1705 AC_SUBST([EGL_CLIENT_APIS])
1706
1707 AC_ARG_WITH([egl-platforms],
1708     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1709         [comma delimited native platforms libEGL supports, e.g.
1710         "x11,drm" @<:@default=auto@:>@])],
1711     [with_egl_platforms="$withval"],
1712     [if test "x$enable_egl" = xyes; then
1713         with_egl_platforms="x11"
1714     else
1715         with_egl_platforms=""
1716     fi])
1717
1718 EGL_PLATFORMS=""
1719
1720 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
1721     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1722 fi
1723
1724 # verify the requested driver directories exist
1725 egl_platforms=`IFS=', '; echo $with_egl_platforms`
1726 for plat in $egl_platforms; do
1727         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1728             AC_MSG_ERROR([EGL platform '$plat' does not exist])
1729         if test "$plat" = "fbdev"; then
1730                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1731         fi
1732         if test "$plat" = "null"; then
1733                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
1734         fi
1735         if test "$plat" = "wayland"; then
1736                 PKG_CHECK_MODULES([WAYLAND], [wayland-client wayland-server],, \
1737                                   [AC_MSG_ERROR([cannot find libwayland-client])])
1738                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/wayland"
1739
1740                 m4_ifdef([WAYLAND_SCANNER_RULES],
1741                          [WAYLAND_SCANNER_RULES(['$(top_srcdir)/src/egl/wayland/wayland-drm/protocol'])])
1742         fi
1743         if test "$plat" = "drm" && test "x$enable_gbm" = "xno"; then
1744                 AC_MSG_ERROR([EGL platform drm needs gbm])
1745         fi
1746         case "$plat$have_libudev" in
1747                 waylandno|drmno)
1748                     AC_MSG_ERROR([cannot build $plat platfrom without udev]) ;;
1749         esac
1750 done
1751
1752 # libEGL wants to default to the first platform specified in
1753 # ./configure.  parse that here.
1754 if test "x$egl_platforms" != "x"; then
1755     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr 'a-z' 'A-Z'`
1756     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
1757 else
1758     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
1759 fi
1760
1761 EGL_PLATFORMS="$egl_platforms"
1762
1763 AM_CONDITIONAL(HAVE_EGL_PLATFORM_X11, echo "$egl_platforms" | grep 'x11' >/dev/null 2>&1)
1764 AM_CONDITIONAL(HAVE_EGL_PLATFORM_WAYLAND, echo "$egl_platforms" | grep 'wayland' >/dev/null 2>&1)
1765 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep 'drm' >/dev/null 2>&1)
1766 AM_CONDITIONAL(HAVE_EGL_PLATFORM_FBDEV, echo "$egl_platforms" | grep 'fbdev' >/dev/null 2>&1)
1767 AM_CONDITIONAL(HAVE_EGL_PLATFORM_NULL, echo "$egl_platforms" | grep 'null' >/dev/null 2>&1)
1768
1769 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
1770 AM_CONDITIONAL(HAVE_EGL_DRIVER_GLX, test "x$HAVE_EGL_DRIVER_GLX" != "x")
1771
1772 AC_SUBST([EGL_NATIVE_PLATFORM])
1773 AC_SUBST([EGL_PLATFORMS])
1774 AC_SUBST([EGL_CFLAGS])
1775
1776 AC_ARG_WITH([egl-driver-dir],
1777     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1778                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1779     [EGL_DRIVER_INSTALL_DIR="$withval"],
1780     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1781 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1782
1783 AC_ARG_WITH([xorg-driver-dir],
1784     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1785                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1786     [XORG_DRIVER_INSTALL_DIR="$withval"],
1787     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1788 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1789
1790 AC_ARG_WITH([max-width],
1791     [AS_HELP_STRING([--with-max-width=N],
1792                     [Maximum framebuffer width (4096)])],
1793     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1794      AS_IF([test "${withval}" -gt "4096"],
1795            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1796 )
1797 AC_ARG_WITH([max-height],
1798     [AS_HELP_STRING([--with-max-height=N],
1799                     [Maximum framebuffer height (4096)])],
1800     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1801      AS_IF([test "${withval}" -gt "4096"],
1802            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1803 )
1804
1805 dnl
1806 dnl Gallium LLVM
1807 dnl
1808 AC_ARG_ENABLE([gallium-llvm],
1809     [AS_HELP_STRING([--enable-gallium-llvm],
1810         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
1811     [enable_gallium_llvm="$enableval"],
1812     [enable_gallium_llvm=auto])
1813
1814 AC_ARG_WITH([llvm-shared-libs],
1815     [AS_HELP_STRING([--with-llvm-shared-libs],
1816         [link with LLVM shared libraries @<:@default=disabled@:>@])],
1817     [with_llvm_shared_libs=yes],
1818     [with_llvm_shared_libs=no])
1819
1820 if test "x$with_gallium_drivers" = x; then
1821     enable_gallium_llvm=no
1822 fi
1823 if test "x$enable_gallium_llvm" = xauto; then
1824     case "$host_cpu" in
1825     i*86|x86_64) enable_gallium_llvm=yes;;
1826     esac
1827 fi
1828 if test "x$enable_gallium_llvm" = xyes; then
1829     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1830
1831     if test "x$LLVM_CONFIG" != xno; then
1832         LLVM_VERSION=`$LLVM_CONFIG --version | sed 's/svn.*//g'`
1833         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags|sed -e 's/-DNDEBUG\>//g' -e 's/-pedantic//g'`
1834         if test "x$with_llvm_shared_libs" = xyes; then
1835             dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
1836             LLVM_LIBS="-lLLVM-`$LLVM_CONFIG --version`"
1837         else
1838             LLVM_LIBS="`$LLVM_CONFIG --libs engine bitwriter`"
1839         fi
1840         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1841         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
1842         LLVM_CXXFLAGS=`$LLVM_CONFIG --cxxflags`
1843         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
1844         DEFINES="${DEFINES} -DHAVE_LLVM=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/0x0\10\2/g'`"
1845         MESA_LLVM=1
1846     else
1847         MESA_LLVM=0
1848     fi
1849 else
1850     MESA_LLVM=0
1851 fi
1852
1853 dnl Directory for XVMC libs
1854 AC_ARG_WITH([xvmc-libdir],
1855     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
1856         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
1857     [XVMC_LIB_INSTALL_DIR="$withval"],
1858     [XVMC_LIB_INSTALL_DIR='${libdir}'])
1859 AC_SUBST([XVMC_LIB_INSTALL_DIR])
1860
1861 dnl
1862 dnl Gallium Tests
1863 dnl
1864 if test "x$enable_gallium_tests" = xyes; then
1865     SRC_DIRS="$SRC_DIRS gallium/tests/trivial"
1866     enable_gallium_loader=yes
1867 fi
1868
1869 dnl Directory for VDPAU libs
1870 AC_ARG_WITH([vdpau-libdir],
1871     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
1872         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
1873     [VDPAU_LIB_INSTALL_DIR="$withval"],
1874     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
1875 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
1876
1877 dnl Directory for VA libs
1878 AC_ARG_WITH([va-libdir],
1879     [AS_HELP_STRING([--with-va-libdir=DIR],
1880         [directory for the VA libraries @<:@default=${libdir}/va@:>@])],
1881     [VA_LIB_INSTALL_DIR="$withval"],
1882     [VA_LIB_INSTALL_DIR='${libdir}/va'])
1883 AC_SUBST([VA_LIB_INSTALL_DIR])
1884
1885 dnl Directory for OpenCL libs
1886 AC_ARG_WITH([opencl-libdir],
1887     [AS_HELP_STRING([--with-opencl-libdir=DIR],
1888         [directory for the OpenCL libraries @<:@default=${libdir}/opencl@:>@])],
1889     [OPENCL_LIB_INSTALL_DIR="$withval"],
1890     [OPENCL_LIB_INSTALL_DIR='${libdir}/opencl'])
1891 AC_SUBST([OPENCL_LIB_INSTALL_DIR])
1892
1893 dnl
1894 dnl Gallium helper functions
1895 dnl
1896 gallium_check_st() {
1897     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes ||
1898          test "x$HAVE_ST_XA" = xyes || test "x$HAVE_ST_XVMC" = xyes ||
1899          test "x$HAVE_ST_VDPAU" = xyes || test "x$HAVE_ST_VA" = xyes; then
1900          if test "x$have_libdrm" != xyes; then
1901             AC_MSG_ERROR([DRI or Xorg DDX requires libdrm >= $LIBDRM_REQUIRED])
1902          fi
1903          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1904     fi
1905     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1906          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1907     fi
1908     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1909          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1910     fi
1911     if test "x$HAVE_ST_XA" = xyes && test "x$4" != x; then
1912          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $4"
1913     fi
1914     if test "x$HAVE_ST_XVMC" = xyes && test "x$5" != x; then
1915          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $5"
1916     fi
1917     if test "x$HAVE_ST_VDPAU" = xyes && test "x$6" != x; then
1918          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $6"
1919     fi
1920     if test "x$HAVE_ST_VA" = xyes && test "x$7" != x; then
1921          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $7"
1922     fi
1923 }
1924
1925 gallium_require_llvm() {
1926     if test "x$MESA_LLVM" = x0; then
1927         case "$host_cpu" in
1928         i*86|x86_64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
1929         esac
1930     fi
1931 }
1932
1933 gallium_require_drm_loader() {
1934     if test "x$enable_gallium_loader" = xyes; then
1935         PKG_CHECK_MODULES([LIBUDEV], [libudev], [],
1936                           AC_MSG_ERROR([Gallium drm loader requrires libudev]))
1937         if test "x$have_libdrm" != xyes; then
1938             AC_MSG_ERROR([Gallium drm loader requires libdrm >= $LIBDRM_REQUIRED])
1939         fi
1940         enable_gallium_drm_loader=yes
1941     fi
1942 }
1943
1944 dnl Gallium drivers
1945 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
1946 if test "x$with_gallium_drivers" != x; then
1947     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
1948     for driver in $gallium_drivers; do
1949         case "x$driver" in
1950         xsvga)
1951             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga softpipe"
1952             gallium_check_st "svga/drm" "dri-vmwgfx" "" "xa-vmwgfx"
1953             ;;
1954         xi915)
1955             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1956             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915 softpipe"
1957             if test "x$MESA_LLVM" = x1; then
1958                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1959             fi
1960             GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1961             gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1962             ;;
1963         xr300)
1964             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1965             gallium_require_llvm "Gallium R300"
1966             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1967             gallium_check_st "radeon/drm" "dri-r300" "xorg-r300" "" "xvmc-r300" "vdpau-r300" "va-r300"
1968             ;;
1969         xr600)
1970             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1971             gallium_require_drm_loader
1972             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1973             if test "x$enable_r600_llvm" = xyes; then
1974                 if test "x$LLVM_VERSION" != "x3.1"; then
1975                     AC_MSG_ERROR([LLVM 3.1 is required for the r600 llvm compiler.])
1976                 fi
1977                 NEED_RADEON_GALLIUM=yes;
1978                 USE_R600_LLVM_COMPILER=yes;
1979             fi
1980             gallium_check_st "radeon/drm" "dri-r600" "xorg-r600" "" "xvmc-r600" "vdpau-r600" "va-r600"
1981             ;;
1982         xradeonsi)
1983             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1984             gallium_require_drm_loader
1985             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS radeonsi"
1986             if test "x$LLVM_VERSION" != "x3.1"; then
1987                 AC_MSG_ERROR([LLVM 3.1 is required to build the radeonsi driver.])
1988             fi
1989             NEED_RADEON_GALLIUM=yes;
1990             gallium_check_st "radeon/drm" "dri-radeonsi" "xorg-radeonsi"
1991             ;;
1992         xnouveau)
1993             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
1994             gallium_require_drm_loader
1995             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nv30 nv50 nvc0"
1996             gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau" "" "xvmc-nouveau" "vdpau-nouveau"
1997             ;;
1998         xswrast)
1999             GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS softpipe"
2000             if test "x$MESA_LLVM" = x1; then
2001                 GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
2002             fi
2003
2004             if test "x$HAVE_ST_DRI" = xyes; then
2005                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
2006             fi
2007             if test "x$HAVE_ST_VDPAU" = xyes; then
2008                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS vdpau-softpipe"
2009             fi
2010             if test "x$HAVE_ST_XVMC" = xyes; then
2011                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS xvmc-softpipe"
2012             fi
2013             if test "x$HAVE_ST_VA" = xyes; then
2014                 GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS va-softpipe"
2015             fi
2016             if test "x$HAVE_ST_VDPAU" = xyes ||
2017                test "x$HAVE_ST_XVMC" = xyes ||
2018                test "x$HAVE_ST_VA" = xyes; then
2019                if test "x$HAVE_WINSYS_XLIB" != xyes; then
2020                   GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
2021                fi
2022             fi
2023             ;;
2024         *)
2025             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2026             ;;
2027         esac
2028     done
2029 fi
2030
2031 if test "x$enable_gallium_loader" = xyes; then
2032     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/null"
2033     GALLIUM_PIPE_LOADER_DEFINES="-DHAVE_PIPE_LOADER_SW"
2034     GALLIUM_PIPE_LOADER_LIBS="\$(TOP)/src/gallium/auxiliary/pipe-loader/libpipe_loader.a"
2035     GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/null/libws_null.a"
2036
2037     if test "x$HAVE_WINSYS_XLIB" = xyes; then
2038         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_XLIB"
2039         GALLIUM_PIPE_LOADER_LIBS="$GALLIUM_PIPE_LOADER_LIBS \$(TOP)/src/gallium/winsys/sw/xlib/libws_xlib.a"
2040     fi
2041
2042     if test "x$enable_gallium_drm_loader" = xyes; then
2043         GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRM"
2044     fi
2045
2046     AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2047     AC_SUBST([GALLIUM_PIPE_LOADER_LIBS])
2048 fi
2049
2050 dnl Tell Automake which drivers to build
2051 for driver in $GALLIUM_DRIVERS_DIRS; do
2052     case "x$driver" in
2053         xgalahad)
2054             HAVE_GALAHAD_GALLIUM=yes;
2055             ;;
2056         xidentity)
2057             HAVE_IDENTITY_GALLIUM=yes;
2058             ;;
2059         xnoop)
2060             HAVE_NOOP_GALLIUM=yes;
2061             ;;
2062         *)
2063             GALLIUM_MAKE_DIRS="$GALLIUM_MAKE_DIRS $driver"
2064             ;;
2065     esac
2066 done
2067
2068 AM_CONDITIONAL(HAVE_GALAHAD_GALLIUM, test x$HAVE_GALAHAD_GALLIUM = xyes)
2069 AM_CONDITIONAL(HAVE_IDENTITY_GALLIUM, test x$HAVE_IDENTITY_GALLIUM = xyes)
2070 AM_CONDITIONAL(HAVE_NOOP_GALLIUM, test x$HAVE_NOOP_GALLIUM = xyes)
2071 AM_CONDITIONAL(NEED_RADEON_GALLIUM, test x$NEED_RADEON_GALLIUM = xyes)
2072 AM_CONDITIONAL(USE_R600_LLVM_COMPILER, test x$USE_R600_LLVM_COMPILER = xyes)
2073 AM_CONDITIONAL(HAVE_LOADER_GALLIUM, test x$enable_gallium_loader = xyes)
2074 AM_CONDITIONAL(HAVE_DRM_LOADER_GALLIUM, test x$enable_gallium_drm_loader = xyes)
2075 AC_SUBST([GALLIUM_MAKE_DIRS])
2076
2077 dnl prepend CORE_DIRS to SRC_DIRS
2078 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
2079
2080 dnl Restore LDFLAGS and CPPFLAGS
2081 LDFLAGS="$_SAVE_LDFLAGS"
2082 CPPFLAGS="$_SAVE_CPPFLAGS"
2083
2084 dnl Add user CFLAGS and CXXFLAGS
2085 CFLAGS="$CFLAGS $USER_CFLAGS"
2086 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2087
2088 dnl Substitute the config
2089 AC_CONFIG_FILES([configs/autoconf
2090                 src/gallium/auxiliary/pipe-loader/Makefile
2091                 src/gallium/state_trackers/clover/Makefile
2092                 src/gallium/drivers/Makefile
2093                 src/gallium/drivers/r300/Makefile
2094                 src/gallium/drivers/r600/Makefile
2095                 src/gallium/targets/opencl/Makefile
2096                 src/gbm/Makefile
2097                 src/gbm/main/gbm.pc
2098                 src/egl/drivers/Makefile
2099                 src/egl/drivers/dri2/Makefile
2100                 src/egl/drivers/glx/Makefile
2101                 src/egl/main/Makefile
2102                 src/egl/main/egl.pc
2103                 src/egl/wayland/Makefile
2104                 src/egl/wayland/wayland-egl/Makefile
2105                 src/egl/wayland/wayland-egl/wayland-egl.pc
2106                 src/egl/wayland/wayland-drm/Makefile
2107                 src/glsl/tests/Makefile
2108                 src/glx/Makefile
2109                 src/mapi/shared-glapi/Makefile
2110                 src/gtest/Makefile
2111                 src/mesa/drivers/dri/dri.pc
2112                 src/mesa/drivers/dri/Makefile
2113                 src/mesa/drivers/dri/common/Makefile
2114                 src/mesa/drivers/dri/i915/Makefile
2115                 src/mesa/drivers/dri/i965/Makefile
2116                 src/mesa/drivers/dri/nouveau/Makefile
2117                 src/mesa/drivers/dri/r200/Makefile
2118                 src/mesa/drivers/dri/radeon/Makefile
2119                 src/mesa/drivers/dri/swrast/Makefile
2120                 tests/Makefile
2121                 tests/glx/Makefile])
2122
2123 dnl Replace the configs/current symlink
2124 AC_CONFIG_COMMANDS([configs],[
2125 if test -f configs/current || test -L configs/current; then
2126     rm -f configs/current
2127 fi
2128 ln -s autoconf configs/current
2129 ])
2130
2131 dnl Sort the dirs alphabetically
2132 GALLIUM_TARGET_DIRS=`echo $GALLIUM_TARGET_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2133 GALLIUM_WINSYS_DIRS=`echo $GALLIUM_WINSYS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2134 GALLIUM_DRIVERS_DIRS=`echo $GALLIUM_DRIVERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2135 GALLIUM_MAKE_DIRS=`echo $GALLIUM_MAKE_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2136 GALLIUM_STATE_TRACKERS_DIRS=`echo $GALLIUM_STATE_TRACKERS_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
2137
2138 AC_OUTPUT
2139
2140 dnl
2141 dnl Output some configuration info for the user
2142 dnl
2143 echo ""
2144 echo "        prefix:          $prefix"
2145 echo "        exec_prefix:     $exec_prefix"
2146 echo "        libdir:          $libdir"
2147 echo "        includedir:      $includedir"
2148
2149 dnl API info
2150 echo ""
2151 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2152 echo "        OpenVG:          $enable_openvg"
2153
2154 dnl Driver info
2155 echo ""
2156 if test "x$enable_osmesa" != xno; then
2157         echo "        OSMesa:          lib$OSMESA_LIB"
2158 else
2159         echo "        OSMesa:          no"
2160 fi
2161
2162 if test "x$enable_dri" != xno; then
2163         # cleanup the drivers var
2164         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2165         if test "x$DRI_DIRS" = x; then
2166             echo "        DRI drivers:     no"
2167         else
2168             echo "        DRI drivers:     $dri_dirs"
2169         fi
2170         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2171 fi
2172
2173 case "x$enable_glx$enable_xlib_glx" in
2174 xyesyes)
2175     echo "        GLX:             Xlib-based"
2176     ;;
2177 xyesno)
2178     echo "        GLX:             DRI-based"
2179     ;;
2180 *)
2181     echo "        GLX:             $enable_glx"
2182     ;;
2183 esac
2184
2185 echo ""
2186 echo "        GLU:             $enable_glu"
2187
2188 dnl EGL
2189 echo ""
2190 echo "        EGL:             $enable_egl"
2191 if test "$enable_egl" = yes; then
2192     echo "        EGL platforms:   $EGL_PLATFORMS"
2193
2194     egl_drivers=""
2195     if test "x$HAVE_EGL_DRIVER_GLX" != "x"; then
2196         egl_drivers="$egl_drivers builtin:egl_glx"
2197     fi
2198     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2199         egl_drivers="$egl_drivers builtin:egl_dri2"
2200     fi
2201
2202     if test "x$HAVE_ST_EGL" = xyes; then
2203         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
2204         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
2205     else
2206         echo "        EGL drivers:    $egl_drivers"
2207     fi
2208 fi
2209
2210 echo ""
2211 if test "x$MESA_LLVM" = x1; then
2212     echo "        llvm:            yes"
2213     echo "        llvm-config:     $LLVM_CONFIG"
2214     echo "        llvm-version:    $LLVM_VERSION"
2215 else
2216     echo "        llvm:            no"
2217 fi
2218
2219 echo ""
2220 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
2221     echo "        Gallium:         yes"
2222     echo "        Gallium dirs:    $GALLIUM_DIRS"
2223     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
2224     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
2225     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
2226     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
2227 else
2228     echo "        Gallium:         no"
2229 fi
2230
2231
2232 dnl Libraries
2233 echo ""
2234 echo "        Shared libs:     $enable_shared"
2235 echo "        Static libs:     $enable_static"
2236
2237 dnl Compiler options
2238 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2239 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2240     $SED 's/^ *//;s/  */ /;s/ *$//'`
2241 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
2242     $SED 's/^ *//;s/  */ /;s/ *$//'`
2243 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
2244 echo ""
2245 echo "        CFLAGS:          $cflags"
2246 echo "        CXXFLAGS:        $cxxflags"
2247 echo "        Macros:          $defines"
2248 echo ""
2249 echo "        PYTHON2:         $PYTHON2"
2250
2251 echo ""
2252 echo "        Run '${MAKE-make}' to build Mesa"
2253 echo ""