configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_CHECK_PROGS([PYTHON2], [python2 python])
  34 AC_PATH_PROG([MKDEP], [makedepend])
  35 AC_PATH_PROG([SED], [sed])
  36
  37 if test "x$MKDEP" = "x"; then
  38     AC_MSG_ERROR([makedepend is required to build Mesa])
  39 fi
  40
  41 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  42 dnl configuration in that case.
  43 AC_PROG_INSTALL
  44 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  45
  46 dnl We need a POSIX shell for parts of the build. Assume we have one
  47 dnl in most cases.
  48 case "$host_os" in
  49 solaris*)
  50     # Solaris /bin/sh is too old/non-POSIX compliant
  51     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  52     SHELL="$POSIX_SHELL"
  53     ;;
  54 esac
  55
  56 dnl clang is mostly GCC-compatible, but its version is much lower,
  57 dnl so we have to check for it.
  58 AC_MSG_CHECKING([if compiling with clang])
  59
  60 AC_COMPILE_IFELSE(
  61 [AC_LANG_PROGRAM([], [[
  62 #ifndef __clang__
  63        not clang
  64 #endif
  65 ]])],
  66 [CLANG=yes], [CLANG=no])
  67
  68 AC_MSG_RESULT([$CLANG])
  69
  70 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  71 dnl versions are explictly not supported.
  72 if test "x$GCC" = xyes -a "x$CLANG" = xno; then
  73     AC_MSG_CHECKING([whether gcc version is sufficient])
  74     major=0
  75     minor=0
  76
  77     GCC_VERSION=`$CC -dumpversion`
  78     if test $? -eq 0; then
  79         major=`echo $GCC_VERSION | cut -d. -f1`
  80         minor=`echo $GCC_VERSION | cut -d. -f1`
  81     fi
  82
  83     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  86     else
  87         AC_MSG_RESULT([yes])
  88     fi
  89 fi
  90
  91
  92 MKDEP_OPTIONS=-fdepend
  93 dnl Ask gcc where it's keeping its secret headers
  94 if test "x$GCC" = xyes; then
  95     for dir in include include-fixed; do
  96         GCC_INCLUDES=`$CC -print-file-name=$dir`
  97         if test "x$GCC_INCLUDES" != x && \
  98            test "$GCC_INCLUDES" != "$dir" && \
  99            test -d "$GCC_INCLUDES"; then
 100             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 101         fi
 102     done
 103 fi
 104 AC_SUBST([MKDEP_OPTIONS])
 105
 106 dnl Make sure the pkg-config macros are defined
 107 m4_ifndef([PKG_PROG_PKG_CONFIG],
 108     [m4_fatal([Could not locate the pkg-config autoconf macros.
 109   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 110   are in a different location, try setting the environment variable
 111   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 112 PKG_PROG_PKG_CONFIG()
 113
 114 dnl LIB_DIR - library basename
 115 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 116 AC_SUBST([LIB_DIR])
 117
 118 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 119 _SAVE_LDFLAGS="$LDFLAGS"
 120 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 121 AC_SUBST([EXTRA_LIB_PATH])
 122
 123 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 124 _SAVE_CPPFLAGS="$CPPFLAGS"
 125 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 126 AC_SUBST([X11_INCLUDES])
 127
 128 dnl Compiler macros
 129 DEFINES=""
 130 AC_SUBST([DEFINES])
 131 case "$host_os" in
 132 linux*|*-gnu*|gnu*)
 133     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 134     ;;
 135 solaris*)
 136     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 137     ;;
 138 cygwin*)
 139     DEFINES="$DEFINES -DPTHREADS"
 140     ;;
 141 esac
 142
 143 dnl Add flags for gcc and g++
 144 if test "x$GCC" = xyes; then
 145     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99"
 146     if test "x$CLANG" = "xno"; then
 147        CFLAGS="$CFLAGS -ffast-math"
 148     fi
 149
 150     # Enable -fvisibility=hidden if using a gcc that supports it
 151     save_CFLAGS="$CFLAGS"
 152     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 153     CFLAGS="$CFLAGS -fvisibility=hidden"
 154     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 155                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 156
 157     # Work around aliasing bugs - developers should comment this out
 158     CFLAGS="$CFLAGS -fno-strict-aliasing"
 159 fi
 160 if test "x$GXX" = xyes; then
 161     CXXFLAGS="$CXXFLAGS -Wall"
 162
 163     # Enable -fvisibility=hidden if using a gcc that supports it
 164     save_CXXFLAGS="$CXXFLAGS"
 165     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 166     CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
 167     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 168                    [CXXFLAGS="$save_CXXFLAGS" ; AC_MSG_RESULT([no])]);
 169
 170     # Work around aliasing bugs - developers should comment this out
 171     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 172 fi
 173
 174 dnl These should be unnecessary, but let the user set them if they want
 175 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 176     Default is to use CFLAGS.])
 177 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 178     compiler. Default is to use CFLAGS.])
 179 AC_SUBST([OPT_FLAGS])
 180 AC_SUBST([ARCH_FLAGS])
 181
 182 dnl
 183 dnl Hacks to enable 32 or 64 bit build
 184 dnl
 185 AC_ARG_ENABLE([32-bit],
 186     [AS_HELP_STRING([--enable-32-bit],
 187         [build 32-bit libraries @<:@default=auto@:>@])],
 188     [enable_32bit="$enableval"],
 189     [enable_32bit=auto]
 190 )
 191 if test "x$enable_32bit" = xyes; then
 192     if test "x$GCC" = xyes; then
 193         CFLAGS="$CFLAGS -m32"
 194         ARCH_FLAGS="$ARCH_FLAGS -m32"
 195     fi
 196     if test "x$GXX" = xyes; then
 197         CXXFLAGS="$CXXFLAGS -m32"
 198     fi
 199 fi
 200 AC_ARG_ENABLE([64-bit],
 201     [AS_HELP_STRING([--enable-64-bit],
 202         [build 64-bit libraries @<:@default=auto@:>@])],
 203     [enable_64bit="$enableval"],
 204     [enable_64bit=auto]
 205 )
 206 if test "x$enable_64bit" = xyes; then
 207     if test "x$GCC" = xyes; then
 208         CFLAGS="$CFLAGS -m64"
 209     fi
 210     if test "x$GXX" = xyes; then
 211         CXXFLAGS="$CXXFLAGS -m64"
 212     fi
 213 fi
 214
 215 dnl
 216 dnl shared/static libraries, mimic libtool options
 217 dnl
 218 AC_ARG_ENABLE([static],
 219     [AS_HELP_STRING([--enable-static],
 220         [build static libraries @<:@default=disabled@:>@])],
 221     [enable_static="$enableval"],
 222     [enable_static=no]
 223 )
 224 case "x$enable_static" in
 225 xyes|xno ) ;;
 226 x ) enable_static=no ;;
 227 * )
 228     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 229     ;;
 230 esac
 231 AC_ARG_ENABLE([shared],
 232     [AS_HELP_STRING([--disable-shared],
 233         [build shared libraries @<:@default=enabled@:>@])],
 234     [enable_shared="$enableval"],
 235     [enable_shared=yes]
 236 )
 237 case "x$enable_shared" in
 238 xyes|xno ) ;;
 239 x ) enable_shared=yes ;;
 240 * )
 241     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 242     ;;
 243 esac
 244
 245 dnl Can't have static and shared libraries, default to static if user
 246 dnl explicitly requested. If both disabled, set to static since shared
 247 dnl was explicitly requirested.
 248 case "x$enable_static$enable_shared" in
 249 xyesyes )
 250     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 251     enable_shared=no
 252     ;;
 253 xnono )
 254     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 255     enable_static=yes
 256     ;;
 257 esac
 258
 259 dnl
 260 dnl mklib options
 261 dnl
 262 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 263 if test "$enable_static" = yes; then
 264     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 265 fi
 266 AC_SUBST([MKLIB_OPTIONS])
 267
 268 dnl
 269 dnl other compiler options
 270 dnl
 271 AC_ARG_ENABLE([debug],
 272     [AS_HELP_STRING([--enable-debug],
 273         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 274     [enable_debug="$enableval"],
 275     [enable_debug=no]
 276 )
 277 if test "x$enable_debug" = xyes; then
 278     DEFINES="$DEFINES -DDEBUG"
 279     if test "x$GCC" = xyes; then
 280         CFLAGS="$CFLAGS -g"
 281     fi
 282     if test "x$GXX" = xyes; then
 283         CXXFLAGS="$CXXFLAGS -g"
 284     fi
 285 fi
 286
 287 dnl
 288 dnl library names
 289 dnl
 290 LIB_PREFIX_GLOB='lib'
 291 LIB_VERSION_SEPARATOR='.'
 292 if test "$enable_static" = yes; then
 293     LIB_EXTENSION='a'
 294 else
 295     case "$host_os" in
 296     darwin* )
 297         LIB_EXTENSION='dylib' ;;
 298     cygwin* )
 299         dnl prefix can be 'cyg' or 'lib'
 300         LIB_PREFIX_GLOB='???'
 301         LIB_VERSION_SEPARATOR='-'
 302         LIB_EXTENSION='dll' ;;
 303     aix* )
 304         LIB_EXTENSION='a' ;;
 305     * )
 306         LIB_EXTENSION='so' ;;
 307     esac
 308 fi
 309
 310 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 311 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 312 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 313 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 314 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 315 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 316 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 317 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 318 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 319
 320 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 321 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 322 GLUT_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLUT_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 323 GLW_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLW_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 324 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 325 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 326 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 327 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 328 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 329 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 330
 331 AC_SUBST([GL_LIB_NAME])
 332 AC_SUBST([GLU_LIB_NAME])
 333 AC_SUBST([GLUT_LIB_NAME])
 334 AC_SUBST([GLW_LIB_NAME])
 335 AC_SUBST([OSMESA_LIB_NAME])
 336 AC_SUBST([EGL_LIB_NAME])
 337 AC_SUBST([GLESv1_CM_LIB_NAME])
 338 AC_SUBST([GLESv2_LIB_NAME])
 339 AC_SUBST([VG_LIB_NAME])
 340
 341 AC_SUBST([GL_LIB_GLOB])
 342 AC_SUBST([GLU_LIB_GLOB])
 343 AC_SUBST([GLUT_LIB_GLOB])
 344 AC_SUBST([GLW_LIB_GLOB])
 345 AC_SUBST([OSMESA_LIB_GLOB])
 346 AC_SUBST([EGL_LIB_GLOB])
 347 AC_SUBST([GLESv1_CM_LIB_GLOB])
 348 AC_SUBST([GLESv2_LIB_GLOB])
 349 AC_SUBST([VG_LIB_GLOB])
 350
 351 dnl
 352 dnl Arch/platform-specific settings
 353 dnl
 354 AC_ARG_ENABLE([asm],
 355     [AS_HELP_STRING([--disable-asm],
 356         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 357     [enable_asm="$enableval"],
 358     [enable_asm=yes]
 359 )
 360 asm_arch=""
 361 ASM_FLAGS=""
 362 MESA_ASM_SOURCES=""
 363 GLAPI_ASM_SOURCES=""
 364 AC_MSG_CHECKING([whether to enable assembly])
 365 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 366 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 367 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 368     case "$host_cpu" in
 369     i?86 | x86_64)
 370         enable_asm=no
 371         AC_MSG_RESULT([no, cross compiling])
 372         ;;
 373     esac
 374 fi
 375 # check for supported arches
 376 if test "x$enable_asm" = xyes; then
 377     case "$host_cpu" in
 378     i?86)
 379         case "$host_os" in
 380         linux* | *freebsd* | dragonfly*)
 381             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 382             ;;
 383         esac
 384         ;;
 385     x86_64)
 386         case "$host_os" in
 387         linux* | *freebsd* | dragonfly*)
 388             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 389             ;;
 390         esac
 391         ;;
 392     powerpc)
 393         case "$host_os" in
 394         linux*)
 395             asm_arch=ppc
 396             ;;
 397         esac
 398         ;;
 399     sparc*)
 400         case "$host_os" in
 401         linux*)
 402             asm_arch=sparc
 403             ;;
 404         esac
 405         ;;
 406     esac
 407
 408     case "$asm_arch" in
 409     x86)
 410         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 411         MESA_ASM_SOURCES='$(X86_SOURCES)'
 412         GLAPI_ASM_SOURCES='$(X86_API)'
 413         AC_MSG_RESULT([yes, x86])
 414         ;;
 415     x86_64)
 416         ASM_FLAGS="-DUSE_X86_64_ASM"
 417         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 418         GLAPI_ASM_SOURCES='$(X86-64_API)'
 419         AC_MSG_RESULT([yes, x86_64])
 420         ;;
 421     ppc)
 422         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 423         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 424         AC_MSG_RESULT([yes, ppc])
 425         ;;
 426     sparc)
 427         ASM_FLAGS="-DUSE_SPARC_ASM"
 428         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 429         GLAPI_ASM_SOURCES='$(SPARC_API)'
 430         AC_MSG_RESULT([yes, sparc])
 431         ;;
 432     *)
 433         AC_MSG_RESULT([no, platform not supported])
 434         ;;
 435     esac
 436 fi
 437 AC_SUBST([ASM_FLAGS])
 438 AC_SUBST([MESA_ASM_SOURCES])
 439 AC_SUBST([GLAPI_ASM_SOURCES])
 440
 441 dnl PIC code macro
 442 MESA_PIC_FLAGS
 443
 444 dnl Check to see if dlopen is in default libraries (like Solaris, which
 445 dnl has it in libc), or if libdl is needed to get it.
 446 AC_CHECK_FUNC([dlopen], [],
 447     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 448 AC_SUBST([DLOPEN_LIBS])
 449
 450 dnl See if posix_memalign is available
 451 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 452
 453 dnl SELinux awareness.
 454 AC_ARG_ENABLE([selinux],
 455     [AS_HELP_STRING([--enable-selinux],
 456         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 457     [MESA_SELINUX="$enableval"],
 458     [MESA_SELINUX=no])
 459 if test "x$enable_selinux" = "xyes"; then
 460     AC_CHECK_HEADER([selinux/selinux.h],[],
 461                     [AC_MSG_ERROR([SELinux headers not found])])
 462     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 463                  [AC_MSG_ERROR([SELinux library not found])])
 464     SELINUX_LIBS="-lselinux"
 465     DEFINES="$DEFINES -DMESA_SELINUX"
 466 fi
 467
 468 dnl Determine which APIs to support
 469 AC_ARG_ENABLE([opengl],
 470     [AS_HELP_STRING([--disable-opengl],
 471         [disable support for standard OpenGL API @<:@default=no@:>@])],
 472     [enable_opengl="$enableval"],
 473     [enable_opengl=yes])
 474 AC_ARG_ENABLE([gles1],
 475     [AS_HELP_STRING([--enable-gles1],
 476         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 477     [enable_gles1="$enableval"],
 478     [enable_gles1=no])
 479 AC_ARG_ENABLE([gles2],
 480     [AS_HELP_STRING([--enable-gles2],
 481         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 482     [enable_gles2="$enableval"],
 483     [enable_gles2=no])
 484 AC_ARG_ENABLE([gles-overlay],
 485     [AS_HELP_STRING([--enable-gles-overlay],
 486         [build separate OpenGL ES only libraries @<:@default=no@:>@])],
 487     [enable_gles_overlay="$enableval"],
 488     [enable_gles_overlay=no])
 489
 490 AC_ARG_ENABLE([openvg],
 491     [AS_HELP_STRING([--enable-openvg],
 492         [enable support for OpenVG API @<:@default=no@:>@])],
 493     [enable_openvg="$enableval"],
 494     [enable_openvg=no])
 495
 496 dnl smooth the transition; should be removed eventually
 497 if test "x$enable_openvg" = xno; then
 498     case "x$with_state_trackers" in
 499     x*vega*)
 500         AC_MSG_WARN([vega state tracker is enabled without --enable-openvg])
 501         enable_openvg=yes
 502         ;;
 503     esac
 504 fi
 505
 506 if test "x$enable_opengl" = xno -a \
 507         "x$enable_gles1" = xno -a \
 508         "x$enable_gles2" = xno -a \
 509         "x$enable_gles_overlay" = xno -a \
 510         "x$enable_openvg" = xno; then
 511     AC_MSG_ERROR([at least one API should be enabled])
 512 fi
 513
 514 API_DEFINES=""
 515 GLES_OVERLAY=0
 516 if test "x$enable_opengl" = xno; then
 517     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 518 else
 519     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 520 fi
 521 if test "x$enable_gles1" = xyes; then
 522     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 523 fi
 524 if test "x$enable_gles2" = xyes; then
 525     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 526 fi
 527 if test "x$enable_gles_overlay" = xyes; then
 528     GLES_OVERLAY=1
 529 fi
 530 AC_SUBST([API_DEFINES])
 531 AC_SUBST([GLES_OVERLAY])
 532
 533 dnl
 534 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 535 dnl More later: fbdev, ...
 536 dnl
 537 default_driver="xlib"
 538
 539 case "$host_os" in
 540 linux*)
 541     case "$host_cpu" in
 542     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 543     esac
 544     ;;
 545 *freebsd* | dragonfly*)
 546     case "$host_cpu" in
 547     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 548     esac
 549     ;;
 550 esac
 551
 552 if test "x$enable_opengl" = xno; then
 553     default_driver="no"
 554 fi
 555
 556 AC_ARG_WITH([driver],
 557     [AS_HELP_STRING([--with-driver=DRIVER],
 558         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 559     [mesa_driver="$withval"],
 560     [mesa_driver="$default_driver"])
 561 dnl Check for valid option
 562 case "x$mesa_driver" in
 563 xxlib|xdri|xosmesa)
 564     if test "x$enable_opengl" = xno; then
 565         AC_MSG_ERROR([Driver '$mesa_driver' requires OpenGL enabled])
 566     fi
 567     ;;
 568 xno)
 569     ;;
 570 *)
 571     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 572     ;;
 573 esac
 574
 575 PKG_CHECK_MODULES([TALLOC], [talloc])
 576 AC_SUBST([TALLOC_LIBS])
 577 AC_SUBST([TALLOC_CFLAGS])
 578
 579 dnl
 580 dnl Driver specific build directories
 581 dnl
 582
 583 dnl this variable will be prepended to SRC_DIRS and is not exported
 584 CORE_DIRS=""
 585
 586 SRC_DIRS=""
 587 GLU_DIRS="sgi"
 588 GALLIUM_DIRS="auxiliary drivers state_trackers"
 589 GALLIUM_TARGET_DIRS=""
 590 GALLIUM_WINSYS_DIRS="sw"
 591 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug identity"
 592 GALLIUM_STATE_TRACKERS_DIRS=""
 593
 594 # build glapi if OpenGL is enabled
 595 if test "x$enable_opengl" = xyes; then
 596     CORE_DIRS="$CORE_DIRS mapi/glapi"
 597 fi
 598
 599 # build es1api and es2api if OpenGL ES is enabled
 600 case "x$enable_gles1$enable_gles2$enable_gles_overlay" in
 601 x*yes*)
 602     CORE_DIRS="$CORE_DIRS mapi/es1api mapi/es2api"
 603     ;;
 604 esac
 605
 606 # build vgapi if OpenVG is enabled
 607 if test "x$enable_openvg" = xyes; then
 608     CORE_DIRS="$CORE_DIRS mapi/vgapi"
 609 fi
 610
 611 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 612 case "x$enable_opengl$enable_gles1$enable_gles2$enable_gles_overlay" in
 613 x*yes*)
 614     CORE_DIRS="$CORE_DIRS glsl mesa"
 615     ;;
 616 esac
 617
 618 case "$mesa_driver" in
 619 xlib)
 620     DRIVER_DIRS="x11"
 621     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 622     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 623     ;;
 624 dri)
 625     SRC_DIRS="$SRC_DIRS glx"
 626     DRIVER_DIRS="dri"
 627     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 628     ;;
 629 osmesa)
 630     DRIVER_DIRS="osmesa"
 631     ;;
 632 no)
 633     DRIVER_DRIS=""
 634     ;;
 635 esac
 636 AC_SUBST([SRC_DIRS])
 637 AC_SUBST([GLU_DIRS])
 638 AC_SUBST([DRIVER_DIRS])
 639 AC_SUBST([GALLIUM_DIRS])
 640 AC_SUBST([GALLIUM_TARGET_DIRS])
 641 AC_SUBST([GALLIUM_WINSYS_DIRS])
 642 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 643 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 644 AC_SUBST([MESA_LLVM])
 645
 646 dnl
 647 dnl Find out if X is available. The variable have_x is set if libX11 is
 648 dnl found to mimic AC_PATH_XTRA.
 649 dnl
 650 if test -n "$PKG_CONFIG"; then
 651     AC_MSG_CHECKING([pkg-config files for X11 are available])
 652     PKG_CHECK_EXISTS([x11],[
 653         x11_pkgconfig=yes
 654         have_x=yes
 655         ],[
 656         x11_pkgconfig=no
 657     ])
 658     AC_MSG_RESULT([$x11_pkgconfig])
 659 else
 660     x11_pkgconfig=no
 661 fi
 662 dnl Use the autoconf macro if no pkg-config files
 663 if test "$x11_pkgconfig" = yes; then
 664     PKG_CHECK_MODULES([X11], [x11])
 665 else
 666     AC_PATH_XTRA
 667     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 668     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 669     AC_SUBST([X11_CFLAGS])
 670     AC_SUBST([X11_LIBS])
 671 fi
 672
 673 dnl Try to tell the user that the --x-* options are only used when
 674 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 675 m4_divert_once([HELP_BEGIN],
 676 [These options are only used when the X libraries cannot be found by the
 677 pkg-config utility.])
 678
 679 dnl We need X for xlib and dri, so bomb now if it's not found
 680 case "$mesa_driver" in
 681 xlib|dri)
 682     if test "$no_x" = yes; then
 683         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 684     fi
 685     ;;
 686 esac
 687
 688 dnl XCB - this is only used for GLX right now
 689 AC_ARG_ENABLE([xcb],
 690     [AS_HELP_STRING([--enable-xcb],
 691         [use XCB for GLX @<:@default=disabled@:>@])],
 692     [enable_xcb="$enableval"],
 693     [enable_xcb=no])
 694 if test "x$enable_xcb" = xyes; then
 695     DEFINES="$DEFINES -DUSE_XCB"
 696 else
 697     enable_xcb=no
 698 fi
 699
 700 dnl
 701 dnl libGL configuration per driver
 702 dnl
 703 case "$mesa_driver" in
 704 xlib)
 705     if test "$x11_pkgconfig" = yes; then
 706         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 707         GL_PC_REQ_PRIV="x11 xext"
 708         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 709         GL_LIB_DEPS="$XLIBGL_LIBS"
 710     else
 711         # should check these...
 712         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 713         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 714         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 715         GL_PC_CFLAGS="$X11_INCLUDES"
 716     fi
 717     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 718     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 719
 720     # if static, move the external libraries to the programs
 721     # and empty the libraries for libGL
 722     if test "$enable_static" = yes; then
 723         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 724         GL_LIB_DEPS=""
 725     fi
 726     ;;
 727 dri|no) # these checks are still desired when there is no mesa_driver
 728     # DRI must be shared, I think
 729     if test "$enable_static" = yes; then
 730         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 731     fi
 732
 733     # Check for libdrm
 734     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 735     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 736     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 737     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 738     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 739
 740     # find the DRI deps for libGL
 741     if test "$x11_pkgconfig" = yes; then
 742         dri_modules="x11 xext xdamage xfixes"
 743
 744         # add xf86vidmode if available
 745         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 746         if test "$HAVE_XF86VIDMODE" = yes ; then
 747             dri_modules="$dri_modules xxf86vm"
 748         fi
 749
 750         # add xcb modules if necessary
 751         if test "$enable_xcb" = yes; then
 752             dri_modules="$dri_modules x11-xcb xcb-glx"
 753         fi
 754
 755         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 756         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 757         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 758         GL_LIB_DEPS="$DRIGL_LIBS"
 759     else
 760         # should check these...
 761         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 762         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 763         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 764         GL_PC_CFLAGS="$X11_INCLUDES"
 765
 766         # XCB can only be used from pkg-config
 767         if test "$enable_xcb" = yes; then
 768             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 769             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 770             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 771             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 772         fi
 773     fi
 774
 775     # need DRM libs, -lpthread, etc.
 776     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 777     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 778     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 779     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 780     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 781     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 782     ;;
 783 osmesa)
 784     # No libGL for osmesa
 785     GL_LIB_DEPS=""
 786     ;;
 787 esac
 788 AC_SUBST([GL_LIB_DEPS])
 789 AC_SUBST([GL_PC_REQ_PRIV])
 790 AC_SUBST([GL_PC_LIB_PRIV])
 791 AC_SUBST([GL_PC_CFLAGS])
 792 AC_SUBST([DRI_PC_REQ_PRIV])
 793 AC_SUBST([GLESv1_CM_LIB_DEPS])
 794 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 795 AC_SUBST([GLESv2_LIB_DEPS])
 796 AC_SUBST([GLESv2_PC_LIB_PRIV])
 797
 798
 799 AC_SUBST([HAVE_XF86VIDMODE])
 800
 801 PKG_CHECK_MODULES([LIBDRM_RADEON],
 802                   [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 803                   HAVE_LIBDRM_RADEON=yes,
 804                   HAVE_LIBDRM_RADEON=no)
 805
 806 dnl
 807 dnl More X11 setup
 808 dnl
 809 if test "$mesa_driver" = xlib; then
 810     DEFINES="$DEFINES -DUSE_XSHM"
 811 fi
 812
 813 dnl
 814 dnl More DRI setup
 815 dnl
 816 AC_ARG_ENABLE([glx-tls],
 817     [AS_HELP_STRING([--enable-glx-tls],
 818         [enable TLS support in GLX @<:@default=disabled@:>@])],
 819     [GLX_USE_TLS="$enableval"],
 820     [GLX_USE_TLS=no])
 821 dnl Directory for DRI drivers
 822 AC_ARG_WITH([dri-driverdir],
 823     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 824         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 825     [DRI_DRIVER_INSTALL_DIR="$withval"],
 826     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 827 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 828 dnl Extra search path for DRI drivers
 829 AC_ARG_WITH([dri-searchpath],
 830     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 831         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 832     [DRI_DRIVER_SEARCH_DIR="$withval"],
 833     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 834 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 835 dnl Direct rendering or just indirect rendering
 836 AC_ARG_ENABLE([driglx-direct],
 837     [AS_HELP_STRING([--disable-driglx-direct],
 838         [enable direct rendering in GLX and EGL for DRI @<:@default=enabled@:>@])],
 839     [driglx_direct="$enableval"],
 840     [driglx_direct="yes"])
 841 dnl Which drivers to build - default is chosen by platform
 842 AC_ARG_WITH([dri-drivers],
 843     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 844         [comma delimited DRI drivers list, e.g.
 845         "swrast,i965,radeon" @<:@default=auto@:>@])],
 846     [with_dri_drivers="$withval"],
 847     [with_dri_drivers=yes])
 848 if test "x$with_dri_drivers" = x; then
 849     with_dri_drivers=no
 850 fi
 851
 852 dnl If $with_dri_drivers is yes, directories will be added through
 853 dnl platform checks
 854 DRI_DIRS=""
 855 case "$with_dri_drivers" in
 856 no) ;;
 857 yes)
 858     DRI_DIRS="yes"
 859     ;;
 860 *)
 861     # verify the requested driver directories exist
 862     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 863     for driver in $dri_drivers; do
 864         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 865             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 866     done
 867     DRI_DIRS="$dri_drivers"
 868     ;;
 869 esac
 870
 871 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 872 if test "$mesa_driver" = dri -o "$mesa_driver" = no; then
 873     # Use TLS in GLX?
 874     if test "x$GLX_USE_TLS" = xyes; then
 875         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 876     fi
 877
 878     # Platform specific settings and drivers to build
 879     case "$host_os" in
 880     linux*)
 881         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 882         if test "x$driglx_direct" = xyes; then
 883             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 884         fi
 885         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 886
 887         case "$host_cpu" in
 888         x86_64)
 889             # sis is missing because they have not be converted to use
 890             # the new interface.  i810 are missing because there is no
 891             # x86-64 system where they could *ever* be used.
 892             if test "x$DRI_DIRS" = "xyes"; then
 893                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 894                     savage tdfx unichrome swrast"
 895             fi
 896             ;;
 897         powerpc*)
 898             # Build only the drivers for cards that exist on PowerPC.
 899             # At some point MGA will be added, but not yet.
 900             if test "x$DRI_DIRS" = "xyes"; then
 901                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 902             fi
 903             ;;
 904         sparc*)
 905             # Build only the drivers for cards that exist on sparc`
 906             if test "x$DRI_DIRS" = "xyes"; then
 907                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 908             fi
 909             ;;
 910         esac
 911         ;;
 912     freebsd* | dragonfly*)
 913         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 914         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 915         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 916         if test "x$driglx_direct" = xyes; then
 917             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 918         fi
 919         if test "x$GXX" = xyes; then
 920             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 921         fi
 922
 923         if test "x$DRI_DIRS" = "xyes"; then
 924             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 925                 unichrome savage sis swrast"
 926         fi
 927         ;;
 928     gnu*)
 929         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 930         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 931         ;;
 932     solaris*)
 933         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 934         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 935         if test "x$driglx_direct" = xyes; then
 936             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 937         fi
 938         ;;
 939     esac
 940
 941     # default drivers
 942     if test "x$DRI_DIRS" = "xyes"; then
 943         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 944             savage sis tdfx unichrome swrast"
 945     fi
 946
 947     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 948
 949     # Check for expat
 950     if test "$mesa_driver" = dri; then
 951         EXPAT_INCLUDES=""
 952         EXPAT_LIB=-lexpat
 953         AC_ARG_WITH([expat],
 954             [AS_HELP_STRING([--with-expat=DIR],
 955                 [expat install directory])],[
 956             EXPAT_INCLUDES="-I$withval/include"
 957             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 958             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 959             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 960             ])
 961         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 962         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 963             [AC_MSG_ERROR([Expat required for DRI.])])
 964     fi
 965
 966     # put all the necessary libs together
 967     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS $TALLOC_LIBS"
 968 fi
 969 AC_SUBST([DRI_DIRS])
 970 AC_SUBST([EXPAT_INCLUDES])
 971 AC_SUBST([DRI_LIB_DEPS])
 972
 973 case $DRI_DIRS in
 974 *i915*|*i965*)
 975     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.21])
 976     ;;
 977 esac
 978
 979 case $DRI_DIRS in
 980 *radeon*|*r200*|*r300*|*r600*)
 981     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
 982         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 983         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 984     fi
 985     ;;
 986 esac
 987 AC_SUBST([RADEON_CFLAGS])
 988 AC_SUBST([RADEON_LDFLAGS])
 989
 990
 991 dnl
 992 dnl OSMesa configuration
 993 dnl
 994 if test "$mesa_driver" = xlib; then
 995     default_gl_osmesa=yes
 996 else
 997     default_gl_osmesa=no
 998 fi
 999 AC_ARG_ENABLE([gl-osmesa],
1000     [AS_HELP_STRING([--enable-gl-osmesa],
1001         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
1002     [gl_osmesa="$enableval"],
1003     [gl_osmesa="$default_gl_osmesa"])
1004 if test "x$gl_osmesa" = xyes; then
1005     if test "x$enable_opengl" = xno; then
1006         AC_MSG_ERROR([OpenGL is not available for OSMesa driver])
1007     fi
1008     if test "$mesa_driver" = osmesa; then
1009         AC_MSG_ERROR([libGL is not available for OSMesa driver])
1010     else
1011         DRIVER_DIRS="$DRIVER_DIRS osmesa"
1012     fi
1013 fi
1014
1015 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1016 AC_ARG_WITH([osmesa-bits],
1017     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1018         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1019     [osmesa_bits="$withval"],
1020     [osmesa_bits=8])
1021 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
1022     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
1023     osmesa_bits=8
1024 fi
1025 case "x$osmesa_bits" in
1026 x8)
1027     OSMESA_LIB=OSMesa
1028     ;;
1029 x16|x32)
1030     OSMESA_LIB="OSMesa$osmesa_bits"
1031     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1032     ;;
1033 *)
1034     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1035     ;;
1036 esac
1037 AC_SUBST([OSMESA_LIB])
1038
1039 case "$DRIVER_DIRS" in
1040 *osmesa*)
1041     # only link libraries with osmesa if shared
1042     if test "$enable_static" = no; then
1043         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1044     else
1045         OSMESA_LIB_DEPS=""
1046     fi
1047     OSMESA_MESA_DEPS=""
1048     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1049     ;;
1050 esac
1051 AC_SUBST([OSMESA_LIB_DEPS])
1052 AC_SUBST([OSMESA_MESA_DEPS])
1053 AC_SUBST([OSMESA_PC_REQ])
1054 AC_SUBST([OSMESA_PC_LIB_PRIV])
1055
1056 dnl
1057 dnl EGL configuration
1058 dnl
1059 AC_ARG_ENABLE([egl],
1060     [AS_HELP_STRING([--disable-egl],
1061         [disable EGL library @<:@default=enabled@:>@])],
1062     [enable_egl="$enableval"],
1063     [enable_egl=yes])
1064 if test "x$enable_egl" = xno; then
1065     if test "x$mesa_driver" = xno; then
1066         AC_MSG_ERROR([cannot disable EGL when there is no mesa driver])
1067     fi
1068     if test "x$enable_openvg" = xyes; then
1069         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1070     fi
1071 fi
1072 if test "x$enable_egl" = xyes; then
1073     SRC_DIRS="$SRC_DIRS egl"
1074     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1075     EGL_DRIVERS_DIRS=""
1076     if test "$enable_static" != yes; then
1077         # build egl_glx when libGL is built
1078         if test "$mesa_driver" = xlib -o "$mesa_driver" = dri; then
1079             EGL_DRIVERS_DIRS="glx"
1080         fi
1081
1082         if test "$mesa_driver" = dri; then
1083             # build egl_dri2 when xcb-dri2 is available
1084             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1085                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1086             PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1087                           [have_libudev=yes],[have_libudev=no])
1088
1089             if test "$have_xcb_dri2" = yes; then
1090                 EGL_DRIVER_DRI2=dri2
1091                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1092                 if test "$have_libudev" = yes; then
1093                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1094                 fi
1095             fi
1096         fi
1097
1098         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1099     fi
1100 fi
1101 AC_SUBST([EGL_LIB_DEPS])
1102 AC_SUBST([EGL_DRIVERS_DIRS])
1103
1104 dnl
1105 dnl GLU configuration
1106 dnl
1107 AC_ARG_ENABLE([glu],
1108     [AS_HELP_STRING([--disable-glu],
1109         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1110     [enable_glu="$enableval"],
1111     [enable_glu=yes])
1112
1113 if test "x$enable_glu" = xyes -a "x$mesa_driver" = xno; then
1114     AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1115     enable_glu=no
1116 fi
1117
1118 if test "x$enable_glu" = xyes; then
1119     SRC_DIRS="$SRC_DIRS glu"
1120
1121     case "$mesa_driver" in
1122     osmesa)
1123         # Link libGLU to libOSMesa instead of libGL
1124         GLU_LIB_DEPS=""
1125         GLU_PC_REQ="osmesa"
1126         if test "$enable_static" = no; then
1127             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1128         else
1129             GLU_MESA_DEPS=""
1130         fi
1131         ;;
1132     *)
1133         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1134         GLU_PC_REQ="gl"
1135         GLU_PC_LIB_PRIV="-lm"
1136         if test "$enable_static" = no; then
1137             GLU_LIB_DEPS="-lm"
1138             GLU_MESA_DEPS='-l$(GL_LIB)'
1139         else
1140             GLU_LIB_DEPS=""
1141             GLU_MESA_DEPS=""
1142             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1143         fi
1144         ;;
1145     esac
1146 fi
1147 if test "$enable_static" = no; then
1148     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1149 fi
1150 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1151 AC_SUBST([GLU_LIB_DEPS])
1152 AC_SUBST([GLU_MESA_DEPS])
1153 AC_SUBST([GLU_PC_REQ])
1154 AC_SUBST([GLU_PC_REQ_PRIV])
1155 AC_SUBST([GLU_PC_LIB_PRIV])
1156 AC_SUBST([GLU_PC_CFLAGS])
1157
1158 dnl
1159 dnl GLw configuration
1160 dnl
1161 AC_ARG_ENABLE([glw],
1162     [AS_HELP_STRING([--disable-glw],
1163         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1164     [enable_glw="$enableval"],
1165     [enable_glw=yes])
1166 dnl Don't build GLw on osmesa
1167 if test "x$enable_glw" = xyes; then
1168     case "$mesa_driver" in
1169     osmesa|no)
1170         AC_MSG_NOTICE([Disabling GLw since there is no OpenGL driver])
1171         enable_glw=no
1172         ;;
1173     esac
1174 fi
1175 AC_ARG_ENABLE([motif],
1176     [AS_HELP_STRING([--enable-motif],
1177         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1178     [enable_motif="$enableval"],
1179     [enable_motif=no])
1180
1181 if test "x$enable_glw" = xyes; then
1182     SRC_DIRS="$SRC_DIRS glw"
1183     if test "$x11_pkgconfig" = yes; then
1184         PKG_CHECK_MODULES([GLW],[x11 xt])
1185         GLW_PC_REQ_PRIV="x11 xt"
1186         GLW_LIB_DEPS="$GLW_LIBS"
1187     else
1188         # should check these...
1189         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1190         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1191         GLW_PC_CFLAGS="$X11_INCLUDES"
1192     fi
1193
1194     GLW_SOURCES="GLwDrawA.c"
1195     MOTIF_CFLAGS=
1196     if test "x$enable_motif" = xyes; then
1197         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1198         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1199         if test "x$MOTIF_CONFIG" != xno; then
1200             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1201             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1202         else
1203             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1204                 [AC_MSG_ERROR([Can't locate Motif headers])])
1205             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1206                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1207         fi
1208         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1209         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1210         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1211         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1212     fi
1213
1214     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1215     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1216     if test "$enable_static" = no; then
1217         GLW_MESA_DEPS='-l$(GL_LIB)'
1218         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1219     else
1220         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1221         GLW_LIB_DEPS=""
1222         GLW_MESA_DEPS=""
1223     fi
1224 fi
1225 AC_SUBST([GLW_LIB_DEPS])
1226 AC_SUBST([GLW_MESA_DEPS])
1227 AC_SUBST([GLW_SOURCES])
1228 AC_SUBST([MOTIF_CFLAGS])
1229 AC_SUBST([GLW_PC_REQ_PRIV])
1230 AC_SUBST([GLW_PC_LIB_PRIV])
1231 AC_SUBST([GLW_PC_CFLAGS])
1232
1233 dnl
1234 dnl GLUT configuration
1235 dnl
1236 if test -f "$srcdir/include/GL/glut.h"; then
1237     default_glut=yes
1238 else
1239     default_glut=no
1240 fi
1241 AC_ARG_ENABLE([glut],
1242     [AS_HELP_STRING([--disable-glut],
1243         [enable GLUT library @<:@default=enabled if source available@:>@])],
1244     [enable_glut="$enableval"],
1245     [enable_glut="$default_glut"])
1246
1247 dnl Don't build glut on osmesa
1248 if test "x$enable_glut" = xyes; then
1249     case "$mesa_driver" in
1250     osmesa|no)
1251         AC_MSG_NOTICE([Disabling glut since there is no OpenGL driver])
1252         enable_glut=no
1253         ;;
1254     esac
1255 fi
1256 dnl Can't build glut if GLU not available
1257 if test "x$enable_glu$enable_glut" = xnoyes; then
1258     AC_MSG_WARN([Disabling glut since GLU is disabled])
1259     enable_glut=no
1260 fi
1261
1262 if test "x$enable_glut" = xyes; then
1263     SRC_DIRS="$SRC_DIRS glut/glx"
1264     if test "$x11_pkgconfig" = yes; then
1265         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1266         GLUT_PC_REQ_PRIV="x11 xmu xi"
1267         GLUT_LIB_DEPS="$GLUT_LIBS"
1268     else
1269         # should check these...
1270         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1271         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1272         GLUT_PC_CFLAGS="$X11_INCLUDES"
1273     fi
1274     if test "x$GCC" = xyes; then
1275         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1276     fi
1277     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1278     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1279
1280     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1281     if test "$enable_static" = no; then
1282         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1283     else
1284         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1285         GLUT_LIB_DEPS=""
1286         GLUT_MESA_DEPS=""
1287     fi
1288 fi
1289 AC_SUBST([GLUT_LIB_DEPS])
1290 AC_SUBST([GLUT_MESA_DEPS])
1291 AC_SUBST([GLUT_CFLAGS])
1292 AC_SUBST([GLUT_PC_REQ_PRIV])
1293 AC_SUBST([GLUT_PC_LIB_PRIV])
1294 AC_SUBST([GLUT_PC_CFLAGS])
1295
1296 dnl
1297 dnl Program library dependencies
1298 dnl    Only libm is added here if necessary as the libraries should
1299 dnl    be pulled in by the linker
1300 dnl
1301 if test "x$APP_LIB_DEPS" = x; then
1302     case "$host_os" in
1303     solaris*)
1304         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1305         ;;
1306     cygwin*)
1307         APP_LIB_DEPS="-lX11"
1308         ;;
1309     *)
1310         APP_LIB_DEPS="-lm"
1311         ;;
1312     esac
1313 fi
1314 AC_SUBST([APP_LIB_DEPS])
1315 AC_SUBST([PROGRAM_DIRS])
1316
1317 dnl
1318 dnl Gallium configuration
1319 dnl
1320 AC_ARG_ENABLE([gallium],
1321     [AS_HELP_STRING([--disable-gallium],
1322         [build gallium @<:@default=enabled@:>@])],
1323     [enable_gallium="$enableval"],
1324     [enable_gallium=yes])
1325 if test "x$enable_gallium" = xno -a "x$enable_openvg" = xyes; then
1326     AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1327 fi
1328 if test "x$enable_gallium" = xyes; then
1329     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1330     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1331                 [HAS_UDIS86="no"])
1332     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1333 fi
1334
1335 AC_SUBST([LLVM_CFLAGS])
1336 AC_SUBST([LLVM_LIBS])
1337 AC_SUBST([LLVM_LDFLAGS])
1338 AC_SUBST([LLVM_VERSION])
1339
1340 dnl
1341 dnl Gallium state trackers configuration
1342 dnl
1343 AC_ARG_WITH([state-trackers],
1344     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1345         [comma delimited state_trackers list, e.g.
1346         "egl,glx" @<:@default=auto@:>@])],
1347     [with_state_trackers="$withval"],
1348     [with_state_trackers=yes])
1349
1350 case "$with_state_trackers" in
1351 no)
1352     GALLIUM_STATE_TRACKERS_DIRS=""
1353     ;;
1354 yes)
1355     st_egl="no"
1356
1357     # look at what else is built
1358     case "$mesa_driver" in
1359     xlib)
1360         GALLIUM_STATE_TRACKERS_DIRS=glx
1361         ;;
1362     dri)
1363         GALLIUM_STATE_TRACKERS_DIRS="dri"
1364         HAVE_ST_DRI="yes"
1365         st_egl="yes"
1366         # Have only tested st/xorg on 1.6.0 servers
1367         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1368             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1369             HAVE_ST_XORG="no")
1370         ;;
1371     no)
1372         st_egl="yes"
1373     esac
1374
1375     if test "x$enable_egl" = xyes; then
1376         if test "$enable_openvg" = yes; then
1377             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vega"
1378             st_egl="yes"
1379         fi
1380
1381         if test "$st_egl" = yes; then
1382             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1383             HAVE_ST_EGL="yes"
1384         fi
1385     fi
1386     ;;
1387 *)
1388     # verify the requested state tracker exist
1389     state_trackers=""
1390     _state_trackers=`IFS=', '; echo $with_state_trackers`
1391     for tracker in $_state_trackers; do
1392         case "$tracker" in
1393         dri)
1394             if test "x$mesa_driver" != xdri; then
1395                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1396             fi
1397             HAVE_ST_DRI="yes"
1398             ;;
1399         egl)
1400             if test "x$enable_egl" != xyes; then
1401                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1402             fi
1403             HAVE_ST_EGL="yes"
1404             ;;
1405         xorg)
1406             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1407             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1408             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1409             HAVE_ST_XORG="yes"
1410             ;;
1411         vega)
1412             if test "x$enable_openvg" != xyes; then
1413                 AC_MSG_ERROR([cannot build vega state tracker without --enable-openvg])
1414             fi
1415             ;;
1416         esac
1417
1418         if test -n "$tracker"; then
1419             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1420                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1421             if test -n "$state_trackers"; then
1422                 state_trackers="$state_trackers $tracker"
1423             else
1424                 state_trackers="$tracker"
1425             fi
1426         fi
1427     done
1428     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1429     ;;
1430 esac
1431
1432
1433 EGL_CLIENT_APIS=""
1434 VG_LIB_DEPS=""
1435
1436 case "x$enable_opengl$enable_gles1$enable_gles2" in
1437 x*yes*)
1438     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1439     ;;
1440 esac
1441 if test "x$enable_gles_overlay" = xyes; then
1442     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1443 fi
1444 if test "x$enable_openvg" = xyes; then
1445     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1446     VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1447 fi
1448
1449 AC_SUBST([VG_LIB_DEPS])
1450 AC_SUBST([EGL_CLIENT_APIS])
1451
1452 if test "x$HAVE_ST_EGL" = xyes; then
1453         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1454         # define GLX_DIRECT_RENDERING even when the driver is not dri
1455         if test "x$mesa_driver" != xdri -a "x$driglx_direct" = xyes; then
1456             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1457         fi
1458 fi
1459
1460 if test "x$HAVE_ST_XORG" = xyes; then
1461     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1462         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1463         HAVE_XEXTPROTO_71="no")
1464 fi
1465
1466 AC_ARG_WITH([egl-platforms],
1467     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1468         [comma delimited native platforms libEGL supports, e.g.
1469         "x11,drm" @<:@default=auto@:>@])],
1470     [with_egl_platforms="$withval"],
1471     [with_egl_platforms=yes])
1472 AC_ARG_WITH([egl-displays],
1473     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1474         [DEPRECATED.  Use --with-egl-platforms instead])],
1475     [with_egl_platforms="$withval"])
1476
1477 EGL_PLATFORMS=""
1478 case "$with_egl_platforms" in
1479 yes)
1480     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1481         EGL_PLATFORMS="x11"
1482         if test "$mesa_driver" = dri; then
1483             EGL_PLATFORMS="$EGL_PLATFORMS drm"
1484         fi
1485     fi
1486     ;;
1487 *)
1488     if test "x$enable_egl" != xyes; then
1489         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1490     fi
1491     # verify the requested driver directories exist
1492     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1493     for plat in $egl_platforms; do
1494         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1495             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1496         if test "$plat" = "fbdev"; then
1497                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1498         fi
1499     done
1500     EGL_PLATFORMS="$egl_platforms"
1501     ;;
1502 esac
1503 AC_SUBST([EGL_PLATFORMS])
1504
1505 AC_ARG_WITH([egl-driver-dir],
1506     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1507                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1508     [EGL_DRIVER_INSTALL_DIR="$withval"],
1509     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1510 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1511
1512 AC_ARG_WITH([xorg-driver-dir],
1513     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1514                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1515     [XORG_DRIVER_INSTALL_DIR="$withval"],
1516     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1517 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1518
1519 AC_ARG_WITH([max-width],
1520     [AS_HELP_STRING([--with-max-width=N],
1521                     [Maximum framebuffer width (4096)])],
1522     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1523      AS_IF([test "${withval}" -gt "4096"],
1524            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1525 )
1526 AC_ARG_WITH([max-height],
1527     [AS_HELP_STRING([--with-max-height=N],
1528                     [Maximum framebuffer height (4096)])],
1529     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1530      AS_IF([test "${withval}" -gt "4096"],
1531            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1532 )
1533
1534 dnl
1535 dnl Gallium LLVM
1536 dnl
1537 AC_ARG_ENABLE([gallium-llvm],
1538     [AS_HELP_STRING([--enable-gallium-llvm],
1539         [build gallium LLVM support @<:@default=disabled@:>@])],
1540     [enable_gallium_llvm="$enableval"],
1541     [enable_gallium_llvm=auto])
1542 if test "x$enable_gallium_llvm" = xyes; then
1543     if test "x$LLVM_CONFIG" != xno; then
1544         LLVM_VERSION=`$LLVM_CONFIG --version`
1545         LLVM_CFLAGS=`$LLVM_CONFIG --cflags`
1546         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1547
1548         if test "x$HAS_UDIS86" != xno; then
1549             LLVM_LIBS="$LLVM_LIBS -ludis86"
1550             DEFINES="$DEFINES -DHAVE_UDIS86"
1551         fi
1552         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1553         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1554         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1555         MESA_LLVM=1
1556     else
1557         MESA_LLVM=0
1558     fi
1559 else
1560     MESA_LLVM=0
1561 fi
1562
1563 dnl
1564 dnl Gallium helper functions
1565 dnl
1566 gallium_check_st() {
1567     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1568          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1569     fi
1570     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1571          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1572     fi
1573     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1574          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1575     fi
1576 }
1577
1578
1579 dnl
1580 dnl Gallium SVGA configuration
1581 dnl
1582 AC_ARG_ENABLE([gallium-svga],
1583     [AS_HELP_STRING([--enable-gallium-svga],
1584         [build gallium SVGA @<:@default=disabled@:>@])],
1585     [enable_gallium_svga="$enableval"],
1586     [enable_gallium_svga=auto])
1587 if test "x$enable_gallium_svga" = xyes; then
1588     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1589     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1590 elif test "x$enable_gallium_svga" = xauto; then
1591     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1592 fi
1593
1594 dnl
1595 dnl Gallium i915 configuration
1596 dnl
1597 AC_ARG_ENABLE([gallium-i915],
1598     [AS_HELP_STRING([--enable-gallium-i915],
1599         [build gallium i915 @<:@default=disabled@:>@])],
1600     [enable_gallium_i915="$enableval"],
1601     [enable_gallium_i915=auto])
1602 if test "x$enable_gallium_i915" = xyes; then
1603     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1604     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1605     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1606 elif test "x$enable_gallium_i915" = xauto; then
1607     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1608     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1609 fi
1610
1611 dnl
1612 dnl Gallium i965 configuration
1613 dnl
1614 AC_ARG_ENABLE([gallium-i965],
1615     [AS_HELP_STRING([--enable-gallium-i965],
1616         [build gallium i965 @<:@default=disabled@:>@])],
1617     [enable_gallium_i965="$enableval"],
1618     [enable_gallium_i965=auto])
1619 if test "x$enable_gallium_i965" = xyes; then
1620     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1621     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1622 elif test "x$enable_gallium_i965" = xauto; then
1623     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1624 fi
1625
1626 dnl
1627 dnl Gallium Radeon r300g configuration
1628 dnl
1629 AC_ARG_ENABLE([gallium-radeon],
1630     [AS_HELP_STRING([--enable-gallium-radeon],
1631         [build gallium radeon @<:@default=disabled@:>@])],
1632     [enable_gallium_radeon="$enableval"],
1633     [enable_gallium_radeon=auto])
1634 if test "x$enable_gallium_radeon" = xauto; then
1635     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1636         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1637         gallium_check_st "radeon/drm" "dri-r300"
1638     else
1639         AC_MSG_WARN([libdrm_radeon is missing, not building gallium-radeon (r300)])
1640     fi
1641 fi
1642 if test "x$enable_gallium_radeon" = xyes; then
1643     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1644         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1645         gallium_check_st "radeon/drm" "dri-r300" "xorg-radeon"
1646     else
1647         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-radeon (r300)])
1648     fi
1649 fi
1650
1651 dnl
1652 dnl Gallium Radeon r600g configuration
1653 dnl
1654 AC_ARG_ENABLE([gallium-r600],
1655     [AS_HELP_STRING([--enable-gallium-r600],
1656         [build gallium radeon @<:@default=disabled@:>@])],
1657     [enable_gallium_r600="$enableval"],
1658     [enable_gallium_r600=auto])
1659 if test "x$enable_gallium_r600" = xyes; then
1660     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1661         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1662         gallium_check_st "r600/drm" "dri-r600"
1663     else
1664         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-r600])
1665     fi
1666 fi
1667
1668 dnl
1669 dnl Gallium Nouveau configuration
1670 dnl
1671 AC_ARG_ENABLE([gallium-nouveau],
1672     [AS_HELP_STRING([--enable-gallium-nouveau],
1673         [build gallium nouveau @<:@default=disabled@:>@])],
1674     [enable_gallium_nouveau="$enableval"],
1675     [enable_gallium_nouveau=no])
1676 if test "x$enable_gallium_nouveau" = xyes; then
1677     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1678     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau"
1679 fi
1680
1681 dnl
1682 dnl Gallium swrast configuration
1683 dnl
1684 AC_ARG_ENABLE([gallium-swrast],
1685     [AS_HELP_STRING([--enable-gallium-swrast],
1686         [build gallium swrast @<:@default=auto@:>@])],
1687     [enable_gallium_swrast="$enableval"],
1688     [enable_gallium_swrast=auto])
1689 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1690     if test "x$HAVE_ST_DRI" = xyes; then
1691         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1692     fi
1693 fi
1694
1695 dnl prepend CORE_DIRS to SRC_DIRS
1696 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1697
1698 dnl Restore LDFLAGS and CPPFLAGS
1699 LDFLAGS="$_SAVE_LDFLAGS"
1700 CPPFLAGS="$_SAVE_CPPFLAGS"
1701
1702 dnl Substitute the config
1703 AC_CONFIG_FILES([configs/autoconf])
1704
1705 dnl Replace the configs/current symlink
1706 AC_CONFIG_COMMANDS([configs],[
1707 if test -f configs/current || test -L configs/current; then
1708     rm -f configs/current
1709 fi
1710 ln -s autoconf configs/current
1711 ])
1712
1713 AC_OUTPUT
1714
1715 dnl
1716 dnl Output some configuration info for the user
1717 dnl
1718 echo ""
1719 echo "        prefix:          $prefix"
1720 echo "        exec_prefix:     $exec_prefix"
1721 echo "        libdir:          $libdir"
1722 echo "        includedir:      $includedir"
1723
1724 dnl API info
1725 echo ""
1726 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
1727 echo "        GLES overlay:    $enable_gles_overlay"
1728 echo "        OpenVG:          $enable_openvg"
1729
1730 dnl Driver info
1731 echo ""
1732 echo "        Driver:          $mesa_driver"
1733 if test "$mesa_driver" != no; then
1734     if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1735         echo "        OSMesa:          lib$OSMESA_LIB"
1736     else
1737         echo "        OSMesa:          no"
1738     fi
1739     if test "$mesa_driver" = dri; then
1740         # cleanup the drivers var
1741         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1742         if test "x$DRI_DIRS" = x; then
1743             echo "        DRI drivers:     no"
1744         else
1745             echo "        DRI drivers:     $dri_dirs"
1746         fi
1747         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1748         echo "        Use XCB:         $enable_xcb"
1749     fi
1750 fi
1751 echo ""
1752 echo "        GLU:             $enable_glu"
1753 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1754 echo "        glut:            $enable_glut"
1755
1756 dnl EGL
1757 echo ""
1758 echo "        EGL:             $enable_egl"
1759 if test "$enable_egl" = yes; then
1760     echo "        EGL platforms:   $EGL_PLATFORMS"
1761     echo "        EGL drivers:     $EGL_DRIVERS_DIRS"
1762     if test "$enable_gallium" = yes -a "$HAVE_ST_EGL" = yes; then
1763         echo "        EGL tracker:     yes"
1764         echo "        EGL client APIs:$EGL_CLIENT_APIS"
1765     else
1766         echo "        EGL tracker:     no"
1767     fi
1768 fi
1769
1770 echo ""
1771 if test "x$MESA_LLVM" = x1; then
1772     echo "        llvm:            yes"
1773     echo "        llvm-config:     $LLVM_CONFIG"
1774     echo "        llvm-version:    $LLVM_VERSION"
1775 else
1776     echo "        llvm:            no"
1777 fi
1778
1779 echo ""
1780 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1781     echo "        Gallium:         yes"
1782     echo "        Gallium dirs:    $GALLIUM_DIRS"
1783     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1784     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1785     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1786     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1787     if test "x$HAVE_ST_EGL" = xyes; then
1788         echo "        EGL client APIs: $EGL_CLIENT_APIS"
1789     fi
1790 else
1791     echo "        Gallium:         no"
1792 fi
1793
1794 dnl Libraries
1795 echo ""
1796 echo "        Shared libs:     $enable_shared"
1797 echo "        Static libs:     $enable_static"
1798
1799 dnl Compiler options
1800 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1801 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1802     $SED 's/^ *//;s/  */ /;s/ *$//'`
1803 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1804     $SED 's/^ *//;s/  */ /;s/ *$//'`
1805 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1806 echo ""
1807 echo "        CFLAGS:          $cflags"
1808 echo "        CXXFLAGS:        $cxxflags"
1809 echo "        Macros:          $defines"
1810 echo ""
1811 echo "        PYTHON2:         $PYTHON2"
1812
1813 echo ""
1814 echo "        Run '${MAKE-make}' to build Mesa"
1815 echo ""