configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # in easier to understand terms:
  24 #
  25 # <mclasen> on the stable branch, interface age == micro
  26 # <mclasen> on the unstable (ie master), interface age = 0
  27
  28 m4_define([glib_major_version], [2])
  29 m4_define([glib_minor_version], [31])
  30 m4_define([glib_micro_version], [0])
  31 m4_define([glib_interface_age], [0])
  32 m4_define([glib_binary_age],
  33           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  34 m4_define([glib_version],
  35           [glib_major_version.glib_minor_version.glib_micro_version])
  36
  37 # libtool version related macros
  38 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  39 m4_define([glib_lt_current],
  40           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  41 m4_define([glib_lt_revision], [glib_interface_age])
  42 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  43 m4_define([glib_lt_current_minus_age],
  44           [m4_eval(glib_lt_current - glib_lt_age)])
  45
  46 # if the minor version number is odd, then we want debugging.  Otherwise
  47 # we only want minimal debugging support.
  48 m4_define([glib_debug_default],
  49           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  50
  51
  52 AC_INIT(glib, [glib_version],
  53         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  54
  55 AC_CONFIG_HEADER([config.h])
  56 AC_CONFIG_SRCDIR([glib/glib.h])
  57 AC_CONFIG_MACRO_DIR([m4macros])
  58
  59 # Save this value here, since automake will set cflags later
  60 cflags_set=${CFLAGS+set}
  61
  62 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  63 AM_MAINTAINER_MODE([enable])
  64
  65 # Support silent build rules. Disable
  66 # by either passing --disable-silent-rules to configure or passing V=1
  67 # to make
  68 AM_SILENT_RULES([yes])
  69
  70 GLIB_MAJOR_VERSION=glib_major_version
  71 GLIB_MINOR_VERSION=glib_minor_version
  72 GLIB_MICRO_VERSION=glib_micro_version
  73 GLIB_INTERFACE_AGE=glib_interface_age
  74 GLIB_BINARY_AGE=glib_binary_age
  75 GLIB_VERSION=glib_version
  76
  77 AC_SUBST(GLIB_MAJOR_VERSION)
  78 AC_SUBST(GLIB_MINOR_VERSION)
  79 AC_SUBST(GLIB_MICRO_VERSION)
  80 AC_SUBST(GLIB_VERSION)
  81 AC_SUBST(GLIB_INTERFACE_AGE)
  82 AC_SUBST(GLIB_BINARY_AGE)
  83
  84 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  85           [Define to the GLIB major version])
  86 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  87           [Define to the GLIB minor version])
  88 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  89           [Define to the GLIB micro version])
  90 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  91           [Define to the GLIB interface age])
  92 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  93           [Define to the GLIB binary age])
  94
  95 # libtool versioning
  96 LT_RELEASE=glib_lt_release
  97 LT_CURRENT=glib_lt_current
  98 LT_REVISION=glib_lt_revision
  99 LT_AGE=glib_lt_age
 100 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 101 AC_SUBST(LT_RELEASE)
 102 AC_SUBST(LT_CURRENT)
 103 AC_SUBST(LT_REVISION)
 104 AC_SUBST(LT_AGE)
 105 AC_SUBST(LT_CURRENT_MINUS_AGE)
 106
 107 dnl Checks for programs.
 108 AC_PROG_CC
 109 AC_PROG_CPP
 110
 111 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 112
 113 AC_CANONICAL_HOST
 114
 115 AC_MSG_CHECKING([for the BeOS])
 116 case $host in
 117   *-*-beos*)
 118     glib_native_beos="yes"
 119     ;;
 120   *)
 121     glib_native_beos="no"
 122     ;;
 123 esac
 124 AC_MSG_RESULT([$glib_native_beos])
 125
 126 dnl
 127
 128 AC_MSG_CHECKING([for Win32])
 129 LIB_EXE_MACHINE_FLAG=X86
 130 case "$host" in
 131   *-*-mingw*)
 132     glib_native_win32=yes
 133     glib_pid_type='void *'
 134     glib_cv_stack_grows=no
 135     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 136     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 137     # (Sorry, I don't know exactly what is the problem, but it is related to
 138     # floating point formatting and decimal point vs. comma.)
 139     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 140     # rigorous enough to notice, though.
 141     # So preset the autoconf cache variables.
 142     ac_cv_func_vsnprintf_c99=no
 143     ac_cv_func_snprintf_c99=no
 144     case "$host" in
 145     x86_64-*-*)
 146       LIB_EXE_MACHINE_FLAG=X64
 147       ;;
 148     esac
 149     ;;
 150   *)
 151     glib_native_win32=no
 152     glib_pid_type=int
 153     ;;
 154 esac
 155 case $host in
 156   *-*-linux*)
 157     glib_os_linux=yes
 158     ;;
 159 esac
 160
 161 AC_MSG_RESULT([$glib_native_win32])
 162
 163 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 164
 165 glib_have_carbon=no
 166 AC_MSG_CHECKING([for Mac OS X Carbon support])
 167 AC_TRY_CPP([
 168 #include <Carbon/Carbon.h>
 169 #include <CoreServices/CoreServices.h>
 170 ], glib_have_carbon=yes)
 171
 172 AC_MSG_RESULT([$glib_have_carbon])
 173
 174 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 175 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 176 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 177 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 178 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 179
 180 if test "$glib_native_win32" = "yes"; then
 181   AC_CHECK_TOOL(WINDRES, windres, no)
 182   if test "$WINDRES" = no; then
 183     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 184   fi
 185   AC_CHECK_TOOL(NM, nm, no)
 186   if test "$NM" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(RANLIB, ranlib, :)
 190   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 191 fi
 192 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 193
 194 if test "$glib_native_win32" != yes; then
 195     # libtool option to control which symbols are exported
 196     # right now, symbols starting with _ are not exported
 197     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 198 else
 199     # We currently use .def files on Windows
 200     LIBTOOL_EXPORT_OPTIONS=
 201 fi
 202 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 203
 204 if test "x$glib_have_carbon" = "xyes"; then
 205   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 206   LDFLAGS="$LDFLAGS -framework Carbon"
 207 fi
 208
 209 gl_GLIBC21
 210 if test "x$GLIBC21" = "xyes"; then
 211   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 212 fi
 213
 214 dnl declare --enable-* args and collect ac_help strings
 215 AC_ARG_ENABLE(debug,
 216               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 217                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 218               enable_debug=glib_debug_default)
 219
 220 AC_ARG_ENABLE(gc_friendly,
 221               [AC_HELP_STRING([--enable-gc-friendly],
 222                               [turn on garbage collector friendliness [default=no]])],,
 223               [enable_gc_friendly=no])
 224 AC_ARG_ENABLE(mem_pools,
 225               [AC_HELP_STRING([--disable-mem-pools],
 226                               [disable all glib memory pools])],,
 227               [disable_mem_pools=no])
 228 AC_ARG_ENABLE(rebuilds,
 229               [AC_HELP_STRING([--disable-rebuilds],
 230                               [disable all source autogeneration rules])],,
 231               [enable_rebuilds=yes])
 232
 233 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 234 if test "x$enable_gc_friendly" = "xyes"; then
 235   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 236   AC_MSG_RESULT([yes])
 237 else
 238   AC_MSG_RESULT([no])
 239 fi
 240
 241 AC_MSG_CHECKING([whether to disable memory pools])
 242 if test "x$disable_mem_pools" = "xno"; then
 243   AC_MSG_RESULT([no])
 244 else
 245   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 246   AC_SUBST(DISABLE_MEM_POOLS)
 247   AC_MSG_RESULT([yes])
 248 fi
 249
 250 dnl location to install runtime libraries, e.g. ../../lib to install
 251 dnl to /lib if libdir is /usr/lib
 252 AC_ARG_WITH(runtime-libdir,
 253            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 254                            [install runtime libraries relative to libdir])],
 255            [],
 256            [with_runtime_libdir=""])
 257 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 258 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 259 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 260 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 261 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 262
 263 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 264 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 265 AC_LANG_SAVE
 266 AC_LANG_CPLUSPLUS
 267 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 268 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 269 AC_LANG_RESTORE
 270
 271 AM_PROG_CC_STDC
 272 AM_PROG_CC_C_O
 273 AC_PROG_INSTALL
 274
 275 AC_SYS_LARGEFILE
 276
 277 PKG_PROG_PKG_CONFIG(0.16)
 278
 279 if test "x$enable_debug" = "xyes"; then
 280   if test x$cflags_set != xset ; then
 281       case " $CFLAGS " in
 282       *[[\ \    ]]-g[[\ \       ]]*) ;;
 283       *) CFLAGS="$CFLAGS -g" ;;
 284       esac
 285   fi
 286
 287   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 288 else
 289   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 290
 291   if test "x$enable_debug" = "xno"; then
 292     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 293   fi
 294 fi
 295
 296 # Ensure MSVC-compatible struct packing convention is used when
 297 # compiling for Win32 with gcc.
 298 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 299 # gcc2 uses "-fnative-struct".
 300 if test x"$glib_native_win32" = xyes; then
 301   if test x"$GCC" = xyes; then
 302     msnative_struct=''
 303     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 304     if test -z "$ac_cv_prog_CC"; then
 305       our_gcc="$CC"
 306     else
 307       our_gcc="$ac_cv_prog_CC"
 308     fi
 309     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 310       2.)
 311         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 312           msnative_struct='-fnative-struct'
 313         fi
 314         ;;
 315       *)
 316         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 317           msnative_struct='-mms-bitfields'
 318         fi
 319         ;;
 320     esac
 321     if test x"$msnative_struct" = x ; then
 322       AC_MSG_RESULT([no way])
 323       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 324     else
 325       CFLAGS="$CFLAGS $msnative_struct"
 326       AC_MSG_RESULT([${msnative_struct}])
 327     fi
 328   fi
 329 fi
 330 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 331 AC_SUBST(GLIB_EXTRA_CFLAGS)
 332
 333 AC_EXEEXT
 334
 335 # define a MAINT-like variable REBUILD which is set if Perl
 336 # and awk are found, so autogenerated sources can be rebuilt
 337 AC_PROG_AWK
 338 AC_CHECK_PROGS(PERL, [perl5 perl])
 339 # We would like indent, but don't require it.
 340 AC_CHECK_PROG(INDENT, indent, indent)
 341 REBUILD=\#
 342 if test "x$enable_rebuilds" = "xyes" && \
 343      test -n "$PERL" && \
 344      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 345      test -n "$AWK" ; then
 346   REBUILD=
 347 fi
 348 AC_SUBST(REBUILD)
 349
 350 # Need full path to Perl for glib-mkenums
 351 #
 352 if test "x$PERL" != x ; then
 353   AC_PATH_PROG(PERL_PATH, [$PERL])
 354 fi
 355 if test "x$PERL_PATH" = x ; then
 356   PERL_PATH="/usr/bin/env perl"
 357 fi
 358 AC_SUBST(PERL_PATH)
 359
 360 # Need suitable python path for greport
 361 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 362
 363
 364 dnl ***********************
 365 dnl *** Tests for iconv ***
 366 dnl ***********************
 367 dnl
 368 dnl We do this before the gettext checks, to avoid distortion
 369
 370 dnl On Windows we use a native implementation
 371
 372 if test x"$glib_native_win32" = xyes; then
 373   with_libiconv=native
 374 else
 375   AC_ARG_WITH(libiconv,
 376               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 377                               [use the libiconv library])],,
 378               [with_libiconv=maybe])
 379
 380   found_iconv=no
 381   case $with_libiconv in
 382     maybe)
 383       # Check in the C library first
 384       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 385       # Check if we have GNU libiconv
 386       if test $found_iconv = "no"; then
 387         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 388       fi
 389       # Check if we have a iconv in -liconv, possibly from vendor
 390       if test $found_iconv = "no"; then
 391         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 392       fi
 393       ;;
 394     no)
 395       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 396       ;;
 397     gnu|yes)
 398       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 399       ;;
 400     native)
 401       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 402       ;;
 403   esac
 404
 405   if test "x$found_iconv" = "xno" ; then
 406      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 407   fi
 408 fi
 409
 410 AC_ARG_ENABLE(iconv-cache,
 411               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 412                               [cache iconv descriptors [default=auto]])],,
 413               [enable_iconv_cache=auto])
 414
 415 AC_MSG_CHECKING([whether to cache iconv descriptors])
 416 case $enable_iconv_cache in
 417   auto)
 418     if test $ac_cv_gnu_library_2_1 = yes; then
 419       enable_iconv_cache=no
 420     else
 421       enable_iconv_cache=yes
 422     fi
 423   ;;
 424   yes|no)
 425   ;;
 426   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 427   ;;
 428 esac
 429
 430 if test $enable_iconv_cache = yes; then
 431    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 432 fi
 433
 434 AC_MSG_RESULT($enable_iconv_cache)
 435
 436
 437 dnl
 438 dnl zlib support
 439 dnl
 440 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 441 if test "x$found_zlib" = "xno" ; then
 442   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 443   if test "x$found_zlib" = "xno" ; then
 444     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 445   fi
 446   ZLIB_LIBS='-lz'
 447   AC_SUBST(ZLIB_LIBS)
 448 fi
 449
 450 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 451 AC_SUBST(LIBFFI_CFLAGS)
 452 AC_SUBST(LIBFFI_LIBS)
 453
 454 dnl
 455 dnl gettext support
 456 dnl
 457
 458 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 459 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 460 GLIB_GNU_GETTEXT
 461
 462 if test "$gt_cv_have_gettext" != "yes" ; then
 463   AC_MSG_ERROR([
 464 *** You must have either have gettext support in your C library, or use the
 465 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 466 ])
 467 fi
 468
 469 LIBS="$INTLLIBS $LIBS"
 470
 471 GETTEXT_PACKAGE=glib20
 472 AC_SUBST(GETTEXT_PACKAGE)
 473 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 474   [Define the gettext package to be used])
 475
 476 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 477
 478 dnl
 479 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 480 dnl
 481
 482 if test x"$glib_native_win32" != xyes; then
 483   if test x$with_libiconv != xno ; then
 484     case " $INTLLIBS " in
 485     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 486     *) ICONV_LIBS="-liconv" ;;
 487     esac
 488   fi
 489 fi
 490 AC_SUBST(ICONV_LIBS)
 491
 492 case $with_libiconv in
 493   gnu)
 494     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 495     ;;
 496   native)
 497     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 498     ;;
 499 esac
 500
 501 dnl Initialize libtool
 502 LT_PREREQ([2.2])
 503 LT_INIT([disable-static win32-dll])
 504 dnl when using libtool 2.x create libtool early, because it's used in configure
 505 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 506
 507
 508 if test "x$GCC" = "xyes"; then
 509   case " $CFLAGS " in
 510   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 511   *) CFLAGS="$CFLAGS -Wall" ;;
 512   esac
 513 fi
 514
 515 CPPFLAGS="$CPPFLAGS -DG_DISABLE_SINGLE_INCLUDES"
 516
 517 if test "$glib_native_win32" = "yes"; then
 518   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 519     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 520   fi
 521   if test x$enable_static = xyes; then
 522     glib_win32_static_compilation=yes
 523     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 524 #define GOBJECT_STATIC_COMPILATION 1"
 525     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 526   fi
 527 fi
 528 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 529
 530 dnl
 531 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 532 dnl
 533 if test $cross_compiling != yes ; then
 534     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 535     glib_save_LIBS=$LIBS
 536     LIBS="$LIBS -lm"
 537     AC_TRY_RUN([#include <math.h>
 538                  int main (void) { return (log(1) != log(1.)); }],
 539          AC_MSG_RESULT(none needed),
 540          glib_save_CFLAGS=$CFLAGS
 541          CFLAGS="$CFLAGS -std1"
 542          AC_TRY_RUN([#include <math.h>
 543                      int main (void) { return (log(1) != log(1.)); }],
 544              AC_MSG_RESULT(-std1),
 545              AC_MSG_RESULT()
 546              CFLAGS=$glib_save_CFLAGS
 547              AC_MSG_WARN(
 548                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 549          )
 550     )
 551     LIBS=$glib_save_LIBS
 552 fi
 553
 554 dnl NeXTStep cc seems to need this
 555 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 556 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 557   AC_MSG_RESULT(none needed),
 558   glib_save_CFLAGS=$CFLAGS
 559   CFLAGS="$CFLAGS -posix"
 560   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 561     AC_MSG_RESULT(-posix),
 562     AC_MSG_RESULT()
 563     CFLAGS=$glib_save_CFLAGS
 564     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 565
 566 # Checks for header files.
 567 AC_HEADER_STDC
 568
 569 # Checks for library functions.
 570 AC_FUNC_VPRINTF
 571 AC_FUNC_ALLOCA
 572 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 573 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 574
 575 dnl don't use AC_CHECK_FUNCS here, otherwise HAVE_QSORT_R will
 576 dnl be automatically defined, which we don't want to do
 577 dnl until we have checked this function is actually usable
 578 AC_CHECK_FUNC([qsort_r])
 579
 580 # BSD has a qsort_r with wrong argument order
 581 if test x$ac_cv_func_qsort_r = xyes ; then
 582   AC_CACHE_CHECK([if qsort_r uses glibc compatible argument order], glib_cv_have_qsort_r, [
 583   AC_RUN_IFELSE([AC_LANG_SOURCE([[
 584   #define _GNU_SOURCE
 585   #include <stdlib.h>
 586
 587   static int
 588   cmp (const void *a, const void *b, void *c)
 589   {
 590     const int *ia = a;
 591     const int *ib = b;
 592
 593     if (*ia < *ib)
 594       return -1;
 595     else if (*ia > *ib)
 596       return 1;
 597     else
 598       return 0;
 599   }
 600
 601   int
 602   main (int argc, char **argv)
 603   {
 604     int arr[3] = { 1, 2, 0 };
 605     int d = 3;
 606
 607     qsort_r (arr, 3, sizeof (int), cmp, &d);
 608
 609     if (arr[0] == 0 && arr[1] == 1 && arr[2] == 2)
 610       return 0;
 611     else
 612       return 1;
 613   }]])],[glib_cv_have_qsort_r=yes],[glib_cv_have_qsort_r=no])])
 614 fi
 615
 616 if test x$glib_cv_have_qsort_r = xyes ; then
 617   AC_DEFINE(HAVE_QSORT_R, 1, [Define to 1 if you have the 'qsort_r' function])
 618 fi
 619
 620 AC_CHECK_SIZEOF(char)
 621 AC_CHECK_SIZEOF(short)
 622 AC_CHECK_SIZEOF(long)
 623 AC_CHECK_SIZEOF(int)
 624 AC_CHECK_SIZEOF(void *)
 625 AC_CHECK_SIZEOF(long long)
 626 AC_CHECK_SIZEOF(__int64)
 627
 628 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 629   :
 630 else
 631   AC_MSG_ERROR([
 632 *** GLib requires a 64 bit type. You might want to consider
 633 *** using the GNU C compiler.
 634 ])
 635 fi
 636
 637 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 638         # long long is a 64 bit integer.
 639         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 640         AC_CACHE_VAL(glib_cv_long_long_format,[
 641                 for format in ll q I64; do
 642                   AC_TRY_RUN([#include <stdio.h>
 643                         int main()
 644                         {
 645                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 646                           char buffer[1000];
 647                           sprintf (buffer, "%${format}u", a);
 648                           sscanf (buffer, "%${format}u", &b);
 649                           exit (b!=a);
 650                         }
 651                         ],
 652                         [glib_cv_long_long_format=${format}
 653                         break],
 654                         [],[:])
 655                 done])
 656         if test -n "$glib_cv_long_long_format"; then
 657           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 658           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 659           if test x"$glib_cv_long_long_format" = xI64; then
 660             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 661           fi
 662         else
 663           AC_MSG_RESULT(none)
 664         fi
 665 elif test x$ac_cv_sizeof___int64 = x8; then
 666         # __int64 is a 64 bit integer.
 667         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 668         # We know this is MSVCRT.DLL, and what the formats are
 669         glib_cv_long_long_format=I64
 670         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 671         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 672         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 673 fi
 674
 675 dnl long doubles were not used, and a portability problem
 676 dnl AC_C_LONG_DOUBLE
 677 AC_C_CONST
 678
 679 dnl ok, here we try to check whether the systems prototypes for
 680 dnl malloc and friends actually match the prototypes provided
 681 dnl by gmem.h (keep in sync). i currently only know how to check
 682 dnl this reliably with gcc (-Werror), improvements for other
 683 dnl compilers are apprechiated.
 684 SANE_MALLOC_PROTOS=no
 685 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 686 glib_save_CFLAGS=$CFLAGS
 687 if test "x$GCC" = "xyes"; then
 688   CFLAGS="$CFLAGS -Werror"
 689   AC_TRY_COMPILE([#include <stdlib.h>], [
 690     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 691     void* (*my_malloc_p)  (size_t)         = malloc;
 692     void  (*my_free_p)    (void*)          = free;
 693     void* (*my_realloc_p) (void*, size_t)  = realloc;
 694     my_calloc_p = 0;
 695     my_malloc_p = 0;
 696     my_free_p = 0;
 697     my_realloc_p = 0;
 698   ],
 699     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 700       [Define if you have correct malloc prototypes])
 701     SANE_MALLOC_PROTOS=yes)
 702 fi
 703 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 704 CFLAGS=$glib_save_CFLAGS
 705
 706 dnl
 707 dnl check in which direction the stack grows
 708 dnl
 709 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 710         AC_TRY_RUN([
 711         volatile int *a = 0, *b = 0;
 712         void foo (void);
 713         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 714         void foo (void) { volatile int x = 5; b = &x; }
 715         ],
 716         glib_cv_stack_grows=no
 717         ,
 718         glib_cv_stack_grows=yes
 719         ,)
 720 ])
 721
 722 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 723 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 724 dnl actually supported.
 725 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 726         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 727         __inline int foo () { return 0; }
 728         int main () { return foo (); }
 729         ]])],
 730         glib_cv_has__inline=yes
 731         ,
 732         glib_cv_has__inline=no
 733         ,)
 734 ])
 735 case x$glib_cv_has__inline in
 736 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 737 esac
 738 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 739         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 740         __inline__ int foo () { return 0; }
 741         int main () { return foo (); }
 742         ]])],
 743         glib_cv_has__inline__=yes
 744         ,
 745         glib_cv_has__inline__=no
 746         ,)
 747 ])
 748 case x$glib_cv_has__inline__ in
 749 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 750 esac
 751 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 752         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 753         #undef inline
 754         inline int foo () { return 0; }
 755         int main () { return foo (); }
 756         ]])],
 757         glib_cv_hasinline=yes
 758         ,
 759         glib_cv_hasinline=no
 760         ,)
 761 ])
 762 case x$glib_cv_hasinline in
 763 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 764 esac
 765
 766 # if we can use inline functions in headers
 767 AC_MSG_CHECKING(if inline functions in headers work)
 768 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 769 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 770 #  undef inline
 771 #  define inline __inline__
 772 #elif !defined (G_HAVE_INLINE)
 773 #  undef inline
 774 #  if defined (G_HAVE___INLINE__)
 775 #    define inline __inline__
 776 #  elif defined (G_HAVE___INLINE)
 777 #    define inline __inline
 778 #  endif
 779 #endif
 780
 781 int glib_test_func2 (int);
 782
 783 static inline int
 784 glib_test_func1 (void) {
 785   return glib_test_func2 (1);
 786 }
 787
 788 int
 789 main (void) {
 790   int i = 1;
 791 }]])],[g_can_inline=yes],[g_can_inline=no])
 792 AC_MSG_RESULT($g_can_inline)
 793
 794 dnl *** check for working do while(0) macros ***
 795 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 796         AC_TRY_COMPILE([],[
 797         #define STMT_START do
 798         #define STMT_END while(0)
 799         #define STMT_TEST STMT_START { i = 0; } STMT_END
 800         int main(void) { int i = 1; STMT_TEST; return i; }],
 801         [g_cv_support_dowhile_macros=yes],
 802         [g_cv_support_dowhile_macros=no],
 803         [g_cv_support_dowhile_macros=yes])
 804 ])
 805 if test x$g_cv_support_dowhile_macros = xyes; then
 806   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 807 fi
 808
 809 # check for flavours of varargs macros
 810 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 811 AC_TRY_COMPILE([],[
 812 int a(int p1, int p2, int p3);
 813 #define call_a(...) a(1,__VA_ARGS__)
 814 call_a(2,3);
 815 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 816 AC_MSG_RESULT($g_have_iso_c_varargs)
 817
 818 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 819 if test "$CXX" = ""; then
 820 dnl No C++ compiler
 821   g_have_iso_cxx_varargs=no
 822 else
 823   AC_LANG_CPLUSPLUS
 824   AC_TRY_COMPILE([],[
 825 int a(int p1, int p2, int p3);
 826 #define call_a(...) a(1,__VA_ARGS__)
 827 call_a(2,3);
 828 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 829   AC_LANG_C
 830 fi
 831 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 832
 833 AC_MSG_CHECKING(for GNUC varargs macros)
 834 AC_TRY_COMPILE([],[
 835 int a(int p1, int p2, int p3);
 836 #define call_a(params...) a(1,params)
 837 call_a(2,3);
 838 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 839 AC_MSG_RESULT($g_have_gnuc_varargs)
 840
 841 # check for GNUC visibility support
 842 AC_MSG_CHECKING(for GNUC visibility attribute)
 843 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 844 void
 845 __attribute__ ((visibility ("hidden")))
 846      f_hidden (void)
 847 {
 848 }
 849 void
 850 __attribute__ ((visibility ("internal")))
 851      f_internal (void)
 852 {
 853 }
 854 void
 855 __attribute__ ((visibility ("protected")))
 856      f_protected (void)
 857 {
 858 }
 859 void
 860 __attribute__ ((visibility ("default")))
 861      f_default (void)
 862 {
 863 }
 864 int main (int argc, char **argv)
 865 {
 866         f_hidden();
 867         f_internal();
 868         f_protected();
 869         f_default();
 870         return 0;
 871 }
 872 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 873 AC_MSG_RESULT($g_have_gnuc_visibility)
 874 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 875
 876 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 877 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 878 #else
 879 # include "error: this is not Sun Studio."
 880 #endif
 881 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 882 AC_MSG_RESULT($g_have_sunstudio_visibility)
 883 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 884
 885 # check for bytesex stuff
 886 AC_C_BIGENDIAN
 887 if test x$ac_cv_c_bigendian = xuniversal ; then
 888 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 889 #else
 890 #error Not a big endian.
 891 #endif],
 892     ac_cv_c_bigendian=yes
 893     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 894 #else
 895 #error Not a little endian.
 896 #endif],
 897     ac_cv_c_bigendian=no
 898     ,AC_MSG_WARN([Could not determine endianness.])))
 899 fi
 900
 901
 902 # check for header files
 903 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 904 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 905 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 906 AC_CHECK_HEADERS([sys/vfs.h sys/mount.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 907 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h sys/sysctl.h fstab.h])
 908 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 909 AC_CHECK_HEADERS([linux/magic.h])
 910 AC_CHECK_HEADERS([sys/prctl.h])
 911
 912 # check for structure fields
 913 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 914 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 915 #include <sys/stat.h>
 916 #include <unistd.h>
 917 #ifdef HAVE_SYS_STATFS_H
 918 #include <sys/statfs.h>
 919 #endif
 920 #ifdef HAVE_SYS_PARAM_H
 921 #include <sys/param.h>
 922 #endif
 923 #ifdef HAVE_SYS_MOUNT_H
 924 #include <sys/mount.h>
 925 #endif])
 926 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 927 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 928 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 929 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 930
 931 # Checks for libcharset
 932 AM_LANGINFO_CODESET
 933 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 934 AC_CHECK_FUNCS(setlocale)
 935
 936 # check additional type sizes
 937 AC_CHECK_SIZEOF(size_t)
 938
 939 dnl Try to figure out whether gsize, gssize should be long or int
 940 AC_MSG_CHECKING([for the appropriate definition for size_t])
 941
 942 case $ac_cv_sizeof_size_t in
 943   $ac_cv_sizeof_short)
 944       glib_size_type=short
 945       ;;
 946   $ac_cv_sizeof_int)
 947       glib_size_type=int
 948       ;;
 949   $ac_cv_sizeof_long)
 950       glib_size_type=long
 951       ;;
 952   $ac_cv_sizeof_long_long)
 953       glib_size_type='long long'
 954       ;;
 955   $ac_cv_sizeof__int64)
 956       glib_size_type='__int64'
 957       ;;
 958   *)  AC_MSG_ERROR([No type matching size_t in size])
 959       ;;
 960 esac
 961
 962 dnl If int/long are the same size, we see which one produces
 963 dnl warnings when used in the location as size_t. (This matters
 964 dnl on AIX with xlc)
 965 dnl
 966 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 967    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 968   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 969 #if defined(_AIX) && !defined(__GNUC__)
 970 #pragma options langlvl=stdc89
 971 #endif
 972 #include <stddef.h>
 973 int main ()
 974 {
 975   size_t s = 1;
 976   unsigned int *size_int = &s;
 977   return (int)*size_int;
 978 }
 979     ]])],glib_size_type=int,
 980       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 981 #if defined(_AIX) && !defined(__GNUC__)
 982 #pragma options langlvl=stdc89
 983 #endif
 984 #include <stddef.h>
 985 int main ()
 986 {
 987    size_t s = 1;
 988    unsigned long *size_long = &s;
 989    return (int)*size_long;
 990 }
 991         ]])],glib_size_type=long)])
 992 fi
 993
 994 AC_MSG_RESULT(unsigned $glib_size_type)
 995
 996 # Check for some functions
 997 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 998 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
 999 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
