configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.11.0,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.11
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 25, 0, 0)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.11.0
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.17])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138
 139 dnl check if the compiler supports '-c' and '-o' options
 140 AM_PROG_CC_C_O
 141
 142 dnl determine if c++ is available on this system
 143 AC_PROG_CXX
 144 dnl CXX may be set to some default even if no c++ compiler is available
 145 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 146 AC_LANG_PUSH([C++])
 147 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 148 AC_LANG_POP([C++])
 149 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 150 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for gobject-introspection
 156 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 157
 158 dnl check for documentation tools
 159 GTK_DOC_CHECK([1.3])
 160 AS_PATH_PYTHON([2.1])
 161 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 AC_CHECK_LIBM
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 ac_cppflags_save="$CPPFLAGS"
 175 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 176 AC_COMPILE_IFELSE(
 177   AC_LANG_PROGRAM([
 178 #include <libxml/HTMLparser.h>
 179                      ],[
 180 #ifndef LIBXML_HTML_ENABLED
 181 #error libxml2 has no HTML support
 182 #endif /* LIBXML_HTML_ENABLED */
 183                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 184 CPPFLAGS="$ac_cppflags_save"
 185 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 186
 187 dnl used in gst/tcp
 188 AC_CHECK_HEADERS([sys/socket.h],
 189   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 190 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 191
 192 dnl used in gst-libs/gst/rtsp
 193 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 194 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 195   WIN32_LIBS="-lws2_32"
 196   AC_SUBST(WIN32_LIBS)
 197 fi
 198
 199 dnl check for hstrerror, for gst-libs/gst/rtsp
 200 save_libs="$LIBS"
 201 AC_CHECK_FUNC(hstrerror, ,
 202     AC_CHECK_LIB(resolv, hstrerror, ,
 203         [AC_DEFINE(NO_HSTRERROR, 1,
 204              [Define if you have no native hstrerror() function.])]))
 205 HSTRERROR_LIBS=$LIBS
 206 AC_SUBST(HSTRERROR_LIBS)
 207 LIBS="$save_libs"
 208
 209 dnl used in gst-libs/gst/pbutils and associated unit test
 210 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 211
 212 dnl also, Windows does not have long long
 213 AX_CREATE_STDINT_H
 214
 215 dnl *** checks for functions ***
 216 AC_CHECK_FUNCS([localtime_r gmtime_r])
 217
 218 dnl *** checks for math functions ***
 219 LIBS_SAVE=$LIBS
 220 LIBS="$LIBS $LIBM"
 221 AC_CHECK_FUNCS(log2)
 222 LIBS=$LIBS_SAVE
 223
 224 dnl *** checks for types/defines ***
 225
 226 dnl Check for FIONREAD ioctl declaration
 227 dnl used in gst/tcp
 228 GST_CHECK_FIONREAD
 229
 230 dnl *** checks for structures ***
 231
 232 dnl *** checks for compiler characteristics ***
 233
 234 dnl *** checks for library functions ***
 235
 236 dnl check for fseeko()
 237 AC_FUNC_FSEEKO
 238
 239 dnl Check for fast float to int casting as defined in C99
 240 dnl used in gst-libs/gst/floatcast/floatcast.h
 241 save_libs=$LIBS
 242 LIBS="$LIBS $LIBM"
 243 AC_C99_FUNC_LRINT
 244 AC_C99_FUNC_LRINTF
 245 LIBS=$save_libs
 246
 247 dnl Check for a way to display the function name in debug output
 248 AG_GST_CHECK_FUNCTION
 249
 250 dnl *** checks for socket and nsl libraries ***
 251 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 252 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 253
 254 dnl *** checks for dependency libraries ***
 255
 256 dnl GLib is required
 257 AG_GST_GLIB_CHECK([2.26])
 258
 259 ORC_CHECK([0.4.11])
 260
 261 dnl checks for gstreamer
 262 dnl uninstalled is selected preferentially -- see pkg-config(1)
 263 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 264 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 265 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 266 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 267 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 268 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 269
 270 dnl Check for documentation xrefs
 271 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 272 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 273 AC_SUBST(GLIB_PREFIX)
 274 AC_SUBST(GST_PREFIX)
 275
 276 dnl GTK is optional and only used in examples
 277 HAVE_GTK=no
 278 HAVE_GTK_X11=no
 279 GTK2_REQ=2.14.0
 280 GTK3_REQ=2.91.3
 281 if test "x$BUILD_EXAMPLES" = "xyes"; then
 282   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 283   AC_ARG_WITH([gtk],
 284     AC_HELP_STRING([--with-gtk=3.0|2.0],
 285                    [which gtk+ version to compile against (default: 2.0)]),
 286     [case "$with_gtk" in
 287         2.0) GTK_REQ=$GTK2_REQ ;;
 288         3.0) GTK_REQ=$GTK3_REQ ;;
 289         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 290     esac],
 291     [with_gtk=2.0
 292      GTK_REQ=$GTK2_REQ])
 293   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 294   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 295   dnl some examples need gtk+-x11
 296   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 297   AC_SUBST(GTK_LIBS)
 298   AC_SUBST(GTK_CFLAGS)
 299 fi
 300 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 301 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 302
 303 dnl QT is optional and only used in examples
 304 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 305   HAVE_QT_GV=yes
 306   HAVE_QT=yes
 307 ], [
 308   HAVE_QT_GV=no
 309   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 310 ])
 311 if test "x$HAVE_QT" = "xyes"; then
 312   AC_MSG_CHECKING([Qt moc])
 313   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 314   AC_MSG_RESULT($QT4_MOC)
 315   AC_SUBST(QT4_MOC)
 316 fi
 317 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 318 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 319
 320 dnl chck for linux headers needed by the joystick seek example
 321 AC_COMPILE_IFELSE(
 322 [
 323   AC_LANG_PROGRAM([
 324     #include <linux/input.h>
 325     #include <linux/joystick.h>
 326   ],[
 327     struct js_event js;
 328     js.type = JS_EVENT_AXIS;
 329   ])
 330 ], [
 331   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 332 ], [
 333   HAVE_LINUX_JOYSTICK_HEADERS="no"
 334 ])
 335 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 336
 337 dnl Check for -Bsymbolic-functions linker flag used to avoid
 338 dnl intra-library PLT jumps, if available.
 339 AC_ARG_ENABLE(Bsymbolic,
 340               [AC_HELP_STRING([--disable-Bsymbolic],
 341                               [avoid linking with -Bsymbolic])],,
 342               [SAVED_LDFLAGS="${LDFLAGS}"
 343                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 344                LDFLAGS=-Wl,-Bsymbolic-functions
 345                AC_TRY_LINK([], [int main (void) { return 0; }],
 346                            AC_MSG_RESULT(yes)
 347                            enable_Bsymbolic=yes,
 348                            AC_MSG_RESULT(no)
 349                            enable_Bsymbolic=no)
 350                LDFLAGS="${SAVED_LDFLAGS}"])
 351
 352
 353 dnl *** set variables based on configure arguments ***
 354
 355 dnl set license and copyright notice
 356 GST_LICENSE="LGPL"
 357 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 358 AC_SUBST(GST_LICENSE)
 359
 360 dnl set location of plugin directory
 361 AG_GST_SET_PLUGINDIR
 362
 363 dnl set release date/time
 364 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 365   ["${srcdir}/gst-plugins-base.doap"],
 366   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 367
 368 dnl define an ERROR_CFLAGS Makefile variable
 369 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 370 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 371     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 372     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 373     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 374     -Wno-multichar -Wnested-externs ])
 375
 376 dnl define an ERROR_CXXFLAGS Makefile variable
 377 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 378     -Wmissing-declarations -Wredundant-decls -Wundef
 379     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 380     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 381     -Wno-multichar])
 382
 383 dnl define correct level for debugging messages
 384 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 385
 386 dnl used in examples
 387 AG_GST_DEFAULT_ELEMENTS
 388
 389 dnl needed for encoding-target
 390 GST_DATADIR="$GST_PREFIX/share"
 391 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 392 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 393
 394 dnl behaviour of speex based audio resampler
 395 AC_MSG_CHECKING(which audio resample format to use for integer)
 396 AC_ARG_WITH([audioresample_format],
 397         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 398         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 399 AC_MSG_RESULT($ac_cv_audioresample_format)
 400 case $ac_cv_audioresample_format in
 401   int)
 402     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 403     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 404   ;;
 405   float)
 406     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 407     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 408   ;;
 409   auto)
 410     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 411     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 412 esac
 413
 414 dnl *** plug-ins to include ***
 415
 416 dnl these are all the gst plug-ins, compilable without additional libs
 417 AG_GST_CHECK_PLUGIN(adder)
 418 AG_GST_CHECK_PLUGIN(app)
 419 AG_GST_CHECK_PLUGIN(audioconvert)
 420 AG_GST_CHECK_PLUGIN(audiorate)
 421 AG_GST_CHECK_PLUGIN(audiotestsrc)
 422 AG_GST_CHECK_PLUGIN(encoding)
 423 AG_GST_CHECK_PLUGIN(videoconvert)
 424 AG_GST_CHECK_PLUGIN(gdp)
 425 AG_GST_CHECK_PLUGIN(playback)
 426 AG_GST_CHECK_PLUGIN(audioresample)
 427 AG_GST_CHECK_PLUGIN(subparse)
 428 AG_GST_CHECK_PLUGIN(tcp)
 429 AG_GST_CHECK_PLUGIN(typefind)
 430 AG_GST_CHECK_PLUGIN(videotestsrc)
 431 AG_GST_CHECK_PLUGIN(videorate)
 432 AG_GST_CHECK_PLUGIN(videoscale)
 433 AG_GST_CHECK_PLUGIN(volume)
 434
 435 dnl FIXME 0.11: check for libxml, split subparse and move libxml parts to ext/
 436 AM_CONDITIONAL(USE_XML, false)
 437 AC_DEFINE([GST_DISABLE_XML], [1], [set to disable libxml2-dependent code in subparse])
 438
 439 dnl disable plug-ins that require libxml2's HTML support if it is not available
 440 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 441   AG_GST_DISABLE_PLUGIN(subparse)
 442 fi
 443
 444 dnl disable plug-ins that require sys/socket.h if it is not available
 445 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 446   AG_GST_DISABLE_PLUGIN(tcp)
 447 fi
 448
 449 dnl iso-codes is optional, used by libgsttag
 450 AC_ARG_ENABLE(iso-codes,
 451 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 452 [case "${enableval}" in
 453   yes) enable_iso_codes=yes ;;
 454   no)  enable_iso_codes=no ;;
 455   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 456 esac
 457 ],
 458 [enable_iso_codes=yes]) dnl Default value
 459
 460 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 461 if test "x$enable_iso_codes" = "xyes"; then
 462   AC_MSG_RESULT([yes])
 463   have_iso_codes=no
 464   AC_MSG_CHECKING([whether iso-codes are available on this system])
 465   if $PKG_CONFIG iso-codes; then
 466     AC_MSG_RESULT([yes])
 467     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 468     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 469       AC_MSG_RESULT([yes])
 470       AC_MSG_CHECKING([for iso-codes prefix])
 471       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 472       if test -d "$ISO_CODES_PREFIX"; then
 473         AC_MSG_RESULT([yes])
 474         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 475         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 476         ISO_639_DOMAIN="iso_639"
 477         AC_MSG_CHECKING([ISO_639_DOMAIN])
 478         AC_MSG_RESULT([$ISO_639_DOMAIN])
 479         have_iso_codes=yes
 480         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 481         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 482         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 483         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 484       else
 485         AC_MSG_RESULT([no])
 486       fi
 487     else
 488       AC_MSG_RESULT([no])
 489     fi
 490   else
 491     AC_MSG_RESULT([no])
 492   fi
 493   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 494 else
 495   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 496   AM_CONDITIONAL(USE_ISO_CODES, false)
 497 fi
 498
 499 dnl *** sys plug-ins ***
 500
 501 echo
 502 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 503 echo
 504
 505 dnl *** X11 ***
 506 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 507 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 508                   [ximagesink], [
 509   AC_PATH_XTRA
 510   ac_cflags_save="$CFLAGS"
 511   ac_cppflags_save="$CPPFLAGS"
 512   CFLAGS="$CFLAGS $X_CFLAGS"
 513   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 514
 515   dnl now try to find the HEADER
 516   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 517
 518   if test "x$HAVE_X" = "xno"
 519   then
 520     AC_MSG_NOTICE([cannot find X11 development files])
 521   else
 522     dnl this is much more than we want
 523     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 524     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 525     dnl it does not add the libs; therefore we add them here
 526     X_LIBS="$X_LIBS -lX11"
 527     AC_SUBST(X_CFLAGS)
 528     AC_SUBST(X_LIBS)
 529   fi
 530   AC_SUBST(HAVE_X)
 531   CFLAGS="$ac_cflags_save"
 532   CPPFLAGS="$ac_cppflags_save"
 533 ])
 534
 535 dnl Check for Xv extension
 536 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 537 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 538                   [xvimagesink], [
 539   AG_GST_CHECK_XV
 540 ])
 541
 542 dnl check for X Shm
 543 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 544 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 545   if test x$HAVE_X = xyes; then
 546     AC_CHECK_LIB(Xext, XShmAttach,
 547                  HAVE_XSHM="yes", HAVE_XSHM="no",
 548                  $X_LIBS)
 549     if test "x$HAVE_XSHM" = "xyes"; then
 550       XSHM_LIBS="-lXext"
 551     else
 552       dnl On AIX, it is in XextSam instead, but we still need -lXext
 553       AC_CHECK_LIB(XextSam, XShmAttach,
 554                    HAVE_XSHM="yes", HAVE_XSHM="no",
 555                    $X_LIBS)
 556       if test "x$HAVE_XSHM" = "xyes"; then
 557         XSHM_LIBS="-lXext -lXextSam"
 558       fi
 559     fi
 560   fi
 561 ], , [
 562   AC_SUBST(HAVE_XSHM)
 563   AC_SUBST(XSHM_LIBS)
 564 ])
 565
 566 dnl *** ext plug-ins ***
 567 dnl keep this list sorted alphabetically !
 568
 569 if test "x$BUILD_EXTERNAL" = "xyes"; then
 570
 571 echo
 572 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 573 echo
 574
 575 dnl *** alsa ***
 576 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 577 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 578   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 579     HAVE_ALSA="yes"
 580     AC_SUBST(ALSA_CFLAGS)
 581     AC_SUBST(ALSA_LIBS)
 582   ], [
 583     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 584   ])
 585 ])
 586
 587 dnl *** CDParanoia ***
 588 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 589 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 590 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 591   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 592     HAVE_CDPARANOIA="yes"
 593   ], [
 594     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 595                         cdda_open, -lm,
 596                         cdda_interface.h,
 597                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 598                         HEADER_DIR="no"
 599                         FOUND_CDPARANOIA="yes")
 600     if test "x$FOUND_CDPARANOIA" != "xyes";
 601     then
 602       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 603                           cdda_open, -lm,
 604                           cdda/cdda_interface.h,
 605                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 606                           HEADER_DIR="yes"
 607                           FOUND_CDPARANOIA="yes")
 608     fi
 609     if test "x$HEADER_DIR" = "xyes";
 610     then
 611       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 612                          defined if cdda headers are in a cdda/ directory)
 613     fi
 614     if test "x$FOUND_CDPARANOIA" = "xyes";
 615     then
 616       AC_CHECK_LIB(cdda_paranoia,
 617                    paranoia_cachemodel_size,
 618                    : ,
 619                    HAVE_CDPARANOIA=no,
 620                  [-lcdda_interface])
 621     fi
 622
 623     AC_SUBST(CDPARANOIA_LIBS)
 624   ])
 625 ])
 626 dnl FIXME : add second check somehow if that is necessary
 627 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 628 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 629
 630 dnl *** ivorbis ***
 631 dnl AM_PATH_IVORBIS only takes two options
 632 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 633 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 634   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 635   if test $HAVE_IVORBIS = no
 636   then
 637     IVORBIS_LIBS=
 638     IVORBIS_CFLAGS=
 639     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 640       [IVORBIS_LIBS=-lvorbisidec
 641       HAVE_IVORBIS=yes
 642       case $host in
 643       arm-*-*)
 644         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 645       esac
 646       ],
 647       HAVE_IVORBIS=no)
 648     AC_SUBST(IVORBIS_LIBS)
 649     AC_SUBST(IVORBIS_CFLAGS)
 650   else
 651     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 652       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 653       USE_TREMOLO=no)
 654   fi
 655 ])
 656
 657 dnl *** libgio ***
 658 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 659 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 660   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 661     HAVE_GIO="yes"
 662     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 663     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 664            [The GIO modules directory.])
 665     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 666     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 667            [The GIO library directory.])
 668   ], [
 669     HAVE_GIO="no"
 670   ])
 671   AC_SUBST(GIO_CFLAGS)
 672   AC_SUBST(GIO_LIBS)
 673   AC_SUBST(GIO_LDFLAGS)
 674 ])
 675
 676 dnl *** libvisual ***
 677 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 678 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 679   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 680   if test $HAVE_LIBVISUAL = no
 681   then
 682     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 683     if test x$HAVE_LIBVISUAL = xyes; then
 684       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 685     fi
 686   else
 687     if test x$HAVE_LIBVISUAL = xyes; then
 688       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 689     fi
 690   fi
 691   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 692   if test x$LIBVIS_PLUGINSDIR != x; then
 693     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 694         "$LIBVIS_PLUGINSDIR",
 695         [directory in which the detected libvisual's plugins are located])
 696   fi
 697 ])
 698
 699 dnl *** ogg ***
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 701 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 702   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 703   if test $HAVE_OGG = no
 704   then
 705     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 706     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 707   fi
 708 ])
 709
 710 dnl *** pango ***
 711 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 712 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 713   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 714 ])
 715
 716 dnl *** theora ***
 717 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 718 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 719   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 720 ])
 721
 722 dnl *** vorbis ***
 723 dnl AM_PATH_VORBIS only takes two options
 724 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 725 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 726   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 727   if test $HAVE_VORBIS = no
 728   then
 729     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 730     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 731   fi
 732 ])
 733
 734 if test "x$HAVE_VORBIS" = "xyes"; then
 735   ac_cflags_save="$CFLAGS"
 736   AC_COMPILE_IFELSE(
 737     AC_LANG_PROGRAM([
 738 #include <vorbis/codec.h>
 739                      ],[
 740 vorbis_dsp_state *v;
 741
 742 vorbis_synthesis_restart (v);
 743                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 744   if test "x$HAVE_VSR" = "xyes"; then
 745     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 746                        [defined if vorbis_synthesis_restart is present])
 747   fi
 748   CFLAGS="$ac_cflags_save"
 749 fi
 750
 751 else
 752
 753 dnl not building plugins with external dependencies,
 754 dnl but we still need to set the conditionals
 755 AM_CONDITIONAL(USE_ALSA, false)
 756 AM_CONDITIONAL(USE_CDPARANOIA, false)
 757 AM_CONDITIONAL(USE_GIO, false)
 758 AM_CONDITIONAL(USE_IVORBIS, false)
 759 AM_CONDITIONAL(USE_LIBVISUAL, false)
 760 AM_CONDITIONAL(USE_OGG, false)
 761 AM_CONDITIONAL(USE_PANGO, false)
 762 AM_CONDITIONAL(USE_THEORA, false)
 763 AM_CONDITIONAL(USE_VORBIS, false)
 764
 765 fi dnl of EXT plugins
 766
 767 dnl seeking needs freetype, so check for it here
 768 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 769   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 770 ])
 771 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 772 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 773 AC_SUBST(FT2_CFLAGS)
 774 AC_SUBST(FT2_LIBS)
 775
 776 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 777
 778 dnl Overview:
 779 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 780 dnl GST_*:              flags shared by built objects to link against GStreamer
 781 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 782 dnl                          (compare to other modules) or for i18n
 783 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 784 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 785 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 786 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 787
 788 dnl GST_OPTION_CFLAGS
 789 if test "x$USE_DEBUG" = xyes; then
 790    PROFILE_CFLAGS="-g"
 791 fi
 792 AC_SUBST(PROFILE_CFLAGS)
 793
 794 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 795   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 796   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 797 else
 798   DEPRECATED_CFLAGS=""
 799 fi
 800 AC_SUBST(DEPRECATED_CFLAGS)
 801
 802 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 803 dnl at make time with e.g. make ERROR_CFLAGS=""
 804 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 805 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 806 AC_SUBST(GST_OPTION_CFLAGS)
 807 AC_SUBST(GST_OPTION_CXXFLAGS)
 808
 809 dnl our libraries need to be versioned correctly
 810 AC_SUBST(GST_LT_LDFLAGS)
 811
 812 dnl GST_PLUGINS_BASE_CFLAGS
 813 dnl prefer internal headers to already installed ones
 814 dnl also add builddir include for enumtypes and marshal
 815 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 816 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 817
 818 dnl FIXME: do we want to rename to GST_ALL_* ?
 819 dnl add GST_OPTION_CFLAGS, but overridable
 820 GST_CFLAGS="$GST_CFLAGS -DGST_USE_UNSTABLE_API"
 821 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 822 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 823 AC_SUBST(GST_CFLAGS)
 824 AC_SUBST(GST_CXXFLAGS)
 825 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 826 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 827 AC_SUBST(GST_LIBS)
 828
 829 dnl LDFLAGS really should only contain flags, not libs - they get added before
 830 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 831 GST_ALL_LDFLAGS="-no-undefined"
 832 if test "x${enable_Bsymbolic}" = "xyes"; then
 833   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 834 fi
 835 AC_SUBST(GST_ALL_LDFLAGS)
 836
 837 dnl GST_LIB_LDFLAGS
 838 dnl linker flags shared by all libraries
 839 dnl LDFLAGS modifier defining exported symbols from built libraries
 840 dnl (export _gst_foo but not __gst_foo)
 841 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 842 AC_SUBST(GST_LIB_LDFLAGS)
 843
 844 dnl this really should only contain flags, not libs - they get added before
 845 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 846 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 847 AC_SUBST(GST_PLUGIN_LDFLAGS)
 848
 849 dnl *** output files ***
 850
 851 AC_CONFIG_FILES(
 852 Makefile
 853 gst-plugins-base.spec
 854 gst/Makefile
 855 gst/adder/Makefile
 856 gst/app/Makefile
 857 gst/audioconvert/Makefile
 858 gst/audiorate/Makefile
 859 gst/audiotestsrc/Makefile
 860 gst/encoding/Makefile
 861 gst/videoconvert/Makefile
 862 gst/gdp/Makefile
 863 gst/playback/Makefile
 864 gst/audioresample/Makefile
 865 gst/subparse/Makefile
 866 gst/tcp/Makefile
 867 gst/typefind/Makefile
 868 gst/videotestsrc/Makefile
 869 gst/videorate/Makefile
 870 gst/videoscale/Makefile
 871 gst/volume/Makefile
 872 sys/Makefile
 873 sys/ximage/Makefile
 874 sys/xvimage/Makefile
 875 ext/Makefile
 876 ext/alsa/Makefile
 877 ext/cdparanoia/Makefile
 878 ext/gio/Makefile
 879 ext/libvisual/Makefile
 880 ext/ogg/Makefile
 881 ext/pango/Makefile
 882 ext/theora/Makefile
 883 ext/vorbis/Makefile
 884 gst-libs/Makefile
 885 gst-libs/gst/Makefile
 886 gst-libs/gst/audio/Makefile
 887 gst-libs/gst/app/Makefile
 888 gst-libs/gst/cdda/Makefile
 889 gst-libs/gst/fft/Makefile
 890 gst-libs/gst/floatcast/Makefile
 891 gst-libs/gst/interfaces/Makefile
 892 gst-libs/gst/netbuffer/Makefile
 893 gst-libs/gst/riff/Makefile
 894 gst-libs/gst/rtp/Makefile
 895 gst-libs/gst/rtsp/Makefile
 896 gst-libs/gst/sdp/Makefile
 897 gst-libs/gst/tag/Makefile
 898 gst-libs/gst/pbutils/Makefile
 899 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 900 gst-libs/gst/video/Makefile
 901 tools/Makefile
 902 pkgconfig/Makefile
 903 pkgconfig/gstreamer-audio.pc
 904 pkgconfig/gstreamer-audio-uninstalled.pc
 905 pkgconfig/gstreamer-app.pc
 906 pkgconfig/gstreamer-app-uninstalled.pc
 907 pkgconfig/gstreamer-cdda.pc
 908 pkgconfig/gstreamer-cdda-uninstalled.pc
 909 pkgconfig/gstreamer-fft.pc
 910 pkgconfig/gstreamer-fft-uninstalled.pc
 911 pkgconfig/gstreamer-floatcast.pc
 912 pkgconfig/gstreamer-floatcast-uninstalled.pc
 913 pkgconfig/gstreamer-interfaces.pc
 914 pkgconfig/gstreamer-interfaces-uninstalled.pc
 915 pkgconfig/gstreamer-netbuffer.pc
 916 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 917 pkgconfig/gstreamer-pbutils.pc
 918 pkgconfig/gstreamer-pbutils-uninstalled.pc
 919 pkgconfig/gstreamer-riff.pc
 920 pkgconfig/gstreamer-riff-uninstalled.pc
 921 pkgconfig/gstreamer-rtp.pc
 922 pkgconfig/gstreamer-rtp-uninstalled.pc
 923 pkgconfig/gstreamer-rtsp.pc
 924 pkgconfig/gstreamer-rtsp-uninstalled.pc
 925 pkgconfig/gstreamer-sdp.pc
 926 pkgconfig/gstreamer-sdp-uninstalled.pc
 927 pkgconfig/gstreamer-tag.pc
 928 pkgconfig/gstreamer-tag-uninstalled.pc
 929 pkgconfig/gstreamer-video.pc
 930 pkgconfig/gstreamer-video-uninstalled.pc
 931 pkgconfig/gstreamer-plugins-base.pc
 932 pkgconfig/gstreamer-plugins-base-uninstalled.pc
 933 tests/Makefile
 934 tests/check/Makefile
 935 tests/examples/Makefile
 936 tests/examples/app/Makefile
 937 tests/examples/audio/Makefile
 938 tests/examples/dynamic/Makefile
 939 tests/examples/encoding/Makefile
 940 tests/examples/gio/Makefile
 941 tests/examples/overlay/Makefile
 942 tests/examples/seek/Makefile
 943 tests/examples/snapshot/Makefile
 944 tests/examples/playrec/Makefile
 945 tests/examples/volume/Makefile
 946 tests/files/Makefile
 947 tests/icles/Makefile
 948 tests/icles/playback/Makefile
 949 docs/Makefile
 950 docs/design/Makefile
 951 docs/libs/Makefile
 952 docs/plugins/Makefile
 953 docs/version.entities
 954 po/Makefile.in
 955 common/Makefile
 956 common/m4/Makefile
 957 m4/Makefile
 958 )
 959
 960 dnl Create the config.h file for Visual Studio builds
 961 dnl Beware of spaces and /'s in some of the shell variable contents.
 962 sed \
 963     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
 964     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
 965     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
 966     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
 967     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
 968     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
 969     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
 970     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
 971     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
 972     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
 973     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
 974     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
 975     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
 976     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
 977     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
 978     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
 979     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
 980     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
 981     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
 982     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
 983     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
 984     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
 985     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
 986     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
 987     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
 988     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
 989     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
 990     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
 991     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
 992     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
 993     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
 994     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
 995     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
 996     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.11"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.11"\n#endif/' \
 997     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
 998     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
 999     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1000     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1001     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1002     config.h.in >win32/common/config.h-new
1003
1004
1005
1006 AC_OUTPUT
1007
1008 AG_GST_OUTPUT_PLUGINS
1009 ORC_OUTPUT
1010