configure.ac

   1 dnl  Copyright © 2008 Dan Nicholson
   2 dnl
   3 dnl  Permission to use, copy, modify, distribute, and sell this software and its
   4 dnl  documentation for any purpose is hereby granted without fee, provided that
   5 dnl  the above copyright notice appear in all copies and that both that
   6 dnl  copyright notice and this permission notice appear in supporting
   7 dnl  documentation, and that the name of Keith Packard not be used in
   8 dnl  advertising or publicity pertaining to distribution of the software without
   9 dnl  specific, written prior permission.  Keith Packard makes no
  10 dnl  representations about the suitability of this software for any purpose.  It
  11 dnl  is provided "as is" without express or implied warranty.
  12 dnl
  13 dnl  DAN NICHOLSON DISCLAIMS ALL WARRANTIES WITH REGARD TO THIS SOFTWARE,
  14 dnl  INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS, IN NO
  15 dnl  EVENT SHALL KEITH PACKARD BE LIABLE FOR ANY SPECIAL, INDIRECT OR
  16 dnl  CONSEQUENTIAL DAMAGES OR ANY DAMAGES WHATSOEVER RESULTING FROM LOSS OF USE,
  17 dnl  DATA OR PROFITS, WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER
  18 dnl  TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE OR
  19 dnl  PERFORMANCE OF THIS SOFTWARE.
  20 dnl
  21 dnl Process this file with autoconf to create configure.
  22
  23 AC_PREREQ([2.57])
  24 AC_INIT([libxkbcommon], [0.1.0],
  25     [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg])
  26 AM_INIT_AUTOMAKE([dist-bzip2 foreign])
  27 AM_SILENT_RULES([yes])
  28 AC_CONFIG_HEADERS([src/config.h])
  29
  30 AC_PROG_LIBTOOL
  31 AC_PROG_CC
  32 AC_PROG_YACC
  33
  34 m4_ifndef([PKG_PROG_PKG_CONFIG],
  35     [m4_fatal([Could not locate the pkg-config autoconf macros.
  36     These are usually located in /usr/share/aclocal/pkg.m4. If your
  37     macros are in a different location, try setting the environment
  38     variable ACLOCAL="aclocal -I/other/macro/dir" before running
  39     autoreconf/autogen.sh.])])
  40 PKG_PROG_PKG_CONFIG
  41
  42 # Require xorg-macros version 1.2.0 or newer for XORG_CHANGELOG macro
  43 m4_ifndef([XORG_MACROS_VERSION],
  44     [m4_fatal([must install xorg-macros before running autoconf/autogen.sh])])
  45 XORG_MACROS_VERSION([1.2.0])
  46
  47 dnl Build native compiler needed for makekeys
  48 AC_ARG_VAR([CC_FOR_BUILD], [Build native C compiler program])
  49 if test "x$CC_FOR_BUILD" = x; then
  50     if test "$cross_compiling" != no; then
  51         AC_PATH_PROGS([CC_FOR_BUILD], [gcc cc], [cc])
  52     else
  53         CC_FOR_BUILD="$CC"
  54     fi
  55 fi
  56
  57 AC_CHECK_FUNCS([strcasecmp])
  58 XORG_CHECK_MALLOC_ZERO
  59 XORG_CWARNFLAGS
  60
  61 PKG_CHECK_MODULES([X11], [xproto kbproto >= 1.0.99.1])
  62 PKG_CHECK_MODULES([XLIB], [x11])
  63
  64 dnl Ensure we have keysym headers
  65 AC_MSG_CHECKING([for X11 includedir])
  66 x11includedir="`$PKG_CONFIG --variable=includedir xproto`/X11"
  67 AC_MSG_RESULT([$x11includedir])
  68
  69 AC_MSG_CHECKING([for keysymdef.h])
  70 KEYSYMDEF_H="$x11includedir/keysymdef.h"
  71 test -f "$KEYSYMDEF_H" || AC_MSG_ERROR([can't locate keysymdef.h in $x11includedir])
  72 AC_MSG_RESULT([$KEYSYMDEF_H])
  73 AC_SUBST([KEYSYMDEF_H])
  74
  75 AC_MSG_CHECKING([for XF86keysym.h])
  76 XF86KEYSYM_H="$x11includedir/XF86keysym.h"
  77 test -f "$XF86KEYSYM_H" || AC_MSG_ERROR([can't locate XF86keysym.h in $x11includedir])
  78 AC_MSG_RESULT([$XF86KEYSYM_H])
  79 AC_SUBST([XF86KEYSYM_H])
  80
  81 AC_SUBST([KS_HEADERS], ['$(KEYSYMDEF_H) $(XF86KEYSYM_H)'])
  82
  83 AC_ARG_WITH([xkb_config_root],
  84     [AC_HELP_STRING([--with-xkb-config-root=<paths>],
  85         [Set default XKB config root (default: ${datadir}/X11/xkb)])],
  86     [XKBCONFIGROOT="$withval"],
  87     [XKBCONFIGROOT='${datadir}/X11/xkb'])
  88 AC_SUBST([XKBCONFIGROOT])
  89
  90 XORG_RELEASE_VERSION
  91 XORG_CHANGELOG
  92
  93 AC_OUTPUT([
  94 Makefile
  95 xkbcommon.pc
  96 include/Makefile
  97 src/Makefile
  98 src/makekeys/Makefile
  99 src/xkbcomp/Makefile
 100 test/Makefile
 101 ])