configure.ac

   1 # clutter package version number, (as distinct from shared library version)
   2 # An odd micro number indicates in-progress development from Git
   3 # An even micro number indicates a released version
   4 #
   5 # Making a point release:
   6 # - increase clutter_micro_version to the next even number
   7 # - increase clutter_interface_age to the next even number
   8 # After the release:
   9 # - increase clutter_micro_version to the next odd number
  10 # - increase clutter_interface_version to the next odd number
  11 m4_define([clutter_major_version], [1])
  12 m4_define([clutter_minor_version], [9])
  13 m4_define([clutter_micro_version], [1])
  14
  15 # • for stable releases: increase the interface age by 1 for each release;
  16 #   if the API changes, set to 0. interface_age and binary_age are used to
  17 #   create the soname of the shared object:
  18 #
  19 #  (<minor> * 100 + <micro>) - <interface_age>
  20 #
  21 # this allows using the same soname for different micro-releases in case
  22 # no API was added or deprecated. for instance:
  23 #
  24 #   clutter 1.2.0  -> 100 * 2 + 0  = 200, interface age = 0 -> 200
  25 #   clutter 1.2.2  -> 100 * 2 + 2  = 202, interface age = 2 -> 200
  26 #   clutter 1.2.4  -> 100 * 2 + 4  = 204, interface age = 4 -> 200
  27 #   [ API addition, deprecation ]
  28 #   clutter 1.2.6  -> 100 * 2 + 6  = 206, interface age = 0 -> 206
  29 #   clutter 1.2.8  -> 100 * 2 + 8  = 208, interface age = 2 -> 206
  30 #   clutter 1.2.10 -> 100 * 2 + 10 = 210, interface age = 4 -> 206
  31 #   ...
  32 #
  33 # • for development releases: keep clutter_interface_age to 0
  34 m4_define([clutter_interface_age], [0])
  35
  36 m4_define([clutter_binary_age], [m4_eval(100 * clutter_minor_version + clutter_micro_version)])
  37
  38 m4_define([clutter_release_status],
  39           [m4_if(m4_eval(clutter_micro_version % 2), [1], [git],
  40                  [m4_if(m4_eval(clutter_minor_version % 2), [1], [snapshot],
  41                                                                  [release])])])
  42
  43 m4_define([clutter_version], [clutter_major_version.clutter_minor_version.clutter_micro_version])
  44
  45 # change this only when breaking the API
  46 m4_define([clutter_api_version], [1.0])
  47
  48 AC_PREREQ([2.63])
  49
  50 AC_INIT([clutter],
  51         [clutter_version],
  52         [http://bugzilla.gnome.org/enter_bug.cgi?product=clutter],
  53         [clutter],
  54         [http://www.clutter-project.org])
  55
  56 AC_CONFIG_SRCDIR([clutter/clutter.h])
  57 AC_CONFIG_HEADERS([config.h])
  58 AC_CONFIG_AUX_DIR([build])
  59 AC_CONFIG_MACRO_DIR([build/autotools])
  60
  61 AM_INIT_AUTOMAKE([1.11 foreign -Wno-portability no-define no-dist-gzip dist-xz tar-ustar])
  62 AM_SILENT_RULES([yes])
  63
  64 AC_SUBST([CLUTTER_MAJOR_VERSION],  [clutter_major_version])
  65 AC_SUBST([CLUTTER_MINOR_VERSION],  [clutter_minor_version])
  66 AC_SUBST([CLUTTER_MICRO_VERSION],  [clutter_micro_version])
  67 AC_SUBST([CLUTTER_VERSION],        [clutter_version])
  68 AC_SUBST([CLUTTER_API_VERSION],    [clutter_api_version])
  69 AC_SUBST([CLUTTER_API_VERSION_AM], [$CLUTTER_MAJOR_VERSION\_0])
  70 AC_SUBST([CLUTTER_RELEASE_STATUS], [clutter_release_status])
  71
  72 m4_define([lt_current],  [m4_eval(100 * clutter_minor_version + clutter_micro_version - clutter_interface_age)])
  73 m4_define([lt_revision], [clutter_interface_age])
  74 m4_define([lt_age],      [m4_eval(clutter_binary_age - clutter_interface_age)])
  75 CLUTTER_LT_CURRENT=lt_current
  76 CLUTTER_LT_REV=lt_revision
  77 CLUTTER_LT_AGE=lt_age
  78 CLUTTER_LT_VERSION="$CLUTTER_LT_CURRENT:$CLUTTER_LT_REV:$CLUTTER_LT_AGE"
  79 CLUTTER_LT_LDFLAGS="-version-info $CLUTTER_LT_VERSION"
  80
  81 AC_PROG_SED
  82
  83 AC_CANONICAL_HOST
  84 AC_MSG_CHECKING([if building for some Win32 platform])
  85 AS_CASE([$host],
  86         [*-*-mingw*|*-*-cygwin*],
  87         [
  88           CLUTTER_LT_LDFLAGS="$CLUTTER_LT_LDFLAGS -no-undefined"
  89           platform_win32=yes
  90         ],
  91
  92         [platform_win32=no]
  93 )
  94 AC_MSG_RESULT([$platform_win32])
  95 AM_CONDITIONAL(OS_WIN32, [test "$platform_win32" = "yes"])
  96
  97 AC_CHECK_HEADER([OpenGL/gl.h], [platform_quartz=yes], [platform_quartz=no])
  98 AM_CONDITIONAL(OS_QUARTZ, [test "$platform_quartz" = "yes"])
  99
 100 AC_SUBST(CLUTTER_LT_VERSION)
 101 AC_SUBST(CLUTTER_LT_LDFLAGS)
 102
 103 dnl ========================================================================
 104
 105 # Checks for programs.
 106 AM_PROG_CC_C_O
 107
 108 # require libtool >= 2.2
 109 LT_PREREQ([2.2.6])
 110 LT_INIT([disable-static])
 111
 112 # Checks for header files.
 113 AC_HEADER_STDC
 114
 115 # required versions for dependencies
 116 m4_define([glib_req_version],           [2.31.0])
 117 m4_define([cogl_req_version],           [1.8.0])
 118 m4_define([json_glib_req_version],      [0.12.0])
 119 m4_define([atk_req_version],            [2.1.5])
 120 m4_define([cairo_req_version],          [1.10])
 121 m4_define([pango_req_version],          [1.20])
 122 m4_define([gi_req_version],             [0.9.5])
 123 m4_define([uprof_req_version],          [0.3])
 124 m4_define([gtk_doc_req_version],        [1.13])
 125 m4_define([xfixes_req_version],         [3])
 126 m4_define([xcomposite_req_version],     [0.4])
 127
 128 AC_SUBST([GLIB_REQ_VERSION],       [glib_req_version])
 129 AC_SUBST([COGL_REQ_VERSION],       [cogl_req_version])
 130 AC_SUBST([JSON_GLIB_REQ_VERSION],  [json_glib_req_version])
 131 AC_SUBST([ATK_REQ_VERSION],        [atk_req_version])
 132 AC_SUBST([CAIRO_REQ_VERSION],      [cairo_req_version])
 133 AC_SUBST([PANGO_REQ_VERSION],      [pango_req_version])
 134 AC_SUBST([GI_REQ_VERSION],         [gi_req_version])
 135 AC_SUBST([UPROF_REQ_VERSION],      [uprof_req_version])
 136 AC_SUBST([GTK_DOC_REQ_VERSION],    [gtk_doc_req_version])
 137 AC_SUBST([XFIXES_REQ_VERSION],     [xfixes_req_version])
 138 AC_SUBST([XCOMPOSITE_REQ_VERSION], [xcomposite_req_version])
 139
 140 # Checks for typedefs, structures, and compiler characteristics.
 141 AM_PATH_GLIB_2_0([glib_req_version],
 142                  [],
 143                  [AC_MSG_ERROR([glib-2.0 is required])],
 144                  [gobject gthread gmodule-no-export])
 145
 146 # Check for -Bsymbolic-functions to avoid intra-library PLT jumps
 147 AC_ARG_ENABLE([Bsymbolic],
 148               [AS_HELP_STRING([--disable-Bsymbolic],
 149                               [Avoid linking with -Bsymbolic])],
 150               [],
 151               [
 152                 saved_LDFLAGS="${LDFLAGS}"
 153                 AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 154                 LDFLAGS=-Wl,-Bsymbolic-functions
 155                 AC_TRY_LINK([], [int main (void) { return 0; }],
 156                             [
 157                               AC_MSG_RESULT([yes])
 158                               enable_Bsymbolic=yes
 159                             ],
 160                             [
 161                               AC_MSG_RESULT([no])
 162                               enable_Bsymbolic=no
 163                             ])
 164                 LDFLAGS="${saved_LDFLAGS}"
 165               ])
 166
 167 AS_IF([test "x$enable_Bsymbolic" = "xyes"], [CLUTTER_LINK_FLAGS=-Wl[,]-Bsymbolic-functions])
 168 AC_SUBST(CLUTTER_LINK_FLAGS)
 169
 170 dnl ========================================================================
 171
 172 # defaults
 173 AS_IF([test "x$platform_win32" = "xyes"],  [CLUTTER_FLAVOUR=win32],
 174       [test "x$platform_quartz" = "xyes"], [CLUTTER_FLAVOUR=osx],
 175       [CLUTTER_FLAVOUR=glx])
 176
 177 FLAVOUR_LIBS=""
 178 FLAVOUR_CFLAGS=""
 179 CLUTTER_WINSYS_BASE=
 180 CLUTTER_WINSYS_BASE_LIB=
 181 CLUTTER_WINSYS=
 182 glesversion=1.1
 183 use_gles2_wrapper=no
 184 experimental_backend=no
 185 experimental_image=no
 186
 187 AC_ARG_WITH([flavour],
 188             [AS_HELP_STRING([--with-flavour=@<:@glx/opengl-egl-xlib/wayland/eglx/eglnative/osx/win32/cex100@:>@],
 189                             [Select the Clutter window system backend])],
 190             [CLUTTER_FLAVOUR=$with_flavour])
 191
 192 AC_ARG_WITH([gles],
 193             [AS_HELP_STRING([--with-gles=@<:@1.1/2.0@:>@],
 194                             [Select Clutter GLES version (for EGL backends)])],
 195             [glesversion=$with_gles])
 196
 197 # base dependencies for core
 198 CLUTTER_BASE_PC_FILES="cogl-1.0 >= $COGL_REQ_VERSION cairo-gobject >= $CAIRO_REQ_VERSION atk >= $ATK_REQ_VERSION pangocairo >= $PANGO_REQ_VERSION cogl-pango-1.0 json-glib-1.0 >= $JSON_GLIB_REQ_VERSION"
 199
 200 # backend specific pkg-config files
 201 BACKEND_PC_FILES=""
 202
 203 dnl === Clutter windowing system backend ======================================
 204
 205 AS_CASE([$CLUTTER_FLAVOUR],
 206
 207         [glx],
 208         [
 209           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_GLX"
 210
 211           SUPPORT_X11=1
 212           SUPPORT_XLIB=1
 213           SUPPORT_GLX=1
 214
 215           CLUTTER_WINSYS=cogl
 216           CLUTTER_WINSYS_BASE=x11
 217           CLUTTER_WINSYS_BASE_LIB="x11/libclutter-x11.la"
 218           CLUTTER_SONAME_INFIX=glx
 219
 220           # Mesa 7.3 added a GL pkg-config file, finally
 221           PKG_CHECK_EXISTS([gl],
 222                            [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"],
 223                            # if a pkg-config file isn't found just add -lGL
 224                            # and hope for the best.
 225                            [FLAVOUR_LIBS="$FLAVOUR_LIBS -lGL"])
 226
 227           # We might fall back to DRM for sync-to-vblank on GLX
 228           PKG_CHECK_EXISTS([libdrm],
 229                            [
 230                              AC_DEFINE([HAVE_DRM], [1], [Have libdrm support])
 231                              BACKEND_PC_FILES="$BACKEND_PC_FILES libdrm"
 232                            ],
 233                            [])
 234         ],
 235
 236         [opengl-egl-xlib],
 237         [
 238           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_EGL"
 239           CLUTTER_EGL_BACKEND="generic"
 240
 241           SUPPORT_X11=1
 242           SUPPORT_XLIB=1
 243           SUPPORT_EGL=1
 244           SUPPORT_EGL_PLATFORM_POWERVR_X11=1
 245
 246           CLUTTER_WINSYS=cogl
 247           CLUTTER_WINSYS_BASE=x11
 248           CLUTTER_WINSYS_BASE_LIB="x11/libclutter-x11.la"
 249           # I think this winsys can be API and ABI compatible with the
 250           # glx flavour so we can also be cheeky and use the same soname
 251           CLUTTER_SONAME_INFIX=glx
 252
 253           PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 254           PKG_CHECK_EXISTS([egl], [BACKEND_PC_FILES="$BACKEND_PC_FILES egl"], [])
 255         ],
 256
 257         [wayland],
 258         [
 259           experimental_backend="yes"
 260           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_WAYLAND"
 261
 262           SUPPORT_WAYLAND=1
 263
 264           CLUTTER_WINSYS=wayland
 265           CLUTTER_SONAME_INFIX=wayland
 266
 267           PKG_CHECK_EXISTS([gl], [BACKEND_PC_FILES="$BACKEND_PC_FILES gl"], [])
 268           PKG_CHECK_EXISTS([egl], [BACKEND_PC_FILES="$BACKEND_PC_FILES egl"], [])
 269           PKG_CHECK_EXISTS([wayland-client xkbcommon],
 270                            [BACKEND_PC_FILES="$BACKEND_PC_FILES wayland-client xkbcommon"], [])
 271         ],
 272
 273         [eglx],
 274         [
 275           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_EGL"
 276           CLUTTER_EGL_BACKEND="generic"
 277
 278           SUPPORT_X11=1
 279           SUPPORT_XLIB=1
 280           SUPPORT_EGL=1
 281           SUPPORT_EGL_PLATFORM_POWERVR_X11=1
 282
 283           CLUTTER_WINSYS=cogl
 284           CLUTTER_WINSYS_BASE=x11
 285           CLUTTER_WINSYS_BASE_LIB="x11/libclutter-x11.la"
 286           CLUTTER_SONAME_INFIX=eglx
 287         ],
 288
 289         [eglnative],
 290         [
 291           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_EGL"
 292           CLUTTER_EGL_BACKEND="generic"
 293
 294           SUPPORT_EGL=1
 295           SUPPORT_EGL_PLATFORM_POWERVR_NULL=1
 296
 297           PKG_CHECK_MODULES(TSLIB, [tslib-1.0], [have_tslib=yes], [have_tslib=no])
 298           AS_IF([test "x$have_tslib" = "xyes"],
 299                 [AC_DEFINE([HAVE_TSLIB], [1], [Have tslib for touchscreen handling])]
 300           )
 301
 302           # evdev
 303           PKG_CHECK_MODULES(EVDEV, [gudev-1.0 xkbcommon],
 304                             [have_evdev=yes], [have_evdev=no])
 305           AS_IF([test "x$have_evdev" = "xyes"],
 306                 [AC_DEFINE([HAVE_EVDEV], 1,
 307                            [Have evdev support for input handling])]
 308           )
 309
 310           # Make sure we don't enable tslib and evdev at the same time, we
 311           # don't support multiple event backends yet.
 312           AS_IF([test "x$have_tslib" = "xyes" -a "x$have_evdev" = "xyes"],
 313                 [AC_MSG_ERROR([Cannot enable both tslib and evdev events])])
 314
 315           FLAVOUR_LIBS="$FLAVOUR_LIBS $TSLIB_LIBS $EVDEV_LIBS"
 316           FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $TSLIB_CFLAGS $EVDEV_CFLAGS"
 317
 318           CLUTTER_WINSYS=cogl
 319           CLUTTER_SONAME_INFIX=eglnative
 320         ],
 321
 322         [cex100],
 323         [
 324           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_EGL"
 325           CLUTTER_EGL_BACKEND="cex100"
 326
 327           SUPPORT_EGL=1
 328           SUPPORT_EGL_PLATFORM_GDL=1
 329
 330           # The cex100 is a small specialization of the EGL backend
 331           CLUTTER_WINSYS=cogl
 332           CLUTTER_SONAME_INFIX=cex100
 333
 334           found_gdl=no
 335           AC_CHECK_HEADERS([libgdl.h], [found_gdl=yes])
 336           AS_IF([test "x$found_gdl" = "xno"],
 337                 [AC_CHECK_HEADERS([CE4100/libgdl.h],
 338                                   [
 339                                     FLAVOUR_CFLAGS="-I/usr/include/CE4100"
 340                                     found_gdl=yes
 341                                     CLUTTER_CEX100_LIBGDL_PREFIX=CE4100/
 342                                   ])
 343                 ])
 344           AC_SUBST(CLUTTER_CEX100_LIBGDL_PREFIX)
 345
 346           AS_IF([test x"$found_gdl" = "xno"], [AC_MSG_ERROR([libgdl.h not found])])
 347
 348           # evdev
 349           PKG_CHECK_MODULES(EVDEV, [gudev-1.0 xkbcommon],
 350                             [have_evdev=yes], [have_evdev=no])
 351           AS_IF([test "x$have_evdev" = "xyes"],
 352                 [AC_DEFINE([HAVE_EVDEV], 1,
 353                            [Have evdev support for input handling])]
 354           )
 355
 356           FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $EVDEV_CFLAGS"
 357           FLAVOUR_LIBS="$FLAVOUR_LIBS -lgdl $EVDEV_LIBS"
 358         ],
 359
 360         [osx],
 361         [
 362           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_OSX"
 363
 364           AC_DEFINE([HAVE_CLUTTER_OSX], [1], [Have the OSX backend])
 365
 366           FLAVOUR_LIBS="$FLAVOUR_LIBS -framework Cocoa -framework OpenGL"
 367
 368           CLUTTER_WINSYS=osx
 369           CLUTTER_SONAME_INFIX=osx
 370         ],
 371
 372         [win32],
 373         [
 374           CLUTTER_STAGE_TYPE="CLUTTER_TYPE_STAGE_WIN32"
 375           AC_DEFINE([HAVE_CLUTTER_WIN32], [1], [Have the Win32 backend])
 376
 377           FLAVOUR_LIBS="$FLAVOUR_LIBS -lopengl32 -lgdi32 -lwinmm"
 378           FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS -D_WIN32_WINNT=0x0500"
 379
 380           AC_CHECK_TOOL(WINDRES, windres, no)
 381           if test "$WINDRES" = no; then
 382              AC_MSG_ERROR([*** windres is required])
 383           fi
 384
 385           CLUTTER_WINSYS=win32
 386           CLUTTER_SONAME_INFIX=win32
 387         ],
 388
 389         [AC_MSG_ERROR([Invalid backend for Clutter])]
 390 )
 391
 392 AS_IF([test "x$SUPPORT_X11" = "x1"],
 393       [
 394         # we use fontconfig API and pango-fc when the fontconfig
 395         # configuration changes
 396         PKG_CHECK_EXISTS([pangoft2],
 397                          [
 398                            AC_DEFINE([HAVE_PANGO_FT2], [1], [Supports PangoFt2])
 399                            BACKEND_PC_FILES="$BACKEND_PC_FILES pangoft2"
 400                          ],
 401                          [])
 402       ])
 403
 404 AS_IF([test "x$SUPPORT_GLX" = "x1"],
 405       [
 406         AC_DEFINE([HAVE_CLUTTER_GLX], [1], [Have the GLX backend])
 407
 408         AC_CHECK_HEADERS([GL/glx.h],
 409                          [],
 410                          [AC_MSG_ERROR([Unable to locate required GLX headers])])
 411
 412         AC_CHECK_LIB(GL, [glXCreateContext],
 413                      [HAVE_LIBGLX=yes],
 414                      [AC_MSG_ERROR([Required GLX library not found])])
 415       ])
 416
 417 AS_IF([test "x$SUPPORT_WAYLAND" = "x1"],
 418       [
 419         AC_DEFINE([HAVE_CLUTTER_WAYLAND], [1], [Have the Wayland backend])
 420       ])
 421
 422 AS_IF([test "x$SUPPORT_EGL" = "x1"],
 423       [
 424         AC_DEFINE([HAVE_CLUTTER_EGL], [1], [Have the EGL backend])
 425       ])
 426
 427 AS_IF([test "x$CLUTTER_EGL_BACKEND" = "xgeneric"],
 428       AC_DEFINE([CLUTTER_EGL_BACKEND_GENERIC], [1], [Use Generic EGL backend]))
 429
 430 AS_IF([test "x$CLUTTER_EGL_BACKEND" = "xcex100"],
 431       AC_DEFINE([CLUTTER_EGL_BACKEND_CEX100], [1], [Use CEX100 EGL backend]))
 432
 433 # winsys conditionals for use in automake files...
 434 AM_CONDITIONAL(SUPPORT_GLX, [test "x$SUPPORT_GLX" = "x1"])
 435 AM_CONDITIONAL(SUPPORT_X11, [test "x$SUPPORT_X11" = "x1"])
 436 AM_CONDITIONAL(SUPPORT_XLIB, [test "x$SUPPORT_XLIB" = "x1"])
 437 AM_CONDITIONAL(SUPPORT_EGL, [test "x$SUPPORT_EGL" = "x1"])
 438 AM_CONDITIONAL(SUPPORT_OSX, [test "x$CLUTTER_WINSYS" = "xosx"])
 439 AM_CONDITIONAL(SUPPORT_WIN32, [test "x$CLUTTER_WINSYS" = "xwin32"])
 440 AM_CONDITIONAL(SUPPORT_CEX100, [test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"])
 441 AM_CONDITIONAL(SUPPORT_WAYLAND, [test "x$CLUTTER_WINSYS" = "xwayland"])
 442 AM_CONDITIONAL(SUPPORT_STUB, [test "x$CLUTTER_WINSYS" = "xwin32" -o \
 443                                    "x$CLUTTER_WINSYS" = "xosx" -o \
 444                                    "x$CLUTTER_WINSYS" = "xwayland"])
 445
 446 AM_CONDITIONAL(USE_TSLIB, [test "x$have_tslib" = "xyes"])
 447 AM_CONDITIONAL(SUPPORT_EVDEV, [test "x$have_evdev" = "xyes"])
 448
 449 dnl Instead of using AM_CFLAGS to ensure
 450 dnl COGL_ENABLE_EXPERIMENTAL_2_0_API is defined while compiling clutter
 451 dnl and cogl code we use a define in config.h instead. This helps ensure
 452 dnl other tools such as glib-mkenums and gir-scanner don't end up
 453 dnl using the define also.
 454 AC_DEFINE([COGL_ENABLE_EXPERIMENTAL_2_0_API], [1], [Can use Cogl 2.0 API internally])
 455
 456 dnl === Clutter configuration =================================================
 457
 458 CLUTTER_CONFIG_DEFINES=
 459
 460 # windowing systems
 461 AS_IF([test "x$SUPPORT_XLIB" = "x1"],
 462       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 463 #define CLUTTER_WINDOWING_X11 1"])
 464 AS_IF([test "x$SUPPORT_GLX" = "x1"],
 465       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 466 #define CLUTTER_WINDOWING_GLX 1"])
 467 AS_IF([test "x$SUPPORT_EGL" = "x1"],
 468       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 469 #define CLUTTER_WINDOWING_EGL 1"])
 470 AS_IF([test "x$CLUTTER_WINSYS" = "xwayland"],
 471       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 472 #define CLUTTER_WINDOWING_WAYLAND 1"])
 473 AS_IF([test "x$CLUTTER_WINSYS" = "xosx"],
 474       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 475 #define CLUTTER_WINDOWING_OSX 1"])
 476 AS_IF([test "x$CLUTTER_WINSYS" = "xwin32"],
 477       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 478 #define CLUTTER_WINDOWING_WIN32 1"])
 479 AS_IF([test "x$SUPPORT_EGL_PLATFORM_GDL" = "x1"],
 480       [CLUTTER_CONFIG_DEFINES="$CLUTTER_CONFIG_DEFINES
 481 #define CLUTTER_WINDOWING_CEX100 1"])
 482
 483 AC_SUBST([CLUTTER_CONFIG_DEFINES])
 484
 485 dnl === Clutter substitutions =================================================
 486 # Eventually the idea of a winsys should be hidden from Clutter and moved
 487 # into Cogl, but for now we have CLUTTER_WINSYS...
 488 AC_SUBST([CLUTTER_WINSYS])
 489 # The same goes for the winsys-base...
 490 AC_SUBST([CLUTTER_WINSYS_BASE])
 491 AC_SUBST([CLUTTER_WINSYS_BASE_LIB])
 492 AC_SUBST(CLUTTER_STAGE_TYPE)
 493 AC_SUBST(CLUTTER_SONAME_INFIX)
 494
 495 CLUTTER_WINSYS_LIB=libclutter-$CLUTTER_SONAME_INFIX-$CLUTTER_API_VERSION.la
 496 AC_SUBST([CLUTTER_WINSYS_LIB])
 497
 498 dnl === Clutter substitutions kept for backwards compatibility ================
 499 AC_SUBST([CLUTTER_FLAVOUR])
 500 CLUTTER_COGL=undefined
 501 AC_SUBST([CLUTTER_COGL])
 502
 503 dnl === Image loading backend =================================================
 504 IMAGE_PC_FILES=""
 505
 506 dnl === X11 checks, only for X11-based backends ===============================
 507 X11_PC_FILES=""
 508 x11_tests=no
 509
 510 AS_IF([test "x$SUPPORT_XLIB" = "x1"],
 511       [
 512         # base X11 includes and libraries
 513         AC_MSG_CHECKING([for X11])
 514
 515         # start with pkg-config
 516         PKG_CHECK_EXISTS([x11], [have_x11=yes], [have_x11=no])
 517         AS_IF([test "x$have_x11" = "xyes"],
 518               [
 519                 X11_PC_FILES="x11"
 520
 521                 # we actually need to ask for CFLAGS and LIBS
 522                 X11_CFLAGS=`$PKG_CONFIG --cflags $X11_PC_FILES`
 523                 X11_LIBS=`$PKG_CONFIG --libs $X11_PC_FILES`
 524
 525                 AC_MSG_RESULT([found])
 526               ],
 527               [
 528                 # no pkg-config, let's go old school
 529                 AC_PATH_X
 530
 531                 AS_IF([test "x$no_x" = "xyes"],
 532                       [AC_MSG_ERROR([No X11 Libraries found])],
 533                       [
 534                         AS_IF([test "x$x_includes" != "xNONE" && test -n "$x_includes"],
 535                               [X11_CFLAGS=-I`echo $x_includes | sed -e "s/:/ -I/g"`])
 536
 537                         AS_IF([test "x$x_libraries" != "xNONE" && test -n "$x_libraries"],
 538                               [X11_LIBS=-L`echo $x_libraries | sed -e "s/:/ -L/g"`])
 539
 540                         AC_MSG_RESULT([found])
 541                       ]
 542                 )
 543               ]
 544         )
 545
 546         # XEXT (required)
 547         AC_MSG_CHECKING([for XEXT extension])
 548         PKG_CHECK_EXISTS([xext], [have_xext=yes], [have_xext=no])
 549         AS_IF([test "x$have_xext" = "xyes"],
 550               [
 551                 AC_DEFINE(HAVE_XEXT, [1], [Define to 1 if we have the XEXT X extension])
 552
 553                 X11_LIBS="$X11_LIBS -lXext"
 554                 X11_PC_FILES="$X11_PC_FILES xext"
 555
 556                 AC_MSG_RESULT([found])
 557               ],
 558               [AC_MSG_ERROR([Not found])]
 559         )
 560
 561         # XFIXES (required)
 562         AC_MSG_CHECKING([for XFIXES extension >= $XFIXES_REQ_VERSION])
 563         PKG_CHECK_EXISTS([xfixes >= $XFIXES_REQ_VERSION], [have_xfixes=yes], [have_xfixes=no])
 564         AS_IF([test "x$have_xfixes" = "xyes"],
 565               [
 566                 AC_DEFINE(HAVE_XFIXES, [1], [Define to 1 if we have the XFIXES X extension])
 567
 568                 X11_LIBS="$X11_LIBS -lXfixes"
 569                 X11_PC_FILES="$X11_PC_FILES xfixes >= $XFIXES_REQ_VERSION"
 570
 571                 AC_MSG_RESULT([found])
 572               ],
 573               [AC_MSG_ERROR([Not found])]
 574         )
 575
 576         # XDAMAGE (required)
 577         AC_MSG_CHECKING([for XDAMAGE extension])
 578         PKG_CHECK_EXISTS([xdamage], [have_xdamage=yes], [have_xdamage=no])
 579         AS_IF([test "x$have_xdamage" = "xyes"],
 580               [
 581                 AC_DEFINE(HAVE_XDAMAGE, [1], [Define to 1 if we have the XDAMAGE X extension])
 582
 583                 X11_LIBS="$X11_LIBS -lXdamage"
 584                 X11_PC_FILES="$X11_PC_FILES xdamage"
 585
 586                 AC_MSG_RESULT([found])
 587               ],
 588               [AC_MSG_ERROR([not found])]
 589         )
 590
 591         # XCOMPOSITE (optional)
 592         AC_MSG_CHECKING([for XCOMPOSITE extension >= $XCOMPOSITE_REQ_VERSION])
 593         PKG_CHECK_EXISTS([xcomposite >= $XCOMPOSITE_REQ_VERSION], [have_xcomposite=yes], [have_xcomposite=no])
 594         AS_IF([test "x$have_xcomposite" = "xyes"],
 595               [
 596                 AC_DEFINE(HAVE_XCOMPOSITE, [1], [Define to 1 if we have the XCOMPOSITE X extension])
 597
 598                 X11_LIBS="$X11_LIBS -lXcomposite"
 599                 X11_PC_FILES="$X11_PC_FILES xcomposite >= $XCOMPOSITE_REQ_VERSION"
 600
 601                 AC_MSG_RESULT([found])
 602               ],
 603               [AC_MSG_ERROR([not found])]
 604         )
 605
 606         # X Generic Extensions (optional)
 607         clutter_save_CPPFLAGS="$CPPFLAGS"
 608         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 609
 610         clutter_save_LIBS="$LIBS"
 611         LIBS="$LIBS $X11_LIBS"
 612
 613         have_xge=no
 614         AC_CHECK_FUNC([XGetEventData],
 615                       [
 616                         AC_DEFINE([HAVE_XGE], [1], [Define to 1 if X Generic Extensions is available])
 617                         have_xge=yes
 618                       ])
 619
 620         CPPFLAGS="$clutter_save_CPPFLAGS"
 621         LIBS="$clutter_save_LIBS"
 622
 623         # XI (optional)
 624         AC_ARG_ENABLE([xinput],
 625                       [AS_HELP_STRING([--enable-xinput], [Use the XI X extension])],
 626                       [],
 627                       [enable_xinput=yes])
 628
 629         AS_IF([test "x$enable_xinput" = "xyes"],
 630               [
 631                 PKG_CHECK_EXISTS([xi], [have_xinput=yes], [have_xinput=no])
 632               ],
 633               [
 634                 have_xinput=no
 635               ])
 636
 637         AS_CASE([$have_xinput],
 638
 639                 [yes],
 640                 [
 641                   AC_CHECK_HEADERS([X11/extensions/XInput2.h],
 642                                    [
 643                                      have_xinput2=yes
 644                                      AC_DEFINE([HAVE_XINPUT_2],
 645                                                [1],
 646                                                [Define to 1 if XI2 is available])
 647                                    ],
 648                                    [
 649                                      have_xinput2=no
 650                                      AC_DEFINE([HAVE_XINPUT],
 651                                                [1],
 652                                                [Define to 1 if XInput is available])
 653                                    ])
 654
 655                   X11_LIBS="$X11_LIBS $XINPUT_LIBS"
 656                   X11_PC_FILES="$X11_PC_FILES xi"
 657                 ],
 658
 659                 [no],
 660                 [have_xinput2=no],
 661
 662                 [*],
 663                 [AC_MSG_ERROR([Invalid argument for --enable-xinput])]
 664         )
 665
 666         # XKB
 667         clutter_save_CPPFLAGS="$CPPFLAGS"
 668         CPPFLAGS="$CPPFLAGS $X11_CFLAGS"
 669
 670         clutter_save_LIBS="$LIBS"
 671         LIBS="$LIBS $X11_LIBS"
 672
 673         have_xkb=no
 674         AC_CHECK_FUNC([XkbQueryExtension],
 675                       [
 676                         AC_DEFINE(HAVE_XKB, 1, [Define to use XKB extension])
 677                         have_xkb=yes
 678                       ])
 679
 680         CPPFLAGS="$clutter_save_CPPFLAGS"
 681         LIBS="$clutter_save_LIBS"
 682
 683         x11_tests=yes
 684         BACKEND_PC_FILES="$BACKEND_PC_FILES $X11_PC_FILES"
 685         FLAVOUR_LIBS="$FLAVOUR_LIBS $X11_LIBS"
 686         FLAVOUR_CFLAGS="$FLAVOUR_CFLAGS $X11_CFLAGS"
 687       ]
 688 )
 689
 690 AM_CONDITIONAL([BUILD_XI2], [test "x$have_xinput2" = "xyes"])
 691 AM_CONDITIONAL(X11_TESTS, [test "x$x11_tests" = "xyes"])
 692
 693 dnl === Enable debug level ====================================================
 694
 695 m4_define([debug_default], [m4_if(m4_eval(clutter_minor_version % 2), [1], [yes], [minimum])])
 696 AC_ARG_ENABLE([debug],
 697               [AS_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 698                               [Control Clutter debugging level @<:@default=]debug_default[@:>@])],
 699               [],
 700               [enable_debug=debug_default])
 701
 702 AS_CASE([$enable_debug],
 703
 704         [yes],
 705         [
 706           test "$cflags_set" = set || CFLAGS="$CFLAGS -g"
 707           CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG"
 708         ],
 709
 710         [minimum],
 711         [CLUTTER_DEBUG_CFLAGS="-DCLUTTER_ENABLE_DEBUG -DG_DISABLE_CAST_CHECKS"],
 712
 713         [no],
 714         [CLUTTER_DEBUG_CFLAGS="-DG_DISABLE_ASSERT -DG_DISABLE_CHECKS -DG_DISABLE_CAST_CHECKS"],
 715
 716         [AC_MSG_ERROR([Unknown argument for --enable-debug])]
 717 )
 718
 719 AC_SUBST(CLUTTER_DEBUG_CFLAGS)
 720
 721 dnl === Enable deprecation guards ==================================================
 722
 723 m4_define([deprecated_default],
 724           [m4_if(m4_eval(clutter_minor_version % 2),
 725                  [1],
 726                  [no],
 727                  [yes])])
 728
 729 AC_ARG_ENABLE([deprecated],
 730               [AS_HELP_STRING([--enable-deprecated=@<:@no/yes@:>@],
 731                               [Whether deprecated symbols should be disabled when compiling Clutter @<:@default=]deprecated_default[@:>@])],
 732               [],
 733               [enable_deprecated=deprecated_default])
 734
 735 AS_CASE([$enable_deprecated],
 736
 737         [no],
 738         [
 739           CLUTTER_DEPRECATED_CFLAGS="-DG_DISABLE_DEPRECATED -DG_DISABLE_SINGLE_INCLUDES -DCOGL_DISABLE_DEPRECATED -DCLUTTER_DISABLE_DEPRECATED"
 740         ],
 741
 742         [yes],
 743         [
 744           CLUTTER_DEPRECATED_CFLAGS=""
 745         ],
 746
 747         [AC_MSG_ERROR([Unknown argument for --enable-deprecated])]
 748 )
 749
 750 AC_SUBST([CLUTTER_DEPRECATED_CFLAGS])
 751
 752
 753 dnl === Conformance test suite ================================================
 754
 755 AC_ARG_ENABLE([conformance],
 756               [AS_HELP_STRING([--enable-conformance=@<:@no/yes@:>@],
 757                               [Build conformance test suite @<:@default=yes@:>@])],
 758               [],
 759               [enable_conformance=yes])
 760
 761 AM_CONDITIONAL([BUILD_TESTS], [test "x$enable_conformance" = "xyes"])
 762
 763 dnl === Profiling =============================================================
 764
 765 m4_define([profile_default], [no])
 766 AC_ARG_ENABLE(profile,
 767               AS_HELP_STRING([--enable-profile=@<:@no/yes@:>@],
 768                              [Turn on profiling support. yes; All profiling probe points are compiled in and may be runtime enabled. no; No profiling support will built into clutter.  @<:@default=no@:>@]),
 769               [],
 770               [enable_profile=profile_default])
 771
 772 AS_CASE([$enable_profile],
 773
 774         [yes],
 775         [
 776           AS_IF([test "x$GCC" = "xyes"],
 777                 [
 778                   PKG_CHECK_MODULES([PROFILE_DEP], [uprof-0.3])
 779                   CLUTTER_PROFILE_CFLAGS="-DCLUTTER_ENABLE_PROFILE $PROFILE_DEP_CFLAGS"
 780                   CLUTTER_PROFILE_LDFLAGS="$PROFILE_DEP_LIBS"
 781
 782                   AS_IF([test "x$enable_debug" = "xyes"], [CLUTTER_PROFILE_CFLAGS+=" -DUPROF_DEBUG"])
 783                 ],
 784                 [
 785                   AC_MSG_ERROR([--enable-profile is currently only supported if using GCC])
 786                 ])
 787         ],
 788
 789         [no],
 790         [
 791           CLUTTER_PROFILE_CFLAGS=""
 792           CLUTTER_PROFILE_LDFLAGS=""
 793         ],
 794
 795         [*], [AC_MSG_ERROR([Invalid value for --enable-profile])]
 796 )
 797 AM_CONDITIONAL(PROFILE, test "x$enable_profile" != "xno")
 798 AC_SUBST(CLUTTER_PROFILE_CFLAGS)
 799 AC_SUBST(CLUTTER_PROFILE_LDFLAGS)
 800
 801 dnl === Coverage report =======================================================
 802
 803 AC_PATH_PROG([GCOV], [gcov], [enable_gcov=no])
 804
 805 AC_MSG_CHECKING([whether to build with gcov testing])
 806
 807 AC_ARG_ENABLE([gcov],
 808               [AS_HELP_STRING([--enable-gcov],
 809                               [Whether to enable coverage testing (requires gcc
 810 and gcov)])],
 811               [],
 812               [enable_gcov=no])
 813
 814 AS_IF([test "x$enable_gcov" = "xyes" && test "x$GCC" = "xyes"],
 815       [
 816         AS_IF([test "x$enable_conformance" = "xno"],
 817               [AC_MSG_WARN([Conformance test suite is disabled, the coverage report will be incomplete])],
 818               [AC_MSG_RESULT([yes])]
 819         )
 820
 821         GCOV_CFLAGS="-g -O0 -fprofile-arcs -ftest-coverage"
 822         GCOV_LDFLAGS="-lgcov"
 823       ],
 824       [AC_MSG_RESULT([no])]
 825 )
 826
 827 AM_CONDITIONAL([GCOV_ENABLED], [test "x$enable_gcov" = "xyes"])
 828 AC_SUBST([GCOV_CFLAGS])
 829 AC_SUBST([GCOV_LDFLAGS])
 830
 831 dnl === Enable strict compiler flags ==========================================
 832
 833 # use strict compiler flags only when building from git; the rules for
 834 # distcheck will take care of turning this on when making a release
 835 m4_define([maintainer_flags_default], [m4_if(m4_eval(clutter_micro_version % 2), [1], [yes], [no])])
 836 AC_ARG_ENABLE([maintainer-flags],
 837               [AS_HELP_STRING([--enable-maintainer-flags=@<:@no/yes/error@:>@],
 838                               [Use strict compiler flags @<:@default=]maintainer_flags_default[@:>@])],
 839               [],
 840               [enable_maintainer_flags=maintainer_flags_default])
 841
 842 MAINTAINER_COMPILER_FLAGS="-Wall -Wshadow -Wcast-align -Wuninitialized
 843                            -Wno-strict-aliasing -Wempty-body -Wformat
 844                            -Wformat-security -Winit-self
 845                            -Wdeclaration-after-statement -Wvla
 846                            -Wpointer-arith"
 847
 848 AS_CASE([$enable_maintainer_flags],
 849         [yes],
 850         [
 851           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 852         ],
 853
 854         [no],
 855         [
 856         ],
 857
 858         [error],
 859         [
 860           MAINTAINER_COMPILER_FLAGS="$MAINTAINER_COMPILER_FLAGS -Werror"
 861           AS_COMPILER_FLAGS([MAINTAINER_CFLAGS], [$MAINTAINER_COMPILER_FLAGS])
 862         ],
 863
 864         [*],
 865         [AC_MSG_ERROR([Invalid option for --enable-maintainer-flags])]
 866 )
 867
 868 # strip leading spaces
 869 MAINTAINER_CFLAGS=${MAINTAINER_CFLAGS#*  }
 870 AC_SUBST(MAINTAINER_CFLAGS)
 871
 872 dnl === Dependencies, compiler flags and linker libraries =====================
 873 # strip leading space
 874 BACKEND_PC_FILES=${BACKEND_PC_FILES#* }
 875
 876 CLUTTER_REQUIRES="$CLUTTER_BASE_PC_FILES $IMAGE_PC_FILES $BACKEND_PC_FILES"
 877 PKG_CHECK_MODULES(CLUTTER_DEPS, [$CLUTTER_REQUIRES])
 878 AC_SUBST(CLUTTER_REQUIRES)
 879
 880 CLUTTER_CFLAGS="$FLAVOUR_CFLAGS $CLUTTER_DEPS_CFLAGS $CLUTTER_PROFILE_CFLAGS $GLIB_CFLAGS"
 881 CLUTTER_LIBS="$FLAVOUR_LIBS $CLUTTER_DEPS_LIBS $CLUTTER_PROFILE_LDFLAGS $GLIB_LIBS"
 882 AC_SUBST(CLUTTER_CFLAGS)
 883 AC_SUBST(CLUTTER_LIBS)
 884
 885
 886 dnl === GObject-Introspection check ===========================================
 887
 888 GOBJECT_INTROSPECTION_CHECK([gi_req_version])
 889
 890 dnl === GTK Doc check =========================================================
 891
 892 GTK_DOC_CHECK([gtk_doc_req_version], [--flavour no-tmpl])
 893
 894 # we don't want to build the documentation from a Git clone unless we
 895 # explicitly tell configure to do so; this allows avoiding to recurse into
 896 # the documentation directory when building Clutter inside Poky for a
 897 # target device that doesn't have gtk-doc installed. for reference
 898 # see: http://bugzilla.openedhand.com/show_bug.cgi?id=1047
 899 #
 900 # we use autogen.sh as it exists only inside the Git clones, and it
 901 # is not packaged into tarballs.
 902 AM_CONDITIONAL([BUILD_GTK_DOC], [test "x$enable_gtk_doc" = "xyes" || test ! -f "autogen.sh"])
 903
 904 # prefixes for fixing gtk-doc references
 905 CAIRO_PREFIX="`$PKG_CONFIG --variable=prefix cairo`"
 906 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 907 PANGO_PREFIX="`$PKG_CONFIG --variable=prefix pango`"
 908 COGL_PREFIX="`$PKG_CONFIG --variable=prefix cogl-1.0`"
 909 ATK_PREFIX="`$PKG_CONFIG --variable=prefix atk`"
 910 AC_SUBST(CAIRO_PREFIX)
 911 AC_SUBST(GLIB_PREFIX)
 912 AC_SUBST(PANGO_PREFIX)
 913 AC_SUBST(COGL_PREFIX)
 914 AC_SUBST(ATK_PREFIX)
 915
 916 dnl === Manual ================================================================
 917
 918 AC_ARG_ENABLE([docs],
 919               [AS_HELP_STRING([--enable-docs=@<:@no/yes@:>@],
 920                               [Build optional documentation; requires xsltproc and jw.])],
 921               [enable_docs=$enableval],
 922               [enable_docs=no])
 923
 924 enable_pdfs=no
 925 AS_IF([test "x$enable_docs" = "xyes"],
 926       [
 927         AC_PATH_PROG(JW, [jw], [no])
 928         AS_IF([test "x$JW" = "xno"],
 929               [
 930                 AC_MSG_WARN([jw not found; pdf generation has been disabled])
 931               ],
 932               [enable_pdfs=yes])
 933
 934         AC_PATH_PROG(XSLTPROC, [xsltproc], [no])
 935         AS_IF([test "x$XSLTPROC" = "xno"],
 936               [
 937                 AC_MSG_ERROR([xsltproc not found])
 938               ])
 939       ]
 940 )
 941
 942 AM_CONDITIONAL(ENABLE_DOCS, [test "x$enable_docs" = "xyes"])
 943 AM_CONDITIONAL(ENABLE_PDFS, [test "x$enable_pdfs" = "xyes"])
 944
 945 dnl === I18N ==================================================================
 946
 947 AM_GNU_GETTEXT_VERSION([0.17])
 948 AM_GNU_GETTEXT([external])
 949
 950 GETTEXT_PACKAGE="clutter-1.0"
 951 AC_SUBST(GETTEXT_PACKAGE)
 952 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE],
 953                    ["$GETTEXT_PACKAGE"],
 954                    [The prefix for our gettext translation domains.])
 955 AS_ALL_LINGUAS
 956
 957 dnl ===========================================================================
 958
 959 AC_CONFIG_FILES([
 960         Makefile
 961         config.h.win32
 962         README
 963
 964         build/Makefile
 965         build/autotools/Makefile
 966         build/mingw/Makefile
 967         build/win32/Makefile
 968         build/win32/vs9/Makefile
 969         build/win32/vs10/Makefile
 970
 971         clutter/Makefile
 972         clutter/clutter-config.h
 973         clutter/clutter-version.h
 974         clutter/clutter-version.h.win32
 975         clutter/clutter-$CLUTTER_API_VERSION.pc:clutter/clutter.pc.in
 976
 977         clutter/cally/cally-$CLUTTER_API_VERSION.pc:clutter/cally/cally.pc.in
 978
 979         clutter/cogl/clutter-cex100.h
 980
 981         tests/Makefile
 982         tests/accessibility/Makefile
 983         tests/conform/Makefile
 984         tests/conform/test-launcher.sh
 985         tests/data/Makefile
 986         tests/interactive/Makefile
 987         tests/interactive/wrapper.sh
 988         tests/micro-bench/Makefile
 989         tests/performance/Makefile
 990
 991         doc/Makefile
 992         doc/reference/Makefile
 993         doc/reference/clutter/Makefile
 994         doc/reference/clutter/clutter-docs.xml
 995         doc/reference/cally/Makefile
 996         doc/reference/cally/cally-docs.xml
 997         doc/common/Makefile
 998         doc/cookbook/Makefile
 999         doc/cookbook/clutter-cookbook.xml
1000         doc/cookbook/examples/Makefile
1001
1002         po/Makefile.in
1003 ])
1004
1005 AC_OUTPUT
1006
1007 dnl === Summary ===============================================================
1008
1009 echo ""
1010 echo "Clutter - $VERSION (${CLUTTER_RELEASE_STATUS})"
1011
1012 # Global flags
1013 echo ""
1014 echo " • Global:"
1015 echo "        Prefix: ${prefix}"
1016 echo "        Flavour: ${CLUTTER_WINSYS}"
1017 echo "        Target library: ${CLUTTER_WINSYS_LIB}"
1018
1019 # Compiler/Debug related flags
1020 echo ""
1021 echo " • Compiler options:"
1022 echo "        Clutter debug level: ${enable_debug}"
1023 echo "        Compiler flags: ${CFLAGS} ${MAINTAINER_CFLAGS}"
1024 echo "        Profiling enabled: ${enable_profile}"
1025 echo "        Enable coverage tests: ${enable_gcov}"
1026 echo "        Enable deprecated symbols: ${enable_deprecated}"
1027
1028 # Documentation
1029 echo ""
1030 echo " • Documentation:"
1031 echo "        Build API Reference: ${enable_gtk_doc}"
1032 echo "        Build Additional Documentation: ${enable_docs} (Generate PDF: ${enable_pdfs})"
1033
1034 # Miscellaneous
1035 echo ""
1036 echo " • Extra:"
1037 echo "        Build introspection data: ${enable_introspection}"
1038 echo "        Build conformance test suite: ${enable_conformance}"
1039
1040 # Clutter backend related flags
1041 echo ""
1042 echo " • Clutter Backend:"
1043
1044 if test "x$experimental_backend" = "xno"; then
1045 echo "        Windowing system: ${CLUTTER_WINSYS}"
1046 else
1047 echo "        Windowing system: ${CLUTTER_WINSYS} (WARNING: Experimental)"
1048 fi
1049
1050 if test "x$SUPPORT_XLIB" = "x1"; then
1051 echo "        Enable XComposite: ${have_xcomposite}"
1052 echo "        Enable XInput: ${have_xinput}"
1053 echo "        Enable Xge: ${have_xge}"
1054 echo "        Enable XI2: ${have_xinput2}"
1055 echo "        Enable XKB: ${have_xkb}"
1056 echo "        Enable X11 tests: ${x11_tests}"
1057 fi
1058
1059 echo ""
1060
1061 # General warning about experimental features
1062 if test "x$experimental_backend" = "xyes" ||
1063    test "x$experimental_image" = "xyes"
1064 then
1065 echo ""
1066 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1067 echo " *WARNING*"
1068 echo ""
1069 echo "  The stability of your build might be affected by one or more"
1070 echo "  experimental backends or experimental and unsupported features"
1071 echo "☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠☠"
1072 echo ""
1073 fi