configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.62])
   3
   4 dnl ***********************************
   5 dnl *** include special GLib macros ***
   6 dnl ***********************************
   7
   8 m4_define(glib_configure_ac)
   9
  10 #
  11 # The following version number definitions apply to GLib, GModule, GObject,
  12 # GThread and GIO as a whole, so if changes occurred in any of them, they are
  13 # all treated with the same interface and binary age.
  14 #
  15 # Making releases:
  16 #   glib_micro_version += 1;
  17 #   glib_interface_age += 1;
  18 #   glib_binary_age += 1;
  19 # if any functions have been added, set glib_interface_age to 0.
  20 # if backwards compatibility has been broken,
  21 # set glib_binary_age _and_ glib_interface_age to 0.
  22 #
  23 # remember to add a GLIB_VERSION_2_xx macro every time the minor version is
  24 # bumped, as well as the GLIB_DEPRECATED_IN and GLIB_AVAILABLE_IN macros
  25 # for that version - see gversion.h for further information.
  26 #
  27 # in easier to understand terms:
  28 #
  29 # <mclasen> on the stable branch, interface age == micro
  30 # <mclasen> on the unstable (ie master), interface age = 0
  31
  32 m4_define([glib_major_version], [2])
  33 m4_define([glib_minor_version], [32])
  34 m4_define([glib_micro_version], [1])
  35 m4_define([glib_interface_age], [1])
  36 m4_define([glib_binary_age],
  37           [m4_eval(100 * glib_minor_version + glib_micro_version)])
  38 m4_define([glib_version],
  39           [glib_major_version.glib_minor_version.glib_micro_version])
  40
  41 # libtool version related macros
  42 m4_define([glib_lt_release], [glib_major_version.glib_minor_version])
  43 m4_define([glib_lt_current],
  44           [m4_eval(100 * glib_minor_version + glib_micro_version - glib_interface_age)])
  45 m4_define([glib_lt_revision], [glib_interface_age])
  46 m4_define([glib_lt_age], [m4_eval(glib_binary_age - glib_interface_age)])
  47 m4_define([glib_lt_current_minus_age],
  48           [m4_eval(glib_lt_current - glib_lt_age)])
  49
  50 # if the minor version number is odd, then we want debugging.  Otherwise
  51 # we only want minimal debugging support.
  52 m4_define([glib_debug_default],
  53           [m4_if(m4_eval(glib_minor_version % 2), [1], [yes], [minimum])])dnl
  54
  55
  56 AC_INIT(glib, [glib_version],
  57         [http://bugzilla.gnome.org/enter_bug.cgi?product=glib])
  58
  59 AC_CONFIG_HEADER([config.h])
  60 AC_CONFIG_SRCDIR([glib/glib.h])
  61 AC_CONFIG_MACRO_DIR([m4macros])
  62
  63 # Save this value here, since automake will set cflags later
  64 cflags_set=${CFLAGS+set}
  65
  66 AM_INIT_AUTOMAKE([1.11 no-define no-dist-gzip dist-xz tar-ustar])
  67 AM_MAINTAINER_MODE([enable])
  68
  69 # Support silent build rules. Disable
  70 # by either passing --disable-silent-rules to configure or passing V=1
  71 # to make
  72 AM_SILENT_RULES([yes])
  73
  74 GLIB_MAJOR_VERSION=glib_major_version
  75 GLIB_MINOR_VERSION=glib_minor_version
  76 GLIB_MICRO_VERSION=glib_micro_version
  77 GLIB_INTERFACE_AGE=glib_interface_age
  78 GLIB_BINARY_AGE=glib_binary_age
  79 GLIB_VERSION=glib_version
  80
  81 AC_SUBST(GLIB_MAJOR_VERSION)
  82 AC_SUBST(GLIB_MINOR_VERSION)
  83 AC_SUBST(GLIB_MICRO_VERSION)
  84 AC_SUBST(GLIB_VERSION)
  85 AC_SUBST(GLIB_INTERFACE_AGE)
  86 AC_SUBST(GLIB_BINARY_AGE)
  87
  88 AC_DEFINE(GLIB_MAJOR_VERSION, [glib_major_version],
  89           [Define to the GLIB major version])
  90 AC_DEFINE(GLIB_MINOR_VERSION, [glib_minor_version],
  91           [Define to the GLIB minor version])
  92 AC_DEFINE(GLIB_MICRO_VERSION, [glib_micro_version],
  93           [Define to the GLIB micro version])
  94 AC_DEFINE(GLIB_INTERFACE_AGE, [glib_interface_age],
  95           [Define to the GLIB interface age])
  96 AC_DEFINE(GLIB_BINARY_AGE, [glib_binary_age],
  97           [Define to the GLIB binary age])
  98
  99 # libtool versioning
 100 LT_RELEASE=glib_lt_release
 101 LT_CURRENT=glib_lt_current
 102 LT_REVISION=glib_lt_revision
 103 LT_AGE=glib_lt_age
 104 LT_CURRENT_MINUS_AGE=glib_lt_current_minus_age
 105 AC_SUBST(LT_RELEASE)
 106 AC_SUBST(LT_CURRENT)
 107 AC_SUBST(LT_REVISION)
 108 AC_SUBST(LT_AGE)
 109 AC_SUBST(LT_CURRENT_MINUS_AGE)
 110
 111 dnl Checks for programs.
 112 AC_PROG_CC
 113 AC_PROG_CPP
 114
 115 AM_CONDITIONAL(HAVE_GCC, [test "$GCC" = "yes"])
 116
 117 AC_CANONICAL_HOST
 118
 119 AC_MSG_CHECKING([for the BeOS])
 120 case $host in
 121   *-*-beos*)
 122     glib_native_beos="yes"
 123     ;;
 124   *)
 125     glib_native_beos="no"
 126     ;;
 127 esac
 128 AC_MSG_RESULT([$glib_native_beos])
 129
 130 dnl
 131
 132 AC_MSG_CHECKING([for Win32])
 133 LIB_EXE_MACHINE_FLAG=X86
 134 case "$host" in
 135   *-*-mingw*)
 136     glib_native_win32=yes
 137     glib_pid_type='void *'
 138     glib_cv_stack_grows=no
 139     # Unfortunately the mingw implementations of C99-style snprintf and vsnprintf
 140     # don't seem to be quite good enough, at least not in mingw-runtime-3.14.
 141     # (Sorry, I don't know exactly what is the problem, but it is related to
 142     # floating point formatting and decimal point vs. comma.)
 143     # The simple tests in AC_FUNC_VSNPRINTF_C99 and AC_FUNC_SNPRINTF_C99 aren't
 144     # rigorous enough to notice, though.
 145     # So preset the autoconf cache variables.
 146     ac_cv_func_vsnprintf_c99=no
 147     ac_cv_func_snprintf_c99=no
 148     case "$host" in
 149     x86_64-*-*)
 150       LIB_EXE_MACHINE_FLAG=X64
 151       ;;
 152     esac
 153     ;;
 154   *)
 155     glib_native_win32=no
 156     glib_pid_type=int
 157     ;;
 158 esac
 159 case $host in
 160   *-*-linux*)
 161     glib_os_linux=yes
 162     ;;
 163 esac
 164
 165 AC_MSG_RESULT([$glib_native_win32])
 166
 167 AC_SUBST(LIB_EXE_MACHINE_FLAG)
 168
 169 glib_have_carbon=no
 170 AC_MSG_CHECKING([for Mac OS X Carbon support])
 171 AC_TRY_CPP([
 172 #include <Carbon/Carbon.h>
 173 #include <CoreServices/CoreServices.h>
 174 ], glib_have_carbon=yes)
 175
 176 AC_MSG_RESULT([$glib_have_carbon])
 177
 178 AM_CONDITIONAL(OS_WIN32, [test "$glib_native_win32" = "yes"])
 179 AM_CONDITIONAL(OS_WIN32_X64, [test "$LIB_EXE_MACHINE_FLAG" = "X64"])
 180 AM_CONDITIONAL(OS_UNIX, [test "$glib_native_win32" != "yes"])
 181 AM_CONDITIONAL(OS_LINUX, [test "$glib_os_linux" = "yes"])
 182 AM_CONDITIONAL(OS_CARBON, [test "$glib_have_carbon" = "yes"])
 183
 184 if test "$glib_native_win32" = "yes"; then
 185   AC_CHECK_TOOL(WINDRES, windres, no)
 186   if test "$WINDRES" = no; then
 187     AC_MSG_ERROR([*** Could not find an implementation of windres in your PATH.])
 188   fi
 189   AC_CHECK_TOOL(NM, nm, no)
 190   if test "$NM" = no; then
 191     AC_MSG_ERROR([*** Could not find an implementation of nm in your PATH.])
 192   fi
 193   AC_CHECK_TOOL(RANLIB, ranlib, :)
 194   AC_CHECK_PROG(ms_librarian, [lib.exe], [yes], [no])
 195 fi
 196 AM_CONDITIONAL(MS_LIB_AVAILABLE, [test x$ms_librarian = xyes])
 197
 198 if test "$glib_native_win32" != yes; then
 199     # libtool option to control which symbols are exported
 200     # right now, symbols starting with _ are not exported
 201     LIBTOOL_EXPORT_OPTIONS='-export-symbols-regex "^g.*"'
 202 else
 203     # We currently use .def files on Windows
 204     LIBTOOL_EXPORT_OPTIONS=
 205 fi
 206 AC_SUBST(LIBTOOL_EXPORT_OPTIONS)
 207
 208 if test "x$glib_have_carbon" = "xyes"; then
 209   AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])
 210   LDFLAGS="$LDFLAGS -framework Carbon"
 211 fi
 212
 213 gl_GLIBC21
 214 if test "x$GLIBC21" = "xyes"; then
 215   AC_DEFINE([_GNU_SOURCE], 1, [Make all glibc extensions visible])
 216 fi
 217
 218 dnl declare --enable-* args and collect ac_help strings
 219 AC_ARG_ENABLE(debug,
 220               AC_HELP_STRING([--enable-debug=@<:@no/minimum/yes@:>@],
 221                              [turn on debugging @<:@default=glib_debug_default@:>@]),,
 222               enable_debug=glib_debug_default)
 223
 224 AC_ARG_ENABLE(gc_friendly,
 225               [AC_HELP_STRING([--enable-gc-friendly],
 226                               [turn on garbage collector friendliness [default=no]])],,
 227               [enable_gc_friendly=no])
 228 AC_ARG_ENABLE(mem_pools,
 229               [AC_HELP_STRING([--disable-mem-pools],
 230                               [disable all glib memory pools])],,
 231               [disable_mem_pools=no])
 232 AC_ARG_ENABLE(rebuilds,
 233               [AC_HELP_STRING([--disable-rebuilds],
 234                               [disable all source autogeneration rules])],,
 235               [enable_rebuilds=yes])
 236
 237 AC_MSG_CHECKING([whether to enable garbage collector friendliness])
 238 if test "x$enable_gc_friendly" = "xyes"; then
 239   AC_DEFINE(ENABLE_GC_FRIENDLY_DEFAULT, 1, [Whether to enable GC friendliness by default])
 240   AC_MSG_RESULT([yes])
 241 else
 242   AC_MSG_RESULT([no])
 243 fi
 244
 245 AC_MSG_CHECKING([whether to disable memory pools])
 246 if test "x$disable_mem_pools" = "xno"; then
 247   AC_MSG_RESULT([no])
 248 else
 249   AC_DEFINE(DISABLE_MEM_POOLS, [1], [Whether to disable memory pools])
 250   AC_MSG_RESULT([yes])
 251 fi
 252
 253 dnl location to install runtime libraries, e.g. ../../lib to install
 254 dnl to /lib if libdir is /usr/lib
 255 AC_ARG_WITH(runtime-libdir,
 256            [AC_HELP_STRING([--with-runtime-libdir=RELPATH],
 257                            [install runtime libraries relative to libdir])],
 258            [],
 259            [with_runtime_libdir=""])
 260 GLIB_RUNTIME_LIBDIR="$with_runtime_libdir"
 261 ABS_GLIB_RUNTIME_LIBDIR="`readlink -f $libdir/$with_runtime_libdir`"
 262 AC_SUBST(GLIB_RUNTIME_LIBDIR)
 263 AC_SUBST(ABS_GLIB_RUNTIME_LIBDIR)
 264 AM_CONDITIONAL(HAVE_GLIB_RUNTIME_LIBDIR, [test "x$with_runtime_libdir" != "x"])
 265
 266 dnl Check for a working C++ compiler, but do not bail out, if none is found.
 267 AC_CHECK_TOOLS(CXX, [$CCC c++ g++ gcc CC cxx cc++ cl], [gcc])
 268 AC_LANG_SAVE
 269 AC_LANG_CPLUSPLUS
 270 AC_TRY_COMPILE(,[class a { int b; } c;], ,CXX=)
 271 AM_CONDITIONAL(HAVE_CXX, [test "$CXX" != ""])
 272 AC_LANG_RESTORE
 273
 274 AM_PROG_CC_STDC
 275 AM_PROG_CC_C_O
 276 AC_PROG_INSTALL
 277
 278 AC_SYS_LARGEFILE
 279
 280 PKG_PROG_PKG_CONFIG(0.16)
 281
 282 if test "x$enable_debug" = "xyes"; then
 283   if test x$cflags_set != xset ; then
 284       case " $CFLAGS " in
 285       *[[\ \    ]]-g[[\ \       ]]*) ;;
 286       *) CFLAGS="$CFLAGS -g" ;;
 287       esac
 288   fi
 289   GLIB_DEBUG_FLAGS="-DG_ENABLE_DEBUG"
 290 else
 291   GLIB_DEBUG_FLAGS="-DG_DISABLE_CAST_CHECKS"
 292
 293   if test "x$enable_debug" = "xno"; then
 294     GLIB_DEBUG_FLAGS="$GLIB_DEBUG_FLAGS -DG_DISABLE_ASSERT -DG_DISABLE_CHECKS"
 295   fi
 296 fi
 297
 298 # Ensure MSVC-compatible struct packing convention is used when
 299 # compiling for Win32 with gcc.
 300 # What flag to depends on gcc version: gcc3 uses "-mms-bitfields", while
 301 # gcc2 uses "-fnative-struct".
 302 if test x"$glib_native_win32" = xyes; then
 303   if test x"$GCC" = xyes; then
 304     msnative_struct=''
 305     AC_MSG_CHECKING([how to get MSVC-compatible struct packing])
 306     if test -z "$ac_cv_prog_CC"; then
 307       our_gcc="$CC"
 308     else
 309       our_gcc="$ac_cv_prog_CC"
 310     fi
 311     case `$our_gcc --version | sed -e 's,\..*,.,' -e q` in
 312       2.)
 313         if $our_gcc -v --help 2>/dev/null | grep fnative-struct >/dev/null; then
 314           msnative_struct='-fnative-struct'
 315         fi
 316         ;;
 317       *)
 318         if $our_gcc -v --help 2>/dev/null | grep ms-bitfields >/dev/null; then
 319           msnative_struct='-mms-bitfields'
 320         fi
 321         ;;
 322     esac
 323     if test x"$msnative_struct" = x ; then
 324       AC_MSG_RESULT([no way])
 325       AC_MSG_WARN([produced libraries might be incompatible with MSVC-compiled code])
 326     else
 327       CFLAGS="$CFLAGS $msnative_struct"
 328       AC_MSG_RESULT([${msnative_struct}])
 329     fi
 330   fi
 331 fi
 332 GLIB_EXTRA_CFLAGS="${msnative_struct}"
 333 AC_SUBST(GLIB_EXTRA_CFLAGS)
 334
 335 AC_EXEEXT
 336
 337 # define a MAINT-like variable REBUILD which is set if Perl
 338 # and awk are found, so autogenerated sources can be rebuilt
 339 AC_PROG_AWK
 340 AC_CHECK_PROGS(PERL, [perl5 perl])
 341 # We would like indent, but don't require it.
 342 AC_CHECK_PROG(INDENT, indent, indent)
 343 REBUILD=\#
 344 if test "x$enable_rebuilds" = "xyes" && \
 345      test -n "$PERL" && \
 346      $PERL -e 'exit !($] >= 5.002)' > /dev/null 2>&1 && \
 347      test -n "$AWK" ; then
 348   REBUILD=
 349 fi
 350 AC_SUBST(REBUILD)
 351
 352 # Need full path to Perl for glib-mkenums
 353 #
 354 if test "x$PERL" != x ; then
 355   AC_PATH_PROG(PERL_PATH, [$PERL])
 356 fi
 357 if test "x$PERL_PATH" = x ; then
 358   PERL_PATH="/usr/bin/env perl"
 359 fi
 360 AC_SUBST(PERL_PATH)
 361
 362 # Need suitable python path for greport
 363 AM_PATH_PYTHON(2.5,,PYTHON="/usr/bin/env python2.5")
 364
 365
 366 dnl ***********************
 367 dnl *** Tests for iconv ***
 368 dnl ***********************
 369 dnl
 370 dnl We do this before the gettext checks, to avoid distortion
 371
 372 dnl On Windows we use a native implementation
 373
 374 if test x"$glib_native_win32" = xyes; then
 375   with_libiconv=native
 376 else
 377   AC_ARG_WITH(libiconv,
 378               [AC_HELP_STRING([--with-libiconv=@<:@no/gnu/native@:>@],
 379                               [use the libiconv library])],,
 380               [with_libiconv=maybe])
 381
 382   found_iconv=no
 383   case $with_libiconv in
 384     maybe)
 385       # Check in the C library first
 386       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 387       # Check if we have GNU libiconv
 388       if test $found_iconv = "no"; then
 389         AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 390       fi
 391       # Check if we have a iconv in -liconv, possibly from vendor
 392       if test $found_iconv = "no"; then
 393         AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 394       fi
 395       ;;
 396     no)
 397       AC_CHECK_FUNC(iconv_open, [with_libiconv=no; found_iconv=yes])
 398       ;;
 399     gnu|yes)
 400       AC_CHECK_LIB(iconv, libiconv_open, [with_libiconv=gnu; found_iconv=yes])
 401       ;;
 402     native)
 403       AC_CHECK_LIB(iconv, iconv_open, [with_libiconv=native; found_iconv=yes])
 404       ;;
 405   esac
 406
 407   if test "x$found_iconv" = "xno" ; then
 408      AC_MSG_ERROR([*** No iconv() implementation found in C library or libiconv])
 409   fi
 410 fi
 411
 412 AC_ARG_ENABLE(iconv-cache,
 413               [AC_HELP_STRING([--enable-iconv-cache=@<:@yes/no/auto@:>@],
 414                               [cache iconv descriptors [default=auto]])],,
 415               [enable_iconv_cache=auto])
 416
 417 AC_MSG_CHECKING([whether to cache iconv descriptors])
 418 case $enable_iconv_cache in
 419   auto)
 420     if test $ac_cv_gnu_library_2_1 = yes; then
 421       enable_iconv_cache=no
 422     else
 423       enable_iconv_cache=yes
 424     fi
 425   ;;
 426   yes|no)
 427   ;;
 428   *) AC_MSG_ERROR([Value given to --enable-iconv-cache must be one of yes, no or auto])
 429   ;;
 430 esac
 431
 432 if test $enable_iconv_cache = yes; then
 433    AC_DEFINE(NEED_ICONV_CACHE,1,[Do we cache iconv descriptors])
 434 fi
 435
 436 AC_MSG_RESULT($enable_iconv_cache)
 437
 438
 439 dnl
 440 dnl zlib support
 441 dnl
 442 PKG_CHECK_MODULES([ZLIB], [zlib], [found_zlib=yes], [found_zlib=no])
 443 if test "x$found_zlib" = "xno" ; then
 444   AC_CHECK_LIB(z, inflate, [AC_CHECK_HEADER(zlib.h, found_zlib=yes)])
 445   if test "x$found_zlib" = "xno" ; then
 446     AC_MSG_ERROR([*** Working zlib library and headers not found ***])
 447   fi
 448   ZLIB_LIBS='-lz'
 449   AC_SUBST(ZLIB_LIBS)
 450 fi
 451
 452 PKG_CHECK_MODULES(LIBFFI, [libffi >= 3.0.0])
 453 AC_SUBST(LIBFFI_CFLAGS)
 454 AC_SUBST(LIBFFI_LIBS)
 455
 456 dnl
 457 dnl gettext support
 458 dnl
 459
 460 ALL_LINGUAS="`grep -v '^#' "$srcdir/po/LINGUAS" | tr '\n' ' '`"
 461 AC_SUBST([CONFIG_STATUS_DEPENDENCIES],['$(top_srcdir)/po/LINGUAS'])
 462 GLIB_GNU_GETTEXT
 463
 464 if test "$gt_cv_have_gettext" != "yes" ; then
 465   AC_MSG_ERROR([
 466 *** You must have either have gettext support in your C library, or use the
 467 *** GNU gettext library. (http://www.gnu.org/software/gettext/gettext.html
 468 ])
 469 fi
 470
 471 LIBS="$INTLLIBS $LIBS"
 472
 473 GETTEXT_PACKAGE=glib20
 474 AC_SUBST(GETTEXT_PACKAGE)
 475 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, ["$GETTEXT_PACKAGE"],
 476   [Define the gettext package to be used])
 477
 478 GLIB_DEFINE_LOCALEDIR(GLIB_LOCALE_DIR)
 479
 480 dnl
 481 dnl Now we are done with gettext checks, figure out ICONV_LIBS
 482 dnl
 483
 484 if test x"$glib_native_win32" != xyes; then
 485   if test x$with_libiconv != xno ; then
 486     case " $INTLLIBS " in
 487     *[[\ \      ]]-liconv[[\ \  ]]*) ;;
 488     *) ICONV_LIBS="-liconv" ;;
 489     esac
 490   fi
 491 fi
 492 AC_SUBST(ICONV_LIBS)
 493
 494 case $with_libiconv in
 495   gnu)
 496     AC_DEFINE(USE_LIBICONV_GNU, 1, [Using GNU libiconv])
 497     ;;
 498   native)
 499     AC_DEFINE(USE_LIBICONV_NATIVE, 1, [Using a native implementation of iconv in a separate library])
 500     ;;
 501 esac
 502
 503 dnl Initialize libtool
 504 LT_PREREQ([2.2])
 505 LT_INIT([disable-static win32-dll])
 506 dnl when using libtool 2.x create libtool early, because it's used in configure
 507 m4_ifdef([LT_OUTPUT], [LT_OUTPUT])
 508
 509
 510 if test "x$GCC" = "xyes"; then
 511   case " $CFLAGS " in
 512   *[[\ \        ]]-Wall[[\ \    ]]*) ;;
 513   *) CFLAGS="$CFLAGS -Wall" ;;
 514   esac
 515 fi
 516
 517 if test "$glib_native_win32" = "yes"; then
 518   if test x$enable_static = xyes -a x$enable_shared = xyes; then
 519     AC_MSG_ERROR([Can not build both shared and static at the same time on Windows.])
 520   fi
 521   if test x$enable_static = xyes; then
 522     glib_win32_static_compilation=yes
 523     GLIB_WIN32_STATIC_COMPILATION_DEFINE="#define GLIB_STATIC_COMPILATION 1
 524 #define GOBJECT_STATIC_COMPILATION 1"
 525     AC_SUBST(GLIB_WIN32_STATIC_COMPILATION_DEFINE)
 526   fi
 527 fi
 528 AM_CONDITIONAL(OS_WIN32_AND_DLL_COMPILATION, [test x$glib_native_win32 = xyes -a x$glib_win32_static_compilation != xyes])
 529
 530 dnl
 531 dnl DU4 native cc currently needs -std1 for ANSI mode (instead of K&R)
 532 dnl
 533 if test $cross_compiling != yes ; then
 534     AC_MSG_CHECKING([for extra flags to get ANSI library prototypes])
 535     glib_save_LIBS=$LIBS
 536     LIBS="$LIBS -lm"
 537     AC_TRY_RUN([#include <math.h>
 538                  int main (void) { return (log(1) != log(1.)); }],
 539          AC_MSG_RESULT(none needed),
 540          glib_save_CFLAGS=$CFLAGS
 541          CFLAGS="$CFLAGS -std1"
 542          AC_TRY_RUN([#include <math.h>
 543                      int main (void) { return (log(1) != log(1.)); }],
 544              AC_MSG_RESULT(-std1),
 545              AC_MSG_RESULT()
 546              CFLAGS=$glib_save_CFLAGS
 547              AC_MSG_WARN(
 548                     [No ANSI prototypes found in library. (-std1 didn't work.)])
 549          )
 550     )
 551     LIBS=$glib_save_LIBS
 552 fi
 553
 554 dnl NeXTStep cc seems to need this
 555 AC_MSG_CHECKING([for extra flags for POSIX compliance])
 556 AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 557   AC_MSG_RESULT(none needed),
 558   glib_save_CFLAGS=$CFLAGS
 559   CFLAGS="$CFLAGS -posix"
 560   AC_TRY_COMPILE([#include <dirent.h>], [DIR *dir;],
 561     AC_MSG_RESULT(-posix),
 562     AC_MSG_RESULT()
 563     CFLAGS=$glib_save_CFLAGS
 564     AC_MSG_WARN([Could not determine POSIX flag. (-posix didn't work.)])))
 565
 566 # Checks for library functions.
 567 AC_FUNC_VPRINTF
 568 AC_FUNC_ALLOCA
 569 AC_CHECK_FUNCS(mmap posix_memalign memalign valloc fsync pipe2)
 570 AC_CHECK_FUNCS(atexit on_exit timegm gmtime_r)
 571
 572 AC_CHECK_SIZEOF(char)
 573 AC_CHECK_SIZEOF(short)
 574 AC_CHECK_SIZEOF(long)
 575 AC_CHECK_SIZEOF(int)
 576 AC_CHECK_SIZEOF(void *)
 577 AC_CHECK_SIZEOF(long long)
 578 AC_CHECK_SIZEOF(__int64)
 579
 580 AC_CACHE_CHECK([for sig_atomic_t], ac_cv_type_sig_atomic_t,
 581   [AC_TRY_LINK([#include <signal.h>
 582      #include <sys/types.h>
 583      sig_atomic_t val = 42;],
 584     [return val == 42 ? 0 : 1],
 585    ac_cv_type_sig_atomic_t=yes,
 586    ac_cv_type_sig_atomic_t=no)])
 587 if test x$ac_cv_type_sig_atomic_t = xyes; then
 588    AC_DEFINE(HAVE_SIG_ATOMIC_T, 1,
 589      [Define if you have the 'sig_atomic_t' type.])
 590 fi
 591
 592 if test x$ac_cv_sizeof_long = x8 || test x$ac_cv_sizeof_long_long = x8 || test x$ac_cv_sizeof___int64 = x8 ; then
 593   :
 594 else
 595   AC_MSG_ERROR([
 596 *** GLib requires a 64 bit type. You might want to consider
 597 *** using the GNU C compiler.
 598 ])
 599 fi
 600
 601 if test x$glib_native_win32 != xyes && test x$ac_cv_sizeof_long_long = x8; then
 602         # long long is a 64 bit integer.
 603         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 604         AC_CACHE_VAL(glib_cv_long_long_format,[
 605                 for format in ll q I64; do
 606                   AC_TRY_RUN([#include <stdio.h>
 607                         int main()
 608                         {
 609                           long long b, a = -0x3AFAFAFAFAFAFAFALL;
 610                           char buffer[1000];
 611                           sprintf (buffer, "%${format}u", a);
 612                           sscanf (buffer, "%${format}u", &b);
 613                           exit (b!=a);
 614                         }
 615                         ],
 616                         [glib_cv_long_long_format=${format}
 617                         break],
 618                         [],[:])
 619                 done])
 620         if test -n "$glib_cv_long_long_format"; then
 621           AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 622           AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 623           if test x"$glib_cv_long_long_format" = xI64; then
 624             AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 625           fi
 626         else
 627           AC_MSG_RESULT(none)
 628         fi
 629 elif test x$ac_cv_sizeof___int64 = x8; then
 630         # __int64 is a 64 bit integer.
 631         AC_MSG_CHECKING(for format to printf and scanf a guint64)
 632         # We know this is MSVCRT.DLL, and what the formats are
 633         glib_cv_long_long_format=I64
 634         AC_MSG_RESULT(%${glib_cv_long_long_format}u)
 635         AC_DEFINE(HAVE_LONG_LONG_FORMAT,1,[define if system printf can print long long])
 636         AC_DEFINE(HAVE_INT64_AND_I64,1,[define to support printing 64-bit integers with format I64])
 637 fi
 638
 639 AC_C_CONST
 640
 641 dnl ok, here we try to check whether the systems prototypes for
 642 dnl malloc and friends actually match the prototypes provided
 643 dnl by gmem.h (keep in sync). i currently only know how to check
 644 dnl this reliably with gcc (-Werror), improvements for other
 645 dnl compilers are apprechiated.
 646 SANE_MALLOC_PROTOS=no
 647 AC_MSG_CHECKING([if malloc() and friends prototypes are gmem.h compatible])
 648 glib_save_CFLAGS=$CFLAGS
 649 if test "x$GCC" = "xyes"; then
 650   CFLAGS="$CFLAGS -Werror"
 651   AC_TRY_COMPILE([#include <stdlib.h>], [
 652     void* (*my_calloc_p)  (size_t, size_t) = calloc;
 653     void* (*my_malloc_p)  (size_t)         = malloc;
 654     void  (*my_free_p)    (void*)          = free;
 655     void* (*my_realloc_p) (void*, size_t)  = realloc;
 656     my_calloc_p = 0;
 657     my_malloc_p = 0;
 658     my_free_p = 0;
 659     my_realloc_p = 0;
 660   ],
 661     AC_DEFINE(SANE_MALLOC_PROTOS, 1,
 662       [Define if you have correct malloc prototypes])
 663     SANE_MALLOC_PROTOS=yes)
 664 fi
 665 AC_MSG_RESULT($SANE_MALLOC_PROTOS)
 666 CFLAGS=$glib_save_CFLAGS
 667
 668 dnl
 669 dnl check in which direction the stack grows
 670 dnl
 671 AC_CACHE_CHECK([for growing stack pointer],glib_cv_stack_grows,[
 672         AC_TRY_RUN([
 673         volatile int *a = 0, *b = 0;
 674         void foo (void);
 675         int main () { volatile int y = 7; a = &y; foo (); return b > a; }
 676         void foo (void) { volatile int x = 5; b = &x; }
 677         ],
 678         glib_cv_stack_grows=no
 679         ,
 680         glib_cv_stack_grows=yes
 681         ,)
 682 ])
 683
 684 dnl AC_C_INLINE is useless to us since it bails out too early, we need to
 685 dnl truely know which ones of `inline', `__inline' and `__inline__' are
 686 dnl actually supported.
 687 AC_CACHE_CHECK([for __inline],glib_cv_has__inline,[
 688         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 689         __inline int foo () { return 0; }
 690         int main () { return foo (); }
 691         ]])],
 692         glib_cv_has__inline=yes
 693         ,
 694         glib_cv_has__inline=no
 695         ,)
 696 ])
 697 case x$glib_cv_has__inline in
 698 xyes) AC_DEFINE(G_HAVE___INLINE,1,[Have __inline keyword])
 699 esac
 700 AC_CACHE_CHECK([for __inline__],glib_cv_has__inline__,[
 701         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 702         __inline__ int foo () { return 0; }
 703         int main () { return foo (); }
 704         ]])],
 705         glib_cv_has__inline__=yes
 706         ,
 707         glib_cv_has__inline__=no
 708         ,)
 709 ])
 710 case x$glib_cv_has__inline__ in
 711 xyes) AC_DEFINE(G_HAVE___INLINE__,1,[Have __inline__ keyword])
 712 esac
 713 AC_CACHE_CHECK([for inline], glib_cv_hasinline,[
 714         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 715         #undef inline
 716         inline int foo () { return 0; }
 717         int main () { return foo (); }
 718         ]])],
 719         glib_cv_hasinline=yes
 720         ,
 721         glib_cv_hasinline=no
 722         ,)
 723 ])
 724 case x$glib_cv_hasinline in
 725 xyes) AC_DEFINE(G_HAVE_INLINE,1,[Have inline keyword])
 726 esac
 727
 728 # if we can use inline functions in headers
 729 AC_MSG_CHECKING(if inline functions in headers work)
 730 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 731 #if defined (G_HAVE_INLINE) && defined (__GNUC__) && defined (__STRICT_ANSI__)
 732 #  undef inline
 733 #  define inline __inline__
 734 #elif !defined (G_HAVE_INLINE)
 735 #  undef inline
 736 #  if defined (G_HAVE___INLINE__)
 737 #    define inline __inline__
 738 #  elif defined (G_HAVE___INLINE)
 739 #    define inline __inline
 740 #  endif
 741 #endif
 742
 743 int glib_test_func2 (int);
 744
 745 static inline int
 746 glib_test_func1 (void) {
 747   return glib_test_func2 (1);
 748 }
 749
 750 int
 751 main (void) {
 752   int i = 1;
 753 }]])],[g_can_inline=yes],[g_can_inline=no])
 754 AC_MSG_RESULT($g_can_inline)
 755
 756 dnl *** check for working do while(0) macros ***
 757 AC_CACHE_CHECK([for working do while(0) macros], g_cv_support_dowhile_macros, [
 758         AC_TRY_COMPILE([],[
 759         #define STMT_START do
 760         #define STMT_END while(0)
 761         #define STMT_TEST STMT_START { i = 0; } STMT_END
 762         int main(void) { int i = 1; STMT_TEST; return i; }],
 763         [g_cv_support_dowhile_macros=yes],
 764         [g_cv_support_dowhile_macros=no],
 765         [g_cv_support_dowhile_macros=yes])
 766 ])
 767 if test x$g_cv_support_dowhile_macros = xyes; then
 768   AC_DEFINE(HAVE_DOWHILE_MACROS, 1, [define for working do while(0) macros])
 769 fi
 770
 771 # check for flavours of varargs macros
 772 AC_MSG_CHECKING(for ISO C99 varargs macros in C)
 773 AC_TRY_COMPILE([],[
 774 int a(int p1, int p2, int p3);
 775 #define call_a(...) a(1,__VA_ARGS__)
 776 call_a(2,3);
 777 ],g_have_iso_c_varargs=yes,g_have_iso_c_varargs=no)
 778 AC_MSG_RESULT($g_have_iso_c_varargs)
 779
 780 AC_MSG_CHECKING(for ISO C99 varargs macros in C++)
 781 if test "$CXX" = ""; then
 782 dnl No C++ compiler
 783   g_have_iso_cxx_varargs=no
 784 else
 785   AC_LANG_CPLUSPLUS
 786   AC_TRY_COMPILE([],[
 787 int a(int p1, int p2, int p3);
 788 #define call_a(...) a(1,__VA_ARGS__)
 789 call_a(2,3);
 790 ],g_have_iso_cxx_varargs=yes,g_have_iso_cxx_varargs=no)
 791   AC_LANG_C
 792 fi
 793 AC_MSG_RESULT($g_have_iso_cxx_varargs)
 794
 795 AC_MSG_CHECKING(for GNUC varargs macros)
 796 AC_TRY_COMPILE([],[
 797 int a(int p1, int p2, int p3);
 798 #define call_a(params...) a(1,params)
 799 call_a(2,3);
 800 ],g_have_gnuc_varargs=yes,g_have_gnuc_varargs=no)
 801 AC_MSG_RESULT($g_have_gnuc_varargs)
 802
 803 # check for GNUC visibility support
 804 AC_MSG_CHECKING(for GNUC visibility attribute)
 805 GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 806 void
 807 __attribute__ ((visibility ("hidden")))
 808      f_hidden (void)
 809 {
 810 }
 811 void
 812 __attribute__ ((visibility ("internal")))
 813      f_internal (void)
 814 {
 815 }
 816 void
 817 __attribute__ ((visibility ("protected")))
 818      f_protected (void)
 819 {
 820 }
 821 void
 822 __attribute__ ((visibility ("default")))
 823      f_default (void)
 824 {
 825 }
 826 int main (int argc, char **argv)
 827 {
 828         f_hidden();
 829         f_internal();
 830         f_protected();
 831         f_default();
 832         return 0;
 833 }
 834 ]])],g_have_gnuc_visibility=yes,g_have_gnuc_visibility=no)
 835 AC_MSG_RESULT($g_have_gnuc_visibility)
 836 AM_CONDITIONAL(HAVE_GNUC_VISIBILITY, [test x$g_have_gnuc_visibility = xyes])
 837
 838 AC_MSG_CHECKING([whether using Sun Studio C compiler])
 839 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#if defined(__SUNPRO_C) || (__SUNPRO_C >= 0x550)
 840 #else
 841 # include "error: this is not Sun Studio."
 842 #endif
 843 ]], [[]])], [ g_have_sunstudio_visibility=yes ], [ g_have_sunstudio_visibility=no ])
 844 AC_MSG_RESULT($g_have_sunstudio_visibility)
 845 AM_CONDITIONAL(HAVE_SUNSTUDIO_VISIBILITY, [test x$g_have_sunstudio_visibility = xyes])
 846
 847 # check for bytesex stuff
 848 AC_C_BIGENDIAN
 849 if test x$ac_cv_c_bigendian = xuniversal ; then
 850 AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __BIG_ENDIAN
 851 #else
 852 #error Not a big endian.
 853 #endif],
 854     ac_cv_c_bigendian=yes
 855     ,AC_TRY_COMPILE([#include <endian.h>], [#if __BYTE_ORDER == __LITTLE_ENDIAN
 856 #else
 857 #error Not a little endian.
 858 #endif],
 859     ac_cv_c_bigendian=no
 860     ,AC_MSG_WARN([Could not determine endianness.])))
 861 fi
 862
 863
 864 # check for header files
 865 AC_CHECK_HEADERS([dirent.h float.h limits.h pwd.h grp.h sys/param.h sys/poll.h sys/resource.h])
 866 AC_CHECK_HEADERS([sys/time.h sys/times.h sys/wait.h unistd.h values.h])
 867 AC_CHECK_HEADERS([sys/select.h sys/types.h stdint.h inttypes.h sched.h malloc.h])
 868 AC_CHECK_HEADERS([sys/vfs.h sys/vmount.h sys/statfs.h sys/statvfs.h])
 869 AC_CHECK_HEADERS([mntent.h sys/mnttab.h sys/vfstab.h sys/mntctl.h fstab.h])
 870 AC_CHECK_HEADERS([sys/uio.h sys/mkdev.h])
 871 AC_CHECK_HEADERS([linux/magic.h])
 872 AC_CHECK_HEADERS([sys/prctl.h])
 873
 874 AC_CHECK_HEADERS([sys/mount.h sys/sysctl.h], [], [],
 875 [#if HAVE_SYS_PARAM_H
 876  #include <sys/param.h>
 877  #endif
 878 ])
 879
 880 AC_CHECK_HEADERS([xlocale.h])
 881
 882 # check for structure fields
 883 AC_CHECK_MEMBERS([struct stat.st_mtimensec, struct stat.st_mtim.tv_nsec, struct stat.st_atimensec, struct stat.st_atim.tv_nsec, struct stat.st_ctimensec, struct stat.st_ctim.tv_nsec])
 884 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct statfs.f_fstypename, struct statfs.f_bavail],,, [#include <sys/types.h>
 885 #include <sys/stat.h>
 886 #include <unistd.h>
 887 #ifdef HAVE_SYS_STATFS_H
 888 #include <sys/statfs.h>
 889 #endif
 890 #ifdef HAVE_SYS_PARAM_H
 891 #include <sys/param.h>
 892 #endif
 893 #ifdef HAVE_SYS_MOUNT_H
 894 #include <sys/mount.h>
 895 #endif])
 896 # struct statvfs.f_basetype is available on Solaris but not for Linux.
 897 AC_CHECK_MEMBERS([struct statvfs.f_basetype],,, [#include <sys/statvfs.h>])
 898 AC_CHECK_MEMBERS([struct statvfs.f_fstypename],,, [#include <sys/statvfs.h>])
 899 AC_CHECK_MEMBERS([struct tm.tm_gmtoff, struct tm.__tm_gmtoff],,,[#include <time.h>])
 900
 901 AC_STRUCT_DIRENT_D_TYPE
 902
 903 # Checks for libcharset
 904 AM_LANGINFO_CODESET
 905 AC_CHECK_HEADERS([stddef.h stdlib.h string.h])
 906 AC_CHECK_FUNCS(setlocale)
 907
 908 # check additional type sizes
 909 AC_CHECK_SIZEOF(size_t)
 910
 911 dnl Try to figure out whether gsize, gssize should be long or int
 912 AC_MSG_CHECKING([for the appropriate definition for size_t])
 913
 914 case $ac_cv_sizeof_size_t in
 915   $ac_cv_sizeof_short)
 916       glib_size_type=short
 917       ;;
 918   $ac_cv_sizeof_int)
 919       glib_size_type=int
 920       ;;
 921   $ac_cv_sizeof_long)
 922       glib_size_type=long
 923       ;;
 924   $ac_cv_sizeof_long_long)
 925       glib_size_type='long long'
 926       ;;
 927   $ac_cv_sizeof__int64)
 928       glib_size_type='__int64'
 929       ;;
 930   *)  AC_MSG_ERROR([No type matching size_t in size])
 931       ;;
 932 esac
 933
 934 dnl If int/long are the same size, we see which one produces
 935 dnl warnings when used in the location as size_t. (This matters
 936 dnl on AIX with xlc)
 937 dnl
 938 if test $ac_cv_sizeof_size_t = $ac_cv_sizeof_int &&
 939    test $ac_cv_sizeof_size_t = $ac_cv_sizeof_long ; then
 940   GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 941 #if defined(_AIX) && !defined(__GNUC__)
 942 #pragma options langlvl=stdc89
 943 #endif
 944 #include <stddef.h>
 945 int main ()
 946 {
 947   size_t s = 1;
 948   unsigned int *size_int = &s;
 949   return (int)*size_int;
 950 }
 951     ]])],glib_size_type=int,
 952       [GLIB_CHECK_COMPILE_WARNINGS([AC_LANG_SOURCE([[
 953 #if defined(_AIX) && !defined(__GNUC__)
 954 #pragma options langlvl=stdc89
 955 #endif
 956 #include <stddef.h>
 957 int main ()
 958 {
 959    size_t s = 1;
 960    unsigned long *size_long = &s;
 961    return (int)*size_long;
 962 }
 963         ]])],glib_size_type=long)])
 964 fi
 965
 966 AC_MSG_RESULT(unsigned $glib_size_type)
 967
 968 # Check for some functions
 969 AC_CHECK_FUNCS(lstat strerror strsignal memmove vsnprintf stpcpy strcasecmp strncasecmp poll getcwd vasprintf setenv unsetenv getc_unlocked readlink symlink fdwalk memmem)
 970 AC_CHECK_FUNCS(chown lchmod lchown fchmod fchown link utimes getgrgid getpwuid)
 971 AC_CHECK_FUNCS(getmntent_r setmntent endmntent hasmntopt getfsstat getvfsstat)
 972 # Check for high-resolution sleep functions
 973 AC_CHECK_FUNCS(splice)
 974 AC_CHECK_FUNCS(prlimit)
 975
 976 # To avoid finding a compatibility unusable statfs, which typically
 977 # successfully compiles, but warns to use the newer statvfs interface:
 978 AS_IF([test $ac_cv_header_sys_statvfs_h = yes], [AC_CHECK_FUNCS([statvfs])])
 979 AS_IF([test $ac_cv_header_sys_statfs_h  = yes -o $ac_cv_header_sys_mount_h = yes], [AC_CHECK_FUNCS([statfs])])
 980
 981 AC_MSG_CHECKING([whether to use statfs or statvfs])
 982 # Some systems have both statfs and statvfs, pick the most "native" for these
 983 AS_IF([test x$ac_cv_func_statfs = xyes && test x$ac_cv_func_statvfs = xyes],
 984    [
 985    # on solaris and irix, statfs doesn't even have the f_bavail field
 986    AS_IF([test x$ac_cv_member_struct_statfs_f_bavail = xno],
 987       [ac_cv_func_statfs=no],
 988    # else, at least on linux, statfs is the actual syscall
 989       [ac_cv_func_statvfs=no])
 990    ])
 991
 992 AS_IF([test x$ac_cv_func_statfs = xyes],
 993       [
 994          AC_DEFINE([USE_STATFS], [1], [Define to use statfs()])
 995          AC_MSG_RESULT([statfs])
 996       ],
 997       [test x$ac_cv_func_statvfs = xyes],
 998       [
 999          AC_DEFINE([USE_STATVFS], [1], [Define to use statvfs()])
1000          AC_MSG_RESULT([statvfs])
1001       ],
1002       [  AC_MSG_RESULT([neither])])
1003
1004 AC_CHECK_HEADERS(crt_externs.h)
1005 AC_CHECK_FUNCS(_NSGetEnviron)
1006
1007 AC_CHECK_FUNCS(newlocale uselocale strtod_l strtoll_l strtoull_l)
1008
1009 AC_FUNC_VSNPRINTF_C99
1010 AC_FUNC_PRINTF_UNIX98
1011
1012 # Internet address families
1013 if test $glib_native_win32 = yes; then
1014   glib_inet_includes=["
1015 #include <winsock2.h>
1016   "]
1017 else
1018   glib_inet_includes=["
1019 #include <sys/types.h>
1020 #include <sys/socket.h>
1021   "]
1022 fi
1023
1024 glib_failed=false
1025 GLIB_CHECK_VALUE(AF_INET, $glib_inet_includes, glib_failed=true)
1026 GLIB_CHECK_VALUE(AF_INET6, $glib_inet_includes, glib_failed=true)
1027 # winsock defines this even though it doesn't support it
1028 GLIB_CHECK_VALUE(AF_UNIX, $glib_inet_includes, glib_failed=true)
1029 if $glib_failed ; then
1030   AC_MSG_ERROR([Could not determine values for AF_INET* constants])
1031 fi
1032
1033 glib_failed=false
1034 GLIB_CHECK_VALUE(MSG_PEEK, $glib_inet_includes, glib_failed=true)
1035 GLIB_CHECK_VALUE(MSG_OOB, $glib_inet_includes, glib_failed=true)
1036 GLIB_CHECK_VALUE(MSG_DONTROUTE, $glib_inet_includes, glib_failed=true)
1037 if $glib_failed ; then
1038   AC_MSG_ERROR([Could not determine values for MSG_* constants])
1039 fi
1040
1041 AC_CHECK_FUNCS(getprotobyname_r endservent if_nametoindex)
1042 AC_CHECK_HEADERS([netdb.h wspiapi.h arpa/nameser_compat.h])
1043
1044 if test $glib_native_win32 = no; then
1045   # We can't just use AC_CHECK_FUNC/AC_CHECK_LIB here. Bug 586150
1046   NETWORK_LIBS=""
1047   AC_MSG_CHECKING([for res_query])
1048   AC_TRY_LINK([#include <sys/types.h>
1049                #include <netinet/in.h>
1050                #include <arpa/nameser.h>
1051                #include <resolv.h>
1052               ],[
1053                res_query("test", 0, 0, (void *)0, 0);
1054               ],[AC_MSG_RESULT([yes])],
1055               [save_libs="$LIBS"
1056                LIBS="-lresolv $LIBS"
1057                AC_TRY_LINK([#include <sys/types.h>
1058                             #include <netinet/in.h>
1059                             #include <arpa/nameser.h>
1060                             #include <resolv.h>
1061                            ],[
1062                             res_query("test", 0, 0, (void *)0, 0);
1063                            ],[AC_MSG_RESULT([in -lresolv])
1064                               NETWORK_LIBS="-lresolv $NETWORK_LIBS"],
1065                            [LIBS="-lbind $save_libs"
1066                             AC_TRY_LINK([#include <resolv.h>],
1067                                         [res_query("test", 0, 0, (void *)0, 0);],
1068                                         [AC_MSG_RESULT([in -lbind])
1069                                          NETWORK_LIBS="-lbind $NETWORK_LIBS"],
1070                                         [AC_MSG_ERROR(not found)])])
1071                LIBS="$save_libs"])
1072   AC_CHECK_FUNC(socket, :, AC_CHECK_LIB(socket, socket,
1073                                         [NETWORK_LIBS="-lsocket $NETWORK_LIBS"],
1074                                         [AC_MSG_ERROR(Could not find socket())]))
1075 fi
1076 AC_SUBST(NETWORK_LIBS)
1077
1078 AC_CHECK_HEADER([linux/netlink.h],
1079                 [AC_DEFINE(HAVE_NETLINK, 1, [We have AF_NETLINK sockets])],,
1080                 [#include <sys/socket.h>])
1081 AM_CONDITIONAL(HAVE_NETLINK, [test "$ac_cv_header_linux_netlink_h" = "yes"])
1082
1083 AC_CHECK_TYPE([struct ip_mreqn], [
1084               AC_DEFINE(HAVE_IP_MREQN,, [Define if we have struct ip_mreqn])],,
1085               [#include <netinet/in.h>])
1086
1087 case $host in
1088   *-*-solaris* )
1089      AC_DEFINE(_XOPEN_SOURCE_EXTENDED, 1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1090      AC_DEFINE(_XOPEN_SOURCE,          2, Needed to get declarations for msg_control and msg_controllen on Solaris)
1091      AC_DEFINE(__EXTENSIONS__,         1, Needed to get declarations for msg_control and msg_controllen on Solaris)
1092      ;;
1093 esac
1094
1095 dnl
1096 dnl if statfs() takes 2 arguments (Posix) or 4 (Solaris)
1097 dnl
1098 if test "$ac_cv_func_statfs" = yes ; then
1099   AC_MSG_CHECKING([number of arguments to statfs()])
1100   AC_TRY_COMPILE([#include <unistd.h>
1101   #ifdef HAVE_SYS_PARAM_H
1102   #include <sys/param.h>
1103   #endif
1104   #ifdef HAVE_SYS_VFS_H
1105   #include <sys/vfs.h>
1106   #endif
1107   #ifdef HAVE_SYS_MOUNT_H
1108   #include <sys/mount.h>
1109   #endif
1110   #ifdef HAVE_SYS_STATFS_H
1111   #include <sys/statfs.h>
1112   #endif], [struct statfs st;
1113   statfs(NULL, &st);],[
1114     AC_MSG_RESULT([2])
1115     AC_DEFINE(STATFS_ARGS, 2, [Number of arguments to statfs()])],[
1116     AC_TRY_COMPILE([#include <unistd.h>
1117   #ifdef HAVE_SYS_PARAM_H
1118   #include <sys/param.h>
1119   #endif
1120   #ifdef HAVE_SYS_VFS_H
1121   #include <sys/vfs.h>
1122   #endif
1123   #ifdef HAVE_SYS_MOUNT_H
1124   #include <sys/mount.h>
1125   #endif
1126   #ifdef HAVE_SYS_STATFS_H
1127   #include <sys/statfs.h>
1128   #endif], [struct statfs st;
1129   statfs(NULL, &st, sizeof (st), 0);],[
1130       AC_MSG_RESULT([4])
1131       AC_DEFINE(STATFS_ARGS, 4, [Number of arguments to statfs()])],[
1132       AC_MSG_RESULT(unknown)
1133       AC_MSG_ERROR([unable to determine number of arguments to statfs()])])])
1134 fi
1135
1136 #
1137 # Check whether to use an included printf
1138 #
1139
1140 AC_ARG_ENABLE(included-printf,
1141               [AC_HELP_STRING([--enable-included-printf],
1142                               [use included printf [default=auto]])],
1143               enable_included_printf="$enableval")
1144
1145 need_included_printf=no
1146 if test "x$enable_included_printf" = "xyes" ; then
1147   need_included_printf=yes
1148 fi
1149 if test "$ac_cv_func_vsnprintf_c99" != "yes" ; then
1150   need_included_printf=yes
1151 fi
1152 if test "$ac_cv_func_printf_unix98" != "yes" ; then
1153   need_included_printf=yes
1154 fi
1155 if test "x$ac_cv_sizeof_long_long" = "x8" &&
1156    test -z "$glib_cv_long_long_format" ; then
1157   need_included_printf=yes
1158 fi
1159
1160 if test "x$enable_included_printf" = "xno" &&
1161    test "x$need_included_printf" = "xyes" ; then
1162   AC_MSG_ERROR([
1163 *** Your C library's printf doesn't appear to have the features that
1164 *** GLib needs, but you specified --enable-included-printf=no.])
1165 fi
1166
1167 enable_included_printf=$need_included_printf
1168
1169 AM_CONDITIONAL(HAVE_GOOD_PRINTF, test "$enable_included_printf" != "yes")
1170 if test "$enable_included_printf" != "yes" ; then
1171   AC_DEFINE(HAVE_GOOD_PRINTF,1,[define to use system printf])
1172 else
1173   if test -z "$glib_cv_long_long_format" ; then
1174     glib_cv_long_long_format="ll"
1175   fi
1176   AC_DEFINE(HAVE_VASPRINTF,1)
1177 fi
1178
1179 # Checks needed for gnulib vasnprintf
1180 bh_C_SIGNED
1181 jm_AC_TYPE_LONG_LONG
1182 gt_TYPE_LONGDOUBLE
1183 gt_TYPE_WCHAR_T
1184 gt_TYPE_WINT_T
1185 AC_TYPE_SIZE_T
1186 AC_CHECK_TYPES(ptrdiff_t)
1187 jm_AC_TYPE_INTMAX_T
1188 AC_CHECK_FUNCS([snprintf wcslen])
1189 AC_FUNC_SNPRINTF_C99
1190
1191 # Check if bcopy can be used for overlapping copies, if memmove isn't found.
1192 # The check is borrowed from the PERL Configure script.
1193 if test "$ac_cv_func_memmove" != "yes"; then
1194   AC_CACHE_CHECK(whether bcopy can handle overlapping copies,
1195     glib_cv_working_bcopy,[AC_TRY_RUN([
1196       int main() {
1197         char buf[128], abc[128], *b;
1198         int len, off, align;
1199         bcopy("abcdefghijklmnopqrstuvwxyz0123456789", abc, 36);
1200         for (align = 7; align >= 0; align--) {
1201           for (len = 36; len; len--) {
1202             b = buf+align; bcopy(abc, b, len);
1203             for (off = 1; off <= len; off++) {
1204               bcopy(b, b+off, len); bcopy(b+off, b, len);
1205                 if (bcmp(b, abc, len)) return(1);
1206             }
1207           }
1208         }
1209         return(0);
1210       }],glib_cv_working_bcopy=yes,glib_cv_working_bcopy=no)])
1211
1212   GLIB_ASSERT_SET(glib_cv_working_bcopy)
1213   if test "$glib_cv_working_bcopy" = "yes"; then
1214     AC_DEFINE(HAVE_WORKING_BCOPY,1,[Have a working bcopy])
1215   fi
1216 fi
1217
1218 # Check if <sys/select.h> needs to be included for fd_set
1219 AC_MSG_CHECKING([for fd_set])
1220 AC_TRY_COMPILE([#include <sys/types.h>],
1221         [fd_set readMask, writeMask;], gtk_ok=yes, gtk_ok=no)
1222 if test "$gtk_ok" = "yes"; then
1223     AC_MSG_RESULT([yes, found in sys/types.h])
1224 else
1225     AC_EGREP_HEADER(fd_set, sys/select.h, gtk_ok=yes)
1226     if test "$gtk_ok" = "yes"; then
1227         # *** FIXME: give it a different name
1228         AC_DEFINE(HAVE_SYS_SELECT_H,1,[found fd_set in sys/select.h])
1229         AC_MSG_RESULT([yes, found in sys/select.h])
1230     else
1231         AC_DEFINE(NO_FD_SET,1,[didn't find fd_set])
1232         AC_MSG_RESULT(no)
1233     fi
1234 fi
1235
1236 dnl *** check for sane realloc() ***
1237 AC_CACHE_CHECK([whether realloc (NULL,) will work],glib_cv_sane_realloc,[
1238         AC_TRY_RUN([#include <stdlib.h>
1239         int main() {
1240           return realloc (0, sizeof (int)) == 0;
1241         }],
1242         [glib_cv_sane_realloc=yes],
1243         [glib_cv_sane_realloc=no],
1244         [glib_cv_sane_realloc=yes])
1245 ])
1246 if test x$glib_cv_sane_realloc = xyes; then
1247   AC_DEFINE(REALLOC_0_WORKS,1,[whether realloc (NULL,) works])
1248 fi
1249
1250 dnl Check for nl_langinfo and CODESET
1251 AC_CACHE_CHECK([for nl_langinfo (CODESET)],glib_cv_langinfo_codeset,[
1252         AC_TRY_COMPILE([#include <langinfo.h>],
1253                 [char *codeset = nl_langinfo (CODESET);],
1254                 [glib_cv_langinfo_codeset=yes],
1255                 [glib_cv_langinfo_codeset=no])])
1256 if test x$glib_cv_langinfo_codeset = xyes; then
1257   AC_DEFINE(HAVE_CODESET,1,[Have nl_langinfo (CODESET)])
1258 fi
1259
1260 dnl Check for nl_langinfo and LC_TIME parts that are needed in gdatetime.c
1261 AC_CACHE_CHECK([for nl_langinfo (PM_STR)],glib_cv_langinfo_time,[
1262         AC_TRY_COMPILE([#include <langinfo.h>],
1263                 [char *str;
1264                  str = nl_langinfo (PM_STR);
1265                  str = nl_langinfo (D_T_FMT);
1266                  str = nl_langinfo (D_FMT);
1267                  str = nl_langinfo (T_FMT);
1268                  str = nl_langinfo (T_FMT_AMPM);
1269                  str = nl_langinfo (MON_1);
1270                  str = nl_langinfo (ABMON_12);
1271                  str = nl_langinfo (DAY_1);
1272                  str = nl_langinfo (ABDAY_7);],
1273                 [glib_cv_langinfo_time=yes],
1274                 [glib_cv_langinfo_time=no])])
1275 if test x$glib_cv_langinfo_time = xyes; then
1276   AC_DEFINE(HAVE_LANGINFO_TIME,1,[Have nl_langinfo (PM_STR)])
1277 fi
1278
1279 dnl Check for nl_langinfo and _NL_CTYPE_OUTDIGITn_MB
1280 AC_CACHE_CHECK([for nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)], glib_cv_langinfo_outdigit,[
1281         AC_TRY_COMPILE([#include <langinfo.h>],
1282                 [char *str;
1283                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT0_MB);
1284                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT1_MB);
1285                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT2_MB);
1286                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT3_MB);
1287                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT4_MB);
1288                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT5_MB);
1289                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT6_MB);
1290                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT7_MB);
1291                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT8_MB);
1292                  str = nl_langinfo (_NL_CTYPE_OUTDIGIT9_MB);],
1293                 [glib_cv_langinfo_outdigit=yes],
1294                 [glib_cv_langinfo_outdigit=no])])
1295 if test x$glib_cv_langinfo_outdigit = xyes; then
1296   AC_DEFINE(HAVE_LANGINFO_OUTDIGIT,1,[Have nl_langinfo (_NL_CTYPE_OUTDIGITn_MB)])
1297 fi
1298
1299 dnl ****************************************
1300 dnl *** posix_memalign                   ***
1301 dnl ****************************************
1302 AC_MSG_CHECKING(for a compliant posix_memalign() implementation)
1303 AC_CACHE_VAL(glib_cv_compliant_posix_memalign,[
1304     glib_cv_compliant_posix_memalign=0
1305     if test "$ac_cv_func_posix_memalign" = "yes" ; then
1306         AC_TRY_RUN([
1307                 #define _XOPEN_SOURCE 600
1308                 #include <stdlib.h> /* posix_memalign() should be defined here */
1309                 /* some systems break if #include <malloc.h> used */
1310                 static void test_memalign (size_t boundary, size_t size) {
1311                     void *mem = 0;
1312                     if (posix_memalign (&mem, boundary, size) != 0 || !mem)
1313                         exit (1);
1314                     else
1315                       free (mem);
1316                 }
1317                 int main() {
1318                     test_memalign (  128,   128 - 2 * sizeof (void*));
1319                     test_memalign (  256,   256 - 2 * sizeof (void*));
1320                     test_memalign (  512,   512 - 2 * sizeof (void*));
1321                     test_memalign ( 1024,  1024 - 2 * sizeof (void*));
1322                     test_memalign ( 2048,  2048 - 2 * sizeof (void*));
1323                     test_memalign ( 4096,  4096 - 2 * sizeof (void*));
1324                     test_memalign ( 8192,  8192 - 2 * sizeof (void*));
1325                     test_memalign (16384, 16384 - 2 * sizeof (void*));
1326                     test_memalign (32768, 32768 - 2 * sizeof (void*));
1327                     exit (0); /* success */
1328                 }
1329                 ],
1330             [glib_cv_compliant_posix_memalign=1], [], [:])
1331       :
1332     fi
1333     ])
1334 if test "$glib_cv_compliant_posix_memalign" = "1"; then
1335     AC_MSG_RESULT(yes)
1336     AC_DEFINE(POSIX_MEMALIGN_WITH_COMPLIANT_ALLOCS, 1, [define if posix_memalign() can allocate any size])
1337 else
1338     AC_MSG_RESULT(no)
1339 fi
1340
1341
1342 dnl ****************************************
1343 dnl *** strlcpy/strlcat                  ***
1344 dnl ****************************************
1345 # Check for strlcpy
1346 AC_CACHE_CHECK([for OpenBSD strlcpy/strlcat],glib_cv_have_strlcpy,[
1347 AC_TRY_RUN([#include <stdlib.h>
1348 #include <string.h>
1349 int main() {
1350   char p[10];
1351   (void) strlcpy (p, "hi", 10);
1352   if (strlcat (p, "bye", 0) != 3)
1353     return 1;
1354   return 0;
1355 }], glib_cv_have_strlcpy=yes,
1356     glib_cv_have_strlcpy=no,
1357     glib_cv_have_strlcpy=no)])
1358 if test "$glib_cv_have_strlcpy" = "yes"; then
1359     AC_DEFINE(HAVE_STRLCPY,1,[Have functions strlcpy and strlcat])
1360 fi
1361
1362
1363 dnl **********************
1364 dnl *** va_copy checks ***
1365 dnl **********************
1366 dnl we currently check for all three va_copy possibilities, so we get
1367 dnl all results in config.log for bug reports.
1368 AC_CACHE_CHECK([for an implementation of va_copy()],glib_cv_va_copy,[
1369         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1370 #include <stdlib.h>
1371         void f (int i, ...) {
1372         va_list args1, args2;
1373         va_start (args1, i);
1374         va_copy (args2, args1);
1375         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1376           exit (1);
1377         va_end (args1); va_end (args2);
1378         }
1379         int main() {
1380           f (0, 42);
1381           return 0;
1382         }]])],
1383         [glib_cv_va_copy=yes],
1384         [glib_cv_va_copy=no])
1385 ])
1386 AC_CACHE_CHECK([for an implementation of __va_copy()],glib_cv___va_copy,[
1387         AC_LINK_IFELSE([AC_LANG_SOURCE([[#include <stdarg.h>
1388 #include <stdlib.h>
1389         void f (int i, ...) {
1390         va_list args1, args2;
1391         va_start (args1, i);
1392         __va_copy (args2, args1);
1393         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1394           exit (1);
1395         va_end (args1); va_end (args2);
1396         }
1397         int main() {
1398           f (0, 42);
1399           return 0;
1400         }]])],
1401         [glib_cv___va_copy=yes],
1402         [glib_cv___va_copy=no])
1403 ])
1404
1405 if test "x$glib_cv_va_copy" = "xyes"; then
1406   g_va_copy_func=va_copy
1407 else if test "x$glib_cv___va_copy" = "xyes"; then
1408   g_va_copy_func=__va_copy
1409 fi
1410 fi
1411
1412 if test -n "$g_va_copy_func"; then
1413   AC_DEFINE_UNQUOTED(G_VA_COPY,$g_va_copy_func,[A 'va_copy' style function])
1414 fi
1415
1416 AC_CACHE_CHECK([whether va_lists can be copied by value],glib_cv_va_val_copy,[
1417         AC_TRY_RUN([#include <stdarg.h>
1418 #include <stdlib.h>
1419         void f (int i, ...) {
1420         va_list args1, args2;
1421         va_start (args1, i);
1422         args2 = args1;
1423         if (va_arg (args2, int) != 42 || va_arg (args1, int) != 42)
1424           exit (1);
1425         va_end (args1); va_end (args2);
1426         }
1427         int main() {
1428           f (0, 42);
1429           return 0;
1430         }],
1431         [glib_cv_va_val_copy=yes],
1432         [glib_cv_va_val_copy=no],
1433         [glib_cv_va_val_copy=yes])
1434 ])
1435
1436 if test "x$glib_cv_va_val_copy" = "xno"; then
1437   AC_DEFINE(G_VA_COPY_AS_ARRAY,1, ['va_lists' cannot be copies as values])
1438 fi
1439
1440 dnl ***********************
1441 dnl *** g_module checks ***
1442 dnl ***********************
1443 G_MODULE_LIBS=
1444 G_MODULE_LIBS_EXTRA=
1445 G_MODULE_PLUGIN_LIBS=
1446 if test x"$glib_native_win32" = xyes; then
1447   dnl No use for this on Win32
1448   G_MODULE_LDFLAGS=
1449 else
1450   export SED
1451   G_MODULE_LDFLAGS=`(./libtool --config; echo eval echo \\$export_dynamic_flag_spec) | sh`
1452 fi
1453 dnl G_MODULE_IMPL= don't reset, so cmd-line can override
1454 G_MODULE_NEED_USCORE=0
1455 G_MODULE_BROKEN_RTLD_GLOBAL=0
1456 G_MODULE_HAVE_DLERROR=0
1457 dnl *** force native WIN32 shared lib loader
1458 if test -z "$G_MODULE_IMPL"; then
1459   case "$host" in
1460   *-*-mingw*|*-*-cygwin*) G_MODULE_IMPL=G_MODULE_IMPL_WIN32 ;;
1461   esac
1462 fi
1463 dnl *** force native AIX library loader
1464 dnl *** dlopen() filepath must be of the form /path/libname.a(libname.so)
1465 if test -z "$G_MODULE_IMPL"; then
1466   case "$host" in
1467   *-*-aix*) G_MODULE_IMPL=G_MODULE_IMPL_AR ;;
1468   esac
1469 fi
1470 dnl *** dlopen() and dlsym() in system libraries
1471 if test -z "$G_MODULE_IMPL"; then
1472         AC_CHECK_FUNC(dlopen,
1473                       [AC_CHECK_FUNC(dlsym,
1474                                      [G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1475                       [])
1476 fi
1477 dnl *** load_image (BeOS)
1478 if test -z "$G_MODULE_IMPL" && test "x$glib_native_beos" = "xyes"; then
1479   AC_CHECK_LIB(root, load_image,
1480       [G_MODULE_LIBS="-lbe -lroot -lglib-2.0 "
1481       G_MODULE_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
1482       G_MODULE_PLUGIN_LIBS="-L\$(top_builddir_full)/gmodule/.libs -lgmodule"
1483       G_MODULE_IMPL=G_MODULE_IMPL_BEOS],
1484       [])
1485 fi
1486 dnl *** NSLinkModule (dyld) in system libraries (Darwin)
1487 if test -z "$G_MODULE_IMPL"; then
1488         AC_CHECK_FUNC(NSLinkModule,
1489                       [G_MODULE_IMPL=G_MODULE_IMPL_DYLD
1490                        G_MODULE_NEED_USCORE=1],
1491                       [])
1492 fi
1493 dnl *** dlopen() and dlsym() in libdl
1494 if test -z "$G_MODULE_IMPL"; then
1495         AC_CHECK_LIB(dl, dlopen,
1496                      [AC_CHECK_LIB(dl, dlsym,
1497                                    [G_MODULE_LIBS=-ldl
1498                                    G_MODULE_IMPL=G_MODULE_IMPL_DL],[])],
1499                      [])
1500 fi
1501 dnl *** shl_load() in libdld (HP-UX)
1502 if test -z "$G_MODULE_IMPL"; then
1503         AC_CHECK_LIB(dld, shl_load,
1504                 [G_MODULE_LIBS=-ldld
1505                 G_MODULE_IMPL=G_MODULE_IMPL_DLD],
1506                 [])
1507 fi
1508 dnl *** additional checks for G_MODULE_IMPL_DL
1509 if test "$G_MODULE_IMPL" = "G_MODULE_IMPL_DL"; then
1510         LIBS_orig="$LIBS"
1511         LDFLAGS_orig="$LDFLAGS"
1512         LIBS="$G_MODULE_LIBS $LIBS"
1513         LDFLAGS="$LDFLAGS $G_MODULE_LDFLAGS"
1514 dnl *** check for OSF1/5.0 RTLD_GLOBAL brokenness
1515         echo "void glib_plugin_test(void) { }" > plugin.c
1516         ${SHELL} ./libtool --mode=compile --tag=CC ${CC} ${CFLAGS} \
1517                 ${CPPFLAGS} -c -o plugin.lo plugin.c >/dev/null 2>&1
1518         ${SHELL} ./libtool --mode=link --tag=CC ${CC} ${CFLAGS} \
1519                 ${LDFLAGS} -module -o plugin.la -export-dynamic \
1520                 -shrext ".o" -avoid-version plugin.lo \
1521                 -rpath /dont/care >/dev/null 2>&1
1522         eval `./libtool --config | grep ^objdir`
1523         AC_CACHE_CHECK([for RTLD_GLOBAL brokenness],
1524                 glib_cv_rtldglobal_broken,[
1525                 AC_TRY_RUN([
1526 #include <dlfcn.h>
1527 #ifndef RTLD_GLOBAL
1528 #  define RTLD_GLOBAL 0
1529 #endif
1530 #ifndef RTLD_LAZY
1531 #  define RTLD_LAZY 0
1532 #endif
1533 int glib_plugin_test;
1534 int main () {
1535     void *handle, *global, *local;
1536     global = &glib_plugin_test;
1537     handle = dlopen ("./$objdir/plugin.o", RTLD_GLOBAL | RTLD_LAZY);
1538     if (!handle) return 0;
1539     local = dlsym (handle, "glib_plugin_test");
1540     return global == local;
1541 }                       ],
1542                         [glib_cv_rtldglobal_broken=no],
1543                         [glib_cv_rtldglobal_broken=yes],
1544                         [glib_cv_rtldglobal_broken=no])
1545                 rm -f plugin.c plugin.o plugin.lo plugin.la ${objdir}/plugin.*
1546                 rmdir ${objdir} 2>/dev/null
1547         ])
1548         if test "x$glib_cv_rtldglobal_broken" = "xyes"; then
1549                 G_MODULE_BROKEN_RTLD_GLOBAL=1
1550         else
1551                 G_MODULE_BROKEN_RTLD_GLOBAL=0
1552         fi
1553 dnl *** check whether we need preceeding underscores
1554         AC_CACHE_CHECK([for preceeding underscore in symbols],
1555                 glib_cv_uscore,[
1556                 AC_TRY_RUN([#include <dlfcn.h>
1557                 int glib_underscore_test (void) { return 42; }
1558                 int main() {
1559                   void *f1 = (void*)0, *f2 = (void*)0, *handle;
1560                   handle = dlopen ((void*)0, 0);
1561                   if (handle) {
1562                     f1 = dlsym (handle, "glib_underscore_test");
1563                     f2 = dlsym (handle, "_glib_underscore_test");
1564                   } return (!f2 || f1);
1565                 }],
1566                         [glib_cv_uscore=yes],
1567                         [glib_cv_uscore=no],
1568                         [])
1569                 rm -f plugin.c plugin.$ac_objext plugin.lo
1570         ])
1571         GLIB_ASSERT_SET(glib_cv_uscore)
1572         if test "x$glib_cv_uscore" = "xyes"; then
1573                 G_MODULE_NEED_USCORE=1
1574         else
1575                 G_MODULE_NEED_USCORE=0
1576         fi
1577
1578         LDFLAGS="$LDFLAGS_orig"
1579 dnl *** check for having dlerror()
1580         AC_CHECK_FUNC(dlerror,
1581                 [G_MODULE_HAVE_DLERROR=1],
1582                 [G_MODULE_HAVE_DLERROR=0])
1583         LIBS="$LIBS_orig"
1584 fi
1585 dnl *** done, have we got an implementation?
1586 if test -z "$G_MODULE_IMPL"; then
1587         G_MODULE_IMPL=0
1588         G_MODULE_SUPPORTED=false
1589 else
1590         G_MODULE_SUPPORTED=true
1591 fi
1592
1593 AC_MSG_CHECKING(for the suffix of module shared libraries)
1594 export SED
1595 shrext_cmds=`./libtool --config | grep '^shrext_cmds='`
1596 eval $shrext_cmds
1597 module=yes eval std_shrext=$shrext_cmds
1598 # chop the initial dot
1599 glib_gmodule_suffix=`echo $std_shrext | sed 's/^\.//'`
1600 AC_MSG_RESULT(.$glib_gmodule_suffix)
1601 # any reason it may fail?
1602 if test "x$glib_gmodule_suffix" = x; then
1603         AC_MSG_ERROR(Cannot determine shared library suffix from libtool)
1604 fi
1605
1606 AC_SUBST(G_MODULE_SUPPORTED)
1607 AC_SUBST(G_MODULE_IMPL)
1608 AC_SUBST(G_MODULE_LIBS)
1609 AC_SUBST(G_MODULE_LIBS_EXTRA)
1610 AC_SUBST(G_MODULE_PLUGIN_LIBS)
1611 AC_SUBST(G_MODULE_LDFLAGS)
1612 AC_SUBST(G_MODULE_HAVE_DLERROR)
1613 AC_SUBST(G_MODULE_BROKEN_RTLD_GLOBAL)
1614 AC_SUBST(G_MODULE_NEED_USCORE)
1615 AC_SUBST(GLIB_DEBUG_FLAGS)
1616
1617 dnl **********************
1618 dnl *** g_spawn checks ***
1619 dnl **********************
1620
1621 AC_MSG_CHECKING(for gspawn implementation)
1622 case "$host" in
1623   *-*-mingw*)
1624     GSPAWN=gspawn-win32.lo
1625     ;;
1626   *)
1627     GSPAWN=gspawn.lo
1628     ;;
1629 esac
1630 AC_MSG_RESULT($GSPAWN)
1631 AC_SUBST(GSPAWN)
1632
1633 dnl *************************
1634 dnl *** GIOChannel checks ***
1635 dnl *************************
1636
1637 AC_MSG_CHECKING(for GIOChannel implementation)
1638 case "$host" in
1639   *-*-mingw*)
1640     GIO=giowin32.lo
1641     ;;
1642   *)
1643     GIO=giounix.lo
1644     ;;
1645 esac
1646 AC_MSG_RESULT($GIO)
1647 AC_SUBST(GIO)
1648
1649 dnl *********************************
1650 dnl *** Directory for GIO modules ***
1651 dnl *********************************
1652
1653 AC_ARG_WITH(gio-module-dir,
1654            [AC_HELP_STRING([--with-gio-module-dir=DIR],
1655                            [load gio modules from this directory [LIBDIR/gio/modules]])],
1656            [],
1657            [with_gio_module_dir='${libdir}/gio/modules'])
1658 GIO_MODULE_DIR=$with_gio_module_dir
1659 AC_SUBST(GIO_MODULE_DIR)
1660
1661 dnl **********************************
1662 dnl *** Check for libselinux (GIO) ***
1663 dnl **********************************
1664 AC_ARG_ENABLE(selinux,
1665               AC_HELP_STRING([--disable-selinux],
1666                              [build without selinux support]))
1667 msg_selinux=no
1668 SELINUX_LIBS=
1669 if test "x$enable_selinux" != "xno"; then
1670
1671  AC_CHECK_LIB(selinux, is_selinux_enabled,
1672    [AC_CHECK_HEADERS(selinux/selinux.h,
1673      [AC_CHECK_LIB(selinux, lgetfilecon_raw,
1674        [AC_DEFINE(HAVE_SELINUX, 1, [Define to 1 if libselinux is available])
1675         SELINUX_LIBS="-lselinux"
1676         msg_selinux=yes])
1677      ])
1678    ])
1679 fi
1680 AC_SUBST(SELINUX_LIBS)
1681
1682 dnl *****************************
1683 dnl ** Check for inotify (GIO) **
1684 dnl *****************************
1685 inotify_support=no
1686 AC_CHECK_HEADERS([sys/inotify.h],
1687 [
1688         inotify_support=yes
1689         AC_CHECK_FUNCS(inotify_init1)
1690 ])
1691
1692 AM_CONDITIONAL(HAVE_INOTIFY, [test "$inotify_support" = "yes"])
1693
1694 dnl *********************************
1695 dnl ** Check for Solaris FEN (GIO) **
1696 dnl *********************************
1697 fen_support=no
1698 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
1699 #include <port.h>
1700 #ifndef PORT_SOURCE_FILE
1701 #error "Please upgrade to Nevada 72 or above to suppoert FEN"
1702 #endif
1703 int main() { return 0; } ]])],
1704 [
1705         fen_support=yes
1706 ],)
1707
1708 AM_CONDITIONAL(HAVE_FEN, [test "$fen_support" = "yes"])
1709
1710 dnl ****************************
1711 dnl *** Checks for FAM (GIO) ***
1712 dnl ****************************
1713
1714 should_disable_fam=no
1715
1716 AC_ARG_ENABLE(fam,
1717               AC_HELP_STRING([--disable-fam],
1718                              [don't use fam for file system monitoring]),
1719                          [
1720                                 if test "x$enable_fam" = "xno"; then
1721                                         should_disable_fam=yes
1722                                 fi
1723                          ]
1724                          )
1725 fam_support=no
1726 FAM_LIBS=
1727 if test "x$should_disable_fam" = "xno"; then
1728 AC_CHECK_LIB(fam, FAMOpen,
1729   [AC_CHECK_HEADERS(fam.h,
1730     [AC_DEFINE(HAVE_FAM, [], [Define if we have FAM])
1731      AC_CHECK_LIB(fam, FAMNoExists,
1732                   AC_DEFINE(HAVE_FAM_NO_EXISTS, [], [Define if we have FAMNoExists in fam]))
1733      FAM_LIBS="-lfam"]
1734      fam_support=yes,
1735     AC_MSG_WARN(*** FAM support will not be built (header files not found) ***))],
1736   AC_MSG_WARN(*** FAM support will not be built (FAM library not found) ***))
1737 AC_SUBST(FAM_LIBS)
1738 fi
1739 AM_CONDITIONAL(HAVE_FAM, [test "$fam_support" = "yes"])
1740
1741
1742 dnl *****************************
1743 dnl *** Check for xattr (GIO) ***
1744 dnl *****************************
1745 AC_ARG_ENABLE(xattr,
1746               AC_HELP_STRING([--disable-xattr], [build without xattr support]))
1747 msg_xattr=no
1748 XATTR_LIBS=
1749 if test "x$enable_xattr" != "xno"; then
1750
1751 dnl either glibc or libattr can provide xattr support
1752
1753 dnl for both of them, we check for getxattr being in
1754 dnl the library and a valid xattr header.
1755
1756 dnl try glibc
1757  AC_CHECK_LIB(c, getxattr,
1758    [AC_CHECK_HEADERS(sys/xattr.h,
1759      [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1760       msg_xattr=yes])
1761    ])
1762
1763   if test "x$msg_xattr" != "xyes"; then
1764 dnl   failure. try libattr
1765    AC_CHECK_LIB(attr, getxattr,
1766       [AC_CHECK_HEADERS(attr/xattr.h,
1767        [AC_DEFINE(HAVE_XATTR, 1, [Define to 1 if xattr is available])
1768         XATTR_LIBS="-lattr"
1769         msg_xattr=yes])
1770       ])
1771   fi
1772
1773   if test "x$msg_xattr" = "xyes"; then
1774     AC_MSG_CHECKING([for XATTR_NOFOLLOW])
1775     AC_TRY_COMPILE([
1776       #include <stdio.h>
1777       #ifdef HAVE_SYS_TYPES_H
1778       #include <sys/types.h>
1779       #endif
1780       #ifdef HAVE_SYS_XATTR_H
1781       #include <sys/xattr.h>
1782       #elif HAVE_ATTR_XATTR_H
1783       #include <attr/xattr.h>
1784       #endif
1785     ],
1786     [ssize_t len = getxattr("", "", NULL, 0, 0, XATTR_NOFOLLOW);],
1787     [
1788       AC_DEFINE([HAVE_XATTR_NOFOLLOW], [1], [Define to 1 if xattr API uses XATTR_NOFOLLOW])
1789       AC_MSG_RESULT([yes])
1790     ],
1791     [AC_MSG_RESULT([no])]
1792     )
1793   fi
1794
1795 fi
1796 AC_SUBST(XATTR_LIBS)
1797
1798 dnl ************************
1799 dnl *** check for libelf ***
1800 dnl ************************
1801
1802 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [
1803   AC_CHECK_LIB([elf], [elf_begin], have_libelf=yes, have_libelf=no)
1804   ])
1805 if test $have_libelf = yes; then
1806   AC_DEFINE(HAVE_LIBELF, 1, [Define if libelf is available])
1807   LIBELF_LIBS=-lelf
1808 fi
1809
1810 dnl ****************************************
1811 dnl *** platform dependent source checks ***
1812 dnl ****************************************
1813
1814 AC_MSG_CHECKING(for platform-dependent source)
1815 case "$host" in
1816   *-*-cygwin*|*-*-mingw*)
1817     PLATFORMDEP=gwin32.lo
1818     ;;
1819   *)
1820     PLATFORMDEP=
1821     ;;
1822 esac
1823 AC_MSG_RESULT($PLATFORMDEP)
1824 AC_SUBST(PLATFORMDEP)
1825
1826 AC_MSG_CHECKING([whether to compile timeloop])
1827 case "$host" in
1828   *-*-cygwin*|*-*-mingw*|*-*-minix)
1829     enable_timeloop=no
1830     ;;
1831   *)
1832     enable_timeloop=yes
1833     ;;
1834 esac
1835 AC_MSG_RESULT($enable_timeloop)
1836 AM_CONDITIONAL(ENABLE_TIMELOOP, test x$enable_timeloop = xyes)
1837
1838 AC_MSG_CHECKING([if building for some Win32 platform])
1839 case "$host" in
1840   *-*-mingw*|*-*-cygwin*)
1841     platform_win32=yes
1842     ;;
1843   *)
1844     platform_win32=no
1845     ;;
1846 esac
1847 AC_MSG_RESULT($platform_win32)
1848 AM_CONDITIONAL(PLATFORM_WIN32, test x$platform_win32 = xyes)
1849
1850 dnl ***********************
1851 dnl *** g_thread checks ***
1852 dnl ***********************
1853
1854 AC_ARG_WITH(threads,
1855            [AC_HELP_STRING([--with-threads=@<:@posix/win32@:>@],
1856                            [specify a thread implementation to use])],
1857            [],
1858            [with_threads=yes])
1859
1860 dnl error and warning message
1861 dnl *************************
1862
1863 THREAD_NO_IMPLEMENTATION="No thread implementation found."
1864
1865 FLAG_DOES_NOT_WORK="I can't find the MACRO to enable thread safety on your
1866                 platform (normally it's "_REENTRANT"). I'll not use any flag on
1867                 compilation now, but then your programs might not work.
1868                 Please provide information on how it is done on your system."
1869
1870 LIBS_NOT_FOUND_1="I can't find the libraries for the thread implementation
1871                  "
1872
1873 LIBS_NOT_FOUND_2=". Please choose another thread implementation or
1874                   provide information on your thread implementation."
1875
1876 FUNC_NO_GETPWUID_R="the 'g_get_(user_name|real_name|home_dir|tmp_dir)'
1877                 functions will not be MT-safe during their first call because
1878                 there is no working 'getpwuid_r' on your system."
1879
1880 FUNC_NO_LOCALTIME_R="the 'g_date_set_time' function will not be MT-safe
1881                 because there is no 'localtime_r' on your system."
1882
1883 AIX_COMPILE_INFO="AIX's C compiler needs to be called by a different name, when
1884                 linking threaded applications. As GLib cannot do that
1885                 automatically, you will get an linkg error everytime you are
1886                 not using the right compiler. In that case you have to relink
1887                 with the right compiler. Ususally just '_r' is appended
1888                 to the compiler name."
1889
1890 dnl determination of thread implementation
1891 dnl ***************************************
1892
1893 AC_MSG_CHECKING(for thread implementation)
1894
1895 have_threads=no
1896 if test "x$with_threads" = xyes || test "x$with_threads" = xposix; then
1897         # -D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE is for DG/UX
1898         # -U_OSF_SOURCE is for Digital UNIX 4.0d
1899         GTHREAD_COMPILE_IMPL_DEFINES="-D_POSIX4_DRAFT_SOURCE -D_POSIX4A_DRAFT10_SOURCE -U_OSF_SOURCE"
1900         glib_save_CPPFLAGS="$CPPFLAGS"
1901         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
1902         if test "x$have_threads" = xno; then
1903                 AC_TRY_COMPILE([#include <pthread.h>],
1904                         [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1905                         have_threads=posix)
1906         fi
1907         # Tru64Unix requires -pthread to find pthread.h. See #103020
1908         CPPFLAGS="$CPPFLAGS -pthread"
1909         if test "x$have_threads" = xno; then
1910         AC_TRY_COMPILE([#include <pthread.h>],
1911                        [pthread_mutex_t m = PTHREAD_MUTEX_INITIALIZER;],
1912                        have_threads=posix)
1913         fi
1914         CPPFLAGS="$glib_save_CPPFLAGS"
1915 fi
1916 if test "x$with_threads" = xyes || test "x$with_threads" = xwin32; then
1917         case $host in
1918                 *-*-mingw*)
1919                 have_threads=win32
1920                 ;;
1921         esac
1922 fi
1923
1924 if test "x$have_threads" = xno; then
1925         AC_MSG_RESULT(none available)
1926         AC_MSG_ERROR($THREAD_NO_IMPLEMENTATION)
1927 else
1928         AC_MSG_RESULT($have_threads)
1929 fi
1930
1931
1932 dnl determination of G_THREAD_CFLAGS
1933 dnl ********************************
1934
1935 G_THREAD_LIBS=
1936 G_THREAD_LIBS_EXTRA=
1937 G_THREAD_CFLAGS=
1938
1939 dnl
1940 dnl Test program for basic POSIX threads functionality
1941 dnl
1942 m4_define([glib_thread_test],[
1943 #include <pthread.h>
1944 int check_me = 0;
1945 void* func(void* data) {check_me = 42; return &check_me;}
1946 int main()
1947  { pthread_t t;
1948    void *ret;
1949    pthread_create (&t, $1, func, 0);
1950    pthread_join (t, &ret);
1951    return (check_me != 42 || ret != &check_me);
1952 }])
1953
1954 if test x"$have_threads" = xposix; then
1955   # First we test for posix, whether -pthread or -pthreads do the trick as
1956   # both CPPFLAG and LIBS.
1957   # One of them does for most gcc versions and some other platforms/compilers
1958   # too and could be considered as the canonical way to go.
1959   case $host in
1960     *-*-cygwin*|*-*-darwin*)
1961        # skip cygwin and darwin -pthread or -pthreads test
1962        ;;
1963     *-solaris*)
1964       # These compiler/linker flags work with both Sun Studio and gcc
1965       # Sun Studio expands -mt to -D_REENTRANT and -lthread
1966       # gcc expands -pthreads to -D_REENTRANT -D_PTHREADS -lpthread
1967       G_THREAD_CFLAGS="-D_REENTRANT -D_PTHREADS"
1968       G_THREAD_LIBS="-lpthread -lthread"
1969       ;;
1970     *)
1971       for flag in pthread pthreads mt; do
1972         glib_save_CFLAGS="$CFLAGS"
1973         CFLAGS="$CFLAGS -$flag"
1974         AC_TRY_RUN(glib_thread_test(0),
1975                    glib_flag_works=yes,
1976                    glib_flag_works=no,
1977                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test(0))],
1978                                    glib_flag_works=yes,
1979                                    glib_flag_works=no)])
1980         CFLAGS="$glib_save_CFLAGS"
1981         if test $glib_flag_works = yes ; then
1982            G_THREAD_CFLAGS=-$flag
1983         G_THREAD_LIBS=-$flag
1984         break;
1985         fi
1986       done
1987        ;;
1988   esac
1989 fi
1990
1991 if test x"$G_THREAD_CFLAGS" = x; then
1992
1993   # The canonical -pthread[s] does not work. Try something different.
1994
1995   case $host in
1996         *-aix*)
1997                 if test x"$GCC" = xyes; then
1998                         # GCC 3.0 and above needs -pthread.
1999                         # Should be coverd by the case above.
2000                         # GCC 2.x and below needs -mthreads
2001                         G_THREAD_CFLAGS="-mthreads"
2002                         G_THREAD_LIBS=$G_THREAD_CFLAGS
2003                 else
2004                         # We are probably using the aix compiler. Normaly a
2005                         # program would have to be compiled with the _r variant
2006                         # of the corresponding compiler, but we as GLib cannot
2007                         # do that: but the good news is that for compiling the
2008                         # only difference is the added -D_THREAD_SAFE compile
2009                         # option. This is according to the "C for AIX User's
2010                         # Guide".
2011                         G_THREAD_CFLAGS="-D_THREAD_SAFE"
2012                 fi
2013                 ;;
2014         *-dg-dgux*)  # DG/UX
2015                 G_THREAD_CFLAGS="-D_REENTRANT -D_POSIX4A_DRAFT10_SOURCE"
2016                 ;;
2017         *-sysv5uw7*) # UnixWare 7
2018                 # We are not using gcc with -pthread. Catched above.
2019                 G_THREAD_CFLAGS="-Kthread"
2020                 G_THREAD_LIBS=$G_THREAD_CFLAGS
2021                 ;;
2022         *-mingw*)
2023                 # No flag needed when using MSVCRT.DLL
2024                 G_THREAD_CFLAGS=""
2025                 ;;
2026         *)
2027                 G_THREAD_CFLAGS="-D_REENTRANT" # good default guess otherwise
2028                 ;;
2029   esac
2030
2031 fi
2032
2033 # if we are not finding the localtime_r function, then we probably are
2034 # not using the proper multithread flag
2035
2036 glib_save_CPPFLAGS="$CPPFLAGS"
2037 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2038
2039 # First we test, whether localtime_r is declared in time.h
2040 # directly. Then we test whether a macro localtime_r exists, in
2041 # which case localtime_r in the test program is replaced and thus
2042 # if we still find localtime_r in the output, it is not defined as
2043 # a macro.
2044
2045 AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>], ,
2046   [AC_EGREP_CPP([[^a-zA-Z1-9_]localtime_r[^a-zA-Z1-9_]], [#include <time.h>
2047                                                            localtime_r(a,b)],
2048                    AC_MSG_WARN($FLAG_DOES_NOT_WORK))])
2049
2050 CPPFLAGS="$glib_save_CPPFLAGS"
2051
2052 AC_MSG_CHECKING(thread related cflags)
2053 AC_MSG_RESULT($G_THREAD_CFLAGS)
2054 CPPFLAGS="$CPPFLAGS $G_THREAD_CFLAGS"
2055
2056 dnl determination of G_THREAD_LIBS
2057 dnl ******************************
2058
2059 case $have_threads in
2060         posix)
2061           glib_save_CPPFLAGS="$CPPFLAGS"
2062           CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2063           if test x"$G_THREAD_LIBS" = x; then
2064             case $host in
2065               *-aix*)
2066                 # We are not using gcc (would have set G_THREAD_LIBS) and thus
2067                 # probably using the aix compiler.
2068                 AC_MSG_WARN($AIX_COMPILE_INFO)
2069                 ;;
2070               *)
2071                 G_THREAD_LIBS=error
2072                 glib_save_LIBS="$LIBS"
2073                 for thread_lib in "" pthread pthread32 pthreads thread; do
2074                         if test x"$thread_lib" = x; then
2075                                 add_thread_lib=""
2076                                 IN=""
2077                         else
2078                                 add_thread_lib="-l$thread_lib"
2079                                 IN=" in -l$thread_lib"
2080                         fi
2081                         if test x"$have_threads" = xposix; then
2082                                 defattr=0
2083                         else
2084                                 defattr=pthread_attr_default
2085                         fi
2086
2087                         LIBS="$add_thread_lib $glib_save_LIBS"
2088
2089                         AC_MSG_CHECKING(for pthread_create/pthread_join$IN)
2090                         AC_TRY_RUN(glib_thread_test($defattr),
2091                                    glib_result=yes,
2092                                    glib_result=no,
2093                                    [AC_LINK_IFELSE([AC_LANG_SOURCE(glib_thread_test($defattr))],
2094                                                    glib_result=yes,
2095                                                    glib_result=no)])
2096                         AC_MSG_RESULT($glib_result)
2097
2098                         if test "$glib_result" = "yes" ; then
2099                           G_THREAD_LIBS="$add_thread_lib"
2100                           break
2101                         fi
2102                 done
2103                 if test "x$G_THREAD_LIBS" = xerror; then
2104                   AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2105                 fi
2106                 LIBS="$glib_save_LIBS"
2107                 ;;
2108             esac
2109           fi
2110
2111           g_threads_impl="POSIX"
2112           AC_SUBST(GTHREAD_COMPILE_IMPL_DEFINES)
2113           CPPFLAGS="$glib_save_CPPFLAGS"
2114           ;;
2115         win32)
2116            g_threads_impl="WIN32"
2117            ;;
2118         *)
2119            g_threads_impl="NONE"
2120            G_THREAD_LIBS=error
2121            ;;
2122 esac
2123
2124 if test "x$G_THREAD_LIBS" = xerror; then
2125         AC_MSG_ERROR($LIBS_NOT_FOUND_1$have_threads$LIBS_NOT_FOUND_2)
2126 fi
2127
2128 case $host in
2129   *-*-beos*)
2130     G_THREAD_LIBS="-lbe -lroot -lglib-2.0 "
2131     G_THREAD_LIBS_EXTRA="-L\$(top_builddir_full)/.libs"
2132     ;;
2133   *)
2134     ;;
2135 esac
2136
2137 AC_MSG_CHECKING(thread related libraries)
2138 AC_MSG_RESULT($G_THREAD_LIBS)
2139
2140 dnl check for mt safe function variants and some posix functions
2141 dnl ************************************************************
2142
2143 glib_save_LIBS="$LIBS"
2144 # we are not doing the following for now, as this might require glib
2145 # to always be linked with the thread libs on some platforms.
2146 # LIBS="$LIBS $G_THREAD_LIBS"
2147 AC_CHECK_FUNCS(localtime_r gmtime_r)
2148 if test "$ac_cv_header_pwd_h" = "yes"; then
2149         AC_CACHE_CHECK([for posix getpwuid_r],
2150                 ac_cv_func_posix_getpwuid_r,
2151                 [AC_TRY_RUN([
2152 #include <errno.h>
2153 #include <pwd.h>
2154 int main () {
2155     char buffer[10000];
2156     struct passwd pwd, *pwptr = &pwd;
2157     int error;
2158     errno = 0;
2159     error = getpwuid_r (0, &pwd, buffer,
2160                         sizeof (buffer), &pwptr);
2161    return (error < 0 && errno == ENOSYS)
2162            || error == ENOSYS;
2163 }                               ],
2164                         [ac_cv_func_posix_getpwuid_r=yes],
2165                         [ac_cv_func_posix_getpwuid_r=no])])
2166         GLIB_ASSERT_SET(ac_cv_func_posix_getpwuid_r)
2167         if test "$ac_cv_func_posix_getpwuid_r" = yes; then
2168                 AC_DEFINE(HAVE_POSIX_GETPWUID_R,1,
2169                         [Have POSIX function getpwuid_r])
2170         else
2171                 AC_CACHE_CHECK([for nonposix getpwuid_r],
2172                         ac_cv_func_nonposix_getpwuid_r,
2173                         [AC_TRY_LINK([#include <pwd.h>],
2174                                 [char buffer[10000];
2175                                 struct passwd pwd;
2176                                 getpwuid_r (0, &pwd, buffer,
2177                                                 sizeof (buffer));],
2178                                 [ac_cv_func_nonposix_getpwuid_r=yes],
2179                                 [ac_cv_func_nonposix_getpwuid_r=no])])
2180                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getpwuid_r)
2181                 if test "$ac_cv_func_nonposix_getpwuid_r" = yes; then
2182                         AC_DEFINE(HAVE_NONPOSIX_GETPWUID_R,1,
2183                                 [Have non-POSIX function getpwuid_r])
2184                 fi
2185         fi
2186 fi
2187 if test "$ac_cv_header_grp_h" = "yes"; then
2188         AC_CACHE_CHECK([for posix getgrgid_r],
2189                 ac_cv_func_posix_getgrgid_r,
2190                 [AC_TRY_RUN([
2191 #include <errno.h>
2192 #include <grp.h>
2193 int main () {
2194     char buffer[10000];
2195     struct group grp, *grpptr = &grp;
2196     int error;
2197     errno = 0;
2198     error = getgrgid_r (0, &grp, buffer,
2199                         sizeof (buffer), &grpptr);
2200    return (error < 0 && errno == ENOSYS)
2201            || error == ENOSYS;
2202 }                              ],
2203                        [ac_cv_func_posix_getgrgid_r=yes],
2204                        [ac_cv_func_posix_getgrgid_r=no])])
2205         GLIB_ASSERT_SET(ac_cv_func_posix_getgrgid_r)
2206         if test "$ac_cv_func_posix_getgrgid_r" = yes; then
2207                 AC_DEFINE(HAVE_POSIX_GETGRGID_R,1,
2208                         [Have POSIX function getgrgid_r])
2209         else
2210                 AC_CACHE_CHECK([for nonposix getgrgid_r],
2211                         ac_cv_func_nonposix_getgrgid_r,
2212                         [AC_TRY_LINK([#include <grp.h>],
2213                                 [char buffer[10000];
2214                                 struct group grp;
2215                                 getgrgid_r (0, &grp, buffer,
2216                                 sizeof (buffer));],
2217                         [ac_cv_func_nonposix_getgrgid_r=yes],
2218                         [ac_cv_func_nonposix_getgrgid_r=no])])
2219                 GLIB_ASSERT_SET(ac_cv_func_nonposix_getgrgid_r)
2220                 if test "$ac_cv_func_nonposix_getgrgid_r" = yes; then
2221                         AC_DEFINE(HAVE_NONPOSIX_GETGRGID_R,1,
2222                                 [Have non-POSIX function getgrgid_r])
2223                 fi
2224         fi
2225 fi
2226 LIBS="$G_THREAD_LIBS $LIBS"
2227 if test x"$have_threads" = xposix; then
2228         glib_save_CPPFLAGS="$CPPFLAGS"
2229         CPPFLAGS="$CPPFLAGS $GTHREAD_COMPILE_IMPL_DEFINES"
2230         # This is not AC_CHECK_FUNC to also work with function
2231         # name mangling in header files.
2232         AC_MSG_CHECKING(for pthread_attr_setstacksize)
2233         AC_LINK_IFELSE(
2234             [AC_LANG_PROGRAM(
2235                 [#include <pthread.h>],
2236                 [pthread_attr_t t; pthread_attr_setstacksize(&t,0)])],
2237             [AC_MSG_RESULT(yes)
2238              AC_DEFINE(HAVE_PTHREAD_ATTR_SETSTACKSIZE,1,
2239                 [Have function pthread_attr_setstacksize])],
2240             [AC_MSG_RESULT(no)])
2241         AC_MSG_CHECKING(for pthread_condattr_setclock)
2242         AC_LINK_IFELSE(
2243             [AC_LANG_PROGRAM(
2244                 [#include <pthread.h>],
2245                 [pthread_condattr_t a; pthread_condattr_setclock(&a,0)])],
2246             [AC_MSG_RESULT(yes)
2247              AC_DEFINE(HAVE_PTHREAD_CONDATTR_SETCLOCK,1,
2248                 [Have function pthread_condattr_setclock])],
2249             [AC_MSG_RESULT(no)])
2250         CPPFLAGS="$glib_save_CPPFLAGS"
2251 fi
2252
2253 LIBS="$glib_save_LIBS"
2254
2255 # now spit out all the warnings.
2256 if test "$ac_cv_func_posix_getpwuid_r" != "yes" &&
2257    test "$ac_cv_func_nonposix_getpwuid_r" != "yes"; then
2258         AC_MSG_WARN($FUNC_NO_GETPWUID_R)
2259 fi
2260 if test "$ac_cv_func_localtime_r" != "yes"; then
2261         AC_MSG_WARN($FUNC_NO_LOCALTIME_R)
2262 fi
2263
2264 #
2265 # Hack to deal with:
2266 #
2267 #  a) GCC < 3.3 for Linux doesn't include -lpthread when
2268 #     building shared libraries with linux.
2269 #  b) FreeBSD doesn't do this either.
2270 #
2271 case $host in
2272   *-*-freebsd*|*-*-linux*)
2273     G_THREAD_LIBS_FOR_GTHREAD="`echo $G_THREAD_LIBS | sed s/-pthread/-lpthread/`"
2274     ;;
2275   *-*-openbsd*)
2276     LDFLAGS="$LDFLAGS -pthread"
2277     ;;
2278   *)
2279     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS"
2280     ;;
2281 esac
2282
2283 AC_SUBST(G_THREAD_CFLAGS)
2284 AC_SUBST(G_THREAD_LIBS)
2285 AC_SUBST(G_THREAD_LIBS_FOR_GTHREAD)
2286 AC_SUBST(G_THREAD_LIBS_EXTRA)
2287
2288 AC_CHECK_FUNCS(clock_gettime, [], [
2289   AC_CHECK_LIB(rt, clock_gettime, [
2290     AC_DEFINE(HAVE_CLOCK_GETTIME, 1)
2291     G_THREAD_LIBS="$G_THREAD_LIBS -lrt"
2292     G_THREAD_LIBS_FOR_GTHREAD="$G_THREAD_LIBS_FOR_GTHREAD -lrt"
2293   ])
2294 ])
2295
2296
2297 dnl ************************
2298 dnl *** g_atomic_* tests ***
2299 dnl ************************
2300
2301 dnl We need to decide at configure time if GLib will use real atomic
2302 dnl operations ("lock free") or emulated ones with a mutex.  This is
2303 dnl because we must put this information in glibconfig.h so we know if
2304 dnl it is safe or not to inline using compiler intrinsics directly from
2305 dnl the header.
2306 dnl
2307 dnl We also publish the information via G_ATOMIC_LOCK_FREE in case the
2308 dnl user is interested in knowing if they can use the atomic ops across
2309 dnl processes.
2310 dnl
2311 dnl We can currently support the atomic ops natively when building GLib
2312 dnl with recent versions of GCC or MSVC.  MSVC doesn't run ./configure,
2313 dnl so we skip that case here and define G_ATOMIC_LOCK_FREE exactly when
2314 dnl we are using GCC.
2315 dnl
2316 dnl Note that the atomic ops are only available with GCC on x86 when
2317 dnl using -march=i486 or higher.  If we detect that the atomic ops are
2318 dnl not available but would be available given the right flags, we want
2319 dnl to abort and advise the user to fix their CFLAGS.  It's better to do
2320 dnl that then to silently fall back on emulated atomic ops just because
2321 dnl the user had the wrong build environment.
2322
2323 dnl We may add other compilers here in the future...
2324
2325 AC_CACHE_CHECK([for lock-free atomic intrinsics], glib_cv_g_atomic_lock_free, [
2326   AC_TRY_COMPILE([],
2327                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2328                  [glib_cv_g_atomic_lock_free=yes],
2329                  [glib_cv_g_atomic_lock_free=no])])
2330
2331 if test "$glib_cv_g_atomic_lock_free" = "no"; then
2332   SAVE_CFLAGS="${CFLAGS}"
2333   CFLAGS="-march=i486"
2334   AC_TRY_COMPILE([],
2335                  [__GCC_HAVE_SYNC_COMPARE_AND_SWAP_4;],
2336                  [AC_MSG_ERROR([GLib must be build with -march=i486 or later.])],
2337                  [])
2338   CFLAGS="${SAVE_CFLAGS}"
2339 fi
2340
2341 dnl We need a more robust approach here...
2342 case $host_cpu in
2343   i?86|x86_64|s390|s390x|arm*|crisv32*|etrax*)
2344     glib_memory_barrier_needed=no
2345     ;;
2346   sparc*|alpha*|powerpc*|ia64)
2347     glib_memory_barrier_needed=yes
2348     ;;
2349   *)
2350     glib_memory_barrier_needed=yes
2351     ;;
2352 esac
2353
2354 dnl ************************
2355 dnl ** Check for futex(2) **
2356 dnl ************************
2357 AC_CACHE_CHECK(for futex(2) system call,
2358     glib_cv_futex,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2359 #include <linux/futex.h>
2360 #include <sys/syscall.h>
2361 #include <unistd.h>
2362 ],[
2363 int
2364 main (void)
2365 {
2366   /* it is not like this actually runs or anything... */
2367   syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
2368   return 0;
2369 }
2370 ])],glib_cv_futex=yes,glib_cv_futex=no))
2371 if test x"$glib_cv_futex" = xyes; then
2372   AC_DEFINE(HAVE_FUTEX, 1, [we have the futex(2) system call])
2373 fi
2374
2375 AC_CACHE_CHECK(for eventfd(2) system call,
2376     glib_cv_eventfd,AC_COMPILE_IFELSE([AC_LANG_PROGRAM([
2377 #include <sys/eventfd.h>
2378 #include <unistd.h>
2379 ],[
2380 int
2381 main (void)
2382 {
2383   eventfd (0, EFD_CLOEXEC);
2384   return 0;
2385 }
2386 ])],glib_cv_eventfd=yes,glib_cv_eventfd=no))
2387 if test x"$glib_cv_eventfd" = x"yes"; then
2388   AC_DEFINE(HAVE_EVENTFD, 1, [we have the eventfd(2) system call])
2389 fi
2390 AM_CONDITIONAL(HAVE_EVENTFD, [test "$glib_cv_eventfd" = "yes"])
2391
2392 dnl ****************************************
2393 dnl *** GLib POLL* compatibility defines ***
2394 dnl ****************************************
2395
2396 glib_poll_includes=["
2397 #include <sys/types.h>
2398 #include <sys/poll.h>
2399 "]
2400
2401 if test $ac_cv_header_sys_types_h = yes &&
2402    test $ac_cv_header_sys_poll_h = yes ; then
2403   glib_failed=false
2404   GLIB_CHECK_VALUE(POLLIN, $glib_poll_includes, glib_failed=true)
2405   GLIB_CHECK_VALUE(POLLOUT, $glib_poll_includes, glib_failed=true)
2406   GLIB_CHECK_VALUE(POLLPRI, $glib_poll_includes, glib_failed=true)
2407   GLIB_CHECK_VALUE(POLLERR, $glib_poll_includes, glib_failed=true)
2408   GLIB_CHECK_VALUE(POLLHUP, $glib_poll_includes, glib_failed=true)
2409   GLIB_CHECK_VALUE(POLLNVAL, $glib_poll_includes, glib_failed=true)
2410   if $glib_failed ; then
2411     AC_MSG_ERROR([Could not determine values for POLL* constants])
2412   fi
2413 else
2414   glib_cv_value_POLLIN=1
2415   glib_cv_value_POLLOUT=4
2416   glib_cv_value_POLLPRI=2
2417   glib_cv_value_POLLERR=8
2418   glib_cv_value_POLLHUP=16
2419   glib_cv_value_POLLNVAL=32
2420 fi
2421
2422 AC_MSG_CHECKING([for broken poll])
2423 AC_RUN_IFELSE([AC_LANG_SOURCE([[
2424         #include <stdlib.h>
2425         #include <fcntl.h>
2426         #include <poll.h>
2427         #ifdef HAVE_SYS_POLL_H
2428         #include <sys/poll.h>
2429         #endif
2430         int main(void) {
2431           struct pollfd fds[1];
2432           int fd;
2433           fd = open("/dev/null", 1);
2434           fds[0].fd = fd;
2435           fds[0].events = POLLIN;
2436           fds[0].revents = 0;
2437           if (poll(fds, 1, 0) < 0 || (fds[0].revents & POLLNVAL) != 0) {
2438                 exit(1);  /* Does not work for devices -- fail */
2439           }
2440           exit(0);
2441         }]])],
2442   [broken_poll=no],
2443   [broken_poll=yes
2444    AC_DEFINE(BROKEN_POLL,1,[poll doesn't work on devices])],
2445   [broken_poll="no (cross compiling)"])
2446 AC_MSG_RESULT($broken_poll)
2447
2448 dnl *********************
2449 dnl *** GRegex checks ***
2450 dnl *********************
2451
2452 PCRE_REQUIRED_VERSION=8.11
2453
2454 # Check if we should use the internal or the system-supplied pcre
2455 AC_ARG_WITH(pcre,
2456             [AC_HELP_STRING([--with-pcre=@<:@internal/system@:>@],
2457                             [whether to use system PCRE [default=internal]])])
2458
2459 AM_CONDITIONAL(USE_SYSTEM_PCRE, [test "x$with_pcre" = xsystem])
2460
2461 if test "x$with_pcre" = xsystem; then
2462   PKG_CHECK_MODULES(PCRE,
2463                     libpcre >= $PCRE_REQUIRED_VERSION)
2464   AC_CACHE_CHECK([for Unicode support in PCRE],glib_cv_pcre_has_unicode,[
2465                   glib_save_CFLAGS="$CFLAGS"
2466                   glib_save_LIBS="$LIBS"
2467                   CFLAGS="$CFLAGS $PCRE_CFLAGS" LIBS="$PCRE_LIBS"
2468                   AC_TRY_RUN([#include <pcre.h>
2469                               int main () {
2470                                 int support;
2471                                 pcre_config (PCRE_CONFIG_UTF8, &support);
2472                                 if (!support)
2473                                   return 1;
2474                                 pcre_config (PCRE_CONFIG_UNICODE_PROPERTIES, &support);
2475                                 if (!support)
2476                                   return 1;
2477                                 return 0;
2478                               }],
2479                   glib_cv_pcre_has_unicode=yes,
2480                   glib_cv_pcre_has_unicode=no,
2481                   glib_cv_pcre_has_unicode=yes)
2482                   CFLAGS="$glib_save_CFLAGS"
2483                   LIBS="$glib_save_LIBS"
2484       ])
2485   if test "$glib_cv_pcre_has_unicode" = "no"; then
2486     AC_MSG_ERROR([*** The system-supplied PCRE does not support Unicode properties or UTF-8.])
2487   fi
2488   AC_SUBST(PCRE_CFLAGS)
2489   AC_SUBST(PCRE_LIBS)
2490   AC_DEFINE(USE_SYSTEM_PCRE, [], [using the system-supplied PCRE library])
2491   PCRE_REQUIRES=libpcre
2492   AC_SUBST(PCRE_REQUIRES)
2493 else
2494   # If using gcc 4 pass -Wno-pointer-sign when compiling the internal PCRE
2495   if test x"$GCC" = xyes; then
2496     AC_MSG_CHECKING([whether compiler understands -Wno-pointer-sign])
2497     save_CFLAGS="$CFLAGS"
2498     CFLAGS="$CFLAGS -Wno-pointer-sign"
2499     AC_TRY_COMPILE([],[],[PCRE_WARN_CFLAGS="$PCRE_WARN_CFLAGS -Wno-pointer-sign"
2500                           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
2501     CFLAGS="$save_CFLAGS"
2502   fi
2503 fi
2504 AC_SUBST(PCRE_WARN_CFLAGS)
2505
2506 dnl **********************
2507 dnl *** Win32 API libs ***
2508 dnl **********************
2509
2510 case $host in
2511   *-*-cygwin*)
2512         G_LIBS_EXTRA="-luser32 -lkernel32"
2513     ;;
2514   *-*-mingw*)
2515         G_LIBS_EXTRA="-lws2_32 -lole32 -lwinmm -lshlwapi"
2516     ;;
2517   *)
2518         G_LIBS_EXTRA=""
2519     ;;
2520 esac
2521 AC_SUBST(G_LIBS_EXTRA)
2522
2523 dnl If the system doesn't define EILSEQ, we should define EILSEQ ourselves
2524 dnl since we need it for g_iconv()
2525
2526 AC_MSG_CHECKING([for EILSEQ])
2527 AC_TRY_COMPILE([
2528 #include <errno.h>
2529 ],
2530 [
2531 int error = EILSEQ;
2532 ], have_eilseq=yes, have_eilseq=no);
2533 AC_MSG_RESULT($have_eilseq)
2534
2535 dnl ******************************************************************
2536 dnl *** If we are cross-compiling, look for glib-genmarshal and    ***
2537 dnl *** glib-compile-schemas in PATH                               ***
2538 dnl ******************************************************************
2539
2540 AM_CONDITIONAL(CROSS_COMPILING, test $cross_compiling = yes)
2541
2542 if test $cross_compiling = yes; then
2543   AC_PATH_PROG(GLIB_GENMARSHAL, glib-genmarshal, no)
2544   if test x$GLIB_GENMARSHAL = xno; then
2545     AC_MSG_ERROR(Could not find a glib-genmarshal in your PATH)
2546   fi
2547
2548   AC_PATH_PROG(GLIB_COMPILE_SCHEMAS, glib-compile-schemas, no)
2549   if test x$GLIB_COMPILE_SCHEMAS = xno; then
2550     AC_MSG_ERROR(Could not find a glib-compile-schemas in your PATH)
2551   fi
2552
2553   AC_PATH_PROG(GLIB_COMPILE_RESOURCES, glib-compile-resources, no)
2554   if test x$GLIB_COMPILE_RESOURCES = xno; then
2555     AC_MSG_ERROR(Could not find a glib-compile-resources in your PATH)
2556   fi
2557 fi
2558
2559 dnl **************************
2560 dnl *** Checks for gtk-doc ***
2561 dnl **************************
2562
2563 GTK_DOC_CHECK([1.15], [--flavour no-tmpl])
2564
2565 AC_ARG_ENABLE(man,
2566               [AC_HELP_STRING([--enable-man],
2567                               [regenerate man pages from Docbook [default=no]])],enable_man=yes,
2568               enable_man=no)
2569
2570 if test "${enable_man}" != no; then
2571 dnl
2572 dnl Check for xsltproc
2573 dnl
2574 AC_PATH_PROG([XSLTPROC], [xsltproc])
2575   if test -z "$XSLTPROC"; then
2576     enable_man=no
2577   fi
2578
2579   dnl check for DocBook DTD and stylesheets in the local catalog.
2580   JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.1.2//EN],
2581      [DocBook XML DTD V4.1.2],,enable_man=no)
2582   JH_CHECK_XML_CATALOG([http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl],
2583      [DocBook XSL Stylesheets],,enable_man=no)
2584 fi
2585
2586 AM_CONDITIONAL(ENABLE_MAN, test x$enable_man != xno)
2587
2588 dnl
2589 dnl Tracing
2590 dnl
2591
2592 AC_ARG_ENABLE([dtrace],
2593              [AS_HELP_STRING([--enable-dtrace],
2594                               [include tracing support for dtrace])])
2595 have_dtrace=no
2596 AC_MSG_CHECKING([whether to include dtrace tracing support])
2597 if test "x$enable_dtrace" != xno; then
2598   if test x$glib_have_carbon = xyes; then
2599     AC_MSG_RESULT([no (not yet compatible with MacOS dtrace)])
2600   else
2601     AC_MSG_RESULT([yes])
2602     AC_CHECK_PROGS(DTRACE, dtrace)
2603     if test -z "$DTRACE"; then
2604       if test "x$enable_dtrace" = xyes; then
2605         AC_MSG_ERROR([dtrace not found])
2606       fi
2607     else
2608       AC_CHECK_HEADER([sys/sdt.h],have_dtrace=yes,
2609                       [if test "x$enable_dtrace" = xyes; then
2610                         AC_MSG_ERROR([dtrace support needs sys/sdt.h header])
2611                        fi])
2612     fi
2613   fi
2614 else
2615   AC_MSG_RESULT([no])
2616 fi
2617 if test "x$have_dtrace" = xyes; then
2618   AC_DEFINE([HAVE_DTRACE], [1], [Define to 1 if using dtrace probes.])
2619 fi
2620 AM_CONDITIONAL([ENABLE_DTRACE], [test x$have_dtrace = xyes ])
2621
2622 AC_MSG_CHECKING([whether to include systemtap tracing support])
2623 AC_ARG_ENABLE([systemtap],
2624              [AS_HELP_STRING([--enable-systemtap],
2625                               [include tracing support for systemtap])])
2626 have_systemtap=no
2627 if test "x$enable_systemtap" != xno -a "x$have_dtrace" = xyes; then
2628   have_systemtap=yes
2629 fi
2630 AC_MSG_RESULT(${have_systemtap})
2631
2632 AM_CONDITIONAL([ENABLE_SYSTEMTAP], [test x$have_systemtap = xyes])
2633
2634 AC_ARG_WITH([tapset-install-dir],
2635             AS_HELP_STRING([--with-tapset-install-dir=DIR],
2636                             [path where systemtap tapsets are installed [DATADIR/systemtap/tapset]]),
2637             [if test "x${withval}" = x; then
2638                ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"
2639              else
2640                ABS_TAPSET_DIR="${withval}"
2641               fi],
2642             [ABS_TAPSET_DIR="\$(datadir)/systemtap/tapset"])
2643 AC_SUBST(ABS_TAPSET_DIR)
2644
2645 dnl ************************************
2646 dnl *** Enable lcov coverage reports ***
2647 dnl ************************************
2648
2649 AC_ARG_ENABLE(gcov,
2650   AS_HELP_STRING([--enable-gcov],
2651                  [enable coverage testing with gcov]),
2652   [use_gcov=$enableval], [use_gcov=no])
2653
2654 if test "x$use_gcov" = "xyes"; then
2655   dnl we need gcc:
2656   if test "$GCC" != "yes"; then
2657     AC_MSG_ERROR([GCC is required for --enable-gcov])
2658   fi
2659
2660   dnl Check if ccache is being used
2661   AC_CHECK_PROG(SHTOOL, shtool, shtool)
2662   case `$SHTOOL path $CC` in
2663     *ccache*[)] gcc_ccache=yes;;
2664     *[)] gcc_ccache=no;;
2665   esac
2666
2667   if test "$gcc_ccache" = "yes" && (test -z "$CCACHE_DISABLE" || test "$CCACHE_DISABLE" != "1"); then
2668     AC_MSG_ERROR([ccache must be disabled when --enable-gcov option is used. You can disable ccache by setting environment variable CCACHE_DISABLE=1.])
2669   fi
2670
2671   ltp_version_list="1.6 1.7 1.8 1.9"
2672   AC_CHECK_PROG(LTP, lcov, lcov)
2673   AC_CHECK_PROG(LTP_GENHTML, genhtml, genhtml)
2674
2675   if test "$LTP"; then
2676     AC_CACHE_CHECK([for ltp version], glib_cv_ltp_version, [
2677       glib_cv_ltp_version=invalid
2678       ltp_version=`$LTP -v 2>/dev/null | $SED -e 's/^.* //'`
2679       for ltp_check_version in $ltp_version_list; do
2680         if test "$ltp_version" = "$ltp_check_version"; then
2681           glib_cv_ltp_version="$ltp_check_version (ok)"
2682         fi
2683       done
2684     ])
2685   else
2686     ltp_msg="To enable code coverage reporting you must have one of the following LTP versions installed: $ltp_version_list"
2687     AC_MSG_ERROR([$ltp_msg])
2688   fi
2689
2690   case $glib_cv_ltp_version in
2691     ""|invalid[)]
2692       ltp_msg="You must have one of the following versions of LTP: $ltp_version_list (found: $ltp_version)."
2693       AC_MSG_ERROR([$ltp_msg])
2694       LTP="exit 0;"
2695       ;;
2696   esac
2697
2698   if test -z "$LTP_GENHTML"; then
2699     AC_MSG_ERROR([Could not find genhtml from the LTP package])
2700   fi
2701
2702   dnl Remove all optimization flags from CFLAGS
2703   changequote({,})
2704   CFLAGS=`echo "$CFLAGS" | $SED -e 's/-O[0-9]*//g'`
2705   changequote([,])
2706
2707   dnl Add the special gcc flags
2708   CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
2709   LDFLAGS="$LDFLAGS -lgcov"
2710 fi
2711
2712 dnl ******************************
2713 dnl *** output the whole stuff ***
2714 dnl ******************************
2715
2716 dnl this section will only be run if config.status is invoked with no
2717 dnl arguments, or with "glib/glibconfig.h" as an argument.
2718 AC_CONFIG_COMMANDS([glib/glibconfig.h],
2719 [
2720         outfile=glib/glibconfig.h-tmp
2721         cat > $outfile <<\_______EOF
2722 /* glibconfig.h
2723  *
2724  * This is a generated file.  Please modify 'configure.ac'
2725  */
2726
2727 #ifndef __GLIBCONFIG_H__
2728 #define __GLIBCONFIG_H__
2729
2730 #include <glib/gmacros.h>
2731
2732 _______EOF
2733
2734         if test x$glib_limits_h = xyes; then
2735           echo '#include <limits.h>' >> $outfile
2736         fi
2737         if test x$glib_float_h = xyes; then
2738           echo '#include <float.h>' >> $outfile
2739         fi
2740         if test x$glib_values_h = xyes; then
2741           echo '#include <values.h>' >> $outfile
2742         fi
2743         if test "$glib_header_alloca_h" = "yes"; then
2744           echo '#define GLIB_HAVE_ALLOCA_H' >> $outfile
2745         fi
2746         if test x$glib_sys_poll_h = xyes; then
2747           echo '#define GLIB_HAVE_SYS_POLL_H' >> $outfile
2748         fi
2749         if test x$glib_included_printf != xyes; then
2750           echo "
2751 /* Specifies that GLib's g_print*() functions wrap the
2752  * system printf functions.  This is useful to know, for example,
2753  * when using glibc's register_printf_function().
2754  */" >> $outfile
2755           echo '#define GLIB_USING_SYSTEM_PRINTF' >> $outfile
2756         fi
2757
2758         cat >> $outfile <<_______EOF
2759
2760 G_BEGIN_DECLS
2761
2762 #define G_MINFLOAT      $glib_mf
2763 #define G_MAXFLOAT      $glib_Mf
2764 #define G_MINDOUBLE     $glib_md
2765 #define G_MAXDOUBLE     $glib_Md
2766 #define G_MINSHORT      $glib_ms
2767 #define G_MAXSHORT      $glib_Ms
2768 #define G_MAXUSHORT     $glib_Mus
2769 #define G_MININT        $glib_mi
2770 #define G_MAXINT        $glib_Mi
2771 #define G_MAXUINT       $glib_Mui
2772 #define G_MINLONG       $glib_ml
2773 #define G_MAXLONG       $glib_Ml
2774 #define G_MAXULONG      $glib_Mul
2775
2776 _______EOF
2777
2778
2779         ### this should always be true in a modern C/C++ compiler
2780         cat >>$outfile <<_______EOF
2781 typedef signed char gint8;
2782 typedef unsigned char guint8;
2783 _______EOF
2784
2785
2786         if test -n "$gint16"; then
2787           cat >>$outfile <<_______EOF
2788 typedef signed $gint16 gint16;
2789 typedef unsigned $gint16 guint16;
2790 #define G_GINT16_MODIFIER $gint16_modifier
2791 #define G_GINT16_FORMAT $gint16_format
2792 #define G_GUINT16_FORMAT $guint16_format
2793 _______EOF
2794         fi
2795
2796
2797         if test -n "$gint32"; then
2798           cat >>$outfile <<_______EOF
2799 typedef signed $gint32 gint32;
2800 typedef unsigned $gint32 guint32;
2801 #define G_GINT32_MODIFIER $gint32_modifier
2802 #define G_GINT32_FORMAT $gint32_format
2803 #define G_GUINT32_FORMAT $guint32_format
2804 _______EOF
2805         fi
2806
2807         cat >>$outfile <<_______EOF
2808 #define G_HAVE_GINT64 1          /* deprecated, always true */
2809
2810 ${glib_extension}typedef signed $gint64 gint64;
2811 ${glib_extension}typedef unsigned $gint64 guint64;
2812
2813 #define G_GINT64_CONSTANT(val)  $gint64_constant
2814 #define G_GUINT64_CONSTANT(val) $guint64_constant
2815 _______EOF
2816
2817         if test x$gint64_format != x ; then
2818           cat >>$outfile <<_______EOF
2819 #define G_GINT64_MODIFIER $gint64_modifier
2820 #define G_GINT64_FORMAT $gint64_format
2821 #define G_GUINT64_FORMAT $guint64_format
2822 _______EOF
2823         else
2824           cat >>$outfile <<_______EOF
2825 #undef G_GINT64_MODIFIER
2826 #undef G_GINT64_FORMAT
2827 #undef G_GUINT64_FORMAT
2828 _______EOF
2829         fi
2830
2831         cat >>$outfile <<_______EOF
2832
2833 #define GLIB_SIZEOF_VOID_P $glib_void_p
2834 #define GLIB_SIZEOF_LONG   $glib_long
2835 #define GLIB_SIZEOF_SIZE_T $glib_size_t
2836
2837 _______EOF
2838
2839         cat >>$outfile <<_______EOF
2840 typedef signed $glib_size_type_define gssize;
2841 typedef unsigned $glib_size_type_define gsize;
2842 #define G_GSIZE_MODIFIER $gsize_modifier
2843 #define G_GSSIZE_FORMAT $gssize_format
2844 #define G_GSIZE_FORMAT $gsize_format
2845
2846 #define G_MAXSIZE       G_MAXU$glib_msize_type
2847 #define G_MINSSIZE      G_MIN$glib_msize_type
2848 #define G_MAXSSIZE      G_MAX$glib_msize_type
2849
2850 typedef gint64 goffset;
2851 #define G_MINOFFSET     G_MININT64
2852 #define G_MAXOFFSET     G_MAXINT64
2853
2854 #define G_GOFFSET_MODIFIER      G_GINT64_MODIFIER
2855 #define G_GOFFSET_FORMAT        G_GINT64_FORMAT
2856 #define G_GOFFSET_CONSTANT(val) G_GINT64_CONSTANT(val)
2857
2858 _______EOF
2859
2860         if test -z "$glib_unknown_void_p"; then
2861           cat >>$outfile <<_______EOF
2862
2863 #define GPOINTER_TO_INT(p)      ((gint)  ${glib_gpi_cast} (p))
2864 #define GPOINTER_TO_UINT(p)     ((guint) ${glib_gpui_cast} (p))
2865
2866 #define GINT_TO_POINTER(i)      ((gpointer) ${glib_gpi_cast} (i))
2867 #define GUINT_TO_POINTER(u)     ((gpointer) ${glib_gpui_cast} (u))
2868
2869 typedef signed $glib_intptr_type_define gintptr;
2870 typedef unsigned $glib_intptr_type_define guintptr;
2871
2872 #define G_GINTPTR_MODIFIER      $gintptr_modifier
2873 #define G_GINTPTR_FORMAT        $gintptr_format
2874 #define G_GUINTPTR_FORMAT       $guintptr_format
2875 _______EOF
2876         else
2877           echo '#error SIZEOF_VOID_P unknown - This should never happen' >>$outfile
2878         fi
2879
2880
2881
2882         cat >>$outfile <<_______EOF
2883 $glib_atexit
2884 $glib_memmove
2885 $glib_defines
2886 $glib_os
2887 $glib_static_compilation
2888
2889 $glib_vacopy
2890
2891 #ifdef  __cplusplus
2892 #define G_HAVE_INLINE   1
2893 #else   /* !__cplusplus */
2894 $glib_inline
2895 #endif  /* !__cplusplus */
2896
2897 #ifdef  __cplusplus
2898 #define G_CAN_INLINE    1
2899 _______EOF
2900
2901         if test x$g_can_inline = xyes ; then
2902                 cat >>$outfile <<_______EOF
2903 #else   /* !__cplusplus */
2904 #define G_CAN_INLINE    1
2905 _______EOF
2906         fi
2907
2908         cat >>$outfile <<_______EOF
2909 #endif
2910
2911 _______EOF
2912
2913         if test x$g_have_iso_c_varargs = xyes ; then
2914                 cat >>$outfile <<_______EOF
2915 #ifndef __cplusplus
2916 # define G_HAVE_ISO_VARARGS 1
2917 #endif
2918 _______EOF
2919         fi
2920         if test x$g_have_iso_cxx_varargs = xyes ; then
2921                 cat >>$outfile <<_______EOF
2922 #ifdef __cplusplus
2923 # define G_HAVE_ISO_VARARGS 1
2924 #endif
2925 _______EOF
2926         fi
2927         if test x$g_have_gnuc_varargs = xyes ; then
2928                 cat >>$outfile <<_______EOF
2929
2930 /* gcc-2.95.x supports both gnu style and ISO varargs, but if -ansi
2931  * is passed ISO vararg support is turned off, and there is no work
2932  * around to turn it on, so we unconditionally turn it off.
2933  */
2934 #if __GNUC__ == 2 && __GNUC_MINOR__ == 95
2935 #  undef G_HAVE_ISO_VARARGS
2936 #endif
2937
2938 #define G_HAVE_GNUC_VARARGS 1
2939 _______EOF
2940         fi
2941
2942         case x$g_stack_grows in
2943         xyes) echo "#define G_HAVE_GROWING_STACK 1" >>$outfile ;;
2944         *)    echo "#define G_HAVE_GROWING_STACK 0" >>$outfile ;;
2945         esac
2946
2947
2948         echo >>$outfile
2949         if test x$g_have_eilseq = xno; then
2950                 cat >>$outfile <<_______EOF
2951 #ifndef EILSEQ
2952 /* On some systems, like SunOS and NetBSD, EILSEQ is not defined.
2953  * The correspondence between this and the corresponding definition
2954  * in libiconv is essential.
2955  */
2956 #  define EILSEQ ENOENT
2957 #endif
2958 _______EOF
2959
2960         fi
2961
2962         if test x$g_have_gnuc_visibility = xyes; then
2963                 cat >>$outfile <<_______EOF
2964 #define G_HAVE_GNUC_VISIBILITY 1
2965 _______EOF
2966         fi
2967                 cat >>$outfile <<_______EOF
2968 #if defined(__SUNPRO_C) && (__SUNPRO_C >= 0x590)
2969 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2970 #elif defined(__SUNPRO_C) && (__SUNPRO_C >= 0x550)
2971 #define G_GNUC_INTERNAL __hidden
2972 #elif defined (__GNUC__) && defined (G_HAVE_GNUC_VISIBILITY)
2973 #define G_GNUC_INTERNAL __attribute__((visibility("hidden")))
2974 #else
2975 #define G_GNUC_INTERNAL
2976 #endif
2977 _______EOF
2978
2979         echo >>$outfile
2980         cat >>$outfile <<_______EOF
2981 #define G_THREADS_ENABLED
2982 #define G_THREADS_IMPL_$g_threads_impl_def
2983 _______EOF
2984
2985         if test x"$g_memory_barrier_needed" != xno; then
2986           echo >>$outfile
2987           echo "#define G_ATOMIC_OP_MEMORY_BARRIER_NEEDED 1" >>$outfile
2988         fi
2989         if test x"$g_atomic_lock_free" = xyes; then
2990           echo >>$outfile
2991           echo "#define G_ATOMIC_LOCK_FREE" >>$outfile
2992         fi
2993         echo >>$outfile
2994         g_bit_sizes="16 32 64"
2995         for bits in $g_bit_sizes; do
2996           cat >>$outfile <<_______EOF
2997 #define GINT${bits}_TO_${g_bs_native}(val)      ((gint${bits}) (val))
2998 #define GUINT${bits}_TO_${g_bs_native}(val)     ((guint${bits}) (val))
2999 #define GINT${bits}_TO_${g_bs_alien}(val)       ((gint${bits}) GUINT${bits}_SWAP_LE_BE (val))
3000 #define GUINT${bits}_TO_${g_bs_alien}(val)      (GUINT${bits}_SWAP_LE_BE (val))
3001 _______EOF
3002         done
3003
3004         cat >>$outfile <<_______EOF
3005 #define GLONG_TO_LE(val)        ((glong) GINT${glongbits}_TO_LE (val))
3006 #define GULONG_TO_LE(val)       ((gulong) GUINT${glongbits}_TO_LE (val))
3007 #define GLONG_TO_BE(val)        ((glong) GINT${glongbits}_TO_BE (val))
3008 #define GULONG_TO_BE(val)       ((gulong) GUINT${glongbits}_TO_BE (val))
3009 #define GINT_TO_LE(val)         ((gint) GINT${gintbits}_TO_LE (val))
3010 #define GUINT_TO_LE(val)        ((guint) GUINT${gintbits}_TO_LE (val))
3011 #define GINT_TO_BE(val)         ((gint) GINT${gintbits}_TO_BE (val))
3012 #define GUINT_TO_BE(val)        ((guint) GUINT${gintbits}_TO_BE (val))
3013 #define GSIZE_TO_LE(val)        ((gsize) GUINT${gsizebits}_TO_LE (val))
3014 #define GSSIZE_TO_LE(val)       ((gssize) GINT${gsizebits}_TO_LE (val))
3015 #define GSIZE_TO_BE(val)        ((gsize) GUINT${gsizebits}_TO_BE (val))
3016 #define GSSIZE_TO_BE(val)       ((gssize) GINT${gsizebits}_TO_BE (val))
3017 #define G_BYTE_ORDER $g_byte_order
3018
3019 #define GLIB_SYSDEF_POLLIN =$g_pollin
3020 #define GLIB_SYSDEF_POLLOUT =$g_pollout
3021 #define GLIB_SYSDEF_POLLPRI =$g_pollpri
3022 #define GLIB_SYSDEF_POLLHUP =$g_pollhup
3023 #define GLIB_SYSDEF_POLLERR =$g_pollerr
3024 #define GLIB_SYSDEF_POLLNVAL =$g_pollnval
3025
3026 #define G_MODULE_SUFFIX "$g_module_suffix"
3027
3028 typedef $g_pid_type GPid;
3029
3030 #define GLIB_SYSDEF_AF_UNIX $g_af_unix
3031 #define GLIB_SYSDEF_AF_INET $g_af_inet
3032 #define GLIB_SYSDEF_AF_INET6 $g_af_inet6
3033
3034 #define GLIB_SYSDEF_MSG_OOB $g_msg_oob
3035 #define GLIB_SYSDEF_MSG_PEEK $g_msg_peek
3036 #define GLIB_SYSDEF_MSG_DONTROUTE $g_msg_dontroute
3037
3038 G_END_DECLS
3039
3040 #endif /* __GLIBCONFIG_H__ */
3041 _______EOF
3042
3043
3044         if cmp -s $outfile glib/glibconfig.h; then
3045           AC_MSG_NOTICE([glib/glibconfig.h is unchanged])
3046           rm -f $outfile
3047         else
3048           mv $outfile glib/glibconfig.h
3049         fi
3050 ],[
3051
3052 # Note that if two cases are the same, case goes with the first one.
3053 # Note also that this is inside an AC_OUTPUT_COMMAND.  We do not depend
3054 # on variable expansion in case labels.  Look at the generated config.status
3055 # for a hint.
3056
3057 if test "x${ac_cv_working_alloca_h+set}" = xset ; then
3058   glib_header_alloca_h="$ac_cv_working_alloca_h"
3059 else
3060   glib_header_alloca_h="$ac_cv_header_alloca_h"
3061 fi
3062
3063 case xyes in
3064 x$ac_cv_header_float_h)
3065   glib_float_h=yes
3066   glib_mf=FLT_MIN glib_Mf=FLT_MAX
3067   glib_md=DBL_MIN glib_Md=DBL_MAX
3068   ;;
3069 x$ac_cv_header_values_h)
3070   glib_values_h=yes
3071   glib_mf=MINFLOAT  glib_Mf=MAXFLOAT
3072   glib_md=MINDOUBLE glib_Md=MAXDOUBLE
3073   ;;
3074 esac
3075
3076 case xyes in
3077 x$ac_cv_header_limits_h)
3078   glib_limits_h=yes
3079   glib_ms=SHRT_MIN glib_Ms=SHRT_MAX glib_Mus=USHRT_MAX
3080   glib_mi=INT_MIN  glib_Mi=INT_MAX  glib_Mui=UINT_MAX
3081   glib_ml=LONG_MIN glib_Ml=LONG_MAX glib_Mul=ULONG_MAX
3082   ;;
3083 x$ac_cv_header_values_h)
3084   glib_values_h=yes
3085   glib_ms=MINSHORT glib_Ms=MAXSHORT glib_Mus="(((gushort)G_MAXSHORT)*2+1)"
3086   glib_mi=MININT   glib_Mi=MAXINT   glib_Mui="(((guint)G_MAXINT)*2+1)"
3087   glib_ml=MINLONG  glib_Ml=MAXLONG  glib_Mul="(((gulong)G_MAXLONG)*2+1)"
3088   ;;
3089 esac
3090
3091 if test x$ac_cv_header_sys_poll_h = xyes ; then
3092   glib_sys_poll_h=yes
3093 fi
3094
3095 if test x$enable_included_printf = xyes ; then
3096   glib_included_printf=yes
3097 fi
3098
3099 case 2 in
3100 $ac_cv_sizeof_short)
3101   gint16=short
3102   gint16_modifier='"h"'
3103   gint16_format='"hi"'
3104   guint16_format='"hu"'
3105   ;;
3106 $ac_cv_sizeof_int)
3107   gint16=int
3108   gint16_modifier='""'
3109   gint16_format='"i"'
3110   guint16_format='"u"'
3111   ;;
3112 esac
3113 case 4 in
3114 $ac_cv_sizeof_short)
3115   gint32=short
3116   gint32_modifier='"h"'
3117   gint32_format='"hi"'
3118   guint32_format='"hu"'
3119   ;;
3120 $ac_cv_sizeof_int)
3121   gint32=int
3122   gint32_modifier='""'
3123   gint32_format='"i"'
3124   guint32_format='"u"'
3125   ;;
3126 $ac_cv_sizeof_long)
3127   gint32=long
3128   gint32_modifier='"l"'
3129   gint32_format='"li"'
3130   guint32_format='"lu"'
3131   ;;
3132 esac
3133 case 8 in
3134 $ac_cv_sizeof_int)
3135   gint64=int
3136   gint64_modifier='""'
3137   gint64_format='"i"'
3138   guint64_format='"u"'
3139   glib_extension=
3140   gint64_constant='(val)'
3141   guint64_constant='(val)'
3142   ;;
3143 $ac_cv_sizeof_long)
3144   gint64=long
3145   gint64_modifier='"l"'
3146   gint64_format='"li"'
3147   guint64_format='"lu"'
3148   glib_extension=
3149   gint64_constant='(val##L)'
3150   guint64_constant='(val##UL)'
3151   ;;
3152 $ac_cv_sizeof_long_long)
3153   gint64='long long'
3154   if test -n "$glib_cv_long_long_format"; then
3155     gint64_modifier='"'$glib_cv_long_long_format'"'
3156     gint64_format='"'$glib_cv_long_long_format'i"'
3157     guint64_format='"'$glib_cv_long_long_format'u"'
3158   fi
3159   glib_extension='G_GNUC_EXTENSION '
3160   gint64_constant='(G_GNUC_EXTENSION (val##LL))'
3161   guint64_constant='(G_GNUC_EXTENSION (val##ULL))'
3162   ;;
3163 $ac_cv_sizeof___int64)
3164   gint64='__int64'
3165   if test -n "$glib_cv_long_long_format"; then
3166     gint64_modifier='"'$glib_cv_long_long_format'"'
3167     gint64_format='"'$glib_cv_long_long_format'i"'
3168     guint64_format='"'$glib_cv_long_long_format'u"'
3169   fi
3170   glib_extension=
3171   gint64_constant='(val##i64)'
3172   guint64_constant='(val##ui64)'
3173   ;;
3174 esac
3175 glib_size_t=$ac_cv_sizeof_size_t
3176 glib_size_type_define="$glib_size_type"
3177 glib_void_p=$ac_cv_sizeof_void_p
3178 glib_long=$ac_cv_sizeof_long
3179
3180 case "$glib_size_type" in
3181 short)
3182   gsize_modifier='"h"'
3183   gsize_format='"hu"'
3184   gssize_format='"hi"'
3185   glib_msize_type='SHRT'
3186   ;;
3187 int)
3188   gsize_modifier='""'
3189   gsize_format='"u"'
3190   gssize_format='"i"'
3191   glib_msize_type='INT'
3192   ;;
3193 long)
3194   gsize_modifier='"l"'
3195   gsize_format='"lu"'
3196   gssize_format='"li"'
3197   glib_msize_type='LONG'
3198   ;;
3199 "long long"|__int64)
3200   gsize_modifier='"I64"'
3201   gsize_format='"I64u"'
3202   gssize_format='"I64i"'
3203   glib_msize_type='INT64'
3204   ;;
3205 esac
3206
3207 gintbits=`expr $ac_cv_sizeof_int \* 8`
3208 glongbits=`expr $ac_cv_sizeof_long \* 8`
3209 gsizebits=`expr $ac_cv_sizeof_size_t \* 8`
3210
3211 case $ac_cv_sizeof_void_p in
3212 $ac_cv_sizeof_int)
3213   glib_intptr_type_define=int
3214   gintptr_modifier='""'
3215   gintptr_format='"i"'
3216   guintptr_format='"u"'
3217   glib_gpi_cast='(gint)'
3218   glib_gpui_cast='(guint)'
3219   ;;
3220 $ac_cv_sizeof_long)
3221   glib_intptr_type_define=long
3222   gintptr_modifier='"l"'
3223   gintptr_format='"li"'
3224   guintptr_format='"lu"'
3225   glib_gpi_cast='(glong)'
3226   glib_gpui_cast='(gulong)'
3227   ;;
3228 $ac_cv_sizeof_long_long)
3229   glib_intptr_type_define='long long'
3230   gintptr_modifier='"I64"'
3231   gintptr_format='"I64i"'
3232   guintptr_format='"I64u"'
3233   glib_gpi_cast='(gint64)'
3234   glib_gpui_cast='(guint64)'
3235   ;;
3236 $ac_cv_sizeof___int64)
3237   glib_intptr_type_define=__int64
3238   gintptr_modifier='"I64"'
3239   gintptr_format='"I64i"'
3240   guintptr_format='"I64u"'
3241   glib_gpi_cast='(gint64)'
3242   glib_gpui_cast='(guint64)'
3243   ;;
3244 *)
3245   glib_unknown_void_p=yes
3246   ;;
3247 esac
3248
3249
3250 case xyes in
3251 x$ac_cv_func_atexit)
3252   glib_atexit="
3253 #ifdef NeXT /* @#%@! NeXTStep */
3254 # define g_ATEXIT(proc) (!atexit (proc))
3255 #else
3256 # define g_ATEXIT(proc) (atexit (proc))
3257 #endif"
3258   ;;
3259 x$ac_cv_func_on_exit)
3260   glib_atexit="
3261 #define g_ATEXIT(proc)  (on_exit ((void (*)(int, void*))(proc), NULL))"
3262   ;;
3263 esac
3264
3265 case xyes in
3266 x$ac_cv_func_memmove)
3267   glib_memmove='
3268 #define g_memmove(dest,src,len) G_STMT_START { memmove ((dest), (src), (len)); } G_STMT_END'
3269   ;;
3270 x$glib_cv_working_bcopy)
3271   glib_memmove="
3272 /* memmove isn't available, but bcopy can copy overlapping memory regions */
3273 #define g_memmove(d,s,n) G_STMT_START { bcopy ((s), (d), (n)); } G_STMT_END"
3274   ;;
3275 *)
3276   glib_memmove="
3277 /* memmove isn't found and bcopy can't copy overlapping memory regions,
3278  * so we have to roll our own copy routine. */
3279 void g_memmove (void* dest, const void * src, unsigned long len);"
3280   ;;
3281 esac
3282
3283 glib_defines="
3284 #define GLIB_MAJOR_VERSION $GLIB_MAJOR_VERSION
3285 #define GLIB_MINOR_VERSION $GLIB_MINOR_VERSION
3286 #define GLIB_MICRO_VERSION $GLIB_MICRO_VERSION
3287 "
3288
3289 case xyes in
3290 x$glib_cv_va_copy)      glib_vacopy='#define G_VA_COPY  va_copy' ;;
3291 x$glib_cv___va_copy)    glib_vacopy='#define G_VA_COPY  __va_copy' ;;
3292 *)                      glib_vacopy=''
3293 esac
3294
3295 if test x$glib_cv_va_val_copy = xno; then
3296   glib_vacopy="\$glib_vacopy
3297 #define G_VA_COPY_AS_ARRAY 1"
3298 fi
3299
3300 if test x$glib_cv_hasinline = xyes; then
3301     glib_inline='#define G_HAVE_INLINE 1'
3302 fi
3303 if test x$glib_cv_has__inline = xyes; then
3304     glib_inline="\$glib_inline
3305 #define G_HAVE___INLINE 1"
3306 fi
3307 if test x$glib_cv_has__inline__ = xyes; then
3308     glib_inline="\$glib_inline
3309 #define G_HAVE___INLINE__ 1"
3310 fi
3311
3312 g_have_gnuc_varargs=$g_have_gnuc_varargs
3313 g_have_iso_c_varargs=$g_have_iso_c_varargs
3314 g_have_iso_cxx_varargs=$g_have_iso_cxx_varargs
3315
3316 g_can_inline=$g_can_inline
3317 g_have_gnuc_visibility=$g_have_gnuc_visibility
3318 g_have_sunstudio_visibility=$g_have_sunstudio_visibility
3319
3320 if test x$ac_cv_c_bigendian = xyes; then
3321   g_byte_order=G_BIG_ENDIAN
3322   g_bs_native=BE
3323   g_bs_alien=LE
3324 else
3325   g_byte_order=G_LITTLE_ENDIAN
3326   g_bs_native=LE
3327   g_bs_alien=BE
3328 fi
3329
3330 g_pollin=$glib_cv_value_POLLIN
3331 g_pollout=$glib_cv_value_POLLOUT
3332 g_pollpri=$glib_cv_value_POLLPRI
3333 g_pollhup=$glib_cv_value_POLLHUP
3334 g_pollerr=$glib_cv_value_POLLERR
3335 g_pollnval=$glib_cv_value_POLLNVAL
3336
3337 g_af_unix=$glib_cv_value_AF_UNIX
3338 g_af_inet=$glib_cv_value_AF_INET
3339 g_af_inet6=$glib_cv_value_AF_INET6
3340
3341 g_msg_peek=$glib_cv_value_MSG_PEEK
3342 g_msg_oob=$glib_cv_value_MSG_OOB
3343 g_msg_dontroute=$glib_cv_value_MSG_DONTROUTE
3344
3345 g_stack_grows=$glib_cv_stack_grows
3346
3347 g_have_eilseq=$have_eilseq
3348
3349 g_threads_impl_def=$g_threads_impl
3350
3351 g_atomic_lock_free="$glib_cv_g_atomic_lock_free"
3352 g_memory_barrier_needed="$glib_memory_barrier_needed"
3353 g_gcc_atomic_ops="$glib_cv_gcc_has_builtin_atomic_operations"
3354
3355 g_module_suffix="$glib_gmodule_suffix"
3356
3357 g_pid_type="$glib_pid_type"
3358 case $host in
3359   *-*-beos*)
3360     glib_os="#define G_OS_BEOS"
3361     ;;
3362   *-*-cygwin*)
3363     glib_os="#define G_OS_UNIX
3364 #define G_PLATFORM_WIN32
3365 #define G_WITH_CYGWIN"
3366     ;;
3367   *-*-mingw*)
3368     glib_os="#define G_OS_WIN32
3369 #define G_PLATFORM_WIN32"
3370     ;;
3371   *)
3372     glib_os="#define G_OS_UNIX"
3373     ;;
3374 esac
3375 glib_static_compilation=""
3376 if test x$glib_win32_static_compilation = xyes; then
3377   glib_static_compilation="#define GLIB_STATIC_COMPILATION 1
3378 #define GOBJECT_STATIC_COMPILATION 1"
3379 fi
3380 ])
3381
3382 # Redo enough to get guint32 and guint64 for the alignment checks below
3383 case 4 in
3384 $ac_cv_sizeof_short)
3385   gint32=short
3386   ;;
3387 $ac_cv_sizeof_int)
3388   gint32=int
3389   ;;
3390 $ac_cv_sizeof_long)
3391   gint32=long
3392   ;;
3393 esac
3394 case 8 in
3395 $ac_cv_sizeof_int)
3396   gint64=int
3397   ;;
3398 $ac_cv_sizeof_long)
3399   gint64=long
3400   ;;
3401 $ac_cv_sizeof_long_long)
3402   gint64='long long'
3403   ;;
3404 $ac_cv_sizeof___int64)
3405   gint64='__int64'
3406   ;;
3407 esac
3408
3409 AC_CHECK_ALIGNOF([guint32], [AC_INCLUDES_DEFAULT
3410 typedef unsigned $gint32 guint32;])
3411 AC_CHECK_ALIGNOF([guint64], [AC_INCLUDES_DEFAULT
3412 typedef unsigned $gint64 guint64;])
3413 AC_CHECK_ALIGNOF([unsigned long])
3414
3415 # Check for libdbus1 - Optional - is only used in the GDBus test cases
3416 #
3417 # 1.2.14 required for dbus_message_set_serial
3418 PKG_CHECK_MODULES(DBUS1,
3419                   dbus-1 >= 1.2.14,
3420                   [AC_DEFINE(HAVE_DBUS1, 1, [Define if dbus-1 is available]) have_dbus1=yes],
3421                   have_dbus1=no)
3422 AC_SUBST(DBUS1_CFLAGS)
3423 AC_SUBST(DBUS1_LIBS)
3424 AM_CONDITIONAL(HAVE_DBUS1, [test "x$have_dbus1" = "xyes"])
3425
3426 dnl
3427 dnl Check for -Bsymbolic-functions linker flag used to avoid
3428 dnl intra-library PLT jumps, if available.
3429 dnl
3430
3431 AC_ARG_ENABLE(Bsymbolic,
3432               [AC_HELP_STRING([--disable-Bsymbolic],
3433                               [avoid linking with -Bsymbolic])],,
3434               [SAVED_LDFLAGS="${LDFLAGS}"
3435                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
3436                LDFLAGS=-Wl,-Bsymbolic-functions
3437                AC_TRY_LINK([], [int main (void) { return 0; }],
3438                            AC_MSG_RESULT(yes)
3439                            enable_Bsymbolic=yes,
3440                            AC_MSG_RESULT(no)
3441                            enable_Bsymbolic=no)
3442                LDFLAGS="${SAVED_LDFLAGS}"])
3443
3444 if test "x${enable_Bsymbolic}" = "xyes"; then
3445   GLIB_LINK_FLAGS=-Wl,-Bsymbolic-functions
3446 fi
3447
3448 AC_SUBST(GLIB_LINK_FLAGS)
3449
3450 #
3451 # Define variables corresponding to the correct include paths to use for
3452 # in-tree building.
3453 #
3454
3455 # for config.h:
3456 config_h_INCLUDES='-I$(top_builddir)'
3457 AC_SUBST(config_h_INCLUDES)
3458
3459 # glib:
3460 #   config.h
3461 #   $(top_builddir)/glib: for glibconfig.h
3462 #   $(top_srcdir)/glib:   for glib.h
3463 #   $(top_srcdir):        for everything
3464 glib_INCLUDES='$(config_h_INCLUDES) -I$(top_builddir)/glib -I$(top_srcdir)/glib -I$(top_srcdir)'
3465 AC_SUBST(glib_INCLUDES)
3466
3467 # gthread:
3468 #   same as glib
3469 gthread_INCLUDES='$(glib_INCLUDES)'
3470 AC_SUBST(gthread_INCLUDES)
3471
3472 # gobject:
3473 #   same as gthread
3474 gobject_INCLUDES='$(gthread_INCLUDES)'
3475 AC_SUBST(gobject_INCLUDES)
3476
3477 # gmodule:
3478 #   glib includes
3479 #   $(top_srcdir)/gmodule: for gmodule.h
3480 gmodule_INCLUDES='$(glib_INCLUDES) -I$(top_srcdir)/gmodule'
3481 AC_SUBST(gmodule_INCLUDES)
3482
3483 # gio:
3484 #   same as gmodule
3485 gio_INCLUDES='$(gmodule_INCLUDES)'
3486 AC_SUBST(gio_INCLUDES)
3487
3488
3489 AC_CONFIG_FILES([
3490 glib-2.0.pc
3491 gmodule-2.0.pc
3492 gmodule-export-2.0.pc
3493 gmodule-no-export-2.0.pc
3494 gthread-2.0.pc
3495 gobject-2.0.pc
3496 gio-2.0.pc
3497 gio-unix-2.0.pc
3498 gio-windows-2.0.pc
3499 glib-zip
3500 glib-gettextize
3501 Makefile
3502 build/Makefile
3503 build/win32/Makefile
3504 build/win32/dirent/Makefile
3505 build/win32/vs9/Makefile
3506 build/win32/vs10/Makefile
3507 glib/Makefile
3508 glib/glib.stp
3509 glib/libcharset/Makefile
3510 glib/gnulib/Makefile
3511 glib/pcre/Makefile
3512 glib/update-pcre/Makefile
3513 glib/tests/Makefile
3514 gmodule/Makefile
3515 gmodule/gmoduleconf.h
3516 gobject/Makefile
3517 gobject/gobject.stp
3518 gobject/glib-mkenums
3519 gobject/tests/Makefile
3520 gthread/Makefile
3521 gio/Makefile
3522 gio/gdbus-2.0/codegen/Makefile
3523 gio/gdbus-2.0/codegen/config.py
3524 gio/xdgmime/Makefile
3525 gio/inotify/Makefile
3526 gio/fen/Makefile
3527 gio/fam/Makefile
3528 gio/win32/Makefile
3529 gio/tests/Makefile
3530 gio/tests/gdbus-object-manager-example/Makefile
3531 po/Makefile.in
3532 docs/Makefile
3533 docs/reference/Makefile
3534 docs/reference/glib/Makefile
3535 docs/reference/glib/version.xml
3536 docs/reference/gobject/Makefile
3537 docs/reference/gobject/version.xml
3538 docs/reference/gio/Makefile
3539 docs/reference/gio/gdbus-object-manager-example/Makefile
3540 docs/reference/gio/version.xml
3541 tests/Makefile
3542 tests/gobject/Makefile
3543 tests/refcount/Makefile
3544 m4macros/Makefile
3545 ])
3546
3547 AC_CONFIG_COMMANDS([chmod-scripts],
3548 [chmod 0755 glib-zip
3549 chmod 0755 glib-gettextize
3550 chmod 0755 gobject/glib-mkenums])
3551
3552 # we want to invoke this macro solely so that the config.status script
3553 # and automake generated makefiles know about these generated files.
3554 # They are only needed to distcheck the package
3555 if false; then
3556   AC_CONFIG_FILES([
3557     INSTALL
3558     README
3559     config.h.win32
3560     glib/glibconfig.h.win32
3561     glib/makefile.msc
3562     glib/glib.rc
3563     gmodule/makefile.msc
3564     gmodule/gmodule.rc
3565     gobject/makefile.msc
3566     gobject/gobject.rc
3567     gthread/makefile.msc
3568     gthread/gthread.rc
3569     gio/gio.rc
3570     tests/makefile.msc
3571   ])
3572 fi
3573
3574 AC_OUTPUT