1000 # Check for high-resolution sleep functions
1001 AC_CHECK_FUNCS(splice)
1002
1003 # To avoid finding a compatibility unusable statfs, which typically
1004 # successfully compiles, but warns to use the newer statvfs interface:
1005 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
1006 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
1007
1008 AC_MSG_CHECKING([whether to use statfs or statvfs])
1009 # Some systems have both statfs and statvfs, pick the most "native" for these
1010 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
1011    [
1012    # on solaris and irix, statfs doesn't even have the f_bavail field
1013    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
1014       [ac_cv_func_statfs=no],
1015    # else, at least on linux, statfs is the actual syscall
1016       [ac_cv_func_statvfs=no])
1017    ])
1018
1019 AS_IF([test x$ac_cv_func_statfs = xyes],
1020       [
1021          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
1022          AC_MSG_RESULT([statfs])
1023       ],
1024       [test x$ac_cv_func_statvfs = xyes],
1025       [
1026          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1027          AC_MSG_RESULT([statvfs])
1028       ],
1029       [  AC_MSG_RESULT([neither])])
1030
1031 AC_CHECK_HEADERS(crt_externs.h)
1032 AC_CHECK_FUNCS(_NSGetEnviron)
1033
1034 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1035
1036 AC_FUNC_VSNPRINTF_C99
1037 AC_FUNC_PRINTF_UNIX98
1038
1039 # Internet address families
1040 if test $glib_native_win32 = yes; then
1041   glib_inet_includes=["
1042 #include <winsock2.h>
1043   "]
1044 else
1045   glib_inet_includes=["
1046 #include <sys/types.h>
1047 #include <sys/socket.h>
1048   "]
1049 fi
1050
1051 glib_failed=false
1052 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1053 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1054 # winsock defines this even though it doesn't support it
1055 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1056 if $glib_failed ; then
1057   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1058 fi
1059
1060 glib_failed=false
1061 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1062 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1063 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1064 if $glib_failed ; then
1065   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1066 fi
1067
1068 AC_CHECK_FUNCS(getprotobyname_r endservent)
1069 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1070
1071 if test $glib_native_win32 = no; then
1072   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1073   NETWORK_LIBS=""
1074   AC_MSG_CHECKING([for res_query])
1075   AC_TRY_LINK([#include <sys/types.h>
1076                #include <netinet/in.h>
1077                #include <arpa/nameser.h>
1078                #include <resolv.h>
1079               ],[
1080                res_query("test", 0, 0, (void *)0, 0);
1081               ],[AC_MSG_RESULT([yes])],
1082               [save_libs="$LIBS"
1083                LIBS="-lresolv $LIBS"
1084                AC_TRY_LINK([#include <sys/types.h>
1085                             #include <netinet/in.h>
1086                             #include <arpa/nameser.h>
1087                             #include <resolv.h>
1088                            ],[
1089                             res_query("test", 0, 0, (void *)0, 0);
1090                            ],[AC_MSG_RESULT([in -lresolv])
1091                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1092                            [LIBS="-lbind $save_libs"
1093                             AC_TRY_LINK([#include <resolv.h>],
1094                                         [res_query("test", 0, 0, (void *)0, 0);],
1095                                         [AC_MSG_RESULT([in -lbind])
1096                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1097                                         [AC_MSG_ERROR(not found)])])
1098                LIBS="$save_libs"])
1099   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1100                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1101                                         [AC_MSG_ERROR(Could not find socket())]))
1102 fi
1103 AC_SUBST(NETWORK_LIBS)
1104
1105 case $host in
1106   *-*-solaris* )
1107      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1108      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1109      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1110      ;;
1111 esac
1112
1113 dnl
1114 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1115 dnl
1116 if test "$ac_cv_func_statfs" = yes ; then
1117   AC_MSG_CHECKING([number of arguments to statfs()])
1118   AC_TRY_COMPILE([#include <unistd.h>
1119   #ifdef HAVE_SYS_PARAM_H
1120   #include <sys/param.h>
1121   #endif
1122   #ifdef HAVE_SYS_VFS_H
1123   #include <sys/vfs.h>
1124   #endif
1125   #ifdef HAVE_SYS_MOUNT_H
1126   #include <sys/mount.h>
1127   #endif
1128   #ifdef HAVE_SYS_STATFS_H
1129   #include <sys/statfs.h>
1130   #endif], [struct statfs st;
1131   statfs(NULL, &st);],[
1132     AC_MSG_RESULT([2])
1133     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1134     AC_TRY_COMPILE([#include <unistd.h>
1135   #ifdef HAVE_SYS_PARAM_H
1136   #include <sys/param.h>
1137   #endif
1138   #ifdef HAVE_SYS_VFS_H
1139   #include <sys/vfs.h>
1140   #endif
1141   #ifdef HAVE_SYS_MOUNT_H
1142   #include <sys/mount.h>
1143   #endif
1144   #ifdef HAVE_SYS_STATFS_H
1145   #include <sys/statfs.h>
1146   #endif], [struct statfs st;
1147   statfs(NULL, &st, sizeof (st), 0);],[
1148       AC_MSG_RESULT([4])
1149       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1150       AC_MSG_RESULT(unknown)
1151       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1152 fi
1153
1154 #
1155 # Check whether to use an included printf
1156 #
1157
1158 AC_ARG_ENABLE(included-printf,
1159               [AC_HELP_STRING([--enable-included-printf],
1160                               [use included printf [default=auto]])],
1161               enable_included_printf="$enableval")
1162
1163 need_included_printf=no
1164 if test "x$enable_included_printf" = "xyes" ; then
1165   need_included_printf=yes
1166 fi
1167 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1168   need_included_printf=yes
1169 fi
1170 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1171   need_included_printf=yes
1172 fi
1173 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1174    test -z "$glib_cv_long_long_format" ; then
1175   need_included_printf=yes
1176 fi
1177
1178 if test "x$enable_included_printf" = "xno" &&
1179    test "x$need_included_printf" = "xyes" ; then
1180   AC_MSG_ERROR([
1181 *** Your C library's printf doesn't appear to have the features that
1182 *** GLib needs, but you specified --enable-included-printf=no.])
1183 fi
1184
1185 enable_included_printf=$need_included_printf
1186
1187 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1188 if test "$enable_included_printf" != "yes" ; then
1189   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1190 else
1191   if test -z "$glib_cv_long_long_format" ; then
1192     glib_cv_long_long_format="ll"
1193   fi
1194   AC_DEFINE(HAVE_VASPRINTF,1)
1195 fi
1196
1197 # Checks needed for gnulib vasnprintf
1198 bh_C_SIGNED
1199 jm_AC_TYPE_LONG_LONG
1200 gt_TYPE_LONGDOUBLE
1201 gt_TYPE_WCHAR_T
1202 gt_TYPE_WINT_T
1203 AC_TYPE_SIZE_T
1204 AC_CHECK_TYPES(ptrdiff_t)
1205 jm_AC_TYPE_INTMAX_T
1206 AC_CHECK_FUNCS([snprintf wcslen])
1207 AC_FUNC_SNPRINTF_C99
1208
1209 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1210 # The check is borrowed from the PERL Configure script.
1211 if test "$ac_cv_func_memmove" != "yes"; then
1212   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1213     glib_cv_working_bcopy,[AC_TRY_RUN([
1214       int main() {
1215         char buf[128], abc[128], *b;
1216         int len, off, align;
1217         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1218         for (align = 7; align >= 0; align--) {
1219           for (len = 36; len; len--) {
1220             b = buf+align; bcopy(abc, b, len);
1221             for (off = 1; off <= len; off++) {
1222               bcopy(b, b+off, len); bcopy(b+off, b, len);
1223                 if (bcmp(b, abc, len)) return(1);
1224             }
1225           }
1226         }
1227         return(0);
1228       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1229
1230   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1231   if test "$glib_cv_working_bcopy" = "yes"; then
1232     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1233   fi
1234 fi
1235
1236 # Check for sys_errlist
1237 AC_MSG_CHECKING(for sys_errlist)
1238 AC_TRY_LINK(, [
1239 extern char *sys_errlist[];
1240 extern int sys_nerr;
1241 sys_errlist[sys_nerr-1][0] = 0;
1242 ], glib_ok=yes, glib_ok=no)
1243 AC_MSG_RESULT($glib_ok)
1244 if test "$glib_ok" = "no"; then
1245     AC_DEFINE(NO_SYS_ERRLIST,1,[global 'sys_errlist' not found])
1246 fi
1247
1248 # Check for sys_siglist
1249 AC_MSG_CHECKING(for sys_siglist)
1250 AC_TRY_LINK(, [
1251 extern char *sys_siglist[];
1252 exit (sys_siglist[0]);
1253 ], glib_ok=yes, glib_ok=no)
1254 AC_MSG_RESULT($glib_ok)
1255 if test "$glib_ok" = "no"; then
1256     AC_DEFINE(NO_SYS_SIGLIST,1,[global 'sys_siglist' not found])
1257 fi
1258
1259 # Check for sys_siglist decl (see Tue Jan 19 00:44:24 1999 in changelog)
1260 AC_MSG_CHECKING(for sys_siglist declaration)
1261 AC_TRY_COMPILE([#include <signal.h>], [
1262 strlen (sys_siglist[0]);
1263 ], glib_ok=yes, glib_ok=no)
1264 AC_MSG_RESULT($glib_ok)
1265 if test "$glib_ok" = "no"; then
1266     AC_DEFINE(NO_SYS_SIGLIST_DECL,1,[global 'sys_siglist' not declared])
1267 fi
1268
1269 # Check if <sys/select.h> needs to be included for fd_set
1270 AC_MSG_CHECKING([for fd_set])
1271 AC_TRY_COMPILE([#include <sys/types.h>],
1272         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1273 if test "$gtk_ok" = "yes"; then
1274     AC_MSG_RESULT([yes, found in sys/types.h])
1275 else
1276     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1277     if test "$gtk_ok" = "yes"; then
1278         # *** FIXME: give it a different name
1279         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1280         AC_MSG_RESULT([yes, found in sys/select.h])
1281     else
1282         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1283         AC_MSG_RESULT(no)
1284     fi
1285 fi
1286
1287 dnl *** check for sane realloc() ***
1288 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1289         AC_TRY_RUN([#include <stdlib.h>
1290         int main() {
1291           return realloc (0, sizeof (int)) == 0;
1292         }],
1293         [glib_cv_sane_realloc=yes],
1294         [glib_cv_sane_realloc=no],
1295         [glib_cv_sane_realloc=yes])
1296 ])
1297 if test x$glib_cv_sane_realloc = xyes; then
1298   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1299 fi
1300
1301 dnl Check for nl_langinfo and CODESET
1302 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1303         AC_TRY_COMPILE([#include <langinfo.h>],
1304                 [char *codeset = nl_langinfo (CODESET);],
1305                 [glib_cv_langinfo_codeset=yes],
1306                 [glib_cv_langinfo_codeset=no])])
1307 if test x$glib_cv_langinfo_codeset = xyes; then
1308   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1309 fi
1310
1311 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1312 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1313         AC_TRY_COMPILE([#include <langinfo.h>],
1314                 [char *str;
1315                  str = nl_langinfo (PM_STR);
1316                  str = nl_langinfo (D_T_FMT);
1317                  str = nl_langinfo (D_FMT);
1318                  str = nl_langinfo (T_FMT);
1319                  str = nl_langinfo (T_FMT_AMPM);
1320                  str = nl_langinfo (MON_1);
1321                  str = nl_langinfo (ABMON_12);
1322                  str = nl_langinfo (DAY_1);
1323                  str = nl_langinfo (ABDAY_7);],
1324                 [glib_cv_langinfo_time=yes],
1325                 [glib_cv_langinfo_time=no])])
1326 if test x$glib_cv_langinfo_time = xyes; then
1327   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1328 fi
1329
1330 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_WC
1331 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)], glib_cv_langinfo_outdigit,[
1332         AC_TRY_COMPILE([#include <langinfo.h>],
1333                 [char *str;
1334                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_WC);
1335                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_WC);
1336                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_WC);
1337                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_WC);
1338                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_WC);
1339                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_WC);
1340                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_WC);
1341                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_WC);
1342                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_WC);
1343                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_WC);],
1344                 [glib_cv_langinfo_outdigit=yes],
1345                 [glib_cv_langinfo_outdigit=no])])
1346 if test x$glib_cv_langinfo_outdigit = xyes; then
1347   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_WC)])
1348 fi
1349
1350 dnl ****************************************
1351 dnl *** posix_memalign                   ***
1352 dnl ****************************************
1353 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1354 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1355     glib_cv_compliant_posix_memalign=0
1356     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1357         AC_TRY_RUN([
1358                 #define _XOPEN_SOURCE 600
1359                 #include <stdlib.h> /* posix_memalign() should be defined here */
1360                 /* some systems break if #include <malloc.h> used */
1361                 static void test_memalign (size_t boundary, size_t size) {
1362                     void *mem = 0;
1363                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1364                         exit (1);
1365                     else
1366                       free (mem);
1367                 }
1368                 int main() {
1369                     test_memalign (  128,   128 - 2 * sizeof (void*));
1370                     test_memalign (  256,   256 - 2 * sizeof (void*));
1371                     test_memalign (  512,   512 - 2 * sizeof (void*));
1372                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1373                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1374                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1375                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1376                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1377                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1378                     exit (0); /* success */
1379                 }
1380                 ],
1381             [glib_cv_compliant_posix_memalign=1], [], [:])
1382       :
1383     fi
1384     ])
1385 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1386     AC_MSG_RESULT(yes)
1387     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1388 else
1389     AC_MSG_RESULT(no)
1390 fi
1391
1392
1393 dnl ****************************************
1394 dnl *** strlcpy/strlcat                  ***
1395 dnl ****************************************
1396 # Check for strlcpy
1397 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1398 AC_TRY_RUN([#include <stdlib.h>
1399 #include <string.h>
1400 int main() {
1401   char p[10];
1402   (void) strlcpy (p, "hi", 10);
1403   if (strlcat (p, "bye", 0) != 3)
1404     return 1;
1405   return 0;
1406 }], glib_cv_have_strlcpy=yes,
1407     glib_cv_have_strlcpy=no,
1408     glib_cv_have_strlcpy=no)])
1409 if test "$glib_cv_have_strlcpy" = "yes"; then
1410     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1411 fi
1412
1413
1414 dnl **********************
1415 dnl *** va_copy checks ***
1416 dnl **********************
1417 dnl we currently check for all three va_copy possibilities, so we get
1418 dnl all results in config.log for bug reports.
1419 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1420         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1421 #include <stdlib.h>
1422         void f (int i, ...) {
1423         va_list args1, args2;
1424         va_start (args1, i);
1425         va_copy (args2, args1);
1426         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1427           exit (1);
1428         va_end (args1); va_end (args2);
1429         }
1430         int main() {
1431           f (0, 42);
1432           return 0;
1433         }]])],
1434         [glib_cv_va_copy=yes],
1435         [glib_cv_va_copy=no])
1436 ])
1437 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1438         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1439 #include <stdlib.h>
1440         void f (int i, ...) {
1441         va_list args1, args2;
1442         va_start (args1, i);
1443         __va_copy (args2, args1);
1444         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1445           exit (1);
1446         va_end (args1); va_end (args2);
1447         }
1448         int main() {
1449           f (0, 42);
1450           return 0;
1451         }]])],
1452         [glib_cv___va_copy=yes],
1453         [glib_cv___va_copy=no])
1454 ])
1455
1456 if test "x$glib_cv_va_copy" = "xyes"; then
1457   g_va_copy_func=va_copy
1458 else if test "x$glib_cv___va_copy" = "xyes"; then
1459   g_va_copy_func=__va_copy
1460 fi
1461 fi
1462
1463 if test -n "$g_va_copy_func"; then
1464   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1465 fi
1466
1467 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1468         AC_TRY_RUN([#include <stdarg.h>
1469 #include <stdlib.h>
1470         void f (int i, ...) {
1471         va_list args1, args2;
1472         va_start (args1, i);
1473         args2 = args1;
1474         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1475           exit (1);
1476         va_end (args1); va_end (args2);
1477         }
1478         int main() {
1479           f (0, 42);
1480           return 0;
1481         }],
1482         [glib_cv_va_val_copy=yes],
1483         [glib_cv_va_val_copy=no],
1484         [glib_cv_va_val_copy=yes])
1485 ])
1486
1487 if test "x$glib_cv_va_val_copy" = "xno"; then
1488   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1489 fi
1490
1491 dnl ***********************
1492 dnl *** g_module checks ***
1493 dnl ***********************
1494 G_MODULE_LIBS=
1495 G_MODULE_LIBS_EXTRA=
1496 G_MODULE_PLUGIN_LIBS=
1497 if test x"$glib_native_win32" = xyes; then
1498   dnl No use for this on Win32
1499   G_MODULE_LDFLAGS=
1500 else
1501   export SED
1502   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1503 fi
1504 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1505 G_MODULE_NEED_USCORE=0
1506 G_MODULE_BROKEN_RTLD_GLOBAL=0
1507 G_MODULE_HAVE_DLERROR=0
1508 dnl *** force native WIN32 shared lib loader
1509 if test -z "$G_MODULE_IMPL"; then
1510   case "$host" in
1511   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1512   esac
1513 fi
1514 dnl *** force native AIX library loader
1515 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1516 if test -z "$G_MODULE_IMPL"; then
1517   case "$host" in
1518   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1519   esac
1520 fi
1521 dnl *** dlopen() and dlsym() in system libraries
1522 if test -z "$G_MODULE_IMPL"; then
1523         AC_CHECK_FUNC(dlopen,
1524                       [AC_CHECK_FUNC(dlsym,
1525                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1526                       [])
1527 fi
1528 dnl *** load_image (BeOS)
1529 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1530   AC_CHECK_LIB(root, load_image,
1531       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1532       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1533       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1534       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1535       [])
1536 fi
1537 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1538 if test -z "$G_MODULE_IMPL"; then
1539         AC_CHECK_FUNC(NSLinkModule,
1540                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1541                        G_MODULE_NEED_USCORE=1],
1542                       [])
1543 fi
1544 dnl *** dlopen() and dlsym() in libdl
1545 if test -z "$G_MODULE_IMPL"; then
1546         AC_CHECK_LIB(dl, dlopen,
1547                      [AC_CHECK_LIB(dl, dlsym,
1548                                    [G_MODULE_LIBS=-ldl
1549                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1550                      [])
1551 fi
1552 dnl *** shl_load() in libdld (HP-UX)
1553 if test -z "$G_MODULE_IMPL"; then
1554         AC_CHECK_LIB(dld, shl_load,
1555                 [G_MODULE_LIBS=-ldld
1556                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1557                 [])
1558 fi
1559 dnl *** additional checks for G_MODULE_IMPL_DL
1560 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1561         LIBS_orig="$LIBS"
1562         LDFLAGS_orig="$LDFLAGS"
1563         LIBS="$G_MODULE_LIBS $LIBS"
1564         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1565 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1566         echo "void glib_plugin_test(void) { }" > plugin.c
1567         ${SHELL} ./libtool --mode=compile ${CC} -shared \
1568                 -export-dynamic -o plugin.o plugin.c 2>&1 >/dev/null
1569         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1570                 glib_cv_rtldglobal_broken,[
1571                 AC_TRY_RUN([
1572 #include <dlfcn.h>
1573 #ifndef RTLD_GLOBAL
1574 #  define RTLD_GLOBAL 0
1575 #endif
1576 #ifndef RTLD_LAZY
1577 #  define RTLD_LAZY 0
1578 #endif
1579 int glib_plugin_test;
1580 int main () {
1581     void *handle, *global, *local;
1582     global = &glib_plugin_test;
1583     handle = dlopen ("./.libs/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1584     if (!handle) return 0;
1585     local = dlsym (handle, "glib_plugin_test");
1586     return global == local;
1587 }                       ],
1588                         [glib_cv_rtldglobal_broken=no],
1589                         [glib_cv_rtldglobal_broken=yes],
1590                         [glib_cv_rtldglobal_broken=no])
1591                 rm -f plugin.c plugin.o plugin.lo .libs/plugin.o
1592                 rmdir .libs 2>/dev/null
1593         ])
1594         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1595                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1596         else
1597                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1598         fi
1599 dnl *** check whether we need preceeding underscores
1600         AC_CACHE_CHECK([for preceeding underscore in symbols],
1601                 glib_cv_uscore,[
1602                 AC_TRY_RUN([#include <dlfcn.h>
1603                 int glib_underscore_test (void) { return 42; }
1604                 int main() {
1605                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1606                   handle = dlopen ((void*)0, 0);
1607                   if (handle) {
1608                     f1 = dlsym (handle, "glib_underscore_test");
1609                     f2 = dlsym (handle, "_glib_underscore_test");
1610                   } return (!f2 || f1);
1611                 }],
1612                         [glib_cv_uscore=yes],
1613                         [glib_cv_uscore=no],
1614                         [])
1615                 rm -f plugin.c plugin.$ac_objext plugin.lo
1616         ])
1617         GLIB_ASSERT_SET(glib_cv_uscore)
1618         if test "x$glib_cv_uscore" = "xyes"; then
1619                 G_MODULE_NEED_USCORE=1
1620         else
1621                 G_MODULE_NEED_USCORE=0
1622         fi
1623
1624         LDFLAGS="$LDFLAGS_orig"
1625 dnl *** check for having dlerror()
1626         AC_CHECK_FUNC(dlerror,
1627                 [G_MODULE_HAVE_DLERROR=1],
1628                 [G_MODULE_HAVE_DLERROR=0])
1629         LIBS="$LIBS_orig"
1630 fi
1631 dnl *** done, have we got an implementation?
1632 if test -z "$G_MODULE_IMPL"; then
1633         G_MODULE_IMPL=0
1634         G_MODULE_SUPPORTED=false
1635 else
1636         G_MODULE_SUPPORTED=true
1637 fi
1638
1639 AC_MSG_CHECKING(for the suffix of module shared libraries)
1640 export SED
1641 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1642 eval $shrext_cmds
1643 module=yes eval std_shrext=$shrext_cmds
1644 # chop the initial dot
1645 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1646 AC_MSG_RESULT(.$glib_gmodule_suffix)
1647 # any reason it may fail?
1648 if test "x$glib_gmodule_suffix" = x; then
1649         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1650 fi
1651
1652 AC_SUBST(G_MODULE_SUPPORTED)
1653 AC_SUBST(G_MODULE_IMPL)
1654 AC_SUBST(G_MODULE_LIBS)
1655 AC_SUBST(G_MODULE_LIBS_EXTRA)
1656 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1657 AC_SUBST(G_MODULE_LDFLAGS)
1658 AC_SUBST(G_MODULE_HAVE_DLERROR)
1659 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1660 AC_SUBST(G_MODULE_NEED_USCORE)
1661 AC_SUBST(GLIB_DEBUG_FLAGS)
1662
1663 dnl **********************
1664 dnl *** g_spawn checks ***
1665 dnl **********************
1666
1667 AC_MSG_CHECKING(for gspawn implementation)
1668 case "$host" in
1669   *-*-mingw*)
1670     GSPAWN=gspawn-win32.lo
1671     ;;
1672   *)
1673     GSPAWN=gspawn.lo
1674     ;;
1675 esac
1676 AC_MSG_RESULT($GSPAWN)
1677 AC_SUBST(GSPAWN)
1678
1679 dnl *************************
1680 dnl *** GIOChannel checks ***
1681 dnl *************************
1682
1683 AC_MSG_CHECKING(for GIOChannel implementation)
1684 case "$host" in
1685   *-*-mingw*)
1686     GIO=giowin32.lo
1687     ;;
1688   *)
1689     GIO=giounix.lo
1690     ;;
1691 esac
1692 AC_MSG_RESULT($GIO)
1693 AC_SUBST(GIO)
1694
1695 dnl *********************************
1696 dnl *** Directory for GIO modules ***
1697 dnl *********************************
1698
1699 AC_ARG_WITH(gio-module-dir,
1700            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1701                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1702            [],
1703            [with_gio_module_dir='${libdir}/gio/modules'])
1704 GIO_MODULE_DIR=$with_gio_module_dir
1705 AC_SUBST(GIO_MODULE_DIR)
1706
1707 dnl **********************************
1708 dnl *** Check for libselinux (GIO) ***
1709 dnl **********************************
1710 AC_ARG_ENABLE(selinux,
1711               AC_HELP_STRING([--disable-selinux],
1712                              [build without selinux support]))
1713 msg_selinux=no
1714 SELINUX_LIBS=
1715 if test "x$enable_selinux" != "xno"; then
1716
1717  AC_CHECK_LIB(selinux, is_selinux_enabled,
1718    [AC_CHECK_HEADERS(selinux/selinux.h,
1719      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1720        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1721         SELINUX_LIBS="-lselinux"
1722         msg_selinux=yes])
1723      ])
1724    ])
1725 fi
1726 AC_SUBST(SELINUX_LIBS)
1727
1728 dnl *****************************
1729 dnl ** Check for inotify (GIO) **
1730 dnl *****************************
1731 inotify_support=no
1732 AC_CHECK_HEADERS([sys/inotify.h],
1733 [
1734         inotify_support=yes
1735         AC_CHECK_FUNCS(inotify_init1)
1736 ])
1737
1738 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1739
1740 dnl *********************************
1741 dnl ** Check for Solaris FEN (GIO) **
1742 dnl *********************************
1743 fen_support=no
1744 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1745 #include <port.h>
1746 #ifndef PORT_SOURCE_FILE
1747 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1748 #endif
1749 int main() { return 0; } ]])],
1750 [
1751         fen_support=yes
1752 ],)
1753
1754 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1755
1756 dnl ****************************
1757 dnl *** Checks for FAM (GIO) ***
1758 dnl ****************************
1759
1760 should_disable_fam=no
1761
1762 AC_ARG_ENABLE(fam,
1763               AC_HELP_STRING([--disable-fam],
1764                              [don't use fam for file system monitoring]),
1765                          [
1766                                 if test "x$enable_fam" = "xno"; then
1767                                         should_disable_fam=yes
1768                                 fi
1769                          ]
1770                          )
1771 fam_support=no
1772 FAM_LIBS=
1773 if test "x$should_disable_fam" = "xno"; then
1774 AC_CHECK_LIB(fam, FAMOpen,
1775   [AC_CHECK_HEADERS(fam.h,
1776     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1777      AC_CHECK_LIB(fam, FAMNoExists,
1778                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1779      FAM_LIBS="-lfam"]
1780      fam_support=yes,
1781     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1782   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1783 AC_SUBST(FAM_LIBS)
1784 fi
1785 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1786
1787
1788 dnl *****************************
1789 dnl *** Check for xattr (GIO) ***
1790 dnl *****************************
1791 AC_ARG_ENABLE(xattr,
1792               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1793 msg_xattr=no
1794 XATTR_LIBS=
1795 if test "x$enable_xattr" != "xno"; then
1796
1797 dnl either glibc or libattr can provide xattr support
1798
1799 dnl for both of them, we check for getxattr being in
1800 dnl the library and a valid xattr header.
1801
1802 dnl try glibc
1803  AC_CHECK_LIB(c, getxattr,
1804    [AC_CHECK_HEADERS(sys/xattr.h,
1805      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1806       msg_xattr=yes])
1807    ])
1808
1809   if test "x$msg_xattr" != "xyes"; then
1810 dnl   failure. try libattr
1811    AC_CHECK_LIB(attr, getxattr,
1812       [AC_CHECK_HEADERS(attr/xattr.h,
1813        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1814         XATTR_LIBS="-lattr"
1815         msg_xattr=yes])
1816       ])
1817   fi
1818
1819   if test "x$msg_xattr" = "xyes"; then
1820     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1821     AC_TRY_COMPILE([
1822       #include <stdio.h>
1823       #ifdef HAVE_SYS_TYPES_H
1824       #include <sys/types.h>
1825       #endif
1826       #ifdef HAVE_SYS_XATTR_H
1827       #include <sys/xattr.h>
1828       #elif HAVE_ATTR_XATTR_H
1829       #include <attr/xattr.h>
1830       #endif
1831     ],
1832     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1833     [
1834       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1835       AC_MSG_RESULT([yes])
1836     ],
1837     [AC_MSG_RESULT([no])]
1838     )
1839   fi
1840
1841 fi
1842 AC_SUBST(XATTR_LIBS)
1843
1844 dnl ****************************************
1845 dnl *** platform dependent source checks ***
1846 dnl ****************************************
1847
1848 AC_MSG_CHECKING(for platform-dependent source)
1849 case "$host" in
1850   *-*-cygwin*|*-*-mingw*)
1851     PLATFORMDEP=gwin32.lo
1852     ;;
1853   *)
1854     PLATFORMDEP=
1855     ;;
1856 esac
1857 AC_MSG_RESULT($PLATFORMDEP)
1858 AC_SUBST(PLATFORMDEP)
1859
1860 AC_MSG_CHECKING([whether to compile timeloop])
1861 case "$host" in
1862   *-*-cygwin*|*-*-mingw*|*-*-minix)
1863     enable_timeloop=no
1864     ;;
1865   *)
1866     enable_timeloop=yes
1867     ;;
1868 esac
1869 AC_MSG_RESULT($enable_timeloop)
1870 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1871
1872 AC_MSG_CHECKING([if building for some Win32 platform])
1873 case "$host" in
1874   *-*-mingw*|*-*-cygwin*)
1875     platform_win32=yes
1876     ;;
1877   *)
1878     platform_win32=no
1879     ;;
1880 esac
1881 AC_MSG_RESULT($platform_win32)
1882 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1883
1884 dnl ***********************
1885 dnl *** g_thread checks ***
1886 dnl ***********************
1887
1888 AC_ARG_WITH(threads,
1889            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1890                            [specify a thread implementation to use])],
1891            [if test "x$with_threads" = x; then
1892                 want_threads=yes
1893             else
1894                 want_threads=$with_threads
1895             fi],
1896            [want_threads=yes])
1897
1898 dnl error and warning message
1899 dnl *************************
1900
1901 THREAD_NO_IMPLEMENTATION="You do not have any known thread system on your
1902                 computer."
1903
1904 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1905                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1906                 compilation now, but then your programs might not work.
1907                 Please provide information on how it is done on your system."
1908
1909 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1910                 "
1911
1912 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1913                 provide information on your thread implementation."
1914
1915 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1916                 functions will not be MT-safe during their first call because
1917                 there is no working 'getpwuid_r' on your system."
1918
1919 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1920                 because there is no 'localtime_r' on your system."
1921
1922 POSIX_NO_YIELD="I can not find a yield functions for your platform. A rather
1923                 crude surrogate will be used. If you happen to know a
1924                 yield function for your system, please inform the GLib
1925                 developers."
1926
1927 POSIX_NO_PRIORITIES="I can not find the minimal and maximal priorities for
1928                 threads on your system. Thus threads can only have the default
1929                 priority. If you happen to know these main/max
1930                 priorities, please inform the GLib developers."
1931
1932 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1933                 linking threaded applications. As GLib cannot do that
1934                 automatically, you will get an linkg error everytime you are
1935                 not using the right compiler. In that case you have to relink
1936                 with the right compiler. Ususally just '_r' is appended
1937                 to the compiler name."
1938
1939 dnl determination of thread implementation
1940 dnl ***************************************
1941
1942 have_threads=no
1943 if test "x$want_threads" = xyes || test "x$want_threads" = xposix \
1944                                 || test "x$want_threads" = xdce; then
1945         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1946         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1947         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1948         glib_save_CPPFLAGS="$CPPFLAGS"
1949         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1950         if test "x$have_threads" = xno; then
1951                 AC_TRY_COMPILE([#include <pthread.h>],
1952                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1953                         have_threads=posix)
1954         fi
1955         # Tru64Unix requires -pthread to find pthread.h. See #103020
1956         CPPFLAGS="$CPPFLAGS -pthread"
1957         if test "x$have_threads" = xno; then
1958         AC_TRY_COMPILE([#include <pthread.h>],
1959                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1960                        have_threads=posix)
1961         fi
1962         CPPFLAGS="$glib_save_CPPFLAGS"
1963 fi
1964 if test "x$want_threads" = xyes || test "x$want_threads" = xwin32; then
1965         case $host in
1966                 *-*-mingw*)
1967                 have_threads=win32
1968                 ;;
1969         esac
1970 fi
1971
1972 AC_MSG_CHECKING(for thread implementation)
1973
1974 if test "x$have_threads" = xno; then
1975         AC_MSG_RESULT(none available)
1976         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1977 else
1978         AC_MSG_RESULT($have_threads)
1979 fi
1980
1981
1982 dnl determination of G_THREAD_CFLAGS
1983 dnl ********************************
1984
1985 G_THREAD_LIBS=
1986 G_THREAD_LIBS_EXTRA=
1987 G_THREAD_CFLAGS=
1988
1989 dnl
1990 dnl Test program for basic POSIX threads functionality
1991 dnl
1992 m4_define([glib_thread_test],[
1993 #include <pthread.h>
1994 int check_me = 0;
1995 void* func(void* data) {check_me = 42; return &check_me;}
1996 int main()
1997  { pthread_t t;
1998    void *ret;
1999    pthread_create (&t, $1, func, 0);
2000    pthread_join (t, &ret);
2001    return (check_me != 42 || ret != &check_me);
2002 }])
2003
2004 dnl
2005 dnl Test program for sched_get_priority_min()
2006 dnl
2007 m4_define([glib_sched_priority_test],[
2008 #include <sched.h>
2009 #include <errno.h>
2010 int main() {
2011     errno = 0;
2012     return sched_get_priority_min(SCHED_OTHER)==-1
2013            && errno != 0;
2014 }])
2015
2016 if test x"$have_threads" = xposix; then
2017   # First we test for posix, whether -pthread or -pthreads do the trick as
2018   # both CPPFLAG and LIBS.
2019   # One of them does for most gcc versions and some other platforms/compilers
2020   # too and could be considered as the canonical way to go.
2021   case $host in
2022     *-*-cygwin*|*-*-darwin*)
2023        # skip cygwin and darwin -pthread or -pthreads test
2024        ;;
2025     *-solaris*)
2026       # These compiler/linker flags work with both Sun Studio and gcc
2027       # Sun Studio expands -mt to -D_REENTRANT and -lthread
2028       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
2029       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
2030       G_THREAD_LIBS="-lpthread -lthread"
2031       ;;
2032     *)
2033       for flag in pthread pthreads mt; do
2034         glib_save_CFLAGS="$CFLAGS"
2035         CFLAGS="$CFLAGS -$flag"
2036         AC_TRY_RUN(glib_thread_test(0),
2037                    glib_flag_works=yes,
2038                    glib_flag_works=no,
2039                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
2040                                    glib_flag_works=yes,
2041                                    glib_flag_works=no)])
2042         CFLAGS="$glib_save_CFLAGS"
2043         if test $glib_flag_works = yes ; then
2044            G_THREAD_CFLAGS=-$flag
2045         G_THREAD_LIBS=-$flag
2046         break;
2047         fi
2048       done
2049        ;;
2050   esac
2051 fi
2052
2053 if test x"$G_THREAD_CFLAGS" = x; then
2054
2055   # The canonical -pthread[s] does not work. Try something different.
2056
2057   case $host in
2058         *-aix*)
2059                 if test x"$GCC" = xyes; then
2060                         # GCC 3.0 and above needs -pthread.
2061                         # Should be coverd by the case above.
2062                         # GCC 2.x and below needs -mthreads
2063                         G_THREAD_CFLAGS="-mthreads"
2064                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2065                 else
2066                         # We are probably using the aix compiler. Normaly a
2067                         # program would have to be compiled with the _r variant
2068                         # of the corresponding compiler, but we as GLib cannot
2069                         # do that: but the good news is that for compiling the
2070                         # only difference is the added -D_THREAD_SAFE compile
2071                         # option. This is according to the "C for AIX User's
2072                         # Guide".
2073                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2074                 fi
2075                 ;;
2076         *-dg-dgux*)  # DG/UX
2077                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2078                 ;;
2079         *-sysv5uw7*) # UnixWare 7
2080                 # We are not using gcc with -pthread. Catched above.
2081                 G_THREAD_CFLAGS="-Kthread"
2082                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2083                 ;;
2084         *-mingw*)
2085                 # No flag needed when using MSVCRT.DLL
2086                 G_THREAD_CFLAGS=""
2087                 ;;
2088         *)
2089                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2090                 ;;
2091   esac
2092
2093 fi
2094
2095 # if we are not finding the localtime_r function, then we probably are
2096 # not using the proper multithread flag
2097
2098 glib_save_CPPFLAGS="$CPPFLAGS"
2099 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2100
2101 # First we test, whether localtime_r is declared in time.h
2102 # directly. Then we test whether a macro localtime_r exists, in
2103 # which case localtime_r in the test program is replaced and thus
2104 # if we still find localtime_r in the output, it is not defined as
2105 # a macro.
2106
2107 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2108   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2109                                                            localtime_r(a,b)],
2110                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2111
2112 CPPFLAGS="$glib_save_CPPFLAGS"
2113
2114 AC_MSG_CHECKING(thread related cflags)
2115 AC_MSG_RESULT($G_THREAD_CFLAGS)
2116 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2117
2118 dnl determination of G_THREAD_LIBS
2119 dnl ******************************
2120
2121 case $have_threads in
2122         posix)
2123           glib_save_CPPFLAGS="$CPPFLAGS"
2124           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2125           if test x"$G_THREAD_LIBS" = x; then
2126             case $host in
2127               *-aix*)
2128                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2129                 # probably using the aix compiler.
2130                 AC_MSG_WARN($AIX_COMPILE_INFO)
2131                 ;;
2132               *)
2133                 G_THREAD_LIBS=error
2134                 glib_save_LIBS="$LIBS"
2135                 for thread_lib in "" pthread pthread32 pthreads thread; do
2136                         if test x"$thread_lib" = x; then
2137                                 add_thread_lib=""
2138                                 IN=""
2139                         else
2140                                 add_thread_lib="-l$thread_lib"
2141                                 IN=" in -l$thread_lib"
2142                         fi
2143                         if test x"$have_threads" = xposix; then
2144                                 defattr=0
2145                         else
2146                                 defattr=pthread_attr_default
2147                         fi
2148
2149                         LIBS="$add_thread_lib $glib_save_LIBS"
2150
2151                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2152                         AC_TRY_RUN(glib_thread_test($defattr),
2153                                    glib_result=yes,
2154                                    glib_result=no,
2155                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2156                                                    glib_result=yes,
2157                                                    glib_result=no)])
2158                         AC_MSG_RESULT($glib_result)
2159
2160                         if test "$glib_result" = "yes" ; then
2161                           G_THREAD_LIBS="$add_thread_lib"
2162                           break
2163                         fi
2164                 done
2165                 if test "x$G_THREAD_LIBS" = xerror; then
2166                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2167                 fi
2168                 LIBS="$glib_save_LIBS"
2169                 ;;
2170             esac
2171           fi
2172
2173           glib_save_LIBS="$LIBS"
2174           for thread_lib in "" rt rte; do
2175             if test x"$thread_lib" = x; then
2176               add_thread_lib=""
2177               IN=""
2178             else
2179               add_thread_lib="-l$thread_lib"
2180               IN=" in -l$thread_lib"
2181             fi
2182             LIBS="$add_thread_lib $glib_save_LIBS"
2183
2184             AC_MSG_CHECKING(for sched_get_priority_min$IN)
2185             AC_TRY_RUN(glib_sched_priority_test,
2186                        glib_result=yes,
2187                        glib_result=no,
2188                        [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_sched_priority_test)],
2189                                        glib_result=yes,
2190                                        glib_result=no)])
2191             AC_MSG_RESULT($glib_result)
2192
2193             if test "$glib_result" = "yes" ; then
2194                G_THREAD_LIBS="$G_THREAD_LIBS $add_thread_lib"
2195                posix_priority_min="sched_get_priority_min(SCHED_OTHER)"
2196                posix_priority_max="sched_get_priority_max(SCHED_OTHER)"
2197                break
2198             fi
2199           done
2200           LIBS="$glib_save_LIBS"
2201           g_threads_impl="POSIX"
2202           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2203           CPPFLAGS="$glib_save_CPPFLAGS"
2204           ;;
2205         win32)
2206            g_threads_impl="WIN32"
2207            ;;
2208         *)
2209            g_threads_impl="NONE"
2210            G_THREAD_LIBS=error
2211            ;;
2212 esac
2213
2214 if test "x$G_THREAD_LIBS" = xerror; then
2215         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2216 fi
2217
2218 case $host in
2219   *-*-beos*)
2220     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2221     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2222     ;;
2223   *)
2224     ;;
2225 esac
2226
2227 AC_MSG_CHECKING(thread related libraries)
2228 AC_MSG_RESULT($G_THREAD_LIBS)
2229
2230 dnl check for mt safe function variants and some posix functions
2231 dnl ************************************************************
2232
2233 glib_save_LIBS="$LIBS"
2234 # we are not doing the following for now, as this might require glib
2235 # to always be linked with the thread libs on some platforms.
2236 # LIBS="$LIBS $G_THREAD_LIBS"
2237 AC_CHECK_FUNCS(localtime_r gmtime_r)
2238 if test "$ac_cv_header_pwd_h" = "yes"; then
2239         AC_CACHE_CHECK([for posix getpwuid_r],
2240                 ac_cv_func_posix_getpwuid_r,
2241                 [AC_TRY_RUN([
2242 #include <errno.h>
2243 #include <pwd.h>
2244 int main () {
2245     char buffer[10000];
2246     struct passwd pwd, *pwptr = &pwd;
2247     int error;
2248     errno = 0;
2249     error = getpwuid_r (0, &pwd, buffer,
2250                         sizeof (buffer), &pwptr);
2251    return (error < 0 && errno == ENOSYS)
2252            || error == ENOSYS;
2253 }                               ],
2254                         [ac_cv_func_posix_getpwuid_r=yes],
2255                         [ac_cv_func_posix_getpwuid_r=no])])
2256         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2257         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2258                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2259                         [Have POSIX function getpwuid_r])
2260         else
2261                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2262                         ac_cv_func_nonposix_getpwuid_r,
2263                         [AC_TRY_LINK([#include <pwd.h>],
2264                                 [char buffer[10000];
2265                                 struct passwd pwd;
2266                                 getpwuid_r (0, &pwd, buffer,
2267                                                 sizeof (buffer));],
2268                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2269                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2270                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2271                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2272                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2273                                 [Have non-POSIX function getpwuid_r])
2274                 fi
2275         fi
2276 fi
2277 if test "$ac_cv_header_grp_h" = "yes"; then
2278         AC_CACHE_CHECK([for posix getgrgid_r],
2279                 ac_cv_func_posix_getgrgid_r,
2280                 [AC_TRY_RUN([
2281 #include <errno.h>
2282 #include <grp.h>
2283 int main () {
2284     char buffer[10000];
2285     struct group grp, *grpptr = &grp;
2286     int error;
2287     errno = 0;
2288     error = getgrgid_r (0, &grp, buffer,
2289                         sizeof (buffer), &grpptr);
2290    return (error < 0 && errno == ENOSYS)
2291            || error == ENOSYS;
2292 }                              ],
2293                        [ac_cv_func_posix_getgrgid_r=yes],
2294                        [ac_cv_func_posix_getgrgid_r=no])])
2295         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2296         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2297                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2298                         [Have POSIX function getgrgid_r])
2299         else
2300                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2301                         ac_cv_func_nonposix_getgrgid_r,
2302                         [AC_TRY_LINK([#include <grp.h>],
2303                                 [char buffer[10000];
2304                                 struct group grp;
2305                                 getgrgid_r (0, &grp, buffer,
2306                                 sizeof (buffer));],
2307                         [ac_cv_func_nonposix_getgrgid_r=yes],
2308                         [ac_cv_func_nonposix_getgrgid_r=no])])
2309                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2310                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2311                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2312                                 [Have non-POSIX function getgrgid_r])
2313                 fi
2314         fi
2315 fi
2316 LIBS="$G_THREAD_LIBS $LIBS"
2317 if test x"$have_threads" = xposix; then
2318         glib_save_CPPFLAGS="$CPPFLAGS"
2319         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2320         dnl we might grow sizeof(pthread_t) later on, so use a dummy name here
2321         GLIB_SIZEOF([#include <pthread.h>], pthread_t, system_thread)
2322         # This is not AC_CHECK_FUNC to also work with function
2323         # name mangling in header files.
2324         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2325         AC_TRY_LINK([#include <pthread.h>],
2326                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)],
2327                 [AC_MSG_RESULT(yes)
2328                 AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2329                           [Have function pthread_attr_setstacksize])],
2330                 [AC_MSG_RESULT(no)])
2331         AC_MSG_CHECKING(for minimal/maximal thread priority)
2332         if test x"$posix_priority_min" = x; then
2333                 AC_EGREP_CPP(PX_PRIO_MIN,[#include <pthread.h>
2334                         PX_PRIO_MIN],,[
2335                         posix_priority_min=PX_PRIO_MIN
2336                         posix_priority_max=PX_PRIO_MAX])
2337         fi
2338         if test x"$posix_priority_min" = x; then
2339                 # AIX
2340                 AC_EGREP_CPP(PTHREAD_PRIO_MIN,[#include <pthread.h>
2341                         PTHREAD_PRIO_MIN],,[
2342                         posix_priority_min=PTHREAD_PRIO_MIN
2343                         posix_priority_max=PTHREAD_PRIO_MAX])
2344         fi
2345         if test x"$posix_priority_min" = x; then
2346                 AC_EGREP_CPP(PRI_OTHER_MIN,[#include <pthread.h>
2347                         PRI_OTHER_MIN],,[
2348                         posix_priority_min=PRI_OTHER_MIN
2349                         posix_priority_max=PRI_OTHER_MAX])
2350         fi
2351         if test x"$posix_priority_min" = x; then
2352                 AC_MSG_RESULT(none found)
2353                 AC_MSG_WARN($POSIX_NO_PRIORITIES)
2354                 posix_priority_min=-1
2355                 posix_priority_max=-1
2356         else
2357                 AC_MSG_RESULT($posix_priority_min/$posix_priority_max)
2358                 AC_MSG_CHECKING(for pthread_setschedparam)
2359                 AC_TRY_LINK([#include <pthread.h>],
2360                   [pthread_t t; pthread_setschedparam(t, 0, NULL)],
2361                   [AC_MSG_RESULT(yes)
2362                 AC_DEFINE_UNQUOTED(POSIX_MIN_PRIORITY,$posix_priority_min,[Minimum POSIX RT priority])
2363                    AC_DEFINE_UNQUOTED(POSIX_MAX_PRIORITY,$posix_priority_max,[Maximum POSIX RT priority])],
2364                   [AC_MSG_RESULT(no)
2365                    AC_MSG_WARN($POSIX_NO_PRIORITIES)])
2366         fi
2367         posix_yield_func=none
2368         AC_MSG_CHECKING(for posix yield function)
2369         for yield_func in sched_yield pthread_yield_np pthread_yield \
2370                                                 thr_yield; do
2371                 AC_TRY_LINK([#include <pthread.h>],
2372                         [$yield_func()],
2373                         [posix_yield_func="$yield_func"
2374                         break])
2375         done
2376         if test x"$posix_yield_func" = xnone; then
2377                 AC_MSG_RESULT(none found)
2378                 AC_MSG_WARN($POSIX_NO_YIELD)
2379                 posix_yield_func="g_usleep(1000)"
2380         else
2381                 AC_MSG_RESULT($posix_yield_func)
2382                 posix_yield_func="$posix_yield_func()"
2383         fi
2384         AC_DEFINE_UNQUOTED(POSIX_YIELD_FUNC,$posix_yield_func,[The POSIX RT yield function])
2385         CPPFLAGS="$glib_save_CPPFLAGS"
2386
2387 elif test x"$have_threads" = xwin32; then
2388         # It's a pointer to a private struct
2389         GLIB_SIZEOF(,struct _GThreadData *, system_thread)
2390 fi
2391
2392 LIBS="$glib_save_LIBS"
2393
2394 # now spit out all the warnings.
2395 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2396    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2397         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2398 fi
2399 if test "$ac_cv_func_localtime_r" != "yes"; then
2400         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2401 fi
2402
2403 if test x"$glib_cv_sizeof_system_thread" = x; then
2404    # use a pointer as a fallback.
2405    GLIB_SIZEOF(,void *, system_thread)
2406 fi
2407
2408 #
2409 # Hack to deal with:
2410 #
2411 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2412 #     building shared libraries with linux.
2413 #  b) FreeBSD doesn't do this either.
2414 #
2415 case $host in
2416   *-*-freebsd*|*-*-linux*)
2417     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2418     ;;
2419   *)
2420     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2421     ;;
2422 esac
2423
2424 AC_SUBST(G_THREAD_CFLAGS)
2425 AC_SUBST(G_THREAD_LIBS)
2426 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2427 AC_SUBST(G_THREAD_LIBS_EXTRA)
2428
2429 AC_CHECK_FUNCS(clock_gettime, [], [
2430   AC_CHECK_LIB(rt, clock_gettime, [
2431     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2432     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2433     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2434     GLIB_RT_LIBS="-lrt"
2435   ])
2436 ])
2437 AC_SUBST(GLIB_RT_LIBS)
2438
2439 AC_CACHE_CHECK(for monotonic clocks,
2440     glib_cv_monotonic_clock,AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2441 #include <time.h>
2442 #include <unistd.h>
2443 int main() {
2444 #if !(defined(_POSIX_MONOTONIC_CLOCK) && _POSIX_MONOTONIC_CLOCK >= 0 && defined(CLOCK_MONOTONIC))
2445         #error No monotonic clock
2446 #endif
2447         return 0;
2448 }
2449 ]])],glib_cv_monotonic_clock=yes,glib_cv_monotonic_clock=no))
2450 if test "$glib_cv_monotonic_clock" = "yes"; then
2451   AC_DEFINE(HAVE_MONOTONIC_CLOCK,1,[Have a monotonic clock])
2452 fi
2453
2454
2455 dnl ************************
2456 dnl *** g_atomic_* tests ***
2457 dnl ************************
2458
2459     case $host_cpu in
2460       i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2461         glib_memory_barrier_needed=no
2462         ;;
2463       sparc*|alpha*|powerpc*|ia64)
2464         glib_memory_barrier_needed=yes
2465         ;;
2466       *)
2467         glib_memory_barrier_needed=yes
2468         ;;
2469     esac
2470
2471 glib_cv_gcc_has_builtin_atomic_operations=no
2472 if test x"$GCC" = xyes; then
2473   AC_MSG_CHECKING([whether GCC supports built-in atomic intrinsics])
2474   AC_TRY_LINK([],
2475               [int i;
2476                __sync_synchronize ();
2477                __sync_bool_compare_and_swap (&i, 0, 1);
2478                __sync_fetch_and_add (&i, 1);
2479               ],
2480               [glib_cv_gcc_has_builtin_atomic_operations=yes],
2481               [glib_cv_gcc_has_builtin_atomic_operations=no])
2482
2483   AC_MSG_RESULT($glib_cv_gcc_has_builtin_atomic_operations)
2484 fi
2485 AM_CONDITIONAL(HAVE_GCC_BUILTINS_FOR_ATOMIC_OPERATIONS,
2486                [test $glib_cv_gcc_has_builtin_atomic_operations = yes])
2487
2488 AC_MSG_CHECKING([for Win32 atomic intrinsics])
2489 glib_cv_has_win32_atomic_operations=no
2490 AC_TRY_LINK([],
2491         [int i; _InterlockedExchangeAdd (&i, 0);],
2492         [glib_cv_has_win32_atomic_operations=yes],
2493         [glib_cv_has_win32_atomic_operations=no])
2494 AC_MSG_RESULT($glib_cv_has_win32_atomic_operations)
2495 if test "x$glib_cv_has_win32_atomic_operations" = xyes; then
2496         AC_DEFINE(HAVE_WIN32_BUILTINS_FOR_ATOMIC_OPERATIONS,1,[Have Win32 atomic intrinsics])
2497 fi
2498
2499 dnl ************************
2500 dnl ** Check for futex(2) **
2501 dnl ************************
2502 AC_CACHE_CHECK(for futex(2) system call,
2503     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2504 #include <linux/futex.h>
2505 #include <sys/syscall.h>
2506 #include <unistd.h>
2507 ],[
2508 int
2509 main (void)
2510 {
2511   /* it is not like this actually runs or anything... */
2512   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2513   return 0;
2514 }
2515 ])],glib_cv_futex=yes,glib_cv_futex=no))
2516 if test x"$glib_cv_futex" = xyes; then
2517   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2518 fi
2519
2520 AC_CACHE_CHECK(for eventfd(2) system call,
2521     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2522 #include <sys/eventfd.h>
2523 #include <unistd.h>
2524 ],[
2525 int
2526 main (void)
2527 {
2528   eventfd (0, EFD_CLOEXEC);
2529   return 0;
2530 }
2531 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2532 if test x"$glib_cv_eventfd" = x"yes"; then
2533   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2534 fi
2535 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2536
2537 dnl ****************************************
2538 dnl *** GLib POLL* compatibility defines ***
2539 dnl ****************************************
2540
2541 glib_poll_includes=["
2542 #include <sys/types.h>
2543 #include <sys/poll.h>
2544 "]
2545
2546 if test $ac_cv_header_sys_types_h = yes &&
2547    test $ac_cv_header_sys_poll_h = yes ; then
2548   glib_failed=false
2549   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2550   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2551   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2552   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2553   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2554   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2555   if $glib_failed ; then
2556     AC_MSG_ERROR([Could not determine values for POLL* constants])
2557   fi
2558 else
2559   glib_cv_value_POLLIN=1
2560   glib_cv_value_POLLOUT=4
2561   glib_cv_value_POLLPRI=2
2562   glib_cv_value_POLLERR=8
2563   glib_cv_value_POLLHUP=16
2564   glib_cv_value_POLLNVAL=32
2565 fi
2566
2567 AC_MSG_CHECKING([for broken poll])
2568 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2569         #include <stdlib.h>
2570         #include <fcntl.h>
2571         #include <poll.h>
2572         #ifdef HAVE_SYS_POLL_H
2573         #include <sys/poll.h>
2574         #endif
2575         int main(void) {
2576           struct pollfd fds[1];
2577           int fd;
2578           fd = open("/dev/null", 1);
2579           fds[0].fd = fd;
2580           fds[0].events = POLLIN;
2581           fds[0].revents = 0;
2582           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2583                 exit(1);  /* Does not work for devices -- fail */
2584           }
2585           exit(0);
2586         }]])],
2587   [broken_poll=no],
2588   [broken_poll=yes
2589    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2590   [broken_poll="no (cross compiling)"])
2591 AC_MSG_RESULT($broken_poll)
2592
2593 dnl *********************
2594 dnl *** GRegex checks ***
2595 dnl *********************
2596 PCRE_REQUIRED_VERSION=8.11
2597
2598 # Check if we should compile GRegex
2599 AC_ARG_ENABLE(regex, AC_HELP_STRING([--disable-regex],
2600                                     [disable the compilation of GRegex]),
2601 [case "${enableval}" in
2602   yes) enable_regex=true ;;
2603   no)  enable_regex=false ;;
2604   *) AC_MSG_ERROR(bad value ${enableval} for --enable-regex) ;;
2605 esac],
2606 [enable_regex=true])
2607
2608 AM_CONDITIONAL(ENABLE_REGEX, $enable_regex)
2609
2610 if test x$enable_regex = xtrue; then
2611   AC_DEFINE(ENABLE_REGEX, [], [include GRegex])
2612   # Check if we should use the internal or the system-supplied pcre
2613   AC_ARG_WITH(pcre,
2614              [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2615                              [whether to use system PCRE [default=internal]])])
2616
2617   AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2618
2619   if test "x$with_pcre" = xsystem; then
2620     PKG_CHECK_MODULES(PCRE,
2621                       libpcre >= $PCRE_REQUIRED_VERSION)
2622     AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2623                    glib_save_CFLAGS="$CFLAGS"
2624                    glib_save_LIBS="$LIBS"
2625                    CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2626                    AC_TRY_RUN([#include <pcre.h>
2627                                int main () {
2628                                  int support;
2629                                  pcre_config (PCRE_CONFIG_UTF8, &support);
2630                                  if (!support)
2631                                    return 1;
2632                                  pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2633                                  if (!support)
2634                                    return 1;
2635                                  return 0;
2636                                }],
2637                    glib_cv_pcre_has_unicode=yes,
2638                    glib_cv_pcre_has_unicode=no,
2639                    glib_cv_pcre_has_unicode=yes)
2640                    CFLAGS="$glib_save_CFLAGS"
2641                    LIBS="$glib_save_LIBS"
2642         ])
2643     if test "$glib_cv_pcre_has_unicode" = "no"; then
2644       AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2645     fi
2646     AC_SUBST(PCRE_CFLAGS)
2647     AC_SUBST(PCRE_LIBS)
2648     AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2649     PCRE_REQUIRES=libpcre
2650     AC_SUBST(PCRE_REQUIRES)
2651   else
2652     # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2653     if test x"$GCC" = xyes; then
2654       AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2655       save_CFLAGS="$CFLAGS"
2656       CFLAGS="$CFLAGS -Wno-pointer-sign"
2657       AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2658                             AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2659       CFLAGS="$save_CFLAGS"
2660     fi
2661   fi
2662   AC_SUBST(PCRE_WARN_CFLAGS)
2663 else
2664   AM_CONDITIONAL(USE_SYSTEM_PCRE, false])
2665 fi
2666
2667 dnl **********************
2668 dnl *** Win32 API libs ***
2669 dnl **********************
2670
2671 case $host in
2672   *-*-cygwin*)
2673         G_LIBS_EXTRA="-luser32 -lkernel32"
2674     ;;
2675   *-*-mingw*)
2676         G_LIBS_EXTRA="-lws2_32 -lole32"
2677     ;;
2678   *)
2679         G_LIBS_EXTRA=""
2680     ;;
2681 esac
2682 AC_SUBST(G_LIBS_EXTRA)
2683
2684 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2685 dnl since we need it for g_iconv()
2686
2687 AC_MSG_CHECKING([for EILSEQ])
2688 AC_TRY_COMPILE([
2689 #include <errno.h>
2690 ],
2691 [
2692 int error = EILSEQ;
2693 ], have_eilseq=yes, have_eilseq=no);
2694 AC_MSG_RESULT($have_eilseq)
2695
2696 dnl ******************************************************************
2697 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2698 dnl *** glib-compile-schemas in PATH                               ***
2699 dnl ******************************************************************
2700
2701 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2702
2703 if test $cross_compiling = yes; then
2704   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2705   if test x$GLIB_GENMARSHAL = xno; then
2706     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2707   fi
2708
2709   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2710   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2711     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2712   fi
2713 fi
2714
2715 dnl **************************
2716 dnl *** Checks for gtk-doc ***
2717 dnl **************************
2718
2719 GTK_DOC_CHECK([1.15])
2720
2721 AC_ARG_ENABLE(man,
2722               [AC_HELP_STRING([--enable-man],
2723                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2724               enable_man=no)
2725
2726 if test "${enable_man}" != no; then
2727 dnl
2728 dnl Check for xsltproc
2729 dnl
2730 AC_PATH_PROG([XSLTPROC], [xsltproc])
2731   if test -z "$XSLTPROC"; then
2732     enable_man=no
2733   fi
2734
2735   dnl check for DocBook DTD and stylesheets in the local catalog.
2736   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2737      [DocBook XML DTD V4.1.2],,enable_man=no)
2738   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2739      [DocBook XSL Stylesheets],,enable_man=no)
2740 fi
2741
2742 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2743
2744 dnl
2745 dnl Tracing
2746 dnl
2747
2748 AC_ARG_ENABLE([dtrace],
2749              [AS_HELP_STRING([--enable-dtrace],
2750                               [include tracing support for dtrace])])
2751 have_dtrace=no
2752 AC_MSG_CHECKING([whether to include dtrace tracing support])
2753 if test "x$enable_dtrace" != xno; then
2754   if test x$glib_have_carbon = xyes; then
2755     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2756   else
2757     AC_MSG_RESULT([yes])
2758     AC_CHECK_PROGS(DTRACE, dtrace)
2759     if test -z "$DTRACE"; then
2760       if test "x$enable_dtrace" = xyes; then
2761         AC_MSG_ERROR([dtrace not found])
2762       fi
2763     else
2764       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2765                       [if test "x$enable_dtrace" = xyes; then
2766                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2767                        fi])
2768     fi
2769   fi
2770 else
2771   AC_MSG_RESULT([no])
2772 fi
2773 if test "x$have_dtrace" = xyes; then
2774   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2775 fi
2776 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2777
2778 AC_MSG_CHECKING([whether to include systemtap tracing support])
2779 AC_ARG_ENABLE([systemtap],
2780              [AS_HELP_STRING([--enable-systemtap],
2781                               [include tracing support for systemtap])])
2782 have_systemtap=no
2783 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2784   have_systemtap=yes
2785 fi
2786 AC_MSG_RESULT(${have_systemtap})
2787
2788 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2789
2790 AC_ARG_WITH([tapset-install-dir],
2791             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2792                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2793             [if test "x${withval}" = x; then
2794                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2795              else
2796                ABS_TAPSET_DIR="${withval}"
2797               fi],
2798             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2799 AC_SUBST(ABS_TAPSET_DIR)
2800
2801 dnl ************************************
2802 dnl *** Enable lcov coverage reports ***
2803 dnl ************************************
2804
2805 AC_ARG_ENABLE(gcov,
2806   AS_HELP_STRING([--enable-gcov],
2807                  [enable coverage testing with gcov]),
2808   [use_gcov=$enableval], [use_gcov=no])
2809
2810 if test "x$use_gcov" = "xyes"; then
2811   dnl we need gcc:
2812   if test "$GCC" != "yes"; then
2813     AC_MSG_ERROR([GCC is required for --enable-gcov])
2814   fi
2815
2816   dnl Check if ccache is being used
2817   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2818   case `$SHTOOL path $CC` in
2819     *ccache*[)] gcc_ccache=yes;;
2820     *[)] gcc_ccache=no;;
2821   esac
2822
2823   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2824     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2825   fi
2826
2827   ltp_version_list="1.6 1.7 1.8 1.9"
2828   AC_CHECK_PROG(LTP, lcov, lcov)
2829   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2830
2831   if test "$LTP"; then
2832     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2833       glib_cv_ltp_version=invalid
2834       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2835       for ltp_check_version in $ltp_version_list; do
2836         if test "$ltp_version" = "$ltp_check_version"; then
2837           glib_cv_ltp_version="$ltp_check_version (ok)"
2838         fi
2839       done
2840     ])
2841   else
2842     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2843     AC_MSG_ERROR([$ltp_msg])
2844   fi
2845
2846   case $glib_cv_ltp_version in
2847     ""|invalid[)]
2848       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2849       AC_MSG_ERROR([$ltp_msg])
2850       LTP="exit 0;"
2851       ;;
2852   esac
2853
2854   if test -z "$LTP_GENHTML"; then
2855     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2856   fi
2857
2858   AC_DEFINE(HAVE_GCOV, 1, [Whether you have gcov])
2859
2860   dnl Remove all optimization flags from CFLAGS
2861   changequote({,})
2862   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2863   changequote([,])
2864
2865   dnl Add the special gcc flags
2866   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2867   LDFLAGS="$LDFLAGS -lgcov"
2868 fi
2869
2870 dnl ******************************
2871 dnl *** output the whole stuff ***
2872 dnl ******************************
2873
2874 dnl this section will only be run if config.status is invoked with no
2875 dnl arguments, or with "glib/glibconfig.h" as an argument.
2876 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2877 [
2878         outfile=glib/glibconfig.h-tmp
2879         cat > $outfile <<\_______EOF
2880 /* glibconfig.h
2881  *
2882  * This is a generated file.  Please modify 'configure.ac'
2883  */
2884
2885 #ifndef __G_LIBCONFIG_H__
2886 #define __G_LIBCONFIG_H__
2887
2888 #include <glib/gmacros.h>
2889
2890 _______EOF
2891
2892         if test x$glib_limits_h = xyes; then
2893           echo '#include <limits.h>' >> $outfile
2894         fi
2895         if test x$glib_float_h = xyes; then
2896           echo '#include <float.h>' >> $outfile
2897         fi
2898         if test x$glib_values_h = xyes; then
2899           echo '#include <values.h>' >> $outfile
2900         fi
2901         if test "$glib_header_alloca_h" = "yes"; then
2902           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2903         fi
2904         if test x$glib_sys_poll_h = xyes; then
2905           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2906         fi
2907         if test x$glib_included_printf != xyes; then
2908           echo "
2909 /* Specifies that GLib's g_print*() functions wrap the
2910  * system printf functions.  This is useful to know, for example,
2911  * when using glibc's register_printf_function().
2912  */" >> $outfile
2913           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2914         fi
2915
2916         cat >> $outfile <<_______EOF
2917
2918 G_BEGIN_DECLS
2919
2920 #define G_MINFLOAT      $glib_mf
2921 #define G_MAXFLOAT      $glib_Mf
2922 #define G_MINDOUBLE     $glib_md
2923 #define G_MAXDOUBLE     $glib_Md
2924 #define G_MINSHORT      $glib_ms
2925 #define G_MAXSHORT      $glib_Ms
2926 #define G_MAXUSHORT     $glib_Mus
2927 #define G_MININT        $glib_mi
2928 #define G_MAXINT        $glib_Mi
2929 #define G_MAXUINT       $glib_Mui
2930 #define G_MINLONG       $glib_ml
2931 #define G_MAXLONG       $glib_Ml
2932 #define G_MAXULONG      $glib_Mul
2933
2934 _______EOF
2935
2936
2937         ### this should always be true in a modern C/C++ compiler
2938         cat >>$outfile <<_______EOF
2939 typedef signed char gint8;
2940 typedef unsigned char guint8;
2941 _______EOF
2942
2943
2944         if test -n "$gint16"; then
2945           cat >>$outfile <<_______EOF
2946 typedef signed $gint16 gint16;
2947 typedef unsigned $gint16 guint16;
2948 #define G_GINT16_MODIFIER $gint16_modifier
2949 #define G_GINT16_FORMAT $gint16_format
2950 #define G_GUINT16_FORMAT $guint16_format
2951 _______EOF
2952         fi
2953
2954
2955         if test -n "$gint32"; then
2956           cat >>$outfile <<_______EOF
2957 typedef signed $gint32 gint32;
2958 typedef unsigned $gint32 guint32;
2959 #define G_GINT32_MODIFIER $gint32_modifier
2960 #define G_GINT32_FORMAT $gint32_format
2961 #define G_GUINT32_FORMAT $guint32_format
2962 _______EOF
2963         fi
2964
2965         cat >>$outfile <<_______EOF
2966 #define G_HAVE_GINT64 1          /* deprecated, always true */
2967
2968 ${glib_extension}typedef signed $gint64 gint64;
2969 ${glib_extension}typedef unsigned $gint64 guint64;
2970
2971 #define G_GINT64_CONSTANT(val)  $gint64_constant
2972 #define G_GUINT64_CONSTANT(val) $guint64_constant
2973 _______EOF
2974
2975         if test x$gint64_format != x ; then
2976           cat >>$outfile <<_______EOF
2977 #define G_GINT64_MODIFIER $gint64_modifier
2978 #define G_GINT64_FORMAT $gint64_format
2979 #define G_GUINT64_FORMAT $guint64_format
2980 _______EOF
2981         else
2982           cat >>$outfile <<_______EOF
2983 #undef G_GINT64_MODIFIER
2984 #undef G_GINT64_FORMAT
2985 #undef G_GUINT64_FORMAT
2986 _______EOF
2987         fi
2988
2989         cat >>$outfile <<_______EOF
2990
2991 #define GLIB_SIZEOF_VOID_P $glib_void_p
2992 #define GLIB_SIZEOF_LONG   $glib_long
2993 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2994
2995 _______EOF
2996
2997         cat >>$outfile <<_______EOF
2998 typedef signed $glib_size_type_define gssize;
2999 typedef unsigned $glib_size_type_define gsize;
3000 #define G_GSIZE_MODIFIER $gsize_modifier
3001 #define G_GSSIZE_FORMAT $gssize_format
3002 #define G_GSIZE_FORMAT $gsize_format
3003
3004 #define G_MAXSIZE       G_MAXU$glib_msize_type
3005 #define G_MINSSIZE      G_MIN$glib_msize_type
3006 #define G_MAXSSIZE      G_MAX$glib_msize_type
3007
3008 typedef gint64 goffset;
3009 #define G_MINOFFSET     G_MININT64
3010 #define G_MAXOFFSET     G_MAXINT64
3011
3012 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
3013 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
3014 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
3015
3016 _______EOF
3017
3018         if test -z "$glib_unknown_void_p"; then
3019           cat >>$outfile <<_______EOF
3020
3021 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
3022 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
3023
3024 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
3025 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
3026
3027 typedef signed $glib_intptr_type_define gintptr;
3028 typedef unsigned $glib_intptr_type_define guintptr;
3029
3030 #define G_GINTPTR_MODIFIER      $gintptr_modifier
3031 #define G_GINTPTR_FORMAT        $gintptr_format
3032 #define G_GUINTPTR_FORMAT       $guintptr_format
3033 _______EOF
3034         else
3035           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
3036         fi
3037
3038
3039
3040         cat >>$outfile <<_______EOF
3041 $glib_atexit
3042 $glib_memmove
3043 $glib_defines
3044 $glib_os
3045 $glib_static_compilation
3046
3047 $glib_vacopy
3048
3049 #ifdef  __cplusplus
3050 #define G_HAVE_INLINE   1
3051 #else   /* !__cplusplus */
3052 $glib_inline
3053 #endif  /* !__cplusplus */
3054
3055 #ifdef  __cplusplus
3056 #define G_CAN_INLINE    1
3057 _______EOF
3058
3059         if test x$g_can_inline = xyes ; then
3060                 cat >>$outfile <<_______EOF
3061 #else   /* !__cplusplus */
3062 #define G_CAN_INLINE    1
3063 _______EOF
3064         fi
3065
3066         cat >>$outfile <<_______EOF
3067 #endif
3068
3069 _______EOF
3070
3071         if test x$g_have_iso_c_varargs = xyes ; then
3072                 cat >>$outfile <<_______EOF
3073 #ifndef __cplusplus
3074 # define G_HAVE_ISO_VARARGS 1
3075 #endif
3076 _______EOF
3077         fi
3078         if test x$g_have_iso_cxx_varargs = xyes ; then
3079                 cat >>$outfile <<_______EOF
3080 #ifdef __cplusplus
3081 # define G_HAVE_ISO_VARARGS 1
3082 #endif
3083 _______EOF
3084         fi
3085         if test x$g_have_gnuc_varargs = xyes ; then
3086                 cat >>$outfile <<_______EOF
3087
3088 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
3089  * is passed ISO vararg support is turned off, and there is no work
3090  * around to turn it on, so we unconditionally turn it off.
3091  */
3092 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
3093 #  undef G_HAVE_ISO_VARARGS
3094 #endif
3095
3096 #define G_HAVE_GNUC_VARARGS 1
3097 _______EOF
3098         fi
3099
3100         case x$g_stack_grows in
3101         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
3102         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
3103         esac
3104
3105
3106         echo >>$outfile
3107         if test x$g_have_eilseq = xno; then
3108                 cat >>$outfile <<_______EOF
3109 #ifndef EILSEQ
3110 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
3111  * The correspondence between this and the corresponding definition
3112  * in libiconv is essential.
3113  */
3114 #  define EILSEQ ENOENT
3115 #endif
3116 _______EOF
3117
3118         fi
3119
3120         if test x$g_have_gnuc_visibility = xyes; then
3121                 cat >>$outfile <<_______EOF
3122 #define G_HAVE_GNUC_VISIBILITY 1
3123 _______EOF
3124         fi
3125                 cat >>$outfile <<_______EOF
3126 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
3127 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3128 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
3129 #define G_GNUC_INTERNAL __hidden
3130 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
3131 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
3132 #else
3133 #define G_GNUC_INTERNAL
3134 #endif
3135 _______EOF
3136
3137         echo >>$outfile
3138         cat >>$outfile <<_______EOF
3139 #define G_THREADS_ENABLED
3140 #define G_THREADS_IMPL_$g_threads_impl_def
3141 _______EOF
3142
3143         cat >>$outfile <<_______EOF
3144 /* This represents a system thread as used by the implementation. An
3145  * alien implementaion, as loaded by g_thread_init can only count on
3146  * "sizeof (gpointer)" bytes to store their info. We however need more
3147  * for some of our native implementations. */
3148 typedef union _GSystemThread GSystemThread;
3149 union _GSystemThread
3150 {
3151   char   data[[$g_system_thread_sizeof]];
3152   double dummy_double;
3153   void  *dummy_pointer;
3154   long   dummy_long;
3155 };
3156 _______EOF
3157         if test x"$g_memory_barrier_needed" != xno; then
3158           echo >>$outfile
3159           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
3160         fi
3161         if test x"$g_gcc_atomic_ops" != xno; then
3162           echo >>$outfile
3163           echo "#define G_ATOMIC_OP_USE_GCC_BUILTINS 1" >>$outfile
3164         fi
3165         echo >>$outfile
3166         g_bit_sizes="16 32 64"
3167         for bits in $g_bit_sizes; do
3168           cat >>$outfile <<_______EOF
3169 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
3170 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
3171 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3172 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3173 _______EOF
3174         done
3175
3176         cat >>$outfile <<_______EOF
3177 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3178 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3179 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3180 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3181 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3182 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3183 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3184 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3185 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3186 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3187 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3188 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3189 #define G_BYTE_ORDER $g_byte_order
3190
3191 #define GLIB_SYSDEF_POLLIN =$g_pollin
3192 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3193 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3194 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3195 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3196 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3197
3198 #define G_MODULE_SUFFIX "$g_module_suffix"
3199
3200 /* A GPid is an abstraction for a process "handle". It is *not* an
3201  * abstraction for a process identifier in general. GPid is used in
3202  * GLib only for descendant processes spawned with the g_spawn*
3203  * functions. On POSIX there is no "process handle" concept as such,
3204  * but on Windows a GPid is a handle to a process, a kind of pointer,
3205  * not a process identifier.
3206  */
3207 typedef $g_pid_type GPid;
3208
3209 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3210 #define GLIB_SYSDEF_AF_INET $g_af_inet
3211 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3212
3213 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3214 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3215 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3216
3217 G_END_DECLS
3218
3219 #endif /* GLIBCONFIG_H */
3220 _______EOF
3221
3222
3223         if cmp -s $outfile glib/glibconfig.h; then
3224           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3225           rm -f $outfile
3226         else
3227           mv $outfile glib/glibconfig.h
3228         fi
3229 ],[
3230
3231 # Note that if two cases are the same, case goes with the first one.
3232 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3233 # on variable expansion in case labels.  Look at the generated config.status
3234 # for a hint.
3235
3236 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3237   glib_header_alloca_h="$ac_cv_working_alloca_h"
3238 else
3239   glib_header_alloca_h="$ac_cv_header_alloca_h"
3240 fi
3241
3242 case xyes in
3243 x$ac_cv_header_float_h)
3244   glib_float_h=yes
3245   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3246   glib_md=DBL_MIN glib_Md=DBL_MAX
3247   ;;
3248 x$ac_cv_header_values_h)
3249   glib_values_h=yes
3250   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3251   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3252   ;;
3253 esac
3254
3255 case xyes in
3256 x$ac_cv_header_limits_h)
3257   glib_limits_h=yes
3258   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3259   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3260   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3261   ;;
3262 x$ac_cv_header_values_h)
3263   glib_values_h=yes
3264   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3265   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3266   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3267   ;;
3268 esac
3269
3270 if test x$ac_cv_header_sys_poll_h = xyes ; then
3271   glib_sys_poll_h=yes
3272 fi
3273
3274 if test x$enable_included_printf = xyes ; then
3275   glib_included_printf=yes
3276 fi
3277
3278 case 2 in
3279 $ac_cv_sizeof_short)
3280   gint16=short
3281   gint16_modifier='"h"'
3282   gint16_format='"hi"'
3283   guint16_format='"hu"'
3284   ;;
3285 $ac_cv_sizeof_int)
3286   gint16=int
3287   gint16_modifier='""'
3288   gint16_format='"i"'
3289   guint16_format='"u"'
3290   ;;
3291 esac
3292 case 4 in
3293 $ac_cv_sizeof_short)
3294   gint32=short
3295   gint32_modifier='"h"'
3296   gint32_format='"hi"'
3297   guint32_format='"hu"'
3298   ;;
3299 $ac_cv_sizeof_int)
3300   gint32=int
3301   gint32_modifier='""'
3302   gint32_format='"i"'
3303   guint32_format='"u"'
3304   ;;
3305 $ac_cv_sizeof_long)
3306   gint32=long
3307   gint32_modifier='"l"'
3308   gint32_format='"li"'
3309   guint32_format='"lu"'
3310   ;;
3311 esac
3312 case 8 in
3313 $ac_cv_sizeof_int)
3314   gint64=int
3315   gint64_modifier='""'
3316   gint64_format='"i"'
3317   guint64_format='"u"'
3318   glib_extension=
3319   gint64_constant='(val)'
3320   guint64_constant='(val)'
3321   ;;
3322 $ac_cv_sizeof_long)
3323   gint64=long
3324   gint64_modifier='"l"'
3325   gint64_format='"li"'
3326   guint64_format='"lu"'
3327   glib_extension=
3328   gint64_constant='(val##L)'
3329   guint64_constant='(val##UL)'
3330   ;;
3331 $ac_cv_sizeof_long_long)
3332   gint64='long long'
3333   if test -n "$glib_cv_long_long_format"; then
3334     gint64_modifier='"'$glib_cv_long_long_format'"'
3335     gint64_format='"'$glib_cv_long_long_format'i"'
3336     guint64_format='"'$glib_cv_long_long_format'u"'
3337   fi
3338   glib_extension='G_GNUC_EXTENSION '
3339   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3340   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3341   ;;
3342 $ac_cv_sizeof___int64)
3343   gint64='__int64'
3344   if test -n "$glib_cv_long_long_format"; then
3345     gint64_modifier='"'$glib_cv_long_long_format'"'
3346     gint64_format='"'$glib_cv_long_long_format'i"'
3347     guint64_format='"'$glib_cv_long_long_format'u"'
3348   fi
3349   glib_extension=
3350   gint64_constant='(val##i64)'
3351   guint64_constant='(val##ui64)'
3352   ;;
3353 esac
3354 glib_size_t=$ac_cv_sizeof_size_t
3355 glib_size_type_define="$glib_size_type"
3356 glib_void_p=$ac_cv_sizeof_void_p
3357 glib_long=$ac_cv_sizeof_long
3358
3359 case "$glib_size_type" in
3360 short)
3361   gsize_modifier='"h"'
3362   gsize_format='"hu"'
3363   gssize_format='"hi"'
3364   glib_msize_type='SHRT'
3365   ;;
3366 int)
3367   gsize_modifier='""'
3368   gsize_format='"u"'
3369   gssize_format='"i"'
3370   glib_msize_type='INT'
3371   ;;
3372 long)
3373   gsize_modifier='"l"'
3374   gsize_format='"lu"'
3375   gssize_format='"li"'
3376   glib_msize_type='LONG'
3377   ;;
3378 "long long"|__int64)
3379   gsize_modifier='"I64"'
3380   gsize_format='"I64u"'
3381   gssize_format='"I64i"'
3382   glib_msize_type='INT64'
3383   ;;
3384 esac
3385
3386 gintbits=`expr $ac_cv_sizeof_int \* 8`
3387 glongbits=`expr $ac_cv_sizeof_long \* 8`
3388 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3389
3390 case $ac_cv_sizeof_void_p in
3391 $ac_cv_sizeof_int)
3392   glib_intptr_type_define=int
3393   gintptr_modifier='""'
3394   gintptr_format='"i"'
3395   guintptr_format='"u"'
3396   glib_gpi_cast=''
3397   glib_gpui_cast=''
3398   ;;
3399 $ac_cv_sizeof_long)
3400   glib_intptr_type_define=long
3401   gintptr_modifier='"l"'
3402   gintptr_format='"li"'
3403   guintptr_format='"lu"'
3404   glib_gpi_cast='(glong)'
3405   glib_gpui_cast='(gulong)'
3406   ;;
3407 $ac_cv_sizeof_long_long)
3408   glib_intptr_type_define='long long'
3409   gintptr_modifier='"I64"'
3410   gintptr_format='"I64i"'
3411   guintptr_format='"I64u"'
3412   glib_gpi_cast='(gint64)'
3413   glib_gpui_cast='(guint64)'
3414   ;;
3415 $ac_cv_sizeof___int64)
3416   glib_intptr_type_define=__int64
3417   gintptr_modifier='"I64"'
3418   gintptr_format='"I64i"'
3419   guintptr_format='"I64u"'
3420   glib_gpi_cast='(gint64)'
3421   glib_gpui_cast='(guint64)'
3422   ;;
3423 *)
3424   glib_unknown_void_p=yes
3425   ;;
3426 esac
3427
3428
3429 case xyes in
3430 x$ac_cv_func_atexit)
3431   glib_atexit="
3432 #ifdef NeXT /* @#%@! NeXTStep */
3433 # define g_ATEXIT(proc) (!atexit (proc))
3434 #else
3435 # define g_ATEXIT(proc) (atexit (proc))
3436 #endif"
3437   ;;
3438 x$ac_cv_func_on_exit)
3439   glib_atexit="
3440 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3441   ;;
3442 esac
3443
3444 case xyes in
3445 x$ac_cv_func_memmove)
3446   glib_memmove='
3447 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3448   ;;
3449 x$glib_cv_working_bcopy)
3450   glib_memmove="
3451 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3452 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3453   ;;
3454 *)
3455   glib_memmove="
3456 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3457  * so we have to roll our own copy routine. */
3458 void g_memmove (void* dest, const void * src, unsigned long len);"
3459   ;;
3460 esac
3461
3462 glib_defines="
3463 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3464 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3465 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3466 "
3467
3468 case xyes in
3469 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3470 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3471 *)                      glib_vacopy=''
3472 esac
3473
3474 if test x$glib_cv_va_val_copy = xno; then
3475   glib_vacopy="\$glib_vacopy
3476 #define G_VA_COPY_AS_ARRAY 1"
3477 fi
3478
3479 if test x$glib_cv_hasinline = xyes; then
3480     glib_inline='#define G_HAVE_INLINE 1'
3481 fi
3482 if test x$glib_cv_has__inline = xyes; then
3483     glib_inline="\$glib_inline
3484 #define G_HAVE___INLINE 1"
3485 fi
3486 if test x$glib_cv_has__inline__ = xyes; then
3487     glib_inline="\$glib_inline
3488 #define G_HAVE___INLINE__ 1"
3489 fi
3490
3491 g_have_gnuc_varargs=$g_have_gnuc_varargs
3492 g_have_iso_c_varargs=$g_have_iso_c_varargs
3493 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3494
3495 g_can_inline=$g_can_inline
3496 g_have_gnuc_visibility=$g_have_gnuc_visibility
3497 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3498
3499 if test x$ac_cv_c_bigendian = xyes; then
3500   g_byte_order=G_BIG_ENDIAN
3501   g_bs_native=BE
3502   g_bs_alien=LE
3503 else
3504   g_byte_order=G_LITTLE_ENDIAN
3505   g_bs_native=LE
3506   g_bs_alien=BE
3507 fi
3508
3509 g_pollin=$glib_cv_value_POLLIN
3510 g_pollout=$glib_cv_value_POLLOUT
3511 g_pollpri=$glib_cv_value_POLLPRI
3512 g_pollhup=$glib_cv_value_POLLHUP
3513 g_pollerr=$glib_cv_value_POLLERR
3514 g_pollnval=$glib_cv_value_POLLNVAL
3515
3516 g_af_unix=$glib_cv_value_AF_UNIX
3517 g_af_inet=$glib_cv_value_AF_INET
3518 g_af_inet6=$glib_cv_value_AF_INET6
3519
3520 g_msg_peek=$glib_cv_value_MSG_PEEK
3521 g_msg_oob=$glib_cv_value_MSG_OOB
3522 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3523
3524 g_stack_grows=$glib_cv_stack_grows
3525
3526 g_have_eilseq=$have_eilseq
3527
3528 g_threads_impl_def=$g_threads_impl
3529
3530 g_system_thread_sizeof="$glib_cv_sizeof_system_thread"
3531
3532 g_memory_barrier_needed="$glib_memory_barrier_needed"
3533 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3534
3535 g_module_suffix="$glib_gmodule_suffix"
3536
3537 g_pid_type="$glib_pid_type"
3538 case $host in
3539   *-*-beos*)
3540     glib_os="#define G_OS_BEOS"
3541     ;;
3542   *-*-cygwin*)
3543     glib_os="#define G_OS_UNIX
3544 #define G_PLATFORM_WIN32
3545 #define G_WITH_CYGWIN"
3546     ;;
3547   *-*-mingw*)
3548     glib_os="#define G_OS_WIN32
3549 #define G_PLATFORM_WIN32"
3550     ;;
3551   *)
3552     glib_os="#define G_OS_UNIX"
3553     ;;
3554 esac
3555 glib_static_compilation=""
3556 if test x$glib_win32_static_compilation = xyes; then
3557   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3558 #define GOBJECT_STATIC_COMPILATION 1"
3559 fi
3560 ])
3561
3562 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3563 #
3564 # 1.2.14 required for dbus_message_set_serial
3565 PKG_CHECK_MODULES(DBUS1,
3566                   dbus-1 >= 1.2.14,
3567                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3568                   have_dbus1=no)
3569 AC_SUBST(DBUS1_CFLAGS)
3570 AC_SUBST(DBUS1_LIBS)
3571 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3572
3573 dnl
3574 dnl Check for -Bsymbolic-functions linker flag used to avoid
3575 dnl intra-library PLT jumps, if available.
3576 dnl
3577
3578 AC_ARG_ENABLE(Bsymbolic,
3579               [AC_HELP_STRING([--disable-Bsymbolic],
3580                               [avoid linking with -Bsymbolic])],,
3581               [SAVED_LDFLAGS="${LDFLAGS}"
3582                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3583                LDFLAGS=-Wl,-Bsymbolic-functions
3584                AC_TRY_LINK([], [int main (void) { return 0; }],
3585                            AC_MSG_RESULT(yes)
3586                            enable_Bsymbolic=yes,
3587                            AC_MSG_RESULT(no)
3588                            enable_Bsymbolic=no)
3589                LDFLAGS="${SAVED_LDFLAGS}"])
3590
3591 if test "x${enable_Bsymbolic}" == "xyes"; then
3592   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3593 fi
3594
3595 AC_SUBST(GLIB_LINK_FLAGS)
3596
3597 #
3598 # Define variables corresponding to the correct include paths to use for
3599 # in-tree building.
3600 #
3601
3602 # for config.h:
3603 config_h_INCLUDES='-I$(top_builddir)'
3604 AC_SUBST(config_h_INCLUDES)
3605
3606 # glib:
3607 #   config.h
3608 #   $(top_builddir)/glib: for glibconfig.h
3609 #   $(top_srcdir)/glib:   for glib.h
3610 #   $(top_srcdir):        for everything
3611 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3612 AC_SUBST(glib_INCLUDES)
3613
3614 # gthread:
3615 #   same as glib
3616 gthread_INCLUDES='$(glib_INCLUDES)'
3617 AC_SUBST(gthread_INCLUDES)
3618
3619 # gobject:
3620 #   same as gthread
3621 gobject_INCLUDES='$(gthread_INCLUDES)'
3622 AC_SUBST(gobject_INCLUDES)
3623
3624 # gmodule:
3625 #   glib includes
3626 #   $(top_srcdir)/gmodule: for gmodule.h
3627 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3628 AC_SUBST(gmodule_INCLUDES)
3629
3630 # gio:
3631 #   same as gmodule
3632 gio_INCLUDES='$(gmodule_INCLUDES)'
3633 AC_SUBST(gio_INCLUDES)
3634
3635
3636 AC_CONFIG_FILES([
3637 glib-2.0.pc
3638 glib-2.0-uninstalled.pc
3639 gmodule-2.0.pc
3640 gmodule-export-2.0.pc
3641 gmodule-no-export-2.0.pc
3642 gmodule-2.0-uninstalled.pc
3643 gmodule-no-export-2.0-uninstalled.pc
3644 gthread-2.0.pc
3645 gthread-2.0-uninstalled.pc
3646 gobject-2.0.pc
3647 gobject-2.0-uninstalled.pc
3648 gio-2.0.pc
3649 gio-unix-2.0.pc
3650 gio-windows-2.0.pc
3651 gio-2.0-uninstalled.pc
3652 gio-unix-2.0-uninstalled.pc
3653 glib-zip
3654 glib-gettextize
3655 Makefile
3656 build/Makefile
3657 build/win32/Makefile
3658 build/win32/dirent/Makefile
3659 build/win32/vs9/Makefile
3660 build/win32/vs10/Makefile
3661 glib/Makefile
3662 glib/glib.stp
3663 glib/libcharset/Makefile
3664 glib/gnulib/Makefile
3665 glib/pcre/Makefile
3666 glib/update-pcre/Makefile
3667 glib/tests/Makefile
3668 gmodule/Makefile
3669 gmodule/gmoduleconf.h
3670 gobject/Makefile
3671 gobject/gobject.stp
3672 gobject/glib-mkenums
3673 gobject/tests/Makefile
3674 gthread/Makefile
3675 gthread/tests/Makefile
3676 gio/Makefile
3677 gio/gdbus-2.0/codegen/Makefile
3678 gio/gdbus-2.0/codegen/config.py
3679 gio/xdgmime/Makefile
3680 gio/inotify/Makefile
3681 gio/fen/Makefile
3682 gio/fam/Makefile
3683 gio/win32/Makefile
3684 gio/tests/Makefile
3685 gio/tests/gdbus-object-manager-example/Makefile
3686 po/Makefile.in
3687 docs/Makefile
3688 docs/reference/Makefile
3689 docs/reference/glib/Makefile
3690 docs/reference/glib/version.xml
3691 docs/reference/gobject/Makefile
3692 docs/reference/gobject/version.xml
3693 docs/reference/gio/Makefile
3694 docs/reference/gio/gdbus-object-manager-example/Makefile
3695 docs/reference/gio/version.xml
3696 tests/Makefile
3697 tests/gobject/Makefile
3698 tests/refcount/Makefile
3699 m4macros/Makefile
3700 ])
3701
3702 AC_CONFIG_COMMANDS([chmod-scripts],
3703 [chmod 0755 glib-zip
3704 chmod 0755 glib-gettextize
3705 chmod 0755 gobject/glib-mkenums])
3706
3707 # we want to invoke this macro solely so that the config.status script
3708 # and automake generated makefiles know about these generated files.
3709 # They are only needed to distcheck the package
3710 if false; then
3711   AC_CONFIG_FILES([
3712     INSTALL
3713     README
3714     config.h.win32
3715     glib/glibconfig.h.win32
3716     glib/makefile.msc
3717     glib/glib.rc
3718     gmodule/makefile.msc
3719     gmodule/gmodule.rc
3720     gobject/makefile.msc
3721     gobject/gobject.rc
3722     gthread/makefile.msc
3723     gthread/gthread.rc
3724     gio/gio.rc
3725     tests/makefile.msc
3726   ])
3727 fi
3728
3729 AC_OUTPUT