configure.ac

   1 AC_PREREQ(2.65)
   2 AC_CONFIG_MACRO_DIR([m4])
   3
   4 AC_INIT([glib-networking],[2.37.4],[http://bugzilla.gnome.org/enter_bug.cgi?product=glib&component=network])
   5
   6 AC_CONFIG_SRCDIR([proxy/libproxy/glibproxyresolver.h])
   7 AC_CONFIG_HEADERS([config.h])
   8
   9 dnl Other initialization
  10 AM_INIT_AUTOMAKE([1.11 no-dist-gzip dist-xz -Wno-portability])
  11 AM_MAINTAINER_MODE([enable])
  12 AM_SILENT_RULES([yes])
  13 LT_INIT
  14
  15 dnl Checks for programs.
  16 AC_PROG_CC
  17 AM_PROG_CC_C_O
  18 AC_PROG_CPP
  19
  20 dnl Checks for libraries.
  21
  22 dnl ****************************
  23 dnl *** Checks for intltool  ***
  24 dnl ****************************
  25
  26 IT_PROG_INTLTOOL([0.35.0])
  27 GETTEXT_PACKAGE=glib-networking
  28
  29 AC_SUBST([GETTEXT_PACKAGE])
  30 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],["$GETTEXT_PACKAGE"],[The gettext domain name])
  31 AM_GLIB_GNU_GETTEXT
  32
  33 dnl *****************************
  34 dnl *** Check GLib GIO        ***
  35 dnl *****************************
  36 AM_PATH_GLIB_2_0(2.35.8,,AC_MSG_ERROR(GLIB not found),gio)
  37 GLIB_CFLAGS="$GLIB_CFLAGS -DGLIB_VERSION_MIN_REQUIRED=GLIB_VERSION_2_36"
  38
  39 GIO_MODULE_DIR=$($PKG_CONFIG --variable giomoduledir gio-2.0)
  40 AS_IF([test "x$GIO_MODULE_DIR" = "x"],
  41       [AC_MSG_FAILURE(GIO_MODULE_DIR is missing from gio-2.0.pc)])
  42 AC_SUBST(GIO_MODULE_DIR)
  43
  44 AC_PATH_PROG(GIO_QUERYMODULES, gio-querymodules)
  45 AC_SUBST(GIO_QUERYMODULES)
  46
  47 GLIB_TESTS
  48
  49 dnl *****************************
  50 dnl *** Checks for LibProxy   ***
  51 dnl *****************************
  52
  53 AC_ARG_WITH(libproxy,
  54     [AC_HELP_STRING([--with-libproxy],
  55                     [support for libproxy @<:@default=check@:>@])],
  56     [],
  57     [with_libproxy=check])
  58 AS_IF([test "x$with_libproxy" != "xno"],
  59     [PKG_CHECK_MODULES(LIBPROXY, [libproxy-1.0 >= 0.3.1],
  60         [with_libproxy=yes; proxy_support=libproxy],
  61         [AS_IF([test "x$with_libproxy" = "xyes"],
  62                [AC_MSG_FAILURE("$LIBPROXY_PKG_ERRORS")])])])
  63 AM_CONDITIONAL(HAVE_LIBPROXY, [test "x$with_libproxy" = "xyes"])
  64 AC_SUBST(LIBPROXY_CFLAGS)
  65 AC_SUBST(LIBPROXY_LIBS)
  66
  67 dnl **************************************
  68 dnl *** Checks for GNOME proxy backend ***
  69 dnl **************************************
  70 AC_ARG_WITH(gnome-proxy,
  71     [AC_HELP_STRING([--with-gnome-proxy],
  72                     [support for GNOME proxy configuration @<:@default=check@:>@])],
  73     [],
  74     [with_gnome_proxy=check])
  75 AS_IF([test "x$with_gnome_proxy" != "xno"],
  76     [PKG_CHECK_MODULES(GSETTINGS_DESKTOP_SCHEMAS, [gsettings-desktop-schemas],
  77         [with_gnome_proxy=yes; proxy_support="gnome $proxy_support"],
  78         [AS_IF([test "x$with_gnome_proxy" = "xyes"],
  79                [AC_MSG_FAILURE("$GSETTINGS_DESKTOP_SCHEMAS_PKG_ERRORS")])])])
  80 AM_CONDITIONAL(HAVE_GNOME_PROXY, [test "x$with_gnome_proxy" = "xyes"])
  81 AC_SUBST(GSETTINGS_DESKTOP_SCHEMAS_CFLAGS)
  82
  83 dnl *****************************
  84 dnl *** Checks for GNUTLS     ***
  85 dnl *****************************
  86
  87 GNUTLS_MIN_REQUIRED=2.12.8
  88
  89 AC_ARG_WITH(gnutls,
  90     [AC_HELP_STRING([--with-gnutls],
  91                     [support for GNUTLS @<:@default=yes@:>@])],
  92     [],
  93     [with_gnutls=yes])
  94 if test "x$with_gnutls" != "xno"; then
  95         PKG_CHECK_MODULES(GNUTLS,
  96                           [gnutls >= $GNUTLS_MIN_REQUIRED],
  97                           [with_gnutls=yes
  98                            tls_support="${tls_support}gnutls "],
  99                           [AS_IF([test "x$with_gnutls" = "xyes"],
 100                                  [AC_MSG_FAILURE("$GNUTLS_PKG_ERRORS")])])
 101 fi
 102 AM_CONDITIONAL(HAVE_GNUTLS, [test "x$with_gnutls" = "xyes"])
 103 AC_SUBST(GNUTLS_CFLAGS)
 104 AC_SUBST(GNUTLS_LIBS)
 105
 106 if test "x$with_gnutls" = "xyes"; then
 107     AC_MSG_CHECKING([location of system Certificate Authority list])
 108     AC_ARG_WITH(ca-certificates,
 109                 [AC_HELP_STRING([--with-ca-certificates=@<:@path@:>@],
 110                                 [path to system Certificate Authority list])])
 111     if test "$with_ca_certificates" = "no"; then
 112         AC_MSG_RESULT([disabled])
 113     else
 114         if test -z "$with_ca_certificates"; then
 115             for f in /etc/pki/tls/certs/ca-bundle.crt \
 116                      /etc/ssl/certs/ca-certificates.crt \
 117                      /etc/ssl/ca-bundle.pem; do
 118                 if test -f "$f"; then
 119                     with_ca_certificates="$f"
 120                 fi
 121             done
 122             if test -z "$with_ca_certificates"; then
 123                 AC_MSG_ERROR([could not find. Use --with-ca-certificates=path to set, or --without-ca-certificates to disable])
 124             fi
 125         fi
 126
 127         AC_MSG_RESULT($with_ca_certificates)
 128         AC_DEFINE_UNQUOTED(GTLS_SYSTEM_CA_FILE, ["$with_ca_certificates"], [The system TLS CA list])
 129     fi
 130 fi
 131
 132 dnl *****************************
 133 dnl *** Checks for pkcs11    ***
 134 dnl *****************************
 135
 136 P11_KIT_REQUIRED=0.8
 137
 138 AC_ARG_WITH(pkcs11,
 139         [AC_HELP_STRING([--with-pkcs11],
 140                         [support for pkcs11 @<:@default=check@:>@])],
 141                         [],
 142                         [with_pkcs11=check])
 143 if test "x$with_pkcs11" != "xno"; then
 144         PKG_CHECK_MODULES(PKCS11,
 145                           [p11-kit-1 >= $P11_KIT_REQUIRED],
 146                           [with_pkcs11=yes
 147                            pkcs11_support=p11-kit
 148                            tls_support="${tls_support}gnutls-pkcs11 "
 149                            AC_DEFINE_UNQUOTED([HAVE_PKCS11], [1], [Building with PKCS#11 support])],
 150                           [AS_IF([test "x$with_pkcs11" = "xyes"],
 151                                  [AC_MSG_FAILURE("$PKCS11_PKG_ERRORS")])
 152                            pkcs11_support=no])
 153 else
 154         pkcs11_support=no
 155 fi
 156 AM_CONDITIONAL(HAVE_PKCS11, [test "x$with_pkcs11" = "xyes"])
 157 AC_SUBST(PKCS11_CFLAGS)
 158 AC_SUBST(PKCS11_LIBS)
 159
 160 dnl ************************************
 161 dnl *** Enable lcov coverage reports ***
 162 dnl ************************************
 163
 164 AC_ARG_ENABLE(gcov,
 165   AS_HELP_STRING([--enable-gcov],
 166                  [Enable gcov]),
 167   [use_gcov=$enableval], [use_gcov=no])
 168
 169 if test "x$use_gcov" = "xyes"; then
 170   dnl we need gcc:
 171   if test "$GCC" != "yes"; then
 172     AC_MSG_ERROR([GCC is required for --enable-gcov])
 173   fi
 174
 175   ltp_version_list="1.6 1.7 1.8 1.9"
 176   AC_CHECK_PROG(LTP, lcov, lcov)
 177   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
 178
 179   if test "$LTP"; then
 180     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
 181       glib_cv_ltp_version=invalid
 182       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
 183       for ltp_check_version in $ltp_version_list; do
 184         if test "$ltp_version" = "$ltp_check_version"; then
 185           glib_cv_ltp_version="$ltp_check_version (ok)"
 186         fi
 187       done
 188     ])
 189   else
 190     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
 191     AC_MSG_ERROR([$ltp_msg])
 192   fi
 193
 194   case $glib_cv_ltp_version in
 195     ""|invalid[)]
 196       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
 197       AC_MSG_ERROR([$ltp_msg])
 198       LTP="exit 0;"
 199       ;;
 200   esac
 201
 202   if test -z "$LTP_GENHTML"; then
 203     AC_MSG_ERROR([Could not find genhtml from the LTP package])
 204   fi
 205
 206   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
 207
 208   dnl Remove all optimization flags from CFLAGS
 209   changequote({,})
 210   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
 211   changequote([,])
 212
 213   dnl Add the special gcc flags
 214   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
 215   LDFLAGS="$LDFLAGS -lgcov"
 216 fi
 217
 218 dnl ****************************************************
 219 dnl *** Warnings to show if using GCC                ***
 220 dnl *** (do this last so -Werror won't mess up tests ***
 221 dnl ****************************************************
 222
 223 AC_ARG_ENABLE(more-warnings,
 224               AS_HELP_STRING([--disable-more-warnings], [Inhibit compiler warnings]),
 225               set_more_warnings=no)
 226
 227 if test "$GCC" = "yes" -a "$set_more_warnings" != "no"; then
 228         CFLAGS="$CFLAGS \
 229                 -Wall -Wstrict-prototypes -Werror=missing-prototypes \
 230                 -Werror=implicit-function-declaration \
 231                 -Werror=pointer-arith -Werror=init-self -Werror=format=2 \
 232                 -Werror=missing-include-dirs \
 233                 -Werror=declaration-after-statement"
 234 fi
 235
 236 dnl *****************************
 237 dnl *** done                  ***
 238 dnl *****************************
 239 AC_CONFIG_FILES([Makefile
 240                  po/Makefile.in po/Makefile
 241                  proxy/libproxy/Makefile
 242                  proxy/gnome/Makefile
 243                  proxy/tests/Makefile
 244                  tls/gnutls/Makefile
 245                  tls/pkcs11/Makefile
 246                  tls/tests/Makefile
 247                 ])
 248 AC_OUTPUT
 249
 250 echo ""
 251 echo     "  Proxy support:     ${proxy_support:-no}"
 252 echo     "  TLS support:       ${tls_support:-no}"
 253 if test "$tls_support" != "no"; then
 254     echo "  PKCS#11 Support:   $pkcs11_support"
 255     echo "  TLS CA file:       ${with_ca_certificates:-(none)}"
 256     if test -n "$with_ca_certificates"; then
 257         if ! test -f "$with_ca_certificates"; then
 258             AC_MSG_WARN([Specified certificate authority file '$with_ca_certificates' does not exist])
 259         fi
 260     fi
 261 fi