configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 AC_INIT()
   4 AC_PREREQ(2.52)
   5
   6 AC_MSG_NOTICE([Configuring ccache])
   7
   8 AC_CONFIG_HEADER(config.h)
   9
  10 AC_CANONICAL_HOST
  11
  12 case $host in
  13     *mingw32* | *cygwin* | *wince* | *mingwce*)
  14         AC_DEFINE(_WIN32_WINNT,0x0600, Windows Vista or newer is required)
  15         ;;
  16 esac
  17
  18 AC_SUBST(extra_cppflags)
  19 AC_SUBST(extra_ldflags)
  20 AC_SUBST(extra_libs)
  21 AC_SUBST(include_dev_mk)
  22 AC_SUBST(test_suites)
  23
  24 dnl Checks for programs.
  25 AC_PROG_CC
  26 AC_PROG_CPP
  27 AC_PROG_INSTALL
  28 AC_PROG_RANLIB
  29 AC_CHECK_TOOL(AR, ar)
  30 if test -z "$AR"; then
  31     AC_MSG_ERROR(cannot find ar)
  32 fi
  33
  34 m4_include(m4/feature_macros.m4)
  35
  36 # If GCC, turn on warnings.
  37 if test "x$GCC" = "xyes"; then
  38     CFLAGS="$CFLAGS -Wall -W"
  39 else
  40     CFLAGS="$CFLAGS -O"
  41 fi
  42
  43 AC_HEADER_DIRENT
  44 AC_HEADER_TIME
  45 AC_HEADER_STDBOOL
  46 AC_HEADER_SYS_WAIT
  47
  48 AC_CHECK_TYPES(long long)
  49
  50 AC_CHECK_HEADERS(ctype.h pwd.h stdlib.h string.h strings.h sys/time.h sys/mman.h)
  51 AC_CHECK_HEADERS(termios.h)
  52
  53 AC_CHECK_FUNCS(gethostname)
  54 AC_CHECK_FUNCS(getopt_long)
  55 AC_CHECK_FUNCS(getpwuid)
  56 AC_CHECK_FUNCS(gettimeofday)
  57 AC_CHECK_FUNCS(mkstemp)
  58 AC_CHECK_FUNCS(realpath)
  59 AC_CHECK_FUNCS(strndup)
  60 AC_CHECK_FUNCS(strtok_r)
  61 AC_CHECK_FUNCS(unsetenv)
  62 AC_CHECK_FUNCS(utimes)
  63
  64 AC_CACHE_CHECK([for compar_fn_t in stdlib.h],ccache_cv_COMPAR_FN_T, [
  65     AC_TRY_COMPILE(
  66         [#include <stdlib.h>],
  67         [void test_fn(void) { qsort(NULL, 0, 0, (__compar_fn_t)NULL); }],
  68         ccache_cv_COMPAR_FN_T=yes,
  69         ccache_cv_COMPAR_FN_T=no)])
  70 if test x"$ccache_cv_COMPAR_FN_T" = x"yes"; then
  71    AC_DEFINE(HAVE_COMPAR_FN_T, 1,
  72              Define to 1 if you have the `__compar_fn_t' typedef.)
  73 fi
  74
  75 dnl Replacements of snprintf and friends.
  76 m4_include(m4/snprintf.m4)
  77 HW_FUNC_VSNPRINTF
  78 HW_FUNC_SNPRINTF
  79 HW_FUNC_VASPRINTF
  80 HW_FUNC_ASPRINTF
  81
  82 dnl Check if -lm is needed.
  83 AC_SEARCH_LIBS(cos, m)
  84
  85
  86 dnl Check for zlib
  87 AC_ARG_WITH(bundled-zlib,
  88   [AS_HELP_STRING([--with-bundled-zlib],
  89     [use bundled zlib instead of the system's default zlib])])
  90 if test x${with_bundled_zlib} = x; then
  91     AC_CACHE_CHECK(
  92         [for zlib >= 1.2.3],
  93         [ccache_cv_zlib_1_2_3],
  94         AC_TRY_COMPILE(
  95             [#include <zlib.h>],
  96             [
  97             #if (ZLIB_VERNUM >= 0x1230)
  98             #else
  99             #error "ZLIB_VERNUM < 0x1230"
 100             #endif
 101             ],
 102             [ccache_cv_zlib_1_2_3=yes],
 103             [ccache_cv_zlib_1_2_3=no]))
 104     AC_CHECK_LIB(z, gzdopen, true)
 105     if test $ccache_cv_zlib_1_2_3 = yes && test $ac_cv_lib_z_gzdopen = yes; then
 106         use_bundled_zlib=no
 107     else
 108         AC_MSG_WARN(using bundled zlib)
 109         use_bundled_zlib=yes
 110     fi
 111 else
 112     AC_MSG_NOTICE(using bundled zlib as requested)
 113     use_bundled_zlib=yes
 114 fi
 115
 116 if test x${use_bundled_zlib} = xyes; then
 117     extra_cppflags="-I\$(srcdir)/zlib"
 118     extra_ldflags="-Lzlib"
 119     extra_libs="zlib/libz.a"
 120     mkdir -p zlib
 121 else
 122     extra_ldflags="-lz"
 123 fi
 124
 125 AC_C_BIGENDIAN
 126
 127 AC_C_INLINE
 128
 129 dnl Check for "extern inline".
 130 AC_CACHE_CHECK(
 131     for extern inline,
 132     ac_cv_c_extern_inline,
 133     [
 134     ac_cv_c_extern_inline=no
 135     AC_TRY_COMPILE(
 136         [
 137         extern $ac_cv_c_inline double foo(double x);
 138         extern $ac_cv_c_inline double foo(double x) { return x+1.0; };
 139         double foo (double x) { return x + 1.0; };
 140         ],
 141         [foo(1.0)],
 142         [ac_cv_c_extern_inline="yes"])])
 143 if test "$ac_cv_c_extern_inline" != no ; then
 144     AC_DEFINE(HAVE_EXTERN_INLINE, 1,
 145               Define to 1 if your compiler supports extern inline)
 146 fi
 147
 148 dnl Enable developer mode if dev.mk.in exists.
 149 if test ! -f $srcdir/dev_mode_disabled && test "$RUN_FROM_BUILD_FARM" != yes; then
 150     AC_MSG_NOTICE(Developer mode enabled)
 151     AC_CONFIG_FILES([dev.mk])
 152     include_dev_mk='include dev.mk'
 153     version=`(git --git-dir=$srcdir/.git describe --dirty 2>/dev/null || echo vunknown) | sed -e 's/v//' -e 's/-/+/' -e 's/-/_/g'`
 154     echo "const char CCACHE_VERSION@<:@@:>@ = \"$version\";" >version.c
 155 else
 156     AC_MSG_NOTICE(Developer mode disabled)
 157 fi
 158
 159 if test ! -f $srcdir/version.c; then
 160     AC_MSG_WARN(unable to determine ccache version)
 161     echo "const char CCACHE_VERSION@<:@@:>@ = \"unknown\";" >version.c
 162 fi
 163
 164 dnl Find test suite files.
 165 test_suites=`ls $srcdir/test/test_*.c | egrep -v 'BASE|BACKUP|LOCAL|REMOTE' | xargs echo`
 166
 167 AC_CONFIG_FILES([Makefile])
 168 AC_OUTPUT
 169
 170 cat <<EOF >config.h.tmp
 171 #ifndef CCACHE_CONFIG_H
 172 #define CCACHE_CONFIG_H
 173 EOF
 174 cat config.h >>config.h.tmp
 175 echo '#endif' >>config.h.tmp
 176 mv config.h.tmp config.h
 177
 178 mkdir -p .deps test
 179
 180
 181 AC_MSG_NOTICE(now build ccache by running make)