configure.ac

   1 AC_INIT([libusb], [1.0.8])
   2 AM_INIT_AUTOMAKE
   3 AC_CONFIG_SRCDIR([libusb/core.c])
   4 AC_CONFIG_MACRO_DIR([m4])
   5 AM_CONFIG_HEADER([config.h])
   6 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   7
   8 AC_PREREQ([2.50])
   9 AC_PROG_CC
  10 AC_PROG_LIBTOOL
  11 AC_C_INLINE
  12 AM_PROG_CC_C_O
  13 AC_DEFINE([_GNU_SOURCE], [], [Use GNU extensions])
  14
  15 AC_MSG_CHECKING([operating system])
  16 case $host in
  17 *-linux*)
  18         AC_DEFINE(OS_LINUX, [], [Linux backend])
  19         AC_SUBST(OS_LINUX)
  20         AC_MSG_RESULT([Linux])
  21         backend="linux"
  22         AC_CHECK_LIB(rt, clock_gettime)
  23         threads="posix"
  24         THREAD_CFLAGS="-pthread"
  25         AM_LDFLAGS=""
  26         ;;
  27 *-darwin*)
  28         AC_DEFINE(OS_DARWIN, [], [Darwin backend])
  29         AC_SUBST(OS_DARWIN)
  30         AC_DEFINE(USBI_OS_HANDLES_TIMEOUT, [], [Backend handles timeout])
  31         AC_MSG_RESULT([Darwin/MacOS X])
  32         backend="darwin"
  33         threads="posix"
  34         THREAD_CFLAGS="-pthread"
  35         AM_LDFLAGS="-Wl,-framework -Wl,IOKit -Wl,-framework -Wl,CoreFoundation -Wl,-prebind -no-undefined"
  36         ;;
  37 *)
  38         AC_MSG_ERROR([unsupported operating system])
  39 esac
  40
  41 AM_CONDITIONAL([OS_LINUX], [test "x$backend" == "xlinux"])
  42 AM_CONDITIONAL([OS_DARWIN], [test "x$backend" == "xdarwin"])
  43 AM_CONDITIONAL([THREADS_POSIX], [test "x$threads" == "xposix"])
  44
  45 # Library versioning
  46 lt_major="0"
  47 lt_revision="0"
  48 lt_age="0"
  49 AC_SUBST(lt_major)
  50 AC_SUBST(lt_revision)
  51 AC_SUBST(lt_age)
  52
  53 # timerfd
  54 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
  55 AC_ARG_ENABLE([timerfd],
  56         [AS_HELP_STRING([--enable-timerfd],
  57                 [use timerfd for timing (default auto)])],
  58         [use_timerfd=$enableval], [use_timerfd='auto'])
  59
  60 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
  61         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
  62 fi
  63
  64 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
  65 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
  66         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
  67 fi
  68
  69 AC_MSG_CHECKING([whether to use timerfd for timing])
  70 if test "x$use_timerfd" = "xno"; then
  71         AC_MSG_RESULT([no (disabled by user)])
  72 else
  73         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
  74                 AC_MSG_RESULT([yes])
  75                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, [], [timerfd headers available])
  76         else
  77                 AC_MSG_RESULT([no (header not available)])
  78         fi
  79 fi
  80
  81 # Message logging
  82 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
  83         [log_enabled=$enableval],
  84         [log_enabled='yes'])
  85 if test "x$log_enabled" != "xno"; then
  86         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
  87 fi
  88
  89 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
  90         [enable debug logging (default n)])],
  91         [debug_log_enabled=$enableval],
  92         [debug_log_enabled='no'])
  93 if test "x$debug_log_enabled" != "xno"; then
  94         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
  95 fi
  96
  97 # Examples build
  98 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
  99         [build example applications (default n)])],
 100         [build_examples=$enableval],
 101         [build_examples='no'])
 102 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 103
 104 # Restore gnu89 inline semantics on gcc 4.3 and newer
 105 saved_cflags="$CFLAGS"
 106 CFLAGS="$CFLAGS -fgnu89-inline"
 107 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), inline_cflags="-fgnu89-inline", inline_cflags="")
 108 CFLAGS="$saved_cflags"
 109
 110 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 111 saved_cflags="$CFLAGS"
 112 CFLAGS="$CFLAGS -fvisibility=hidden"
 113 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 114         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 115          AC_DEFINE([API_EXPORTED], [__attribute__((visibility("default")))], [Default visibility]) ],
 116         [ VISIBILITY_CFLAGS=""
 117          AC_DEFINE([API_EXPORTED], [], [Default visibility]) ],
 118         ])
 119 CFLAGS="$saved_cflags"
 120
 121 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 122 saved_cflags="$CFLAGS"
 123 CFLAGS="$CFLAGS -Wno-pointer-sign"
 124 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 125         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 126 CFLAGS="$saved_cflags"
 127
 128 AC_SUBST([THREAD_CFLAGS])
 129
 130 AM_CFLAGS="-std=gnu99 $inline_cflags -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 131
 132 AC_SUBST(VISIBILITY_CFLAGS)
 133 AC_SUBST(AM_CFLAGS)
 134 AC_SUBST(AM_LDFLAGS)
 135
 136 AC_CONFIG_FILES([libusb-1.0.pc] [Makefile] [libusb/Makefile] [examples/Makefile] [doc/Makefile] [doc/doxygen.cfg])
 137 AC_OUTPUT
 138