configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_SUBST(DISABLE_MEM_POOLS)
 247   AC_MSG_RESULT([yes])
 248 fi
 249
 250 dnl location to install runtime libraries, e.g. ../../lib to install
 251 dnl to /lib if libdir is /usr/lib
 252 AC_ARG_WITH(runtime-libdir,
 253            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 254                            [install runtime libraries relative to libdir])],
 255            [],
 256            [with_runtime_libdir=""])
 257 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 258 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 259 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 260 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 264 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 265 AC_LANG_SAVE
 266 AC_LANG_CPLUSPLUS
 267 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 268 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 269 AC_LANG_RESTORE
 270
 271 AM_PROG_CC_STDC
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test x$cflags_set != xset ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286
 287   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 288 else
 289   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 290
 291   if test "x$enable_debug" = "xno"; then
 292     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 293   fi
 294 fi
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$glib_native_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 331 AC_SUBST(GLIB_EXTRA_CFLAGS)
 332
 333 AC_EXEEXT
 334
 335 # define a MAINT-like variable REBUILD which is set if Perl
 336 # and awk are found, so autogenerated sources can be rebuilt
 337 AC_PROG_AWK
 338 AC_CHECK_PROGS(PERL, [perl5 perl])
 339 # We would like indent, but don't require it.
 340 AC_CHECK_PROG(INDENT, indent, indent)
 341 REBUILD=\#
 342 if test "x$enable_rebuilds" = "xyes" && \
 343      test -n "$PERL" && \
 344      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 345      test -n "$AWK" ; then
 346   REBUILD=
 347 fi
 348 AC_SUBST(REBUILD)
 349
 350 # Need full path to Perl for glib-mkenums
 351 #
 352 if test "x$PERL" != x ; then
 353   AC_PATH_PROG(PERL_PATH, [$PERL])
 354 fi
 355 if test "x$PERL_PATH" = x ; then
 356   PERL_PATH="/usr/bin/env perl"
 357 fi
 358 AC_SUBST(PERL_PATH)
 359
 360 # Need suitable python path for greport
 361 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 362
 363
 364 dnl ***********************
 365 dnl *** Tests for iconv ***
 366 dnl ***********************
 367 dnl
 368 dnl We do this before the gettext checks, to avoid distortion
 369
 370 dnl On Windows we use a native implementation
 371
 372 if test x"$glib_native_win32" = xyes; then
 373   with_libiconv=native
 374 else
 375   AC_ARG_WITH(libiconv,
 376               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 377                               [use the libiconv library])],,
 378               [with_libiconv=maybe])
 379
 380   found_iconv=no
 381   case $with_libiconv in
 382     maybe)
 383       # Check in the C library first
 384       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385       # Check if we have GNU libiconv
 386       if test $found_iconv = "no"; then
 387         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388       fi
 389       # Check if we have a iconv in -liconv, possibly from vendor
 390       if test $found_iconv = "no"; then
 391         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 392       fi
 393       ;;
 394     no)
 395       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 396       ;;
 397     gnu|yes)
 398       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 399       ;;
 400     native)
 401       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 402       ;;
 403   esac
 404
 405   if test "x$found_iconv" = "xno" ; then
 406      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 407   fi
 408 fi
 409
 410 AC_ARG_ENABLE(iconv-cache,
 411               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 412                               [cache iconv descriptors [default=auto]])],,
 413               [enable_iconv_cache=auto])
 414
 415 AC_MSG_CHECKING([whether to cache iconv descriptors])
 416 case $enable_iconv_cache in
 417   auto)
 418     if test $ac_cv_gnu_library_2_1 = yes; then
 419       enable_iconv_cache=no
 420     else
 421       enable_iconv_cache=yes
 422     fi
 423   ;;
 424   yes|no)
 425   ;;
 426   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 427   ;;
 428 esac
 429
 430 if test $enable_iconv_cache = yes; then
 431    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 432 fi
 433
 434 AC_MSG_RESULT($enable_iconv_cache)
 435
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 if test "x$found_zlib" = "xno" ; then
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 fi
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 if test x"$glib_native_win32" != xyes; then
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 fi
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 if test "x$GCC" = "xyes"; then
 509   case " $CFLAGS " in
 510   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 511   *) CFLAGS="$CFLAGS -Wall" ;;
 512   esac
 513 fi
 514
 515 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 516
 517 if test "$glib_native_win32" = "yes"; then
 518   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 519     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 520   fi
 521   if test x$enable_static = xyes; then
 522     glib_win32_static_compilation=yes
 523     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 524 #define GOBJECT_STATIC_COMPILATION 1"
 525     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 526   fi
 527 fi
 528 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 529
 530 dnl
 531 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 532 dnl
 533 if test $cross_compiling != yes ; then
 534     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 535     glib_save_LIBS=$LIBS
 536     LIBS="$LIBS -lm"
 537     AC_TRY_RUN([#include <math.h>
 538                  int main (void) { return (log(1) != log(1.)); }],
 539          AC_MSG_RESULT(none needed),
 540          glib_save_CFLAGS=$CFLAGS
 541          CFLAGS="$CFLAGS -std1"
 542          AC_TRY_RUN([#include <math.h>
 543                      int main (void) { return (log(1) != log(1.)); }],
 544              AC_MSG_RESULT(-std1),
 545              AC_MSG_RESULT()
 546              CFLAGS=$glib_save_CFLAGS
 547              AC_MSG_WARN(
 548                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 549          )
 550     )
 551     LIBS=$glib_save_LIBS
 552 fi
 553
 554 dnl NeXTStep cc seems to need this
 555 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 556 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 557   AC_MSG_RESULT(none needed),
 558   glib_save_CFLAGS=$CFLAGS
 559   CFLAGS="$CFLAGS -posix"
 560   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 561     AC_MSG_RESULT(-posix),
 562     AC_MSG_RESULT()
 563     CFLAGS=$glib_save_CFLAGS
 564     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 565
 566 # Checks for header files.
 567 AC_HEADER_STDC
 568
 569 # Checks for library functions.
 570 AC_FUNC_VPRINTF
 571 AC_FUNC_ALLOCA
 572 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 573 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 574
 575 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 576 dnl be automatically defined, which we don't want to do
 577 dnl until we have checked this function is actually usable
 578 AC_CHECK_FUNC([qsort_r])
 579
 580 # BSD has a qsort_r with wrong argument order
 581 if test x$ac_cv_func_qsort_r = xyes ; then
 582   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 583   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 584   #define _GNU_SOURCE
 585   #include <stdlib.h>
 586
 587   static int
 588   cmp (const void *a, const void *b, void *c)
 589   {
 590     const int *ia = a;
 591     const int *ib = b;
 592
 593     if (*ia < *ib)
 594       return -1;
 595     else if (*ia > *ib)
 596       return 1;
 597     else
 598       return 0;
 599   }
 600
 601   int
 602   main (int argc, char **argv)
 603   {
 604     int arr[3] = { 1, 2, 0 };
 605     int d = 3;
 606
 607     qsort_r (arr, 3, sizeof (int), cmp, &d);
 608
 609     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 610       return 0;
 611     else
 612       return 1;
 613   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 614 fi
 615
 616 if test x$glib_cv_have_qsort_r = xyes ; then
 617   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 618 fi
 619
 620 AC_CHECK_SIZEOF(char)
 621 AC_CHECK_SIZEOF(short)
 622 AC_CHECK_SIZEOF(long)
 623 AC_CHECK_SIZEOF(int)
 624 AC_CHECK_SIZEOF(void *)
 625 AC_CHECK_SIZEOF(long long)
 626 AC_CHECK_SIZEOF(__int64)
 627
 628 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 629   :
 630 else
 631   AC_MSG_ERROR([
 632 *** GLib requires a 64 bit type. You might want to consider
 633 *** using the GNU C compiler.
 634 ])
 635 fi
 636
 637 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 638         # long long is a 64 bit integer.
 639         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 640         AC_CACHE_VAL(glib_cv_long_long_format,[
 641                 for format in ll q I64; do
 642                   AC_TRY_RUN([#include <stdio.h>
 643                         int main()
 644                         {
 645                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 646                           char buffer[1000];
 647                           sprintf (buffer, "%${format}u", a);
 648                           sscanf (buffer, "%${format}u", &b);
 649                           exit (b!=a);
 650                         }
 651                         ],
 652                         [glib_cv_long_long_format=${format}
 653                         break],
 654                         [],[:])
 655                 done])
 656         if test -n "$glib_cv_long_long_format"; then
 657           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 658           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 659           if test x"$glib_cv_long_long_format" = xI64; then
 660             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 661           fi
 662         else
 663           AC_MSG_RESULT(none)
 664         fi
 665 elif test x$ac_cv_sizeof___int64 = x8; then
 666         # __int64 is a 64 bit integer.
 667         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 668         # We know this is MSVCRT.DLL, and what the formats are
 669         glib_cv_long_long_format=I64
 670         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 671         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 672         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 673 fi
 674
 675 dnl long doubles were not used, and a portability problem
 676 dnl AC_C_LONG_DOUBLE
 677 AC_C_CONST
 678
 679 dnl ok, here we try to check whether the systems prototypes for
 680 dnl malloc and friends actually match the prototypes provided
 681 dnl by gmem.h (keep in sync). i currently only know how to check
 682 dnl this reliably with gcc (-Werror), improvements for other
 683 dnl compilers are apprechiated.
 684 SANE_MALLOC_PROTOS=no
 685 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 686 glib_save_CFLAGS=$CFLAGS
 687 if test "x$GCC" = "xyes"; then
 688   CFLAGS="$CFLAGS -Werror"
 689   AC_TRY_COMPILE([#include <stdlib.h>], [
 690     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 691     void* (*my_malloc_p)  (size_t)         = malloc;
 692     void  (*my_free_p)    (void*)          = free;
 693     void* (*my_realloc_p) (void*, size_t)  = realloc;
 694     my_calloc_p = 0;
 695     my_malloc_p = 0;
 696     my_free_p = 0;
 697     my_realloc_p = 0;
 698   ],
 699     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 700       [Define if you have correct malloc prototypes])
 701     SANE_MALLOC_PROTOS=yes)
 702 fi
 703 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 704 CFLAGS=$glib_save_CFLAGS
 705
 706 dnl
 707 dnl check in which direction the stack grows
 708 dnl
 709 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 710         AC_TRY_RUN([
 711         volatile int *a = 0, *b = 0;
 712         void foo (void);
 713         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 714         void foo (void) { volatile int x = 5; b = &x; }
 715         ],
 716         glib_cv_stack_grows=no
 717         ,
 718         glib_cv_stack_grows=yes
 719         ,)
 720 ])
 721
 722 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 723 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 724 dnl actually supported.
 725 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 726         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 727         __inline int foo () { return 0; }
 728         int main () { return foo (); }
 729         ]])],
 730         glib_cv_has__inline=yes
 731         ,
 732         glib_cv_has__inline=no
 733         ,)
 734 ])
 735 case x$glib_cv_has__inline in
 736 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 737 esac
 738 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 739         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 740         __inline__ int foo () { return 0; }
 741         int main () { return foo (); }
 742         ]])],
 743         glib_cv_has__inline__=yes
 744         ,
 745         glib_cv_has__inline__=no
 746         ,)
 747 ])
 748 case x$glib_cv_has__inline__ in
 749 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 750 esac
 751 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 752         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 753         #undef inline
 754         inline int foo () { return 0; }
 755         int main () { return foo (); }
 756         ]])],
 757         glib_cv_hasinline=yes
 758         ,
 759         glib_cv_hasinline=no
 760         ,)
 761 ])
 762 case x$glib_cv_hasinline in
 763 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 764 esac
 765
 766 # if we can use inline functions in headers
 767 AC_MSG_CHECKING(if inline functions in headers work)
 768 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 769 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 770 #  undef inline
 771 #  define inline __inline__
 772 #elif !defined (G_HAVE_INLINE)
 773 #  undef inline
 774 #  if defined (G_HAVE___INLINE__)
 775 #    define inline __inline__
 776 #  elif defined (G_HAVE___INLINE)
 777 #    define inline __inline
 778 #  endif
 779 #endif
 780
 781 int glib_test_func2 (int);
 782
 783 static inline int
 784 glib_test_func1 (void) {
 785   return glib_test_func2 (1);
 786 }
 787
 788 int
 789 main (void) {
 790   int i = 1;
 791 }]])],[g_can_inline=yes],[g_can_inline=no])
 792 AC_MSG_RESULT($g_can_inline)
 793
 794 dnl *** check for working do while(0) macros ***
 795 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 796         AC_TRY_COMPILE([],[
 797         #define STMT_START do
 798         #define STMT_END while(0)
 799         #define STMT_TEST STMT_START { i = 0; } STMT_END
 800         int main(void) { int i = 1; STMT_TEST; return i; }],
 801         [g_cv_support_dowhile_macros=yes],
 802         [g_cv_support_dowhile_macros=no],
 803         [g_cv_support_dowhile_macros=yes])
 804 ])
 805 if test x$g_cv_support_dowhile_macros = xyes; then
 806   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 807 fi
 808
 809 # check for flavours of varargs macros
 810 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 811 AC_TRY_COMPILE([],[
 812 int a(int p1, int p2, int p3);
 813 #define call_a(...) a(1,__VA_ARGS__)
 814 call_a(2,3);
 815 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 816 AC_MSG_RESULT($g_have_iso_c_varargs)
 817
 818 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 819 if test "$CXX" = ""; then
 820 dnl No C++ compiler
 821   g_have_iso_cxx_varargs=no
 822 else
 823   AC_LANG_CPLUSPLUS
 824   AC_TRY_COMPILE([],[
 825 int a(int p1, int p2, int p3);
 826 #define call_a(...) a(1,__VA_ARGS__)
 827 call_a(2,3);
 828 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 829   AC_LANG_C
 830 fi
 831 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 832
 833 AC_MSG_CHECKING(for GNUC varargs macros)
 834 AC_TRY_COMPILE([],[
 835 int a(int p1, int p2, int p3);
 836 #define call_a(params...) a(1,params)
 837 call_a(2,3);
 838 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 839 AC_MSG_RESULT($g_have_gnuc_varargs)
 840
 841 # check for GNUC visibility support
 842 AC_MSG_CHECKING(for GNUC visibility attribute)
 843 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 844 void
 845 __attribute__ ((visibility ("hidden")))
 846      f_hidden (void)
 847 {
 848 }
 849 void
 850 __attribute__ ((visibility ("internal")))
 851      f_internal (void)
 852 {
 853 }
 854 void
 855 __attribute__ ((visibility ("protected")))
 856      f_protected (void)
 857 {
 858 }
 859 void
 860 __attribute__ ((visibility ("default")))
 861      f_default (void)
 862 {
 863 }
 864 int main (int argc, char **argv)
 865 {
 866         f_hidden();
 867         f_internal();
 868         f_protected();
 869         f_default();
 870         return 0;
 871 }
 872 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 873 AC_MSG_RESULT($g_have_gnuc_visibility)
 874 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 875
 876 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 877 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 878 #else
 879 # include "error: this is not Sun Studio."
 880 #endif
 881 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 882 AC_MSG_RESULT($g_have_sunstudio_visibility)
 883 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 884
 885 # check for bytesex stuff
 886 AC_C_BIGENDIAN
 887 if test x$ac_cv_c_bigendian = xuniversal ; then
 888 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 889 #else
 890 #error Not a big endian.
 891 #endif],
 892     ac_cv_c_bigendian=yes
 893     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 894 #else
 895 #error Not a little endian.
 896 #endif],
 897     ac_cv_c_bigendian=no
 898     ,AC_MSG_WARN([Could not determine endianness.])))
 899 fi
 900
 901
 902 # check for header files
 903 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 904 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 905 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 906 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 907 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 908 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 909 AC_CHECK_HEADERS([linux/magic.h])
 910
 911 # check for structure fields
 912 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 913 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 914 #include <sys/stat.h>
 915 #include <unistd.h>
 916 #ifdef HAVE_SYS_STATFS_H
 917 #include <sys/statfs.h>
 918 #endif
 919 #ifdef HAVE_SYS_PARAM_H
 920 #include <sys/param.h>
 921 #endif
 922 #ifdef HAVE_SYS_MOUNT_H
 923 #include <sys/mount.h>
 924 #endif])
 925 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 926 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 927 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 928 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 929
 930 # Checks for libcharset
 931 AM_LANGINFO_CODESET
 932 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 933 AC_CHECK_FUNCS(setlocale)
 934
 935 # check additional type sizes
 936 AC_CHECK_SIZEOF(size_t)
 937
 938 dnl Try to figure out whether gsize, gssize should be long or int
 939 AC_MSG_CHECKING([for the appropriate definition for size_t])
 940
 941 case $ac_cv_sizeof_size_t in
 942   $ac_cv_sizeof_short)
 943       glib_size_type=short
 944       ;;
 945   $ac_cv_sizeof_int)
 946       glib_size_type=int
 947       ;;
 948   $ac_cv_sizeof_long)
 949       glib_size_type=long
 950       ;;
 951   $ac_cv_sizeof_long_long)
 952       glib_size_type='long long'
 953       ;;
 954   $ac_cv_sizeof__int64)
 955       glib_size_type='__int64'
 956       ;;
 957   *)  AC_MSG_ERROR([No type matching size_t in size])
 958       ;;
 959 esac
 960
 961 dnl If int/long are the same size, we see which one produces
 962 dnl warnings when used in the location as size_t. (This matters
 963 dnl on AIX with xlc)
 964 dnl
 965 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 966    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 967   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 968 #if defined(_AIX) && !defined(__GNUC__)
 969 #pragma options langlvl=stdc89
 970 #endif
 971 #include <stddef.h>
 972 int main ()
 973 {
 974   size_t s = 1;
 975   unsigned int *size_int = &s;
 976   return (int)*size_int;
 977 }
 978     ]])],glib_size_type=int,
 979       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 980 #if defined(_AIX) && !defined(__GNUC__)
 981 #pragma options langlvl=stdc89
 982 #endif
 983 #include <stddef.h>
 984 int main ()
 985 {
 986    size_t s = 1;
 987    unsigned long *size_long = &s;
 988    return (int)*size_long;
 989 }
 990         ]])],glib_size_type=long)])
 991 fi
 992
 993 AC_MSG_RESULT(unsigned $glib_size_type)
 994
 995 # Check for some functions
 996 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 997 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
 998 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 999 # Check for high-resolution sleep functions
