configure.ac

   1 # If not 1, append datestamp to the version number
   2 m4_define([folks_released], [0])
   3
   4 m4_define([folks_major_version], [0])
   5 m4_define([folks_minor_version], [6])
   6 m4_define([folks_micro_version], [4])
   7 m4_define([folks_nano_version], [1])
   8
   9 # If library source has changed since last release, increment revision
  10 # If public symbols have been added, removed or changed since last release,
  11 #  increment current and set revision to 0
  12 # If public symbols have been added since last release, increment age
  13 # If public symbols have been removed since last release, set age to 0
  14 m4_define([folks_lt_current], [28])
  15 m4_define([folks_lt_revision], [0])
  16 m4_define([folks_lt_age], [3])
  17
  18 # Display the nano_version only if it's not '0'
  19 m4_define([folks_base_version],
  20           folks_major_version.folks_minor_version.folks_micro_version)
  21 m4_define([folks_full_version],
  22           [m4_if(folks_nano_version, [0],
  23                  folks_base_version, folks_base_version.folks_nano_version)])
  24
  25 m4_define([folks_maybe_datestamp],
  26           m4_if(folks_released, [1],
  27                 [], [m4_esyscmd([date +.%Y%m%d | tr -d '\n\r'])]))
  28
  29 m4_define([folks_version], folks_full_version[]folks_maybe_datestamp)
  30 m4_define([folks_major_minor_version], folks_major_version.folks_minor_version)
  31 m4_define([folks_module_version], folks_lt_current)
  32
  33 AC_INIT([folks], folks_version,
  34         [https://bugzilla.gnome.org/browse.cgi?product=folks], [folks],
  35         [http://telepathy.freedesktop.org/wiki/Folks])
  36 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  37
  38 AC_PREREQ([2.65])
  39 AC_COPYRIGHT([Copyright (C) 2010 Collabora Ltd.])
  40
  41 AC_CONFIG_MACRO_DIR([m4])
  42 AC_CONFIG_SRCDIR([Makefile.am])
  43 AC_CONFIG_HEADERS(config.h)
  44 AC_CONFIG_SRCDIR([configure.ac])
  45 AM_INIT_AUTOMAKE([1.11 dist-bzip2 no-define
  46                   no-dist-gzip tar-ustar -Wno-portability])
  47 AM_MAINTAINER_MODE([enable])
  48
  49 AC_PROG_CC
  50 AM_PROG_CC_C_O
  51 AC_DISABLE_STATIC
  52 LT_INIT
  53 PKG_PROG_PKG_CONFIG([0.21])
  54
  55 AC_SUBST([CFLAGS])
  56 AC_SUBST([CPPFLAGS])
  57 AC_SUBST([LDFLAGS])
  58
  59 LT_CURRENT=folks_lt_current
  60 LT_REVISION=folks_lt_revision
  61 LT_AGE=folks_lt_age
  62 AC_SUBST([LT_CURRENT])
  63 AC_SUBST([LT_REVISION])
  64 AC_SUBST([LT_AGE])
  65
  66 FOLKS_MAJOR_MINOR_VERSION=folks_major_minor_version
  67 AC_SUBST([FOLKS_MAJOR_MINOR_VERSION])
  68
  69 API_VERSION=0.6
  70 AC_SUBST([API_VERSION])
  71
  72 AC_ARG_ENABLE(tracker-backend,
  73         AC_HELP_STRING([--enable-tracker-backend],
  74                        [ build the Tracker backend]),
  75         enable_tracker_backend=$enableval,
  76         enable_tracker_backend=no )
  77
  78 AM_CONDITIONAL([ENABLE_TRACKER], [test "x$enable_tracker_backend" = "xyes"])
  79
  80 AC_ARG_ENABLE(eds-backend,
  81         AC_HELP_STRING([--enable-eds-backend],
  82                        [ build the E-D-S backend]),
  83         enable_eds_backend=$enableval,
  84         enable_eds_backend=yes )
  85
  86 AM_CONDITIONAL([ENABLE_EDS], [test "x$enable_eds_backend" = "xyes"])
  87
  88 # Automatically check the dependencies for the libsocialweb backend
  89 SW_CLIENT_REQUIRED=0.25.15
  90 AC_ARG_ENABLE(libsocialweb-backend,
  91         AC_HELP_STRING([--enable-libsocialweb-backend=@<:@no/yes/auto@:>@],
  92                        [build the Libsocialweb backend (default: auto)]),
  93         enable_libsocialweb_backend=$enableval,
  94         enable_libsocialweb_backend=auto )
  95
  96 if test "x$enable_libsocialweb_backend" != "xno"; then
  97   PKG_CHECK_MODULES([SW_CLIENT], [libsocialweb-client >= $SW_CLIENT_REQUIRED],
  98       have_libsocialweb_backend="yes", have_libsocialweb_backend="no")
  99   if test "x$have_libsocialweb_backend" = "xyes" -a \
 100           "x$enable_vala" = "xyes"; then
 101     VALA_CHECK_PACKAGES([telepathy-glib
 102                          gio-2.0
 103                          gee-1.0
 104                          libsocialweb-client],
 105         ,
 106         have_libsocialweb_backend="no")
 107   fi
 108
 109   if test "x$have_libsocialweb_backend" = "xyes"; then
 110     AC_DEFINE(HAVE_LIBSOCIALWEB, [],
 111               [Define if you have the libsocialweb backend])
 112   fi
 113 else
 114    have_libsocialweb_backend=no
 115 fi
 116
 117 if test "x$enable_libsocialweb_backend" = "xyes" -a \
 118   "x$have_libsocialweb_backend" != "xyes"; then
 119     AC_MSG_ERROR([Cannot find libsocialweb dependencies.])
 120 fi
 121
 122 AM_CONDITIONAL([ENABLE_LIBSOCIALWEB],
 123         [test "x$have_libsocialweb_backend" = "xyes"])
 124
 125 # -----------------------------------------------------------
 126 # Dependencies
 127 # -----------------------------------------------------------
 128
 129 GLIB_REQUIRED=2.24.0
 130 TP_GLIB_REQUIRED=0.13.1
 131 VALA_REQUIRED=0.13.4
 132 VALADOC_REQUIRED=0.3.1
 133 TRACKER_SPARQL_MAJOR=0.12
 134 TRACKER_SPARQL_REQUIRED=0.12.0
 135 GCONF2_REQUIRED=2.31
 136 EBOOK_REQUIRED=3.1.5
 137 EDATASERVER_REQUIRED=3.1.5
 138
 139 PKG_CHECK_MODULES([GLIB],
 140                   [glib-2.0 >= $GLIB_REQUIRED
 141                    gobject-2.0 >= $GLIB_REQUIRED])
 142 PKG_CHECK_MODULES([GMODULE], [gmodule-no-export-2.0])
 143 PKG_CHECK_MODULES([GIO], [gio-2.0 >= $GLIB_REQUIRED])
 144 PKG_CHECK_MODULES([DBUS_GLIB], [dbus-glib-1])
 145 PKG_CHECK_MODULES([GCONF2], [gconf-2.0 >= $GCONF2_REQUIRED])
 146
 147 # FIXME: We depend on libgee < 0.7 because 0.7 breaks API. bgo#627746
 148 PKG_CHECK_MODULES([GEE], [gee-1.0 < 0.7],
 149                   have_gee_0_6_x="yes",
 150                   have_gee_0_6_x="no")
 151
 152 if test "x$have_gee_0_6_x" != "xyes"; then
 153     AC_MSG_ERROR([
 154 Gee 0.6.x required but not installed.
 155
 156 Note that Gee 0.8.x provides gee-0.8 (but gee-1.0 is, confusingly, provided by
 157 Gee 0.6.x)])
 158 fi
 159
 160 PKG_CHECK_MODULES([TP_GLIB], [telepathy-glib >= $TP_GLIB_REQUIRED])
 161
 162 if test x$enable_tracker_backend = xyes; then
 163         PKG_CHECK_MODULES([TRACKER_SPARQL],
 164                           [tracker-sparql-$TRACKER_SPARQL_MAJOR >= \
 165                            $TRACKER_SPARQL_REQUIRED])
 166 fi
 167
 168 if test x$enable_eds_backend = xyes; then
 169         PKG_CHECK_MODULES([EBOOK], [libebook-1.2 >= $EBOOK_REQUIRED])
 170         PKG_CHECK_MODULES([EDATASERVER], [libedataserver-1.2 >= $EDATASERVER_REQUIRED])
 171 fi
 172
 173 #
 174 # Vala building options -- allows tarball builds without installing Vala
 175 #
 176 AC_ARG_ENABLE([vala],
 177               AS_HELP_STRING([--enable-vala],
 178                              [Enable building from the Vala sources]),
 179               [enable_vala=$enableval],
 180               [enable_vala=no])
 181
 182 # will be re-set as necessary below
 183 AM_CONDITIONAL([HAVE_INTROSPECTION], [test "x$enable_vala" = "xyes"])
 184 sd=${srcdir}/
 185
 186 # Force Vala for non-release builds
 187 m4_if(folks_released, [1], [],
 188     [
 189         enable_vala=yes
 190         echo "Vala compiler required for non-release builds; requiring Vala..."
 191     ])
 192
 193 # Force Vala if generated source is missing or outdated
 194 if test \
 195         ! -e ${sd}tools/folks_import_vala.stamp -o \
 196         ! -e ${sd}tests/folks/abstract_field_details_vala.stamp -o \
 197         ! -e ${sd}tests/folks/aggregation_vala.stamp -o \
 198         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 199         ! -e ${sd}tests/key-file/individual_retrieval_vala.stamp -o \
 200         ! -e ${sd}tests/lib/folks-test.vapi -o \
 201         ! -e ${sd}tests/lib/key-file/kf-test.vapi -o \
 202         ! -e ${sd}tests/lib/key-file/libkf_test_la_vala.stamp -o \
 203         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.gir -o \
 204         ! -e ${sd}tests/lib/telepathy/contactlist/tp-test-contactlist.vapi -o \
 205         ! -e ${sd}tests/lib/libfolks_test_la_vala.stamp -o \
 206         ! -e ${sd}tests/telepathy/persona_store_capabilities_vala.stamp -o \
 207         ! -e ${sd}tests/telepathy/individual_retrieval_vala.stamp -o \
 208         ! -e ${sd}tests/telepathy/individual_properties_vala.stamp -o \
 209         ! -e ${sd}tests/folks/backend_loading_vala.stamp -o \
 210         ! -e ${sd}backends/key-file/key_file_la_vala.stamp -o \
 211         ! -e ${sd}backends/telepathy/telepathy_la_vala.stamp \
 212                 -o \
 213         ! -e ${sd}backends/telepathy/lib/folks-telepathy.vapi -o \
 214         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.gir -o \
 215         ! -e ${sd}backends/telepathy/lib/tp-lowlevel.vapi -o \
 216         ! -e ${sd}backends/telepathy/lib/libfolks_telepathy_la_vala.stamp -o \
 217         ! -e ${sd}folks/folks-internal.h -o \
 218         ! -e ${sd}folks/folks-internal.vapi -o \
 219         ! -e ${sd}folks/libfolks_internal_la_vala.stamp -o \
 220         ! -e ${sd}folks/folks.vapi -o \
 221         ! -e ${sd}folks/libfolks_la_vala.stamp ; then
 222         enable_vala=yes
 223         echo "Vala source needs to be re-compiled; requiring Vala..."
 224 fi
 225
 226 if test "x$enable_vala" = "xyes" ; then
 227         AM_PROG_VALAC([$VALA_REQUIRED])
 228         if test "x$VALAC" = "x"; then
 229               AC_MSG_ERROR([Vala requested but valac is not installed])
 230         fi
 231
 232         AC_PATH_PROG([VAPIGEN], [vapigen], [])
 233         if test "x$VAPIGEN" = "x"; then
 234               AC_MSG_ERROR([Vala must be built with --enable-vapigen])
 235         fi
 236
 237         # require GLib >= 2.24 so GLib.Array, etc. reffing is handled
 238         # automatically
 239         VALAFLAGS="$VALAFLAGS --target-glib=2.24"
 240         AC_SUBST([VALAFLAGS])
 241         AC_SUBST([VAPIGENFLAGS])
 242         AC_SUBST([VAPIDIR])
 243
 244         VALA_CHECK_PACKAGES([telepathy-glib
 245                              gio-2.0
 246                              gee-1.0])
 247
 248         if test x$enable_tracker_backend = xyes; then
 249           VALA_CHECK_PACKAGES([tracker-sparql-$TRACKER_SPARQL_MAJOR])
 250         fi
 251
 252         if test x$enable_eds_backend = xyes; then
 253           VALA_CHECK_PACKAGES([libebook-1.2 libedataserver-1.2 libxml-2.0])
 254         fi
 255 fi
 256
 257 # this will set HAVE_INTROSPECTION
 258 GOBJECT_INTROSPECTION_REQUIRE([0.9.12])
 259
 260 AM_CONDITIONAL([HAVE_VALA], [test "x$enable_vala" = "xyes"])
 261
 262 # Various functions that we need (used in C code generated from Vala)
 263 AC_CHECK_FUNCS([memset])
 264 AC_CHECK_FUNCS([strstr])
 265
 266 # -----------------------------------------------------------
 267 # Backends
 268 # -----------------------------------------------------------
 269
 270 FOLKS_MODULE_VERSION=folks_module_version
 271 AC_SUBST([FOLKS_MODULE_VERSION])
 272 AC_DEFINE([MODULE_VERSION], "folks_module_version", [Module interface version])
 273
 274 BACKEND_DIR='$(libdir)/folks/$(FOLKS_MODULE_VERSION)/backends'
 275 AC_SUBST([BACKEND_DIR])
 276
 277 BACKEND_KF='$(top_builddir)/backends/key-file/.libs/key-file.so'
 278 AC_SUBST([BACKEND_KF])
 279 BACKEND_TP='$(top_builddir)/backends/telepathy/.libs/telepathy.so'
 280 AC_SUBST([BACKEND_TP])
 281
 282 if test x$have_libsocialweb_backend = xyes; then
 283   BACKEND_LIBSOCIALWEB='$(top_builddir)/backends/libsocialweb/.libs/libsocialweb.so'
 284   AC_SUBST([BACKEND_LIBSOCIALWEB])
 285 fi
 286
 287 if test x$enable_tracker_backend = xyes; then
 288   BACKEND_TRACKER='$(top_builddir)/backends/tracker/.libs/tracker.so'
 289   AC_SUBST([BACKEND_TRACKER])
 290 fi
 291
 292 if test x$enable_eds_backend = xyes; then
 293   BACKEND_EDS='$(top_builddir)/backends/eds/.libs/eds.so'
 294   AC_SUBST([BACKEND_EDS])
 295 fi
 296
 297 # All of the backend libraries in our tree; to be used by the tests
 298 BACKEND_UNINST_PATH='$(BACKEND_KF):$(BACKEND_TP)'
 299 if test x$have_libsocialweb_backend = xyes; then
 300   LIBSOCIALWEB_BACKEND_UNINST_PATH='$(BACKEND_LIBSOCIALWEB)'
 301   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$LIBSOCIALWEB_BACKEND_UNINST_PATH"
 302 fi
 303 if test x$enable_tracker_backend = xyes; then
 304   TRACKER_BACKEND_UNINST_PATH='$(BACKEND_TRACKER)'
 305   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$TRACKER_BACKEND_UNINST_PATH"
 306 fi
 307 if test x$enable_eds_backend = xyes; then
 308   EDS_BACKEND_UNINST_PATH='$(BACKEND_EDS)'
 309   BACKEND_UNINST_PATH="$BACKEND_UNINST_PATH:$EDS_BACKEND_UNINST_PATH"
 310 fi
 311 AC_SUBST([BACKEND_UNINST_PATH])
 312
 313 # -----------------------------------------------------------
 314 # Tools
 315 # -----------------------------------------------------------
 316
 317 AC_ARG_ENABLE([import-tool],
 318               AS_HELP_STRING([--enable-import-tool],
 319                              [Enable building the meta-contact import tool]),
 320               [enable_import_tool=$enableval with_import_tool=$enableval],
 321               [enable_import_tool=maybe with_import_tool=no])
 322 AS_IF([test "$enable_import_tool" != "no"],
 323       [PKG_CHECK_MODULES([LIBXML], [libxml-2.0],
 324                          [with_import_tool=yes], [with_import_tool=no])])
 325 AS_IF([test "$enable_import_tool" = "yes" -a "$with_import_tool" = "no"],
 326       [AC_MSG_ERROR([Import tool explicitly enabled, but libxml2 not found])])
 327 AM_CONDITIONAL([ENABLE_IMPORT_TOOL], [test "$with_import_tool" = "yes"])
 328
 329 # Readline's required for the folks-inspect program
 330 AC_ARG_ENABLE([inspect-tool],
 331               AS_HELP_STRING([--enable-inspect-tool],
 332                              [Enable building the data inspection tool]),
 333               [enable_inspect_tool=$enableval with_inspect_tool=$enableval],
 334               [enable_inspect_tool=maybe with_inspect_tool=no])
 335 AS_IF([test "$enable_inspect_tool" = "yes" -a "$enable_vala" != "yes"],
 336       [AC_MSG_ERROR([Inspect tool explicitly enabled, but Vala wasn't enabled \
 337                      using --enable-vala])])
 338 AS_IF([test "$enable_inspect_tool" = "maybe" -a "$enable_vala" != "yes"],
 339       [AC_MSG_NOTICE([Inspect tool disabled, as Vala wasn't enabled using \
 340                       --enable-vala])])
 341 AS_IF([test "$enable_inspect_tool" != "no" -a "x$enable_vala" = "xyes"],
 342       [AC_CHECK_LIB([readline], [main],
 343                     [with_inspect_tool=yes], [with_inspect_tool=no],
 344                     [-lncurses])])
 345 AS_IF([test "$enable_inspect_tool" != "no" -a "$with_inspect_tool" = "yes" -a \
 346        "x$enable_vala" = "xyes"],
 347       [VALA_CHECK_PACKAGES([readline])
 348        LIBREADLINE="-lreadline -lncurses"
 349        AC_DEFINE([HAVE_LIBREADLINE], [1], [Define if you have libreadline])
 350        AC_SUBST([LIBREADLINE])])
 351 AS_IF([test "$enable_inspect_tool" = "yes" -a "$with_inspect_tool" = "no"],
 352       [AC_MSG_ERROR([Inspect tool explicitly enabled, but readline not found])])
 353 AM_CONDITIONAL([ENABLE_INSPECT_TOOL], [test "$with_inspect_tool" = "yes"])
 354
 355 # -----------------------------------------------------------
 356 # Documentation
 357 # -----------------------------------------------------------
 358
 359 AC_ARG_ENABLE([docs],
 360               AS_HELP_STRING([--enable-docs],[Enable documentation generation]),
 361               [enable_docs=$enableval], [enable_docs=no])
 362 AM_CONDITIONAL([ENABLE_DOCS], [test x$enable_docs = xyes])
 363
 364 have_valadoc=no
 365 if test x$enable_docs = xyes; then
 366   # make sure the library is new enough and the program exists
 367   PKG_CHECK_MODULES([VALADOC], [valadoc-1.0 >= $VALADOC_REQUIRED])
 368   AC_PATH_PROG([VALADOC], [valadoc], [:])
 369   AS_IF([test "$VALADOC" != :], have_valadoc=yes)
 370 fi
 371 AM_CONDITIONAL([HAVE_VALADOC], [test x$have_valadoc = xyes])
 372
 373 if test "x$enable_docs" = "xyes" -a "x$have_valadoc" != "xyes"; then
 374     AC_MSG_ERROR([Doc building requested but valadoc not installed.])
 375 fi
 376
 377 # -----------------------------------------------------------
 378 # Gettext
 379 # -----------------------------------------------------------
 380
 381 GETTEXT_PACKAGE=AC_PACKAGE_NAME
 382 AC_SUBST(GETTEXT_PACKAGE)
 383 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"], [Define the gettext package to be used])
 384 IT_PROG_INTLTOOL([0.35.0])
 385
 386 # -----------------------------------------------------------
 387 # Error flags
 388 # -----------------------------------------------------------
 389
 390 AS_COMPILER_FLAG([-Wall], [ERROR_CFLAGS="-Wall"], [ERROR_CFLAGS=""])
 391 AS_COMPILER_FLAG([-Werror], [werror=yes], [werror=no])
 392
 393 AC_ARG_ENABLE([debug],
 394               AS_HELP_STRING([--disable-debug],[compile without debug code]),
 395               [enable_debug=$enableval], [enable_debug=yes])
 396
 397 AC_ARG_ENABLE([Werror],
 398               AS_HELP_STRING([--disable-Werror],
 399                              [compile without -Werror (normally enabled in
 400                               development builds)]),
 401               [werror=$enableval], [werror=yes])
 402
 403 AS_COMPILER_FLAG([-Wextra], [wextra=yes], [wextra=no])
 404 AS_COMPILER_FLAG([-Wno-missing-field-initializers],
 405                  [wno_missing_field_initializers=yes],
 406                  [wno_missing_field_initializers=no])
 407 AS_COMPILER_FLAG([-Wno-unused-parameter],
 408                  [wno_unused_parameter=yes], [wno_unused_parameter=no])
 409
 410 m4_if(folks_released, [1], [],
 411     [
 412         if test x$werror = xyes; then
 413             ERROR_CFLAGS="$ERROR_CFLAGS -Werror"
 414         fi
 415         if test x$wextra = xyes -a \
 416             x$wno_missing_field_initializers = xyes -a \
 417             x$wno_unused_parameter = xyes; then
 418             ERROR_CFLAGS="$ERROR_CFLAGS -Wextra \
 419                 -Wno-missing-field-initializers -Wno-unused-parameter"
 420         fi
 421     ])
 422
 423 AS_COMPILER_FLAG([-D_POSIX_SOURCE], [ERROR_CFLAGS="$ERROR_CFLAGS -D_POSIX_SOURCE"])
 424 AS_COMPILER_FLAG([-std=c99], [ERROR_CFLAGS="$ERROR_CFLAGS -std=c99"])
 425 AS_COMPILER_FLAG([-Wshadow], [ERROR_CFLAGS="$ERROR_CFLAGS -Wshadow"])
 426 AS_COMPILER_FLAG([-Wmissing-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 427                                           -Wmissing-prototypes"])
 428 AS_COMPILER_FLAG([-Wmissing-declarations], [ERROR_CFLAGS="$ERROR_CFLAGS \
 429                                             -Wmissing-declarations"])
 430 AS_COMPILER_FLAG([-Wstrict-prototypes], [ERROR_CFLAGS="$ERROR_CFLAGS \
 431                                          -Wstrict-prototypes"])
 432
 433 AC_SUBST([ERROR_CFLAGS])
 434
 435 # Vala-related flags
 436 AS_IF([test "x$enable_vala" = "xyes"],
 437       [ERROR_INTROSPECTION_SCANNER_ARGS="\
 438                         $ERROR_INTROSPECTION_SCANNER_ARGS --warn-error"
 439        ERROR_VALAFLAGS="$ERROR_VALAFLAGS --fatal-warnings"])
 440
 441 m4_if(folks_released, [1], [],
 442     [
 443         ERROR_VALAFLAGS="$ERROR_VALAFLAGS -g"
 444     ])
 445
 446 AC_SUBST([ERROR_INTROSPECTION_SCANNER_ARGS])
 447 AC_SUBST([ERROR_VALAFLAGS])
 448
 449 # -----------------------------------------------------------
 450 # Final output
 451 # -----------------------------------------------------------
 452
 453 AC_CONFIG_FILES([
 454     backends/telepathy/lib/folks-telepathy.pc
 455     backends/telepathy/lib/folks-telepathy-uninstalled.pc
 456     backends/tracker/lib/folks-tracker.pc
 457     backends/tracker/lib/folks-tracker-uninstalled.pc
 458     backends/eds/lib/folks-eds.pc
 459     backends/eds/lib/folks-eds-uninstalled.pc
 460     folks/folks.pc
 461     folks/folks-uninstalled.pc
 462     Makefile
 463     backends/Makefile
 464     backends/key-file/Makefile
 465     backends/libsocialweb/Makefile
 466     backends/libsocialweb/lib/Makefile
 467     backends/libsocialweb/lib/folks-libsocialweb.pc
 468     backends/libsocialweb/lib/folks-libsocialweb-uninstalled.pc
 469     backends/telepathy/Makefile
 470     backends/telepathy/lib/Makefile
 471     backends/tracker/Makefile
 472     backends/tracker/lib/Makefile
 473     backends/eds/Makefile
 474     backends/eds/lib/Makefile
 475     folks/Makefile
 476     docs/Makefile
 477     po/Makefile.in
 478     tests/Makefile
 479     tests/data/Makefile
 480     tests/data/gconf.path
 481     tests/folks/Makefile
 482     tests/key-file/Makefile
 483     tests/libsocialweb/Makefile
 484     tests/telepathy/Makefile
 485     tests/tracker/Makefile
 486     tests/lib/Makefile
 487     tests/lib/folks-test-uninstalled.pc
 488     tests/lib/key-file/Makefile
 489     tests/lib/libsocialweb/Makefile
 490     tests/lib/libsocialweb/session.conf
 491     tests/eds/Makefile
 492     tests/lib/eds/Makefile
 493     tests/lib/telepathy/Makefile
 494     tests/lib/tracker/Makefile
 495     tests/lib/telepathy/contactlist/Makefile
 496     tests/lib/telepathy/contactlist/session.conf
 497     tests/tools/Makefile
 498     tools/Makefile
 499     tools/inspect/Makefile
 500 ])
 501
 502 AC_OUTPUT
 503
 504 echo "
 505 Configure summary:
 506
 507         Vala........................:  ${enable_vala}
 508         Vala Compiler...............:  ${VALAC}
 509         C Compiler Flags............:  ${CFLAGS} ${ERROR_CFLAGS}
 510         Prefix......................:  ${prefix}
 511         Bugreporting URL............:  ${PACKAGE_BUGREPORT}
 512         Documentation...............:  ${have_valadoc}
 513         Import tool.................:  ${with_import_tool}
 514         Inspector tool..............:  ${with_inspect_tool}
 515         Tracker backend.............:  ${enable_tracker_backend}
 516         Libsocialweb backend........:  ${have_libsocialweb_backend}
 517         E-D-S backend...............:  ${enable_eds_backend}
 518
 519 "