configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.12.0a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([dist-xz filename-length-max=99 color-tests
  43                   parallel-tests silent-rules no-define no-dependencies])
  44
  45 ## Keep this on a line of its own, since it must be found and processed
  46 ## by the 'update-copyright' rule in our Makefile.
  47 RELEASE_YEAR=2012
  48 AC_SUBST([RELEASE_YEAR])
  49
  50 # The API version is the base version.  We must guarantee
  51 # compatibility for all releases with the same API version.
  52 # Our current rule is that:
  53 # * All releases, including the prereleases, in an X.Y series
  54 #   are compatible.  So 1.5.1c is compatible with 1.5.
  55 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  56 #   aren't the same.
  57 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  58 AC_SUBST([APIVERSION])
  59
  60 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  61 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  62 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  63 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  64 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  65
  66 # $AUTOMAKE and $ACLOCAL are always run after a "cd $top_srcdir",
  67 # hence '.' is really what we want for perllibdir, libdir, and acdir.
  68 ACLOCAL="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" --acdir=m4 -I m4"
  69 AUTOMAKE="perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" --libdir=lib"
  70
  71 AC_PATH_PROG([PERL], [perl])
  72 if test -z "$PERL"; then
  73    AC_MSG_ERROR([perl not found])
  74 fi
  75 # Save details about the selected perl interpreter in config.log.
  76 AM_RUN_LOG([$PERL --version])
  77 $PERL -e 'require 5.006;' || {
  78    AC_MSG_ERROR(
  79 [perl 5.6 or better is required; perl 5.8.2 or better
  80 is recommended.  If you have several perl versions
  81 installed, select the one Automake should use using
  82   ./configure PERL=/path/to/perl])
  83 }
  84
  85 # We require ithreads support, and version 5.7.2 for CLONE.
  86 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  87 [if $PERL -e '
  88     require 5.007_002;
  89     use Config;
  90     if ($Config{useithreads})
  91       {
  92         require threads;
  93         import threads;
  94         require Thread::Queue;
  95         import Thread::Queue;
  96         exit 0;
  97       }
  98     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
  99 then
 100   am_cv_prog_PERL_ithreads=yes
 101 else
 102   am_cv_prog_PERL_ithreads=no
 103 fi])
 104 if test $am_cv_prog_PERL_ithreads = yes; then
 105   PERL_THREADS=1;
 106 else
 107   PERL_THREADS=0;
 108 fi
 109 AC_SUBST([PERL_THREADS])
 110
 111 # The test suite will skip some tests if tex is absent.
 112 AC_CHECK_PROG([TEX], [tex], [tex])
 113 # Save details about the selected TeX program in config.log.
 114 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 115 # for input from the terminal.
 116 AM_RUN_LOG([$TEX --version </dev/null])
 117
 118 # The test suite will skip some tests if no lex or yacc program is
 119 # available.
 120 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 121 #  1. we don't want flex (resp. bison) to be preferred to system lex
 122 #     (resp. system yacc);
 123 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 124 #     by default;
 125 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 126 #     LEXLIB to be calculated and/or AC_SUBST'd;
 127 #  4. we prefer that the YACC and LEX variables are not reported in the
 128 #     configure help screen.
 129 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 130 AC_CHECK_PROGS([LEX], [lex flex], [false])
 131
 132 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 133 # deletion of any files created (such as those added to
 134 # autom4te.cache).  We used to perform only the last of the three
 135 # following tests, but some users were unable to figure out that their
 136 # installation was broken since --version appeared to work.
 137
 138 required_autoconf_version=2.62
 139 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 140 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 141 then
 142   am_cv_autoconf_installed=yes
 143 else
 144   am_cv_autoconf_installed=no
 145 fi])
 146 if test "$am_cv_autoconf_installed" = no; then
 147   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 148     Please make sure it is installed and in your PATH.])
 149 fi
 150
 151 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 152 [mkdir conftest
 153 echo 'AC''_INIT' > conftest/conftest.ac
 154 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 155 then
 156   am_cv_autoconf_works=yes
 157 else
 158   am_cv_autoconf_works=no
 159 fi
 160 rm -rf conftest])
 161 if test "$am_cv_autoconf_works" = no; then
 162   AC_MSG_ERROR([The installed version of autoconf does not work.
 163     Please check config.log for error messages before this one.])
 164 fi
 165
 166 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 167 [mkdir conftest
 168 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 169 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 170 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 171 then
 172   am_cv_autoconf_version=yes
 173 else
 174   am_cv_autoconf_version=no
 175 fi
 176 rm -rf conftest])
 177 if test "$am_cv_autoconf_version" = no; then
 178   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 179 fi
 180
 181 # Test for ln.  We need use it to install the versioned binaries.
 182 AC_MSG_CHECKING([whether ln works])
 183 AC_CACHE_VAL([am_cv_prog_ln], [
 184 rm -f conftest conftest.file
 185 : >conftest.file
 186 if ln conftest.file conftest 2>/dev/null; then
 187   am_cv_prog_ln=ln
 188 else
 189   am_cv_prog_ln='cp -p'
 190 fi
 191 rm -f conftest conftest.file])
 192 AC_SUBST([LN], [$am_cv_prog_ln])
 193 result=no
 194 test "x$am_cv_prog_ln" = xln && result=yes
 195 AC_MSG_RESULT([$result])
 196
 197 # The amount we should wait after modifying files depends on the platform.
 198 # On Windows '95, '98 and ME, files modifications have 2-seconds
 199 # granularity and can be up to 3 seconds in the future w.r.t. the
 200 # system clock.  When it is important to ensure one file is older
 201 # than another we wait at least 5 seconds between creations.
 202 case $build in
 203   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 204   *)               MODIFICATION_DELAY=2;;
 205 esac
 206 AC_SUBST([MODIFICATION_DELAY])
 207
 208 # Test for things needed by the test suite.
 209 AC_PROG_EGREP
 210 AC_PROG_FGREP
 211
 212 # Shell used to run our test scripts.  The same as $SHELL/$CONFIG_SHELL
 213 # for the moment.
 214 AC_SUBST([AM_TEST_RUNNER_SHELL], [$SHELL])
 215
 216 AC_CACHE_CHECK([whether $SHELL has working 'set -e' with exit trap],
 217 [am_cv_sh_errexit_works],
 218 [if $SHELL -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 219 then
 220   am_cv_sh_errexit_works=yes
 221 else
 222   am_cv_sh_errexit_works=no
 223 fi
 224 ])
 225 if test $am_cv_sh_errexit_works = no; then
 226   AC_MSG_WARN(["${MAKE-make} check" will leave leftover directories t/*.dir])
 227   AC_MSG_WARN([you can clean them up manually using "${MAKE-make} clean" or])
 228   AC_MSG_WARN(["cd t && ${MAKE-make} clean-local-check'])
 229 fi
 230 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 231
 232
 233 ###########################################################################
 234
 235 # Look for C, C++ and fortran compilers to be used in the testsuite.
 236
 237 dnl We don't want to abort our configuration script if no C compiler is
 238 dnl available, as such a compiler is only required to run part of the
 239 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 240 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 241 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 242
 243 dnl We want the body of this macro to expand as a single shell statement,
 244 dnl thus we wrap it into { ... } brackets.
 245 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 246   AC_MSG_WARN([$1])
 247   am__failed=yes
 248   break
 249 } ])
 250
 251 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 252   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 253   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 254   am__failed=no
 255   while :; do
 256      $1
 257      break
 258   done
 259   AS_IF([test $am__failed = yes], [$2])
 260   # We have to clear these cache variables, so that future checks on
 261   # compilers for different languages won't be confused.
 262   unset ac_cv_objext ac_cv_exeext
 263   # We also need to meddle with the autoconf internals to ensure that
 264   # checks to find object and executable extensions will be run anew.
 265   # FIXME: In the long run, the better thing to do would be to fix
 266   # FIXME: autoconf instead ...
 267   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 268   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 269   m4_popdef([AC_MSG_FAILURE])
 270   m4_popdef([AC_MSG_ERROR])
 271 ])
 272
 273 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 274   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 275
 276 # Prefer generic compilers to GNU ones when possible.  This will ensure
 277 # more testsuite coverage "in the wild".
 278 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 279 # deliberate; for more discussion and rationale, see:
 280 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 281
 282 AC_MSG_NOTICE([will now look for generic compilers])
 283
 284 # C compiler.
 285 _AM_COMPILER_CAN_FAIL(dnl
 286   [AC_PROG_CC([cc gcc])],
 287   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 288
 289 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 290
 291 # The list of C++ compilers here has been copied, pasted and edited
 292 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 293 # Keep it in sync, or better again, find out a way to avoid this code
 294 # duplication.
 295 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 296   [aCC CC FCC KCC RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 297   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 298
 299 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 300
 301 # The lists of Fortran compilers here has been copied, pasted and edited
 302 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 303 # Keep it in sync, or better again, find out a way to avoid this code
 304 # duplication.
 305
 306 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 307   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 308   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 309   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 310
 311 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 312
 313 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 314   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 315   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 316
 317 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 318
 319 # Some tests will need the GNU compilers.  Searching for them here would
 320 # be overkill, since our testsuite already handles their search and setup
 321 # pretty well.  But in case the compilers already found are the GNU ones,
 322 # we want to use them in the testsuite where GNU compilers are required.
 323 # Also, in case the compilers detected above (at configure time) are not
 324 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 325 # FFLAGS detected for them with the GNU compilers too, since it's likely
 326 # they won't be compatible.  So we allow the user to define variants of
 327 # these variables for the GNU compilers separately.
 328
 329 AC_MSG_NOTICE([will now look for GNU compilers])
 330
 331 # GNU C compiler.
 332 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 333 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 334 if test $am_CC_is_GNU = yes; then
 335   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 336   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 337 else
 338   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 339 fi
 340 AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 341       [AC_MSG_WARN([botched installation for GNU C compiler])
 342        _AM_SKIP_COMP_TESTS([GNU C])])
 343
 344 # GNU C++ compiler.
 345 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 346 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 347 if test $am_CXX_is_GNU = yes; then
 348   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 349   GNU_CXX=$CXX
 350   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 351 else
 352   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 353 fi
 354 AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 355       [AC_MSG_WARN([botched installation for GNU C++ compiler])
 356        _AM_SKIP_COMP_TESTS([GNU C++])])
 357
 358 # GNU Fortran compiler.
 359 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 360 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 361 if test $am_FC_is_GNU = yes; then
 362   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 363   GNU_FC=$FC
 364   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 365 else
 366   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 367 fi
 368 AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 369       [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 370        _AM_SKIP_COMP_TESTS([GNU Fortran])])
 371
 372 # GNU Fortran 77 compiler.
 373 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 374 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 375 if test $am_F77_is_GNU = yes; then
 376   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 377   GNU_F77=$F77
 378   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 379 else
 380   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 381 fi
 382 AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 383       [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 384       _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 385
 386 # GNU Java compiler.
 387 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 388 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 389 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 390 AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 391       [AC_MSG_WARN([botched installation for GNU Java compiler])
 392       _AM_SKIP_COMP_TESTS([GNU Java])])
 393
 394 # If we have been able to find at least a working compiler above, we
 395 # know what the object and executable extensions for this platform are.
 396 OBJEXT=${ac_cv_objext-UNKNOWN}
 397 EXEEXT=${ac_cv_exeext-UNKNOWN}
 398 AC_SUBST([OBJEXT])
 399 AC_SUBST([EXEEXT])
 400
 401 ###########################################################################
 402
 403 AC_CONFIG_FILES([Makefile])
 404
 405 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 406 AC_CONFIG_LINKS([defs:defs])
 407
 408 AC_CONFIG_FILES([t/wrap/aclocal-${APIVERSION}:t/wrap/aclocal.in],
 409                 [chmod +x t/wrap/aclocal-${APIVERSION}],
 410                 [APIVERSION=$APIVERSION])
 411 AC_CONFIG_FILES([t/wrap/automake-${APIVERSION}:t/wrap/automake.in],
 412                 [chmod +x t/wrap/automake-${APIVERSION}],
 413                 [APIVERSION=$APIVERSION])
 414
 415 AC_OUTPUT
 416
 417 # Inform the user if this version of automake is a beta release or
 418 # a development snapshot.
 419 # According to HACKING, the version of a development snapshot should
 420 # end with an "odd" letter (a, c, ...), the version of a test release
 421 # should end wit an "even" letter (b, d, ...).
 422
 423 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 424 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 425
 426 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 427   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 428   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 429   { print \"development snapshot\"; }"]`
 430
 431 test "$am_release_type" = stable || cat <<EOF
 432
 433 WARNING: You are about to use a $am_release_type of automake.
 434 WARNING: It might easily suffer from new bugs or regressions.
 435 WARNING: You are strongly advised not to use it in production code.
 436
 437 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
 438 EOF
 439
 440 AS_EXIT([0])