configure.ac

   1 m4_define(LIBUSB_MAJOR, [1])
   2 m4_define(LIBUSB_MINOR, [0])
   3 m4_define(LIBUSB_MICRO, [8])
   4
   5 AC_INIT([libusb], LIBUSB_MAJOR.LIBUSB_MINOR.LIBUSB_MICRO, [libusb-devel@lists.sourceforge.net], [libusb], [http://www.libusb.org/])
   6
   7 AC_SUBST([LIBUSB_VERSION_MAJOR], [LIBUSB_MAJOR])
   8 AC_SUBST([LIBUSB_VERSION_MINOR], [LIBUSB_MINOR])
   9 AC_SUBST([LIBUSB_VERSION_MICRO], [LIBUSB_MICRO])
  10
  11 # Library versioning
  12 # These numbers should be tweaked on every release. Read carefully:
  13 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  14 # http://sourceware.org/autobook/autobook/autobook_91.html
  15 lt_current="1"
  16 lt_revision="0"
  17 lt_age="1"
  18 AC_SUBST(lt_current)
  19 AC_SUBST(lt_revision)
  20 AC_SUBST(lt_age)
  21
  22 AM_INIT_AUTOMAKE
  23 AC_CONFIG_SRCDIR([libusb/core.c])
  24 AC_CONFIG_MACRO_DIR([m4])
  25 AM_CONFIG_HEADER([config.h])
  26 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
  27
  28 AC_PREREQ([2.50])
  29 AC_PROG_CC
  30 AC_PROG_LIBTOOL
  31 AC_C_INLINE
  32 AM_PROG_CC_C_O
  33 AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions])
  34
  35 AM_MAINTAINER_MODE
  36
  37 AC_MSG_CHECKING([operating system])
  38 PC_LIBS_PRIVATE=
  39 case $host in
  40 *-linux*)
  41         AC_DEFINE(OS_LINUX, 1, [Linux backend])
  42         AC_SUBST(OS_LINUX)
  43         AC_MSG_RESULT([Linux])
  44         backend="linux"
  45         AC_CHECK_LIB(rt, clock_gettime, PC_LIBS_PRIVATE="-lrt")
  46         threads="posix"
  47         THREAD_CFLAGS="-pthread"
  48         PC_LIBS_PRIVATE="${PC_LIBS_PRIVATE} -pthread"
  49         AC_CHECK_HEADERS([poll.h])
  50         AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])
  51         ;;
  52 *-darwin*)
  53         AC_DEFINE(OS_DARWIN, 1, [Darwin backend])
  54         AC_SUBST(OS_DARWIN)
  55         AC_MSG_RESULT([Darwin/Mac OS X])
  56         backend="darwin"
  57         threads="posix"
  58         PC_LIBS_PRIVATE="-Wl,-framework,IOKit -Wl,-framework,CoreFoundation -Wl,-prebind -no-undefined"
  59         AC_CHECK_HEADERS([poll.h])
  60         AC_CHECK_TYPE([nfds_t],
  61                 [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])],
  62                 [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])],
  63                 [#include <poll.h>])
  64 ;;
  65 *-mingw*)
  66         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
  67         AC_SUBST(OS_WINDOWS)
  68         AC_MSG_RESULT([Windows])
  69         backend="windows"
  70         PC_LIBS_PRIVATE="-lsetupapi -lole32 -ladvapi32"
  71         AM_LDFLAGS="-no-undefined -avoid-version --add-stdcall-alias"
  72         AC_CHECK_TOOL(RC, windres, no)
  73         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
  74         ;;
  75 *-cygwin*)
  76         AC_DEFINE(OS_WINDOWS, 1, [Windows backend])
  77         AC_SUBST(OS_WINDOWS)
  78         AC_MSG_RESULT([Cygwin (using Windows backend)])
  79         backend="windows"
  80         threads="posix"
  81         PC_LIBS_PRIVATE="-lsetupapi -lole32 -ladvapi32"
  82         AM_LDFLAGS="-no-undefined -avoid-version"
  83         AC_CHECK_TOOL(RC, windres, no)
  84         AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])
  85         ;;
  86 *)
  87         AC_MSG_ERROR([unsupported operating system])
  88 esac
  89 AC_SUBST(PC_LIBS_PRIVATE)
  90 LIBS="${LIBS} ${PC_LIBS_PRIVATE}"
  91
  92 AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux)
  93 AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin)
  94 AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows)
  95 AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix)
  96 if test "$threads" = posix; then
  97         AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads])
  98 fi
  99
 100 # timerfd
 101 AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0])
 102 AC_ARG_ENABLE([timerfd],
 103         [AS_HELP_STRING([--enable-timerfd],
 104                 [use timerfd for timing (default auto)])],
 105         [use_timerfd=$enableval], [use_timerfd='auto'])
 106
 107 if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then
 108         AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required])
 109 fi
 110
 111 AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>])
 112 if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then
 113         AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required])
 114 fi
 115
 116 AC_MSG_CHECKING([whether to use timerfd for timing])
 117 if test "x$use_timerfd" = "xno"; then
 118         AC_MSG_RESULT([no (disabled by user)])
 119 else
 120         if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then
 121                 AC_MSG_RESULT([yes])
 122                 AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available])
 123         else
 124                 AC_MSG_RESULT([no (header not available)])
 125         fi
 126 fi
 127
 128 AC_CHECK_TYPES(struct timespec)
 129
 130 # Message logging
 131 AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])],
 132         [log_enabled=$enableval],
 133         [log_enabled='yes'])
 134 if test "x$log_enabled" != "xno"; then
 135         AC_DEFINE([ENABLE_LOGGING], 1, [Message logging])
 136 fi
 137
 138 AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log],
 139         [enable debug logging (default n)])],
 140         [debug_log_enabled=$enableval],
 141         [debug_log_enabled='no'])
 142 if test "x$debug_log_enabled" != "xno"; then
 143         AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging])
 144 fi
 145
 146 # Examples build
 147 AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build],
 148         [build example applications (default n)])],
 149         [build_examples=$enableval],
 150         [build_examples='no'])
 151 AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"])
 152
 153 # Restore gnu89 inline semantics on gcc 4.3 and newer
 154 saved_cflags="$CFLAGS"
 155 CFLAGS="$CFLAGS -fgnu89-inline"
 156 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), inline_cflags="-fgnu89-inline", inline_cflags="")
 157 CFLAGS="$saved_cflags"
 158
 159 # check for -fvisibility=hidden compiler support (GCC >= 3.4)
 160 saved_cflags="$CFLAGS"
 161 # -Werror required for cygwin
 162 CFLAGS="$CFLAGS -Werror -fvisibility=hidden"
 163 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 164         [VISIBILITY_CFLAGS="-fvisibility=hidden"
 165          AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ],
 166         [ VISIBILITY_CFLAGS=""
 167          AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ],
 168         ])
 169 CFLAGS="$saved_cflags"
 170
 171 # check for -Wno-pointer-sign compiler support (GCC >= 4)
 172 saved_cflags="$CFLAGS"
 173 CFLAGS="$CFLAGS -Wno-pointer-sign"
 174 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]),
 175         nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="")
 176 CFLAGS="$saved_cflags"
 177
 178 # sigaction not available on MinGW
 179 AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no])
 180 AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"])
 181
 182 # headers not available on all platforms but required on others
 183 AC_CHECK_HEADERS([sys/time.h])
 184
 185 AC_SUBST([THREAD_CFLAGS])
 186
 187 AM_CFLAGS="-std=gnu99 $inline_cflags -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow"
 188
 189 AC_SUBST(VISIBILITY_CFLAGS)
 190 AC_SUBST(AM_CFLAGS)
 191 AC_SUBST(AM_LDFLAGS)
 192
 193 AC_CONFIG_FILES([libusb-1.0.pc] [Makefile] [libusb/Makefile] [libusb/libusb-1.0.rc] [examples/Makefile] [doc/Makefile] [doc/doxygen.cfg])
 194 AC_OUTPUT
 195