configure.ac

   1 AC_PREREQ(2.57)
   2
   3 dnl Version not hardcoded here. Fetched later from ares_version.h
   4 AC_INIT([c-ares], [-],
   5   [c-ares mailing list: http://cool.haxx.se/mailman/listinfo/c-ares])
   6
   7 CARES_OVERRIDE_AUTOCONF
   8
   9 AC_CONFIG_SRCDIR([ares_ipv6.h])
  10 AM_CONFIG_HEADER([ares_config.h ares_build.h])
  11 AC_CONFIG_MACRO_DIR([m4])
  12 AM_MAINTAINER_MODE
  13
  14 CARES_CHECK_OPTION_DEBUG
  15 CARES_CHECK_OPTION_OPTIMIZE
  16 CARES_CHECK_OPTION_WARNINGS
  17 CARES_CHECK_OPTION_WERROR
  18 CARES_CHECK_OPTION_CURLDEBUG
  19 CARES_CHECK_OPTION_SYMBOL_HIDING
  20
  21 CARES_CHECK_PATH_SEPARATOR_REQUIRED
  22
  23 dnl SED is mandatory for configure process and libtool.
  24 dnl Set it now, allowing it to be changed later.
  25 AC_PATH_PROG([SED], [sed], [not_found],
  26   [$PATH:/usr/bin:/usr/local/bin])
  27 if test -z "$SED" || test "$SED" = "not_found"; then
  28   AC_MSG_ERROR([sed not found in PATH. Cannot continue without sed.])
  29 fi
  30 AC_SUBST([SED])
  31
  32 dnl GREP is mandatory for configure process and libtool.
  33 dnl Set it now, allowing it to be changed later.
  34 AC_PATH_PROG([GREP], [grep], [not_found],
  35   [$PATH:/usr/bin:/usr/local/bin])
  36 if test -z "$GREP" || test "$GREP" = "not_found"; then
  37   AC_MSG_ERROR([grep not found in PATH. Cannot continue without grep.])
  38 fi
  39 AC_SUBST([GREP])
  40
  41 dnl EGREP is mandatory for configure process and libtool.
  42 dnl Set it now, allowing it to be changed later.
  43 if echo a | ($GREP -E '(a|b)') >/dev/null 2>&1; then
  44   AC_MSG_CHECKING([for egrep])
  45   EGREP="$GREP -E"
  46   AC_MSG_RESULT([$EGREP])
  47 else
  48   AC_PATH_PROG([EGREP], [egrep], [not_found],
  49     [$PATH:/usr/bin:/usr/local/bin])
  50 fi
  51 if test -z "$EGREP" || test "$EGREP" = "not_found"; then
  52   AC_MSG_ERROR([egrep not found in PATH. Cannot continue without egrep.])
  53 fi
  54 AC_SUBST([EGREP])
  55
  56 dnl AR is mandatory for configure process and libtool.
  57 dnl This is target dependent, so check it as a tool.
  58 AC_PATH_TOOL([AR], [ar], [not_found],
  59   [$PATH:/usr/bin:/usr/local/bin])
  60 if test -z "$AR" || test "$AR" = "not_found"; then
  61   AC_MSG_ERROR([ar not found in PATH. Cannot continue without ar.])
  62 fi
  63 AC_SUBST([AR])
  64
  65 dnl Remove non-configure distributed ares_build.h
  66 if test -f ${srcdir}/ares_build.h; then
  67   rm -f ${srcdir}/ares_build.h
  68 fi
  69
  70 AM_INIT_AUTOMAKE
  71
  72 dnl
  73 dnl Detect the canonical host and target build environment
  74 dnl
  75
  76 AC_CANONICAL_HOST
  77 dnl Get system canonical name
  78 AC_DEFINE_UNQUOTED(OS, "${host}", [cpu-machine-OS])
  79
  80 CARES_CHECK_PROG_CC
  81 AM_PROG_CC_C_O
  82 AC_PROG_INSTALL
  83
  84 dnl This defines _ALL_SOURCE for AIX
  85 CARES_CHECK_AIX_ALL_SOURCE
  86
  87 dnl Our configure and build reentrant settings
  88 CARES_CONFIGURE_THREAD_SAFE
  89 CARES_CONFIGURE_REENTRANT
  90
  91 dnl check for how to do large files
  92 AC_SYS_LARGEFILE
  93
  94 case $host_os in
  95   solaris*)
  96     AC_DEFINE(ETC_INET, 1, [if a /etc/inet dir is being used])
  97     ;;
  98 esac
  99
 100 dnl support building of Windows DLLs
 101 AC_LIBTOOL_WIN32_DLL
 102
 103 dnl force libtool to build static libraries with PIC on AMD64-Linux & FreeBSD
 104 AC_MSG_CHECKING([if arch-OS host is AMD64-Linux/FreeBSD (to build static libraries with PIC)])
 105 case $host in
 106   x86_64*linux*|amd64*freebsd*|ia64*freebsd*)
 107     AC_MSG_RESULT([yes])
 108     with_pic=yes
 109     ;;
 110   *)
 111     AC_MSG_RESULT([no])
 112     ;;
 113 esac
 114
 115 AC_MSG_CHECKING([if compiler is icc (to build with PIC)])
 116 case $CC in
 117   icc | */icc)
 118     AC_MSG_RESULT([yes])
 119     with_pic=yes
 120     ;;
 121   *)
 122     AC_MSG_RESULT([no])
 123     ;;
 124 esac
 125
 126 dnl libtool setup
 127 AC_PROG_LIBTOOL
 128
 129 AC_MSG_CHECKING([if we need CARES_BUILDING_LIBRARY])
 130 case $host in
 131   *-*-mingw*)
 132     AC_DEFINE(CARES_BUILDING_LIBRARY, 1, [when building c-ares library])
 133     AC_MSG_RESULT(yes)
 134     AC_MSG_CHECKING([if we need CARES_STATICLIB])
 135     if test "X$enable_shared" = "Xno"
 136     then
 137       AC_DEFINE(CARES_STATICLIB, 1, [when not building a shared library])
 138       AC_MSG_RESULT(yes)
 139     else
 140       AC_MSG_RESULT(no)
 141     fi
 142     ;;
 143   *)
 144     AC_MSG_RESULT(no)
 145     ;;
 146 esac
 147
 148 dnl **********************************************************************
 149 dnl platform/compiler/architecture specific checks/flags
 150 dnl **********************************************************************
 151
 152 CARES_CHECK_COMPILER
 153 CARES_SET_COMPILER_BASIC_OPTS
 154 CARES_SET_COMPILER_DEBUG_OPTS
 155 CARES_SET_COMPILER_OPTIMIZE_OPTS
 156 CARES_SET_COMPILER_WARNING_OPTS
 157
 158 if test "$compiler_id" = "INTEL_UNIX_C"; then
 159   #
 160   if test "$compiler_num" -ge "1000"; then
 161     dnl icc 10.X or later
 162     CFLAGS="$CFLAGS -shared-intel"
 163   elif test "$compiler_num" -ge "900"; then
 164     dnl icc 9.X specific
 165     CFLAGS="$CFLAGS -i-dynamic"
 166   fi
 167   #
 168 fi
 169
 170 CARES_CHECK_COMPILER_HALT_ON_ERROR
 171 CARES_CHECK_COMPILER_ARRAY_SIZE_NEGATIVE
 172 CARES_CHECK_COMPILER_SYMBOL_HIDING
 173
 174 CARES_CHECK_NO_UNDEFINED
 175 AM_CONDITIONAL(NO_UNDEFINED, test x$need_no_undefined = xyes)
 176
 177 CARES_CHECK_CURLDEBUG
 178 AM_CONDITIONAL(CURLDEBUG, test x$want_curldebug = xyes)
 179
 180 dnl **********************************************************************
 181 dnl Compilation based checks should not be done before this point.
 182 dnl **********************************************************************
 183
 184 dnl **********************************************************************
 185 dnl Make sure that our checks for headers windows.h winsock.h winsock2.h
 186 dnl and ws2tcpip.h take precedence over any other further checks which
 187 dnl could be done later using AC_CHECK_HEADER or AC_CHECK_HEADERS for
 188 dnl this specific header files. And do them before its results are used.
 189 dnl **********************************************************************
 190
 191 CURL_CHECK_HEADER_WINDOWS
 192 CURL_CHECK_NATIVE_WINDOWS
 193 case X-"$ac_cv_native_windows" in
 194   X-yes)
 195     CURL_CHECK_HEADER_WINSOCK
 196     CURL_CHECK_HEADER_WINSOCK2
 197     CURL_CHECK_HEADER_WS2TCPIP
 198     ;;
 199   *)
 200     ac_cv_header_winsock_h="no"
 201     ac_cv_header_winsock2_h="no"
 202     ac_cv_header_ws2tcpip_h="no"
 203     ;;
 204 esac
 205
 206 dnl **********************************************************************
 207 dnl Checks for libraries.
 208 dnl **********************************************************************
 209
 210 CARES_CHECK_LIB_XNET
 211
 212 dnl gethostbyname without lib or in the nsl lib?
 213 AC_CHECK_FUNC(gethostbyname,
 214               [HAVE_GETHOSTBYNAME="1"
 215               ],
 216               [ AC_CHECK_LIB(nsl, gethostbyname,
 217                              [HAVE_GETHOSTBYNAME="1"
 218                              LIBS="$LIBS -lnsl"
 219                              ])
 220               ])
 221
 222 if test "$HAVE_GETHOSTBYNAME" != "1"
 223 then
 224   dnl gethostbyname in the socket lib?
 225   AC_CHECK_LIB(socket, gethostbyname,
 226                [HAVE_GETHOSTBYNAME="1"
 227                LIBS="$LIBS -lsocket"
 228                ])
 229 fi
 230
 231 dnl At least one system has been identified to require BOTH nsl and socket
 232 dnl libs at the same time to link properly.
 233 if test "$HAVE_GETHOSTBYNAME" != "1"
 234 then
 235   AC_MSG_CHECKING([for gethostbyname with both nsl and socket libs])
 236   my_ac_save_LIBS=$LIBS
 237   LIBS="-lnsl -lsocket $LIBS"
 238   AC_LINK_IFELSE([
 239     AC_LANG_PROGRAM([[
 240     ]],[[
 241       gethostbyname();
 242     ]])
 243   ],[
 244     AC_MSG_RESULT([yes])
 245     HAVE_GETHOSTBYNAME="1"
 246   ],[
 247     AC_MSG_RESULT([no])
 248     LIBS=$my_ac_save_LIBS
 249   ])
 250 fi
 251
 252 if test "$HAVE_GETHOSTBYNAME" != "1"
 253 then
 254   dnl This is for winsock systems
 255   if test "$ac_cv_header_windows_h" = "yes"; then
 256     if test "$ac_cv_header_winsock_h" = "yes"; then
 257       case $host in
 258         *-*-mingw32ce*)
 259           winsock_LIB="-lwinsock"
 260           ;;
 261         *)
 262           winsock_LIB="-lwsock32"
 263           ;;
 264       esac
 265     fi
 266     if test "$ac_cv_header_winsock2_h" = "yes"; then
 267       winsock_LIB="-lws2_32"
 268     fi
 269     if test ! -z "$winsock_LIB"; then
 270       my_ac_save_LIBS=$LIBS
 271       LIBS="$winsock_LIB $LIBS"
 272       AC_MSG_CHECKING([for gethostbyname in $winsock_LIB])
 273       AC_LINK_IFELSE([
 274         AC_LANG_PROGRAM([[
 275 #ifdef HAVE_WINDOWS_H
 276 #ifndef WIN32_LEAN_AND_MEAN
 277 #define WIN32_LEAN_AND_MEAN
 278 #endif
 279 #include <windows.h>
 280 #ifdef HAVE_WINSOCK2_H
 281 #include <winsock2.h>
 282 #else
 283 #ifdef HAVE_WINSOCK_H
 284 #include <winsock.h>
 285 #endif
 286 #endif
 287 #endif
 288         ]],[[
 289           gethostbyname("www.dummysite.com");
 290         ]])
 291       ],[
 292         AC_MSG_RESULT([yes])
 293         HAVE_GETHOSTBYNAME="1"
 294       ],[
 295         AC_MSG_RESULT([no])
 296         winsock_LIB=""
 297         LIBS=$my_ac_save_LIBS
 298       ])
 299     fi
 300   fi
 301 fi
 302
 303 if test "$HAVE_GETHOSTBYNAME" != "1"
 304 then
 305   dnl This is for Minix 3.1
 306   AC_MSG_CHECKING([for gethostbyname for Minix 3])
 307   AC_LINK_IFELSE([
 308     AC_LANG_PROGRAM([[
 309 /* Older Minix versions may need <net/gen/netdb.h> here instead */
 310 #include <netdb.h>
 311     ]],[[
 312       gethostbyname("www.dummysite.com");
 313     ]])
 314   ],[
 315     AC_MSG_RESULT([yes])
 316     HAVE_GETHOSTBYNAME="1"
 317   ],[
 318     AC_MSG_RESULT([no])
 319   ])
 320 fi
 321
 322 if test "$HAVE_GETHOSTBYNAME" != "1"
 323 then
 324   dnl This is for eCos with a stubbed DNS implementation
 325   AC_MSG_CHECKING([for gethostbyname for eCos])
 326   AC_LINK_IFELSE([
 327     AC_LANG_PROGRAM([[
 328 #include <stdio.h>
 329 #include <netdb.h>
 330     ]],[[
 331       gethostbyname("www.dummysite.com");
 332     ]])
 333   ],[
 334     AC_MSG_RESULT([yes])
 335     HAVE_GETHOSTBYNAME="1"
 336   ],[
 337     AC_MSG_RESULT([no])
 338   ])
 339 fi
 340
 341 if test "$HAVE_GETHOSTBYNAME" != "1"
 342 then
 343   dnl gethostbyname in the net lib - for BeOS
 344   AC_CHECK_LIB(net, gethostbyname,
 345                [HAVE_GETHOSTBYNAME="1"
 346                LIBS="$LIBS -lnet"
 347                ])
 348 fi
 349
 350
 351 if test "$HAVE_GETHOSTBYNAME" != "1"; then
 352   AC_MSG_ERROR([couldn't find libraries for gethostbyname()])
 353 fi
 354
 355 dnl resolve lib?
 356 AC_CHECK_FUNC(strcasecmp, , [ AC_CHECK_LIB(resolve, strcasecmp) ])
 357
 358 if test "$ac_cv_lib_resolve_strcasecmp" = "$ac_cv_func_strcasecmp"; then
 359   AC_CHECK_LIB(resolve, strcasecmp,
 360               [LIBS="-lresolve $LIBS"],
 361                ,
 362                -lnsl)
 363 fi
 364 ac_cv_func_strcasecmp="no"
 365
 366 CARES_CHECK_LIBS_CONNECT
 367
 368 dnl **********************************************************************
 369 dnl In case that function clock_gettime with monotonic timer is available,
 370 dnl check for additional required libraries.
 371 dnl **********************************************************************
 372 CURL_CHECK_LIBS_CLOCK_GETTIME_MONOTONIC
 373
 374 AC_MSG_CHECKING([whether to use libgcc])
 375 AC_ARG_ENABLE(libgcc,
 376 AC_HELP_STRING([--enable-libgcc],[use libgcc when linking]),
 377 [ case "$enableval" in
 378   yes)
 379         LIBS="$LIBS -lgcc"
 380        AC_MSG_RESULT(yes)
 381        ;;
 382   *)   AC_MSG_RESULT(no)
 383        ;;
 384   esac ],
 385        AC_MSG_RESULT(no)
 386 )
 387
 388
 389 dnl Let's hope this split URL remains working:
 390 dnl http://publibn.boulder.ibm.com/doc_link/en_US/a_doc_lib/aixprggd/ \
 391 dnl genprogc/thread_quick_ref.htm
 392
 393
 394 dnl **********************************************************************
 395 dnl Back to "normal" configuring
 396 dnl **********************************************************************
 397
 398 dnl Checks for header files.
 399 AC_HEADER_STDC
 400
 401 CURL_CHECK_HEADER_MALLOC
 402 CURL_CHECK_HEADER_MEMORY
 403
 404 dnl check for a few basic system headers we need
 405 AC_CHECK_HEADERS(
 406        sys/types.h \
 407        sys/time.h \
 408        sys/select.h \
 409        sys/socket.h \
 410        sys/ioctl.h \
 411        sys/param.h \
 412        sys/uio.h \
 413        assert.h \
 414        netdb.h \
 415        netinet/in.h \
 416        netinet/tcp.h \
 417        net/if.h \
 418        errno.h \
 419        socket.h \
 420        strings.h \
 421        stdbool.h \
 422        time.h \
 423        limits.h \
 424        arpa/nameser.h \
 425        arpa/nameser_compat.h \
 426        arpa/inet.h,
 427 dnl to do if not found
 428 [],
 429 dnl to do if found
 430 [],
 431 dnl default includes
 432 [
 433 #ifdef HAVE_SYS_TYPES_H
 434 #include <sys/types.h>
 435 #endif
 436 #ifdef HAVE_SYS_TIME_H
 437 #include <sys/time.h>
 438 #endif
 439 dnl We do this default-include simply to make sure that the nameser_compat.h
 440 dnl header *REALLY* can be include after the new nameser.h. It seems AIX 5.1
 441 dnl (and others?) is not designed to allow this.
 442 #ifdef HAVE_ARPA_NAMESER_H
 443 #include <arpa/nameser.h>
 444 #endif
 445
 446 dnl *Sigh* these are needed in order for net/if.h to get properly detected.
 447 #ifdef HAVE_SYS_SOCKET_H
 448 #include <sys/socket.h>
 449 #endif
 450 #ifdef HAVE_NETINET_IN_H
 451 #include <netinet/in.h>
 452 #endif
 453 ]
 454 )
 455
 456 dnl Checks for typedefs, structures, and compiler characteristics.
 457 AC_C_CONST
 458 AC_TYPE_SIZE_T
 459 AC_HEADER_TIME
 460 CURL_CHECK_STRUCT_TIMEVAL
 461
 462 AC_CHECK_SIZEOF(size_t)
 463 AC_CHECK_SIZEOF(int)
 464 AC_CHECK_SIZEOF(long)
 465 AC_CHECK_SIZEOF(time_t)
 466
 467 AC_CHECK_TYPE(long long,
 468    [AC_DEFINE(HAVE_LONGLONG, 1,
 469      [Define to 1 if the compiler supports the 'long long' data type.])]
 470    longlong="yes"
 471 )
 472
 473 if test "xyes" = "x$longlong"; then
 474   AC_MSG_CHECKING([if numberLL works])
 475   AC_COMPILE_IFELSE([
 476     AC_LANG_PROGRAM([[
 477     ]],[[
 478       long long val = 1000LL;
 479     ]])
 480   ],[
 481     AC_MSG_RESULT([yes])
 482     AC_DEFINE(HAVE_LL, 1, [if your compiler supports LL])
 483   ],[
 484     AC_MSG_RESULT([no])
 485   ])
 486 fi
 487
 488
 489 # check for ssize_t
 490 AC_CHECK_TYPE(ssize_t, ,
 491    AC_DEFINE(ssize_t, int, [the signed version of size_t]))
 492
 493 # check for bool type
 494 AC_CHECK_TYPE([bool],[
 495   AC_DEFINE(HAVE_BOOL_T, 1,
 496     [Define to 1 if bool is an available type.])
 497 ], ,[
 498 #ifdef HAVE_SYS_TYPES_H
 499 #include <sys/types.h>
 500 #endif
 501 #ifdef HAVE_STDBOOL_H
 502 #include <stdbool.h>
 503 #endif
 504 ])
 505
 506 CARES_CONFIGURE_ARES_SOCKLEN_T
 507
 508 TYPE_IN_ADDR_T
 509
 510 TYPE_SOCKADDR_STORAGE
 511
 512 TYPE_SIG_ATOMIC_T
 513
 514 AC_TYPE_SIGNAL
 515
 516 CURL_CHECK_FUNC_RECV
 517 CURL_CHECK_FUNC_RECVFROM
 518 CURL_CHECK_FUNC_SEND
 519 CURL_CHECK_MSG_NOSIGNAL
 520
 521 CARES_CHECK_FUNC_CLOSESOCKET
 522 CARES_CHECK_FUNC_CLOSESOCKET_CAMEL
 523 CARES_CHECK_FUNC_CONNECT
 524 CARES_CHECK_FUNC_FCNTL
 525 CARES_CHECK_FUNC_FREEADDRINFO
 526 CARES_CHECK_FUNC_GETADDRINFO
 527 CARES_CHECK_FUNC_GETENV
 528 CARES_CHECK_FUNC_GETHOSTBYADDR
 529 CARES_CHECK_FUNC_GETHOSTBYNAME
 530 CARES_CHECK_FUNC_GETHOSTNAME
 531 CARES_CHECK_FUNC_GETSERVBYPORT_R
 532 CARES_CHECK_FUNC_INET_NET_PTON
 533 CARES_CHECK_FUNC_INET_NTOP
 534 CARES_CHECK_FUNC_INET_PTON
 535 CARES_CHECK_FUNC_IOCTL
 536 CARES_CHECK_FUNC_IOCTLSOCKET
 537 CARES_CHECK_FUNC_IOCTLSOCKET_CAMEL
 538 CARES_CHECK_FUNC_SETSOCKOPT
 539 CARES_CHECK_FUNC_SOCKET
 540 CARES_CHECK_FUNC_STRCASECMP
 541 CARES_CHECK_FUNC_STRCMPI
 542 CARES_CHECK_FUNC_STRDUP
 543 CARES_CHECK_FUNC_STRICMP
 544 CARES_CHECK_FUNC_STRNCASECMP
 545 CARES_CHECK_FUNC_STRNCMPI
 546 CARES_CHECK_FUNC_STRNICMP
 547 CARES_CHECK_FUNC_WRITEV
 548
 549
 550 dnl check for AF_INET6
 551 CARES_CHECK_CONSTANT(
 552   [
 553 #undef inline
 554 #ifdef HAVE_WINDOWS_H
 555 #ifndef WIN32_LEAN_AND_MEAN
 556 #define WIN32_LEAN_AND_MEAN
 557 #endif
 558 #include <windows.h>
 559 #ifdef HAVE_WINSOCK2_H
 560 #include <winsock2.h>
 561 #endif
 562 #else
 563 #ifdef HAVE_SYS_TYPES_H
 564 #include <sys/types.h>
 565 #endif
 566 #ifdef HAVE_SYS_SOCKET_H
 567 #include <sys/socket.h>
 568 #endif
 569 #endif
 570   ], [PF_INET6],
 571      AC_DEFINE_UNQUOTED(HAVE_PF_INET6,1,[Define to 1 if you have PF_INET6.])
 572 )
 573
 574 dnl check for PF_INET6
 575 CARES_CHECK_CONSTANT(
 576   [
 577 #undef inline
 578 #ifdef HAVE_WINDOWS_H
 579 #ifndef WIN32_LEAN_AND_MEAN
 580 #define WIN32_LEAN_AND_MEAN
 581 #endif
 582 #include <windows.h>
 583 #ifdef HAVE_WINSOCK2_H
 584 #include <winsock2.h>
 585 #endif
 586 #else
 587 #ifdef HAVE_SYS_TYPES_H
 588 #include <sys/types.h>
 589 #endif
 590 #ifdef HAVE_SYS_SOCKET_H
 591 #include <sys/socket.h>
 592 #endif
 593 #endif
 594   ], [AF_INET6],
 595      AC_DEFINE_UNQUOTED(HAVE_AF_INET6,1,[Define to 1 if you have AF_INET6.])
 596 )
 597
 598
 599 dnl check for the in6_addr structure
 600 CARES_CHECK_STRUCT(
 601   [
 602 #undef inline
 603 #ifdef HAVE_WINDOWS_H
 604 #ifndef WIN32_LEAN_AND_MEAN
 605 #define WIN32_LEAN_AND_MEAN
 606 #endif
 607 #include <windows.h>
 608 #ifdef HAVE_WINSOCK2_H
 609 #include <winsock2.h>
 610 #ifdef HAVE_WS2TCPIP_H
 611 #include <ws2tcpip.h>
 612 #endif
 613 #endif
 614 #else
 615 #ifdef HAVE_SYS_TYPES_H
 616 #include <sys/types.h>
 617 #endif
 618 #ifdef HAVE_NETINET_IN_H
 619 #include <netinet/in.h>
 620 #endif
 621 #endif
 622   ], [in6_addr],
 623      AC_DEFINE_UNQUOTED(HAVE_STRUCT_IN6_ADDR,1,[Define to 1 if you have struct in6_addr.])
 624 )
 625
 626 dnl check for the sockaddr_in6 structure
 627 CARES_CHECK_STRUCT(
 628   [
 629 #undef inline
 630 #ifdef HAVE_WINDOWS_H
 631 #ifndef WIN32_LEAN_AND_MEAN
 632 #define WIN32_LEAN_AND_MEAN
 633 #endif
 634 #include <windows.h>
 635 #ifdef HAVE_WINSOCK2_H
 636 #include <winsock2.h>
 637 #ifdef HAVE_WS2TCPIP_H
 638 #include <ws2tcpip.h>
 639 #endif
 640 #endif
 641 #else
 642 #ifdef HAVE_SYS_TYPES_H
 643 #include <sys/types.h>
 644 #endif
 645 #ifdef HAVE_NETINET_IN_H
 646 #include <netinet/in.h>
 647 #endif
 648 #endif
 649   ], [sockaddr_in6],
 650      AC_DEFINE_UNQUOTED(HAVE_STRUCT_SOCKADDR_IN6,1,
 651        [Define to 1 if you have struct sockaddr_in6.]) ac_have_sockaddr_in6=yes
 652 )
 653
 654 AC_CHECK_MEMBER(struct sockaddr_in6.sin6_scope_id,
 655     AC_DEFINE_UNQUOTED(HAVE_SOCKADDR_IN6_SIN6_SCOPE_ID,1,
 656       [Define to 1 if your struct sockaddr_in6 has sin6_scope_id.])
 657    , ,
 658   [
 659 #undef inline
 660 #ifdef HAVE_WINDOWS_H
 661 #ifndef WIN32_LEAN_AND_MEAN
 662 #define WIN32_LEAN_AND_MEAN
 663 #endif
 664 #include <windows.h>
 665 #ifdef HAVE_WINSOCK2_H
 666 #include <winsock2.h>
 667 #ifdef HAVE_WS2TCPIP_H
 668 #include <ws2tcpip.h>
 669 #endif
 670 #endif
 671 #else
 672 #ifdef HAVE_SYS_TYPES_H
 673 #include <sys/types.h>
 674 #endif
 675 #ifdef HAVE_NETINET_IN_H
 676 #include <netinet/in.h>
 677 #endif
 678 #endif
 679   ])
 680
 681 dnl check for the addrinfo structure
 682 AC_CHECK_MEMBER(struct addrinfo.ai_flags,
 683      AC_DEFINE_UNQUOTED(HAVE_STRUCT_ADDRINFO,1,
 684        [Define to 1 if you have struct addrinfo.]),,
 685   [
 686 #undef inline
 687 #ifdef HAVE_WINDOWS_H
 688 #ifndef WIN32_LEAN_AND_MEAN
 689 #define WIN32_LEAN_AND_MEAN
 690 #endif
 691 #include <windows.h>
 692 #ifdef HAVE_WINSOCK2_H
 693 #include <winsock2.h>
 694 #ifdef HAVE_WS2TCPIP_H
 695 #include <ws2tcpip.h>
 696 #endif
 697 #endif
 698 #else
 699 #ifdef HAVE_SYS_TYPES_H
 700 #include <sys/types.h>
 701 #endif
 702 #ifdef HAVE_NETINET_IN_H
 703 #include <netinet/in.h>
 704 #endif
 705 #ifdef HAVE_SYS_SOCKET_H
 706 #include <sys/socket.h>
 707 #endif
 708 #ifdef HAVE_NETDB_H
 709 #include <netdb.h>
 710 #endif
 711 #endif
 712   ]
 713 )
 714
 715
 716 AC_CHECK_FUNCS([bitncmp \
 717   gettimeofday \
 718   if_indextoname
 719 ],[
 720 ],[
 721   func="$ac_func"
 722   AC_MSG_CHECKING([deeper for $func])
 723   AC_LINK_IFELSE([
 724     AC_LANG_PROGRAM([[
 725     ]],[[
 726       $func ();
 727     ]])
 728   ],[
 729     AC_MSG_RESULT([yes])
 730     eval "ac_cv_func_$func=yes"
 731     AC_DEFINE_UNQUOTED(AS_TR_CPP([HAVE_$func]), [1],
 732       [Define to 1 if you have the $func function.])
 733   ],[
 734     AC_MSG_RESULT([but still no])
 735   ])
 736 ])
 737
 738
 739 AC_CHECK_SIZEOF(struct in6_addr, ,
 740 [
 741 #undef inline
 742 #ifdef HAVE_WINDOWS_H
 743 #ifndef WIN32_LEAN_AND_MEAN
 744 #define WIN32_LEAN_AND_MEAN
 745 #endif
 746 #include <windows.h>
 747 #ifdef HAVE_WINSOCK2_H
 748 #include <winsock2.h>
 749 #ifdef HAVE_WS2TCPIP_H
 750 #include <ws2tcpip.h>
 751 #endif
 752 #endif
 753 #else
 754 #ifdef HAVE_SYS_TYPES_H
 755 #include <sys/types.h>
 756 #endif
 757 #ifdef HAVE_SYS_SOCKET_H
 758 #include <sys/socket.h>
 759 #endif
 760 #ifdef HAVE_NETINET_IN_H
 761 #include <netinet/in.h>
 762 #endif
 763 #endif
 764 ]
 765 )
 766
 767 AC_CHECK_SIZEOF(struct in_addr, ,
 768 [
 769 #undef inline
 770 #ifdef HAVE_WINDOWS_H
 771 #ifndef WIN32_LEAN_AND_MEAN
 772 #define WIN32_LEAN_AND_MEAN
 773 #endif
 774 #include <windows.h>
 775 #ifdef HAVE_WINSOCK2_H
 776 #include <winsock2.h>
 777 #ifdef HAVE_WS2TCPIP_H
 778 #include <ws2tcpip.h>
 779 #endif
 780 #endif
 781 #else
 782 #ifdef HAVE_SYS_TYPES_H
 783 #include <sys/types.h>
 784 #endif
 785 #ifdef HAVE_SYS_SOCKET_H
 786 #include <sys/socket.h>
 787 #endif
 788 #ifdef HAVE_NETINET_IN_H
 789 #include <netinet/in.h>
 790 #endif
 791 #endif
 792 ]
 793 )
 794
 795
 796 dnl Check if the getnameinfo function is available
 797 dnl and get the types of five of its arguments.
 798 CURL_CHECK_FUNC_GETNAMEINFO
 799
 800
 801 AC_C_BIGENDIAN(
 802     [AC_DEFINE(ARES_BIG_ENDIAN, 1,
 803       [define this if ares is built for a big endian system])],
 804     ,
 805     [AC_MSG_WARN([couldn't figure out endianess, assuming little endian!])]
 806 )
 807
 808 dnl Check for user-specified random device
 809 AC_ARG_WITH(random,
 810 AC_HELP_STRING([--with-random=FILE],
 811                [read randomness from FILE (default=/dev/urandom)]),
 812     [ RANDOM_FILE="$withval" ],
 813     [
 814         dnl Check for random device.  If we're cross compiling, we can't
 815         dnl check, and it's better to assume it doesn't exist than it is
 816         dnl to fail on AC_CHECK_FILE or later.
 817         if test "$cross_compiling" = "no"; then
 818           AC_CHECK_FILE("/dev/urandom", [ RANDOM_FILE="/dev/urandom"] )
 819         else
 820           AC_MSG_WARN([cannot check for /dev/urandom while cross compiling; assuming none])
 821         fi
 822
 823     ]
 824 )
 825 if test -n "$RANDOM_FILE" && test X"$RANDOM_FILE" != Xno ; then
 826         AC_SUBST(RANDOM_FILE)
 827         AC_DEFINE_UNQUOTED(RANDOM_FILE, "$RANDOM_FILE",
 828         [a suitable file/device to read random data from])
 829 fi
 830
 831 CARES_CHECK_OPTION_NONBLOCKING
 832 CARES_CHECK_NONBLOCKING_SOCKET
 833
 834 CARES_CONFIGURE_SYMBOL_HIDING
 835
 836 CARES_PRIVATE_LIBS="$LIBS"
 837 AC_SUBST(CARES_PRIVATE_LIBS)
 838
 839 CARES_CFLAG_EXTRAS=""
 840 if test X"$want_werror" = Xyes; then
 841   CARES_CFLAG_EXTRAS="-Werror"
 842 fi
 843 AC_SUBST(CARES_CFLAG_EXTRAS)
 844
 845 dnl squeeze whitespace out of some variables
 846
 847 squeeze CFLAGS
 848 squeeze CPPFLAGS
 849 squeeze DEFS
 850 squeeze LDFLAGS
 851 squeeze LIBS
 852
 853 squeeze CARES_PRIVATE_LIBS
 854
 855 AC_CONFIG_FILES([Makefile libcares.pc])
 856 AC_OUTPUT