configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Configure input file for elfutils.                     -*-autoconf-*-
   3 dnl
   4 dnl Copyright (C) 1996-2015 Red Hat, Inc.
   5 dnl
   6 dnl This file is part of elfutils.
   7 dnl
   8 dnl  This file is free software; you can redistribute it and/or modify
   9 dnl  it under the terms of the GNU General Public License as published by
  10 dnl  the Free Software Foundation; either version 3 of the License, or
  11 dnl  (at your option) any later version.
  12 dnl
  13 dnl  elfutils is distributed in the hope that it will be useful, but
  14 dnl  WITHOUT ANY WARRANTY; without even the implied warranty of
  15 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 dnl  GNU General Public License for more details.
  17 dnl
  18 dnl  You should have received a copy of the GNU General Public License
  19 dnl  along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20 AC_INIT([elfutils],[0.161],[https://bugzilla.redhat.com/],[elfutils])
  21
  22 AC_CONFIG_AUX_DIR([config])
  23 AC_CONFIG_FILES([config/Makefile])
  24
  25 AC_COPYRIGHT([Copyright (C) 1996-2015 Red Hat, Inc.])
  26 AC_PREREQ(2.63)                 dnl Minimum Autoconf version required.
  27
  28 dnl We use GNU make extensions; automake 1.10 defaults to -Wportability.
  29 AM_INIT_AUTOMAKE([gnits 1.11 -Wno-portability dist-bzip2 no-dist-gzip parallel-tests])
  30 AM_MAINTAINER_MODE
  31
  32 dnl Unique ID for this build.
  33 MODVERSION="Build on $(hostname) $(date +%FT%R:%S%z)"
  34 AC_SUBST([MODVERSION])
  35 AC_DEFINE_UNQUOTED(MODVERSION, "$MODVERSION")
  36 AH_TEMPLATE([MODVERSION], [Identifier for modules in the build.])
  37
  38 AC_CONFIG_SRCDIR([libelf/libelf.h])
  39 AC_CONFIG_FILES([Makefile])
  40 AC_CONFIG_HEADERS([config.h])
  41
  42 AC_CONFIG_MACRO_DIR([m4])
  43 AC_CONFIG_FILES([m4/Makefile])
  44
  45 dnl The RPM spec file.  We substitute a few values in the file.
  46 AC_CONFIG_FILES([elfutils.spec:config/elfutils.spec.in])
  47
  48
  49 AC_CANONICAL_HOST
  50
  51 AC_ARG_ENABLE(deterministic-archives,
  52 [AS_HELP_STRING([--enable-deterministic-archives],
  53                 [ar and ranlib default to -D behavior])], [
  54 if test "${enableval}" = no; then
  55   default_ar_deterministic=false
  56 else
  57   default_ar_deterministic=true
  58 fi], [default_ar_deterministic=false])
  59 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  60                    [Should ar and ranlib use -D behavior by default?])
  61
  62 AC_ARG_ENABLE([thread-safety],
  63 AS_HELP_STRING([--enable-thread-safety],
  64                [enable thread safety of libraries EXPERIMENTAL]),
  65                use_locks=$enableval, use_locks=no)
  66 AM_CONDITIONAL(USE_LOCKS, test "$use_locks" = yes)
  67 AS_IF([test "$use_locks" = yes], [AC_DEFINE(USE_LOCKS)])
  68 AS_IF([test "$use_locks" = yes],
  69       [AC_MSG_WARN([thread-safety is EXPERIMENTAL tests might fail.])])
  70
  71 AH_TEMPLATE([USE_LOCKS], [Defined if libraries should be thread-safe.])
  72
  73 AC_PROG_CC
  74 AC_PROG_RANLIB
  75 AC_PROG_YACC
  76 AM_PROG_LEX
  77 # Only available since automake 1.12
  78 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  79 AC_CHECK_TOOL([READELF], [readelf])
  80 AC_CHECK_TOOL([NM], [nm])
  81
  82 # We use -std=gnu99 but have explicit checks for some language constructs
  83 # and GNU extensions since some compilers claim GNU99 support, but don't
  84 # really support all language extensions. In particular we need
  85 # Mixed Declarations and Code
  86 # https://gcc.gnu.org/onlinedocs/gcc/Mixed-Declarations.html
  87 # Nested Functions
  88 # https://gcc.gnu.org/onlinedocs/gcc/Nested-Functions.html
  89 # Arrays of Variable Length
  90 # https://gcc.gnu.org/onlinedocs/gcc/Variable-Length.html
  91 AC_CACHE_CHECK([for gcc with GNU99 support], ac_cv_c99, [dnl
  92 old_CFLAGS="$CFLAGS"
  93 CFLAGS="$CFLAGS -std=gnu99"
  94 AC_COMPILE_IFELSE([AC_LANG_SOURCE([dnl
  95 int foo (int a)
  96 {
  97   for (int i = 0; i < a; ++i) if (i % 4) break; int s = a; return s;
  98 }
  99
 100 double bar (double a, double b)
 101 {
 102   double square (double z) { return z * z; }
 103   return square (a) + square (b);
 104 }
 105
 106 void baz (int n)
 107 {
 108   struct S { int x[[n]]; };
 109 }])],
 110                   ac_cv_c99=yes, ac_cv_c99=no)
 111 CFLAGS="$old_CFLAGS"])
 112 AS_IF([test "x$ac_cv_c99" != xyes],
 113       AC_MSG_ERROR([gcc with GNU99 support required]))
 114
 115 AC_CACHE_CHECK([for __thread support], ac_cv_tls, [dnl
 116 # Use the same flags that we use for our DSOs, so the test is representative.
 117 # Some old compiler/linker/libc combinations fail some ways and not others.
 118 save_CFLAGS="$CFLAGS"
 119 save_LDFLAGS="$LDFLAGS"
 120 CFLAGS="-fpic $CFLAGS"
 121 LDFLAGS="-shared -Wl,-z,defs,-z,relro $LDFLAGS"
 122 AC_LINK_IFELSE([dnl
 123 AC_LANG_PROGRAM([[#include <stdlib.h>
 124 #undef __thread
 125 static __thread int a; int foo (int b) { return a + b; }]],
 126                 [[exit (foo (0));]])],
 127                ac_cv_tls=yes, ac_cv_tls=no)
 128 CFLAGS="$save_CFLAGS"
 129 LDFLAGS="$save_LDFLAGS"])
 130 AS_IF([test "x$ac_cv_tls" != xyes],
 131       AC_MSG_ERROR([__thread support required]))
 132
 133 dnl This test must come as early as possible after the compiler configuration
 134 dnl tests, because the choice of the file model can (in principle) affect
 135 dnl whether functions and headers are available, whether they work, etc.
 136 AC_SYS_LARGEFILE
 137
 138 dnl Enable the linker to be build as a native-only linker.  By default it
 139 dnl can handle all architectures but this comes at a cost.  A native
 140 dnl will be slightly faster, small, and has fewer dependencies.
 141 native_ld=no
 142 AC_ARG_ENABLE([generic],
 143 AS_HELP_STRING([--disable-generic], [do not build generic linker]), [dnl
 144 if test "$enable_generic" = no; then
 145   case "$host_cpu" in
 146    i?86)
 147     AC_DEFINE(NATIVE_ELF, 32)
 148     native_ld=yes
 149     base_cpu=i386
 150     ;;
 151    *)
 152     AC_MSG_ERROR([no machine-specific linker for this configuration available])
 153     ;;
 154   esac
 155 fi])
 156 AH_TEMPLATE([NATIVE_ELF],
 157 [Define to 32 or 64 if a specific implementation is wanted.])
 158 AM_CONDITIONAL(NATIVE_LD, test "$native_ld" = yes)
 159 dnl The automake generated Makefile cannot deal with macros in the name
 160 dnl of files if at any time there is no such file, even if the filename
 161 dnl would not be used.
 162 AS_IF([test -z "$base_cpu"], [base_cpu=none])
 163 AC_SUBST(base_cpu)
 164 dnl Support to work around automake's inflexible dependency generation.
 165 dnl See src/Makefile.am for more information.
 166 AM_CONDITIONAL(NEVER, false)
 167
 168 dnl enable debugging of branch prediction.
 169 AC_ARG_ENABLE([debugpred],
 170 AS_HELP_STRING([--enable-debugpred],[build binaries with support to debug branch prediction]),
 171 [use_debugpred=$enableval], [use_debugpred=no])
 172 case $use_debugpred in
 173  yes) use_debugpred_val=1 ;;
 174  *)   use_debugpred_val=0 ;;
 175 esac
 176 AC_SUBST([DEBUGPRED], $use_debugpred_val)
 177
 178 dnl Enable gprof suport.
 179 AC_ARG_ENABLE([gprof],
 180 AS_HELP_STRING([--enable-gprof],[build binaries with gprof support]), [use_gprof=$enableval], [use_gprof=no])
 181 if test "$use_gprof" = yes; then
 182   CFLAGS="$CFLAGS -pg"
 183   LDFLAGS="$LDFLAGS -pg"
 184 fi
 185 AM_CONDITIONAL(GPROF, test "$use_gprof" = yes)
 186
 187 # Enable gcov suport.
 188 AC_ARG_ENABLE([gcov],
 189 AS_HELP_STRING([--enable-gcov],[build binaries with gcov support]), [use_gcov=$enableval], [use_gcov=no])
 190 if test "$use_gcov" = yes; then
 191   CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 192   LDFLAGS="$LDFLAGS -fprofile-arcs"
 193 fi
 194 AM_CONDITIONAL(GCOV, test "$use_gcov" = yes)
 195
 196 AC_ARG_ENABLE([sanitize-undefined],
 197               AS_HELP_STRING([--enable-sanitize-undefined],
 198                              [Use gcc undefined behaviour sanitizer]),
 199                              [use_undefined=$enableval], [use_undefined=no])
 200 if test "$use_undefined" = yes; then
 201   old_CFLAGS="$CFLAGS"
 202   old_CXXFLAGS="$CXXFLAGS"
 203   # We explicitly use unaligned access when possible (see ALLOW_UNALIGNED)
 204   # We want to fail immediately on first error, don't try to recover.
 205   CFLAGS="$CFLAGS -fsanitize=undefined -fno-sanitize-recover"
 206   CXXFLAGS="$CXXFLAGS -fsanitize=undefined -fno-sanitize-recover"
 207   AC_LINK_IFELSE([AC_LANG_SOURCE([int main (int argc, char **argv) { return 0; }])], use_undefined=yes, use_undefined=no)
 208   AS_IF([test "x$use_undefined" != xyes],
 209         AC_MSG_WARN([gcc undefined behaviour sanitizer not available])
 210         CFLAGS="$old_CFLAGS" CXXFLAGS="$old_CXXFLAGS")
 211 fi
 212 case $use_undefined in
 213  yes) check_undefined_val=1 ;;
 214  *)   check_undefined_val=0 ;;
 215 esac
 216 AC_DEFINE_UNQUOTED(CHECK_UNDEFINED, $check_undefined_val,
 217                    [Building with -fsanitize=undefined or not])
 218
 219 AC_ARG_ENABLE([valgrind],
 220 AS_HELP_STRING([--enable-valgrind],[run all tests under valgrind]),
 221 [use_valgrind=$enableval], [use_valgrind=no])
 222 if test "$use_valgrind" = yes; then
 223   AC_CHECK_PROG(HAVE_VALGRIND, valgrind, yes, no)
 224   if test "$HAVE_VALGRIND" = "no"; then
 225     AC_MSG_ERROR([valgrind not found])
 226   fi
 227 fi
 228 AM_CONDITIONAL(USE_VALGRIND, test "$use_valgrind" = yes)
 229
 230 AM_CONDITIONAL(BUILD_STATIC, [dnl
 231 test "$use_gprof" = yes -o "$use_gcov" = yes])
 232
 233 AC_ARG_ENABLE([tests-rpath],
 234 AS_HELP_STRING([--enable-tests-rpath],[build $ORIGIN-using rpath into tests]),
 235                [tests_use_rpath=$enableval], [tests_use_rpath=no])
 236 AM_CONDITIONAL(TESTS_RPATH, test "$tests_use_rpath" = yes)
 237
 238 LIBEBL_SUBDIR="$PACKAGE"
 239 AC_ARG_ENABLE([libebl-subdir],
 240 AS_HELP_STRING([--enable-libebl-subdir=DIR],
 241 [install libebl_CPU modules in $(libdir)/DIR]), [dnl
 242 LIBEBL_SUBDIR="$enable_libebl_subdir"])
 243 AC_SUBST([LIBEBL_SUBDIR])
 244 AC_DEFINE_UNQUOTED(LIBEBL_SUBDIR, "$LIBEBL_SUBDIR")
 245 AH_TEMPLATE([LIBEBL_SUBDIR], [$libdir subdirectory containing libebl modules.])
 246
 247 dnl Test for zlib and bzlib, gives ZLIB/BZLIB .am
 248 dnl conditional and config.h USE_ZLIB/USE_BZLIB #define.
 249 save_LIBS="$LIBS"
 250 LIBS=
 251 eu_ZIPLIB(zlib,ZLIB,z,gzdirect,gzip)
 252 eu_ZIPLIB(bzlib,BZLIB,bz2,BZ2_bzdopen,bzip2)
 253 eu_ZIPLIB(lzma,LZMA,lzma,lzma_auto_decoder,[LZMA (xz)])
 254 zip_LIBS="$LIBS"
 255 LIBS="$save_LIBS"
 256 AC_SUBST([zip_LIBS])
 257
 258 AC_CHECK_LIB([stdc++], [__cxa_demangle], [dnl
 259 AC_DEFINE([USE_DEMANGLE], [1], [Defined if demangling is enabled])])
 260 AM_CONDITIONAL(DEMANGLE, test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes")
 261 AS_IF([test "x$ac_cv_lib_stdcpp___cxa_demangle" = "xyes"],
 262       [enable_demangler=yes],[enable_demangler=no])
 263
 264 AC_ARG_ENABLE([textrelcheck],
 265 AS_HELP_STRING([--disable-textrelcheck],
 266                [Disable textrelcheck being a fatal error]))
 267 AM_CONDITIONAL(FATAL_TEXTREL, [test "x$enable_textrelcheck" != "xno"])
 268 AS_IF([test "x$enable_textrelcheck" != "xno"],
 269       [enable_textrelcheck=yes],[enable_textrelcheck=no])
 270
 271 AC_ARG_ENABLE([symbol-versioning],
 272 AS_HELP_STRING([--disable-symbol-versioning],
 273                [Disable symbol versioning in shared objects]))
 274 AM_CONDITIONAL(SYMBOL_VERSIONING, [test "x$enable_symbol_versioning" != "xno"])
 275 AS_IF([test "x$enable_symbol_versioning" = "xno"],
 276       [AC_MSG_WARN([Disabling symbol versioning breaks ABI compatibility.])
 277        enable_symbol_versioning=no],[enable_symbol_versioning=yes])
 278
 279 dnl Check if we have argp available from our libc
 280 AC_LINK_IFELSE(
 281         [AC_LANG_PROGRAM(
 282                 [#include <argp.h>],
 283                 [int argc=1; char *argv[]={"test"}; argp_parse(0,argc,argv,0,0,0); return 0;]
 284                 )],
 285         [libc_has_argp="true"],
 286         [libc_has_argp="false"]
 287 )
 288
 289 dnl If our libc doesn't provide argp, then test for libargp
 290 if test "$libc_has_argp" = "false" ; then
 291         AC_MSG_WARN("libc does not have argp")
 292         AC_CHECK_LIB([argp], [argp_parse], [have_argp="true"], [have_argp="false"])
 293
 294         if test "$have_argp" = "false"; then
 295                 AC_MSG_ERROR("no libargp found")
 296         else
 297                 argp_LDADD="-largp"
 298         fi
 299 else
 300         argp_LDADD=""
 301 fi
 302 AC_SUBST([argp_LDADD])
 303
 304 dnl The directories with content.
 305
 306 dnl Documentation.
 307 dnl Commented out for now.
 308 dnl AC_CONFIG_FILES([doc/Makefile])
 309
 310 dnl Support library.
 311 AC_CONFIG_FILES([lib/Makefile])
 312
 313 dnl ELF library.
 314 AC_CONFIG_FILES([libelf/Makefile])
 315
 316 dnl Higher-level ELF support library.
 317 AC_CONFIG_FILES([libebl/Makefile])
 318
 319 dnl DWARF-ELF Lower-level Functions support library.
 320 AC_CONFIG_FILES([libdwelf/Makefile])
 321
 322 dnl DWARF library.
 323 AC_CONFIG_FILES([libdw/Makefile])
 324
 325 dnl Higher-level DWARF support library.
 326 AC_CONFIG_FILES([libdwfl/Makefile])
 327
 328 dnl CPU handling library.
 329 AC_CONFIG_FILES([libcpu/Makefile])
 330
 331 dnl Assembler library.
 332 AM_CONDITIONAL(HAVE_LIBASM, true)dnl Used in tests/Makefile.am, which see.
 333 AC_CONFIG_FILES([libasm/Makefile])
 334
 335 dnl CPU-specific backend libraries.
 336 AC_CONFIG_FILES([backends/Makefile])
 337
 338 dnl Tools.
 339 AC_CONFIG_FILES([src/Makefile po/Makefile.in])
 340
 341 dnl Test suite.
 342 AM_CONDITIONAL(STANDALONE, false)dnl Used in tests/Makefile.am, which see.
 343 AC_CONFIG_FILES([tests/Makefile])
 344
 345 # Get the definitions necessary to create the Makefiles in the po
 346 # subdirectories.  This is a small subset of the gettext rules.
 347 AC_SUBST(USE_NLS, yes)
 348 AM_PO_SUBDIRS
 349
 350 dnl Appended to the config.h file.
 351 dnl We hide all kinds of configuration magic in lib/eu-config.h.
 352 AH_BOTTOM([#include <eu-config.h>])
 353
 354 dnl Version compatibility header.
 355 AC_CONFIG_FILES([version.h:config/version.h.in])
 356 AC_SUBST([eu_version])
 357
 358 # 1.234<whatever> -> 1234<whatever>
 359 case "$PACKAGE_VERSION" in
 360 [[0-9]].*) eu_version=`echo "$PACKAGE_VERSION" | sed 's@\.@@'` ;;
 361 *)         AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 362 esac
 363 case "$eu_version" in
 364 *.*)
 365   # 1234.567 -> "1234", "567"
 366   eu_extra_version="${eu_version#*.}"
 367   eu_version="${eu_version%%.*}"
 368   case "$eu_extra_version" in
 369   [[0-9]][[0-9]][[0-9]]) ;;
 370   [[0-9]][[0-9]])       eu_extra_version="${eu_extra_version}0" ;;
 371   [[0-9]])              eu_extra_version="${eu_extra_version}00" ;;
 372   *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 373   esac
 374   ;;
 375 *)
 376   eu_extra_version=000
 377   ;;
 378 esac
 379
 380 case "$eu_version" in
 381       0[[0-9]][[0-9]][[0-9]]) eu_version="${eu_version#0}$eu_extra_version" ;;
 382 [[0-9]][[0-9]][[0-9]][[0-9]]) eu_version="${eu_version}$eu_extra_version" ;;
 383 [[0-9]][[0-9]][[0-9]])        eu_version="${eu_version}0$eu_extra_version" ;;
 384 [[0-9]][[0-9]])               eu_version="${eu_version}00$eu_extra_version";;
 385 *) AC_MSG_ERROR([confused by version number '$PACKAGE_VERSION']) ;;
 386 esac
 387
 388 # Round up to the next release API (x.y) version.
 389 eu_version=$(( (eu_version + 999) / 1000 ))
 390
 391 AC_CHECK_SIZEOF(long)
 392
 393 # On aarch64 before glibc 2.20 we would get the kernel user_pt_regs instead
 394 # of the user_regs_struct from sys/user.h. They are structurally the same
 395 # but we get either one or the other.
 396 AC_CHECK_TYPE([struct user_regs_struct],
 397               [sys_user_has_user_regs=yes], [sys_user_has_user_regs=no],
 398               [[#include <sys/ptrace.h>]
 399                [#include <sys/time.h>]
 400                [#include <sys/user.h>]])
 401 if test "$sys_user_has_user_regs" = "yes"; then
 402   AC_DEFINE(HAVE_SYS_USER_REGS, 1,
 403             [Define to 1 if <sys/user.h> defines struct user_regs_struct])
 404 fi
 405
 406 # On a 64-bit host where can can use $CC -m32, we'll run two sets of tests.
 407 # Likewise in a 32-bit build on a host where $CC -m64 works.
 408 utrace_BIARCH
 409 # `$utrace_biarch' will be `-m64' even on an uniarch i386 machine.
 410 CC_BIARCH="$CC $utrace_biarch"
 411 AC_SUBST([CC_BIARCH])
 412
 413 # In maintainer mode we really need flex and bison.
 414 # Otherwise we really need a release dir with maintainer files generated.
 415 if test "x$enable_maintainer_mode" = xyes; then
 416   AC_CHECK_PROG(HAVE_FLEX, flex, yes, no)
 417   if test "$HAVE_FLEX" = "no"; then
 418     AC_MSG_ERROR([flex needed in maintainer mode])
 419   fi
 420   AC_CHECK_PROG(HAVE_BISON, bison, yes, no)
 421   if test "$HAVE_BISON" = "no"; then
 422     AC_MSG_ERROR([bison needed in maintainer mode])
 423   fi
 424 else
 425   if test ! -f ${srcdir}/libdw/known-dwarf.h; then
 426     AC_MSG_ERROR([No libdw/known-dwarf.h. configure --enable-maintainer-mode])
 427   fi
 428 fi
 429
 430 # The testfiles are all compressed, we need bunzip2 when running make check
 431 AC_CHECK_PROG(HAVE_BUNZIP2, bunzip2, yes, no)
 432 if test "$HAVE_BUNZIP2" = "no"; then
 433   AC_MSG_WARN([No bunzip2, needed to run make check])
 434 fi
 435
 436 AC_OUTPUT
 437
 438 AC_MSG_NOTICE([
 439 =====================================================================
 440         elfutils: ${PACKAGE_VERSION} (eu_version: ${eu_version})
 441 =====================================================================
 442
 443     Prefix                             : ${prefix}
 444     Program prefix ("eu-" recommended) : ${program_prefix}
 445     Source code location               : ${srcdir}
 446     Maintainer mode                    : ${enable_maintainer_mode}
 447     libebl modules subdirectory        : ${LIBEBL_SUBDIR}
 448     build arch                         : ${ac_cv_build}
 449
 450   RECOMMENDED FEATURES (should all be yes)
 451     gzip support                       : ${with_zlib}
 452     bzip2 support                      : ${with_bzlib}
 453     lzma/xz support                    : ${with_lzma}
 454     libstdc++ demangle support         : ${enable_demangler}
 455     File textrel check                 : ${enable_textrelcheck}
 456     Symbol versioning                  : ${enable_symbol_versioning}
 457
 458   NOT RECOMMENDED FEATURES (should all be no)
 459     Experimental thread safety         : ${use_locks}
 460
 461   OTHER FEATURES
 462     Deterministic archives by default  : ${default_ar_deterministic}
 463     Native language support            : ${USE_NLS}
 464
 465   EXTRA TEST FEATURES (used with make check)
 466     have bunzip2 installed (required)  : ${HAVE_BUNZIP2}
 467     debug branch prediction            : ${use_debugpred}
 468     gprof support                      : ${use_gprof}
 469     gcov support                       : ${use_gcov}
 470     run all tests under valgrind       : ${use_valgrind}
 471     gcc undefined behaviour sanitizer  : ${use_undefined}
 472     use rpath in tests                 : ${tests_use_rpath}
 473     test biarch                        : ${utrace_cv_cc_biarch}
 474 ])