1000 AC_CHECK_FUNCS(splice)
1001
1002 # To avoid finding a compatibility unusable statfs, which typically
1003 # successfully compiles, but warns to use the newer statvfs interface:
1004 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1005 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1006
1007 AC_MSG_CHECKING([whether to use statfs or statvfs])
1008 # Some systems have both statfs and statvfs, pick the most "native" for these
1009 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1010    [
1011    # on solaris and irix, statfs doesn't even have the f_bavail field
1012    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1013       [ac_cv_func_statfs=no],
1014    # else, at least on linux, statfs is the actual syscall
1015       [ac_cv_func_statvfs=no])
1016    ])
1017
1018 AS_IF([test x$ac_cv_func_statfs = xyes],
1019       [
1020          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1021          AC_MSG_RESULT([statfs])
1022       ],
1023       [test x$ac_cv_func_statvfs = xyes],
1024       [
1025          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1026          AC_MSG_RESULT([statvfs])
1027       ],
1028       [  AC_MSG_RESULT([neither])])
1029
1030 AC_CHECK_HEADERS(crt_externs.h)
1031 AC_CHECK_FUNCS(_NSGetEnviron)
1032
1033 AC_FUNC_VSNPRINTF_C99
1034 AC_FUNC_PRINTF_UNIX98
1035
1036 # Internet address families
1037 if test $glib_native_win32 = yes; then
1038   glib_inet_includes=["
1039 #include <winsock2.h>
1040   "]
1041 else
1042   glib_inet_includes=["
1043 #include <sys/types.h>
1044 #include <sys/socket.h>
1045   "]
1046 fi
1047
1048 glib_failed=false
1049 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1050 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1051 # winsock defines this even though it doesn't support it
1052 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1053 if $glib_failed ; then
1054   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1055 fi
1056
1057 glib_failed=false
1058 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1059 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1060 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1061 if $glib_failed ; then
1062   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1063 fi
1064
1065 AC_CHECK_FUNCS(getprotobyname_r endservent)
1066 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1067
1068 if test $glib_native_win32 = no; then
1069   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1070   NETWORK_LIBS=""
1071   AC_MSG_CHECKING([for res_query])
1072   AC_TRY_LINK([#include <sys/types.h>
1073                #include <netinet/in.h>
1074                #include <arpa/nameser.h>
1075                #include <resolv.h>
1076               ],[
1077                res_query("test", 0, 0, (void *)0, 0);
1078               ],[AC_MSG_RESULT([yes])],
1079               [save_libs="$LIBS"
1080                LIBS="-lresolv $LIBS"
1081                AC_TRY_LINK([#include <sys/types.h>
1082                             #include <netinet/in.h>
1083                             #include <arpa/nameser.h>
1084                             #include <resolv.h>
1085                            ],[
1086                             res_query("test", 0, 0, (void *)0, 0);
1087                            ],[AC_MSG_RESULT([in -lresolv])
1088                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1089                            [LIBS="-lbind $save_libs"
1090                             AC_TRY_LINK([#include <resolv.h>],
1091                                         [res_query("test", 0, 0, (void *)0, 0);],
1092                                         [AC_MSG_RESULT([in -lbind])
1093                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1094                                         [AC_MSG_ERROR(not found)])])
1095                LIBS="$save_libs"])
1096   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1097                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1098                                         [AC_MSG_ERROR(Could not find socket())]))
1099 fi
1100 AC_SUBST(NETWORK_LIBS)
1101
1102 case $host in
1103   *-*-solaris* )
1104      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1105      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1106      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1107      ;;
1108 esac
1109
1110 dnl
1111 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1112 dnl
1113 if test "$ac_cv_func_statfs" = yes ; then
1114   AC_MSG_CHECKING([number of arguments to statfs()])
1115   AC_TRY_COMPILE([#include <unistd.h>
1116   #ifdef HAVE_SYS_PARAM_H
1117   #include <sys/param.h>
1118   #endif
1119   #ifdef HAVE_SYS_VFS_H
1120   #include <sys/vfs.h>
1121   #endif
1122   #ifdef HAVE_SYS_MOUNT_H
1123   #include <sys/mount.h>
1124   #endif
1125   #ifdef HAVE_SYS_STATFS_H
1126   #include <sys/statfs.h>
1127   #endif], [struct statfs st;
1128   statfs(NULL, &st);],[
1129     AC_MSG_RESULT([2])
1130     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1131     AC_TRY_COMPILE([#include <unistd.h>
1132   #ifdef HAVE_SYS_PARAM_H
1133   #include <sys/param.h>
1134   #endif
1135   #ifdef HAVE_SYS_VFS_H
1136   #include <sys/vfs.h>
1137   #endif
1138   #ifdef HAVE_SYS_MOUNT_H
1139   #include <sys/mount.h>
1140   #endif
1141   #ifdef HAVE_SYS_STATFS_H
1142   #include <sys/statfs.h>
1143   #endif], [struct statfs st;
1144   statfs(NULL, &st, sizeof (st), 0);],[
1145       AC_MSG_RESULT([4])
1146       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1147       AC_MSG_RESULT(unknown)
1148       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1149 fi
1150
1151 #
1152 # Check whether to use an included printf
1153 #
1154
1155 AC_ARG_ENABLE(included-printf,
1156               [AC_HELP_STRING([--enable-included-printf],
1157                               [use included printf [default=auto]])],
1158               enable_included_printf="$enableval")
1159
1160 need_included_printf=no
1161 if test "x$enable_included_printf" = "xyes" ; then
1162   need_included_printf=yes
1163 fi
1164 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1165   need_included_printf=yes
1166 fi
1167 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1168   need_included_printf=yes
1169 fi
1170 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1171    test -z "$glib_cv_long_long_format" ; then
1172   need_included_printf=yes
1173 fi
1174
1175 if test "x$enable_included_printf" = "xno" &&
1176    test "x$need_included_printf" = "xyes" ; then
1177   AC_MSG_ERROR([
1178 *** Your C library's printf doesn't appear to have the features that
1179 *** GLib needs, but you specified --enable-included-printf=no.])
1180 fi
1181
1182 enable_included_printf=$need_included_printf
1183
1184 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1185 if test "$enable_included_printf" != "yes" ; then
1186   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1187 else
1188   if test -z "$glib_cv_long_long_format" ; then
1189     glib_cv_long_long_format="ll"
1190   fi
1191   AC_DEFINE(HAVE_VASPRINTF,1)
1192 fi
1193
1194 # Checks needed for gnulib vasnprintf
1195 bh_C_SIGNED
1196 jm_AC_TYPE_LONG_LONG
1197 gt_TYPE_LONGDOUBLE
1198 gt_TYPE_WCHAR_T
1199 gt_TYPE_WINT_T
1200 AC_TYPE_SIZE_T
1201 AC_CHECK_TYPES(ptrdiff_t)
1202 jm_AC_TYPE_INTMAX_T
1203 AC_CHECK_FUNCS([snprintf wcslen])
1204 AC_FUNC_SNPRINTF_C99
1205
1206 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1207 # The check is borrowed from the PERL Configure script.
1208 if test "$ac_cv_func_memmove" != "yes"; then
1209   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1210     glib_cv_working_bcopy,[AC_TRY_RUN([
1211       int main() {
1212         char buf[128], abc[128], *b;
1213         int len, off, align;
1214         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1215         for (align = 7; align >= 0; align--) {
1216           for (len = 36; len; len--) {
1217             b = buf+align; bcopy(abc, b, len);
1218             for (off = 1; off <= len; off++) {
1219               bcopy(b, b+off, len); bcopy(b+off, b, len);
1220                 if (bcmp(b, abc, len)) return(1);
1221             }
1222           }
1223         }
1224         return(0);
1225       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1226
1227   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1228   if test "$glib_cv_working_bcopy" = "yes"; then
1229     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1230   fi
1231 fi
1232
1233 # Check for sys_errlist
1234 AC_MSG_CHECKING(for sys_errlist)
1235 AC_TRY_LINK(, [
1236 extern char *sys_errlist[];
1237 extern int sys_nerr;
1238 sys_errlist[sys_nerr-1][0] = 0;
1239 ], glib_ok=yes, glib_ok=no)
1240 AC_MSG_RESULT($glib_ok)
1241 if test "$glib_ok" = "no"; then
1242     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1243 fi
1244
1245 # Check for sys_siglist
1246 AC_MSG_CHECKING(for sys_siglist)
1247 AC_TRY_LINK(, [
1248 extern char *sys_siglist[];
1249 exit (sys_siglist[0]);
1250 ], glib_ok=yes, glib_ok=no)
1251 AC_MSG_RESULT($glib_ok)
1252 if test "$glib_ok" = "no"; then
1253     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1254 fi
1255
1256 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1257 AC_MSG_CHECKING(for sys_siglist declaration)
1258 AC_TRY_COMPILE([#include <signal.h>], [
1259 strlen (sys_siglist[0]);
1260 ], glib_ok=yes, glib_ok=no)
1261 AC_MSG_RESULT($glib_ok)
1262 if test "$glib_ok" = "no"; then
1263     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1264 fi
1265
1266 # Check if <sys/select.h> needs to be included for fd_set
1267 AC_MSG_CHECKING([for fd_set])
1268 AC_TRY_COMPILE([#include <sys/types.h>],
1269         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1270 if test "$gtk_ok" = "yes"; then
1271     AC_MSG_RESULT([yes, found in sys/types.h])
1272 else
1273     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1274     if test "$gtk_ok" = "yes"; then
1275         # *** FIXME: give it a different name
1276         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1277         AC_MSG_RESULT([yes, found in sys/select.h])
1278     else
1279         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1280         AC_MSG_RESULT(no)
1281     fi
1282 fi
1283
1284 dnl *** check for sane realloc() ***
1285 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1286         AC_TRY_RUN([#include <stdlib.h>
1287         int main() {
1288           return realloc (0, sizeof (int)) == 0;
1289         }],
1290         [glib_cv_sane_realloc=yes],
1291         [glib_cv_sane_realloc=no],
1292         [glib_cv_sane_realloc=yes])
1293 ])
1294 if test x$glib_cv_sane_realloc = xyes; then
1295   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1296 fi
1297
1298 dnl Check for nl_langinfo and CODESET
1299 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1300         AC_TRY_COMPILE([#include <langinfo.h>],
1301                 [char *codeset = nl_langinfo (CODESET);],
1302                 [glib_cv_langinfo_codeset=yes],
1303                 [glib_cv_langinfo_codeset=no])])
1304 if test x$glib_cv_langinfo_codeset = xyes; then
1305   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1306 fi
1307
1308 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1309 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1310         AC_TRY_COMPILE([#include <langinfo.h>],
1311                 [char *str;
1312                  str = nl_langinfo (PM_STR);
1313                  str = nl_langinfo (D_T_FMT);
1314                  str = nl_langinfo (D_FMT);
1315                  str = nl_langinfo (T_FMT);
1316                  str = nl_langinfo (T_FMT_AMPM);
1317                  str = nl_langinfo (MON_1);
1318                  str = nl_langinfo (ABMON_12);
1319                  str = nl_langinfo (DAY_1);
1320                  str = nl_langinfo (ABDAY_7);],
1321                 [glib_cv_langinfo_time=yes],
1322                 [glib_cv_langinfo_time=no])])
1323 if test x$glib_cv_langinfo_time = xyes; then
1324   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1325 fi
1326
1327 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1328 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1329         AC_TRY_COMPILE([#include <langinfo.h>],
1330                 [char *str;
1331                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1332                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1333                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1334                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1335                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1336                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1337                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1338                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1339                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1340                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1341                 [glib_cv_langinfo_outdigit=yes],
1342                 [glib_cv_langinfo_outdigit=no])])
1343 if test x$glib_cv_langinfo_outdigit = xyes; then
1344   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1345 fi
1346
1347 dnl ****************************************
1348 dnl *** posix_memalign                   ***
1349 dnl ****************************************
1350 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1351 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1352     glib_cv_compliant_posix_memalign=0
1353     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1354         AC_TRY_RUN([
1355                 #define _XOPEN_SOURCE 600
1356                 #include <stdlib.h> /* posix_memalign() should be defined here */
1357                 /* some systems break if #include <malloc.h> used */
1358                 static void test_memalign (size_t boundary, size_t size) {
1359                     void *mem = 0;
1360                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1361                         exit (1);
1362                     else
1363                       free (mem);
1364                 }
1365                 int main() {
1366                     test_memalign (  128,   128 - 2 * sizeof (void*));
1367                     test_memalign (  256,   256 - 2 * sizeof (void*));
1368                     test_memalign (  512,   512 - 2 * sizeof (void*));
1369                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1370                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1371                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1372                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1373                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1374                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1375                     exit (0); /* success */
1376                 }
1377                 ],
1378             [glib_cv_compliant_posix_memalign=1], [], [:])
1379       :
1380     fi
1381     ])
1382 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1383     AC_MSG_RESULT(yes)
1384     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1385 else
1386     AC_MSG_RESULT(no)
1387 fi
1388
1389
1390 dnl ****************************************
1391 dnl *** strlcpy/strlcat                  ***
1392 dnl ****************************************
1393 # Check for strlcpy
1394 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1395 AC_TRY_RUN([#include <stdlib.h>
1396 #include <string.h>
1397 int main() {
1398   char p[10];
1399   (void) strlcpy (p, "hi", 10);
1400   if (strlcat (p, "bye", 0) != 3)
1401     return 1;
1402   return 0;
1403 }], glib_cv_have_strlcpy=yes,
1404     glib_cv_have_strlcpy=no,
1405     glib_cv_have_strlcpy=no)])
1406 if test "$glib_cv_have_strlcpy" = "yes"; then
1407     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1408 fi
1409
1410
1411 dnl **********************
1412 dnl *** va_copy checks ***
1413 dnl **********************
1414 dnl we currently check for all three va_copy possibilities, so we get
1415 dnl all results in config.log for bug reports.
1416 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1417         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1418 #include <stdlib.h>
1419         void f (int i, ...) {
1420         va_list args1, args2;
1421         va_start (args1, i);
1422         va_copy (args2, args1);
1423         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1424           exit (1);
1425         va_end (args1); va_end (args2);
1426         }
1427         int main() {
1428           f (0, 42);
1429           return 0;
1430         }]])],
1431         [glib_cv_va_copy=yes],
1432         [glib_cv_va_copy=no])
1433 ])
1434 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1435         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1436 #include <stdlib.h>
1437         void f (int i, ...) {
1438         va_list args1, args2;
1439         va_start (args1, i);
1440         __va_copy (args2, args1);
1441         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1442           exit (1);
1443         va_end (args1); va_end (args2);
1444         }
1445         int main() {
1446           f (0, 42);
1447           return 0;
1448         }]])],
1449         [glib_cv___va_copy=yes],
1450         [glib_cv___va_copy=no])
1451 ])
1452
1453 if test "x$glib_cv_va_copy" = "xyes"; then
1454   g_va_copy_func=va_copy
1455 else if test "x$glib_cv___va_copy" = "xyes"; then
1456   g_va_copy_func=__va_copy
1457 fi
1458 fi
1459
1460 if test -n "$g_va_copy_func"; then
1461   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1462 fi
1463
1464 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1465         AC_TRY_RUN([#include <stdarg.h>
1466 #include <stdlib.h>
1467         void f (int i, ...) {
1468         va_list args1, args2;
1469         va_start (args1, i);
1470         args2 = args1;
1471         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1472           exit (1);
1473         va_end (args1); va_end (args2);
1474         }
1475         int main() {
1476           f (0, 42);
1477           return 0;
1478         }],
1479         [glib_cv_va_val_copy=yes],
1480         [glib_cv_va_val_copy=no],
1481         [glib_cv_va_val_copy=yes])
1482 ])
1483
1484 if test "x$glib_cv_va_val_copy" = "xno"; then
1485   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1486 fi
1487
1488 dnl ***********************
1489 dnl *** g_module checks ***
1490 dnl ***********************
1491 G_MODULE_LIBS=
1492 G_MODULE_LIBS_EXTRA=
1493 G_MODULE_PLUGIN_LIBS=
1494 if test x"$glib_native_win32" = xyes; then
1495   dnl No use for this on Win32
1496   G_MODULE_LDFLAGS=
1497 else
1498   export SED
1499   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1500 fi
1501 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1502 G_MODULE_NEED_USCORE=0
1503 G_MODULE_BROKEN_RTLD_GLOBAL=0
1504 G_MODULE_HAVE_DLERROR=0
1505 dnl *** force native WIN32 shared lib loader
1506 if test -z "$G_MODULE_IMPL"; then
1507   case "$host" in
1508   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1509   esac
1510 fi
1511 dnl *** force native AIX library loader
1512 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1513 if test -z "$G_MODULE_IMPL"; then
1514   case "$host" in
1515   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1516   esac
1517 fi
1518 dnl *** dlopen() and dlsym() in system libraries
1519 if test -z "$G_MODULE_IMPL"; then
1520         AC_CHECK_FUNC(dlopen,
1521                       [AC_CHECK_FUNC(dlsym,
1522                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1523                       [])
1524 fi
1525 dnl *** load_image (BeOS)
1526 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1527   AC_CHECK_LIB(root, load_image,
1528       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1529       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1530       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1531       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1532       [])
1533 fi
1534 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1535 if test -z "$G_MODULE_IMPL"; then
1536         AC_CHECK_FUNC(NSLinkModule,
1537                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1538                        G_MODULE_NEED_USCORE=1],
1539                       [])
1540 fi
1541 dnl *** dlopen() and dlsym() in libdl
1542 if test -z "$G_MODULE_IMPL"; then
1543         AC_CHECK_LIB(dl, dlopen,
1544                      [AC_CHECK_LIB(dl, dlsym,
1545                                    [G_MODULE_LIBS=-ldl
1546                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1547                      [])
1548 fi
1549 dnl *** shl_load() in libdld (HP-UX)
1550 if test -z "$G_MODULE_IMPL"; then
1551         AC_CHECK_LIB(dld, shl_load,
1552                 [G_MODULE_LIBS=-ldld
1553                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1554                 [])
1555 fi
1556 dnl *** additional checks for G_MODULE_IMPL_DL
1557 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1558         LIBS_orig="$LIBS"
1559         LDFLAGS_orig="$LDFLAGS"
1560         LIBS="$G_MODULE_LIBS $LIBS"
1561         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1562 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1563         echo "void glib_plugin_test(void) { }" > plugin.c
1564         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1565                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1566         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1567                 glib_cv_rtldglobal_broken,[
1568                 AC_TRY_RUN([
1569 #include <dlfcn.h>
1570 #ifndef RTLD_GLOBAL
1571 #  define RTLD_GLOBAL 0
1572 #endif
1573 #ifndef RTLD_LAZY
1574 #  define RTLD_LAZY 0
1575 #endif
1576 int glib_plugin_test;
1577 int main () {
1578     void *handle, *global, *local;
1579     global = &glib_plugin_test;
1580     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1581     if (!handle) return 0;
1582     local = dlsym (handle, "glib_plugin_test");
1583     return global == local;
1584 }                       ],
1585                         [glib_cv_rtldglobal_broken=no],
1586                         [glib_cv_rtldglobal_broken=yes],
1587                         [glib_cv_rtldglobal_broken=no])
1588                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1589                 rmdir .libs 2>/dev/null
1590         ])
1591         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1592                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1593         else
1594                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1595         fi
1596 dnl *** check whether we need preceeding underscores
1597         AC_CACHE_CHECK([for preceeding underscore in symbols],
1598                 glib_cv_uscore,[
1599                 AC_TRY_RUN([#include <dlfcn.h>
1600                 int glib_underscore_test (void) { return 42; }
1601                 int main() {
1602                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1603                   handle = dlopen ((void*)0, 0);
1604                   if (handle) {
1605                     f1 = dlsym (handle, "glib_underscore_test");
1606                     f2 = dlsym (handle, "_glib_underscore_test");
1607                   } return (!f2 || f1);
1608                 }],
1609                         [glib_cv_uscore=yes],
1610                         [glib_cv_uscore=no],
1611                         [])
1612                 rm -f plugin.c plugin.$ac_objext plugin.lo
1613         ])
1614         GLIB_ASSERT_SET(glib_cv_uscore)
1615         if test "x$glib_cv_uscore" = "xyes"; then
1616                 G_MODULE_NEED_USCORE=1
1617         else
1618                 G_MODULE_NEED_USCORE=0
1619         fi
1620
1621         LDFLAGS="$LDFLAGS_orig"
1622 dnl *** check for having dlerror()
1623         AC_CHECK_FUNC(dlerror,
1624                 [G_MODULE_HAVE_DLERROR=1],
1625                 [G_MODULE_HAVE_DLERROR=0])
1626         LIBS="$LIBS_orig"
1627 fi
1628 dnl *** done, have we got an implementation?
1629 if test -z "$G_MODULE_IMPL"; then
1630         G_MODULE_IMPL=0
1631         G_MODULE_SUPPORTED=false
1632 else
1633         G_MODULE_SUPPORTED=true
1634 fi
1635
1636 AC_MSG_CHECKING(for the suffix of module shared libraries)
1637 export SED
1638 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1639 eval $shrext_cmds
1640 module=yes eval std_shrext=$shrext_cmds
1641 # chop the initial dot
1642 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1643 AC_MSG_RESULT(.$glib_gmodule_suffix)
1644 # any reason it may fail?
1645 if test "x$glib_gmodule_suffix" = x; then
1646         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1647 fi
1648
1649 AC_SUBST(G_MODULE_SUPPORTED)
1650 AC_SUBST(G_MODULE_IMPL)
1651 AC_SUBST(G_MODULE_LIBS)
1652 AC_SUBST(G_MODULE_LIBS_EXTRA)
1653 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1654 AC_SUBST(G_MODULE_LDFLAGS)
1655 AC_SUBST(G_MODULE_HAVE_DLERROR)
1656 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1657 AC_SUBST(G_MODULE_NEED_USCORE)
1658 AC_SUBST(GLIB_DEBUG_FLAGS)
1659
1660 dnl **********************
1661 dnl *** g_spawn checks ***
1662 dnl **********************
1663
1664 AC_MSG_CHECKING(for gspawn implementation)
1665 case "$host" in
1666   *-*-mingw*)
1667     GSPAWN=gspawn-win32.lo
1668     ;;
1669   *)
1670     GSPAWN=gspawn.lo
1671     ;;
1672 esac
1673 AC_MSG_RESULT($GSPAWN)
1674 AC_SUBST(GSPAWN)
1675
1676 dnl *************************
1677 dnl *** GIOChannel checks ***
1678 dnl *************************
1679
1680 AC_MSG_CHECKING(for GIOChannel implementation)
1681 case "$host" in
1682   *-*-mingw*)
1683     GIO=giowin32.lo
1684     ;;
1685   *)
1686     GIO=giounix.lo
1687     ;;
1688 esac
1689 AC_MSG_RESULT($GIO)
1690 AC_SUBST(GIO)
1691
1692 dnl *********************************
1693 dnl *** Directory for GIO modules ***
1694 dnl *********************************
1695
1696 AC_ARG_WITH(gio-module-dir,
1697            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1698                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1699            [],
1700            [with_gio_module_dir='${libdir}/gio/modules'])
1701 GIO_MODULE_DIR=$with_gio_module_dir
1702 AC_SUBST(GIO_MODULE_DIR)
1703
1704 dnl **********************************
1705 dnl *** Check for libselinux (GIO) ***
1706 dnl **********************************
1707 AC_ARG_ENABLE(selinux,
1708               AC_HELP_STRING([--disable-selinux],
1709                              [build without selinux support]))
1710 msg_selinux=no
1711 SELINUX_LIBS=
1712 if test "x$enable_selinux" != "xno"; then
1713
1714  AC_CHECK_LIB(selinux, is_selinux_enabled,
1715    [AC_CHECK_HEADERS(selinux/selinux.h,
1716      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1717        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1718         SELINUX_LIBS="-lselinux"
1719         msg_selinux=yes])
1720      ])
1721    ])
1722 fi
1723 AC_SUBST(SELINUX_LIBS)
1724
1725 dnl *****************************
1726 dnl ** Check for inotify (GIO) **
1727 dnl *****************************
1728 inotify_support=no
1729 AC_CHECK_HEADERS([sys/inotify.h],
1730 [
1731         inotify_support=yes
1732         AC_CHECK_FUNCS(inotify_init1)
1733 ])
1734
1735 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1736
1737 dnl *********************************
1738 dnl ** Check for Solaris FEN (GIO) **
1739 dnl *********************************
1740 fen_support=no
1741 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1742 #include <port.h>
1743 #ifndef PORT_SOURCE_FILE
1744 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1745 #endif
1746 int main() { return 0; } ]])],
1747 [
1748         fen_support=yes
1749 ],)
1750
1751 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1752
1753 dnl ****************************
1754 dnl *** Checks for FAM (GIO) ***
1755 dnl ****************************
1756
1757 should_disable_fam=no
1758
1759 AC_ARG_ENABLE(fam,
1760               AC_HELP_STRING([--disable-fam],
1761                              [don't use fam for file system monitoring]),
1762                          [
1763                                 if test "x$enable_fam" = "xno"; then
1764                                         should_disable_fam=yes
1765                                 fi
1766                          ]
1767                          )
1768 fam_support=no
1769 FAM_LIBS=
1770 if test "x$should_disable_fam" = "xno"; then
1771 AC_CHECK_LIB(fam, FAMOpen,
1772   [AC_CHECK_HEADERS(fam.h,
1773     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1774      AC_CHECK_LIB(fam, FAMNoExists,
1775                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1776      FAM_LIBS="-lfam"]
1777      fam_support=yes,
1778     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1779   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1780 AC_SUBST(FAM_LIBS)
1781 fi
1782 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1783
1784
1785 dnl *****************************
1786 dnl *** Check for xattr (GIO) ***
1787 dnl *****************************
1788 AC_ARG_ENABLE(xattr,
1789               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1790 msg_xattr=no
1791 XATTR_LIBS=
1792 if test "x$enable_xattr" != "xno"; then
1793
1794 dnl either glibc or libattr can provide xattr support
1795
1796 dnl for both of them, we check for getxattr being in
1797 dnl the library and a valid xattr header.
1798
1799 dnl try glibc
1800  AC_CHECK_LIB(c, getxattr,
1801    [AC_CHECK_HEADERS(sys/xattr.h,
1802      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1803       msg_xattr=yes])
1804    ])
1805
1806   if test "x$msg_xattr" != "xyes"; then
1807 dnl   failure. try libattr
1808    AC_CHECK_LIB(attr, getxattr,
1809       [AC_CHECK_HEADERS(attr/xattr.h,
1810        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1811         XATTR_LIBS="-lattr"
1812         msg_xattr=yes])
1813       ])
1814   fi
1815
1816   if test "x$msg_xattr" = "xyes"; then
1817     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1818     AC_TRY_COMPILE([
1819       #include <stdio.h>
1820       #ifdef HAVE_SYS_TYPES_H
1821       #include <sys/types.h>
1822       #endif
1823       #ifdef HAVE_SYS_XATTR_H
1824       #include <sys/xattr.h>
1825       #elif HAVE_ATTR_XATTR_H
1826       #include <attr/xattr.h>
1827       #endif
1828     ],
1829     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1830     [
1831       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1832       AC_MSG_RESULT([yes])
1833     ],
1834     [AC_MSG_RESULT([no])]
1835     )
1836   fi
1837
1838 fi
1839 AC_SUBST(XATTR_LIBS)
1840
1841 dnl ****************************************
1842 dnl *** platform dependent source checks ***
1843 dnl ****************************************
1844
1845 AC_MSG_CHECKING(for platform-dependent source)
1846 case "$host" in
1847   *-*-cygwin*|*-*-mingw*)
1848     PLATFORMDEP=gwin32.lo
1849     ;;
1850   *)
1851     PLATFORMDEP=
1852     ;;
1853 esac
1854 AC_MSG_RESULT($PLATFORMDEP)
1855 AC_SUBST(PLATFORMDEP)
1856
1857 AC_MSG_CHECKING([whether to compile timeloop])
1858 case "$host" in
1859   *-*-cygwin*|*-*-mingw*|*-*-minix)
1860     enable_timeloop=no
1861     ;;
1862   *)
1863     enable_timeloop=yes
1864     ;;
1865 esac
1866 AC_MSG_RESULT($enable_timeloop)
1867 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1868
1869 AC_MSG_CHECKING([if building for some Win32 platform])
1870 case "$host" in
1871   *-*-mingw*|*-*-cygwin*)
1872     platform_win32=yes
1873     ;;
1874   *)
1875     platform_win32=no
1876     ;;
1877 esac
1878 AC_MSG_RESULT($platform_win32)
1879 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1880
1881 dnl ***********************
1882 dnl *** g_thread checks ***
1883 dnl ***********************
1884
1885 AC_ARG_WITH(threads,
1886            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1887                            [specify a thread implementation to use])],
1888            [if test "x$with_threads" = x; then
1889                 want_threads=yes
1890             else
1891                 want_threads=$with_threads
1892             fi],
1893            [want_threads=yes])
1894
1895 dnl error and warning message
1896 dnl *************************
1897
1898 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1899                 computer."
1900
1901 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1902                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1903                 compilation now, but then your programs might not work.
1904                 Please provide information on how it is done on your system."
1905
1906 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1907                 "
1908
1909 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1910                 provide information on your thread implementation."
1911
1912 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1913                 functions will not be MT-safe during their first call because
1914                 there is no working 'getpwuid_r' on your system."
1915
1916 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1917                 because there is no 'localtime_r' on your system."
1918
1919 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1920                 crude surrogate will be used. If you happen to know a
1921                 yield function for your system, please inform the GLib
1922                 developers."
1923
1924 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1925                 threads on your system. Thus threads can only have the default
1926                 priority. If you happen to know these main/max
1927                 priorities, please inform the GLib developers."
1928
1929 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1930                 linking threaded applications. As GLib cannot do that
1931                 automatically, you will get an linkg error everytime you are
1932                 not using the right compiler. In that case you have to relink
1933                 with the right compiler. Ususally just '_r' is appended
1934                 to the compiler name."
1935
1936 dnl determination of thread implementation
1937 dnl ***************************************
1938
1939 have_threads=no
1940 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1941                                 || test "x$want_threads" = xdce; then
1942         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1943         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1944         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1945         glib_save_CPPFLAGS="$CPPFLAGS"
1946         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1947         if test "x$have_threads" = xno; then
1948                 AC_TRY_COMPILE([#include <pthread.h>],
1949                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1950                         have_threads=posix)
1951         fi
1952         # Tru64Unix requires -pthread to find pthread.h. See #103020
1953         CPPFLAGS="$CPPFLAGS -pthread"
1954         if test "x$have_threads" = xno; then
1955         AC_TRY_COMPILE([#include <pthread.h>],
1956                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1957                        have_threads=posix)
1958         fi
1959         CPPFLAGS="$glib_save_CPPFLAGS"
1960 fi
1961 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1962         case $host in
1963                 *-*-mingw*)
1964                 have_threads=win32
1965                 ;;
1966         esac
1967 fi
1968
1969 AC_MSG_CHECKING(for thread implementation)
1970
1971 if test "x$have_threads" = xno; then
1972         AC_MSG_RESULT(none available)
1973         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1974 else
1975         AC_MSG_RESULT($have_threads)
1976 fi
1977
1978
1979 dnl determination of G_THREAD_CFLAGS
1980 dnl ********************************
1981
1982 G_THREAD_LIBS=
1983 G_THREAD_LIBS_EXTRA=
1984 G_THREAD_CFLAGS=
1985
1986 dnl
1987 dnl Test program for basic POSIX threads functionality
1988 dnl
1989 m4_define([glib_thread_test],[
1990 #include <pthread.h>
1991 int check_me = 0;
1992 void* func(void* data) {check_me = 42; return &check_me;}
1993 int main()
1994  { pthread_t t;
1995    void *ret;
1996    pthread_create (&t, $1, func, 0);
1997    pthread_join (t, &ret);
1998    return (check_me != 42 || ret != &check_me);
1999 }])
2000
2001 dnl
2002 dnl Test program for sched_get_priority_min()
2003 dnl
2004 m4_define([glib_sched_priority_test],[
2005 #include <sched.h>
2006 #include <errno.h>
2007 int main() {
2008     errno = 0;
2009     return sched_get_priority_min(SCHED_OTHER)==-1
2010            && errno != 0;
2011 }])
2012
2013 if test x"$have_threads" = xposix; then
2014   # First we test for posix, whether -pthread or -pthreads do the trick as
2015   # both CPPFLAG and LIBS.
2016   # One of them does for most gcc versions and some other platforms/compilers
2017   # too and could be considered as the canonical way to go.
2018   case $host in
2019     *-*-cygwin*|*-*-darwin*)
2020        # skip cygwin and darwin -pthread or -pthreads test
2021        ;;
2022     *-solaris*)
2023       # These compiler/linker flags work with both Sun Studio and gcc
2024       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2025       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2026       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2027       G_THREAD_LIBS="-lpthread -lthread"
2028       ;;
2029     *)
2030       for flag in pthread pthreads mt; do
2031         glib_save_CFLAGS="$CFLAGS"
2032         CFLAGS="$CFLAGS -$flag"
2033         AC_TRY_RUN(glib_thread_test(0),
2034                    glib_flag_works=yes,
2035                    glib_flag_works=no,
2036                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2037                                    glib_flag_works=yes,
2038                                    glib_flag_works=no)])
2039         CFLAGS="$glib_save_CFLAGS"
2040         if test $glib_flag_works = yes ; then
2041            G_THREAD_CFLAGS=-$flag
2042         G_THREAD_LIBS=-$flag
2043         break;
2044         fi
2045       done
2046        ;;
2047   esac
2048 fi
2049
2050 if test x"$G_THREAD_CFLAGS" = x; then
2051
2052   # The canonical -pthread[s] does not work. Try something different.
2053
2054   case $host in
2055         *-aix*)
2056                 if test x"$GCC" = xyes; then
2057                         # GCC 3.0 and above needs -pthread.
2058                         # Should be coverd by the case above.
2059                         # GCC 2.x and below needs -mthreads
2060                         G_THREAD_CFLAGS="-mthreads"
2061                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2062                 else
2063                         # We are probably using the aix compiler. Normaly a
2064                         # program would have to be compiled with the _r variant
2065                         # of the corresponding compiler, but we as GLib cannot
2066                         # do that: but the good news is that for compiling the
2067                         # only difference is the added -D_THREAD_SAFE compile
2068                         # option. This is according to the "C for AIX User's
2069                         # Guide".
2070                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2071                 fi
2072                 ;;
2073         *-dg-dgux*)  # DG/UX
2074                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2075                 ;;
2076         *-sysv5uw7*) # UnixWare 7
2077                 # We are not using gcc with -pthread. Catched above.
2078                 G_THREAD_CFLAGS="-Kthread"
2079                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2080                 ;;
2081         *-mingw*)
2082                 # No flag needed when using MSVCRT.DLL
2083                 G_THREAD_CFLAGS=""
2084                 ;;
2085         *)
2086                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2087                 ;;
2088   esac
2089
2090 fi
2091
2092 # if we are not finding the localtime_r function, then we probably are
2093 # not using the proper multithread flag
2094
2095 glib_save_CPPFLAGS="$CPPFLAGS"
2096 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2097
2098 # First we test, whether localtime_r is declared in time.h
2099 # directly. Then we test whether a macro localtime_r exists, in
2100 # which case localtime_r in the test program is replaced and thus
2101 # if we still find localtime_r in the output, it is not defined as
2102 # a macro.
2103
2104 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2105   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2106                                                            localtime_r(a,b)],
2107                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2108
2109 CPPFLAGS="$glib_save_CPPFLAGS"
2110
2111 AC_MSG_CHECKING(thread related cflags)
2112 AC_MSG_RESULT($G_THREAD_CFLAGS)
2113 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2114
2115 dnl determination of G_THREAD_LIBS
2116 dnl ******************************
2117
2118 mutex_has_default=no
2119 case $have_threads in
2120         posix)
2121           glib_save_CPPFLAGS="$CPPFLAGS"
2122           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2123           if test x"$G_THREAD_LIBS" = x; then
2124             case $host in
2125               *-aix*)
2126                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2127                 # probably using the aix compiler.
2128                 AC_MSG_WARN($AIX_COMPILE_INFO)
2129                 ;;
2130               *)
2131                 G_THREAD_LIBS=error
2132                 glib_save_LIBS="$LIBS"
2133                 for thread_lib in "" pthread pthread32 pthreads thread; do
2134                         if test x"$thread_lib" = x; then
2135                                 add_thread_lib=""
2136                                 IN=""
2137                         else
2138                                 add_thread_lib="-l$thread_lib"
2139                                 IN=" in -l$thread_lib"
2140                         fi
2141                         if test x"$have_threads" = xposix; then
2142                                 defattr=0
2143                         else
2144                                 defattr=pthread_attr_default
2145                         fi
2146
2147                         LIBS="$add_thread_lib $glib_save_LIBS"
2148
2149                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2150                         AC_TRY_RUN(glib_thread_test($defattr),
2151                                    glib_result=yes,
2152                                    glib_result=no,
2153                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2154                                                    glib_result=yes,
2155                                                    glib_result=no)])
2156                         AC_MSG_RESULT($glib_result)
2157
2158                         if test "$glib_result" = "yes" ; then
2159                           G_THREAD_LIBS="$add_thread_lib"
2160                           break
2161                         fi
2162                 done
2163                 if test "x$G_THREAD_LIBS" = xerror; then
2164                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2165                 fi
2166                 LIBS="$glib_save_LIBS"
2167                 ;;
2168             esac
2169           fi
2170
2171           glib_save_LIBS="$LIBS"
2172           for thread_lib in "" rt rte; do
2173             if test x"$thread_lib" = x; then
2174               add_thread_lib=""
2175               IN=""
2176             else
2177               add_thread_lib="-l$thread_lib"
2178               IN=" in -l$thread_lib"
2179             fi
2180             LIBS="$add_thread_lib $glib_save_LIBS"
2181
2182             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2183             AC_TRY_RUN(glib_sched_priority_test,
2184                        glib_result=yes,
2185                        glib_result=no,
2186                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2187                                        glib_result=yes,
2188                                        glib_result=no)])
2189             AC_MSG_RESULT($glib_result)
2190
2191             if test "$glib_result" = "yes" ; then
2192                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2193                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2194                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2195                break
2196             fi
2197           done
2198           LIBS="$glib_save_LIBS"
2199           mutex_has_default=yes
2200           mutex_default_type='pthread_mutex_t'
2201           mutex_default_init='PTHREAD_MUTEX_INITIALIZER'
2202           mutex_header_file='pthread.h'
2203           g_threads_impl="POSIX"
2204           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2205           CPPFLAGS="$glib_save_CPPFLAGS"
2206           ;;
2207         win32)
2208            g_threads_impl="WIN32"
2209            ;;
2210         *)
2211            g_threads_impl="NONE"
2212            G_THREAD_LIBS=error
2213            ;;
2214 esac
2215
2216 if test "x$G_THREAD_LIBS" = xerror; then
2217         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2218 fi
2219
2220 case $host in
2221   *-*-beos*)
2222     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2223     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2224     ;;
2225   *)
2226     ;;
2227 esac
2228
2229 AC_MSG_CHECKING(thread related libraries)
2230 AC_MSG_RESULT($G_THREAD_LIBS)
2231
2232 dnl check for mt safe function variants and some posix functions
2233 dnl ************************************************************
2234
2235 glib_save_LIBS="$LIBS"
2236 # we are not doing the following for now, as this might require glib
2237 # to always be linked with the thread libs on some platforms.
2238 # LIBS="$LIBS $G_THREAD_LIBS"
2239 AC_CHECK_FUNCS(localtime_r gmtime_r)
2240 if test "$ac_cv_header_pwd_h" = "yes"; then
2241         AC_CACHE_CHECK([for posix getpwuid_r],
2242                 ac_cv_func_posix_getpwuid_r,
2243                 [AC_TRY_RUN([
2244 #include <errno.h>
2245 #include <pwd.h>
2246 int main () {
2247     char buffer[10000];
2248     struct passwd pwd, *pwptr = &pwd;
2249     int error;
2250     errno = 0;
2251     error = getpwuid_r (0, &pwd, buffer,
2252                         sizeof (buffer), &pwptr);
2253    return (error < 0 && errno == ENOSYS)
2254            || error == ENOSYS;
2255 }                               ],
2256                         [ac_cv_func_posix_getpwuid_r=yes],
2257                         [ac_cv_func_posix_getpwuid_r=no])])
2258         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2259         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2260                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2261                         [Have POSIX function getpwuid_r])
2262         else
2263                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2264                         ac_cv_func_nonposix_getpwuid_r,
2265                         [AC_TRY_LINK([#include <pwd.h>],
2266                                 [char buffer[10000];
2267                                 struct passwd pwd;
2268                                 getpwuid_r (0, &pwd, buffer,
2269                                                 sizeof (buffer));],
2270                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2271                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2272                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2273                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2274                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2275                                 [Have non-POSIX function getpwuid_r])
2276                 fi
2277         fi
2278 fi
2279 if test "$ac_cv_header_grp_h" = "yes"; then
2280         AC_CACHE_CHECK([for posix getgrgid_r],
2281                 ac_cv_func_posix_getgrgid_r,
2282                 [AC_TRY_RUN([
2283 #include <errno.h>
2284 #include <grp.h>
2285 int main () {
2286     char buffer[10000];
2287     struct group grp, *grpptr = &grp;
2288     int error;
2289     errno = 0;
2290     error = getgrgid_r (0, &grp, buffer,
2291                         sizeof (buffer), &grpptr);
2292    return (error < 0 && errno == ENOSYS)
2293            || error == ENOSYS;
2294 }                              ],
2295                        [ac_cv_func_posix_getgrgid_r=yes],
2296                        [ac_cv_func_posix_getgrgid_r=no])])
2297         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2298         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2299                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2300                         [Have POSIX function getgrgid_r])
2301         else
2302                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2303                         ac_cv_func_nonposix_getgrgid_r,
2304                         [AC_TRY_LINK([#include <grp.h>],
2305                                 [char buffer[10000];
2306                                 struct group grp;
2307                                 getgrgid_r (0, &grp, buffer,
2308                                 sizeof (buffer));],
2309                         [ac_cv_func_nonposix_getgrgid_r=yes],
2310                         [ac_cv_func_nonposix_getgrgid_r=no])])
2311                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2312                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2313                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2314                                 [Have non-POSIX function getgrgid_r])
2315                 fi
2316         fi
2317 fi
2318 LIBS="$G_THREAD_LIBS $LIBS"
2319 if test x"$have_threads" = xposix; then
2320         glib_save_CPPFLAGS="$CPPFLAGS"
2321         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2322         dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2323         GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2324         # This is not AC_CHECK_FUNC to also work with function
2325         # name mangling in header files.
2326         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2327         AC_TRY_LINK([#include <pthread.h>],
2328                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2329                 [AC_MSG_RESULT(yes)
2330                 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2331                           [Have function pthread_attr_setstacksize])],
2332                 [AC_MSG_RESULT(no)])
2333         AC_MSG_CHECKING(for minimal/maximal thread priority)
2334         if test x"$posix_priority_min" = x; then
2335                 AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2336                         PX_PRIO_MIN],,[
2337                         posix_priority_min=PX_PRIO_MIN
2338                         posix_priority_max=PX_PRIO_MAX])
2339         fi
2340         if test x"$posix_priority_min" = x; then
2341                 # AIX
2342                 AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2343                         PTHREAD_PRIO_MIN],,[
2344                         posix_priority_min=PTHREAD_PRIO_MIN
2345                         posix_priority_max=PTHREAD_PRIO_MAX])
2346         fi
2347         if test x"$posix_priority_min" = x; then
2348                 AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2349                         PRI_OTHER_MIN],,[
2350                         posix_priority_min=PRI_OTHER_MIN
2351                         posix_priority_max=PRI_OTHER_MAX])
2352         fi
2353         if test x"$posix_priority_min" = x; then
2354                 AC_MSG_RESULT(none found)
2355                 AC_MSG_WARN($POSIX_NO_PRIORITIES)
2356                 posix_priority_min=-1
2357                 posix_priority_max=-1
2358         else
2359                 AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2360                 AC_MSG_CHECKING(for pthread_setschedparam)
2361                 AC_TRY_LINK([#include <pthread.h>],
2362                   [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2363                   [AC_MSG_RESULT(yes)
2364                 AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2365                    AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2366                   [AC_MSG_RESULT(no)
2367                    AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2368         fi
2369         posix_yield_func=none
2370         AC_MSG_CHECKING(for posix yield function)
2371         for yield_func in sched_yield pthread_yield_np pthread_yield \
2372                                                 thr_yield; do
2373                 AC_TRY_LINK([#include <pthread.h>],
2374                         [$yield_func()],
2375                         [posix_yield_func="$yield_func"
2376                         break])
2377         done
2378         if test x"$posix_yield_func" = xnone; then
2379                 AC_MSG_RESULT(none found)
2380                 AC_MSG_WARN($POSIX_NO_YIELD)
2381                 posix_yield_func="g_usleep(1000)"
2382         else
2383                 AC_MSG_RESULT($posix_yield_func)
2384                 posix_yield_func="$posix_yield_func()"
2385         fi
2386         AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2387         CPPFLAGS="$glib_save_CPPFLAGS"
2388
2389 elif test x"$have_threads" = xwin32; then
2390         # It's a pointer to a private struct
2391         GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2392 fi
2393
2394 LIBS="$glib_save_LIBS"
2395
2396 # now spit out all the warnings.
2397 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2398    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2399         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2400 fi
2401 if test "$ac_cv_func_localtime_r" != "yes"; then
2402         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2403 fi
2404
2405 if test x"$glib_cv_sizeof_system_thread" = x; then
2406    # use a pointer as a fallback.
2407    GLIB_SIZEOF(,void *, system_thread)
2408 fi
2409
2410 #
2411 # Hack to deal with:
2412 #
2413 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2414 #     building shared libraries with linux.
2415 #  b) FreeBSD doesn't do this either.
2416 #
2417 case $host in
2418   *-*-freebsd*|*-*-linux*)
2419     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2420     ;;
2421   *)
2422     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2423     ;;
2424 esac
2425
2426 AC_SUBST(G_THREAD_CFLAGS)
2427 AC_SUBST(G_THREAD_LIBS)
2428 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2429 AC_SUBST(G_THREAD_LIBS_EXTRA)
2430
2431 dnl **********************************************
2432 dnl *** GDefaultMutex setup and initialization ***
2433 dnl **********************************************
2434 dnl
2435 dnl if mutex_has_default = yes, we also got
2436 dnl mutex_default_type, mutex_default_init and mutex_header_file
2437 if test $mutex_has_default = yes ; then
2438         glib_save_CPPFLAGS="$CPPFLAGS"
2439         glib_save_LIBS="$LIBS"
2440         LIBS="$G_THREAD_LIBS $LIBS"
2441         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2442         GLIB_SIZEOF([#include <$mutex_header_file>],
2443                     $mutex_default_type,
2444                     gmutex)
2445         GLIB_BYTE_CONTENTS([#include <$mutex_header_file>],
2446                            $mutex_default_type,
2447                            gmutex,
2448                            $glib_cv_sizeof_gmutex,
2449                            $mutex_default_init)
2450         if test x"$glib_cv_byte_contents_gmutex" = xno; then
2451                 mutex_has_default=no
2452         fi
2453         CPPFLAGS="$glib_save_CPPFLAGS"
2454         LIBS="$glib_save_LIBS"
2455 fi
2456
2457 AC_CHECK_FUNCS(clock_gettime, [], [
2458   AC_CHECK_LIB(rt, clock_gettime, [
2459     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2460     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2461     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2462     GLIB_RT_LIBS="-lrt"
2463   ])
2464 ])
2465 AC_SUBST(GLIB_RT_LIBS)
2466
2467 AC_CACHE_CHECK(for monotonic clocks,
2468     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2469 #include <time.h>
2470 #include <unistd.h>
2471 int main() {
2472 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2473         #error No monotonic clock
2474 #endif
2475         return 0;
2476 }
2477 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2478 if test "$glib_cv_monotonic_clock" = "yes"; then
2479   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2480 fi
2481
2482
2483 dnl ************************
2484 dnl *** g_atomic_* tests ***
2485 dnl ************************
2486
2487 AC_MSG_CHECKING([whether to use assembler code for atomic operations])
2488     case $host_cpu in
2489       i386)
2490         AC_MSG_RESULT([none])
2491         glib_memory_barrier_needed=no
2492         ;;
2493       i?86)
2494         AC_MSG_RESULT([i486])
2495         AC_DEFINE_UNQUOTED(G_ATOMIC_I486, 1,
2496                            [i486 atomic implementation])
2497         glib_memory_barrier_needed=no
2498         ;;
2499       sparc*)
2500         SPARCV9_WARNING="Try to rerun configure with CFLAGS='-mcpu=v9',
2501                          when you are using a sparc with v9 instruction set (most
2502                          sparcs nowadays). This will make the code for atomic
2503                          operations much faster. The resulting code will not run
2504                          on very old sparcs though."
2505
2506         AC_LINK_IFELSE([AC_LANG_SOURCE([[
2507           main ()
2508           {
2509             int tmp1, tmp2, tmp3;
2510             __asm__ __volatile__("casx [%2], %0, %1"
2511                                  : "=&r" (tmp1), "=&r" (tmp2) : "r" (&tmp3));
2512           }]])],
2513           AC_MSG_RESULT([sparcv9])
2514           AC_DEFINE_UNQUOTED(G_ATOMIC_SPARCV9, 1,
2515                              [sparcv9 atomic implementation]),
2516           AC_MSG_RESULT([no])
2517           AC_MSG_WARN([[$SPARCV9_WARNING]]))
2518         glib_memory_barrier_needed=yes
2519         ;;
2520       alpha*)
2521         AC_MSG_RESULT([alpha])
2522         AC_DEFINE_UNQUOTED(G_ATOMIC_ALPHA, 1,
2523                            [alpha atomic implementation])
2524         glib_memory_barrier_needed=yes
2525         ;;
2526       x86_64)
2527         AC_MSG_RESULT([x86_64])
2528         AC_DEFINE_UNQUOTED(G_ATOMIC_X86_64, 1,
2529                            [x86_64 atomic implementation])
2530         glib_memory_barrier_needed=no
2531        ;;
2532       powerpc*)
2533         AC_MSG_RESULT([powerpc])
2534         AC_DEFINE_UNQUOTED(G_ATOMIC_POWERPC, 1,
2535                            [powerpc atomic implementation])
2536         glib_memory_barrier_needed=yes
2537         AC_MSG_CHECKING([whether asm supports numbered local labels])
2538         AC_TRY_COMPILE(
2539                        ,[
2540                        __asm__ __volatile__ ("1:       nop\n"
2541                                "         bne-    1b")
2542                        ],[
2543                        AC_DEFINE_UNQUOTED(ASM_NUMERIC_LABELS, 1, [define if asm blocks can use numeric local labels])
2544                        AC_MSG_RESULT([yes])
2545                        ],[
2546                        AC_MSG_RESULT([no])
2547                        ])
2548         ;;
2549       ia64)
2550         AC_MSG_RESULT([ia64])
2551         AC_DEFINE_UNQUOTED(G_ATOMIC_IA64, 1,
2552                            [ia64 atomic implementation])
2553         glib_memory_barrier_needed=yes
2554         ;;
2555       s390|s390x)
2556         AC_MSG_RESULT([s390])
2557         AC_DEFINE_UNQUOTED(G_ATOMIC_S390, 1,
2558                            [s390 atomic implementation])
2559         glib_memory_barrier_needed=no
2560         ;;
2561       arm*)
2562         AC_MSG_RESULT([arm])
2563         AC_DEFINE_UNQUOTED(G_ATOMIC_ARM, 1,
2564                            [arm atomic implementation])
2565         glib_memory_barrier_needed=no
2566         ;;
2567       crisv32*|etraxfs*)
2568         AC_MSG_RESULT([crisv32])
2569         AC_DEFINE_UNQUOTED(G_ATOMIC_CRISV32, 1,
2570                            [crisv32 atomic implementation])
2571         glib_memory_barrier_needed=no
2572         ;;
2573       cris*|etrax*)
2574         AC_MSG_RESULT([cris])
2575         AC_DEFINE_UNQUOTED(G_ATOMIC_CRIS, 1,
2576                            [cris atomic implementation])
2577         glib_memory_barrier_needed=no
2578         ;;
2579       *)
2580         AC_MSG_RESULT([none])
2581         glib_memory_barrier_needed=yes
2582         ;;
2583     esac
2584
2585 glib_cv_gcc_has_builtin_atomic_operations=no
2586 if test x"$GCC" = xyes; then
2587   AC_MSG_CHECKING([whether GCC supports built-in atomic intrinsics])
2588   AC_TRY_LINK([],
2589               [int i;
2590                __sync_synchronize ();
2591                __sync_bool_compare_and_swap (&i, 0, 1);
2592                __sync_fetch_and_add (&i, 1);
2593               ],
2594               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2595               [glib_cv_gcc_has_builtin_atomic_operations=no])
2596
2597   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2598 fi
2599 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2600                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2601
2602 AC_MSG_CHECKING([for Win32 atomic intrinsics])
2603 glib_cv_has_win32_atomic_operations=no
2604 AC_TRY_LINK([],
2605         [int i; _InterlockedExchangeAdd (&i, 0);],
2606         [glib_cv_has_win32_atomic_operations=yes],
2607         [glib_cv_has_win32_atomic_operations=no])
2608 AC_MSG_RESULT($glib_cv_has_win32_atomic_operations)
2609 if test "x$glib_cv_has_win32_atomic_operations" = xyes; then
2610         AC_DEFINE(HAVE_WIN32_BUILTINS_FOR_ATOMIC_OPERATIONS,1,[Have Win32 atomic intrinsics])
2611 fi
2612
2613 dnl ************************
2614 dnl ** Check for futex(2) **
2615 dnl ************************
2616 AC_CACHE_CHECK(for futex(2) system call,
2617     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2618 #include <linux/futex.h>
2619 #include <sys/syscall.h>
2620 #include <unistd.h>
2621 ],[
2622 int
2623 main (void)
2624 {
2625   /* it is not like this actually runs or anything... */
2626   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2627   return 0;
2628 }
2629 ])],glib_cv_futex=yes,glib_cv_futex=no))
2630 if test x"$glib_cv_futex" = xyes; then
2631   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2632 fi
2633
2634 AC_CACHE_CHECK(for eventfd(2) system call,
2635     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2636 #include <sys/eventfd.h>
2637 #include <unistd.h>
2638 ],[
2639 int
2640 main (void)
2641 {
2642   eventfd (0, EFD_CLOEXEC);
2643   return 0;
2644 }
2645 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2646 if test x"$glib_cv_eventfd" = x"yes"; then
2647   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2648 fi
2649 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2650
2651 dnl ****************************************
2652 dnl *** GLib POLL* compatibility defines ***
2653 dnl ****************************************
2654
2655 glib_poll_includes=["
2656 #include <sys/types.h>
2657 #include <sys/poll.h>
2658 "]
2659
2660 if test $ac_cv_header_sys_types_h = yes &&
2661    test $ac_cv_header_sys_poll_h = yes ; then
2662   glib_failed=false
2663   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2664   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2665   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2666   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2667   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2668   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2669   if $glib_failed ; then
2670     AC_MSG_ERROR([Could not determine values for POLL* constants])
2671   fi
2672 else
2673   glib_cv_value_POLLIN=1
2674   glib_cv_value_POLLOUT=4
2675   glib_cv_value_POLLPRI=2
2676   glib_cv_value_POLLERR=8
2677   glib_cv_value_POLLHUP=16
2678   glib_cv_value_POLLNVAL=32
2679 fi
2680
2681 AC_MSG_CHECKING([for broken poll])
2682 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2683         #include <stdlib.h>
2684         #include <fcntl.h>
2685         #include <poll.h>
2686         #ifdef HAVE_SYS_POLL_H
2687         #include <sys/poll.h>
2688         #endif
2689         int main(void) {
2690           struct pollfd fds[1];
2691           int fd;
2692           fd = open("/dev/null", 1);
2693           fds[0].fd = fd;
2694           fds[0].events = POLLIN;
2695           fds[0].revents = 0;
2696           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2697                 exit(1);  /* Does not work for devices -- fail */
2698           }
2699           exit(0);
2700         }]])],
2701   [broken_poll=no],
2702   [broken_poll=yes
2703    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2704   [broken_poll="no (cross compiling)"])
2705 AC_MSG_RESULT($broken_poll)
2706
2707 dnl *********************
2708 dnl *** GRegex checks ***
2709 dnl *********************
2710 PCRE_REQUIRED_VERSION=8.11
2711
2712 # Check if we should compile GRegex
2713 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2714                                     [disable the compilation of GRegex]),
2715 [case "${enableval}" in
2716   yes) enable_regex=true ;;
2717   no)  enable_regex=false ;;
2718   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2719 esac],
2720 [enable_regex=true])
2721
2722 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2723
2724 if test x$enable_regex = xtrue; then
2725   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2726   # Check if we should use the internal or the system-supplied pcre
2727   AC_ARG_WITH(pcre,
2728              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2729                              [whether to use system PCRE [default=internal]])])
2730
2731   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2732
2733   if test "x$with_pcre" = xsystem; then
2734     PKG_CHECK_MODULES(PCRE,
2735                       libpcre >= $PCRE_REQUIRED_VERSION)
2736     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2737                    glib_save_CFLAGS="$CFLAGS"
2738                    glib_save_LIBS="$LIBS"
2739                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2740                    AC_TRY_RUN([#include <pcre.h>
2741                                int main () {
2742                                  int support;
2743                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2744                                  if (!support)
2745                                    return 1;
2746                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2747                                  if (!support)
2748                                    return 1;
2749                                  return 0;
2750                                }],
2751                    glib_cv_pcre_has_unicode=yes,
2752                    glib_cv_pcre_has_unicode=no,
2753                    glib_cv_pcre_has_unicode=yes)
2754                    CFLAGS="$glib_save_CFLAGS"
2755                    LIBS="$glib_save_LIBS"
2756         ])
2757     if test "$glib_cv_pcre_has_unicode" = "no"; then
2758       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2759     fi
2760     AC_SUBST(PCRE_CFLAGS)
2761     AC_SUBST(PCRE_LIBS)
2762     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2763     PCRE_REQUIRES=libpcre
2764     AC_SUBST(PCRE_REQUIRES)
2765   else
2766     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2767     if test x"$GCC" = xyes; then
2768       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2769       save_CFLAGS="$CFLAGS"
2770       CFLAGS="$CFLAGS -Wno-pointer-sign"
2771       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2772                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2773       CFLAGS="$save_CFLAGS"
2774     fi
2775   fi
2776   AC_SUBST(PCRE_WARN_CFLAGS)
2777 else
2778   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2779 fi
2780
2781 dnl **********************
2782 dnl *** Win32 API libs ***
2783 dnl **********************
2784
2785 case $host in
2786   *-*-cygwin*)
2787         G_LIBS_EXTRA="-luser32 -lkernel32"
2788     ;;
2789   *-*-mingw*)
2790         G_LIBS_EXTRA="-lws2_32 -lole32"
2791     ;;
2792   *)
2793         G_LIBS_EXTRA=""
2794     ;;
2795 esac
2796 AC_SUBST(G_LIBS_EXTRA)
2797
2798 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2799 dnl since we need it for g_iconv()
2800
2801 AC_MSG_CHECKING([for EILSEQ])
2802 AC_TRY_COMPILE([
2803 #include <errno.h>
2804 ],
2805 [
2806 int error = EILSEQ;
2807 ], have_eilseq=yes, have_eilseq=no);
2808 AC_MSG_RESULT($have_eilseq)
2809
2810 dnl ******************************************************************
2811 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2812 dnl *** glib-compile-schemas in PATH                               ***
2813 dnl ******************************************************************
2814
2815 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2816
2817 if test $cross_compiling = yes; then
2818   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2819   if test x$GLIB_GENMARSHAL = xno; then
2820     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2821   fi
2822
2823   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2824   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2825     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2826   fi
2827 fi
2828
2829 dnl **************************
2830 dnl *** Checks for gtk-doc ***
2831 dnl **************************
2832
2833 GTK_DOC_CHECK([1.15])
2834
2835 AC_ARG_ENABLE(man,
2836               [AC_HELP_STRING([--enable-man],
2837                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2838               enable_man=no)
2839
2840 if test "${enable_man}" != no; then
2841 dnl
2842 dnl Check for xsltproc
2843 dnl
2844 AC_PATH_PROG([XSLTPROC], [xsltproc])
2845   if test -z "$XSLTPROC"; then
2846     enable_man=no
2847   fi
2848
2849   dnl check for DocBook DTD and stylesheets in the local catalog.
2850   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2851      [DocBook XML DTD V4.1.2],,enable_man=no)
2852   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2853      [DocBook XSL Stylesheets],,enable_man=no)
2854 fi
2855
2856 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2857
2858 dnl
2859 dnl Tracing
2860 dnl
2861
2862 AC_ARG_ENABLE([dtrace],
2863              [AS_HELP_STRING([--enable-dtrace],
2864                               [include tracing support for dtrace])])
2865 have_dtrace=no
2866 AC_MSG_CHECKING([whether to include dtrace tracing support])
2867 if test "x$enable_dtrace" != xno; then
2868   if test x$glib_have_carbon = xyes; then
2869     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2870   else
2871     AC_MSG_RESULT([yes])
2872     AC_CHECK_PROGS(DTRACE, dtrace)
2873     if test -z "$DTRACE"; then
2874       if test "x$enable_dtrace" = xyes; then
2875         AC_MSG_ERROR([dtrace not found])
2876       fi
2877     else
2878       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2879                       [if test "x$enable_dtrace" = xyes; then
2880                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2881                        fi])
2882     fi
2883   fi
2884 else
2885   AC_MSG_RESULT([no])
2886 fi
2887 if test "x$have_dtrace" = xyes; then
2888   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2889 fi
2890 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2891
2892 AC_MSG_CHECKING([whether to include systemtap tracing support])
2893 AC_ARG_ENABLE([systemtap],
2894              [AS_HELP_STRING([--enable-systemtap],
2895                               [include tracing support for systemtap])])
2896 have_systemtap=no
2897 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2898   have_systemtap=yes
2899 fi
2900 AC_MSG_RESULT(${have_systemtap})
2901
2902 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2903
2904 AC_ARG_WITH([tapset-install-dir],
2905             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2906                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2907             [if test "x${withval}" = x; then
2908                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2909              else
2910                ABS_TAPSET_DIR="${withval}"
2911               fi],
2912             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2913 AC_SUBST(ABS_TAPSET_DIR)
2914
2915 dnl ************************************
2916 dnl *** Enable lcov coverage reports ***
2917 dnl ************************************
2918
2919 AC_ARG_ENABLE(gcov,
2920   AS_HELP_STRING([--enable-gcov],
2921                  [enable coverage testing with gcov]),
2922   [use_gcov=$enableval], [use_gcov=no])
2923
2924 if test "x$use_gcov" = "xyes"; then
2925   dnl we need gcc:
2926   if test "$GCC" != "yes"; then
2927     AC_MSG_ERROR([GCC is required for --enable-gcov])
2928   fi
2929
2930   dnl Check if ccache is being used
2931   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2932   case `$SHTOOL path $CC` in
2933     *ccache*[)] gcc_ccache=yes;;
2934     *[)] gcc_ccache=no;;
2935   esac
2936
2937   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2938     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2939   fi
2940
2941   ltp_version_list="1.6 1.7 1.8 1.9"
2942   AC_CHECK_PROG(LTP, lcov, lcov)
2943   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2944
2945   if test "$LTP"; then
2946     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2947       glib_cv_ltp_version=invalid
2948       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2949       for ltp_check_version in $ltp_version_list; do
2950         if test "$ltp_version" = "$ltp_check_version"; then
2951           glib_cv_ltp_version="$ltp_check_version (ok)"
2952         fi
2953       done
2954     ])
2955   else
2956     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2957     AC_MSG_ERROR([$ltp_msg])
2958   fi
2959
2960   case $glib_cv_ltp_version in
2961     ""|invalid[)]
2962       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2963       AC_MSG_ERROR([$ltp_msg])
2964       LTP="exit 0;"
2965       ;;
2966   esac
2967
2968   if test -z "$LTP_GENHTML"; then
2969     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2970   fi
2971
2972   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2973
2974   dnl Remove all optimization flags from CFLAGS
2975   changequote({,})
2976   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2977   changequote([,])
2978
2979   dnl Add the special gcc flags
2980   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2981   LDFLAGS="$LDFLAGS -lgcov"
2982 fi
2983
2984 dnl ******************************
2985 dnl *** output the whole stuff ***
2986 dnl ******************************
2987
2988 dnl this section will only be run if config.status is invoked with no
2989 dnl arguments, or with "glib/glibconfig.h" as an argument.
2990 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2991 [
2992         outfile=glib/glibconfig.h-tmp
2993         cat > $outfile <<\_______EOF
2994 /* glibconfig.h
2995  *
2996  * This is a generated file.  Please modify 'configure.ac'
2997  */
2998
2999 #ifndef __G_LIBCONFIG_H__
3000 #define __G_LIBCONFIG_H__
3001
3002 #include <glib/gmacros.h>
3003
3004 _______EOF
3005
3006         if test x$glib_limits_h = xyes; then
3007           echo '#include <limits.h>' >> $outfile
3008         fi
3009         if test x$glib_float_h = xyes; then
3010           echo '#include <float.h>' >> $outfile
3011         fi
3012         if test x$glib_values_h = xyes; then
3013           echo '#include <values.h>' >> $outfile
3014         fi
3015         if test "$glib_header_alloca_h" = "yes"; then
3016           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
3017         fi
3018         if test x$glib_sys_poll_h = xyes; then
3019           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
3020         fi
3021         if test x$glib_included_printf != xyes; then
3022           echo "
3023 /* Specifies that GLib's g_print*() functions wrap the
3024  * system printf functions.  This is useful to know, for example,
3025  * when using glibc's register_printf_function().
3026  */" >> $outfile
3027           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
3028         fi
3029
3030         cat >> $outfile <<_______EOF
3031
3032 G_BEGIN_DECLS
3033
3034 #define G_MINFLOAT      $glib_mf
3035 #define G_MAXFLOAT      $glib_Mf
3036 #define G_MINDOUBLE     $glib_md
3037 #define G_MAXDOUBLE     $glib_Md
3038 #define G_MINSHORT      $glib_ms
3039 #define G_MAXSHORT      $glib_Ms
3040 #define G_MAXUSHORT     $glib_Mus
3041 #define G_MININT        $glib_mi
3042 #define G_MAXINT        $glib_Mi
3043 #define G_MAXUINT       $glib_Mui
3044 #define G_MINLONG       $glib_ml
3045 #define G_MAXLONG       $glib_Ml
3046 #define G_MAXULONG      $glib_Mul
3047
3048 _______EOF
3049
3050
3051         ### this should always be true in a modern C/C++ compiler
3052         cat >>$outfile <<_______EOF
3053 typedef signed char gint8;
3054 typedef unsigned char guint8;
3055 _______EOF
3056
3057
3058         if test -n "$gint16"; then
3059           cat >>$outfile <<_______EOF
3060 typedef signed $gint16 gint16;
3061 typedef unsigned $gint16 guint16;
3062 #define G_GINT16_MODIFIER $gint16_modifier
3063 #define G_GINT16_FORMAT $gint16_format
3064 #define G_GUINT16_FORMAT $guint16_format
3065 _______EOF
3066         fi
3067
3068
3069         if test -n "$gint32"; then
3070           cat >>$outfile <<_______EOF
3071 typedef signed $gint32 gint32;
3072 typedef unsigned $gint32 guint32;
3073 #define G_GINT32_MODIFIER $gint32_modifier
3074 #define G_GINT32_FORMAT $gint32_format
3075 #define G_GUINT32_FORMAT $guint32_format
3076 _______EOF
3077         fi
3078
3079         cat >>$outfile <<_______EOF
3080 #define G_HAVE_GINT64 1          /* deprecated, always true */
3081
3082 ${glib_extension}typedef signed $gint64 gint64;
3083 ${glib_extension}typedef unsigned $gint64 guint64;
3084
3085 #define G_GINT64_CONSTANT(val)  $gint64_constant
3086 #define G_GUINT64_CONSTANT(val) $guint64_constant
3087 _______EOF
3088
3089         if test x$gint64_format != x ; then
3090           cat >>$outfile <<_______EOF
3091 #define G_GINT64_MODIFIER $gint64_modifier
3092 #define G_GINT64_FORMAT $gint64_format
3093 #define G_GUINT64_FORMAT $guint64_format
3094 _______EOF
3095         else
3096           cat >>$outfile <<_______EOF
3097 #undef G_GINT64_MODIFIER
3098 #undef G_GINT64_FORMAT
3099 #undef G_GUINT64_FORMAT
3100 _______EOF
3101         fi
3102
3103         cat >>$outfile <<_______EOF
3104
3105 #define GLIB_SIZEOF_VOID_P $glib_void_p
3106 #define GLIB_SIZEOF_LONG   $glib_long
3107 #define GLIB_SIZEOF_SIZE_T $glib_size_t
3108
3109 _______EOF
3110
3111         cat >>$outfile <<_______EOF
3112 typedef signed $glib_size_type_define gssize;
3113 typedef unsigned $glib_size_type_define gsize;
3114 #define G_GSIZE_MODIFIER $gsize_modifier
3115 #define G_GSSIZE_FORMAT $gssize_format
3116 #define G_GSIZE_FORMAT $gsize_format
3117
3118 #define G_MAXSIZE       G_MAXU$glib_msize_type
3119 #define G_MINSSIZE      G_MIN$glib_msize_type
3120 #define G_MAXSSIZE      G_MAX$glib_msize_type
3121
3122 typedef gint64 goffset;
3123 #define G_MINOFFSET     G_MININT64
3124 #define G_MAXOFFSET     G_MAXINT64
3125
3126 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3127 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3128 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3129
3130 _______EOF
3131
3132         if test -z "$glib_unknown_void_p"; then
3133           cat >>$outfile <<_______EOF
3134
3135 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3136 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3137
3138 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3139 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3140
3141 typedef signed $glib_intptr_type_define gintptr;
3142 typedef unsigned $glib_intptr_type_define guintptr;
3143
3144 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3145 #define G_GINTPTR_FORMAT        $gintptr_format
3146 #define G_GUINTPTR_FORMAT       $guintptr_format
3147 _______EOF
3148         else
3149           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3150         fi
3151
3152
3153
3154         cat >>$outfile <<_______EOF
3155 $glib_atexit
3156 $glib_memmove
3157 $glib_defines
3158 $glib_os
3159 $glib_static_compilation
3160
3161 $glib_vacopy
3162
3163 #ifdef  __cplusplus
3164 #define G_HAVE_INLINE   1
3165 #else   /* !__cplusplus */
3166 $glib_inline
3167 #endif  /* !__cplusplus */
3168
3169 #ifdef  __cplusplus
3170 #define G_CAN_INLINE    1
3171 _______EOF
3172
3173         if test x$g_can_inline = xyes ; then
3174                 cat >>$outfile <<_______EOF
3175 #else   /* !__cplusplus */
3176 #define G_CAN_INLINE    1
3177 _______EOF
3178         fi
3179
3180         cat >>$outfile <<_______EOF
3181 #endif
3182
3183 _______EOF
3184
3185         if test x$g_have_iso_c_varargs = xyes ; then
3186                 cat >>$outfile <<_______EOF
3187 #ifndef __cplusplus
3188 # define G_HAVE_ISO_VARARGS 1
3189 #endif
3190 _______EOF
3191         fi
3192         if test x$g_have_iso_cxx_varargs = xyes ; then
3193                 cat >>$outfile <<_______EOF
3194 #ifdef __cplusplus
3195 # define G_HAVE_ISO_VARARGS 1
3196 #endif
3197 _______EOF
3198         fi
3199         if test x$g_have_gnuc_varargs = xyes ; then
3200                 cat >>$outfile <<_______EOF
3201
3202 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3203  * is passed ISO vararg support is turned off, and there is no work
3204  * around to turn it on, so we unconditionally turn it off.
3205  */
3206 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3207 #  undef G_HAVE_ISO_VARARGS
3208 #endif
3209
3210 #define G_HAVE_GNUC_VARARGS 1
3211 _______EOF
3212         fi
3213
3214         case x$g_stack_grows in
3215         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3216         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3217         esac
3218
3219
3220         echo >>$outfile
3221         if test x$g_have_eilseq = xno; then
3222                 cat >>$outfile <<_______EOF
3223 #ifndef EILSEQ
3224 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3225  * The correspondence between this and the corresponding definition
3226  * in libiconv is essential.
3227  */
3228 #  define EILSEQ ENOENT
3229 #endif
3230 _______EOF
3231
3232         fi
3233
3234         if test x$g_have_gnuc_visibility = xyes; then
3235                 cat >>$outfile <<_______EOF
3236 #define G_HAVE_GNUC_VISIBILITY 1
3237 _______EOF
3238         fi
3239                 cat >>$outfile <<_______EOF
3240 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3241 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3242 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3243 #define G_GNUC_INTERNAL __hidden
3244 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3245 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3246 #else
3247 #define G_GNUC_INTERNAL
3248 #endif
3249 _______EOF
3250
3251
3252         echo >>$outfile
3253         if test x$g_mutex_has_default = xyes; then
3254                 cat >>$outfile <<_______EOF
3255 #define G_THREADS_ENABLED
3256 #define G_THREADS_IMPL_$g_threads_impl_def
3257 typedef struct _GStaticMutex GStaticMutex;
3258 struct _GStaticMutex
3259 {
3260   struct _GMutex *runtime_mutex;
3261   union {
3262     char   pad[[$g_mutex_sizeof]];
3263     double dummy_double;
3264     void  *dummy_pointer;
3265     long   dummy_long;
3266   } static_mutex;
3267 };
3268 #define G_STATIC_MUTEX_INIT     { NULL, { { $g_mutex_contents} } }
3269 #define g_static_mutex_get_mutex(mutex) \\
3270   (g_thread_use_default_impl ? ((GMutex*)(gpointer) ((mutex)->static_mutex.pad)) : \\
3271    g_static_mutex_get_mutex_impl_shortcut (&((mutex)->runtime_mutex)))
3272 _______EOF
3273         else
3274                 cat >>$outfile <<_______EOF
3275 #define G_THREADS_ENABLED
3276 #define G_THREADS_IMPL_$g_threads_impl_def
3277 typedef struct _GMutex* GStaticMutex;
3278 #define G_STATIC_MUTEX_INIT NULL
3279 #define g_static_mutex_get_mutex(mutex) \\
3280   (g_static_mutex_get_mutex_impl_shortcut (mutex))
3281 _______EOF
3282         fi
3283
3284         cat >>$outfile <<_______EOF
3285 /* This represents a system thread as used by the implementation. An
3286  * alien implementaion, as loaded by g_thread_init can only count on
3287  * "sizeof (gpointer)" bytes to store their info. We however need more
3288  * for some of our native implementations. */
3289 typedef union _GSystemThread GSystemThread;
3290 union _GSystemThread
3291 {
3292   char   data[[$g_system_thread_sizeof]];
3293   double dummy_double;
3294   void  *dummy_pointer;
3295   long   dummy_long;
3296 };
3297 _______EOF
3298         if test x"$g_memory_barrier_needed" != xno; then
3299           echo >>$outfile
3300           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3301         fi
3302         if test x"$g_gcc_atomic_ops" != xno; then
3303           echo >>$outfile
3304           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3305         fi
3306         echo >>$outfile
3307         g_bit_sizes="16 32 64"
3308         for bits in $g_bit_sizes; do
3309           cat >>$outfile <<_______EOF
3310 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3311 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3312 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3313 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3314 _______EOF
3315         done
3316
3317         cat >>$outfile <<_______EOF
3318 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3319 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3320 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3321 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3322 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3323 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3324 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3325 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3326 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3327 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3328 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3329 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3330 #define G_BYTE_ORDER $g_byte_order
3331
3332 #define GLIB_SYSDEF_POLLIN =$g_pollin
3333 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3334 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3335 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3336 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3337 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3338
3339 #define G_MODULE_SUFFIX "$g_module_suffix"
3340
3341 /* A GPid is an abstraction for a process "handle". It is *not* an
3342  * abstraction for a process identifier in general. GPid is used in
3343  * GLib only for descendant processes spawned with the g_spawn*
3344  * functions. On POSIX there is no "process handle" concept as such,
3345  * but on Windows a GPid is a handle to a process, a kind of pointer,
3346  * not a process identifier.
3347  */
3348 typedef $g_pid_type GPid;
3349
3350 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3351 #define GLIB_SYSDEF_AF_INET $g_af_inet
3352 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3353
3354 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3355 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3356 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3357
3358 G_END_DECLS
3359
3360 #endif /* GLIBCONFIG_H */
3361 _______EOF
3362
3363
3364         if cmp -s $outfile glib/glibconfig.h; then
3365           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3366           rm -f $outfile
3367         else
3368           mv $outfile glib/glibconfig.h
3369         fi
3370 ],[
3371
3372 # Note that if two cases are the same, case goes with the first one.
3373 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3374 # on variable expansion in case labels.  Look at the generated config.status
3375 # for a hint.
3376
3377 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3378   glib_header_alloca_h="$ac_cv_working_alloca_h"
3379 else
3380   glib_header_alloca_h="$ac_cv_header_alloca_h"
3381 fi
3382
3383 case xyes in
3384 x$ac_cv_header_float_h)
3385   glib_float_h=yes
3386   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3387   glib_md=DBL_MIN glib_Md=DBL_MAX
3388   ;;
3389 x$ac_cv_header_values_h)
3390   glib_values_h=yes
3391   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3392   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3393   ;;
3394 esac
3395
3396 case xyes in
3397 x$ac_cv_header_limits_h)
3398   glib_limits_h=yes
3399   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3400   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3401   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3402   ;;
3403 x$ac_cv_header_values_h)
3404   glib_values_h=yes
3405   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3406   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3407   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3408   ;;
3409 esac
3410
3411 if test x$ac_cv_header_sys_poll_h = xyes ; then
3412   glib_sys_poll_h=yes
3413 fi
3414
3415 if test x$enable_included_printf = xyes ; then
3416   glib_included_printf=yes
3417 fi
3418
3419 case 2 in
3420 $ac_cv_sizeof_short)
3421   gint16=short
3422   gint16_modifier='"h"'
3423   gint16_format='"hi"'
3424   guint16_format='"hu"'
3425   ;;
3426 $ac_cv_sizeof_int)
3427   gint16=int
3428   gint16_modifier='""'
3429   gint16_format='"i"'
3430   guint16_format='"u"'
3431   ;;
3432 esac
3433 case 4 in
3434 $ac_cv_sizeof_short)
3435   gint32=short
3436   gint32_modifier='"h"'
3437   gint32_format='"hi"'
3438   guint32_format='"hu"'
3439   ;;
3440 $ac_cv_sizeof_int)
3441   gint32=int
3442   gint32_modifier='""'
3443   gint32_format='"i"'
3444   guint32_format='"u"'
3445   ;;
3446 $ac_cv_sizeof_long)
3447   gint32=long
3448   gint32_modifier='"l"'
3449   gint32_format='"li"'
3450   guint32_format='"lu"'
3451   ;;
3452 esac
3453 case 8 in
3454 $ac_cv_sizeof_int)
3455   gint64=int
3456   gint64_modifier='""'
3457   gint64_format='"i"'
3458   guint64_format='"u"'
3459   glib_extension=
3460   gint64_constant='(val)'
3461   guint64_constant='(val)'
3462   ;;
3463 $ac_cv_sizeof_long)
3464   gint64=long
3465   gint64_modifier='"l"'
3466   gint64_format='"li"'
3467   guint64_format='"lu"'
3468   glib_extension=
3469   gint64_constant='(val##L)'
3470   guint64_constant='(val##UL)'
3471   ;;
3472 $ac_cv_sizeof_long_long)
3473   gint64='long long'
3474   if test -n "$glib_cv_long_long_format"; then
3475     gint64_modifier='"'$glib_cv_long_long_format'"'
3476     gint64_format='"'$glib_cv_long_long_format'i"'
3477     guint64_format='"'$glib_cv_long_long_format'u"'
3478   fi
3479   glib_extension='G_GNUC_EXTENSION '
3480   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3481   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3482   ;;
3483 $ac_cv_sizeof___int64)
3484   gint64='__int64'
3485   if test -n "$glib_cv_long_long_format"; then
3486     gint64_modifier='"'$glib_cv_long_long_format'"'
3487     gint64_format='"'$glib_cv_long_long_format'i"'
3488     guint64_format='"'$glib_cv_long_long_format'u"'
3489   fi
3490   glib_extension=
3491   gint64_constant='(val##i64)'
3492   guint64_constant='(val##ui64)'
3493   ;;
3494 esac
3495 glib_size_t=$ac_cv_sizeof_size_t
3496 glib_size_type_define="$glib_size_type"
3497 glib_void_p=$ac_cv_sizeof_void_p
3498 glib_long=$ac_cv_sizeof_long
3499
3500 case "$glib_size_type" in
3501 short)
3502   gsize_modifier='"h"'
3503   gsize_format='"hu"'
3504   gssize_format='"hi"'
3505   glib_msize_type='SHRT'
3506   ;;
3507 int)
3508   gsize_modifier='""'
3509   gsize_format='"u"'
3510   gssize_format='"i"'
3511   glib_msize_type='INT'
3512   ;;
3513 long)
3514   gsize_modifier='"l"'
3515   gsize_format='"lu"'
3516   gssize_format='"li"'
3517   glib_msize_type='LONG'
3518   ;;
3519 "long long"|__int64)
3520   gsize_modifier='"I64"'
3521   gsize_format='"I64u"'
3522   gssize_format='"I64i"'
3523   glib_msize_type='INT64'
3524   ;;
3525 esac
3526
3527 gintbits=`expr $ac_cv_sizeof_int \* 8`
3528 glongbits=`expr $ac_cv_sizeof_long \* 8`
3529 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3530
3531 case $ac_cv_sizeof_void_p in
3532 $ac_cv_sizeof_int)
3533   glib_intptr_type_define=int
3534   gintptr_modifier='""'
3535   gintptr_format='"i"'
3536   guintptr_format='"u"'
3537   glib_gpi_cast=''
3538   glib_gpui_cast=''
3539   ;;
3540 $ac_cv_sizeof_long)
3541   glib_intptr_type_define=long
3542   gintptr_modifier='"l"'
3543   gintptr_format='"li"'
3544   guintptr_format='"lu"'
3545   glib_gpi_cast='(glong)'
3546   glib_gpui_cast='(gulong)'
3547   ;;
3548 $ac_cv_sizeof_long_long)
3549   glib_intptr_type_define='long long'
3550   gintptr_modifier='"I64"'
3551   gintptr_format='"I64i"'
3552   guintptr_format='"I64u"'
3553   glib_gpi_cast='(gint64)'
3554   glib_gpui_cast='(guint64)'
3555   ;;
3556 $ac_cv_sizeof___int64)
3557   glib_intptr_type_define=__int64
3558   gintptr_modifier='"I64"'
3559   gintptr_format='"I64i"'
3560   guintptr_format='"I64u"'
3561   glib_gpi_cast='(gint64)'
3562   glib_gpui_cast='(guint64)'
3563   ;;
3564 *)
3565   glib_unknown_void_p=yes
3566   ;;
3567 esac
3568
3569
3570 case xyes in
3571 x$ac_cv_func_atexit)
3572   glib_atexit="
3573 #ifdef NeXT /* @#%@! NeXTStep */
3574 # define g_ATEXIT(proc) (!atexit (proc))
3575 #else
3576 # define g_ATEXIT(proc) (atexit (proc))
3577 #endif"
3578   ;;
3579 x$ac_cv_func_on_exit)
3580   glib_atexit="
3581 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3582   ;;
3583 esac
3584
3585 case xyes in
3586 x$ac_cv_func_memmove)
3587   glib_memmove='
3588 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3589   ;;
3590 x$glib_cv_working_bcopy)
3591   glib_memmove="
3592 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3593 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3594   ;;
3595 *)
3596   glib_memmove="
3597 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3598  * so we have to roll our own copy routine. */
3599 void g_memmove (void* dest, const void * src, unsigned long len);"
3600   ;;
3601 esac
3602
3603 glib_defines="
3604 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3605 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3606 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3607 "
3608
3609 case xyes in
3610 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3611 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3612 *)                      glib_vacopy=''
3613 esac
3614
3615 if test x$glib_cv_va_val_copy = xno; then
3616   glib_vacopy="\$glib_vacopy
3617 #define G_VA_COPY_AS_ARRAY 1"
3618 fi
3619
3620 if test x$glib_cv_hasinline = xyes; then
3621     glib_inline='#define G_HAVE_INLINE 1'
3622 fi
3623 if test x$glib_cv_has__inline = xyes; then
3624     glib_inline="\$glib_inline
3625 #define G_HAVE___INLINE 1"
3626 fi
3627 if test x$glib_cv_has__inline__ = xyes; then
3628     glib_inline="\$glib_inline
3629 #define G_HAVE___INLINE__ 1"
3630 fi
3631
3632 g_have_gnuc_varargs=$g_have_gnuc_varargs
3633 g_have_iso_c_varargs=$g_have_iso_c_varargs
3634 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3635
3636 g_can_inline=$g_can_inline
3637 g_have_gnuc_visibility=$g_have_gnuc_visibility
3638 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3639
3640 if test x$ac_cv_c_bigendian = xyes; then
3641   g_byte_order=G_BIG_ENDIAN
3642   g_bs_native=BE
3643   g_bs_alien=LE
3644 else
3645   g_byte_order=G_LITTLE_ENDIAN
3646   g_bs_native=LE
3647   g_bs_alien=BE
3648 fi
3649
3650 g_pollin=$glib_cv_value_POLLIN
3651 g_pollout=$glib_cv_value_POLLOUT
3652 g_pollpri=$glib_cv_value_POLLPRI
3653 g_pollhup=$glib_cv_value_POLLHUP
3654 g_pollerr=$glib_cv_value_POLLERR
3655 g_pollnval=$glib_cv_value_POLLNVAL
3656
3657 g_af_unix=$glib_cv_value_AF_UNIX
3658 g_af_inet=$glib_cv_value_AF_INET
3659 g_af_inet6=$glib_cv_value_AF_INET6
3660
3661 g_msg_peek=$glib_cv_value_MSG_PEEK
3662 g_msg_oob=$glib_cv_value_MSG_OOB
3663 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3664
3665 g_stack_grows=$glib_cv_stack_grows
3666
3667 g_have_eilseq=$have_eilseq
3668
3669 g_threads_impl_def=$g_threads_impl
3670
3671 g_mutex_has_default="$mutex_has_default"
3672 g_mutex_sizeof="$glib_cv_sizeof_gmutex"
3673 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3674 g_mutex_contents="$glib_cv_byte_contents_gmutex"
3675
3676 g_memory_barrier_needed="$glib_memory_barrier_needed"
3677 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3678
3679 g_module_suffix="$glib_gmodule_suffix"
3680
3681 g_pid_type="$glib_pid_type"
3682 case $host in
3683   *-*-beos*)
3684     glib_os="#define G_OS_BEOS"
3685     ;;
3686   *-*-cygwin*)
3687     glib_os="#define G_OS_UNIX
3688 #define G_PLATFORM_WIN32
3689 #define G_WITH_CYGWIN"
3690     ;;
3691   *-*-mingw*)
3692     glib_os="#define G_OS_WIN32
3693 #define G_PLATFORM_WIN32"
3694     ;;
3695   *)
3696     glib_os="#define G_OS_UNIX"
3697     ;;
3698 esac
3699 glib_static_compilation=""
3700 if test x$glib_win32_static_compilation = xyes; then
3701   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3702 #define GOBJECT_STATIC_COMPILATION 1"
3703 fi
3704 ])
3705
3706 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3707 #
3708 # 1.2.14 required for dbus_message_set_serial
3709 PKG_CHECK_MODULES(DBUS1,
3710                   dbus-1 >= 1.2.14,
3711                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3712                   have_dbus1=no)
3713 AC_SUBST(DBUS1_CFLAGS)
3714 AC_SUBST(DBUS1_LIBS)
3715 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3716
3717 dnl
3718 dnl Check for -Bsymbolic-functions linker flag used to avoid
3719 dnl intra-library PLT jumps, if available.
3720 dnl
3721
3722 AC_ARG_ENABLE(Bsymbolic,
3723               [AC_HELP_STRING([--disable-Bsymbolic],
3724                               [avoid linking with -Bsymbolic])],,
3725               [SAVED_LDFLAGS="${LDFLAGS}"
3726                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3727                LDFLAGS=-Wl,-Bsymbolic-functions
3728                AC_TRY_LINK([], [int main (void) { return 0; }],
3729                            AC_MSG_RESULT(yes)
3730                            enable_Bsymbolic=yes,
3731                            AC_MSG_RESULT(no)
3732                            enable_Bsymbolic=no)
3733                LDFLAGS="${SAVED_LDFLAGS}"])
3734
3735 if test "x${enable_Bsymbolic}" == "xyes"; then
3736   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3737 fi
3738
3739 AC_SUBST(GLIB_LINK_FLAGS)
3740
3741 #
3742 # Define variables corresponding to the correct include paths to use for
3743 # in-tree building.
3744 #
3745
3746 # for config.h:
3747 config_h_INCLUDES='-I$(top_builddir)'
3748 AC_SUBST(config_h_INCLUDES)
3749
3750 # glib:
3751 #   config.h
3752 #   $(top_builddir)/glib: for glibconfig.h
3753 #   $(top_srcdir)/glib:   for glib.h
3754 #   $(top_srcdir):        for everything
3755 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3756 AC_SUBST(glib_INCLUDES)
3757
3758 # gthread:
3759 #   same as glib
3760 gthread_INCLUDES='$(glib_INCLUDES)'
3761 AC_SUBST(gthread_INCLUDES)
3762
3763 # gobject:
3764 #   same as gthread
3765 gobject_INCLUDES='$(gthread_INCLUDES)'
3766 AC_SUBST(gobject_INCLUDES)
3767
3768 # gmodule:
3769 #   glib includes
3770 #   $(top_srcdir)/gmodule: for gmodule.h
3771 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3772 AC_SUBST(gmodule_INCLUDES)
3773
3774 # gio:
3775 #   same as gmodule
3776 gio_INCLUDES='$(gmodule_INCLUDES)'
3777 AC_SUBST(gio_INCLUDES)
3778
3779
3780 AC_CONFIG_FILES([
3781 glib-2.0.pc
3782 glib-2.0-uninstalled.pc
3783 gmodule-2.0.pc
3784 gmodule-export-2.0.pc
3785 gmodule-no-export-2.0.pc
3786 gmodule-2.0-uninstalled.pc
3787 gmodule-no-export-2.0-uninstalled.pc
3788 gthread-2.0.pc
3789 gthread-2.0-uninstalled.pc
3790 gobject-2.0.pc
3791 gobject-2.0-uninstalled.pc
3792 gio-2.0.pc
3793 gio-unix-2.0.pc
3794 gio-windows-2.0.pc
3795 gio-2.0-uninstalled.pc
3796 gio-unix-2.0-uninstalled.pc
3797 glib-zip
3798 glib-gettextize
3799 Makefile
3800 build/Makefile
3801 build/win32/Makefile
3802 build/win32/dirent/Makefile
3803 build/win32/vs9/Makefile
3804 build/win32/vs10/Makefile
3805 glib/Makefile
3806 glib/glib.stp
3807 glib/libcharset/Makefile
3808 glib/gnulib/Makefile
3809 glib/pcre/Makefile
3810 glib/update-pcre/Makefile
3811 glib/tests/Makefile
3812 gmodule/Makefile
3813 gmodule/gmoduleconf.h
3814 gobject/Makefile
3815 gobject/gobject.stp
3816 gobject/glib-mkenums
3817 gobject/tests/Makefile
3818 gthread/Makefile
3819 gthread/tests/Makefile
3820 gio/Makefile
3821 gio/gdbus-2.0/codegen/Makefile
3822 gio/gdbus-2.0/codegen/config.py
3823 gio/xdgmime/Makefile
3824 gio/inotify/Makefile
3825 gio/fen/Makefile
3826 gio/fam/Makefile
3827 gio/win32/Makefile
3828 gio/tests/Makefile
3829 gio/tests/gdbus-object-manager-example/Makefile
3830 po/Makefile.in
3831 docs/Makefile
3832 docs/reference/Makefile
3833 docs/reference/glib/Makefile
3834 docs/reference/glib/version.xml
3835 docs/reference/gobject/Makefile
3836 docs/reference/gobject/version.xml
3837 docs/reference/gio/Makefile
3838 docs/reference/gio/gdbus-object-manager-example/Makefile
3839 docs/reference/gio/version.xml
3840 tests/Makefile
3841 tests/gobject/Makefile
3842 tests/refcount/Makefile
3843 m4macros/Makefile
3844 ])
3845
3846 AC_CONFIG_COMMANDS([chmod-scripts],
3847 [chmod 0755 glib-zip
3848 chmod 0755 glib-gettextize
3849 chmod 0755 gobject/glib-mkenums])
3850
3851 # we want to invoke this macro solely so that the config.status script
3852 # and automake generated makefiles know about these generated files.
3853 # They are only needed to distcheck the package
3854 if false; then
3855   AC_CONFIG_FILES([
3856     INSTALL
3857     README
3858     config.h.win32
3859     glib/glibconfig.h.win32
3860     glib/makefile.msc
3861     glib/glib.rc
3862     gmodule/makefile.msc
3863     gmodule/gmodule.rc
3864     gobject/makefile.msc
3865     gobject/gobject.rc
3866     gthread/makefile.msc
3867     gthread/gthread.rc
3868     gio/gio.rc
3869     tests/makefile.msc
3870   ])
3871 fi
3872
3873 AC_OUTPUT