configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2
   3 # Copyright (C) 1995-2012 Free Software Foundation, Inc.
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.69])
  19 AC_INIT([GNU Automake], [1.12a], [bug-automake@gnu.org])
  20
  21 AC_CONFIG_SRCDIR([automake.in])
  22 AC_CONFIG_AUX_DIR([lib])
  23
  24 AM_SILENT_RULES([yes])
  25
  26 AC_CANONICAL_HOST
  27 AC_CANONICAL_BUILD
  28
  29 # Save the AUTOCONF setting before AM_INIT_AUTOMAKE overrides it; this
  30 # way we can run Autoconf tests from configure (or from the test
  31 # suite) without being bothered by 'missing'.  Likewise for autom4te,
  32 # autoreconf, autoheader, and autoupdate.
  33 AC_SUBST([am_AUTOCONF], ["${AUTOCONF-autoconf}"])
  34 AC_SUBST([am_AUTOM4TE], ["${AUTOM4TE-autom4te}"])
  35 AC_SUBST([am_AUTORECONF], ["${AUTORECONF-autoreconf}"])
  36 AC_SUBST([am_AUTOHEADER], ["${AUTOHEADER-autoheader}"])
  37 AC_SUBST([am_AUTOUPDATE], ["${AUTOUPDATE-autoupdate}"])
  38
  39 dnl We call AC_PROG_CC in an unusual way, and only for use in our
  40 dnl testsuite, so also use 'no-dependencies' and 'no-define' among
  41 dnl the automake options to avoid bloating and potential problems.
  42 AM_INIT_AUTOMAKE([dist-xz filename-length-max=99 color-tests
  43                   parallel-tests silent-rules no-define no-dependencies])
  44
  45 ## Keep this on a line of its own, since it must be found and processed
  46 ## by the 'update-copyright' rule in our Makefile.
  47 RELEASE_YEAR=2012
  48 AC_SUBST([RELEASE_YEAR])
  49
  50 # The API version is the base version.  We must guarantee
  51 # compatibility for all releases with the same API version.
  52 # Our current rule is that:
  53 # * All releases, including the prereleases, in an X.Y series
  54 #   are compatible.  So 1.5.1c is compatible with 1.5.
  55 # * Prereleases on the trunk are all incompatible -- 1.5b and 1.5c
  56 #   aren't the same.
  57 APIVERSION=`echo "$VERSION" | sed -e 's/^\([[0-9]]*\.[[0-9]]*[[a-z]]*\).*$/\1/'`
  58 AC_SUBST([APIVERSION])
  59
  60 AC_SUBST([pkgvdatadir], ["\${datadir}/$PACKAGE-$APIVERSION"])
  61 AC_SUBST([scriptdir], ["\${pkgvdatadir}"])
  62 AC_SUBST([amdir], ["\${pkgvdatadir}/am"])
  63 AC_SUBST([automake_acdir], ["\${datadir}/aclocal-$APIVERSION"])
  64 AC_SUBST([system_acdir], ["\${datadir}/aclocal"])
  65
  66 # $AUTOMAKE and $ACLOCAL are always run after a "cd $top_srcdir",
  67 # hence '.' is really what we want for perllibdir, libdir, and acdir.
  68 # Use '-I' with aclocal so that our own *.m4 files in m4/ gets included,
  69 # not copied, in aclocal.m4.
  70 ACLOCAL="\
  71   perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/aclocal\" \
  72   --automake-acdir=m4 --system-acdir=m4/acdir -I m4"
  73 AUTOMAKE="\
  74   perllibdir=\"`pwd`/lib$PATH_SEPARATOR./lib\" \"`pwd`/automake\" \
  75   --libdir=lib"
  76
  77 AC_PATH_PROG([PERL], [perl])
  78 if test -z "$PERL"; then
  79    AC_MSG_ERROR([perl not found])
  80 fi
  81 # Save details about the selected perl interpreter in config.log.
  82 AM_RUN_LOG([$PERL --version])
  83 $PERL -e 'require 5.006;' || {
  84    AC_MSG_ERROR(
  85 [perl 5.6 or better is required; perl 5.8.2 or better
  86 is recommended.  If you have several perl versions
  87 installed, select the one Automake should use using
  88   ./configure PERL=/path/to/perl])
  89 }
  90
  91 # We require ithreads support, and version 5.7.2 for CLONE.
  92 AC_CACHE_CHECK([whether $PERL supports ithreads], [am_cv_prog_PERL_ithreads],
  93 [if $PERL -e '
  94     require 5.007_002;
  95     use Config;
  96     if ($Config{useithreads})
  97       {
  98         require threads;
  99         import threads;
 100         require Thread::Queue;
 101         import Thread::Queue;
 102         exit 0;
 103       }
 104     exit 1;' >&AS_MESSAGE_LOG_FD 2>&1
 105 then
 106   am_cv_prog_PERL_ithreads=yes
 107 else
 108   am_cv_prog_PERL_ithreads=no
 109 fi])
 110 if test $am_cv_prog_PERL_ithreads = yes; then
 111   PERL_THREADS=1;
 112 else
 113   PERL_THREADS=0;
 114 fi
 115 AC_SUBST([PERL_THREADS])
 116
 117 # The test suite will skip some tests if tex is absent.
 118 AC_CHECK_PROG([TEX], [tex], [tex])
 119 # Save details about the selected TeX program in config.log.
 120 # Redirect input from /dev/null, as TeX might otherwise hang waiting
 121 # for input from the terminal.
 122 AM_RUN_LOG([$TEX --version </dev/null])
 123
 124 # The test suite will skip some tests if no lex or yacc program is
 125 # available.
 126 # We don't use AC_PROG_LEX nor AC_PROG_YACC here because:
 127 #  1. we don't want flex (resp. bison) to be preferred to system lex
 128 #     (resp. system yacc);
 129 #  2. we don't want $LEX (resp. $YACC) to be defined to ':' (resp. 'yacc')
 130 #     by default;
 131 #  3. we prefer not to have the variables YFLAGS, LEX_OUTPUT_ROOT and
 132 #     LEXLIB to be calculated and/or AC_SUBST'd;
 133 #  4. we prefer that the YACC and LEX variables are not reported in the
 134 #     configure help screen.
 135 AC_CHECK_PROGS([YACC], [yacc byacc 'bison -y'], [false])
 136 AC_CHECK_PROGS([LEX], [lex flex], [false])
 137
 138 # Test for Autoconf.  We run Autoconf in a subdirectory to ease
 139 # deletion of any files created (such as those added to
 140 # autom4te.cache).  We used to perform only the last of the three
 141 # following tests, but some users were unable to figure out that their
 142 # installation was broken since --version appeared to work.
 143
 144 required_autoconf_version=2.62
 145 AC_CACHE_CHECK([whether autoconf is installed], [am_cv_autoconf_installed],
 146 [if AM_RUN_LOG([$am_AUTOCONF --version]);
 147 then
 148   am_cv_autoconf_installed=yes
 149 else
 150   am_cv_autoconf_installed=no
 151 fi])
 152 if test "$am_cv_autoconf_installed" = no; then
 153   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.
 154     Please make sure it is installed and in your PATH.])
 155 fi
 156
 157 AC_CACHE_CHECK([whether autoconf works], [am_cv_autoconf_works],
 158 [mkdir conftest
 159 echo 'AC''_INIT' > conftest/conftest.ac
 160 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 161 then
 162   am_cv_autoconf_works=yes
 163 else
 164   am_cv_autoconf_works=no
 165 fi
 166 rm -rf conftest])
 167 if test "$am_cv_autoconf_works" = no; then
 168   AC_MSG_ERROR([The installed version of autoconf does not work.
 169     Please check config.log for error messages before this one.])
 170 fi
 171
 172 AC_CACHE_CHECK([whether autoconf is recent enough], [am_cv_autoconf_version],
 173 [mkdir conftest
 174 dnl Creative quoting required to avoid spurious expansion of AC_PREREQ macro
 175 echo 'AC'"_PREREQ([[$required_autoconf_version]])" > conftest/conftest.ac
 176 if AM_RUN_LOG([cd conftest && $am_AUTOCONF -o /dev/null conftest.ac]);
 177 then
 178   am_cv_autoconf_version=yes
 179 else
 180   am_cv_autoconf_version=no
 181 fi
 182 rm -rf conftest])
 183 if test "$am_cv_autoconf_version" = no; then
 184   AC_MSG_ERROR([Autoconf $required_autoconf_version or better is required.])
 185 fi
 186
 187 # Test for ln.  We need use it to install the versioned binaries.
 188 AC_MSG_CHECKING([whether ln works])
 189 AC_CACHE_VAL([am_cv_prog_ln], [
 190 rm -f conftest conftest.file
 191 : >conftest.file
 192 if ln conftest.file conftest 2>/dev/null; then
 193   am_cv_prog_ln=ln
 194 else
 195   am_cv_prog_ln='cp -p'
 196 fi
 197 rm -f conftest conftest.file])
 198 AC_SUBST([LN], [$am_cv_prog_ln])
 199 result=no
 200 test "x$am_cv_prog_ln" = xln && result=yes
 201 AC_MSG_RESULT([$result])
 202
 203 # The amount we should wait after modifying files depends on the platform.
 204 # On Windows '95, '98 and ME, files modifications have 2-seconds
 205 # granularity and can be up to 3 seconds in the future w.r.t. the
 206 # system clock.  When it is important to ensure one file is older
 207 # than another we wait at least 5 seconds between creations.
 208 case $build in
 209   *-pc-msdosdjgpp) MODIFICATION_DELAY=5;;
 210   *)               MODIFICATION_DELAY=2;;
 211 esac
 212 AC_SUBST([MODIFICATION_DELAY])
 213
 214 # Test for things needed by the test suite.
 215 AC_PROG_EGREP
 216 AC_PROG_FGREP
 217
 218 AC_CACHE_CHECK([whether $SHELL has working 'set -e' with exit trap],
 219 [am_cv_sh_errexit_works],
 220 [if $SHELL -ec "trap 'exit \$?' 0; (exit 77); exit 77"; test $? = 77
 221 then
 222   am_cv_sh_errexit_works=yes
 223 else
 224   am_cv_sh_errexit_works=no
 225 fi
 226 ])
 227 if test $am_cv_sh_errexit_works = no; then
 228   AC_MSG_WARN(["${MAKE-make} check" will leave leftover directories t/*.dir])
 229   AC_MSG_WARN([you can clean them up manually using "${MAKE-make} clean" or])
 230   AC_MSG_WARN(["cd t && ${MAKE-make} clean-local-check'])
 231 fi
 232 AC_SUBST([sh_errexit_works], [$am_cv_sh_errexit_works])
 233
 234
 235 ###########################################################################
 236
 237 # Look for C, C++ and fortran compilers to be used in the testsuite.
 238
 239 dnl We don't want to abort our configuration script if no C compiler is
 240 dnl available, as such a compiler is only required to run part of the
 241 dnl testsuite, not to build or install Automake.  Ditto for C++, Fortran
 242 dnl and Fortran 77 compilers.  Unfortunately, autoconf does not offer an
 243 dnl easy way to obtain this behaviour, so we'll need a few hacks.
 244
 245 dnl We want the body of this macro to expand as a single shell statement,
 246 dnl thus we wrap it into { ... } brackets.
 247 AC_DEFUN([_AM_WRAP_MSG_ERROR], [ {
 248   AC_MSG_WARN([$1])
 249   am__failed=yes
 250   break
 251 } ])
 252
 253 AC_DEFUN([_AM_COMPILER_CAN_FAIL], [
 254   m4_pushdef([AC_MSG_FAILURE], m4_defn([_AM_WRAP_MSG_ERROR]))
 255   m4_pushdef([AC_MSG_ERROR],   m4_defn([_AM_WRAP_MSG_ERROR]))
 256   am__failed=no
 257   while :; do
 258      $1
 259      break
 260   done
 261   AS_IF([test $am__failed = yes], [$2])
 262   # We have to clear these cache variables, so that future checks on
 263   # compilers for different languages won't be confused.
 264   unset ac_cv_objext ac_cv_exeext
 265   # We also need to meddle with the autoconf internals to ensure that
 266   # checks to find object and executable extensions will be run anew.
 267   # FIXME: In the long run, the better thing to do would be to fix
 268   # FIXME: autoconf instead ...
 269   m4_undefine([m4_provide(_AC_COMPILER_OBJEXT)])
 270   m4_undefine([m4_provide(_AC_COMPILER_EXEEXT)])
 271   m4_popdef([AC_MSG_FAILURE])
 272   m4_popdef([AC_MSG_ERROR])
 273 ])
 274
 275 AC_DEFUN([_AM_SKIP_COMP_TESTS],
 276   [AC_MSG_NOTICE([tests requiring the $1 compiler will be skipped])])
 277
 278 # Prefer generic compilers to GNU ones when possible.  This will ensure
 279 # more testsuite coverage "in the wild".
 280 # Note that we don't look for the MSVC C/C++ compiler here.  This is
 281 # deliberate; for more discussion and rationale, see:
 282 # <http://lists.gnu.org/archive/html/automake-patches/2012-01/msg00130.html>
 283
 284 AC_MSG_NOTICE([will now look for generic compilers])
 285
 286 # C compiler.
 287 _AM_COMPILER_CAN_FAIL(dnl
 288   [AC_PROG_CC([cc gcc])],
 289   [CC=false; _AM_SKIP_COMP_TESTS([C])])
 290
 291 AS_IF([test x"$GCC" = x"yes"], [am_CC_is_GNU=yes], [am_CC_is_GNU=no])
 292
 293 # The list of C++ compilers here has been copied, pasted and edited
 294 # from 'lib/autoconf/c.m4:AC_PROG_CXX' in the Autoconf distribution.
 295 # Keep it in sync, or better again, find out a way to avoid this code
 296 # duplication.
 297 _AM_COMPILER_CAN_FAIL([AC_PROG_CXX(dnl
 298   [aCC CC FCC KCC RCC xlC_r xlC c++ cxx cc++ gpp g++])],
 299   [CXX=false; _AM_SKIP_COMP_TESTS([C++])])
 300
 301 AS_IF([test x"$GXX" = x"yes"], [am_CXX_is_GNU=yes], [am_CXX_is_GNU=no])
 302
 303 # The lists of Fortran compilers here has been copied, pasted and edited
 304 # from file 'lib/autoconf/fortran.m4' in the Autoconf distribution.
 305 # Keep it in sync, or better again, find out a way to avoid this code
 306 # duplication.
 307
 308 _AM_COMPILER_CAN_FAIL([AC_PROG_FC(dnl
 309   [xlf95 f95 fort ifort ifc efc pgfortran pgf95 lf95 ftn nagfor] dnl
 310   [xlf90 f90 pgf90 pghpf epcf90 g95 gfortran])],
 311   [FC=false; _AM_SKIP_COMP_TESTS([Fortran])])
 312
 313 AS_IF([test x"$GFC" = x"yes"], [am_FC_is_GNU=yes], [am_FC_is_GNU=no])
 314
 315 _AM_COMPILER_CAN_FAIL([AC_PROG_F77(dnl
 316   [xlf f77 frt pgf77 cf77 fort77 fl32 af77 g77 gfortran])],
 317   [F77=false; _AM_SKIP_COMP_TESTS([Fortran 77])])
 318
 319 AS_IF([test x"$G77" = x"yes"], [am_F77_is_GNU=yes], [am_F77_is_GNU=no])
 320
 321 # Some tests will need the GNU compilers.  Searching for them here would
 322 # be overkill, since our testsuite already handles their search and setup
 323 # pretty well.  But in case the compilers already found are the GNU ones,
 324 # we want to use them in the testsuite where GNU compilers are required.
 325 # Also, in case the compilers detected above (at configure time) are not
 326 # the GNU ones, we cannot use the values of CFLAGS, CXXFLAGS, FCFLAGS and
 327 # FFLAGS detected for them with the GNU compilers too, since it's likely
 328 # they won't be compatible.  So we allow the user to define variants of
 329 # these variables for the GNU compilers separately.
 330
 331 AC_MSG_NOTICE([will now look for GNU compilers])
 332
 333 # GNU C compiler.
 334 AC_ARG_VAR([GNU_CC],     [GNU C compiler])
 335 AC_ARG_VAR([GNU_CFLAGS], [GNU C compiler flags])
 336 if test $am_CC_is_GNU = yes; then
 337   AC_MSG_NOTICE([$CC is already a GNU C compiler])
 338   GNU_CC=$CC GNU_CFLAGS=${GNU_CFLAGS-$CFLAGS}
 339 else
 340   AC_CHECK_TOOLS([GNU_CC], [gcc], [false])
 341 fi
 342 AS_IF([AM_RUN_LOG([$GNU_CC --version && $GNU_CC -v])], [],
 343       [AC_MSG_WARN([botched installation for GNU C compiler])
 344        _AM_SKIP_COMP_TESTS([GNU C])])
 345
 346 # GNU C++ compiler.
 347 AC_ARG_VAR([GNU_CXX],      [GNU C++ compiler])
 348 AC_ARG_VAR([GNU_CXXFLAGS], [GNU C++ compiler flags])
 349 if test $am_CXX_is_GNU = yes; then
 350   AC_MSG_NOTICE([$CXX is already a GNU C++ compiler])
 351   GNU_CXX=$CXX
 352   GNU_CXXFLAGS=${GNU_CXXFLAGS-$CXXFLAGS}
 353 else
 354   AC_CHECK_TOOLS([GNU_CXX], [g++ gpp], [false])
 355 fi
 356 AS_IF([AM_RUN_LOG([$GNU_CXX --version && $GNU_CXX -v])], [],
 357       [AC_MSG_WARN([botched installation for GNU C++ compiler])
 358        _AM_SKIP_COMP_TESTS([GNU C++])])
 359
 360 # GNU Fortran compiler.
 361 AC_ARG_VAR([GNU_FC],      [GNU Fortran compiler])
 362 AC_ARG_VAR([GNU_FCFLAGS], [GNU Fortran compiler flags])
 363 if test $am_FC_is_GNU = yes; then
 364   AC_MSG_NOTICE([$FC is already a GNU Fortran compiler])
 365   GNU_FC=$FC
 366   GNU_FCFLAGS=${GNU_FCFLAGS-$FCFLAGS}
 367 else
 368   AC_CHECK_TOOLS([GNU_FC], [gfortran], [false])
 369 fi
 370 AS_IF([AM_RUN_LOG([$GNU_FC --version && $GNU_FC -v])], [],
 371       [AC_MSG_WARN([botched installation for GNU Fortran compiler])
 372        _AM_SKIP_COMP_TESTS([GNU Fortran])])
 373
 374 # GNU Fortran 77 compiler.
 375 AC_ARG_VAR([GNU_F77],    [GNU Fortran 77 compiler])
 376 AC_ARG_VAR([GNU_FFLAGS], [GNU Fortran 77 compiler flags])
 377 if test $am_F77_is_GNU = yes; then
 378   AC_MSG_NOTICE([$F77 is already a GNU Fortran 77 compiler])
 379   GNU_F77=$F77
 380   GNU_FFLAGS=${GNU_FFLAGS-$FFLAGS}
 381 else
 382   AC_CHECK_TOOLS([GNU_F77], [g77 gfortran], [false])
 383 fi
 384 AS_IF([AM_RUN_LOG([$GNU_F77 --version && $GNU_F77 -v])], [],
 385       [AC_MSG_WARN([botched installation for GNU Fortran 77 compiler])
 386       _AM_SKIP_COMP_TESTS([GNU Fortran 77])])
 387
 388 # GNU Java compiler.
 389 AC_ARG_VAR([GNU_GCJ], [GNU Java compiler])
 390 AC_ARG_VAR([GNU_GCJFLAGS], [GNU Java compiler flags])
 391 AC_CHECK_TOOLS([GNU_GCJ], [gcj], [false])
 392 AS_IF([AM_RUN_LOG([$GNU_GCJ --version && $GNU_GCJ -v])], [],
 393       [AC_MSG_WARN([botched installation for GNU Java compiler])
 394       _AM_SKIP_COMP_TESTS([GNU Java])])
 395
 396 # If we have been able to find at least a working compiler above, we
 397 # know what the object and executable extensions for this platform are.
 398 OBJEXT=${ac_cv_objext-UNKNOWN}
 399 EXEEXT=${ac_cv_exeext-UNKNOWN}
 400 AC_SUBST([OBJEXT])
 401 AC_SUBST([EXEEXT])
 402
 403 ###########################################################################
 404
 405 AC_CONFIG_FILES([Makefile])
 406
 407 AC_CONFIG_LINKS([GNUmakefile:GNUmakefile])
 408 AC_CONFIG_LINKS([defs:defs])
 409
 410 AC_CONFIG_FILES([t/wrap/aclocal-${APIVERSION}:t/wrap/aclocal.in],
 411                 [chmod +x t/wrap/aclocal-${APIVERSION}],
 412                 [APIVERSION=$APIVERSION])
 413 AC_CONFIG_FILES([t/wrap/automake-${APIVERSION}:t/wrap/automake.in],
 414                 [chmod +x t/wrap/automake-${APIVERSION}],
 415                 [APIVERSION=$APIVERSION])
 416
 417 AC_OUTPUT
 418
 419 # Inform the user if this version of automake is a beta release or
 420 # a development snapshot.
 421 # According to HACKING, the version of a development snapshot should
 422 # end with an "odd" letter (a, c, ...), the version of a test release
 423 # should end wit an "even" letter (b, d, ...).
 424
 425 am_stable_version_rx='[[1-9]\.[0-9]+(\.[0-9]+)?]'
 426 am_beta_version_rx="[$am_stable_version_rx[bdfhjlnprtvxz]]"
 427
 428 am_release_type=`AS_ECHO(["$PACKAGE_VERSION"]) | LC_ALL=C awk ["
 429   /^$am_stable_version_rx$/ { print \"stable\"; exit(0); }
 430   /^$am_beta_version_rx$/ { print \"beta version\"; exit(0); }
 431   { print \"development snapshot\"; }"]`
 432
 433 test "$am_release_type" = stable || cat <<EOF
 434
 435 WARNING: You are about to use a $am_release_type of automake.
 436 WARNING: It might easily suffer from new bugs or regressions.
 437 WARNING: You are strongly advised not to use it in production code.
 438
 439 Please report bugs, problems and feedback to <AC_PACKAGE_BUGREPORT>.
 440 EOF
 441
 442 AS_EXIT([0])